qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include <common/effects/qc/globalsound.qh>
  36
  37 #include "../common/mapobjects/func/conveyor.qh"
  38 #include "../common/mapobjects/teleporters.qh"
  39 #include "../common/mapobjects/target/spawnpoint.qh"
  40
  41 #include "../common/vehicles/all.qh"
  42
  43 #include "weapons/hitplot.qh"
  44 #include "weapons/weaponsystem.qh"
  45
  46 #include "../common/net_notice.qh"
  47 #include "../common/net_linked.qh"
  48 #include "../common/physics/player.qh"
  49
  50 #include <common/vehicles/sv_vehicles.qh>
  51
  52 #include "../common/items/_mod.qh"
  53
  54 #include "../common/mutators/mutator/waypoints/all.qh"
  55 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  56 #include <common/gamemodes/_mod.qh>
  57
  58 #include "../common/mapobjects/subs.qh"
  59 #include "../common/mapobjects/triggers.qh"
  60 #include "../common/mapobjects/trigger/secret.qh"
  61
  62 #include "../common/minigames/sv_minigames.qh"
  63
  64 #include "../common/items/inventory.qh"
  65
  66 #include "../common/monsters/sv_monsters.qh"
  67
  68 #include "../lib/warpzone/server.qh"
  69
  70 #include <common/mutators/mutator/overkill/oknex.qh>
  71
  72 STATIC_METHOD(Client, Add, void(Client this, int _team))
  73 {
  74     ClientConnect(this);
  75     TRANSMUTE(Player, this);
  76     this.frame = 12; // 7
  77     this.team = _team;
  78     PutClientInServer(this);
  79 }
  80
  81 STATIC_METHOD(Client, Remove, void(Client this))
  82 {
  83     TRANSMUTE(Observer, this);
  84     PutClientInServer(this);
  85     ClientDisconnect(this);
  86 }
  87
  88 void send_CSQC_teamnagger() {
  89         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  90 }
  91
  92 int CountSpectators(entity player, entity to)
  93 {
  94         if(!player) { return 0; } // not sure how, but best to be safe
  95
  96         int spec_count = 0;
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 spec_count++;
 101         });
 102
 103         return spec_count;
 104 }
 105
 106 void WriteSpectators(entity player, entity to)
 107 {
 108         if(!player) { return; } // not sure how, but best to be safe
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 WriteByte(MSG_ENTITY, num_for_edict(it));
 113         });
 114 }
 115
 116 bool ClientData_Send(entity this, entity to, int sf)
 117 {
 118         assert(to == this.owner, return false);
 119
 120         entity e = to;
 121         if (IS_SPEC(e)) e = e.enemy;
 122
 123         sf = 0;
 124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 128
 129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 130         WriteByte(MSG_ENTITY, sf);
 131
 132         if (sf & BIT(1))
 133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 134
 135         if(sf & BIT(4))
 136         {
 137                 float specs = CountSpectators(e, to);
 138                 WriteByte(MSG_ENTITY, specs);
 139                 WriteSpectators(e, to);
 140         }
 141
 142         return true;
 143 }
 144
 145 void ClientData_Attach(entity this)
 146 {
 147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 148         CS(this).clientdata.drawonlytoclient = this;
 149         CS(this).clientdata.owner = this;
 150 }
 151
 152 void ClientData_Detach(entity this)
 153 {
 154         delete(CS(this).clientdata);
 155         CS(this).clientdata = NULL;
 156 }
 157
 158 void ClientData_Touch(entity e)
 159 {
 160         entity cd = CS(e).clientdata;
 161         if (cd) { cd.SendFlags = 1; }
 162
 163         // make it spectatable
 164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 165         {
 166                 entity cd = CS(it).clientdata;
 167                 if (cd) { cd.SendFlags = 1; }
 168         });
 169 }
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 /** putting a client as observer in the server */
 225 void PutObserverInServer(entity this)
 226 {
 227     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 228         PlayerState_detach(this);
 229
 230         if (IS_PLAYER(this))
 231         {
 232                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 233                 {
 234                         // despawn effect
 235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 236                 }
 237
 238                 // was a player, recount votes and ready status
 239                 if(IS_REAL_CLIENT(this))
 240                 {
 241                         if (vote_called) { VoteCount(false); }
 242                         ReadyCount();
 243                 }
 244     }
 245
 246     {
 247         entity spot = SelectSpawnPoint(this, true);
 248         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 249         this.angles = vec2(spot.angles);
 250         this.fixangle = true;
 251         // offset it so that the spectator spawns higher off the ground, looks better this way
 252         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 253         if (IS_REAL_CLIENT(this))
 254         {
 255             msg_entity = this;
 256             WriteByte(MSG_ONE, SVC_SETVIEW);
 257             WriteEntity(MSG_ONE, this);
 258         }
 259         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 260         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 261         if(!autocvar_g_debug_globalsounds)
 262         {
 263                 // needed for player sounds
 264                 this.model = "";
 265                 FixPlayermodel(this);
 266         }
 267         setmodel(this, MDL_Null);
 268         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 269         this.view_ofs = '0 0 0';
 270     }
 271
 272     RemoveGrapplingHooks(this);
 273         Portal_ClearAll(this);
 274         Unfreeze(this);
 275         SetSpectatee(this, NULL);
 276
 277         if (this.alivetime)
 278         {
 279                 if (!warmup_stage)
 280                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 281                 this.alivetime = 0;
 282         }
 283
 284         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 285
 286         WaypointSprite_PlayerDead(this);
 287
 288         if (mutator_returnvalue) {
 289             // mutator prevents resetting teams+score
 290         } else {
 291                 Player_SetTeamIndex(this, -1);
 292                 this.frags = FRAGS_SPECTATOR;
 293         PlayerScore_Clear(this);  // clear scores when needed
 294     }
 295
 296         if (CS(this).killcount != FRAGS_SPECTATOR)
 297         {
 298                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 299                 if(!game_stopped)
 300                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 301                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 302
 303                 if(!CS(this).just_joined)
 304                         LogTeamchange(this.playerid, -1, TEAM_CHANGE_SPECTATOR);
 305                 else
 306                         CS(this).just_joined = false;
 307         }
 308
 309         accuracy_resend(this);
 310
 311         CS(this).spectatortime = time;
 312         if(this.bot_attack)
 313                 IL_REMOVE(g_bot_targets, this);
 314         this.bot_attack = false;
 315         if(this.monster_attack)
 316                 IL_REMOVE(g_monster_targets, this);
 317         this.monster_attack = false;
 318     STAT(HUD, this) = HUD_NORMAL;
 319         TRANSMUTE(Observer, this);
 320         this.iscreature = false;
 321         this.teleportable = TELEPORT_SIMPLE;
 322         if(this.damagedbycontents)
 323                 IL_REMOVE(g_damagedbycontents, this);
 324         this.damagedbycontents = false;
 325         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 326         SetSpectatee_status(this, etof(this));
 327         this.takedamage = DAMAGE_NO;
 328         this.solid = SOLID_NOT;
 329         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 330         this.flags = FL_CLIENT | FL_NOTARGET;
 331         this.effects = 0;
 332         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 333         this.pauserotarmor_finished = 0;
 334         this.pauserothealth_finished = 0;
 335         this.pauseregen_finished = 0;
 336         this.damageforcescale = 0;
 337         this.death_time = 0;
 338         this.respawn_flags = 0;
 339         this.respawn_time = 0;
 340         STAT(RESPAWN_TIME, this) = 0;
 341         this.alpha = 0;
 342         this.scale = 0;
 343         this.fade_time = 0;
 344         this.pain_frame = 0;
 345         this.pain_finished = 0;
 346         this.strength_finished = 0;
 347         this.invincible_finished = 0;
 348         this.superweapons_finished = 0;
 349         this.dphitcontentsmask = 0;
 350         this.pushltime = 0;
 351         this.istypefrag = 0;
 352         setthink(this, func_null);
 353         this.nextthink = 0;
 354         this.deadflag = DEAD_NO;
 355         this.crouch = false;
 356         STAT(REVIVE_PROGRESS, this) = 0;
 357         this.revival_time = 0;
 358
 359         this.items = 0;
 360         STAT(WEAPONS, this) = '0 0 0';
 361         this.drawonlytoclient = this;
 362
 363         this.viewloc = NULL;
 364
 365         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 366
 367         this.weaponmodel = "";
 368         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 369         {
 370                 this.weaponentities[slot] = NULL;
 371         }
 372         this.exteriorweaponentity = NULL;
 373         CS(this).killcount = FRAGS_SPECTATOR;
 374         this.velocity = '0 0 0';
 375         this.avelocity = '0 0 0';
 376         this.punchangle = '0 0 0';
 377         this.punchvector = '0 0 0';
 378         this.oldvelocity = this.velocity;
 379         this.fire_endtime = -1;
 380         this.event_damage = func_null;
 381
 382         for(int slot = 0; slot < MAX_AXH; ++slot)
 383         {
 384                 entity axh = this.(AuxiliaryXhair[slot]);
 385                 this.(AuxiliaryXhair[slot]) = NULL;
 386
 387                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 388                         delete(axh);
 389         }
 390 }
 391
 392 int player_getspecies(entity this)
 393 {
 394         get_model_parameters(this.model, this.skin);
 395         int s = get_model_parameters_species;
 396         get_model_parameters(string_null, 0);
 397         if (s < 0) return SPECIES_HUMAN;
 398         return s;
 399 }
 400
 401 .float model_randomizer;
 402 void FixPlayermodel(entity player)
 403 {
 404         string defaultmodel = "";
 405         int defaultskin = 0;
 406         if(autocvar_sv_defaultcharacter)
 407         {
 408                 if(teamplay)
 409                 {
 410                         switch(player.team)
 411                         {
 412                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 413                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 414                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 415                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 416                         }
 417                 }
 418
 419                 if(defaultmodel == "")
 420                 {
 421                         defaultmodel = autocvar_sv_defaultplayermodel;
 422                         defaultskin = autocvar_sv_defaultplayerskin;
 423                 }
 424
 425                 int n = tokenize_console(defaultmodel);
 426                 if(n > 0)
 427                 {
 428                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 429                         // However, do NOT randomize if the player-selected model is in the list.
 430                         for (int i = 0; i < n; ++i)
 431                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 432                                         defaultmodel = argv(i);
 433                 }
 434
 435                 int i = strstrofs(defaultmodel, ":", 0);
 436                 if(i >= 0)
 437                 {
 438                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 439                         defaultmodel = substring(defaultmodel, 0, i);
 440                 }
 441         }
 442         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 443         {
 444                 if(teamplay)
 445                 {
 446                         switch(player.team)
 447                         {
 448                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 449                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 450                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 451                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 452                         }
 453                 }
 454
 455                 if(!defaultskin)
 456                         defaultskin = autocvar_sv_defaultplayerskin;
 457         }
 458
 459         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 460         defaultmodel = M_ARGV(0, string);
 461         defaultskin = M_ARGV(1, int);
 462
 463         bool chmdl = false;
 464         int oldskin;
 465         if(defaultmodel != "")
 466         {
 467                 if (defaultmodel != player.model)
 468                 {
 469                         vector m1 = player.mins;
 470                         vector m2 = player.maxs;
 471                         setplayermodel (player, defaultmodel);
 472                         setsize (player, m1, m2);
 473                         chmdl = true;
 474                 }
 475
 476                 oldskin = player.skin;
 477                 player.skin = defaultskin;
 478         } else {
 479                 if (player.playermodel != player.model || player.playermodel == "")
 480                 {
 481                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 482                         vector m1 = player.mins;
 483                         vector m2 = player.maxs;
 484                         setplayermodel (player, player.playermodel);
 485                         setsize (player, m1, m2);
 486                         chmdl = true;
 487                 }
 488
 489                 if(!autocvar_sv_defaultcharacterskin)
 490                 {
 491                         oldskin = player.skin;
 492                         player.skin = stof(player.playerskin);
 493                 }
 494                 else
 495                 {
 496                         oldskin = player.skin;
 497                         player.skin = defaultskin;
 498                 }
 499         }
 500
 501         if(chmdl || oldskin != player.skin) // model or skin has changed
 502         {
 503                 player.species = player_getspecies(player); // update species
 504                 if(!autocvar_g_debug_globalsounds)
 505                         UpdatePlayerSounds(player); // update skin sounds
 506         }
 507
 508         if(!teamplay)
 509                 if(strlen(autocvar_sv_defaultplayercolors))
 510                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 511                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 512 }
 513
 514 void PutPlayerInServer(entity this)
 515 {
 516         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 517
 518         PlayerState_attach(this);
 519         accuracy_resend(this);
 520
 521         if (this.team < 0)
 522                 TeamBalance_JoinBestTeam(this, true);
 523
 524         entity spot = SelectSpawnPoint(this, false);
 525         if (!spot) {
 526                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 527                 return; // spawn failed
 528         }
 529
 530         TRANSMUTE(Player, this);
 531
 532         CS(this).wasplayer = true;
 533         this.iscreature = true;
 534         this.teleportable = TELEPORT_NORMAL;
 535         if(!this.damagedbycontents)
 536                 IL_PUSH(g_damagedbycontents, this);
 537         this.damagedbycontents = true;
 538         set_movetype(this, MOVETYPE_WALK);
 539         this.solid = SOLID_SLIDEBOX;
 540         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 541         if (autocvar_g_playerclip_collisions)
 542                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 543         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 545         this.frags = FRAGS_PLAYER;
 546         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 547         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 548         if (autocvar__notarget)
 549                 this.flags |= FL_NOTARGET;
 550         this.takedamage = DAMAGE_AIM;
 551         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 552
 553         if (warmup_stage) {
 554                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 555                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 556                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 557                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 558                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 559                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 560                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 561                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 562                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 563         } else {
 564                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 565                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 566                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 567                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 568                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 569                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 570                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 571                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 572                 STAT(WEAPONS, this) = start_weapons;
 573                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 574                 {
 575                         GiveRandomWeapons(this, random_start_weapons_count,
 576                                 autocvar_g_random_start_weapons, random_start_ammo);
 577                 }
 578         }
 579         SetSpectatee_status(this, 0);
 580
 581         PS(this).dual_weapons = '0 0 0';
 582
 583         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 584
 585         this.items = start_items;
 586
 587         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 588         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 589         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 590         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 591         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 592         if (!sv_ready_restart_after_countdown && time < game_starttime)
 593         {
 594                 float f = game_starttime - time;
 595                 this.spawnshieldtime += f;
 596                 this.pauserotarmor_finished += f;
 597                 this.pauserothealth_finished += f;
 598                 this.pauseregen_finished += f;
 599         }
 600
 601         this.damageforcescale = 2;
 602         this.death_time = 0;
 603         this.respawn_flags = 0;
 604         this.respawn_time = 0;
 605         STAT(RESPAWN_TIME, this) = 0;
 606         this.scale = autocvar_sv_player_scale;
 607         this.fade_time = 0;
 608         this.pain_frame = 0;
 609         this.pain_finished = 0;
 610         this.pushltime = 0;
 611         setthink(this, func_null); // players have no think function
 612         this.nextthink = 0;
 613         this.dmg_team = 0;
 614         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 615
 616         this.deadflag = DEAD_NO;
 617
 618         this.angles = spot.angles;
 619         this.angles_z = 0; // never spawn tilted even if the spot says to
 620         if (IS_BOT_CLIENT(this))
 621                 this.v_angle = this.angles;
 622         this.fixangle = true; // turn this way immediately
 623         this.oldvelocity = this.velocity = '0 0 0';
 624         this.avelocity = '0 0 0';
 625         this.punchangle = '0 0 0';
 626         this.punchvector = '0 0 0';
 627
 628         this.strength_finished = 0;
 629         this.invincible_finished = 0;
 630         this.fire_endtime = -1;
 631         STAT(REVIVE_PROGRESS, this) = 0;
 632         this.revival_time = 0;
 633
 634         this.air_finished = time + 12;
 635         this.waterlevel = WATERLEVEL_NONE;
 636         this.watertype = CONTENT_EMPTY;
 637
 638         entity spawnevent = new_pure(spawnevent);
 639         spawnevent.owner = this;
 640         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 641
 642         // Cut off any still running player sounds.
 643         stopsound(this, CH_PLAYER_SINGLE);
 644
 645         this.model = "";
 646         FixPlayermodel(this);
 647         this.drawonlytoclient = NULL;
 648
 649         this.viewloc = NULL;
 650
 651         for(int slot = 0; slot < MAX_AXH; ++slot)
 652         {
 653                 entity axh = this.(AuxiliaryXhair[slot]);
 654                 this.(AuxiliaryXhair[slot]) = NULL;
 655
 656                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 657                         delete(axh);
 658         }
 659
 660         this.spawnpoint_targ = NULL;
 661
 662         this.crouch = false;
 663         this.view_ofs = STAT(PL_VIEW_OFS, this);
 664         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 665         this.spawnorigin = spot.origin;
 666         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 667         // don't reset back to last position, even if new position is stuck in solid
 668         this.oldorigin = this.origin;
 669         if(this.conveyor)
 670                 IL_REMOVE(g_conveyed, this);
 671         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 672         STAT(HUD, this) = HUD_NORMAL;
 673
 674         this.event_damage = PlayerDamage;
 675
 676         if(!this.bot_attack)
 677                 IL_PUSH(g_bot_targets, this);
 678         this.bot_attack = true;
 679         if(!this.monster_attack)
 680                 IL_PUSH(g_monster_targets, this);
 681         this.monster_attack = true;
 682         navigation_dynamicgoal_init(this, false);
 683
 684         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 685
 686         // player was spectator
 687         if (CS(this).killcount == FRAGS_SPECTATOR) {
 688                 PlayerScore_Clear(this);
 689                 CS(this).killcount = 0;
 690                 CS(this).startplaytime = time;
 691         }
 692
 693         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 694         {
 695                 .entity weaponentity = weaponentities[slot];
 696                 entity oldwep = this.(weaponentity);
 697                 CL_SpawnWeaponentity(this, weaponentity);
 698                 if(oldwep && oldwep.owner == this)
 699                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 700         }
 701         this.alpha = default_player_alpha;
 702         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 703         this.exteriorweaponentity.alpha = default_weapon_alpha;
 704
 705         this.speedrunning = false;
 706
 707         target_voicescript_clear(this);
 708
 709         // reset fields the weapons may use
 710         FOREACH(Weapons, true, {
 711                 it.wr_resetplayer(it, this);
 712                         // reload all reloadable weapons
 713                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 714                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 715                         {
 716                                 .entity weaponentity = weaponentities[slot];
 717                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 718                         }
 719                 }
 720         });
 721
 722         {
 723                 string s = spot.target;
 724                 spot.target = string_null;
 725                 SUB_UseTargets(spot, this, NULL);
 726                 spot.target = s;
 727         }
 728
 729         Unfreeze(this);
 730
 731         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 732
 733         if (autocvar_spawn_debug)
 734         {
 735                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 736                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 737         }
 738
 739         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 740         {
 741                 .entity weaponentity = weaponentities[slot];
 742                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 743                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 744                 else
 745                         this.(weaponentity).m_switchweapon = WEP_Null;
 746                 this.(weaponentity).m_weapon = WEP_Null;
 747                 this.(weaponentity).weaponname = "";
 748                 this.(weaponentity).m_switchingweapon = WEP_Null;
 749                 this.(weaponentity).cnt = -1;
 750         }
 751
 752         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 753
 754         if (!warmup_stage && !this.alivetime)
 755                 this.alivetime = time;
 756
 757         antilag_clear(this, CS(this));
 758 }
 759
 760 /** Called when a client spawns in the server */
 761 void PutClientInServer(entity this)
 762 {
 763         if (IS_BOT_CLIENT(this)) {
 764                 TRANSMUTE(Player, this);
 765         } else if (IS_REAL_CLIENT(this)) {
 766                 msg_entity = this;
 767                 WriteByte(MSG_ONE, SVC_SETVIEW);
 768                 WriteEntity(MSG_ONE, this);
 769         }
 770         if (game_stopped)
 771                 TRANSMUTE(Observer, this);
 772
 773         SetSpectatee(this, NULL);
 774
 775         // reset player keys
 776         if(PS(this))
 777                 PS(this).itemkeys = 0;
 778
 779         MUTATOR_CALLHOOK(PutClientInServer, this);
 780
 781         if (IS_OBSERVER(this)) {
 782                 PutObserverInServer(this);
 783         } else if (IS_PLAYER(this)) {
 784                 PutPlayerInServer(this);
 785         }
 786 }
 787
 788 // TODO do we need all these fields, or should we stop autodetecting runtime
 789 // changes and just have a console command to update this?
 790 bool ClientInit_SendEntity(entity this, entity to, int sf)
 791 {
 792         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 793         return = true;
 794         msg_entity = to;
 795         // MSG_INIT replacement
 796         // TODO: make easier to use
 797         Registry_send_all();
 798         W_PROP_reload(MSG_ONE, to);
 799         ClientInit_misc(this);
 800         MUTATOR_CALLHOOK(Ent_Init);
 801 }
 802 void ClientInit_misc(entity this)
 803 {
 804         int channel = MSG_ONE;
 805         WriteHeader(channel, ENT_CLIENT_INIT);
 806         WriteByte(channel, g_nexball_meter_period * 32);
 807         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 810         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 811         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 814         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 815
 816         if(sv_foginterval && world.fog != "")
 817                 WriteString(channel, world.fog);
 818         else
 819                 WriteString(channel, "");
 820         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 821         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 822         WriteByte(channel, serverflags);
 823         WriteCoord(channel, autocvar_g_trueaim_minrange);
 824 }
 825
 826 void ClientInit_CheckUpdate(entity this)
 827 {
 828         this.nextthink = time;
 829         if(this.count != autocvar_g_balance_armor_blockpercent)
 830         {
 831                 this.count = autocvar_g_balance_armor_blockpercent;
 832                 this.SendFlags |= 1;
 833         }
 834         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 835         {
 836                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 837                 this.SendFlags |= 1;
 838         }
 839 }
 840
 841 void ClientInit_Spawn()
 842 {
 843         entity e = new_pure(clientinit);
 844         setthink(e, ClientInit_CheckUpdate);
 845         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 846
 847         ClientInit_CheckUpdate(e);
 848 }
 849
 850 /*
 851 =============
 852 SetNewParms
 853 =============
 854 */
 855 void SetNewParms ()
 856 {
 857         // initialize parms for a new player
 858         parm1 = -(86400 * 366);
 859
 860         MUTATOR_CALLHOOK(SetNewParms);
 861 }
 862
 863 /*
 864 =============
 865 SetChangeParms
 866 =============
 867 */
 868 void SetChangeParms (entity this)
 869 {
 870         // save parms for level change
 871         parm1 = CS(this).parm_idlesince - time;
 872
 873         MUTATOR_CALLHOOK(SetChangeParms);
 874 }
 875
 876 /*
 877 =============
 878 DecodeLevelParms
 879 =============
 880 */
 881 void DecodeLevelParms(entity this)
 882 {
 883         // load parms
 884         CS(this).parm_idlesince = parm1;
 885         if (CS(this).parm_idlesince == -(86400 * 366))
 886                 CS(this).parm_idlesince = time;
 887
 888         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 889         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 890
 891         MUTATOR_CALLHOOK(DecodeLevelParms);
 892 }
 893
 894 /*
 895 =============
 896 ClientKill
 897
 898 Called when a client types 'kill' in the console
 899 =============
 900 */
 901
 902 .float clientkill_nexttime;
 903 void ClientKill_Now_TeamChange(entity this)
 904 {
 905         if(this.killindicator_teamchange == -1)
 906         {
 907                 TeamBalance_JoinBestTeam(this, true);
 908         }
 909         else if(this.killindicator_teamchange == -2)
 910         {
 911                 if(blockSpectators)
 912                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 913                 PutObserverInServer(this);
 914         }
 915         else
 916                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 917         this.killindicator_teamchange = 0;
 918 }
 919
 920 void ClientKill_Now(entity this)
 921 {
 922         if(this.vehicle)
 923         {
 924             vehicles_exit(this.vehicle, VHEF_RELEASE);
 925             if(!this.killindicator_teamchange)
 926             {
 927             this.vehicle_health = -1;
 928             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 929             }
 930         }
 931
 932         if(this.killindicator && !wasfreed(this.killindicator))
 933                 delete(this.killindicator);
 934
 935         this.killindicator = NULL;
 936
 937         if(this.killindicator_teamchange)
 938                 ClientKill_Now_TeamChange(this);
 939
 940         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 941         {
 942                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 943         }
 944
 945         // now I am sure the player IS dead
 946 }
 947 void KillIndicator_Think(entity this)
 948 {
 949         if (game_stopped)
 950         {
 951                 this.owner.killindicator = NULL;
 952                 delete(this);
 953                 return;
 954         }
 955
 956         if (this.owner.alpha < 0 && !this.owner.vehicle)
 957         {
 958                 this.owner.killindicator = NULL;
 959                 delete(this);
 960                 return;
 961         }
 962
 963         if(this.cnt <= 0)
 964         {
 965                 ClientKill_Now(this.owner);
 966                 return;
 967         }
 968     else if(this.count == 1) // count == 1 means that it's silent
 969     {
 970         this.nextthink = time + 1;
 971         this.cnt -= 1;
 972     }
 973         else
 974         {
 975                 if(this.cnt <= 10)
 976                         setmodel(this, MDL_NUM(this.cnt));
 977                 if(IS_REAL_CLIENT(this.owner))
 978                 {
 979                         if(this.cnt <= 10)
 980                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 981                 }
 982                 this.nextthink = time + 1;
 983                 this.cnt -= 1;
 984         }
 985 }
 986
 987 float clientkilltime;
 988 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 989 {
 990         float killtime;
 991         float starttime;
 992
 993         if (game_stopped)
 994                 return;
 995
 996         killtime = autocvar_g_balance_kill_delay;
 997
 998     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 999         return;
1000     killtime = M_ARGV(1, float);
1001
1002         this.killindicator_teamchange = targetteam;
1003
1004     if(!this.killindicator)
1005         {
1006                 if(!IS_DEAD(this))
1007                 {
1008                         killtime = max(killtime, this.clientkill_nexttime - time);
1009                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1010                 }
1011
1012                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1013                 {
1014                         ClientKill_Now(this);
1015                 }
1016                 else
1017                 {
1018                         starttime = max(time, clientkilltime);
1019
1020                         this.killindicator = spawn();
1021                         this.killindicator.owner = this;
1022                         this.killindicator.scale = 0.5;
1023                         setattachment(this.killindicator, this, "");
1024                         setorigin(this.killindicator, '0 0 52');
1025                         setthink(this.killindicator, KillIndicator_Think);
1026                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1027                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1028                         this.killindicator.cnt = ceil(killtime);
1029                         this.killindicator.count = bound(0, ceil(killtime), 10);
1030                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1031
1032                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1033                         {
1034                                 it.killindicator = spawn();
1035                                 it.killindicator.owner = it;
1036                                 it.killindicator.scale = 0.5;
1037                                 setattachment(it.killindicator, it, "");
1038                                 setorigin(it.killindicator, '0 0 52');
1039                                 setthink(it.killindicator, KillIndicator_Think);
1040                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1041                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1042                                 it.killindicator.cnt = ceil(killtime);
1043                         });
1044                         this.lip = 0;
1045                 }
1046         }
1047         if(this.killindicator)
1048         {
1049                 if(targetteam == 0) // just die
1050                 {
1051                         this.killindicator.colormod = '0 0 0';
1052                         if(IS_REAL_CLIENT(this))
1053                         if(this.killindicator.cnt > 0)
1054                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1055                 }
1056                 else if(targetteam == -1) // auto
1057                 {
1058                         this.killindicator.colormod = '0 1 0';
1059                         if(IS_REAL_CLIENT(this))
1060                         if(this.killindicator.cnt > 0)
1061                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1062                 }
1063                 else if(targetteam == -2) // spectate
1064                 {
1065                         this.killindicator.colormod = '0.5 0.5 0.5';
1066                         if(IS_REAL_CLIENT(this))
1067                         if(this.killindicator.cnt > 0)
1068                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1069                 }
1070                 else
1071                 {
1072                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1073                         if(IS_REAL_CLIENT(this))
1074                         if(this.killindicator.cnt > 0)
1075                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1076                 }
1077         }
1078
1079 }
1080
1081 void ClientKill (entity this)
1082 {
1083         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1084
1085         if(game_stopped) return;
1086         if(this.player_blocked) return;
1087         if(STAT(FROZEN, this)) return;
1088
1089         ClientKill_TeamChange(this, 0);
1090 }
1091
1092 void FixClientCvars(entity e)
1093 {
1094         // send prediction settings to the client
1095         stuffcmd(e, "\nin_bindmap 0 0\n");
1096         if(autocvar_g_antilag == 3) // client side hitscan
1097                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1098         if(autocvar_sv_gentle)
1099                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1100
1101         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1102         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1103
1104         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1105
1106         MUTATOR_CALLHOOK(FixClientCvars, e);
1107 }
1108
1109 bool findinlist_abbrev(string tofind, string list)
1110 {
1111         if(list == "" || tofind == "")
1112                 return false; // empty list or search, just return
1113
1114         // this function allows abbreviated strings!
1115         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1116         {
1117                 return true;
1118         });
1119
1120         return false;
1121 }
1122
1123 bool PlayerInIPList(entity p, string iplist)
1124 {
1125         // some safety checks (never allow local?)
1126         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1127                 return false;
1128
1129         return findinlist_abbrev(p.netaddress, iplist);
1130 }
1131
1132 bool PlayerInIDList(entity p, string idlist)
1133 {
1134         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1135         if(!p.crypto_idfp)
1136                 return false;
1137
1138         return findinlist_abbrev(p.crypto_idfp, idlist);
1139 }
1140
1141 bool PlayerInList(entity player, string list)
1142 {
1143         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1144 }
1145
1146 #ifdef DP_EXT_PRECONNECT
1147 /*
1148 =============
1149 ClientPreConnect
1150
1151 Called once (not at each match start) when a client begins a connection to the server
1152 =============
1153 */
1154 void ClientPreConnect(entity this)
1155 {
1156         if(autocvar_sv_eventlog)
1157         {
1158                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1159                         this.playerid,
1160                         etof(this),
1161                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1162                 ));
1163         }
1164 }
1165 #endif
1166
1167 string GetClientVersionMessage(entity this)
1168 {
1169         if (CS(this).version_mismatch) {
1170                 if(CS(this).version < autocvar_gameversion) {
1171                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1172                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1173                 } else {
1174                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1175                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1176                 }
1177         } else {
1178                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1179         }
1180 }
1181
1182 string getwelcomemessage(entity this)
1183 {
1184         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1185         string modifications = M_ARGV(0, string);
1186
1187         if(g_weaponarena)
1188         {
1189                 if(g_weaponarena_random)
1190                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1191                 else
1192                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1193         }
1194         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1195                 modifications = strcat(modifications, ", No start weapons");
1196         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1197                 modifications = strcat(modifications, ", Low gravity");
1198         if(g_weapon_stay && !g_cts)
1199                 modifications = strcat(modifications, ", Weapons stay");
1200         if(g_jetpack)
1201                 modifications = strcat(modifications, ", Jet pack");
1202         if(autocvar_g_powerups == 0)
1203                 modifications = strcat(modifications, ", No powerups");
1204         if(autocvar_g_powerups > 0)
1205                 modifications = strcat(modifications, ", Powerups");
1206         modifications = substring(modifications, 2, strlen(modifications) - 2);
1207
1208         string versionmessage = GetClientVersionMessage(this);
1209         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1210
1211         if(modifications != "")
1212                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1213
1214         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1215         {
1216                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1217                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1218         }
1219
1220         if (cache_mutatormsg != "") {
1221                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1222         }
1223
1224         string mutator_msg = "";
1225         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1226         mutator_msg = M_ARGV(0, string);
1227
1228         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1229
1230         string motd = autocvar_sv_motd;
1231         if (motd != "") {
1232                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1233         }
1234         return s;
1235 }
1236
1237 /**
1238 =============
1239 ClientConnect
1240
1241 Called when a client connects to the server
1242 =============
1243 */
1244 void ClientConnect(entity this)
1245 {
1246         if (Ban_MaybeEnforceBanOnce(this)) return;
1247         assert(!IS_CLIENT(this), return);
1248         this.flags |= FL_CLIENT;
1249         assert(player_count >= 0, player_count = 0);
1250
1251 #ifdef WATERMARK
1252         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1253 #endif
1254         TRANSMUTE(Client, this);
1255         CS(this).version_nagtime = time + 10 + random() * 10;
1256
1257         // identify the right forced team
1258         if (autocvar_g_campaign)
1259         {
1260                 if (IS_REAL_CLIENT(this)) // only players, not bots
1261                 {
1262                         switch (autocvar_g_campaign_forceteam)
1263                         {
1264                                 case 1: this.team_forced = NUM_TEAM_1; break;
1265                                 case 2: this.team_forced = NUM_TEAM_2; break;
1266                                 case 3: this.team_forced = NUM_TEAM_3; break;
1267                                 case 4: this.team_forced = NUM_TEAM_4; break;
1268                                 default: this.team_forced = 0;
1269                         }
1270                 }
1271         }
1272         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1273         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1274         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1275         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1276         else switch (autocvar_g_forced_team_otherwise)
1277         {
1278                 default: this.team_forced = 0; break;
1279                 case "red": this.team_forced = NUM_TEAM_1; break;
1280                 case "blue": this.team_forced = NUM_TEAM_2; break;
1281                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1282                 case "pink": this.team_forced = NUM_TEAM_4; break;
1283                 case "spectate":
1284                 case "spectator":
1285                         this.team_forced = -1;
1286                         break;
1287         }
1288         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1289
1290         int playerid_save = this.playerid;
1291         this.playerid = 0; // silent
1292         TeamBalance_JoinBestTeam(this, false); // if the team number is valid, keep it
1293         this.playerid = playerid_save;
1294
1295         TRANSMUTE(Observer, this);
1296
1297         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1298
1299         // always track bots, don't ask for cl_allow_uidtracking
1300         if (IS_BOT_CLIENT(this))
1301                 PlayerStats_GameReport_AddPlayer(this);
1302         else
1303                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1304
1305         if (autocvar_sv_eventlog)
1306                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1307
1308         LogTeamchange(this.playerid, this.team, TEAM_CHANGE_CONNECT);
1309
1310         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1311
1312         if(teamplay && IS_PLAYER(this))
1313                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1314         else
1315                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1316
1317         stuffcmd(this, clientstuff, "\n");
1318         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1319
1320         FixClientCvars(this);
1321
1322         // get version info from player
1323         stuffcmd(this, "cmd clientversion $gameversion\n");
1324
1325         // notify about available teams
1326         if (teamplay)
1327         {
1328                 entity balance = TeamBalance_CheckAllowedTeams(this);
1329                 int t = TeamBalance_GetAllowedTeams(balance);
1330                 TeamBalance_Destroy(balance);
1331                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1332         }
1333         else
1334         {
1335                 stuffcmd(this, "set _teams_available 0\n");
1336         }
1337
1338         bot_relinkplayerlist();
1339
1340         CS(this).spectatortime = time;
1341         if (blockSpectators)
1342         {
1343                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1344         }
1345
1346         CS(this).jointime = time;
1347
1348         if (IS_REAL_CLIENT(this))
1349         {
1350                 if (g_weaponarena_weapons == WEPSET(TUBA))
1351                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1352         }
1353
1354         if (!sv_foginterval && world.fog != "")
1355                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1356
1357         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1358                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1359                         send_CSQC_teamnagger();
1360
1361         CSQCMODEL_AUTOINIT(this);
1362
1363         CS(this).model_randomizer = random();
1364
1365         if (IS_REAL_CLIENT(this))
1366                 sv_notice_join(this);
1367
1368         // update physics stats (players can spawn before physics runs)
1369         Physics_UpdateStats(this);
1370
1371         IL_EACH(g_initforplayer, it.init_for_player, {
1372                 it.init_for_player(it, this);
1373         });
1374
1375         Handicap_Initialize(this);
1376
1377         MUTATOR_CALLHOOK(ClientConnect, this);
1378
1379         if (IS_REAL_CLIENT(this))
1380         {
1381                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1382                 {
1383                         CS(this).motd_actived_time = -1;
1384                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1385                 }
1386         }
1387 }
1388 /*
1389 =============
1390 ClientDisconnect
1391
1392 Called when a client disconnects from the server
1393 =============
1394 */
1395 .entity chatbubbleentity;
1396 void ClientDisconnect(entity this)
1397 {
1398         assert(IS_CLIENT(this), return);
1399
1400         PlayerStats_GameReport_FinalizePlayer(this);
1401         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1402         if (CS(this).active_minigame) part_minigame(this);
1403         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1404
1405         if (autocvar_sv_eventlog)
1406                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1407
1408         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1409
1410         if(IS_SPEC(this))
1411                 SetSpectatee(this, NULL);
1412
1413     MUTATOR_CALLHOOK(ClientDisconnect, this);
1414
1415         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1416         strfree(CS(this).weaponorder_byimpulse);
1417         ClientState_detach(this);
1418
1419         Portal_ClearAll(this);
1420
1421         Unfreeze(this);
1422
1423         RemoveGrapplingHooks(this);
1424
1425         // Here, everything has been done that requires this player to be a client.
1426
1427         this.flags &= ~FL_CLIENT;
1428
1429         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1430         if (this.killindicator) delete(this.killindicator);
1431
1432         WaypointSprite_PlayerGone(this);
1433
1434         bot_relinkplayerlist();
1435
1436         strfree(this.clientstatus);
1437         if (this.personal) delete(this.personal);
1438
1439         this.playerid = 0;
1440         ReadyCount();
1441         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1442
1443         ONREMOVE(this);
1444 }
1445
1446 void ChatBubbleThink(entity this)
1447 {
1448         this.nextthink = time;
1449         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1450         {
1451                 if(this.owner) // but why can that ever be NULL?
1452                         this.owner.chatbubbleentity = NULL;
1453                 delete(this);
1454                 return;
1455         }
1456
1457         this.mdl = "";
1458
1459         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1460         {
1461                 if ( CS(this.owner).active_minigame )
1462                         this.mdl = "models/sprites/minigame_busy.iqm";
1463                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1464                         this.mdl = "models/misc/chatbubble.spr";
1465         }
1466
1467         if ( this.model != this.mdl )
1468                 _setmodel(this, this.mdl);
1469
1470 }
1471
1472 void UpdateChatBubble(entity this)
1473 {
1474         if (this.alpha < 0)
1475                 return;
1476         // spawn a chatbubble entity if needed
1477         if (!this.chatbubbleentity)
1478         {
1479                 this.chatbubbleentity = new(chatbubbleentity);
1480                 this.chatbubbleentity.owner = this;
1481                 this.chatbubbleentity.exteriormodeltoclient = this;
1482                 setthink(this.chatbubbleentity, ChatBubbleThink);
1483                 this.chatbubbleentity.nextthink = time;
1484                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1485                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1486                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1487                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1488                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1489                 //this.chatbubbleentity.model = "";
1490                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1491         }
1492 }
1493
1494
1495 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1496 // added to the model skins
1497 /*void UpdateColorModHack()
1498 {
1499         float c;
1500         c = this.clientcolors & 15;
1501         // LordHavoc: only bothering to support white, green, red, yellow, blue
1502              if (!teamplay) this.colormod = '0 0 0';
1503         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1504         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1505         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1506         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1507         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1508         else this.colormod = '1 1 1';
1509 }*/
1510
1511 void respawn(entity this)
1512 {
1513         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1514         {
1515                 this.solid = SOLID_NOT;
1516                 this.takedamage = DAMAGE_NO;
1517                 set_movetype(this, MOVETYPE_FLY);
1518                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1519                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1520                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1521                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1522                 if(autocvar_g_respawn_ghosts_maxtime)
1523                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1524         }
1525
1526         CopyBody(this, 1);
1527
1528         this.effects |= EF_NODRAW; // prevent another CopyBody
1529         PutClientInServer(this);
1530 }
1531
1532 void PrintToChat(entity client, string text)
1533 {
1534         text = strcat("\{1}^7", text, "\n");
1535         sprint(client, text);
1536 }
1537
1538 void DebugPrintToChat(entity client, string text)
1539 {
1540         if (autocvar_developer)
1541         {
1542                 PrintToChat(client, text);
1543         }
1544 }
1545
1546 void PrintToChatAll(string text)
1547 {
1548         text = strcat("\{1}^7", text, "\n");
1549         bprint(text);
1550 }
1551
1552 void DebugPrintToChatAll(string text)
1553 {
1554         if (autocvar_developer)
1555         {
1556                 PrintToChatAll(text);
1557         }
1558 }
1559
1560 void PrintToChatTeam(int team_num, string text)
1561 {
1562         text = strcat("\{1}^7", text, "\n");
1563         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1564         {
1565                 if (it.team == team_num)
1566                 {
1567                         sprint(it, text);
1568                 }
1569         });
1570 }
1571
1572 void DebugPrintToChatTeam(int team_num, string text)
1573 {
1574         if (autocvar_developer)
1575         {
1576                 PrintToChatTeam(team_num, text);
1577         }
1578 }
1579
1580 void play_countdown(entity this, float finished, Sound samp)
1581 {
1582     TC(Sound, samp);
1583         if(IS_REAL_CLIENT(this))
1584                 if(floor(finished - time - frametime) != floor(finished - time))
1585                         if(finished - time < 6)
1586                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1587 }
1588
1589 void player_powerups(entity this)
1590 {
1591         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1592         int items_prev = this.items;
1593
1594         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1595                 this.modelflags |= MF_ROCKET;
1596         else
1597                 this.modelflags &= ~MF_ROCKET;
1598
1599         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1600
1601         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1602                 return;
1603
1604         Fire_ApplyDamage(this);
1605         Fire_ApplyEffect(this);
1606
1607         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1608         {
1609                 if (this.items & ITEM_Strength.m_itemid)
1610                 {
1611                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1612                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1613                         if (time > this.strength_finished)
1614                         {
1615                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1616                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1617                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1618                         }
1619                 }
1620                 else
1621                 {
1622                         if (time < this.strength_finished)
1623                         {
1624                                 this.items = this.items | ITEM_Strength.m_itemid;
1625                                 if(!g_cts)
1626                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1627                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1628                         }
1629                 }
1630                 if (this.items & ITEM_Shield.m_itemid)
1631                 {
1632                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1633                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1634                         if (time > this.invincible_finished)
1635                         {
1636                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1637                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1638                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1639                         }
1640                 }
1641                 else
1642                 {
1643                         if (time < this.invincible_finished)
1644                         {
1645                                 this.items = this.items | ITEM_Shield.m_itemid;
1646                                 if(!g_cts)
1647                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1648                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1649                         }
1650                 }
1651                 if (this.items & IT_SUPERWEAPON)
1652                 {
1653                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1654                         {
1655                                 this.superweapons_finished = 0;
1656                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1657                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1658                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1659                         }
1660                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1661                         {
1662                                 // don't let them run out
1663                         }
1664                         else
1665                         {
1666                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1667                                 if (time > this.superweapons_finished)
1668                                 {
1669                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1670                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1671                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1672                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1673                                 }
1674                         }
1675                 }
1676                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1677                 {
1678                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1679                         {
1680                                 this.items = this.items | IT_SUPERWEAPON;
1681                                 if(!g_cts)
1682                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1683                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1684                         }
1685                         else
1686                         {
1687                                 this.superweapons_finished = 0;
1688                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1689                         }
1690                 }
1691                 else
1692                 {
1693                         this.superweapons_finished = 0;
1694                 }
1695         }
1696
1697         if(autocvar_g_nodepthtestplayers)
1698                 this.effects = this.effects | EF_NODEPTHTEST;
1699
1700         if(autocvar_g_fullbrightplayers)
1701                 this.effects = this.effects | EF_FULLBRIGHT;
1702
1703         if (time >= game_starttime)
1704         if (time < this.spawnshieldtime)
1705                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1706
1707         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1708 }
1709
1710 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1711 {
1712         if(current > stable)
1713                 return current;
1714         else if(current > stable - 0.25) // when close enough, "snap"
1715                 return stable;
1716         else
1717                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1718 }
1719
1720 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1721 {
1722         if(current < stable)
1723                 return current;
1724         else if(current < stable + 0.25) // when close enough, "snap"
1725                 return stable;
1726         else
1727                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1728 }
1729
1730 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1731 {
1732         if(current > rotstable)
1733         {
1734                 if(rotframetime > 0)
1735                 {
1736                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1737                         current = max(rotstable, current - rotlinear * rotframetime);
1738                 }
1739         }
1740         else if(current < regenstable)
1741         {
1742                 if(regenframetime > 0)
1743                 {
1744                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1745                         current = min(regenstable, current + regenlinear * regenframetime);
1746                 }
1747         }
1748
1749         if(current > limit)
1750                 current = limit;
1751
1752         return current;
1753 }
1754
1755 void player_regen(entity this)
1756 {
1757         float max_mod, regen_mod, rot_mod, limit_mod;
1758         max_mod = regen_mod = rot_mod = limit_mod = 1;
1759
1760         float regen_health = autocvar_g_balance_health_regen;
1761         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1762         float regen_health_rot = autocvar_g_balance_health_rot;
1763         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1764         float regen_health_stable = autocvar_g_balance_health_regenstable;
1765         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1766         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1767                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1768         max_mod = M_ARGV(1, float);
1769         regen_mod = M_ARGV(2, float);
1770         rot_mod = M_ARGV(3, float);
1771         limit_mod = M_ARGV(4, float);
1772         regen_health = M_ARGV(5, float);
1773         regen_health_linear = M_ARGV(6, float);
1774         regen_health_rot = M_ARGV(7, float);
1775         regen_health_rotlinear = M_ARGV(8, float);
1776         regen_health_stable = M_ARGV(9, float);
1777         regen_health_rotstable = M_ARGV(10, float);
1778
1779         if(!mutator_returnvalue)
1780         if(!STAT(FROZEN, this))
1781         {
1782                 float mina, maxa, limith, limita;
1783                 maxa = autocvar_g_balance_armor_rotstable;
1784                 mina = autocvar_g_balance_armor_regenstable;
1785                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1786                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1787
1788                 regen_health_rotstable = regen_health_rotstable * max_mod;
1789                 regen_health_stable = regen_health_stable * max_mod;
1790                 limith = limith * limit_mod;
1791                 limita = limita * limit_mod;
1792
1793                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1794                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1795                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1796                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1797                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1798                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1799         }
1800
1801         // if player rotted to death...  die!
1802         // check this outside above checks, as player may still be able to rot to death
1803         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1804         {
1805                 if(this.vehicle)
1806                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1807                 if(this.event_damage)
1808                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1809         }
1810
1811         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1812         {
1813                 float minf, maxf, limitf;
1814
1815                 maxf = autocvar_g_balance_fuel_rotstable;
1816                 minf = autocvar_g_balance_fuel_regenstable;
1817                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1818
1819                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1820                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1821                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1822         }
1823 }
1824
1825 bool zoomstate_set;
1826 void SetZoomState(entity this, float newzoom)
1827 {
1828         if(newzoom != CS(this).zoomstate)
1829         {
1830                 CS(this).zoomstate = newzoom;
1831                 ClientData_Touch(this);
1832         }
1833         zoomstate_set = true;
1834 }
1835
1836 void GetPressedKeys(entity this)
1837 {
1838         MUTATOR_CALLHOOK(GetPressedKeys, this);
1839         int keys = STAT(PRESSED_KEYS, this);
1840         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1841         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1842         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1843         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1844
1845         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1846         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1847         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1848         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1849         CS(this).pressedkeys = keys; // store for other users
1850
1851         STAT(PRESSED_KEYS, this) = keys;
1852 }
1853
1854 /*
1855 ======================
1856 spectate mode routines
1857 ======================
1858 */
1859
1860 void SpectateCopy(entity this, entity spectatee)
1861 {
1862     TC(Client, this); TC(Client, spectatee);
1863
1864         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1865         PS(this) = PS(spectatee);
1866         this.armortype = spectatee.armortype;
1867         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1868         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1869         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1870         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1871         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1872         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1873         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1874         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1875         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1876         CS(this).impulse = 0;
1877         this.items = spectatee.items;
1878         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1879         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1880         this.strength_finished = spectatee.strength_finished;
1881         this.invincible_finished = spectatee.invincible_finished;
1882         this.superweapons_finished = spectatee.superweapons_finished;
1883         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1884         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1885         this.punchangle = spectatee.punchangle;
1886         this.view_ofs = spectatee.view_ofs;
1887         this.velocity = spectatee.velocity;
1888         this.dmg_take = spectatee.dmg_take;
1889         this.dmg_save = spectatee.dmg_save;
1890         this.dmg_inflictor = spectatee.dmg_inflictor;
1891         this.v_angle = spectatee.v_angle;
1892         this.angles = spectatee.v_angle;
1893         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1894         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1895         this.viewloc = spectatee.viewloc;
1896         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1897                 this.fixangle = true;
1898         setorigin(this, spectatee.origin);
1899         setsize(this, spectatee.mins, spectatee.maxs);
1900         SetZoomState(this, CS(spectatee).zoomstate);
1901
1902     anticheat_spectatecopy(this, spectatee);
1903         STAT(HUD, this) = STAT(HUD, spectatee);
1904         if(spectatee.vehicle)
1905     {
1906         this.angles = spectatee.v_angle;
1907
1908         //this.fixangle = false;
1909         //this.velocity = spectatee.vehicle.velocity;
1910         this.vehicle_health = spectatee.vehicle_health;
1911         this.vehicle_shield = spectatee.vehicle_shield;
1912         this.vehicle_energy = spectatee.vehicle_energy;
1913         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1914         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1915         this.vehicle_reload1 = spectatee.vehicle_reload1;
1916         this.vehicle_reload2 = spectatee.vehicle_reload2;
1917
1918         //msg_entity = this;
1919
1920        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1921             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1922            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1923            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1924
1925         //WriteByte (MSG_ONE, SVC_SETVIEW);
1926         //    WriteEntity(MSG_ONE, this);
1927         //makevectors(spectatee.v_angle);
1928         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1929     }
1930 }
1931
1932 bool SpectateUpdate(entity this)
1933 {
1934         if(!this.enemy)
1935                 return false;
1936
1937         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1938         {
1939                 SetSpectatee(this, NULL);
1940                 return false;
1941         }
1942
1943         SpectateCopy(this, this.enemy);
1944
1945         return true;
1946 }
1947
1948 bool SpectateSet(entity this)
1949 {
1950         if(!IS_PLAYER(this.enemy))
1951                 return false;
1952
1953         ClientData_Touch(this.enemy);
1954
1955         msg_entity = this;
1956         WriteByte(MSG_ONE, SVC_SETVIEW);
1957         WriteEntity(MSG_ONE, this.enemy);
1958         set_movetype(this, MOVETYPE_NONE);
1959         accuracy_resend(this);
1960
1961         if(!SpectateUpdate(this))
1962                 PutObserverInServer(this);
1963
1964         return true;
1965 }
1966
1967 void SetSpectatee_status(entity this, int spectatee_num)
1968 {
1969         int oldspectatee_status = CS(this).spectatee_status;
1970         CS(this).spectatee_status = spectatee_num;
1971
1972         if (CS(this).spectatee_status != oldspectatee_status)
1973         {
1974                 ClientData_Touch(this);
1975                 if (g_race || g_cts) race_InitSpectator();
1976         }
1977 }
1978
1979 void SetSpectatee(entity this, entity spectatee)
1980 {
1981         if(IS_BOT_CLIENT(this))
1982                 return; // bots abuse .enemy, this code is useless to them
1983
1984         entity old_spectatee = this.enemy;
1985
1986         this.enemy = spectatee;
1987
1988         // WEAPONTODO
1989         // these are required to fix the spectator bug with arc
1990         if(old_spectatee)
1991         {
1992                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1993                 {
1994                         .entity weaponentity = weaponentities[slot];
1995                         if(old_spectatee.(weaponentity).arc_beam)
1996                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1997                 }
1998         }
1999         if(this.enemy)
2000         {
2001                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2002                 {
2003                         .entity weaponentity = weaponentities[slot];
2004                         if(this.enemy.(weaponentity).arc_beam)
2005                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
2006                 }
2007         }
2008
2009         if (this.enemy)
2010                 SetSpectatee_status(this, etof(this.enemy));
2011
2012         // needed to update spectator list
2013         if(old_spectatee) { ClientData_Touch(old_spectatee); }
2014 }
2015
2016 bool Spectate(entity this, entity pl)
2017 {
2018         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
2019                 return false;
2020         pl = M_ARGV(1, entity);
2021
2022         SetSpectatee(this, pl);
2023         return SpectateSet(this);
2024 }
2025
2026 bool SpectateNext(entity this)
2027 {
2028         entity ent = find(this.enemy, classname, STR_PLAYER);
2029
2030         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2031                 ent = M_ARGV(1, entity);
2032         else if (!ent)
2033                 ent = find(ent, classname, STR_PLAYER);
2034
2035         if(ent) { SetSpectatee(this, ent); }
2036
2037         return SpectateSet(this);
2038 }
2039
2040 bool SpectatePrev(entity this)
2041 {
2042         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2043         entity ent = findchain(classname, STR_PLAYER);
2044         if (!ent) // no player
2045                 return false;
2046
2047         entity first = ent;
2048         // skip players until current spectated player
2049         if(this.enemy)
2050         while(ent && ent != this.enemy)
2051                 ent = ent.chain;
2052
2053         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2054         {
2055                 case MUT_SPECPREV_FOUND:
2056                     ent = M_ARGV(1, entity);
2057                     break;
2058                 case MUT_SPECPREV_RETURN:
2059                     return true;
2060                 case MUT_SPECPREV_CONTINUE:
2061                 default:
2062                 {
2063                         if(ent.chain)
2064                                 ent = ent.chain;
2065                         else
2066                                 ent = first;
2067                         break;
2068                 }
2069         }
2070
2071         SetSpectatee(this, ent);
2072         return SpectateSet(this);
2073 }
2074
2075 /*
2076 =============
2077 ShowRespawnCountdown()
2078
2079 Update a respawn countdown display.
2080 =============
2081 */
2082 void ShowRespawnCountdown(entity this)
2083 {
2084         float number;
2085         if(!IS_DEAD(this)) // just respawned?
2086                 return;
2087         else
2088         {
2089                 number = ceil(this.respawn_time - time);
2090                 if(number <= 0)
2091                         return;
2092                 if(number <= this.respawn_countdown)
2093                 {
2094                         this.respawn_countdown = number - 1;
2095                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2096                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2097                 }
2098         }
2099 }
2100
2101 .bool team_selected;
2102 bool ShowTeamSelection(entity this)
2103 {
2104         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2105                 return false;
2106         stuffcmd(this, "menu_showteamselect\n");
2107         return true;
2108 }
2109 void Join(entity this)
2110 {
2111         TRANSMUTE(Player, this);
2112
2113         if(!this.team_selected)
2114         if(autocvar_g_campaign || autocvar_g_balance_teams)
2115                 TeamBalance_JoinBestTeam(this, true);
2116
2117         if(autocvar_g_campaign)
2118                 campaign_bots_may_start = true;
2119
2120         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2121
2122         PutClientInServer(this);
2123
2124         if(IS_PLAYER(this))
2125         if(teamplay && this.team != -1)
2126         {
2127                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2128         }
2129         else
2130                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2131         this.team_selected = false;
2132 }
2133
2134 /**
2135  * Determines whether the player is allowed to join. This depends on cvar
2136  * g_maxplayers, if it isn't used this function always return true, otherwise
2137  * it checks whether the number of currently playing players exceeds g_maxplayers.
2138  * @return int number of free slots for players, 0 if none
2139  */
2140 int nJoinAllowed(entity this, entity ignore)
2141 {
2142         if(!ignore)
2143         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2144         // so report 0 free slots if restricted
2145         {
2146                 if(autocvar_g_forced_team_otherwise == "spectate")
2147                         return 0;
2148                 if(autocvar_g_forced_team_otherwise == "spectator")
2149                         return 0;
2150         }
2151
2152         if(this && this.team_forced < 0)
2153                 return 0; // forced spectators can never join
2154
2155         // TODO simplify this
2156         int totalClients = 0;
2157         int currentlyPlaying = 0;
2158         FOREACH_CLIENT(true, {
2159                 if(it != ignore)
2160                         ++totalClients;
2161                 if(IS_REAL_CLIENT(it))
2162                 if(IS_PLAYER(it) || it.caplayer)
2163                         ++currentlyPlaying;
2164         });
2165
2166         float free_slots = 0;
2167         if (!autocvar_g_maxplayers)
2168                 free_slots = maxclients - totalClients;
2169         else if(currentlyPlaying < autocvar_g_maxplayers)
2170                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2171
2172         static float join_prevent_msg_time = 0;
2173         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2174         {
2175                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2176                 join_prevent_msg_time = time + 3;
2177         }
2178
2179         return free_slots;
2180 }
2181
2182 /**
2183  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2184  * g_maxplayers_spectator_blocktime seconds
2185  */
2186 void checkSpectatorBlock(entity this)
2187 {
2188         if(IS_SPEC(this) || IS_OBSERVER(this))
2189         if(!this.caplayer)
2190         if(IS_REAL_CLIENT(this))
2191         {
2192                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2193                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2194                         dropclient(this);
2195                 }
2196         }
2197 }
2198
2199 void PrintWelcomeMessage(entity this)
2200 {
2201         if(CS(this).motd_actived_time == 0)
2202         {
2203                 if (autocvar_g_campaign) {
2204                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2205                                 CS(this).motd_actived_time = time;
2206                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2207                         }
2208                 } else {
2209                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2210                                 CS(this).motd_actived_time = time;
2211                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2212                         }
2213                 }
2214         }
2215         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2216         {
2217                 if (autocvar_g_campaign) {
2218                         if (PHYS_INPUT_BUTTON_INFO(this))
2219                                 CS(this).motd_actived_time = time;
2220                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2221                                 CS(this).motd_actived_time = 0;
2222                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2223                         }
2224                 } else {
2225                         if (PHYS_INPUT_BUTTON_INFO(this))
2226                                 CS(this).motd_actived_time = time;
2227                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2228                                 CS(this).motd_actived_time = 0;
2229                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2230                         }
2231                 }
2232         }
2233         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2234         {
2235                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2236                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2237                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2238                 {
2239                         // instanctly hide MOTD
2240                         CS(this).motd_actived_time = 0;
2241                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2242                 }
2243         }
2244 }
2245
2246 const int MIN_SPEC_TIME = 1;
2247 bool joinAllowed(entity this)
2248 {
2249         if (CS(this).version_mismatch) return false;
2250         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2251         if (!nJoinAllowed(this, this)) return false;
2252         if (teamplay && lockteams) return false;
2253         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2254         if (ShowTeamSelection(this)) return false;
2255         return true;
2256 }
2257
2258 .int items_added;
2259 .string shootfromfixedorigin;
2260 bool PlayerThink(entity this)
2261 {
2262         if (game_stopped || intermission_running) {
2263                 this.modelflags &= ~MF_ROCKET;
2264                 if(intermission_running)
2265                         IntermissionThink(this);
2266                 return false;
2267         }
2268
2269         if (timeout_status == TIMEOUT_ACTIVE) {
2270         // don't allow the player to turn around while game is paused
2271                 // FIXME turn this into CSQC stuff
2272                 this.v_angle = this.lastV_angle;
2273                 this.angles = this.lastV_angle;
2274                 this.fixangle = true;
2275         }
2276
2277         if (frametime) player_powerups(this);
2278
2279         if (IS_DEAD(this)) {
2280                 if (this.personal && g_race_qualifying) {
2281                         if (time > this.respawn_time) {
2282                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2283                                 respawn(this);
2284                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2285                         }
2286                 } else {
2287                         if (frametime) player_anim(this);
2288
2289                         if (this.respawn_flags & RESPAWN_DENY)
2290                         {
2291                                 STAT(RESPAWN_TIME, this) = 0;
2292                                 return false;
2293                         }
2294
2295                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2296
2297                         switch(this.deadflag)
2298                         {
2299                                 case DEAD_DYING:
2300                                 {
2301                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2302                                                 this.deadflag = DEAD_RESPAWNING;
2303                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2304                                                 this.deadflag = DEAD_DEAD;
2305                                         break;
2306                                 }
2307                                 case DEAD_DEAD:
2308                                 {
2309                                         if (button_pressed)
2310                                                 this.deadflag = DEAD_RESPAWNABLE;
2311                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2312                                                 this.deadflag = DEAD_RESPAWNING;
2313                                         break;
2314                                 }
2315                                 case DEAD_RESPAWNABLE:
2316                                 {
2317                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2318                                                 this.deadflag = DEAD_RESPAWNING;
2319                                         break;
2320                                 }
2321                                 case DEAD_RESPAWNING:
2322                                 {
2323                                         if (time > this.respawn_time)
2324                                         {
2325                                                 this.respawn_time = time + 1; // only retry once a second
2326                                                 this.respawn_time_max = this.respawn_time;
2327                                                 respawn(this);
2328                                         }
2329                                         break;
2330                                 }
2331                         }
2332
2333                         ShowRespawnCountdown(this);
2334
2335                         if (this.respawn_flags & RESPAWN_SILENT)
2336                                 STAT(RESPAWN_TIME, this) = 0;
2337                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2338                         {
2339                                 if (time < this.respawn_time)
2340                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2341                                 else if (this.deadflag != DEAD_RESPAWNING)
2342                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2343                         }
2344                         else
2345                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2346                 }
2347
2348                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2349                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2350                         STAT(RESPAWN_TIME, this) *= -1;
2351
2352                 return false;
2353         }
2354
2355         FixPlayermodel(this);
2356
2357         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2358                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2359                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2360         }
2361
2362         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2363         //if(frametime)
2364         {
2365                 this.items &= ~this.items_added;
2366
2367                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2368                 {
2369                         .entity weaponentity = weaponentities[slot];
2370                         W_WeaponFrame(this, weaponentity);
2371                 }
2372
2373                 this.items_added = 0;
2374                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2375             this.items_added |= IT_FUEL;
2376
2377                 this.items |= this.items_added;
2378         }
2379
2380         player_regen(this);
2381
2382         // WEAPONTODO: Add a weapon request for this
2383         // rot vortex charge to the charge limit
2384         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2385         {
2386                 .entity weaponentity = weaponentities[slot];
2387                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2388                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2389         }
2390
2391         if (frametime) player_anim(this);
2392
2393         // secret status
2394         secrets_setstatus(this);
2395
2396         // monsters status
2397         monsters_setstatus(this);
2398
2399         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2400
2401         return true;
2402 }
2403
2404 .bool would_spectate;
2405 void ObserverThink(entity this)
2406 {
2407         if ( CS(this).impulse )
2408         {
2409                 MinigameImpulse(this, CS(this).impulse);
2410                 CS(this).impulse = 0;
2411         }
2412
2413         if (this.flags & FL_JUMPRELEASED) {
2414                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2415                         this.flags &= ~FL_JUMPRELEASED;
2416                         this.flags |= FL_SPAWNING;
2417                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2418                         this.flags &= ~FL_JUMPRELEASED;
2419                         if(SpectateNext(this)) {
2420                                 TRANSMUTE(Spectator, this);
2421                         }
2422                 } else {
2423                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2424                         set_movetype(this, preferred_movetype);
2425                 }
2426         } else {
2427                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2428                         this.flags |= FL_JUMPRELEASED;
2429                         if(this.flags & FL_SPAWNING)
2430                         {
2431                                 this.flags &= ~FL_SPAWNING;
2432                                 Join(this);
2433                                 return;
2434                         }
2435                 }
2436         }
2437 }
2438
2439 void SpectatorThink(entity this)
2440 {
2441         if ( CS(this).impulse )
2442         {
2443                 if(MinigameImpulse(this, CS(this).impulse))
2444                         CS(this).impulse = 0;
2445
2446                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2447                 {
2448                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2449                         CS(this).impulse = 0;
2450                         return;
2451                 }
2452         }
2453
2454         if (this.flags & FL_JUMPRELEASED) {
2455                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2456                         this.flags &= ~FL_JUMPRELEASED;
2457                         this.flags |= FL_SPAWNING;
2458                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2459                         this.flags &= ~FL_JUMPRELEASED;
2460                         if(SpectateNext(this)) {
2461                                 TRANSMUTE(Spectator, this);
2462                         } else {
2463                                 TRANSMUTE(Observer, this);
2464                                 PutClientInServer(this);
2465                         }
2466                         CS(this).impulse = 0;
2467                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2468                         this.flags &= ~FL_JUMPRELEASED;
2469                         if(SpectatePrev(this)) {
2470                                 TRANSMUTE(Spectator, this);
2471                         } else {
2472                                 TRANSMUTE(Observer, this);
2473                                 PutClientInServer(this);
2474                         }
2475                         CS(this).impulse = 0;
2476                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2477                         this.would_spectate = false;
2478                         this.flags &= ~FL_JUMPRELEASED;
2479                         TRANSMUTE(Observer, this);
2480                         PutClientInServer(this);
2481                 } else {
2482                         if(!SpectateUpdate(this))
2483                         {
2484                                 if(!SpectateNext(this))
2485                                 {
2486                                         PutObserverInServer(this);
2487                                         this.would_spectate = true;
2488                                 }
2489                         }
2490                 }
2491         } else {
2492                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2493                         this.flags |= FL_JUMPRELEASED;
2494                         if(this.flags & FL_SPAWNING)
2495                         {
2496                                 this.flags &= ~FL_SPAWNING;
2497                                 Join(this);
2498                                 return;
2499                         }
2500                 }
2501                 if(!SpectateUpdate(this))
2502                         PutObserverInServer(this);
2503         }
2504
2505         this.flags |= FL_CLIENT | FL_NOTARGET;
2506 }
2507
2508 void PlayerUseKey(entity this)
2509 {
2510         if (!IS_PLAYER(this))
2511                 return;
2512
2513         if(this.vehicle)
2514         {
2515                 if(!game_stopped)
2516                 {
2517                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2518                         return;
2519                 }
2520         }
2521         else if(autocvar_g_vehicles_enter)
2522         {
2523                 if(!STAT(FROZEN, this))
2524                 if(!IS_DEAD(this))
2525                 if(!game_stopped)
2526                 {
2527                         entity head, closest_target = NULL;
2528                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2529
2530                         while(head) // find the closest acceptable target to enter
2531                         {
2532                                 if(IS_VEHICLE(head))
2533                                 if(!IS_DEAD(head))
2534                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2535                                 if(head.takedamage != DAMAGE_NO)
2536                                 {
2537                                         if(closest_target)
2538                                         {
2539                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2540                                                 { closest_target = head; }
2541                                         }
2542                                         else { closest_target = head; }
2543                                 }
2544
2545                                 head = head.chain;
2546                         }
2547
2548                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2549                 }
2550         }
2551
2552         // a use key was pressed; call handlers
2553         MUTATOR_CALLHOOK(PlayerUseKey, this);
2554 }
2555
2556
2557 /*
2558 =============
2559 PlayerPreThink
2560
2561 Called every frame for each client before the physics are run
2562 =============
2563 */
2564 .float last_vehiclecheck;
2565 void PlayerPreThink (entity this)
2566 {
2567         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2568         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2569
2570         WarpZone_PlayerPhysics_FixVAngle(this);
2571
2572         if (frametime) {
2573                 // physics frames: update anticheat stuff
2574                 anticheat_prethink(this);
2575         }
2576
2577         if (blockSpectators && frametime) {
2578                 // WORKAROUND: only use dropclient in server frames (frametime set).
2579                 // Never use it in cl_movement frames (frametime zero).
2580                 checkSpectatorBlock(this);
2581         }
2582
2583         zoomstate_set = false;
2584
2585         // Check for nameless players
2586         if (this.netname == "" || this.netname != CS(this).netname_previous)
2587         {
2588                 bool assume_unchanged = (CS(this).netname_previous == "");
2589                 if (isInvisibleString(this.netname))
2590                 {
2591                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2592                         assume_unchanged = false;
2593                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2594                 }
2595                 if (!assume_unchanged && autocvar_sv_eventlog)
2596                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2597                 strcpy(CS(this).netname_previous, this.netname);
2598         }
2599
2600         // version nagging
2601         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2602         CS(this).version_nagtime = 0;
2603         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2604             // git client
2605         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2606             // git server
2607             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2608         } else {
2609             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2610             if (r < 0) { // old client
2611                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2612             } else if (r > 0) { // old server
2613                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2614             }
2615         }
2616     }
2617
2618         // GOD MODE info
2619         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2620         {
2621                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2622                 this.max_armorvalue = 0;
2623         }
2624
2625         if(IS_PLAYER(this))
2626         {
2627                 if (STAT(FROZEN, this) == 2)
2628                 {
2629                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2630                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2631                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2632
2633                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2634                                 Unfreeze(this);
2635                 }
2636                 else if (STAT(FROZEN, this) == 3)
2637                 {
2638                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2639                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2640
2641                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2642                         {
2643                                 if (this.vehicle)
2644                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2645                                 if(this.event_damage)
2646                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2647                         }
2648                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2649                                 Unfreeze(this);
2650                 }
2651         }
2652
2653         MUTATOR_CALLHOOK(PlayerPreThink, this);
2654
2655         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2656         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2657         {
2658                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2659                 {
2660                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2661                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2662                         {
2663                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2664                         }
2665                         else if(!it.owner)
2666                         {
2667                                 if(!it.team || SAME_TEAM(this, it))
2668                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2669                                 else if(autocvar_g_vehicles_steal)
2670                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2671                         }
2672                 });
2673
2674                 this.last_vehiclecheck = time + 1;
2675         }
2676
2677         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2678         {
2679                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2680                         PlayerUseKey(this);
2681                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2682         }
2683
2684         if (IS_REAL_CLIENT(this))
2685                 PrintWelcomeMessage(this);
2686
2687         if (IS_PLAYER(this)) {
2688                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2689                         error("Client can't be spawned as player on connection!");
2690                 if(!PlayerThink(this))
2691                         return;
2692         }
2693         else if (game_stopped || intermission_running) {
2694                 if(intermission_running)
2695                         IntermissionThink(this);
2696                 return;
2697         }
2698         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2699         {
2700                 CS(this).autojoin_checked = true;
2701                 // don't do this in ClientConnect
2702                 // many things can go wrong if a client is spawned as player on connection
2703                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2704                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2705                                 && (!teamplay || autocvar_g_balance_teams)))
2706                 {
2707                         campaign_bots_may_start = true;
2708                         Join(this);
2709                         return;
2710                 }
2711         }
2712         else if (IS_OBSERVER(this)) {
2713                 ObserverThink(this);
2714         }
2715         else if (IS_SPEC(this)) {
2716                 SpectatorThink(this);
2717         }
2718
2719         // WEAPONTODO: Add weapon request for this
2720         if (!zoomstate_set) {
2721                 bool wep_zoomed = false;
2722                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2723                 {
2724                         .entity weaponentity = weaponentities[slot];
2725                         Weapon thiswep = this.(weaponentity).m_weapon;
2726                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2727                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2728                 }
2729                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2730     }
2731
2732         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2733         {
2734                 CS(this).teamkill_soundtime = 0;
2735
2736                 entity e = CS(this).teamkill_soundsource;
2737                 entity oldpusher = e.pusher;
2738                 e.pusher = this;
2739                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2740                 e.pusher = oldpusher;
2741         }
2742
2743         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2744                 CS(this).taunt_soundtime = 0;
2745                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2746         }
2747
2748         target_voicescript_next(this);
2749
2750         // WEAPONTODO: Move into weaponsystem somehow
2751         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2752         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2753         {
2754                 .entity weaponentity = weaponentities[slot];
2755                 if(this.(weaponentity).m_weapon == WEP_Null)
2756                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2757         }
2758 }
2759
2760 void DrownPlayer(entity this)
2761 {
2762         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2763                 return;
2764
2765         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2766         {
2767                 if(this.air_finished < time)
2768                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2769                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2770         }
2771         else if (this.air_finished < time)
2772         {       // drown!
2773                 if (this.pain_finished < time)
2774                 {
2775                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2776                         this.pain_finished = time + 0.5;
2777                 }
2778         }
2779 }
2780
2781 .bool move_qcphysics;
2782
2783 void Player_Physics(entity this)
2784 {
2785         set_movetype(this, this.move_movetype);
2786
2787         if(!this.move_qcphysics)
2788                 return;
2789
2790         if(!frametime && !CS(this).pm_frametime)
2791                 return;
2792
2793         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2794
2795         CS(this).pm_frametime = 0;
2796 }
2797
2798 /*
2799 =============
2800 PlayerPostThink
2801
2802 Called every frame for each client after the physics are run
2803 =============
2804 */
2805 void PlayerPostThink (entity this)
2806 {
2807         Player_Physics(this);
2808
2809         if (sv_maxidle > 0)
2810         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2811         if (IS_REAL_CLIENT(this))
2812         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2813         {
2814                 int totalClients = 0;
2815                 if(sv_maxidle_slots > 0)
2816                 {
2817                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2818                         {
2819                                 ++totalClients;
2820                         });
2821                 }
2822
2823                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2824                 { /* do nothing */ }
2825                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2826                 {
2827                         if (CS(this).idlekick_lasttimeleft)
2828                         {
2829                                 CS(this).idlekick_lasttimeleft = 0;
2830                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2831                         }
2832                 }
2833                 else
2834                 {
2835                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2836                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2837                                 if (!CS(this).idlekick_lasttimeleft)
2838                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2839                         }
2840                         if (timeleft <= 0) {
2841                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2842                                 dropclient(this);
2843                                 return;
2844                         }
2845                         else if (timeleft <= 10) {
2846                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2847                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2848                 }
2849                                 CS(this).idlekick_lasttimeleft = timeleft;
2850                         }
2851                 }
2852         }
2853
2854         CheatFrame(this);
2855
2856         if (game_stopped)
2857         {
2858                 this.solid = SOLID_NOT;
2859                 this.takedamage = DAMAGE_NO;
2860                 set_movetype(this, MOVETYPE_NONE);
2861         }
2862
2863         if (IS_PLAYER(this)) {
2864                 if(this.death_time == time && IS_DEAD(this))
2865                 {
2866                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2867                         // once all the damage events of this frame have been processed with normal size
2868                         this.maxs.z = 5;
2869                         setsize(this, this.mins, this.maxs);
2870                 }
2871                 DrownPlayer(this);
2872                 UpdateChatBubble(this);
2873                 if (CS(this).impulse) ImpulseCommands(this);
2874                 if (game_stopped)
2875                 {
2876                         CSQCMODEL_AUTOUPDATE(this);
2877                         return;
2878                 }
2879                 GetPressedKeys(this);
2880         }
2881
2882         if (this.waypointsprite_attachedforcarrier) {
2883             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2884                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2885     }
2886
2887         playerdemo_write(this);
2888
2889         CSQCMODEL_AUTOUPDATE(this);
2890 }
2891
2892 // hack to copy the button fields from the client entity to the Client State
2893 void PM_UpdateButtons(entity this, entity store)
2894 {
2895         if(this.impulse)
2896                 store.impulse = this.impulse;
2897         this.impulse = 0;
2898
2899         bool typing = this.buttonchat;
2900
2901         store.button0 = (typing) ? 0 : this.button0;
2902         //button1?!
2903         store.button2 = (typing) ? 0 : this.button2;
2904         store.button3 = (typing) ? 0 : this.button3;
2905         store.button4 = this.button4;
2906         store.button5 = (typing) ? 0 : this.button5;
2907         store.button6 = this.button6;
2908         store.button7 = this.button7;
2909         store.button8 = this.button8;
2910         store.button9 = this.button9;
2911         store.button10 = this.button10;
2912         store.button11 = this.button11;
2913         store.button12 = this.button12;
2914         store.button13 = this.button13;
2915         store.button14 = this.button14;
2916         store.button15 = this.button15;
2917         store.button16 = this.button16;
2918         store.buttonuse = this.buttonuse;
2919         store.buttonchat = this.buttonchat;
2920
2921         store.cursor_active = this.cursor_active;
2922         store.cursor_screen = this.cursor_screen;
2923         store.cursor_trace_start = this.cursor_trace_start;
2924         store.cursor_trace_endpos = this.cursor_trace_endpos;
2925         store.cursor_trace_ent = this.cursor_trace_ent;
2926
2927         store.ping = this.ping;
2928         store.ping_packetloss = this.ping_packetloss;
2929         store.ping_movementloss = this.ping_movementloss;
2930
2931         store.v_angle = this.v_angle;
2932         store.movement = (typing) ? '0 0 0' : this.movement;
2933 }
2934
2935 NET_HANDLE(fpsreport, bool)
2936 {
2937         int fps = ReadShort();
2938         PlayerScore_Set(sender, SP_FPS, fps);
2939         return true;
2940 }