qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../campaign.qh"
  12 #include "../cheats.qh"
  13 #include "../client.qh"
  14 #include "../clientkill.qh"
  15 #include "../player.qh"
  16 #include "../ipban.qh"
  17 #include "../mapvoting.qh"
  18 #include "../scores.qh"
  19 #include "../teamplay.qh"
  20
  21 #include <server/mutators/_mod.qh>
  22 #include <common/gamemodes/_mod.qh>
  23
  24 #ifdef SVQC
  25         #include <common/vehicles/all.qh>
  26 #endif
  27
  28 #include <common/constants.qh>
  29 #include <common/deathtypes/all.qh>
  30 #include <common/effects/all.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/notifications/all.qh>
  33 #include <common/physics/player.qh>
  34 #include <common/teams.qh>
  35 #include <common/util.qh>
  36 #include <common/mapobjects/triggers.qh>
  37
  38 #include <common/minigames/sv_minigames.qh>
  39
  40 #include <common/monsters/_mod.qh>
  41 #include <common/monsters/sv_spawn.qh>
  42 #include <common/monsters/sv_monsters.qh>
  43
  44 #include <lib/warpzone/common.qh>
  45
  46 // =========================================================
  47 //  Server side networked commands code, reworked by Samual
  48 //  Last updated: December 28th, 2011
  49 // =========================================================
  50
  51 bool SV_ParseClientCommand_floodcheck(entity this)
  52 {
  53         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  54
  55         if (!timeout_status)  // not while paused
  56         {
  57                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  58                 {
  59                         store.cmd_floodcount += 1;
  60                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  61                 }
  62                 else
  63                 {
  64                         store.cmd_floodtime = time;
  65                         store.cmd_floodcount = 1;
  66                 }
  67         }
  68         return true;  // continue, as we're not flooding yet
  69 }
  70
  71
  72 // =======================
  73 //  Command Sub-Functions
  74 // =======================
  75
  76 void ClientCommand_autoswitch(entity caller, int request, int argc)
  77 {
  78         switch (request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if (argv(1) != "")
  83                         {
  84                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  85                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  86                                 return;
  87                         }
  88                 }
  89
  90                 default:
  91                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  92                 case CMD_REQUEST_USAGE:
  93                 {
  94                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  95                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  96                         return;
  97                 }
  98         }
  99 }
 100
 101 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 102 {
 103         switch (request)
 104         {
 105                 case CMD_REQUEST_COMMAND:
 106                 {
 107                         if (argv(1) != "")
 108                         {
 109                                 if (IS_CLIENT(caller))
 110                                 {
 111                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 112
 113                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 114                                         {
 115                                                 CS(caller).version_mismatch = true;
 116                                                 ClientKill_TeamChange(caller, -2);  // observe
 117                                         }
 118                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 119                                         {
 120                                                 // JoinBestTeam(caller, false, true);
 121                                         }
 122                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 123                                         {
 124                                                 TRANSMUTE(Observer, caller);  // really?
 125                                                 stuffcmd(caller, "menu_showteamselect\n");
 126                                         }
 127                                 }
 128
 129                                 return;
 130                         }
 131                 }
 132
 133                 default:
 134                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 135                 case CMD_REQUEST_USAGE:
 136                 {
 137                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 138                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 139                         return;
 140                 }
 141         }
 142 }
 143
 144 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 145 {
 146         switch (request)
 147         {
 148                 case CMD_REQUEST_COMMAND:
 149                 {
 150                         if (argv(1) != "")
 151                         {
 152                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 153
 154                                 return;
 155                         }
 156                 }
 157
 158                 default:
 159                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 160                 case CMD_REQUEST_USAGE:
 161                 {
 162                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 163                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 164                         return;
 165                 }
 166         }
 167 }
 168
 169 void ClientCommand_join(entity caller, int request)
 170 {
 171         switch (request)
 172         {
 173                 case CMD_REQUEST_COMMAND:
 174                 {
 175                         if (!game_stopped)
 176                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 177                         if (joinAllowed(caller))
 178                                 Join(caller);
 179
 180                         return;  // never fall through to usage
 181                 }
 182
 183                 default:
 184                 case CMD_REQUEST_USAGE:
 185                 {
 186                         sprint(caller, "\nUsage:^3 cmd join\n");
 187                         sprint(caller, "  No arguments required.\n");
 188                         return;
 189                 }
 190         }
 191 }
 192
 193 void ClientCommand_physics(entity caller, int request, int argc)
 194 {
 195         switch (request)
 196         {
 197                 case CMD_REQUEST_COMMAND:
 198                 {
 199                         string command = strtolower(argv(1));
 200
 201                         if (!autocvar_g_physics_clientselect)
 202                         {
 203                                 sprint(caller, "Client physics selection is currently disabled.\n");
 204                                 return;
 205                         }
 206
 207                         if (command == "list" || command == "help")
 208                         {
 209                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 210                                 return;
 211                         }
 212
 213                         if (Physics_Valid(command) || command == "default")
 214                         {
 215                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 216                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 217                                 return;
 218                         }
 219                 }
 220
 221                 default:
 222                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 223                 case CMD_REQUEST_USAGE:
 224                 {
 225                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 226                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 227                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 228                         return;
 229                 }
 230         }
 231 }
 232
 233 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 234 {
 235         switch (request)
 236         {
 237                 case CMD_REQUEST_COMMAND:
 238                 {
 239                         if (IS_CLIENT(caller))
 240                         {
 241                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 242                                 {
 243                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 244                                         {
 245                                                 if (time < game_starttime) // game is already restarting
 246                                                         return;
 247                                                 if (caller.ready)            // toggle
 248                                                 {
 249                                                         caller.ready = false;
 250                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 251                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 252                                                 }
 253                                                 else
 254                                                 {
 255                                                         caller.ready = true;
 256                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 257                                                                 bprint(playername(caller, false), "^2 is ready\n");
 258                                                 }
 259
 260                                                 // cannot reset the game while a timeout is active!
 261                                                 if (!timeout_status) ReadyCount();
 262                                         }
 263                                         else
 264                                         {
 265                                                 sprint(caller, "^1Game has already been restarted\n");
 266                                         }
 267                                 }
 268                         }
 269                         return;  // never fall through to usage
 270                 }
 271
 272                 default:
 273                 case CMD_REQUEST_USAGE:
 274                 {
 275                         sprint(caller, "\nUsage:^3 cmd ready\n");
 276                         sprint(caller, "  No arguments required.\n");
 277                         return;
 278                 }
 279         }
 280 }
 281
 282 void ClientCommand_say(entity caller, int request, int argc, string command)
 283 {
 284         switch (request)
 285         {
 286                 case CMD_REQUEST_COMMAND:
 287                 {
 288                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 289                         return;  // never fall through to usage
 290                 }
 291
 292                 default:
 293                 case CMD_REQUEST_USAGE:
 294                 {
 295                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 296                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 297                         return;
 298                 }
 299         }
 300 }
 301
 302 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 303 {
 304         switch (request)
 305         {
 306                 case CMD_REQUEST_COMMAND:
 307                 {
 308                         if (argc >= 2)
 309                         {
 310                                 string _classname = string_null;
 311                                 if (!IS_PLAYER(caller) && caller.caplayer)
 312                                 {
 313                                         // CA: make work team chat for killed players
 314                                         _classname = caller.classname;
 315                                         caller.classname = STR_PLAYER;
 316                                 }
 317
 318                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 319                                 if (_classname)
 320                                         caller.classname = _classname;
 321                         }
 322                         return;  // never fall through to usage
 323                 }
 324
 325                 default:
 326                 case CMD_REQUEST_USAGE:
 327                 {
 328                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 329                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 330                         return;
 331                 }
 332         }
 333 }
 334
 335 .bool team_selected;
 336 void ClientCommand_selectteam(entity caller, int request, int argc)
 337 {
 338         switch (request)
 339         {
 340                 case CMD_REQUEST_COMMAND:
 341                 {
 342                         if (argv(1) == "")
 343                         {
 344                                 return;
 345                         }
 346                         if (!IS_CLIENT(caller))
 347                         {
 348                                 return;
 349                         }
 350                         if (!teamplay)
 351                         {
 352                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 353                                 return;
 354                         }
 355                         if (Player_GetForcedTeamIndex(caller) > 0)
 356                         {
 357                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 358                                 return;
 359                         }
 360                         if (lockteams)
 361                         {
 362                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 363                                 return;
 364                         }
 365                         float selection;
 366                         switch (argv(1))
 367                         {
 368                                 case "red":
 369                                 {
 370                                         selection = NUM_TEAM_1;
 371                                         break;
 372                                 }
 373                                 case "blue":
 374                                 {
 375                                         selection = NUM_TEAM_2;
 376                                         break;
 377                                 }
 378                                 case "yellow":
 379                                 {
 380                                         selection = NUM_TEAM_3;
 381                                         break;
 382                                 }
 383                                 case "pink":
 384                                 {
 385                                         selection = NUM_TEAM_4;
 386                                         break;
 387                                 }
 388                                 case "auto":
 389                                 {
 390                                         selection = (-1);
 391                                         break;
 392                                 }
 393                                 default:
 394                                 {
 395                                         return;
 396                                 }
 397                         }
 398                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 399                         {
 400                                 sprint(caller, "^7You already are on that team.\n");
 401                                 return;
 402                         }
 403                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 404                         {
 405                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 406                                 return;
 407                         }
 408                         if ((selection != -1) && autocvar_g_balance_teams &&
 409                                 autocvar_g_balance_teams_prevent_imbalance)
 410                         {
 411                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 412                                 TeamBalance_GetTeamCounts(balance, caller);
 413                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 414                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 415                                 {
 416                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 417                                         TeamBalance_Destroy(balance);
 418                                         return;
 419                                 }
 420                                 TeamBalance_Destroy(balance);
 421                         }
 422                         ClientKill_TeamChange(caller, selection);
 423                         if (!IS_PLAYER(caller))
 424                         {
 425                                 caller.team_selected = true; // avoids asking again for team selection on join
 426                         }
 427                         return;
 428                 }
 429                 default:
 430                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 431                 case CMD_REQUEST_USAGE:
 432                 {
 433                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 434                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 435                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 436                         return;
 437                 }
 438         }
 439 }
 440
 441 void ClientCommand_selfstuff(entity caller, int request, string command)
 442 {
 443         switch (request)
 444         {
 445                 case CMD_REQUEST_COMMAND:
 446                 {
 447                         if (argv(1) != "")
 448                         {
 449                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 450                                 return;
 451                         }
 452                 }
 453
 454                 default:
 455                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 456                 case CMD_REQUEST_USAGE:
 457                 {
 458                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 459                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 460                         return;
 461                 }
 462         }
 463 }
 464
 465 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 466 {
 467         switch (request)
 468         {
 469                 case CMD_REQUEST_COMMAND:
 470                 {
 471                         if (argv(1) != "")
 472                         {
 473                                 // float tokens;
 474                                 string s;
 475
 476                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 477                                 {
 478                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 479                                         tokenize_console(s);
 480                                 }
 481
 482                                 GetCvars(caller, CS(caller), 1);
 483
 484                                 return;
 485                         }
 486                 }
 487
 488                 default:
 489                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 490                 case CMD_REQUEST_USAGE:
 491                 {
 492                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 493                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 494                         return;
 495                 }
 496         }
 497 }
 498
 499 void ClientCommand_spectate(entity caller, int request)
 500 {
 501         switch (request)
 502         {
 503                 case CMD_REQUEST_COMMAND:
 504                 {
 505                         if (!intermission_running && IS_CLIENT(caller))
 506                         {
 507                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 508                                 {
 509                                         entity client = GetFilteredEntity(argv(1));
 510                                         int spec_accepted = VerifyClientEntity(client, false, false);
 511                                         if(spec_accepted > 0 && IS_PLAYER(client))
 512                                         {
 513                                                 if(Spectate(caller, client))
 514                                                         return; // fall back to regular handling
 515                                         }
 516                                 }
 517
 518                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 519
 520                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 521
 522                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 523                                 if (autocvar_sv_spectate == 1)
 524                                         ClientKill_TeamChange(caller, -2); // observe
 525                         }
 526                         return; // never fall through to usage
 527                 }
 528
 529                 default:
 530                 case CMD_REQUEST_USAGE:
 531                 {
 532                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 533                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 534                         return;
 535                 }
 536         }
 537 }
 538
 539 void ClientCommand_suggestmap(entity caller, int request, int argc)
 540 {
 541         switch (request)
 542         {
 543                 case CMD_REQUEST_COMMAND:
 544                 {
 545                         if (argv(1) != "")
 546                         {
 547                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 548                                 return;
 549                         }
 550                 }
 551
 552                 default:
 553                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 554                 case CMD_REQUEST_USAGE:
 555                 {
 556                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 557                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 558                         return;
 559                 }
 560         }
 561 }
 562
 563 void ClientCommand_tell(entity caller, int request, int argc, string command)
 564 {
 565         switch (request)
 566         {
 567                 case CMD_REQUEST_COMMAND:
 568                 {
 569                         if (argc >= 3)
 570                         {
 571                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 572                                 {
 573                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 574                                         return;
 575                                 }
 576
 577                                 entity tell_to = GetIndexedEntity(argc, 1);
 578                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 579
 580                                 if (tell_accepted > 0)   // the target is a real client
 581                                 {
 582                                         if (tell_to != caller) // and we're allowed to send to them :D
 583                                         {
 584                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 585                                                 // In this case when the player name contains utf8 chars
 586                                                 // the message gets partially trimmed in the beginning.
 587                                                 // Potentially this bug affects any substring call that uses
 588                                                 // argv_start_index and argv_end_index.
 589
 590                                                 string utf8_enable_save = cvar_string("utf8_enable");
 591                                                 cvar_set("utf8_enable", "0");
 592                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 593                                                 cvar_set("utf8_enable", utf8_enable_save);
 594
 595                                                 Say(caller, false, tell_to, msg, true);
 596                                                 return;
 597                                         }
 598                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 599                                 }
 600                                 else if (argv(1) == "#0")
 601                                 {
 602                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 603                                         return;
 604                                 }
 605                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 606                         }
 607                 }
 608
 609                 default:
 610                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 611                 case CMD_REQUEST_USAGE:
 612                 {
 613                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 614                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 615                         return;
 616                 }
 617         }
 618 }
 619
 620 void ClientCommand_voice(entity caller, int request, int argc, string command)
 621 {
 622         switch (request)
 623         {
 624                 case CMD_REQUEST_COMMAND:
 625                 {
 626                         if (argv(1) != "")
 627                         {
 628                                 entity e = GetVoiceMessage(argv(1));
 629                                 if (!e)
 630                                 {
 631                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 632                                         return;
 633                                 }
 634                                 string msg = "";
 635                                 if (argc >= 3)
 636                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 637                                 VoiceMessage(caller, e, msg);
 638
 639                                 return;
 640                         }
 641                 }
 642
 643                 default:
 644                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 645                 case CMD_REQUEST_USAGE:
 646                 {
 647                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 648                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 649                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 650                         return;
 651                 }
 652         }
 653 }
 654
 655 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 656 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 657 void ClientCommand_(entity caller, int request)
 658 {
 659     switch(request)
 660     {
 661         case CMD_REQUEST_COMMAND:
 662         {
 663
 664             return; // never fall through to usage
 665         }
 666
 667         default:
 668         case CMD_REQUEST_USAGE:
 669         {
 670             sprint(caller, "\nUsage:^3 cmd \n");
 671             sprint(caller, "  No arguments required.\n");
 672             return;
 673         }
 674     }
 675 }
 676 */
 677
 678
 679 // =====================================
 680 //  Macro system for networked commands
 681 // =====================================
 682
 683 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 684 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 685         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 686         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 687         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 688         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 689         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 690         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 691         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 692         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 693         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 694         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 695         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 696         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 697         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 698         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 699         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 700         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 701         /* nothing */
 702
 703 void ClientCommand_macro_help(entity caller)
 704 {
 705         #define CLIENT_COMMAND(name, function, description) \
 706                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 707
 708         CLIENT_COMMANDS(NULL, 0, 0, "");
 709 #undef CLIENT_COMMAND
 710 }
 711
 712 float ClientCommand_macro_command(int argc, entity caller, string command)
 713 {
 714         #define CLIENT_COMMAND(name, function, description) \
 715                 { if (name == strtolower(argv(0))) { function; return true; } }
 716
 717         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 718 #undef CLIENT_COMMAND
 719
 720         return false;
 721 }
 722
 723 float ClientCommand_macro_usage(int argc, entity caller)
 724 {
 725         #define CLIENT_COMMAND(name, function, description) \
 726                 { if (name == strtolower(argv(1))) { function; return true; } }
 727
 728         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 729 #undef CLIENT_COMMAND
 730
 731         return false;
 732 }
 733
 734 void ClientCommand_macro_write_aliases(float fh)
 735 {
 736         #define CLIENT_COMMAND(name, function, description) \
 737                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 738
 739         CLIENT_COMMANDS(NULL, 0, 0, "");
 740 #undef CLIENT_COMMAND
 741 }
 742
 743 // ======================================
 744 //  Main Function Called By Engine (cmd)
 745 // ======================================
 746 // If this function exists, server game code parses clientcommand before the engine code gets it.
 747
 748 void SV_ParseClientCommand(entity this, string command)
 749 {
 750         // If invalid UTF-8, don't even parse it
 751         string command2 = "";
 752         float len = strlen(command);
 753         float i;
 754         for (i = 0; i < len; ++i)
 755                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 756         if (command != command2) return;
 757
 758         // if we're banned, don't even parse the command
 759         if (Ban_MaybeEnforceBanOnce(this)) return;
 760
 761         int argc = tokenize_console(command);
 762
 763         // Guide for working with argc arguments by example:
 764         // argc:   1    - 2      - 3     - 4
 765         // argv:   0    - 1      - 2     - 3
 766         // cmd     vote - master - login - password
 767
 768         // for floodcheck
 769         switch (strtolower(argv(0)))
 770         {
 771                 // exempt commands which are not subject to floodcheck
 772                 case "begin": break;                               // handled by engine in host_cmd.c
 773                 case "download": break;                            // handled by engine in cl_parse.c
 774                 case "mv_getpicture": break;                       // handled by server in this file
 775                 case "pause": break;                               // handled by engine in host_cmd.c
 776                 case "prespawn": break;                            // handled by engine in host_cmd.c
 777                 case "sentcvar": break;                            // handled by server in this file
 778                 case "spawn": break;                               // handled by engine in host_cmd.c
 779                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 780
 781                 default:
 782                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 783                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 784         }
 785
 786         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 787         if (argv(0) == "help")
 788         {
 789                 if (argc == 1)
 790                 {
 791                         sprint(this, "\nClient networked commands:\n");
 792                         ClientCommand_macro_help(this);
 793
 794                         sprint(this, "\nCommon networked commands:\n");
 795                         CommonCommand_macro_help(this);
 796
 797                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 798                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 799                         return;
 800                 }
 801                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 802                 {
 803                         return;
 804                 }
 805                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 806                 {
 807                         return;
 808                 }
 809         }
 810         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 811         {
 812                 return;  // handled by a mutator
 813         }
 814         else if (CheatCommand(this, argc))
 815         {
 816                 return;  // handled by server/cheats.qc
 817         }
 818         else if (CommonCommand_macro_command(argc, this, command))
 819         {
 820                 return;                                          // handled by server/command/common.qc
 821         }
 822         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 823         {
 824                 return;                                          // handled by one of the above ClientCommand_* functions
 825         }
 826         else
 827         {
 828                 clientcommand(this, command);
 829         }
 830 }