qcsrc/server/command/banning.qc

   1 // =====================================================
   2 //  Banning and kicking command code, written by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 void BanCommand_ban(float request, float argc, string command)
   7 {
   8         switch(request)
   9         {
  10                 case CMD_REQUEST_COMMAND:
  11                 {
  12                         if(argc >= 2)
  13                         {
  14                                 string ip = argv(1);
  15                                 float reason_arg, bantime;
  16                                 string reason;
  17
  18                                 reason_arg = 2;
  19
  20                                 GET_BAN_ARG(bantime, autocvar_g_ban_default_bantime);
  21                                 GET_BAN_REASON(reason, "No reason provided");
  22
  23                                 Ban_Insert(ip, bantime, reason, 1);
  24                                 return;
  25                         }
  26                 }
  27
  28                 default:
  29                         print("Incorrect parameters for ^2ban^7\n");
  30                 case CMD_REQUEST_USAGE:
  31                 {
  32                         print("\nUsage:^3 sv_cmd ban address [bantime] [reason]\n");
  33                         print("  'address' is the IP address or range of the player to ban,\n");
  34                         print("  'bantime' is the amount of time that the ban is active (default if not provided),\n");
  35                         print("  and 'reason' is the string to label the ban with as reason for banning.\n");
  36                         print("See also: ^2banlist, kickban, unban^7\n");
  37                         return;
  38                 }
  39         }
  40 }
  41
  42 void BanCommand_banlist(float request)
  43 {
  44         switch(request)
  45         {
  46                 case CMD_REQUEST_COMMAND:
  47                 {
  48                         Ban_View();
  49                         return;
  50                 }
  51
  52                 default:
  53                 case CMD_REQUEST_USAGE:
  54                 {
  55                         print("\nUsage:^3 sv_cmd banlist\n");
  56                         print("  No arguments required.\n");
  57                         print("See also: ^2ban, kickban, unban^7\n");
  58                         return;
  59                 }
  60         }
  61 }
  62
  63 void BanCommand_kickban(float request, float argc, string command)
  64 {
  65         switch(request)
  66         {
  67                 case CMD_REQUEST_COMMAND:
  68                 {
  69                         if(argc >= 2)
  70                         {
  71                                 entity client = GetIndexedEntity(argc, 1);
  72                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
  73                                 float reason_arg, bantime, masksize;
  74                                 string reason;
  75
  76                                 if(accepted > 0)
  77                                 {
  78                                         reason_arg = next_token;
  79
  80                                         GET_BAN_ARG(bantime, autocvar_g_ban_default_bantime);
  81                                         GET_BAN_ARG(masksize, autocvar_g_ban_default_masksize);
  82                                         GET_BAN_REASON(reason, "No reason provided");
  83
  84                                         Ban_KickBanClient(client, bantime, masksize, reason);
  85
  86                                         return;
  87                                 }
  88                                 else
  89                                 {
  90                                         print("kickban: ", GetClientErrorString(accepted, argv(1)), ".\n");
  91                                 }
  92                         }
  93                 }
  94
  95                 default:
  96                         print("Incorrect parameters for ^2kickban^7\n");
  97                 case CMD_REQUEST_USAGE:
  98                 {
  99                         print("\nUsage:^3 sv_cmd kickban client [bantime] [masksize] [reason]\n");
 100                         print("  'client' is the entity number or name of the player to ban,\n");
 101                         print("  'bantime' is the amount of time that the ban is active (default if not provided),\n");
 102                         print("  'masksize' is the range of the IP address (1-thru-4, default if not provided),\n");
 103                         print("  and 'reason' is the string to label the ban with as reason for banning.\n");
 104                         print("See also: ^2ban, banlist, unban^7\n");
 105                         return;
 106                 }
 107         }
 108 }
 109
 110 void BanCommand_mute(float request, float argc, string command) // TODO: Add a sort of mute-"ban" which allows players to be muted based on IP/cryptokey
 111 {
 112         switch(request)
 113         {
 114                 case CMD_REQUEST_COMMAND:
 115                 {
 116                         if(argc >= 2)
 117                         {
 118                                 entity client = GetFilteredEntity(argv(1));
 119                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
 120
 121                                 if(accepted > 0)
 122                                 {
 123                                         client.muted = TRUE;
 124                                         return;
 125                                 }
 126                                 else
 127                                 {
 128                                         print("mute: ", GetClientErrorString(accepted, argv(1)), ".\n");
 129                                 }
 130                         }
 131                 }
 132
 133                 default:
 134                         print("Incorrect parameters for ^2mute^7\n");
 135                 case CMD_REQUEST_USAGE:
 136                 {
 137                         print("\nUsage:^3 sv_cmd mute client\n");
 138                         print("  'client' is the entity number or name of the player to mute.\n");
 139                         print("See also: ^2unmute^7\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void BanCommand_unban(float request, float argc)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(argv(1))
 152                         {
 153                                 Ban_Delete(stof(argv(1)));
 154                                 return;
 155                         }
 156                 }
 157
 158                 default:
 159                 case CMD_REQUEST_USAGE:
 160                 {
 161                         print("\nUsage:^3 sv_cmd unban banid\n");
 162                         print("  Where 'banid' is the ID of the ban of which to remove.\n");
 163                         print("See also: ^2ban, banlist, kickban^7\n");
 164                         return;
 165                 }
 166         }
 167 }
 168
 169 void BanCommand_unmute(float request, float argc)
 170 {
 171         switch(request)
 172         {
 173                 case CMD_REQUEST_COMMAND:
 174                 {
 175                         if(argc >= 2)
 176                         {
 177                                 entity client = GetFilteredEntity(argv(1));
 178                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
 179
 180                                 if(accepted > 0)
 181                                 {
 182                                         client.muted = FALSE;
 183                                         return;
 184                                 }
 185                                 else
 186                                 {
 187                                         print("unmute: ", GetClientErrorString(accepted, argv(1)), ".\n");
 188                                 }
 189                         }
 190                 }
 191
 192                 default:
 193                         print("Incorrect parameters for ^2mute^7\n");
 194                 case CMD_REQUEST_USAGE:
 195                 {
 196                         print("\nUsage:^3 sv_cmd unmute client\n");
 197                         print("  'client' is the entity number or name of the player to unmute.\n");
 198                         print("See also: ^2mute^7\n");
 199                         return;
 200                 }
 201         }
 202 }
 203
 204 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 205 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 206 void BanCommand_(float request)
 207 {
 208         switch(request)
 209         {
 210                 case CMD_REQUEST_COMMAND:
 211                 {
 212
 213                         return;
 214                 }
 215
 216                 default:
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         print("\nUsage:^3 sv_cmd \n");
 220                         print("  No arguments required.\n");
 221                         return;
 222                 }
 223         }
 224 }
 225 */
 226
 227
 228 // ==================================
 229 //  Macro system for server commands
 230 // ==================================
 231
 232 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 233 #define BAN_COMMANDS(request,arguments,command) \
 234         BAN_COMMAND("ban", BanCommand_ban(request, arguments, command), "Ban an IP address or a range of addresses (like 1.2.3)") \
 235         BAN_COMMAND("banlist", BanCommand_banlist(request), "List all existing bans") \
 236         BAN_COMMAND("kickban", BanCommand_kickban(request, arguments, command), "Disconnect a client and ban it at the same time") \
 237         BAN_COMMAND("mute", BanCommand_mute(request, arguments, command), "Disallow a client from talking by muting them") \
 238         BAN_COMMAND("unban", BanCommand_unban(request, arguments), "Remove an existing ban") \
 239         BAN_COMMAND("unmute", BanCommand_unmute(request, arguments), "Unmute a client") \
 240         /* nothing */
 241
 242 void BanCommand_macro_help()
 243 {
 244         #define BAN_COMMAND(name,function,description) \
 245                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 246
 247         BAN_COMMANDS(0, 0, "")
 248         #undef BAN_COMMAND
 249
 250         return;
 251 }
 252
 253 float BanCommand_macro_command(float argc, string command)
 254 {
 255         #define BAN_COMMAND(name,function,description) \
 256                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 257
 258         BAN_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 259         #undef BAN_COMMAND
 260
 261         return FALSE;
 262 }
 263
 264 float BanCommand_macro_usage(float argc)
 265 {
 266         #define BAN_COMMAND(name,function,description) \
 267                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 268
 269         BAN_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 270         #undef BAN_COMMAND
 271
 272         return FALSE;
 273 }
 274
 275 void BanCommand_macro_write_aliases(float fh)
 276 {
 277         #define BAN_COMMAND(name,function,description) \
 278                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_sv", name, description); } }
 279
 280         BAN_COMMANDS(0, 0, "")
 281         #undef BAN_COMMAND
 282
 283         return;
 284 }
 285
 286 float BanCommand(string command)
 287 {
 288         float argc = tokenize_console(command);
 289
 290         // Guide for working with argc arguments by example:
 291         // argc:   1    - 2      - 3     - 4
 292         // argv:   0    - 1      - 2     - 3
 293         // cmd     vote - master - login - password
 294
 295         if(BanCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 296         {
 297                 return TRUE; // handled by one of the above GenericCommand_* functions
 298         }
 299
 300         return FALSE;
 301 }