qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/physics/player.qh"
  41
  42 #include "../common/items/_mod.qh"
  43
  44 #include "../common/mutators/mutator/waypoints/all.qh"
  45
  46 #include "../common/triggers/subs.qh"
  47 #include "../common/triggers/triggers.qh"
  48 #include "../common/triggers/trigger/secret.qh"
  49
  50 #include "../common/minigames/sv_minigames.qh"
  51
  52 #include "../common/items/inventory.qh"
  53
  54 #include "../common/monsters/sv_monsters.qh"
  55
  56 #include "../lib/warpzone/server.qh"
  57
  58 STATIC_METHOD(Client, Add, void(Client this, int _team))
  59 {
  60     ClientConnect(this);
  61     TRANSMUTE(Player, this);
  62     this.frame = 12; // 7
  63     this.team = _team;
  64     PutClientInServer(this);
  65 }
  66
  67 void PutObserverInServer(entity this);
  68
  69 STATIC_METHOD(Client, Remove, void(Client this))
  70 {
  71     TRANSMUTE(Observer, this);
  72     PutClientInServer(this);
  73     ClientDisconnect(this);
  74 }
  75
  76 void send_CSQC_teamnagger() {
  77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  78 }
  79
  80 int CountSpectators(entity player, entity to)
  81 {
  82         if(!player) { return 0; } // not sure how, but best to be safe
  83
  84         int spec_count = 0;
  85
  86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  87         {
  88                 spec_count++;
  89         });
  90
  91         return spec_count;
  92 }
  93
  94 void WriteSpectators(entity player, entity to)
  95 {
  96         if(!player) { return; } // not sure how, but best to be safe
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 WriteByte(MSG_ENTITY, num_for_edict(it));
 101         });
 102 }
 103
 104 bool ClientData_Send(entity this, entity to, int sf)
 105 {
 106         assert(to == this.owner, return false);
 107
 108         entity e = to;
 109         if (IS_SPEC(e)) e = e.enemy;
 110
 111         sf = 0;
 112         if (e.race_completed)       sf |= 1; // forced scoreboard
 113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 114         if (e.zoomstate)            sf |= 4; // zoomed
 115         if (e.porto_v_angle_held)   sf |= 8; // angles held
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125         if (sf & 8)
 126         {
 127                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 128                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 129         }
 130
 131         if(sf & 16)
 132         {
 133                 float specs = CountSpectators(e, to);
 134                 WriteByte(MSG_ENTITY, specs);
 135                 WriteSpectators(e, to);
 136         }
 137
 138         return true;
 139 }
 140
 141 void ClientData_Attach(entity this)
 142 {
 143         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 144         this.clientdata.drawonlytoclient = this;
 145         this.clientdata.owner = this;
 146 }
 147
 148 void ClientData_Detach(entity this)
 149 {
 150         delete(this.clientdata);
 151         this.clientdata = NULL;
 152 }
 153
 154 void ClientData_Touch(entity e)
 155 {
 156         e.clientdata.SendFlags = 1;
 157
 158         // make it spectatable
 159         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 160 }
 161
 162 .string netname_previous;
 163
 164 void SetSpectatee(entity this, entity spectatee);
 165 void SetSpectatee_status(entity this, int spectatee_num);
 166
 167
 168 /*
 169 =============
 170 CheckPlayerModel
 171
 172 Checks if the argument string can be a valid playermodel.
 173 Returns a valid one in doubt.
 174 =============
 175 */
 176 string FallbackPlayerModel;
 177 string CheckPlayerModel(string plyermodel) {
 178         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 179         {
 180                 // note: we cannot summon Don Strunzone here, some player may
 181                 // still have the model string set. In case anyone manages how
 182                 // to change a cvar default, we'll have a small leak here.
 183                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 184         }
 185         // only in right path
 186         if( substring(plyermodel,0,14) != "models/player/")
 187                 return FallbackPlayerModel;
 188         // only good file extensions
 189         if(substring(plyermodel,-4,4) != ".zym")
 190         if(substring(plyermodel,-4,4) != ".dpm")
 191         if(substring(plyermodel,-4,4) != ".iqm")
 192         if(substring(plyermodel,-4,4) != ".md3")
 193         if(substring(plyermodel,-4,4) != ".psk")
 194                 return FallbackPlayerModel;
 195         // forbid the LOD models
 196         if(substring(plyermodel, -9,5) == "_lod1")
 197                 return FallbackPlayerModel;
 198         if(substring(plyermodel, -9,5) == "_lod2")
 199                 return FallbackPlayerModel;
 200         if(plyermodel != strtolower(plyermodel))
 201                 return FallbackPlayerModel;
 202         // also, restrict to server models
 203         if(autocvar_sv_servermodelsonly)
 204         {
 205                 if(!fexists(plyermodel))
 206                         return FallbackPlayerModel;
 207         }
 208         return plyermodel;
 209 }
 210
 211 void setplayermodel(entity e, string modelname)
 212 {
 213         precache_model(modelname);
 214         _setmodel(e, modelname);
 215         player_setupanimsformodel(e);
 216         if(!autocvar_g_debug_globalsounds)
 217                 UpdatePlayerSounds(e);
 218 }
 219
 220 void FixPlayermodel(entity player);
 221 /** putting a client as observer in the server */
 222 void PutObserverInServer(entity this)
 223 {
 224     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 225         PlayerState_detach(this);
 226
 227         if (IS_PLAYER(this) && this.health >= 1) {
 228         // despawn effect
 229                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230     }
 231
 232     {
 233         entity spot = SelectSpawnPoint(this, true);
 234         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 235         this.angles = spot.angles;
 236         this.angles_z = 0;
 237         this.fixangle = true;
 238         // offset it so that the spectator spawns higher off the ground, looks better this way
 239         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 240         this.prevorigin = this.origin;
 241         if (IS_REAL_CLIENT(this))
 242         {
 243             msg_entity = this;
 244             WriteByte(MSG_ONE, SVC_SETVIEW);
 245             WriteEntity(MSG_ONE, this);
 246         }
 247         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249         if(!autocvar_g_debug_globalsounds)
 250         {
 251                 // needed for player sounds
 252                 this.model = "";
 253                 FixPlayermodel(this);
 254         }
 255         setmodel(this, MDL_Null);
 256         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 257         this.view_ofs = '0 0 0';
 258     }
 259
 260     RemoveGrapplingHooks(this);
 261         Portal_ClearAll(this);
 262         Unfreeze(this);
 263         SetSpectatee(this, NULL);
 264
 265         if (this.alivetime)
 266         {
 267                 if (!warmup_stage)
 268                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 269                 this.alivetime = 0;
 270         }
 271
 272         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 273
 274         WaypointSprite_PlayerDead(this);
 275
 276         if (mutator_returnvalue) {
 277             // mutator prevents resetting teams+score
 278         } else {
 279                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 280         this.frags = FRAGS_SPECTATOR;
 281         PlayerScore_Clear(this);  // clear scores when needed
 282     }
 283
 284         if (this.killcount != FRAGS_SPECTATOR)
 285         {
 286                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 287                 if(!intermission_running)
 288                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 289                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 290
 291                 if(this.just_joined == false) {
 292                         LogTeamchange(this.playerid, -1, 4);
 293                 } else
 294                         this.just_joined = false;
 295         }
 296
 297         accuracy_resend(this);
 298
 299         this.spectatortime = time;
 300         if(this.bot_attack)
 301                 IL_REMOVE(g_bot_targets, this);
 302         this.bot_attack = false;
 303     this.hud = HUD_NORMAL;
 304         TRANSMUTE(Observer, this);
 305         this.iscreature = false;
 306         this.teleportable = TELEPORT_SIMPLE;
 307         this.damagedbycontents = false;
 308         this.health = FRAGS_SPECTATOR;
 309         SetSpectatee_status(this, etof(this));
 310         this.takedamage = DAMAGE_NO;
 311         this.solid = SOLID_NOT;
 312         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 313         this.flags = FL_CLIENT | FL_NOTARGET;
 314         this.armorvalue = 666;
 315         this.effects = 0;
 316         this.armorvalue = autocvar_g_balance_armor_start;
 317         this.pauserotarmor_finished = 0;
 318         this.pauserothealth_finished = 0;
 319         this.pauseregen_finished = 0;
 320         this.damageforcescale = 0;
 321         this.death_time = 0;
 322         this.respawn_flags = 0;
 323         this.respawn_time = 0;
 324         this.stat_respawn_time = 0;
 325         this.alpha = 0;
 326         this.scale = 0;
 327         this.fade_time = 0;
 328         this.pain_frame = 0;
 329         this.pain_finished = 0;
 330         this.strength_finished = 0;
 331         this.invincible_finished = 0;
 332         this.superweapons_finished = 0;
 333         this.pushltime = 0;
 334         this.istypefrag = 0;
 335         setthink(this, func_null);
 336         this.nextthink = 0;
 337         this.deadflag = DEAD_NO;
 338         this.crouch = false;
 339         this.revival_time = 0;
 340
 341         this.items = 0;
 342         this.weapons = '0 0 0';
 343         this.drawonlytoclient = this;
 344
 345         this.weaponmodel = "";
 346         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 347         {
 348                 this.weaponentities[slot].hook_time = 0;
 349                 this.weaponentities[slot].weaponname = "";
 350                 this.weaponentities[slot] = NULL;
 351         }
 352         this.exteriorweaponentity = NULL;
 353         this.killcount = FRAGS_SPECTATOR;
 354         this.velocity = '0 0 0';
 355         this.avelocity = '0 0 0';
 356         this.punchangle = '0 0 0';
 357         this.punchvector = '0 0 0';
 358         this.oldvelocity = this.velocity;
 359         this.fire_endtime = -1;
 360         this.event_damage = func_null;
 361
 362         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 363         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 364         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 365 }
 366
 367 int player_getspecies(entity this)
 368 {
 369         get_model_parameters(this.model, this.skin);
 370         int s = get_model_parameters_species;
 371         get_model_parameters(string_null, 0);
 372         if (s < 0) return SPECIES_HUMAN;
 373         return s;
 374 }
 375
 376 .float model_randomizer;
 377 void FixPlayermodel(entity player)
 378 {
 379         string defaultmodel = "";
 380         int defaultskin = 0;
 381         if(autocvar_sv_defaultcharacter)
 382         {
 383                 if(teamplay)
 384                 {
 385                         string s = Static_Team_ColorName_Lower(player.team);
 386                         if (s != "neutral")
 387                         {
 388                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 389                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 390                         }
 391                 }
 392
 393                 if(defaultmodel == "")
 394                 {
 395                         defaultmodel = autocvar_sv_defaultplayermodel;
 396                         defaultskin = autocvar_sv_defaultplayerskin;
 397                 }
 398
 399                 int n = tokenize_console(defaultmodel);
 400                 if(n > 0)
 401                 {
 402                         defaultmodel = argv(floor(n * player.model_randomizer));
 403                         // However, do NOT randomize if the player-selected model is in the list.
 404                         for (int i = 0; i < n; ++i)
 405                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 406                                         defaultmodel = argv(i);
 407                 }
 408
 409                 int i = strstrofs(defaultmodel, ":", 0);
 410                 if(i >= 0)
 411                 {
 412                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 413                         defaultmodel = substring(defaultmodel, 0, i);
 414                 }
 415         }
 416         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 417         {
 418                 if(teamplay)
 419                 {
 420                         string s = Static_Team_ColorName_Lower(player.team);
 421                         if (s != "neutral")
 422                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 423                 }
 424
 425                 if(!defaultskin)
 426                         defaultskin = autocvar_sv_defaultplayerskin;
 427         }
 428
 429         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 430         defaultmodel = M_ARGV(0, string);
 431         defaultskin = M_ARGV(1, int);
 432
 433         bool chmdl = false;
 434         int oldskin;
 435         if(defaultmodel != "")
 436         {
 437                 if (defaultmodel != player.model)
 438                 {
 439                         vector m1 = player.mins;
 440                         vector m2 = player.maxs;
 441                         setplayermodel (player, defaultmodel);
 442                         setsize (player, m1, m2);
 443                         chmdl = true;
 444                 }
 445
 446                 oldskin = player.skin;
 447                 player.skin = defaultskin;
 448         } else {
 449                 if (player.playermodel != player.model || player.playermodel == "")
 450                 {
 451                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 452                         vector m1 = player.mins;
 453                         vector m2 = player.maxs;
 454                         setplayermodel (player, player.playermodel);
 455                         setsize (player, m1, m2);
 456                         chmdl = true;
 457                 }
 458
 459                 if(!autocvar_sv_defaultcharacterskin)
 460                 {
 461                         oldskin = player.skin;
 462                         player.skin = stof(player.playerskin);
 463                 }
 464                 else
 465                 {
 466                         oldskin = player.skin;
 467                         player.skin = defaultskin;
 468                 }
 469         }
 470
 471         if(chmdl || oldskin != player.skin) // model or skin has changed
 472         {
 473                 player.species = player_getspecies(player); // update species
 474                 if(!autocvar_g_debug_globalsounds)
 475                         UpdatePlayerSounds(player); // update skin sounds
 476         }
 477
 478         if(!teamplay)
 479                 if(strlen(autocvar_sv_defaultplayercolors))
 480                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 481                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 482 }
 483
 484
 485 /** Called when a client spawns in the server */
 486 void PutClientInServer(entity this)
 487 {
 488         if (IS_BOT_CLIENT(this)) {
 489                 TRANSMUTE(Player, this);
 490         } else if (IS_REAL_CLIENT(this)) {
 491                 msg_entity = this;
 492                 WriteByte(MSG_ONE, SVC_SETVIEW);
 493                 WriteEntity(MSG_ONE, this);
 494         }
 495         if (gameover) {
 496                 TRANSMUTE(Observer, this);
 497         }
 498
 499         SetSpectatee(this, NULL);
 500
 501         // reset player keys
 502         this.itemkeys = 0;
 503
 504         MUTATOR_CALLHOOK(PutClientInServer, this);
 505
 506         if (IS_OBSERVER(this)) {
 507                 PutObserverInServer(this);
 508         } else if (IS_PLAYER(this)) {
 509                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 510
 511                 PlayerState_attach(this);
 512                 accuracy_resend(this);
 513
 514                 if (this.team < 0)
 515                         JoinBestTeam(this, false, true);
 516
 517                 entity spot = SelectSpawnPoint(this, false);
 518                 if (!spot) {
 519                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 520                         return; // spawn failed
 521                 }
 522
 523                 TRANSMUTE(Player, this);
 524
 525                 this.wasplayer = true;
 526                 this.iscreature = true;
 527                 this.teleportable = TELEPORT_NORMAL;
 528                 this.damagedbycontents = true;
 529                 set_movetype(this, MOVETYPE_WALK);
 530                 this.solid = SOLID_SLIDEBOX;
 531                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 532                 if (autocvar_g_playerclip_collisions)
 533                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 534                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 535                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 536                 this.frags = FRAGS_PLAYER;
 537                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 538                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 539                 if (autocvar__notarget)
 540                         this.flags |= FL_NOTARGET;
 541                 this.takedamage = DAMAGE_AIM;
 542                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 543                 this.dmg = 2; // WTF
 544
 545                 if (warmup_stage) {
 546                         this.ammo_shells = warmup_start_ammo_shells;
 547                         this.ammo_nails = warmup_start_ammo_nails;
 548                         this.ammo_rockets = warmup_start_ammo_rockets;
 549                         this.ammo_cells = warmup_start_ammo_cells;
 550                         this.ammo_plasma = warmup_start_ammo_plasma;
 551                         this.ammo_fuel = warmup_start_ammo_fuel;
 552                         this.health = warmup_start_health;
 553                         this.armorvalue = warmup_start_armorvalue;
 554                         this.weapons = WARMUP_START_WEAPONS;
 555                 } else {
 556                         this.ammo_shells = start_ammo_shells;
 557                         this.ammo_nails = start_ammo_nails;
 558                         this.ammo_rockets = start_ammo_rockets;
 559                         this.ammo_cells = start_ammo_cells;
 560                         this.ammo_plasma = start_ammo_plasma;
 561                         this.ammo_fuel = start_ammo_fuel;
 562                         this.health = start_health;
 563                         this.armorvalue = start_armorvalue;
 564                         this.weapons = start_weapons;
 565                 }
 566                 SetSpectatee_status(this, 0);
 567
 568                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 569
 570                 this.items = start_items;
 571
 572                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 573                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 574                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 575                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 576                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 577                 // extend the pause of rotting if client was reset at the beginning of the countdown
 578                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 579                         float f = game_starttime - time;
 580                         this.spawnshieldtime += f;
 581                         this.pauserotarmor_finished += f;
 582                         this.pauserothealth_finished += f;
 583                         this.pauseregen_finished += f;
 584                 }
 585                 this.damageforcescale = 2;
 586                 this.death_time = 0;
 587                 this.respawn_flags = 0;
 588                 this.respawn_time = 0;
 589                 this.stat_respawn_time = 0;
 590                 this.scale = autocvar_sv_player_scale;
 591                 this.fade_time = 0;
 592                 this.pain_frame = 0;
 593                 this.pain_finished = 0;
 594                 this.pushltime = 0;
 595                 setthink(this, func_null); // players have no think function
 596                 this.nextthink = 0;
 597                 this.dmg_team = 0;
 598                 this.ballistics_density = autocvar_g_ballistics_density_player;
 599
 600                 this.deadflag = DEAD_NO;
 601
 602                 this.angles = spot.angles;
 603                 this.angles_z = 0; // never spawn tilted even if the spot says to
 604                 if (IS_BOT_CLIENT(this))
 605                         this.v_angle = this.angles;
 606                 this.fixangle = true; // turn this way immediately
 607                 this.oldvelocity = this.velocity = '0 0 0';
 608                 this.avelocity = '0 0 0';
 609                 this.punchangle = '0 0 0';
 610                 this.punchvector = '0 0 0';
 611
 612                 this.strength_finished = 0;
 613                 this.invincible_finished = 0;
 614                 this.fire_endtime = -1;
 615                 this.revival_time = 0;
 616                 this.air_finished = time + 12;
 617
 618                 entity spawnevent = new_pure(spawnevent);
 619                 spawnevent.owner = this;
 620                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 621
 622                 // Cut off any still running player sounds.
 623                 stopsound(this, CH_PLAYER_SINGLE);
 624
 625                 this.model = "";
 626                 FixPlayermodel(this);
 627                 this.drawonlytoclient = NULL;
 628
 629                 this.crouch = false;
 630                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 631                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 632                 this.spawnorigin = spot.origin;
 633                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 634                 // don't reset back to last position, even if new position is stuck in solid
 635                 this.oldorigin = this.origin;
 636                 this.prevorigin = this.origin;
 637                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 638                 if(this.conveyor)
 639                         IL_REMOVE(g_conveyed, this);
 640                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 641                 this.hud = HUD_NORMAL;
 642
 643                 this.event_damage = PlayerDamage;
 644
 645                 if(!this.bot_attack)
 646                         IL_PUSH(g_bot_targets, this);
 647                 this.bot_attack = true;
 648                 this.monster_attack = true;
 649
 650                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 651
 652                 if (this.killcount == FRAGS_SPECTATOR) {
 653                         PlayerScore_Clear(this);
 654                         this.killcount = 0;
 655                 }
 656
 657                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 658                 {
 659                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 660                 }
 661                 this.alpha = default_player_alpha;
 662                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 663                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 664
 665                 this.speedrunning = false;
 666
 667                 target_voicescript_clear(this);
 668
 669                 // reset fields the weapons may use
 670                 FOREACH(Weapons, true, LAMBDA(
 671                         it.wr_resetplayer(it, this);
 672                         // reload all reloadable weapons
 673                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 674                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 675                                 {
 676                                         .entity weaponentity = weaponentities[slot];
 677                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 678                                 }
 679                         }
 680                 ));
 681
 682                 {
 683                         string s = spot.target;
 684                         spot.target = string_null;
 685                         SUB_UseTargets(spot, this, NULL);
 686                         spot.target = s;
 687                 }
 688
 689                 Unfreeze(this);
 690
 691                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 692
 693                 if (autocvar_spawn_debug)
 694                 {
 695                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 696                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 697                 }
 698
 699                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 700                 {
 701                         .entity weaponentity = weaponentities[slot];
 702                         if(slot == 0)
 703                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 704                         else
 705                                 this.(weaponentity).m_switchweapon = WEP_Null;
 706                         this.(weaponentity).weaponname = "";
 707                         this.(weaponentity).m_switchingweapon = WEP_Null;
 708                         this.(weaponentity).cnt = -1;
 709                 }
 710
 711                 if (!warmup_stage && !this.alivetime)
 712                         this.alivetime = time;
 713
 714                 antilag_clear(this, CS(this));
 715         }
 716 }
 717
 718 void ClientInit_misc(entity this);
 719
 720 .float ebouncefactor, ebouncestop; // electro's values
 721 // TODO do we need all these fields, or should we stop autodetecting runtime
 722 // changes and just have a console command to update this?
 723 bool ClientInit_SendEntity(entity this, entity to, int sf)
 724 {
 725         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 726         return = true;
 727         msg_entity = to;
 728         // MSG_INIT replacement
 729         // TODO: make easier to use
 730         Registry_send_all();
 731         W_PROP_reload(MSG_ONE, to);
 732         ClientInit_misc(this);
 733         MUTATOR_CALLHOOK(Ent_Init);
 734 }
 735 void ClientInit_misc(entity this)
 736 {
 737         int channel = MSG_ONE;
 738         WriteHeader(channel, ENT_CLIENT_INIT);
 739         WriteByte(channel, g_nexball_meter_period * 32);
 740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 741         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 742         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 743         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 745         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 746         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 747         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 748
 749         if(sv_foginterval && world.fog != "")
 750                 WriteString(channel, world.fog);
 751         else
 752                 WriteString(channel, "");
 753         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 754         WriteByte(channel, serverflags);
 755         WriteCoord(channel, autocvar_g_trueaim_minrange);
 756 }
 757
 758 void ClientInit_CheckUpdate(entity this)
 759 {
 760         this.nextthink = time;
 761         if(this.count != autocvar_g_balance_armor_blockpercent)
 762         {
 763                 this.count = autocvar_g_balance_armor_blockpercent;
 764                 this.SendFlags |= 1;
 765         }
 766 }
 767
 768 void ClientInit_Spawn()
 769 {
 770         entity e = new_pure(clientinit);
 771         setthink(e, ClientInit_CheckUpdate);
 772         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 773
 774         ClientInit_CheckUpdate(e);
 775 }
 776
 777 /*
 778 =============
 779 SetNewParms
 780 =============
 781 */
 782 void SetNewParms ()
 783 {
 784         // initialize parms for a new player
 785         parm1 = -(86400 * 366);
 786
 787         MUTATOR_CALLHOOK(SetNewParms);
 788 }
 789
 790 /*
 791 =============
 792 SetChangeParms
 793 =============
 794 */
 795 void SetChangeParms (entity this)
 796 {
 797         // save parms for level change
 798         parm1 = this.parm_idlesince - time;
 799
 800         MUTATOR_CALLHOOK(SetChangeParms);
 801 }
 802
 803 /*
 804 =============
 805 DecodeLevelParms
 806 =============
 807 */
 808 void DecodeLevelParms(entity this)
 809 {
 810         // load parms
 811         this.parm_idlesince = parm1;
 812         if (this.parm_idlesince == -(86400 * 366))
 813                 this.parm_idlesince = time;
 814
 815         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 816         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 817
 818         MUTATOR_CALLHOOK(DecodeLevelParms);
 819 }
 820
 821 /*
 822 =============
 823 ClientKill
 824
 825 Called when a client types 'kill' in the console
 826 =============
 827 */
 828
 829 .float clientkill_nexttime;
 830 void ClientKill_Now_TeamChange(entity this)
 831 {
 832         if(this.killindicator_teamchange == -1)
 833         {
 834                 JoinBestTeam( this, false, true );
 835         }
 836         else if(this.killindicator_teamchange == -2)
 837         {
 838                 if(blockSpectators)
 839                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 840                 PutObserverInServer(this);
 841         }
 842         else
 843                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 844         this.killindicator_teamchange = 0;
 845 }
 846
 847 void ClientKill_Now(entity this)
 848 {
 849         if(this.vehicle)
 850         {
 851             vehicles_exit(this.vehicle, VHEF_RELEASE);
 852             if(!this.killindicator_teamchange)
 853             {
 854             this.vehicle_health = -1;
 855             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 856             }
 857         }
 858
 859         if(this.killindicator && !wasfreed(this.killindicator))
 860                 delete(this.killindicator);
 861
 862         this.killindicator = NULL;
 863
 864         if(this.killindicator_teamchange)
 865                 ClientKill_Now_TeamChange(this);
 866
 867         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 868                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 869
 870         // now I am sure the player IS dead
 871 }
 872 void KillIndicator_Think(entity this)
 873 {
 874         if (gameover)
 875         {
 876                 this.owner.killindicator = NULL;
 877                 delete(this);
 878                 return;
 879         }
 880
 881         if (this.owner.alpha < 0 && !this.owner.vehicle)
 882         {
 883                 this.owner.killindicator = NULL;
 884                 delete(this);
 885                 return;
 886         }
 887
 888         if(this.cnt <= 0)
 889         {
 890                 ClientKill_Now(this.owner);
 891                 return;
 892         }
 893     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 894     {
 895         this.nextthink = time + 1;
 896         this.cnt -= 1;
 897     }
 898         else
 899         {
 900                 if(this.cnt <= 10)
 901                         setmodel(this, MDL_NUM(this.cnt));
 902                 if(IS_REAL_CLIENT(this.owner))
 903                 {
 904                         if(this.cnt <= 10)
 905                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 906                 }
 907                 this.nextthink = time + 1;
 908                 this.cnt -= 1;
 909         }
 910 }
 911
 912 float clientkilltime;
 913 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 914 {
 915         float killtime;
 916         float starttime;
 917
 918         if (gameover)
 919                 return;
 920
 921         killtime = autocvar_g_balance_kill_delay;
 922
 923         if(g_race_qualifying || g_cts)
 924                 killtime = 0;
 925
 926     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 927         return;
 928
 929         this.killindicator_teamchange = targetteam;
 930
 931     if(!this.killindicator)
 932         {
 933                 if(!IS_DEAD(this))
 934                 {
 935                         killtime = max(killtime, this.clientkill_nexttime - time);
 936                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 937                 }
 938
 939                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 940                 {
 941                         ClientKill_Now(this);
 942                 }
 943                 else
 944                 {
 945                         starttime = max(time, clientkilltime);
 946
 947                         this.killindicator = spawn();
 948                         this.killindicator.owner = this;
 949                         this.killindicator.scale = 0.5;
 950                         setattachment(this.killindicator, this, "");
 951                         setorigin(this.killindicator, '0 0 52');
 952                         setthink(this.killindicator, KillIndicator_Think);
 953                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 954                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 955                         this.killindicator.cnt = ceil(killtime);
 956                         this.killindicator.count = bound(0, ceil(killtime), 10);
 957                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 958
 959                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 960                         {
 961                                 it.killindicator = spawn();
 962                                 it.killindicator.owner = it;
 963                                 it.killindicator.scale = 0.5;
 964                                 setattachment(it.killindicator, it, "");
 965                                 setorigin(it.killindicator, '0 0 52');
 966                                 setthink(it.killindicator, KillIndicator_Think);
 967                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 968                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 969                                 it.killindicator.cnt = ceil(killtime);
 970                         });
 971                         this.lip = 0;
 972                 }
 973         }
 974         if(this.killindicator)
 975         {
 976                 if(targetteam == 0) // just die
 977                 {
 978                         this.killindicator.colormod = '0 0 0';
 979                         if(IS_REAL_CLIENT(this))
 980                         if(this.killindicator.cnt > 0)
 981                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 982                 }
 983                 else if(targetteam == -1) // auto
 984                 {
 985                         this.killindicator.colormod = '0 1 0';
 986                         if(IS_REAL_CLIENT(this))
 987                         if(this.killindicator.cnt > 0)
 988                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 989                 }
 990                 else if(targetteam == -2) // spectate
 991                 {
 992                         this.killindicator.colormod = '0.5 0.5 0.5';
 993                         if(IS_REAL_CLIENT(this))
 994                         if(this.killindicator.cnt > 0)
 995                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 996                 }
 997                 else
 998                 {
 999                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1000                         if(IS_REAL_CLIENT(this))
1001                         if(this.killindicator.cnt > 0)
1002                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1003                 }
1004         }
1005
1006 }
1007
1008 void ClientKill (entity this)
1009 {
1010         if(gameover) return;
1011         if(this.player_blocked) return;
1012         if(STAT(FROZEN, this)) return;
1013
1014         ClientKill_TeamChange(this, 0);
1015 }
1016
1017 void FixClientCvars(entity e)
1018 {
1019         // send prediction settings to the client
1020         stuffcmd(e, "\nin_bindmap 0 0\n");
1021         if(autocvar_g_antilag == 3) // client side hitscan
1022                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1023         if(autocvar_sv_gentle)
1024                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1025
1026         MUTATOR_CALLHOOK(FixClientCvars, e);
1027 }
1028
1029 float PlayerInIDList(entity p, string idlist)
1030 {
1031         float n, i;
1032         string s;
1033
1034         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1035         if (!p.crypto_idfp)
1036                 return 0;
1037
1038         // this function allows abbreviated player IDs too!
1039         n = tokenize_console(idlist);
1040         for(i = 0; i < n; ++i)
1041         {
1042                 s = argv(i);
1043                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1044                         return 1;
1045         }
1046
1047         return 0;
1048 }
1049
1050 #ifdef DP_EXT_PRECONNECT
1051 /*
1052 =============
1053 ClientPreConnect
1054
1055 Called once (not at each match start) when a client begins a connection to the server
1056 =============
1057 */
1058 void ClientPreConnect ()
1059 {ENGINE_EVENT();
1060         if(autocvar_sv_eventlog)
1061         {
1062                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1063                         this.playerid,
1064                         etof(this),
1065                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1066                 ));
1067         }
1068 }
1069 #endif
1070
1071 /**
1072 =============
1073 ClientConnect
1074
1075 Called when a client connects to the server
1076 =============
1077 */
1078 void ClientConnect(entity this)
1079 {
1080         if (Ban_MaybeEnforceBanOnce(this)) return;
1081         assert(!IS_CLIENT(this), return);
1082         this.flags |= FL_CLIENT;
1083         assert(player_count >= 0, player_count = 0);
1084
1085 #ifdef WATERMARK
1086         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1087 #endif
1088         this.version_nagtime = time + 10 + random() * 10;
1089         TRANSMUTE(Client, this);
1090
1091         // identify the right forced team
1092         if (autocvar_g_campaign)
1093         {
1094                 if (IS_REAL_CLIENT(this)) // only players, not bots
1095                 {
1096                         switch (autocvar_g_campaign_forceteam)
1097                         {
1098                                 case 1: this.team_forced = NUM_TEAM_1; break;
1099                                 case 2: this.team_forced = NUM_TEAM_2; break;
1100                                 case 3: this.team_forced = NUM_TEAM_3; break;
1101                                 case 4: this.team_forced = NUM_TEAM_4; break;
1102                                 default: this.team_forced = 0;
1103                         }
1104                 }
1105         }
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1107         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1108         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1109         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1110         else switch (autocvar_g_forced_team_otherwise)
1111         {
1112                 default: this.team_forced = 0; break;
1113                 case "red": this.team_forced = NUM_TEAM_1; break;
1114                 case "blue": this.team_forced = NUM_TEAM_2; break;
1115                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1116                 case "pink": this.team_forced = NUM_TEAM_4; break;
1117                 case "spectate":
1118                 case "spectator":
1119                         this.team_forced = -1;
1120                         break;
1121         }
1122         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1123
1124     {
1125         int id = this.playerid;
1126         this.playerid = 0; // silent
1127             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1128             this.playerid = id;
1129     }
1130
1131         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1132                 TRANSMUTE(Observer, this);
1133         } else {
1134                 if (!teamplay || autocvar_g_balance_teams) {
1135                         TRANSMUTE(Player, this);
1136                         campaign_bots_may_start = true;
1137                 } else {
1138                         TRANSMUTE(Observer, this); // do it anyway
1139                 }
1140         }
1141
1142         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1143
1144         // always track bots, don't ask for cl_allow_uidtracking
1145     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1146
1147         if (autocvar_sv_eventlog)
1148                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1149
1150         LogTeamchange(this.playerid, this.team, 1);
1151
1152         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1153
1154         this.netname_previous = strzone(this.netname);
1155
1156         if(teamplay && IS_PLAYER(this))
1157                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1158         else
1159                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1160
1161         stuffcmd(this, clientstuff, "\n");
1162         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1163
1164         FixClientCvars(this);
1165
1166         // get version info from player
1167         stuffcmd(this, "cmd clientversion $gameversion\n");
1168
1169         // notify about available teams
1170         if (teamplay)
1171         {
1172                 CheckAllowedTeams(this);
1173                 int t = 0;
1174                 if (c1 >= 0) t |= BIT(0);
1175                 if (c2 >= 0) t |= BIT(1);
1176                 if (c3 >= 0) t |= BIT(2);
1177                 if (c4 >= 0) t |= BIT(3);
1178                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1179         }
1180         else
1181         {
1182                 stuffcmd(this, "set _teams_available 0\n");
1183         }
1184
1185         bot_relinkplayerlist();
1186
1187         this.spectatortime = time;
1188         if (blockSpectators)
1189         {
1190                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1191         }
1192
1193         this.jointime = time;
1194         this.allowed_timeouts = autocvar_sv_timeout_number;
1195
1196         if (IS_REAL_CLIENT(this))
1197         {
1198                 if (!autocvar_g_campaign)
1199                 {
1200                         this.motd_actived_time = -1;
1201                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1202                 }
1203
1204                 if (g_weaponarena_weapons == WEPSET(TUBA))
1205                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1206         }
1207
1208         if (!sv_foginterval && world.fog != "")
1209                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1210
1211         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1212                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1213                         send_CSQC_teamnagger();
1214
1215         CSQCMODEL_AUTOINIT(this);
1216
1217         this.model_randomizer = random();
1218
1219         if (IS_REAL_CLIENT(this))
1220                 sv_notice_join(this);
1221
1222         IL_EACH(g_initforplayer, it.init_for_player, {
1223                 it.init_for_player(it, this);
1224         });
1225
1226         MUTATOR_CALLHOOK(ClientConnect, this);
1227 }
1228 /*
1229 =============
1230 ClientDisconnect
1231
1232 Called when a client disconnects from the server
1233 =============
1234 */
1235 .entity chatbubbleentity;
1236 void ReadyCount();
1237 void ClientDisconnect(entity this)
1238 {
1239         assert(IS_CLIENT(this), return);
1240
1241         PlayerStats_GameReport_FinalizePlayer(this);
1242         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1243         if (this.active_minigame) part_minigame(this);
1244         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1245
1246         if (autocvar_sv_eventlog)
1247                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1248
1249         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1250
1251         SetSpectatee(this, NULL);
1252
1253     MUTATOR_CALLHOOK(ClientDisconnect, this);
1254
1255         ClientState_detach(this);
1256
1257         Portal_ClearAll(this);
1258
1259         Unfreeze(this);
1260
1261         RemoveGrapplingHooks(this);
1262
1263         // Here, everything has been done that requires this player to be a client.
1264
1265         this.flags &= ~FL_CLIENT;
1266
1267         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1268         if (this.killindicator) delete(this.killindicator);
1269
1270         WaypointSprite_PlayerGone(this);
1271
1272         bot_relinkplayerlist();
1273
1274         if (this.netname_previous) strunzone(this.netname_previous);
1275         if (this.clientstatus) strunzone(this.clientstatus);
1276         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1277         if (this.personal) delete(this.personal);
1278
1279         this.playerid = 0;
1280         ReadyCount();
1281         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1282 }
1283
1284 void ChatBubbleThink(entity this)
1285 {
1286         this.nextthink = time;
1287         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1288         {
1289                 if(this.owner) // but why can that ever be NULL?
1290                         this.owner.chatbubbleentity = NULL;
1291                 delete(this);
1292                 return;
1293         }
1294
1295         this.mdl = "";
1296
1297         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1298         {
1299                 if ( this.owner.active_minigame )
1300                         this.mdl = "models/sprites/minigame_busy.iqm";
1301                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1302                         this.mdl = "models/misc/chatbubble.spr";
1303         }
1304
1305         if ( this.model != this.mdl )
1306                 _setmodel(this, this.mdl);
1307
1308 }
1309
1310 void UpdateChatBubble(entity this)
1311 {
1312         if (this.alpha < 0)
1313                 return;
1314         // spawn a chatbubble entity if needed
1315         if (!this.chatbubbleentity)
1316         {
1317                 this.chatbubbleentity = new(chatbubbleentity);
1318                 this.chatbubbleentity.owner = this;
1319                 this.chatbubbleentity.exteriormodeltoclient = this;
1320                 setthink(this.chatbubbleentity, ChatBubbleThink);
1321                 this.chatbubbleentity.nextthink = time;
1322                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1323                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1324                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1325                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1326                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1327                 //this.chatbubbleentity.model = "";
1328                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1329         }
1330 }
1331
1332
1333 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1334 // added to the model skins
1335 /*void UpdateColorModHack()
1336 {
1337         float c;
1338         c = this.clientcolors & 15;
1339         // LordHavoc: only bothering to support white, green, red, yellow, blue
1340              if (!teamplay) this.colormod = '0 0 0';
1341         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1342         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1343         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1344         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1345         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1346         else this.colormod = '1 1 1';
1347 }*/
1348
1349 void respawn(entity this)
1350 {
1351         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1352         {
1353                 this.solid = SOLID_NOT;
1354                 this.takedamage = DAMAGE_NO;
1355                 set_movetype(this, MOVETYPE_FLY);
1356                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1357                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1358                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1359                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1360                 if(autocvar_g_respawn_ghosts_maxtime)
1361                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1362         }
1363
1364         CopyBody(this, 1);
1365
1366         this.effects |= EF_NODRAW; // prevent another CopyBody
1367         PutClientInServer(this);
1368 }
1369
1370 void play_countdown(entity this, float finished, Sound samp)
1371 {
1372     TC(Sound, samp);
1373         if(IS_REAL_CLIENT(this))
1374                 if(floor(finished - time - frametime) != floor(finished - time))
1375                         if(finished - time < 6)
1376                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1377 }
1378
1379 void player_powerups(entity this)
1380 {
1381         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1382         int items_prev = this.items;
1383
1384         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1385                 this.modelflags |= MF_ROCKET;
1386         else
1387                 this.modelflags &= ~MF_ROCKET;
1388
1389         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1390
1391         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1392                 return;
1393
1394         Fire_ApplyDamage(this);
1395         Fire_ApplyEffect(this);
1396
1397         if (!g_instagib)
1398         {
1399                 if (this.items & ITEM_Strength.m_itemid)
1400                 {
1401                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1402                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1403                         if (time > this.strength_finished)
1404                         {
1405                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1406                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1407                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1408                         }
1409                 }
1410                 else
1411                 {
1412                         if (time < this.strength_finished)
1413                         {
1414                                 this.items = this.items | ITEM_Strength.m_itemid;
1415                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1416                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1417                         }
1418                 }
1419                 if (this.items & ITEM_Shield.m_itemid)
1420                 {
1421                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1422                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1423                         if (time > this.invincible_finished)
1424                         {
1425                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1426                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1427                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1428                         }
1429                 }
1430                 else
1431                 {
1432                         if (time < this.invincible_finished)
1433                         {
1434                                 this.items = this.items | ITEM_Shield.m_itemid;
1435                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1437                         }
1438                 }
1439                 if (this.items & IT_SUPERWEAPON)
1440                 {
1441                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1442                         {
1443                                 this.superweapons_finished = 0;
1444                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1445                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1446                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1447                         }
1448                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1449                         {
1450                                 // don't let them run out
1451                         }
1452                         else
1453                         {
1454                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1455                                 if (time > this.superweapons_finished)
1456                                 {
1457                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1458                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1459                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1460                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1461                                 }
1462                         }
1463                 }
1464                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1465                 {
1466                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1467                         {
1468                                 this.items = this.items | IT_SUPERWEAPON;
1469                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1470                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1471                         }
1472                         else
1473                         {
1474                                 this.superweapons_finished = 0;
1475                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1476                         }
1477                 }
1478                 else
1479                 {
1480                         this.superweapons_finished = 0;
1481                 }
1482         }
1483
1484         if(autocvar_g_nodepthtestplayers)
1485                 this.effects = this.effects | EF_NODEPTHTEST;
1486
1487         if(autocvar_g_fullbrightplayers)
1488                 this.effects = this.effects | EF_FULLBRIGHT;
1489
1490         if (time >= game_starttime)
1491         if (time < this.spawnshieldtime)
1492                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1493
1494         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1495 }
1496
1497 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1498 {
1499         if(current > stable)
1500                 return current;
1501         else if(current > stable - 0.25) // when close enough, "snap"
1502                 return stable;
1503         else
1504                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1505 }
1506
1507 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1508 {
1509         if(current < stable)
1510                 return current;
1511         else if(current < stable + 0.25) // when close enough, "snap"
1512                 return stable;
1513         else
1514                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1515 }
1516
1517 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1518 {
1519         if(current > rotstable)
1520         {
1521                 if(rotframetime > 0)
1522                 {
1523                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1524                         current = max(rotstable, current - rotlinear * rotframetime);
1525                 }
1526         }
1527         else if(current < regenstable)
1528         {
1529                 if(regenframetime > 0)
1530                 {
1531                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1532                         current = min(regenstable, current + regenlinear * regenframetime);
1533                 }
1534         }
1535
1536         if(current > limit)
1537                 current = limit;
1538
1539         return current;
1540 }
1541
1542 void player_regen(entity this)
1543 {
1544         float max_mod, regen_mod, rot_mod, limit_mod;
1545         max_mod = regen_mod = rot_mod = limit_mod = 1;
1546
1547         float regen_health = autocvar_g_balance_health_regen;
1548         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1549         float regen_health_rot = autocvar_g_balance_health_rot;
1550         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1551         float regen_health_stable = autocvar_g_balance_health_regenstable;
1552         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1553         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1554                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1555         max_mod = M_ARGV(1, float);
1556         regen_mod = M_ARGV(2, float);
1557         rot_mod = M_ARGV(3, float);
1558         limit_mod = M_ARGV(4, float);
1559         regen_health = M_ARGV(5, float);
1560         regen_health_linear = M_ARGV(6, float);
1561         regen_health_rot = M_ARGV(7, float);
1562         regen_health_rotlinear = M_ARGV(8, float);
1563         regen_health_stable = M_ARGV(9, float);
1564         regen_health_rotstable = M_ARGV(10, float);
1565
1566
1567         if(!mutator_returnvalue)
1568         if(!STAT(FROZEN, this))
1569         {
1570                 float mina, maxa, limith, limita;
1571                 maxa = autocvar_g_balance_armor_rotstable;
1572                 mina = autocvar_g_balance_armor_regenstable;
1573                 limith = autocvar_g_balance_health_limit;
1574                 limita = autocvar_g_balance_armor_limit;
1575
1576                 regen_health_rotstable = regen_health_rotstable * max_mod;
1577                 regen_health_stable = regen_health_stable * max_mod;
1578                 limith = limith * limit_mod;
1579                 limita = limita * limit_mod;
1580
1581                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1582                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1583         }
1584
1585         // if player rotted to death...  die!
1586         // check this outside above checks, as player may still be able to rot to death
1587         if(this.health < 1)
1588         {
1589                 if(this.vehicle)
1590                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1591                 if(this.event_damage)
1592                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1593         }
1594
1595         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1596         {
1597                 float minf, maxf, limitf;
1598
1599                 maxf = autocvar_g_balance_fuel_rotstable;
1600                 minf = autocvar_g_balance_fuel_regenstable;
1601                 limitf = autocvar_g_balance_fuel_limit;
1602
1603                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1604         }
1605 }
1606
1607 bool zoomstate_set;
1608 void SetZoomState(entity this, float z)
1609 {
1610         if(z != this.zoomstate)
1611         {
1612                 this.zoomstate = z;
1613                 ClientData_Touch(this);
1614         }
1615         zoomstate_set = true;
1616 }
1617
1618 void GetPressedKeys(entity this)
1619 {
1620         MUTATOR_CALLHOOK(GetPressedKeys, this);
1621         int keys = this.pressedkeys;
1622         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1623         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1624         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1625         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1626
1627         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1628         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1629         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1630         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1631         this.pressedkeys = keys;
1632 }
1633
1634 /*
1635 ======================
1636 spectate mode routines
1637 ======================
1638 */
1639
1640 void SpectateCopy(entity this, entity spectatee)
1641 {
1642     TC(Client, this); TC(Client, spectatee);
1643
1644         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1645         PS(this) = PS(spectatee);
1646         this.armortype = spectatee.armortype;
1647         this.armorvalue = spectatee.armorvalue;
1648         this.ammo_cells = spectatee.ammo_cells;
1649         this.ammo_plasma = spectatee.ammo_plasma;
1650         this.ammo_shells = spectatee.ammo_shells;
1651         this.ammo_nails = spectatee.ammo_nails;
1652         this.ammo_rockets = spectatee.ammo_rockets;
1653         this.ammo_fuel = spectatee.ammo_fuel;
1654         this.clip_load = spectatee.clip_load;
1655         this.clip_size = spectatee.clip_size;
1656         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1657         this.health = spectatee.health;
1658         this.impulse = 0;
1659         this.items = spectatee.items;
1660         this.last_pickup = spectatee.last_pickup;
1661         this.hit_time = spectatee.hit_time;
1662         this.strength_finished = spectatee.strength_finished;
1663         this.invincible_finished = spectatee.invincible_finished;
1664         this.pressedkeys = spectatee.pressedkeys;
1665         this.weapons = spectatee.weapons;
1666         this.vortex_charge = spectatee.vortex_charge;
1667         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1668         this.hagar_load = spectatee.hagar_load;
1669         this.arc_heat_percent = spectatee.arc_heat_percent;
1670         this.minelayer_mines = spectatee.minelayer_mines;
1671         this.punchangle = spectatee.punchangle;
1672         this.view_ofs = spectatee.view_ofs;
1673         this.velocity = spectatee.velocity;
1674         this.dmg_take = spectatee.dmg_take;
1675         this.dmg_save = spectatee.dmg_save;
1676         this.dmg_inflictor = spectatee.dmg_inflictor;
1677         this.v_angle = spectatee.v_angle;
1678         this.angles = spectatee.v_angle;
1679         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1680         this.revive_progress = spectatee.revive_progress;
1681         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1682                 this.fixangle = true;
1683         setorigin(this, spectatee.origin);
1684         setsize(this, spectatee.mins, spectatee.maxs);
1685         SetZoomState(this, spectatee.zoomstate);
1686
1687     anticheat_spectatecopy(this, spectatee);
1688         this.hud = spectatee.hud;
1689         if(spectatee.vehicle)
1690     {
1691         this.angles = spectatee.v_angle;
1692
1693         //this.fixangle = false;
1694         //this.velocity = spectatee.vehicle.velocity;
1695         this.vehicle_health = spectatee.vehicle_health;
1696         this.vehicle_shield = spectatee.vehicle_shield;
1697         this.vehicle_energy = spectatee.vehicle_energy;
1698         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1699         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1700         this.vehicle_reload1 = spectatee.vehicle_reload1;
1701         this.vehicle_reload2 = spectatee.vehicle_reload2;
1702
1703         //msg_entity = this;
1704
1705        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1706             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1707            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1708            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1709
1710         //WriteByte (MSG_ONE, SVC_SETVIEW);
1711         //    WriteEntity(MSG_ONE, this);
1712         //makevectors(spectatee.v_angle);
1713         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1714     }
1715 }
1716
1717 bool SpectateUpdate(entity this)
1718 {
1719         if(!this.enemy)
1720                 return false;
1721
1722         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1723         {
1724                 SetSpectatee(this, NULL);
1725                 return false;
1726         }
1727
1728         SpectateCopy(this, this.enemy);
1729
1730         return true;
1731 }
1732
1733 bool SpectateSet(entity this)
1734 {
1735         if(!IS_PLAYER(this.enemy))
1736                 return false;
1737
1738         ClientData_Touch(this.enemy);
1739
1740         msg_entity = this;
1741         WriteByte(MSG_ONE, SVC_SETVIEW);
1742         WriteEntity(MSG_ONE, this.enemy);
1743         set_movetype(this, MOVETYPE_NONE);
1744         accuracy_resend(this);
1745
1746         if(!SpectateUpdate(this))
1747                 PutObserverInServer(this);
1748
1749         return true;
1750 }
1751
1752 void SetSpectatee_status(entity this, int spectatee_num)
1753 {
1754         int oldspectatee_status = this.spectatee_status;
1755         this.spectatee_status = spectatee_num;
1756
1757         if (this.spectatee_status != oldspectatee_status)
1758         {
1759                 ClientData_Touch(this);
1760                 if (g_race || g_cts) race_InitSpectator();
1761         }
1762 }
1763
1764 void SetSpectatee(entity this, entity spectatee)
1765 {
1766         entity old_spectatee = this.enemy;
1767
1768         this.enemy = spectatee;
1769
1770         // WEAPONTODO
1771         // these are required to fix the spectator bug with arc
1772         if(old_spectatee)
1773         {
1774                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1775                 {
1776                         .entity weaponentity = weaponentities[slot];
1777                         if(old_spectatee.(weaponentity).arc_beam)
1778                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1779                 }
1780         }
1781         if(this.enemy)
1782         {
1783                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1784                 {
1785                         .entity weaponentity = weaponentities[slot];
1786                         if(this.enemy.(weaponentity).arc_beam)
1787                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1788                 }
1789         }
1790
1791         if (this.enemy)
1792                 SetSpectatee_status(this, etof(this.enemy));
1793
1794         // needed to update spectator list
1795         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1796 }
1797
1798 bool Spectate(entity this, entity pl)
1799 {
1800         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1801                 return false;
1802         pl = M_ARGV(1, entity);
1803
1804         SetSpectatee(this, pl);
1805         return SpectateSet(this);
1806 }
1807
1808 bool SpectateNext(entity this)
1809 {
1810         entity ent = find(this.enemy, classname, STR_PLAYER);
1811
1812         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1813                 ent = M_ARGV(1, entity);
1814         else if (!ent)
1815                 ent = find(ent, classname, STR_PLAYER);
1816
1817         if(ent) { SetSpectatee(this, ent); }
1818
1819         return SpectateSet(this);
1820 }
1821
1822 bool SpectatePrev(entity this)
1823 {
1824         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1825         entity ent = findchain(classname, STR_PLAYER);
1826         if (!ent) // no player
1827                 return false;
1828
1829         entity first = ent;
1830         // skip players until current spectated player
1831         if(this.enemy)
1832         while(ent && ent != this.enemy)
1833                 ent = ent.chain;
1834
1835         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1836         {
1837                 case MUT_SPECPREV_FOUND:
1838                     ent = M_ARGV(1, entity);
1839                     break;
1840                 case MUT_SPECPREV_RETURN:
1841                     return true;
1842                 case MUT_SPECPREV_CONTINUE:
1843                 default:
1844                 {
1845                         if(ent.chain)
1846                                 ent = ent.chain;
1847                         else
1848                                 ent = first;
1849                         break;
1850                 }
1851         }
1852
1853         SetSpectatee(this, ent);
1854         return SpectateSet(this);
1855 }
1856
1857 /*
1858 =============
1859 ShowRespawnCountdown()
1860
1861 Update a respawn countdown display.
1862 =============
1863 */
1864 void ShowRespawnCountdown(entity this)
1865 {
1866         float number;
1867         if(!IS_DEAD(this)) // just respawned?
1868                 return;
1869         else
1870         {
1871                 number = ceil(this.respawn_time - time);
1872                 if(number <= 0)
1873                         return;
1874                 if(number <= this.respawn_countdown)
1875                 {
1876                         this.respawn_countdown = number - 1;
1877                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1878                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1879                 }
1880         }
1881 }
1882
1883 .bool team_selected;
1884 bool ShowTeamSelection(entity this)
1885 {
1886         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1887                 return false;
1888         stuffcmd(this, "menu_showteamselect\n");
1889         return true;
1890 }
1891 void Join(entity this)
1892 {
1893         TRANSMUTE(Player, this);
1894
1895         if(!this.team_selected)
1896         if(autocvar_g_campaign || autocvar_g_balance_teams)
1897                 JoinBestTeam(this, false, true);
1898
1899         if(autocvar_g_campaign)
1900                 campaign_bots_may_start = true;
1901
1902         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1903
1904         PutClientInServer(this);
1905
1906         if(teamplay && this.team != -1)
1907                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1908         else
1909                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1910         this.team_selected = false;
1911 }
1912
1913 /**
1914  * Determines whether the player is allowed to join. This depends on cvar
1915  * g_maxplayers, if it isn't used this function always return true, otherwise
1916  * it checks whether the number of currently playing players exceeds g_maxplayers.
1917  * @return int number of free slots for players, 0 if none
1918  */
1919 int nJoinAllowed(entity this, entity ignore)
1920 {
1921         if(!ignore)
1922         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1923         // so report 0 free slots if restricted
1924         {
1925                 if(autocvar_g_forced_team_otherwise == "spectate")
1926                         return 0;
1927                 if(autocvar_g_forced_team_otherwise == "spectator")
1928                         return 0;
1929         }
1930
1931         if(this && this.team_forced < 0)
1932                 return 0; // forced spectators can never join
1933
1934         // TODO simplify this
1935         int totalClients = 0;
1936         int currentlyPlaying = 0;
1937         FOREACH_CLIENT(true, LAMBDA(
1938                 if(it != ignore)
1939                         ++totalClients;
1940                 if(IS_REAL_CLIENT(it))
1941                 if(IS_PLAYER(it) || it.caplayer)
1942                         ++currentlyPlaying;
1943         ));
1944
1945         float free_slots = 0;
1946         if (!autocvar_g_maxplayers)
1947                 free_slots = maxclients - totalClients;
1948         else if(currentlyPlaying < autocvar_g_maxplayers)
1949                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1950
1951         static float join_prevent_msg_time = 0;
1952         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1953         {
1954                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1955                 join_prevent_msg_time = time + 3;
1956         }
1957
1958         return free_slots;
1959 }
1960
1961 /**
1962  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1963  * g_maxplayers_spectator_blocktime seconds
1964  */
1965 void checkSpectatorBlock(entity this)
1966 {
1967         if(IS_SPEC(this) || IS_OBSERVER(this))
1968         if(!this.caplayer)
1969         if(IS_REAL_CLIENT(this))
1970         {
1971                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1972                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1973                         dropclient(this);
1974                 }
1975         }
1976 }
1977
1978 void PrintWelcomeMessage(entity this)
1979 {
1980         if(this.motd_actived_time == 0)
1981         {
1982                 if (autocvar_g_campaign) {
1983                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1984                                 this.motd_actived_time = time;
1985                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1986                         }
1987                 } else {
1988                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1989                                 this.motd_actived_time = time;
1990                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1991                         }
1992                 }
1993         }
1994         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1995         {
1996                 if (autocvar_g_campaign) {
1997                         if (PHYS_INPUT_BUTTON_INFO(this))
1998                                 this.motd_actived_time = time;
1999                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2000                                 this.motd_actived_time = 0;
2001                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2002                         }
2003                 } else {
2004                         if (PHYS_INPUT_BUTTON_INFO(this))
2005                                 this.motd_actived_time = time;
2006                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2007                                 this.motd_actived_time = 0;
2008                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2009                         }
2010                 }
2011         }
2012         else //if(this.motd_actived_time < 0) // just connected, motd is active
2013         {
2014                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2015                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2016                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2017                 {
2018                         // instanctly hide MOTD
2019                         this.motd_actived_time = 0;
2020                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2021                 }
2022         }
2023 }
2024
2025 bool joinAllowed(entity this)
2026 {
2027         if (this.version_mismatch) return false;
2028         if (!nJoinAllowed(this, this)) return false;
2029         if (teamplay && lockteams) return false;
2030         if (ShowTeamSelection(this)) return false;
2031         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2032         return true;
2033 }
2034
2035 void ObserverThink(entity this)
2036 {
2037         if ( this.impulse )
2038         {
2039                 MinigameImpulse(this, this.impulse);
2040                 this.impulse = 0;
2041         }
2042
2043         if (this.flags & FL_JUMPRELEASED) {
2044                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2045                         this.flags &= ~FL_JUMPRELEASED;
2046                         this.flags |= FL_SPAWNING;
2047                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2048                         this.flags &= ~FL_JUMPRELEASED;
2049                         if(SpectateNext(this)) {
2050                                 TRANSMUTE(Spectator, this);
2051                         }
2052                 } else {
2053                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2054                         set_movetype(this, preferred_movetype);
2055                 }
2056         } else {
2057                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2058                         this.flags |= FL_JUMPRELEASED;
2059                         if(this.flags & FL_SPAWNING)
2060                         {
2061                                 this.flags &= ~FL_SPAWNING;
2062                                 Join(this);
2063                                 return;
2064                         }
2065                 }
2066         }
2067 }
2068
2069 void SpectatorThink(entity this)
2070 {
2071         if ( this.impulse )
2072         {
2073                 if(MinigameImpulse(this, this.impulse))
2074                         this.impulse = 0;
2075
2076                 if (this.impulse == IMP_weapon_drop.impulse)
2077                 {
2078                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2079                         this.impulse = 0;
2080                         return;
2081                 }
2082         }
2083
2084         if (this.flags & FL_JUMPRELEASED) {
2085                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2086                         this.flags &= ~FL_JUMPRELEASED;
2087                         this.flags |= FL_SPAWNING;
2088                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2089                         this.flags &= ~FL_JUMPRELEASED;
2090                         if(SpectateNext(this)) {
2091                                 TRANSMUTE(Spectator, this);
2092                         } else {
2093                                 TRANSMUTE(Observer, this);
2094                                 PutClientInServer(this);
2095                         }
2096                         this.impulse = 0;
2097                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2098                         this.flags &= ~FL_JUMPRELEASED;
2099                         if(SpectatePrev(this)) {
2100                                 TRANSMUTE(Spectator, this);
2101                         } else {
2102                                 TRANSMUTE(Observer, this);
2103                                 PutClientInServer(this);
2104                         }
2105                         this.impulse = 0;
2106                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2107                         this.flags &= ~FL_JUMPRELEASED;
2108                         TRANSMUTE(Observer, this);
2109                         PutClientInServer(this);
2110                 } else {
2111                         if(!SpectateUpdate(this))
2112                                 PutObserverInServer(this);
2113                 }
2114         } else {
2115                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2116                         this.flags |= FL_JUMPRELEASED;
2117                         if(this.flags & FL_SPAWNING)
2118                         {
2119                                 this.flags &= ~FL_SPAWNING;
2120                                 Join(this);
2121                                 return;
2122                         }
2123                 }
2124                 if(!SpectateUpdate(this))
2125                         PutObserverInServer(this);
2126         }
2127
2128         this.flags |= FL_CLIENT | FL_NOTARGET;
2129 }
2130
2131 void vehicles_enter (entity pl, entity veh);
2132 void PlayerUseKey(entity this)
2133 {
2134         if (!IS_PLAYER(this))
2135                 return;
2136
2137         if(this.vehicle)
2138         {
2139                 if(!gameover)
2140                 {
2141                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2142                         return;
2143                 }
2144         }
2145         else if(autocvar_g_vehicles_enter)
2146         {
2147                 if(!STAT(FROZEN, this))
2148                 if(!IS_DEAD(this))
2149                 if(!gameover)
2150                 {
2151                         entity head, closest_target = NULL;
2152                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2153
2154                         while(head) // find the closest acceptable target to enter
2155                         {
2156                                 if(IS_VEHICLE(head))
2157                                 if(!IS_DEAD(head))
2158                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2159                                 if(head.takedamage != DAMAGE_NO)
2160                                 {
2161                                         if(closest_target)
2162                                         {
2163                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2164                                                 { closest_target = head; }
2165                                         }
2166                                         else { closest_target = head; }
2167                                 }
2168
2169                                 head = head.chain;
2170                         }
2171
2172                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2173                 }
2174         }
2175
2176         // a use key was pressed; call handlers
2177         MUTATOR_CALLHOOK(PlayerUseKey, this);
2178 }
2179
2180
2181 /*
2182 =============
2183 PlayerPreThink
2184
2185 Called every frame for each client before the physics are run
2186 =============
2187 */
2188 .float usekeypressed;
2189 .float last_vehiclecheck;
2190 .int items_added;
2191 void PlayerPreThink (entity this)
2192 {
2193         WarpZone_PlayerPhysics_FixVAngle(this);
2194
2195     STAT(GAMESTARTTIME, this) = game_starttime;
2196         STAT(ROUNDSTARTTIME, this) = round_starttime;
2197         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2198         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2199
2200         STAT(WEAPONSINMAP, this) = weaponsInMap;
2201
2202         if (frametime) {
2203                 // physics frames: update anticheat stuff
2204                 anticheat_prethink(this);
2205         }
2206
2207         if (blockSpectators && frametime) {
2208                 // WORKAROUND: only use dropclient in server frames (frametime set).
2209                 // Never use it in cl_movement frames (frametime zero).
2210                 checkSpectatorBlock(this);
2211     }
2212
2213         zoomstate_set = false;
2214
2215         // Check for nameless players
2216         if (isInvisibleString(this.netname)) {
2217                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2218                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2219         }
2220         if (this.netname != this.netname_previous) {
2221                 if (autocvar_sv_eventlog) {
2222                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2223         }
2224                 if (this.netname_previous) strunzone(this.netname_previous);
2225                 this.netname_previous = strzone(this.netname);
2226         }
2227
2228         // version nagging
2229         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2230         this.version_nagtime = 0;
2231         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2232             // git client
2233         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2234             // git server
2235             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2236         } else {
2237             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2238             if (r < 0) { // old client
2239                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2240             } else if (r > 0) { // old server
2241                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2242             }
2243         }
2244     }
2245
2246         // GOD MODE info
2247         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2248         {
2249                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2250                 this.max_armorvalue = 0;
2251         }
2252
2253         if (STAT(FROZEN, this) == 2)
2254         {
2255                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2256                 this.health = max(1, this.revive_progress * start_health);
2257                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2258
2259                 if (this.revive_progress >= 1)
2260                         Unfreeze(this);
2261         }
2262         else if (STAT(FROZEN, this) == 3)
2263         {
2264                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2265                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2266
2267                 if (this.health < 1)
2268                 {
2269                         if (this.vehicle)
2270                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2271                         if(this.event_damage)
2272                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2273                 }
2274                 else if (this.revive_progress <= 0)
2275                         Unfreeze(this);
2276         }
2277
2278         MUTATOR_CALLHOOK(PlayerPreThink, this);
2279
2280         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2281         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2282         {
2283                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2284                 {
2285                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2286                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2287                         {
2288                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2289                         }
2290                         else if(!it.owner)
2291                         {
2292                                 if(!it.team || SAME_TEAM(this, it))
2293                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2294                                 else if(autocvar_g_vehicles_steal)
2295                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2296                         }
2297                 });
2298
2299                 this.last_vehiclecheck = time + 1;
2300         }
2301
2302         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2303         {
2304                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2305                         PlayerUseKey(this);
2306                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2307         }
2308
2309         if (IS_REAL_CLIENT(this))
2310                 PrintWelcomeMessage(this);
2311
2312         if (IS_PLAYER(this)) {
2313                 CheckRules_Player(this);
2314
2315                 if (intermission_running) {
2316                         IntermissionThink(this);
2317                         return;
2318                 }
2319
2320                 if (timeout_status == TIMEOUT_ACTIVE) {
2321             // don't allow the player to turn around while game is paused
2322                         // FIXME turn this into CSQC stuff
2323                         this.v_angle = this.lastV_angle;
2324                         this.angles = this.lastV_angle;
2325                         this.fixangle = true;
2326                 }
2327
2328                 if (frametime) player_powerups(this);
2329
2330                 if (IS_DEAD(this)) {
2331                         if (this.personal && g_race_qualifying) {
2332                                 if (time > this.respawn_time) {
2333                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2334                                         respawn(this);
2335                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2336                                 }
2337                         } else {
2338                                 if (frametime) player_anim(this);
2339                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2340
2341                                 switch(this.deadflag)
2342                                 {
2343                                         case DEAD_DYING:
2344                                         {
2345                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2346                                                         this.deadflag = DEAD_RESPAWNING;
2347                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2348                                                         this.deadflag = DEAD_DEAD;
2349                                                 break;
2350                                         }
2351                                         case DEAD_DEAD:
2352                                         {
2353                                                 if (button_pressed)
2354                                                         this.deadflag = DEAD_RESPAWNABLE;
2355                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2356                                                         this.deadflag = DEAD_RESPAWNING;
2357                                                 break;
2358                                         }
2359                                         case DEAD_RESPAWNABLE:
2360                                         {
2361                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2362                                                         this.deadflag = DEAD_RESPAWNING;
2363                                                 break;
2364                                         }
2365                                         case DEAD_RESPAWNING:
2366                                         {
2367                                                 if (time > this.respawn_time)
2368                                                 {
2369                                                         this.respawn_time = time + 1; // only retry once a second
2370                                                         this.respawn_time_max = this.respawn_time;
2371                                                         respawn(this);
2372                                                 }
2373                                                 break;
2374                                         }
2375                                 }
2376
2377                                 ShowRespawnCountdown(this);
2378
2379                                 if (this.respawn_flags & RESPAWN_SILENT)
2380                                         STAT(RESPAWN_TIME, this) = 0;
2381                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2382                                 {
2383                                         if (time < this.respawn_time)
2384                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2385                                         else if (this.deadflag != DEAD_RESPAWNING)
2386                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2387                                 }
2388                                 else
2389                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2390                         }
2391
2392                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2393                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2394                                 STAT(RESPAWN_TIME, this) *= -1;
2395
2396                         return;
2397                 }
2398
2399                 this.prevorigin = this.origin;
2400
2401                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2402                 if (this.hook.state) {
2403                         do_crouch = false;
2404                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2405                         do_crouch = false;
2406                 } else if (this.vehicle) {
2407                         do_crouch = false;
2408                 } else if (STAT(FROZEN, this)) {
2409                         do_crouch = false;
2410         }
2411
2412                 if (do_crouch) {
2413                         if (!this.crouch) {
2414                                 this.crouch = true;
2415                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2416                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2417                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2418                         }
2419                 } else if (this.crouch) {
2420             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2421             if (!trace_startsolid) {
2422                 this.crouch = false;
2423                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2424                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2425             }
2426                 }
2427
2428                 FixPlayermodel(this);
2429
2430                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2431                 //if(frametime)
2432                 {
2433                         this.items &= ~this.items_added;
2434
2435                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2436                         {
2437                                 .entity weaponentity = weaponentities[slot];
2438                                 W_WeaponFrame(this, weaponentity);
2439
2440                                 if(slot == 0)
2441                                 {
2442                                         this.clip_load = this.(weaponentity).clip_load;
2443                                         this.clip_size = this.(weaponentity).clip_size;
2444                                 }
2445                         }
2446
2447                         this.items_added = 0;
2448                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2449                 this.items_added |= IT_FUEL;
2450
2451                         this.items |= this.items_added;
2452                 }
2453
2454                 player_regen(this);
2455
2456                 // WEAPONTODO: Add a weapon request for this
2457                 // rot vortex charge to the charge limit
2458                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2459                 {
2460                         .entity weaponentity = weaponentities[slot];
2461                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2462                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2463                 }
2464
2465                 if (frametime) player_anim(this);
2466
2467                 // secret status
2468                 secrets_setstatus(this);
2469
2470                 // monsters status
2471                 monsters_setstatus(this);
2472
2473                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2474         }
2475         else if (gameover) {
2476                 if (intermission_running) IntermissionThink(this);
2477                 return;
2478         }
2479         else if (IS_OBSERVER(this)) {
2480                 ObserverThink(this);
2481         }
2482         else if (IS_SPEC(this)) {
2483                 SpectatorThink(this);
2484         }
2485
2486         // WEAPONTODO: Add weapon request for this
2487         if (!zoomstate_set) {
2488                 bool wep_zoomed = false;
2489                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2490                 {
2491                         .entity weaponentity = weaponentities[slot];
2492                         Weapon thiswep = this.(weaponentity).m_weapon;
2493                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2494                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2495                 }
2496                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2497     }
2498
2499         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2500         {
2501                 this.teamkill_soundtime = 0;
2502
2503                 entity e = this.teamkill_soundsource;
2504                 entity oldpusher = e.pusher;
2505                 e.pusher = this;
2506                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2507                 e.pusher = oldpusher;
2508         }
2509
2510         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2511                 this.taunt_soundtime = 0;
2512                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2513         }
2514
2515         target_voicescript_next(this);
2516
2517         // WEAPONTODO: Move into weaponsystem somehow
2518         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2519         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2520         {
2521                 .entity weaponentity = weaponentities[slot];
2522                 if(this.(weaponentity).m_weapon == WEP_Null)
2523                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2524         }
2525 }
2526
2527 void DrownPlayer(entity this)
2528 {
2529         if(IS_DEAD(this))
2530                 return;
2531
2532         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2533         {
2534                 if(this.air_finished < time)
2535                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2536                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2537                 this.dmg = 2;
2538         }
2539         else if (this.air_finished < time)
2540         {       // drown!
2541                 if (this.pain_finished < time)
2542                 {
2543                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2544                         this.pain_finished = time + 0.5;
2545                 }
2546         }
2547 }
2548
2549 .bool move_qcphysics;
2550
2551 void Player_Physics(entity this)
2552 {
2553         set_movetype(this, this.move_movetype);
2554
2555         if(!this.move_qcphysics)
2556                 return;
2557
2558         if(!frametime && !this.pm_frametime)
2559                 return;
2560
2561         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2562
2563         this.pm_frametime = 0;
2564 }
2565
2566 /*
2567 =============
2568 PlayerPostThink
2569
2570 Called every frame for each client after the physics are run
2571 =============
2572 */
2573 .float idlekick_lasttimeleft;
2574 void PlayerPostThink (entity this)
2575 {
2576         Player_Physics(this);
2577
2578         if (sv_maxidle > 0)
2579         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2580         if (IS_REAL_CLIENT(this))
2581         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2582         {
2583                 int totalClients = 0;
2584                 if(sv_maxidle_slots > 0)
2585                 {
2586                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2587                         {
2588                                 ++totalClients;
2589                         });
2590                 }
2591
2592                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2593                 { /* do nothing */ }
2594                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2595                 {
2596                         if (this.idlekick_lasttimeleft)
2597                         {
2598                                 this.idlekick_lasttimeleft = 0;
2599                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2600                         }
2601                 }
2602                 else
2603                 {
2604                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2605                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2606                                 if (!this.idlekick_lasttimeleft)
2607                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2608                         }
2609                         if (timeleft <= 0) {
2610                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2611                                 dropclient(this);
2612                                 return;
2613                         }
2614                         else if (timeleft <= 10) {
2615                                 if (timeleft != this.idlekick_lasttimeleft) {
2616                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2617                 }
2618                                 this.idlekick_lasttimeleft = timeleft;
2619                         }
2620                 }
2621         }
2622
2623         CheatFrame(this);
2624
2625         //CheckPlayerJump();
2626
2627         if (IS_PLAYER(this)) {
2628                 DrownPlayer(this);
2629                 CheckRules_Player(this);
2630                 UpdateChatBubble(this);
2631                 if (this.impulse) ImpulseCommands(this);
2632                 if (intermission_running) return; // intermission or finale
2633                 GetPressedKeys(this);
2634         }
2635
2636         if (this.waypointsprite_attachedforcarrier) {
2637             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2638                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2639     }
2640
2641         playerdemo_write(this);
2642
2643         CSQCMODEL_AUTOUPDATE(this);
2644 }