qcsrc/server/command/cmd.qc

   1 #include "../../common/command/command.qh"
   2 #include "cmd.qh"
   3 #include "../_all.qh"
   4
   5 #include "common.qh"
   6 #include "vote.qh"
   7
   8 #include "../campaign.qh"
   9 #include "../cheats.qh"
  10 #include "../cl_player.qh"
  11 #include "../ipban.qh"
  12 #include "../mapvoting.qh"
  13 #include "../scores.qh"
  14 #include "../teamplay.qh"
  15
  16 #include "../mutators/mutators_include.qh"
  17
  18 #ifdef SVQC
  19         #include "../vehicles/vehicle.qh"
  20 #endif
  21
  22 #include "../../common/constants.qh"
  23 #include "../../common/deathtypes.qh"
  24 #include "../../common/mapinfo.qh"
  25 #include "../../common/notifications.qh"
  26 #include "../../common/teams.qh"
  27 #include "../../common/util.qh"
  28
  29 #include "../../common/monsters/all.qh"
  30 #include "../../common/monsters/spawn.qh"
  31 #include "../../common/monsters/sv_monsters.qh"
  32
  33 #include "../../warpzonelib/common.qh"
  34
  35 void ClientKill_TeamChange (float targetteam); // 0 = don't change, -1 = auto, -2 = spec
  36
  37 // =========================================================
  38 //  Server side networked commands code, reworked by Samual
  39 //  Last updated: December 28th, 2011
  40 // =========================================================
  41
  42 float SV_ParseClientCommand_floodcheck()
  43 {
  44         if (!timeout_status) // not while paused
  45         {
  46                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  47                 {
  48                         self.cmd_floodcount += 1;
  49                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return false; } // too much spam, halt
  50                 }
  51                 else
  52                 {
  53                         self.cmd_floodtime = time;
  54                         self.cmd_floodcount = 1;
  55                 }
  56         }
  57         return true; // continue, as we're not flooding yet
  58 }
  59
  60
  61 // =======================
  62 //  Command Sub-Functions
  63 // =======================
  64
  65 void ClientCommand_autoswitch(float request, float argc)
  66 {
  67         switch(request)
  68         {
  69                 case CMD_REQUEST_COMMAND:
  70                 {
  71                         if(argv(1) != "")
  72                         {
  73                                 self.autoswitch = InterpretBoolean(argv(1));
  74                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  75                                 return;
  76                         }
  77                 }
  78
  79                 default:
  80                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  81                 case CMD_REQUEST_USAGE:
  82                 {
  83                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  84                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  85                         return;
  86                 }
  87         }
  88 }
  89
  90 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  91 {
  92         switch(request)
  93         {
  94                 case CMD_REQUEST_COMMAND:
  95                 {
  96                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  97                         self.checkfail = 1;
  98                         return; // never fall through to usage
  99                 }
 100
 101                 default:
 102                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
 103                 case CMD_REQUEST_USAGE:
 104                 {
 105                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
 106                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
 107                         return;
 108                 }
 109         }
 110 }
 111
 112 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
 113 {
 114         switch(request)
 115         {
 116                 case CMD_REQUEST_COMMAND:
 117                 {
 118                         if(argv(1) != "")
 119                         {
 120                                 if(IS_CLIENT(self))
 121                                 {
 122                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 123
 124                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
 125                                         {
 126                                                 self.version_mismatch = 1;
 127                                                 ClientKill_TeamChange(-2); // observe
 128                                         }
 129                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
 130                                         {
 131                                                 //JoinBestTeam(self, false, true);
 132                                         }
 133                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
 134                                         {
 135                                                 self.classname = "observer"; // really?
 136                                                 stuffcmd(self, "menu_showteamselect\n");
 137                                         }
 138                                 }
 139
 140                                 return;
 141                         }
 142                 }
 143
 144                 default:
 145                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 146                 case CMD_REQUEST_USAGE:
 147                 {
 148                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 149                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 150                         return;
 151                 }
 152         }
 153 }
 154
 155 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 156 {
 157         switch(request)
 158         {
 159                 case CMD_REQUEST_COMMAND:
 160                 {
 161                         if(argv(1) != "")
 162                         {
 163                                 if(intermission_running)
 164                                         MapVote_SendPicture(stof(argv(1)));
 165
 166                                 return;
 167                         }
 168                 }
 169
 170                 default:
 171                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 172                 case CMD_REQUEST_USAGE:
 173                 {
 174                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 175                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 176                         return;
 177                 }
 178         }
 179 }
 180
 181 void ClientCommand_join(float request)
 182 {
 183         switch(request)
 184         {
 185                 case CMD_REQUEST_COMMAND:
 186                 {
 187                         if(IS_CLIENT(self))
 188                         {
 189                                 if(!IS_PLAYER(self) && !lockteams && !gameover)
 190                                 {
 191                                         if(self.caplayer)
 192                                                 return;
 193                                         if(nJoinAllowed(self))
 194                                         {
 195                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 196
 197                                                 self.classname = "player";
 198                                                 PlayerScore_Clear(self);
 199                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 200                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 201                                                 PutClientInServer();
 202                                         }
 203                                         else
 204                                         {
 205                                                 //player may not join because of g_maxplayers is set
 206                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 207                                         }
 208                                 }
 209                         }
 210                         return; // never fall through to usage
 211                 }
 212
 213                 default:
 214                 case CMD_REQUEST_USAGE:
 215                 {
 216                         sprint(self, "\nUsage:^3 cmd join\n");
 217                         sprint(self, "  No arguments required.\n");
 218                         return;
 219                 }
 220         }
 221 }
 222
 223 void ClientCommand_mobedit(float request, float argc)
 224 {
 225         switch(request)
 226         {
 227                 case CMD_REQUEST_COMMAND:
 228                 {
 229                         if(argv(1) && argv(2))
 230                         {
 231                                 makevectors(self.v_angle);
 232                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 233
 234                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 235                                 if(trace_ent.flags & FL_MONSTER)
 236                                 {
 237                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 238                                         switch(argv(1))
 239                                         {
 240                                                 case "skin":
 241                                                 {
 242                                                         if(trace_ent.monsterid != MON_MAGE)
 243                                                                 trace_ent.skin = stof(argv(2));
 244                                                         return;
 245                                                 }
 246                                                 case "movetarget":
 247                                                 {
 248                                                         trace_ent.monster_moveflags = stof(argv(2));
 249                                                         return;
 250                                                 }
 251                                         }
 252                                 }
 253                         }
 254                 }
 255                 default:
 256                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 257                 case CMD_REQUEST_USAGE:
 258                 {
 259                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 260                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 261                         sprint(self, "  Aim at your monster to edit its properties.\n");
 262                         return;
 263                 }
 264         }
 265 }
 266
 267 void ClientCommand_mobkill(float request)
 268 {
 269         switch(request)
 270         {
 271                 case CMD_REQUEST_COMMAND:
 272                 {
 273                         makevectors(self.v_angle);
 274                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 275
 276                         if(trace_ent.flags & FL_MONSTER)
 277                         {
 278                                 if(trace_ent.realowner != self)
 279                                 {
 280                                         sprint(self, "That monster does not belong to you.\n");
 281                                         return;
 282                                 }
 283                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 284                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 285                                 return;
 286                         }
 287                 }
 288
 289                 default:
 290                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 291                 case CMD_REQUEST_USAGE:
 292                 {
 293                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 294                         sprint(self, "  Aim at your monster to kill it.\n");
 295                         return;
 296                 }
 297         }
 298 }
 299
 300 void ClientCommand_mobspawn(float request, float argc)
 301 {
 302         switch(request)
 303         {
 304                 case CMD_REQUEST_COMMAND:
 305                 {
 306                         entity e;
 307                         string tospawn;
 308                         float moveflag, monstercount = 0;
 309
 310                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 311                         tospawn = strtolower(argv(1));
 312
 313                         if(tospawn == "list")
 314                         {
 315                                 sprint(self, monsterlist_reply);
 316                                 return;
 317                         }
 318
 319                         FOR_EACH_MONSTER(e)
 320                         {
 321                                 if(e.realowner == self)
 322                                         ++monstercount;
 323                         }
 324
 325                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 326                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 327                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 328                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 329                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 330                         else if(self.frozen) { sprint(self, "You can't spawn monsters while frozen.\n"); return; }
 331                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 332                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 333                         else if(monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 334                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 335                         else if(tospawn != "")
 336                         {
 337                                 float found = 0, i;
 338                                 entity mon;
 339
 340                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 341                                 {
 342                                         mon = get_monsterinfo(i);
 343                                         if(mon.netname == tospawn)
 344                                         {
 345                                                 found = true;
 346                                                 break;
 347                                         }
 348                                 }
 349
 350                                 if(found || tospawn == "random")
 351                                 {
 352                                         totalspawned += 1;
 353
 354                                         makevectors(self.v_angle);
 355                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, true, self);
 356                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 357
 358                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, false, false, moveflag);
 359
 360                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 361
 362                                         return;
 363                                 }
 364                         }
 365                 }
 366
 367                 default:
 368                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 369                 case CMD_REQUEST_USAGE:
 370                 {
 371                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 372                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 373                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 374                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 375                         return;
 376                 }
 377         }
 378 }
 379
 380 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 381 {
 382         switch(request)
 383         {
 384                 case CMD_REQUEST_COMMAND:
 385                 {
 386                         if(IS_CLIENT(self))
 387                         {
 388                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 389                                 {
 390                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 391                                         {
 392                                                 if(time < game_starttime) // game is already restarting
 393                                                         return;
 394                                                 if (self.ready) // toggle
 395                                                 {
 396                                                         self.ready = false;
 397                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 398                                                 }
 399                                                 else
 400                                                 {
 401                                                         self.ready = true;
 402                                                         bprint(self.netname, "^2 is ready\n");
 403                                                 }
 404
 405                                                 // cannot reset the game while a timeout is active!
 406                                                 if (!timeout_status)
 407                                                         ReadyCount();
 408                                         } else {
 409                                                 sprint(self, "^1Game has already been restarted\n");
 410                                         }
 411                                 }
 412                         }
 413                         return; // never fall through to usage
 414                 }
 415
 416                 default:
 417                 case CMD_REQUEST_USAGE:
 418                 {
 419                         sprint(self, "\nUsage:^3 cmd ready\n");
 420                         sprint(self, "  No arguments required.\n");
 421                         return;
 422                 }
 423         }
 424 }
 425
 426 void ClientCommand_say(float request, float argc, string command)
 427 {
 428         switch(request)
 429         {
 430                 case CMD_REQUEST_COMMAND:
 431                 {
 432                         if(argc >= 2) { Say(self, false, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 433                         return; // never fall through to usage
 434                 }
 435
 436                 default:
 437                 case CMD_REQUEST_USAGE:
 438                 {
 439                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 440                         sprint(self, "  Where 'message' is the string of text to say.\n");
 441                         return;
 442                 }
 443         }
 444 }
 445
 446 void ClientCommand_say_team(float request, float argc, string command)
 447 {
 448         switch(request)
 449         {
 450                 case CMD_REQUEST_COMMAND:
 451                 {
 452                         if(argc >= 2) { Say(self, true, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 453                         return; // never fall through to usage
 454                 }
 455
 456                 default:
 457                 case CMD_REQUEST_USAGE:
 458                 {
 459                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 460                         sprint(self, "  Where 'message' is the string of text to say.\n");
 461                         return;
 462                 }
 463         }
 464 }
 465
 466 void ClientCommand_selectteam(float request, float argc)
 467 {
 468         switch(request)
 469         {
 470                 case CMD_REQUEST_COMMAND:
 471                 {
 472                         if(argv(1) != "")
 473                         {
 474                                 if(IS_CLIENT(self))
 475                                 {
 476                                         if(teamplay)
 477                                                 if(self.team_forced <= 0)
 478                                                         if (!lockteams)
 479                                                         {
 480                                                                 float selection;
 481
 482                                                                 switch(argv(1))
 483                                                                 {
 484                                                                         case "red": selection = NUM_TEAM_1; break;
 485                                                                         case "blue": selection = NUM_TEAM_2; break;
 486                                                                         case "yellow": selection = NUM_TEAM_3; break;
 487                                                                         case "pink": selection = NUM_TEAM_4; break;
 488                                                                         case "auto": selection = (-1); break;
 489
 490                                                                         default: selection = 0; break;
 491                                                                 }
 492
 493                                                                 if(selection)
 494                                                                 {
 495                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 496                                                                                 sprint(self, "^7You already are on that team.\n");
 497                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 498                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 499                                                                         else
 500                                                                         {
 501                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 502                                                                                 {
 503                                                                                         CheckAllowedTeams(self);
 504                                                                                         GetTeamCounts(self);
 505                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 506                                                                                         {
 507                                                                                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 508                                                                                                 return;
 509                                                                                         }
 510                                                                                 }
 511                                                                                 ClientKill_TeamChange(selection);
 512                                                                         }
 513                                                                 }
 514                                                         }
 515                                                         else
 516                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 517                                                 else
 518                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 519                                         else
 520                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 521                                 }
 522                                 return;
 523                         }
 524                 }
 525
 526                 default:
 527                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 528                 case CMD_REQUEST_USAGE:
 529                 {
 530                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 531                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 532                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 533                         return;
 534                 }
 535         }
 536 }
 537
 538 void ClientCommand_selfstuff(float request, string command)
 539 {
 540         switch(request)
 541         {
 542                 case CMD_REQUEST_COMMAND:
 543                 {
 544                         if(argv(1) != "")
 545                         {
 546                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 547                                 return;
 548                         }
 549                 }
 550
 551                 default:
 552                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 553                 case CMD_REQUEST_USAGE:
 554                 {
 555                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 556                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 557                         return;
 558                 }
 559         }
 560 }
 561
 562 void ClientCommand_sentcvar(float request, float argc, string command)
 563 {
 564         switch(request)
 565         {
 566                 case CMD_REQUEST_COMMAND:
 567                 {
 568                         if(argv(1) != "")
 569                         {
 570                                 //float tokens;
 571                                 string s;
 572
 573                                 if(argc == 2) // undefined cvar: use the default value on the server then
 574                                 {
 575                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 576                                         tokenize_console(s);
 577                                 }
 578
 579                                 GetCvars(1);
 580
 581                                 return;
 582                         }
 583                 }
 584
 585                 default:
 586                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 587                 case CMD_REQUEST_USAGE:
 588                 {
 589                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 590                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 591                         return;
 592                 }
 593         }
 594 }
 595
 596 void ClientCommand_spectate(float request)
 597 {
 598         switch(request)
 599         {
 600                 case CMD_REQUEST_COMMAND:
 601                 {
 602                         if(IS_CLIENT(self))
 603                         {
 604                                 if(g_lms)
 605                                 {
 606                                         if(self.lms_spectate_warning)
 607                                         {
 608                                                 // for the forfeit message...
 609                                                 self.lms_spectate_warning = 2;
 610                                                 // mark player as spectator
 611                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 612                                         }
 613                                         else
 614                                         {
 615                                                 self.lms_spectate_warning = 1;
 616                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 617                                                 return;
 618                                         }
 619                                 }
 620
 621                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
 622                                 {
 623                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 624                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_LEAVE);
 625                                         ClientKill_TeamChange(-2); // observe
 626                                 }
 627                         }
 628                         return; // never fall through to usage
 629                 }
 630
 631                 default:
 632                 case CMD_REQUEST_USAGE:
 633                 {
 634                         sprint(self, "\nUsage:^3 cmd spectate\n");
 635                         sprint(self, "  No arguments required.\n");
 636                         return;
 637                 }
 638         }
 639 }
 640
 641 void ClientCommand_suggestmap(float request, float argc)
 642 {
 643         switch(request)
 644         {
 645                 case CMD_REQUEST_COMMAND:
 646                 {
 647                         if(argv(1) != "")
 648                         {
 649                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 650                                 return;
 651                         }
 652                 }
 653
 654                 default:
 655                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 656                 case CMD_REQUEST_USAGE:
 657                 {
 658                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 659                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 660                         return;
 661                 }
 662         }
 663 }
 664
 665 void ClientCommand_tell(float request, float argc, string command)
 666 {
 667         switch(request)
 668         {
 669                 case CMD_REQUEST_COMMAND:
 670                 {
 671                         if(argc >= 3)
 672                         {
 673                                 entity tell_to = GetIndexedEntity(argc, 1);
 674                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 675
 676                                 if(tell_accepted > 0) // the target is a real client
 677                                 {
 678                                         if(tell_to != self) // and we're allowed to send to them :D
 679                                         {
 680                                                 Say(self, false, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), true);
 681                                                 return;
 682                                         }
 683                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 684                                 }
 685                                 else if(argv(1) == "#0")
 686                                 {
 687                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 688                                         return;
 689                                 }
 690                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 691                         }
 692                 }
 693
 694                 default:
 695                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 696                 case CMD_REQUEST_USAGE:
 697                 {
 698                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 699                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 700                         return;
 701                 }
 702         }
 703 }
 704
 705 void ClientCommand_voice(float request, float argc, string command)
 706 {
 707         switch(request)
 708         {
 709                 case CMD_REQUEST_COMMAND:
 710                 {
 711                         if(argv(1) != "")
 712                         {
 713                                 if(argc >= 3)
 714                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 715                                 else
 716                                         VoiceMessage(argv(1), "");
 717
 718                                 return;
 719                         }
 720                 }
 721
 722                 default:
 723                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 724                 case CMD_REQUEST_USAGE:
 725                 {
 726                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 727                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 728                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 729                         return;
 730                 }
 731         }
 732 }
 733
 734 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 735 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 736 void ClientCommand_(float request)
 737 {
 738         switch(request)
 739         {
 740                 case CMD_REQUEST_COMMAND:
 741                 {
 742
 743                         return; // never fall through to usage
 744                 }
 745
 746                 default:
 747                 case CMD_REQUEST_USAGE:
 748                 {
 749                         sprint(self, "\nUsage:^3 cmd \n");
 750                         sprint(self, "  No arguments required.\n");
 751                         return;
 752                 }
 753         }
 754 }
 755 */
 756
 757
 758 // =====================================
 759 //  Macro system for networked commands
 760 // =====================================
 761
 762 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 763 #define CLIENT_COMMANDS(request,arguments,command) \
 764         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 765         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 766         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 767         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 768         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 769         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 770         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 771         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 772         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 773         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 774         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 775         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 776         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 777         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 778         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 779         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 780         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 781         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 782         /* nothing */
 783
 784 void ClientCommand_macro_help()
 785 {
 786         #define CLIENT_COMMAND(name,function,description) \
 787                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 788
 789         CLIENT_COMMANDS(0, 0, "");
 790         #undef CLIENT_COMMAND
 791
 792         return;
 793 }
 794
 795 float ClientCommand_macro_command(float argc, string command)
 796 {
 797         #define CLIENT_COMMAND(name,function,description) \
 798                 { if(name == strtolower(argv(0))) { function; return true; } }
 799
 800         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
 801         #undef CLIENT_COMMAND
 802
 803         return false;
 804 }
 805
 806 float ClientCommand_macro_usage(float argc)
 807 {
 808         #define CLIENT_COMMAND(name,function,description) \
 809                 { if(name == strtolower(argv(1))) { function; return true; } }
 810
 811         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "");
 812         #undef CLIENT_COMMAND
 813
 814         return false;
 815 }
 816
 817 void ClientCommand_macro_write_aliases(float fh)
 818 {
 819         #define CLIENT_COMMAND(name,function,description) \
 820                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 821
 822         CLIENT_COMMANDS(0, 0, "");
 823         #undef CLIENT_COMMAND
 824
 825         return;
 826 }
 827
 828 // ======================================
 829 //  Main Function Called By Engine (cmd)
 830 // ======================================
 831 // If this function exists, server game code parses clientcommand before the engine code gets it.
 832
 833 void SV_ParseClientCommand(string command)
 834 {
 835         // If invalid UTF-8, don't even parse it
 836         string command2 = "";
 837         float len = strlen(command);
 838         float i;
 839         for (i = 0; i < len; ++i)
 840                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 841         if (command != command2)
 842                 return;
 843
 844         // if we're banned, don't even parse the command
 845         if(Ban_MaybeEnforceBanOnce(self))
 846                 return;
 847
 848         float argc = tokenize_console(command);
 849
 850         // for the mutator hook system
 851         cmd_name = strtolower(argv(0));
 852         cmd_argc = argc;
 853         cmd_string = command;
 854
 855         // Guide for working with argc arguments by example:
 856         // argc:   1    - 2      - 3     - 4
 857         // argv:   0    - 1      - 2     - 3
 858         // cmd     vote - master - login - password
 859
 860         // for floodcheck
 861         switch(strtolower(argv(0)))
 862         {
 863                 // exempt commands which are not subject to floodcheck
 864                 case "begin": break; // handled by engine in host_cmd.c
 865                 case "download": break; // handled by engine in cl_parse.c
 866                 case "mv_getpicture": break; // handled by server in this file
 867                 case "pause": break; // handled by engine in host_cmd.c
 868                 case "prespawn": break; // handled by engine in host_cmd.c
 869                 case "sentcvar": break; // handled by server in this file
 870                 case "spawn": break; // handled by engine in host_cmd.c
 871
 872                 default:
 873                         if(SV_ParseClientCommand_floodcheck())
 874                                 break; // "true": continue, as we're not flooding yet
 875                         else
 876                                 return; // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 877         }
 878
 879         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 880         if(argv(0) == "help")
 881         {
 882                 if(argc == 1)
 883                 {
 884                         sprint(self, "\nClient networked commands:\n");
 885                         ClientCommand_macro_help();
 886
 887                         sprint(self, "\nCommon networked commands:\n");
 888                         CommonCommand_macro_help(self);
 889
 890                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 891                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 892                         return;
 893                 }
 894                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 895                 {
 896                         return;
 897                 }
 898                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 899                 {
 900                         return;
 901                 }
 902         }
 903         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 904         {
 905                 return; // handled by a mutator
 906         }
 907         else if(CheatCommand(argc))
 908         {
 909                 return; // handled by server/cheats.qc
 910         }
 911         else if(CommonCommand_macro_command(argc, self, command))
 912         {
 913                 return; // handled by server/command/common.qc
 914         }
 915         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 916         {
 917                 return; // handled by one of the above ClientCommand_* functions
 918         }
 919         else
 920                 clientcommand(self, command);
 921 }