qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2 #include <common/command/_mod.qh>
   3
   4 #include "common.qh"
   5 #include "vote.qh"
   6
   7 #include "../campaign.qh"
   8 #include "../cheats.qh"
   9 #include "../player.qh"
  10 #include "../ipban.qh"
  11 #include "../mapvoting.qh"
  12 #include "../scores.qh"
  13 #include "../teamplay.qh"
  14
  15 #include "../mutators/_mod.qh"
  16
  17 #ifdef SVQC
  18         #include <common/vehicles/all.qh>
  19 #endif
  20
  21 #include <common/constants.qh>
  22 #include <common/deathtypes/all.qh>
  23 #include <common/effects/all.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/notifications/all.qh>
  26 #include <common/physics/player.qh>
  27 #include <common/teams.qh>
  28 #include <common/util.qh>
  29 #include <common/triggers/triggers.qh>
  30
  31 #include <common/minigames/sv_minigames.qh>
  32
  33 #include <common/monsters/_mod.qh>
  34 #include <common/monsters/sv_spawn.qh>
  35 #include <common/monsters/sv_monsters.qh>
  36
  37 #include <lib/warpzone/common.qh>
  38
  39 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
  40
  41 // =========================================================
  42 //  Server side networked commands code, reworked by Samual
  43 //  Last updated: December 28th, 2011
  44 // =========================================================
  45
  46 bool SV_ParseClientCommand_floodcheck(entity this)
  47 {
  48         if (!timeout_status)  // not while paused
  49         {
  50                 if (time <= (this.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  51                 {
  52                         this.cmd_floodcount += 1;
  53                         if (this.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  54                 }
  55                 else
  56                 {
  57                         this.cmd_floodtime = time;
  58                         this.cmd_floodcount = 1;
  59                 }
  60         }
  61         return true;  // continue, as we're not flooding yet
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void ClientCommand_autoswitch(entity caller, float request, float argc)
  70 {
  71         switch (request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         if (argv(1) != "")
  76                         {
  77                                 caller.autoswitch = InterpretBoolean(argv(1));
  78                                 sprint(caller, strcat("^1autoswitch is currently turned ", (caller.autoswitch ? "on" : "off"), ".\n"));
  79                                 return;
  80                         }
  81                 }
  82
  83                 default:
  84                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  85                 case CMD_REQUEST_USAGE:
  86                 {
  87                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  88                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  89                         return;
  90                 }
  91         }
  92 }
  93
  94 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
  95 {
  96         switch (request)
  97         {
  98                 case CMD_REQUEST_COMMAND:
  99                 {
 100                         if (argv(1) != "")
 101                         {
 102                                 if (IS_CLIENT(caller))
 103                                 {
 104                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 105
 106                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 107                                         {
 108                                                 CS(caller).version_mismatch = true;
 109                                                 ClientKill_TeamChange(caller, -2);  // observe
 110                                         }
 111                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 112                                         {
 113                                                 // JoinBestTeam(caller, false, true);
 114                                         }
 115                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 116                                         {
 117                                                 TRANSMUTE(Observer, caller);  // really?
 118                                                 stuffcmd(caller, "menu_showteamselect\n");
 119                                         }
 120                                 }
 121
 122                                 return;
 123                         }
 124                 }
 125
 126                 default:
 127                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 128                 case CMD_REQUEST_USAGE:
 129                 {
 130                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 131                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 132                         return;
 133                 }
 134         }
 135 }
 136
 137 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 138 {
 139         switch (request)
 140         {
 141                 case CMD_REQUEST_COMMAND:
 142                 {
 143                         if (argv(1) != "")
 144                         {
 145                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 146
 147                                 return;
 148                         }
 149                 }
 150
 151                 default:
 152                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 153                 case CMD_REQUEST_USAGE:
 154                 {
 155                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 156                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 157                         return;
 158                 }
 159         }
 160 }
 161
 162 bool joinAllowed(entity this);
 163 void Join(entity this);
 164 void ClientCommand_join(entity caller, float request)
 165 {
 166         switch (request)
 167         {
 168                 case CMD_REQUEST_COMMAND:
 169                 {
 170                         if (!game_stopped)
 171                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 172                         if (joinAllowed(caller))
 173                                 Join(caller);
 174
 175                         return;  // never fall through to usage
 176                 }
 177
 178                 default:
 179                 case CMD_REQUEST_USAGE:
 180                 {
 181                         sprint(caller, "\nUsage:^3 cmd join\n");
 182                         sprint(caller, "  No arguments required.\n");
 183                         return;
 184                 }
 185         }
 186 }
 187
 188 void ClientCommand_physics(entity caller, float request, float argc)
 189 {
 190         switch (request)
 191         {
 192                 case CMD_REQUEST_COMMAND:
 193                 {
 194                         string command = strtolower(argv(1));
 195
 196                         if (!autocvar_g_physics_clientselect)
 197                         {
 198                                 sprint(caller, "Client physics selection is currently disabled.\n");
 199                                 return;
 200                         }
 201
 202                         if (command == "list" || command == "help")
 203                         {
 204                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 205                                 return;
 206                         }
 207
 208                         if (Physics_Valid(command) || command == "default")
 209                         {
 210                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 211                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 212                                 return;
 213                         }
 214                 }
 215
 216                 default:
 217                         sprint(caller, strcat("Current physics set: ^3", caller.cvar_cl_physics, "\n"));
 218                 case CMD_REQUEST_USAGE:
 219                 {
 220                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 221                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 222                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 223                         return;
 224                 }
 225         }
 226 }
 227
 228 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 229 {
 230         switch (request)
 231         {
 232                 case CMD_REQUEST_COMMAND:
 233                 {
 234                         if (IS_CLIENT(caller))
 235                         {
 236                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 237                                 {
 238                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 239                                         {
 240                                                 if (time < game_starttime) // game is already restarting
 241                                                         return;
 242                                                 if (caller.ready)            // toggle
 243                                                 {
 244                                                         caller.ready = false;
 245                                                         bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 246                                                 }
 247                                                 else
 248                                                 {
 249                                                         caller.ready = true;
 250                                                         bprint(playername(caller, false), "^2 is ready\n");
 251                                                 }
 252
 253                                                 // cannot reset the game while a timeout is active!
 254                                                 if (!timeout_status) ReadyCount();
 255                                         }
 256                                         else
 257                                         {
 258                                                 sprint(caller, "^1Game has already been restarted\n");
 259                                         }
 260                                 }
 261                         }
 262                         return;  // never fall through to usage
 263                 }
 264
 265                 default:
 266                 case CMD_REQUEST_USAGE:
 267                 {
 268                         sprint(caller, "\nUsage:^3 cmd ready\n");
 269                         sprint(caller, "  No arguments required.\n");
 270                         return;
 271                 }
 272         }
 273 }
 274
 275 void ClientCommand_say(entity caller, float request, float argc, string command)
 276 {
 277         switch (request)
 278         {
 279                 case CMD_REQUEST_COMMAND:
 280                 {
 281                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 282                         return;  // never fall through to usage
 283                 }
 284
 285                 default:
 286                 case CMD_REQUEST_USAGE:
 287                 {
 288                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 289                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 290                         return;
 291                 }
 292         }
 293 }
 294
 295 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 296 {
 297         switch (request)
 298         {
 299                 case CMD_REQUEST_COMMAND:
 300                 {
 301                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 302                         return;  // never fall through to usage
 303                 }
 304
 305                 default:
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 309                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 310                         return;
 311                 }
 312         }
 313 }
 314
 315 .bool team_selected;
 316 void ClientCommand_selectteam(entity caller, float request, float argc)
 317 {
 318         switch (request)
 319         {
 320                 case CMD_REQUEST_COMMAND:
 321                 {
 322                         if (argv(1) == "")
 323                         {
 324                                 return;
 325                         }
 326                         if (!IS_CLIENT(caller))
 327                         {
 328                                 return;
 329                         }
 330                         if (!teamplay)
 331                         {
 332                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 333                                 return;
 334                         }
 335                         if (caller.team_forced > 0)
 336                         {
 337                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 338                                 return;
 339                         }
 340                         if (lockteams)
 341                         {
 342                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 343                                 return;
 344                         }
 345                         float selection;
 346                         switch (argv(1))
 347                         {
 348                                 case "red":
 349                                 {
 350                                         selection = NUM_TEAM_1;
 351                                         break;
 352                                 }
 353                                 case "blue":
 354                                 {
 355                                         selection = NUM_TEAM_2;
 356                                         break;
 357                                 }
 358                                 case "yellow":
 359                                 {
 360                                         selection = NUM_TEAM_3;
 361                                         break;
 362                                 }
 363                                 case "pink":
 364                                 {
 365                                         selection = NUM_TEAM_4;
 366                                         break;
 367                                 }
 368                                 case "auto":
 369                                 {
 370                                         selection = (-1);
 371                                         break;
 372                                 }
 373                                 default:
 374                                 {
 375                                         return;
 376                                 }
 377                         }
 378                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 379                         {
 380                                 sprint(caller, "^7You already are on that team.\n");
 381                                 return;
 382                         }
 383                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 384                         {
 385                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 386                                 return;
 387                         }
 388                         if ((selection != -1) && autocvar_g_balance_teams &&
 389                                 autocvar_g_balance_teams_prevent_imbalance)
 390                         {
 391                                 CheckAllowedTeams(caller);
 392                                 GetTeamCounts(caller);
 393                                 if ((BIT(Team_TeamToNumber(selection) - 1) & FindBestTeams(caller, false)) == 0)
 394                                 {
 395                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 396                                         return;
 397                                 }
 398                         }
 399                         ClientKill_TeamChange(caller, selection);
 400                         if (!IS_PLAYER(caller))
 401                         {
 402                                 caller.team_selected = true; // avoids asking again for team selection on join
 403                         }
 404                         return;
 405                 }
 406                 default:
 407                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 408                 case CMD_REQUEST_USAGE:
 409                 {
 410                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 411                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 412                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 413                         return;
 414                 }
 415         }
 416 }
 417
 418 void ClientCommand_selfstuff(entity caller, float request, string command)
 419 {
 420         switch (request)
 421         {
 422                 case CMD_REQUEST_COMMAND:
 423                 {
 424                         if (argv(1) != "")
 425                         {
 426                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 427                                 return;
 428                         }
 429                 }
 430
 431                 default:
 432                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 433                 case CMD_REQUEST_USAGE:
 434                 {
 435                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 436                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 437                         return;
 438                 }
 439         }
 440 }
 441
 442 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 443 {
 444         switch (request)
 445         {
 446                 case CMD_REQUEST_COMMAND:
 447                 {
 448                         if (argv(1) != "")
 449                         {
 450                                 // float tokens;
 451                                 string s;
 452
 453                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 454                                 {
 455                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 456                                         tokenize_console(s);
 457                                 }
 458
 459                                 GetCvars(caller, 1);
 460
 461                                 return;
 462                         }
 463                 }
 464
 465                 default:
 466                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 467                 case CMD_REQUEST_USAGE:
 468                 {
 469                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 470                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 471                         return;
 472                 }
 473         }
 474 }
 475
 476 void ClientCommand_spectate(entity caller, float request)
 477 {
 478         switch (request)
 479         {
 480                 case CMD_REQUEST_COMMAND:
 481                 {
 482                         if (!intermission_running && IS_CLIENT(caller))
 483                         {
 484                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 485                                 {
 486                                         entity client = GetFilteredEntity(argv(1));
 487                                         int spec_accepted = VerifyClientEntity(client, false, false);
 488                                         if(spec_accepted > 0 && IS_PLAYER(client))
 489                                         {
 490                                                 if(Spectate(caller, client))
 491                                                         return; // fall back to regular handling
 492                                         }
 493                                 }
 494
 495                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 496
 497                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 498
 499                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 500                                 if (autocvar_sv_spectate == 1)
 501                                         ClientKill_TeamChange(caller, -2); // observe
 502                         }
 503                         return; // never fall through to usage
 504                 }
 505
 506                 default:
 507                 case CMD_REQUEST_USAGE:
 508                 {
 509                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 510                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 511                         return;
 512                 }
 513         }
 514 }
 515
 516 void ClientCommand_suggestmap(entity caller, float request, float argc)
 517 {
 518         switch (request)
 519         {
 520                 case CMD_REQUEST_COMMAND:
 521                 {
 522                         if (argv(1) != "")
 523                         {
 524                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 525                                 return;
 526                         }
 527                 }
 528
 529                 default:
 530                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 531                 case CMD_REQUEST_USAGE:
 532                 {
 533                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 534                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 535                         return;
 536                 }
 537         }
 538 }
 539
 540 void ClientCommand_tell(entity caller, float request, float argc, string command)
 541 {
 542         switch (request)
 543         {
 544                 case CMD_REQUEST_COMMAND:
 545                 {
 546                         if (argc >= 3)
 547                         {
 548                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 549                                 {
 550                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 551                                         return;
 552                                 }
 553
 554                                 entity tell_to = GetIndexedEntity(argc, 1);
 555                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 556
 557                                 if (tell_accepted > 0)   // the target is a real client
 558                                 {
 559                                         if (tell_to != caller) // and we're allowed to send to them :D
 560                                         {
 561                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 562                                                 // In this case when the player name contains utf8 chars
 563                                                 // the message gets partially trimmed in the beginning.
 564                                                 // Potentially this bug affects any substring call that uses
 565                                                 // argv_start_index and argv_end_index.
 566
 567                                                 string utf8_enable_save = cvar_string("utf8_enable");
 568                                                 cvar_set("utf8_enable", "0");
 569                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 570                                                 cvar_set("utf8_enable", utf8_enable_save);
 571
 572                                                 Say(caller, false, tell_to, msg, true);
 573                                                 return;
 574                                         }
 575                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 576                                 }
 577                                 else if (argv(1) == "#0")
 578                                 {
 579                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 580                                         return;
 581                                 }
 582                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 583                         }
 584                 }
 585
 586                 default:
 587                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 588                 case CMD_REQUEST_USAGE:
 589                 {
 590                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 591                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 592                         return;
 593                 }
 594         }
 595 }
 596
 597 void ClientCommand_voice(entity caller, float request, float argc, string command)
 598 {
 599         switch (request)
 600         {
 601                 case CMD_REQUEST_COMMAND:
 602                 {
 603                         if (argv(1) != "")
 604                         {
 605                                 entity e = GetVoiceMessage(argv(1));
 606                                 if (!e)
 607                                 {
 608                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 609                                         return;
 610                                 }
 611                                 if (argc >= 3) VoiceMessage(caller, e, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 612                                 else VoiceMessage(caller, e, "");
 613
 614                                 return;
 615                         }
 616                 }
 617
 618                 default:
 619                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 620                 case CMD_REQUEST_USAGE:
 621                 {
 622                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 623                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 624                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 625                         return;
 626                 }
 627         }
 628 }
 629
 630 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 631 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 632 void ClientCommand_(entity caller, float request)
 633 {
 634     switch(request)
 635     {
 636         case CMD_REQUEST_COMMAND:
 637         {
 638
 639             return; // never fall through to usage
 640         }
 641
 642         default:
 643         case CMD_REQUEST_USAGE:
 644         {
 645             sprint(caller, "\nUsage:^3 cmd \n");
 646             sprint(caller, "  No arguments required.\n");
 647             return;
 648         }
 649     }
 650 }
 651 */
 652
 653
 654 // =====================================
 655 //  Macro system for networked commands
 656 // =====================================
 657
 658 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 659 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 660         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 661         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 662         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 663         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 664         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 665         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 666         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 667         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 668         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 669         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 670         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 671         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 672         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 673         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 674         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 675         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 676         /* nothing */
 677
 678 void ClientCommand_macro_help(entity caller)
 679 {
 680         #define CLIENT_COMMAND(name, function, description) \
 681                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 682
 683         CLIENT_COMMANDS(NULL, 0, 0, "");
 684 #undef CLIENT_COMMAND
 685 }
 686
 687 float ClientCommand_macro_command(float argc, entity caller, string command)
 688 {
 689         #define CLIENT_COMMAND(name, function, description) \
 690                 { if (name == strtolower(argv(0))) { function; return true; } }
 691
 692         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 693 #undef CLIENT_COMMAND
 694
 695         return false;
 696 }
 697
 698 float ClientCommand_macro_usage(float argc, entity caller)
 699 {
 700         #define CLIENT_COMMAND(name, function, description) \
 701                 { if (name == strtolower(argv(1))) { function; return true; } }
 702
 703         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 704 #undef CLIENT_COMMAND
 705
 706         return false;
 707 }
 708
 709 void ClientCommand_macro_write_aliases(float fh)
 710 {
 711         #define CLIENT_COMMAND(name, function, description) \
 712                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 713
 714         CLIENT_COMMANDS(NULL, 0, 0, "");
 715 #undef CLIENT_COMMAND
 716 }
 717
 718 // ======================================
 719 //  Main Function Called By Engine (cmd)
 720 // ======================================
 721 // If this function exists, server game code parses clientcommand before the engine code gets it.
 722
 723 void SV_ParseClientCommand(entity this, string command)
 724 {
 725         // If invalid UTF-8, don't even parse it
 726         string command2 = "";
 727         float len = strlen(command);
 728         float i;
 729         for (i = 0; i < len; ++i)
 730                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 731         if (command != command2) return;
 732
 733         // if we're banned, don't even parse the command
 734         if (Ban_MaybeEnforceBanOnce(this)) return;
 735
 736         float argc = tokenize_console(command);
 737
 738         // Guide for working with argc arguments by example:
 739         // argc:   1    - 2      - 3     - 4
 740         // argv:   0    - 1      - 2     - 3
 741         // cmd     vote - master - login - password
 742
 743         // for floodcheck
 744         switch (strtolower(argv(0)))
 745         {
 746                 // exempt commands which are not subject to floodcheck
 747                 case "begin": break;                               // handled by engine in host_cmd.c
 748                 case "download": break;                            // handled by engine in cl_parse.c
 749                 case "mv_getpicture": break;                       // handled by server in this file
 750                 case "pause": break;                               // handled by engine in host_cmd.c
 751                 case "prespawn": break;                            // handled by engine in host_cmd.c
 752                 case "sentcvar": break;                            // handled by server in this file
 753                 case "spawn": break;                               // handled by engine in host_cmd.c
 754                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 755
 756                 default:
 757                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 758                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 759         }
 760
 761         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 762         if (argv(0) == "help")
 763         {
 764                 if (argc == 1)
 765                 {
 766                         sprint(this, "\nClient networked commands:\n");
 767                         ClientCommand_macro_help(this);
 768
 769                         sprint(this, "\nCommon networked commands:\n");
 770                         CommonCommand_macro_help(this);
 771
 772                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 773                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 774                         return;
 775                 }
 776                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 777                 {
 778                         return;
 779                 }
 780                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 781                 {
 782                         return;
 783                 }
 784         }
 785         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 786         {
 787                 return;  // handled by a mutator
 788         }
 789         else if (CheatCommand(this, argc))
 790         {
 791                 return;  // handled by server/cheats.qc
 792         }
 793         else if (CommonCommand_macro_command(argc, this, command))
 794         {
 795                 return;                                          // handled by server/command/common.qc
 796         }
 797         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 798         {
 799                 return;                                          // handled by one of the above ClientCommand_* functions
 800         }
 801         else
 802         {
 803                 clientcommand(this, command);
 804         }
 805 }