qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(argv(1) && argv(2))
 192                         {
 193                                 makevectors(self.v_angle);
 194                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 195
 196                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); }
 197                                 if(!(trace_ent.flags & FL_MONSTER)) { sprint(self, "You need to aim at your monster to edit its properties.\n"); }
 198                                 else if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); }
 199                                 else // all went well, continue
 200                                 {
 201                                         switch(argv(1))
 202                                         {
 203                                                 case "skin":
 204                                                 {
 205                                                         if(trace_ent.monsterid != MON_MAGE)
 206                                                                 trace_ent.skin = stof(argv(2));
 207                                                         break;
 208                                                 }
 209                                                 case "movetarget":
 210                                                 {
 211                                                         trace_ent.monster_moveflags = stof(argv(2));
 212                                                         break;
 213                                                 }
 214                                         }
 215                                 }
 216
 217                                 return;
 218                         }
 219                 }
 220                 default:
 221                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 222                 case CMD_REQUEST_USAGE:
 223                 {
 224                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 225                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 226                         return;
 227                 }
 228         }
 229 }
 230
 231 void ClientCommand_mobkill(float request)
 232 {
 233         switch(request)
 234         {
 235                 case CMD_REQUEST_COMMAND:
 236                 {
 237                         makevectors(self.v_angle);
 238                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 239
 240                         if(trace_ent.flags & FL_MONSTER)
 241                         {
 242                                 if(trace_ent.realowner != self)
 243                                 {
 244                                         sprint(self, "That monster does not belong to you.\n");
 245                                         return;
 246                                 }
 247                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 248                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 249                                 return;
 250                         }
 251                         else
 252                                 sprint(self, "You need to aim at your monster to kill it.\n");
 253
 254                         return;
 255                 }
 256
 257                 default:
 258                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 259                 case CMD_REQUEST_USAGE:
 260                 {
 261                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 262                         sprint(self, "  Aim at your monster to kill it.\n");
 263                         return;
 264                 }
 265         }
 266 }
 267
 268 void ClientCommand_mobspawn(float request, float argc)
 269 {
 270         switch(request)
 271         {
 272                 case CMD_REQUEST_COMMAND:
 273                 {
 274                         entity e;
 275                         string tospawn;
 276                         float moveflag;
 277
 278                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 279                         tospawn = strtolower(argv(1));
 280
 281                         if(tospawn == "list")
 282                         {
 283                                 sprint(self, monsterlist_reply);
 284                                 return;
 285                         }
 286
 287                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
 288                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
 289                         else if(tospawn == "") { sprint(self, "No argument specified.\n"); }
 290                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); }
 291                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
 292                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
 293                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
 294                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); }
 295                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
 296                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
 297                         else // all worked out, so continue
 298                         {
 299                                 self.monstercount += 1;
 300                                 totalspawned += 1;
 301
 302                                 makevectors(self.v_angle);
 303                                 WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 304                                 //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 305
 306                                 e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
 307
 308                                 sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 309                         }
 310
 311                         return;
 312                 }
 313
 314                 default:
 315                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 316                 case CMD_REQUEST_USAGE:
 317                 {
 318                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 319                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
 320                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 321                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 322                         return;
 323                 }
 324         }
 325 }
 326
 327 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 328 {
 329         switch(request)
 330         {
 331                 case CMD_REQUEST_COMMAND:
 332                 {
 333                         if(IS_CLIENT(self))
 334                         {
 335                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 336                                 {
 337                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 338                                         {
 339                                                 if(time < game_starttime) // game is already restarting
 340                                                         return;
 341                                                 if (self.ready) // toggle
 342                                                 {
 343                                                         self.ready = FALSE;
 344                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 345                                                 }
 346                                                 else
 347                                                 {
 348                                                         self.ready = TRUE;
 349                                                         bprint(self.netname, "^2 is ready\n");
 350                                                 }
 351
 352                                                 // cannot reset the game while a timeout is active!
 353                                                 if (!timeout_status)
 354                                                         ReadyCount();
 355                                         } else {
 356                                                 sprint(self, "^1Game has already been restarted\n");
 357                                         }
 358                                 }
 359                         }
 360                         return; // never fall through to usage
 361                 }
 362
 363                 default:
 364                 case CMD_REQUEST_USAGE:
 365                 {
 366                         sprint(self, "\nUsage:^3 cmd ready\n");
 367                         sprint(self, "  No arguments required.\n");
 368                         return;
 369                 }
 370         }
 371 }
 372
 373 void ClientCommand_say(float request, float argc, string command)
 374 {
 375         switch(request)
 376         {
 377                 case CMD_REQUEST_COMMAND:
 378                 {
 379                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 380                         return; // never fall through to usage
 381                 }
 382
 383                 default:
 384                 case CMD_REQUEST_USAGE:
 385                 {
 386                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 387                         sprint(self, "  Where 'message' is the string of text to say.\n");
 388                         return;
 389                 }
 390         }
 391 }
 392
 393 void ClientCommand_say_team(float request, float argc, string command)
 394 {
 395         switch(request)
 396         {
 397                 case CMD_REQUEST_COMMAND:
 398                 {
 399                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 400                         return; // never fall through to usage
 401                 }
 402
 403                 default:
 404                 case CMD_REQUEST_USAGE:
 405                 {
 406                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 407                         sprint(self, "  Where 'message' is the string of text to say.\n");
 408                         return;
 409                 }
 410         }
 411 }
 412
 413 void ClientCommand_selectteam(float request, float argc)
 414 {
 415         switch(request)
 416         {
 417                 case CMD_REQUEST_COMMAND:
 418                 {
 419                         if(argv(1) != "")
 420                         {
 421                                 if(IS_CLIENT(self))
 422                                 {
 423                                         if(teamplay)
 424                                                 if(self.team_forced <= 0)
 425                                                         if (!lockteams)
 426                                                         {
 427                                                                 float selection;
 428
 429                                                                 switch(argv(1))
 430                                                                 {
 431                                                                         case "red": selection = NUM_TEAM_1; break;
 432                                                                         case "blue": selection = NUM_TEAM_2; break;
 433                                                                         case "yellow": selection = NUM_TEAM_3; break;
 434                                                                         case "pink": selection = NUM_TEAM_4; break;
 435                                                                         case "auto": selection = (-1); break;
 436
 437                                                                         default: selection = 0; break;
 438                                                                 }
 439
 440                                                                 if(selection)
 441                                                                 {
 442                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 443                                                                                 sprint(self, "^7You already are on that team.\n");
 444                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 445                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 446                                                                         else
 447                                                                                 ClientKill_TeamChange(selection);
 448                                                                 }
 449                                                         }
 450                                                         else
 451                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 452                                                 else
 453                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 454                                         else
 455                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 456                                 }
 457                                 return;
 458                         }
 459                 }
 460
 461                 default:
 462                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 463                 case CMD_REQUEST_USAGE:
 464                 {
 465                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 466                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 467                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 468                         return;
 469                 }
 470         }
 471 }
 472
 473 void ClientCommand_selfstuff(float request, string command)
 474 {
 475         switch(request)
 476         {
 477                 case CMD_REQUEST_COMMAND:
 478                 {
 479                         if(argv(1) != "")
 480                         {
 481                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 482                                 return;
 483                         }
 484                 }
 485
 486                 default:
 487                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 488                 case CMD_REQUEST_USAGE:
 489                 {
 490                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 491                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 492                         return;
 493                 }
 494         }
 495 }
 496
 497 void ClientCommand_sentcvar(float request, float argc, string command)
 498 {
 499         switch(request)
 500         {
 501                 case CMD_REQUEST_COMMAND:
 502                 {
 503                         if(argv(1) != "")
 504                         {
 505                                 //float tokens;
 506                                 string s;
 507
 508                                 if(argc == 2) // undefined cvar: use the default value on the server then
 509                                 {
 510                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 511                                         tokenize_console(s);
 512                                 }
 513
 514                                 GetCvars(1);
 515
 516                                 return;
 517                         }
 518                 }
 519
 520                 default:
 521                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 522                 case CMD_REQUEST_USAGE:
 523                 {
 524                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 525                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 526                         return;
 527                 }
 528         }
 529 }
 530
 531 void ClientCommand_spectate(float request)
 532 {
 533         switch(request)
 534         {
 535                 case CMD_REQUEST_COMMAND:
 536                 {
 537                         if(IS_CLIENT(self))
 538                         {
 539                                 if(g_lms)
 540                                 {
 541                                         if(self.lms_spectate_warning)
 542                                         {
 543                                                 // for the forfeit message...
 544                                                 self.lms_spectate_warning = 2;
 545                                                 // mark player as spectator
 546                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 547                                         }
 548                                         else
 549                                         {
 550                                                 self.lms_spectate_warning = 1;
 551                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 552                                                 return;
 553                                         }
 554                                 }
 555
 556                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 557                                         ClientKill_TeamChange(-2); // observe
 558
 559                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 560                                 // note: if arena game mode is ever done properly, this needs to be removed.
 561                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 562                                 {
 563                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 564                                         self.caplayer = 0;
 565                                 }
 566                         }
 567                         return; // never fall through to usage
 568                 }
 569
 570                 default:
 571                 case CMD_REQUEST_USAGE:
 572                 {
 573                         sprint(self, "\nUsage:^3 cmd spectate\n");
 574                         sprint(self, "  No arguments required.\n");
 575                         return;
 576                 }
 577         }
 578 }
 579
 580 void ClientCommand_suggestmap(float request, float argc)
 581 {
 582         switch(request)
 583         {
 584                 case CMD_REQUEST_COMMAND:
 585                 {
 586                         if(argv(1) != "")
 587                         {
 588                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 589                                 return;
 590                         }
 591                 }
 592
 593                 default:
 594                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 595                 case CMD_REQUEST_USAGE:
 596                 {
 597                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 598                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 599                         return;
 600                 }
 601         }
 602 }
 603
 604 void ClientCommand_tell(float request, float argc, string command)
 605 {
 606         switch(request)
 607         {
 608                 case CMD_REQUEST_COMMAND:
 609                 {
 610                         if(argc >= 3)
 611                         {
 612                                 entity tell_to = GetIndexedEntity(argc, 1);
 613                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 614
 615                                 if(tell_accepted > 0) // the target is a real client
 616                                 {
 617                                         if(tell_to != self) // and we're allowed to send to them :D
 618                                         {
 619                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 620                                                 return;
 621                                         }
 622                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 623                                 }
 624                                 else if(argv(1) == "#0")
 625                                 {
 626                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 627                                         return;
 628                                 }
 629                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 630                         }
 631                 }
 632
 633                 default:
 634                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 635                 case CMD_REQUEST_USAGE:
 636                 {
 637                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 638                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 639                         return;
 640                 }
 641         }
 642 }
 643
 644 void ClientCommand_voice(float request, float argc, string command)
 645 {
 646         switch(request)
 647         {
 648                 case CMD_REQUEST_COMMAND:
 649                 {
 650                         if(argv(1) != "")
 651                         {
 652                                 if(argc >= 3)
 653                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 654                                 else
 655                                         VoiceMessage(argv(1), "");
 656
 657                                 return;
 658                         }
 659                 }
 660
 661                 default:
 662                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 663                 case CMD_REQUEST_USAGE:
 664                 {
 665                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 666                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 667                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 668                         return;
 669                 }
 670         }
 671 }
 672
 673 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 674 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 675 void ClientCommand_(float request)
 676 {
 677         switch(request)
 678         {
 679                 case CMD_REQUEST_COMMAND:
 680                 {
 681
 682                         return; // never fall through to usage
 683                 }
 684
 685                 default:
 686                 case CMD_REQUEST_USAGE:
 687                 {
 688                         sprint(self, "\nUsage:^3 cmd \n");
 689                         sprint(self, "  No arguments required.\n");
 690                         return;
 691                 }
 692         }
 693 }
 694 */
 695
 696
 697 // =====================================
 698 //  Macro system for networked commands
 699 // =====================================
 700
 701 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 702 #define CLIENT_COMMANDS(request,arguments,command) \
 703         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 704         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 705         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 706         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 707         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 708         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 709         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 710         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 711         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 712         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 713         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 714         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 715         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 716         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 717         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 718         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 719         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 720         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 721         /* nothing */
 722
 723 void ClientCommand_macro_help()
 724 {
 725         #define CLIENT_COMMAND(name,function,description) \
 726                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 727
 728         CLIENT_COMMANDS(0, 0, "")
 729         #undef CLIENT_COMMAND
 730
 731         return;
 732 }
 733
 734 float ClientCommand_macro_command(float argc, string command)
 735 {
 736         #define CLIENT_COMMAND(name,function,description) \
 737                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 738
 739         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 740         #undef CLIENT_COMMAND
 741
 742         return FALSE;
 743 }
 744
 745 float ClientCommand_macro_usage(float argc)
 746 {
 747         #define CLIENT_COMMAND(name,function,description) \
 748                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 749
 750         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 751         #undef CLIENT_COMMAND
 752
 753         return FALSE;
 754 }
 755
 756 void ClientCommand_macro_write_aliases(float fh)
 757 {
 758         #define CLIENT_COMMAND(name,function,description) \
 759                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 760
 761         CLIENT_COMMANDS(0, 0, "")
 762         #undef CLIENT_COMMAND
 763
 764         return;
 765 }
 766
 767 // ======================================
 768 //  Main Function Called By Engine (cmd)
 769 // ======================================
 770 // If this function exists, server game code parses clientcommand before the engine code gets it.
 771
 772 void SV_ParseClientCommand(string command)
 773 {
 774         // if we're banned, don't even parse the command
 775         if(Ban_MaybeEnforceBanOnce(self))
 776                 return;
 777
 778         float argc = tokenize_console(command);
 779
 780         // for the mutator hook system
 781         cmd_name = strtolower(argv(0));
 782         cmd_argc = argc;
 783         cmd_string = command;
 784
 785         // Guide for working with argc arguments by example:
 786         // argc:   1    - 2      - 3     - 4
 787         // argv:   0    - 1      - 2     - 3
 788         // cmd     vote - master - login - password
 789
 790         // for floodcheck
 791         switch(strtolower(argv(0)))
 792         {
 793                 // exempt commands which are not subject to floodcheck
 794                 case "begin": break; // handled by engine in host_cmd.c
 795                 case "download": break; // handled by engine in cl_parse.c
 796                 case "mv_getpicture": break; // handled by server in this file
 797                 case "pause": break; // handled by engine in host_cmd.c
 798                 case "prespawn": break; // handled by engine in host_cmd.c
 799                 case "sentcvar": break; // handled by server in this file
 800                 case "spawn": break; // handled by engine in host_cmd.c
 801
 802                 default:
 803                         if(SV_ParseClientCommand_floodcheck())
 804                                 break; // "TRUE": continue, as we're not flooding yet
 805                         else
 806                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 807         }
 808
 809         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 810         if(argv(0) == "help")
 811         {
 812                 if(argc == 1)
 813                 {
 814                         sprint(self, "\nClient networked commands:\n");
 815                         ClientCommand_macro_help();
 816
 817                         sprint(self, "\nCommon networked commands:\n");
 818                         CommonCommand_macro_help(self);
 819
 820                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 821                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 822                         return;
 823                 }
 824                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 825                 {
 826                         return;
 827                 }
 828                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 829                 {
 830                         return;
 831                 }
 832         }
 833         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 834         {
 835                 return; // handled by a mutator
 836         }
 837         else if(CheatCommand(argc))
 838         {
 839                 return; // handled by server/cheats.qc
 840         }
 841         else if(CommonCommand_macro_command(argc, self, command))
 842         {
 843                 return; // handled by server/command/common.qc
 844         }
 845         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 846         {
 847                 return; // handled by one of the above ClientCommand_* functions
 848         }
 849         else
 850                 clientcommand(self, command);
 851 }