qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(argv(1) && argv(2))
 192                         {
 193                                 makevectors(self.v_angle);
 194                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 195
 196                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 197                                 if(trace_ent.flags & FL_MONSTER)
 198                                 {
 199                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 200                                         switch(argv(1))
 201                                         {
 202                                                 case "skin":
 203                                                 {
 204                                                         if(trace_ent.monsterid != MON_MAGE)
 205                                                                 trace_ent.skin = stof(argv(2));
 206                                                         return;
 207                                                 }
 208                                                 case "movetarget":
 209                                                 {
 210                                                         trace_ent.monster_moveflags = stof(argv(2));
 211                                                         return;
 212                                                 }
 213                                         }
 214                                 }
 215                         }
 216                 }
 217                 default:
 218                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 219                 case CMD_REQUEST_USAGE:
 220                 {
 221                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 222                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 223                         sprint(self, "  Aim at your monster to edit its properties.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void ClientCommand_mobkill(float request)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         makevectors(self.v_angle);
 236                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 237
 238                         if(trace_ent.flags & FL_MONSTER)
 239                         {
 240                                 if(trace_ent.realowner != self)
 241                                 {
 242                                         sprint(self, "That monster does not belong to you.\n");
 243                                         return;
 244                                 }
 245                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 246                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 247                                 return;
 248                         }
 249                 }
 250
 251                 default:
 252                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 253                 case CMD_REQUEST_USAGE:
 254                 {
 255                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 256                         sprint(self, "  Aim at your monster to kill it.\n");
 257                         return;
 258                 }
 259         }
 260 }
 261
 262 void ClientCommand_mobspawn(float request, float argc)
 263 {
 264         switch(request)
 265         {
 266                 case CMD_REQUEST_COMMAND:
 267                 {
 268                         entity e;
 269                         string tospawn;
 270                         float moveflag;
 271
 272                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 273                         tospawn = strtolower(argv(1));
 274
 275                         if(tospawn == "list")
 276                         {
 277                                 sprint(self, monsterlist_reply);
 278                                 return;
 279                         }
 280
 281                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 282                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 283                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 284                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 285                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 286                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 287                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 288                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 289                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 290                         else if(tospawn != "")
 291                         {
 292                                 float found = 0, i;
 293                                 entity mon;
 294
 295                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 296                                 {
 297                                         mon = get_monsterinfo(i);
 298                                         if(mon.netname == tospawn)
 299                                         {
 300                                                 found = TRUE;
 301                                                 break;
 302                                         }
 303                                 }
 304
 305                                 if(found)
 306                                 {
 307                                         self.monstercount += 1;
 308                                         totalspawned += 1;
 309
 310                                         makevectors(self.v_angle);
 311                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 312                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 313
 314                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
 315
 316                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 317
 318                                         return;
 319                                 }
 320                         }
 321                 }
 322
 323                 default:
 324                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 325                 case CMD_REQUEST_USAGE:
 326                 {
 327                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 328                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 329                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 330                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 331                         return;
 332                 }
 333         }
 334 }
 335
 336 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 337 {
 338         switch(request)
 339         {
 340                 case CMD_REQUEST_COMMAND:
 341                 {
 342                         if(IS_CLIENT(self))
 343                         {
 344                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 345                                 {
 346                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 347                                         {
 348                                                 if(time < game_starttime) // game is already restarting
 349                                                         return;
 350                                                 if (self.ready) // toggle
 351                                                 {
 352                                                         self.ready = FALSE;
 353                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 354                                                 }
 355                                                 else
 356                                                 {
 357                                                         self.ready = TRUE;
 358                                                         bprint(self.netname, "^2 is ready\n");
 359                                                 }
 360
 361                                                 // cannot reset the game while a timeout is active!
 362                                                 if (!timeout_status)
 363                                                         ReadyCount();
 364                                         } else {
 365                                                 sprint(self, "^1Game has already been restarted\n");
 366                                         }
 367                                 }
 368                         }
 369                         return; // never fall through to usage
 370                 }
 371
 372                 default:
 373                 case CMD_REQUEST_USAGE:
 374                 {
 375                         sprint(self, "\nUsage:^3 cmd ready\n");
 376                         sprint(self, "  No arguments required.\n");
 377                         return;
 378                 }
 379         }
 380 }
 381
 382 void ClientCommand_say(float request, float argc, string command)
 383 {
 384         switch(request)
 385         {
 386                 case CMD_REQUEST_COMMAND:
 387                 {
 388                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 389                         return; // never fall through to usage
 390                 }
 391
 392                 default:
 393                 case CMD_REQUEST_USAGE:
 394                 {
 395                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 396                         sprint(self, "  Where 'message' is the string of text to say.\n");
 397                         return;
 398                 }
 399         }
 400 }
 401
 402 void ClientCommand_say_team(float request, float argc, string command)
 403 {
 404         switch(request)
 405         {
 406                 case CMD_REQUEST_COMMAND:
 407                 {
 408                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 409                         return; // never fall through to usage
 410                 }
 411
 412                 default:
 413                 case CMD_REQUEST_USAGE:
 414                 {
 415                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 416                         sprint(self, "  Where 'message' is the string of text to say.\n");
 417                         return;
 418                 }
 419         }
 420 }
 421
 422 void ClientCommand_selectteam(float request, float argc)
 423 {
 424         switch(request)
 425         {
 426                 case CMD_REQUEST_COMMAND:
 427                 {
 428                         if(argv(1) != "")
 429                         {
 430                                 if(IS_CLIENT(self))
 431                                 {
 432                                         if(teamplay)
 433                                                 if(self.team_forced <= 0)
 434                                                         if (!lockteams)
 435                                                         {
 436                                                                 float selection;
 437
 438                                                                 switch(argv(1))
 439                                                                 {
 440                                                                         case "red": selection = NUM_TEAM_1; break;
 441                                                                         case "blue": selection = NUM_TEAM_2; break;
 442                                                                         case "yellow": selection = NUM_TEAM_3; break;
 443                                                                         case "pink": selection = NUM_TEAM_4; break;
 444                                                                         case "auto": selection = (-1); break;
 445
 446                                                                         default: selection = 0; break;
 447                                                                 }
 448
 449                                                                 if(selection)
 450                                                                 {
 451                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 452                                                                                 sprint(self, "^7You already are on that team.\n");
 453                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 454                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 455                                                                         else
 456                                                                         {
 457                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 458                                                                                 {
 459                                                                                         GetTeamCounts(self);
 460                                                                                         if(!TeamSmallerEqThanTeam(selection, self.team, self))
 461                                                                                         {
 462                                                                                                 sprint(self, "Cannot change to a larger/better/shinier team\n");
 463                                                                                                 return;
 464                                                                                         }
 465                                                                                 }
 466                                                                                 ClientKill_TeamChange(selection);
 467                                                                         }
 468                                                                 }
 469                                                         }
 470                                                         else
 471                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 472                                                 else
 473                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 474                                         else
 475                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 476                                 }
 477                                 return;
 478                         }
 479                 }
 480
 481                 default:
 482                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 483                 case CMD_REQUEST_USAGE:
 484                 {
 485                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 486                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 487                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 488                         return;
 489                 }
 490         }
 491 }
 492
 493 void ClientCommand_selfstuff(float request, string command)
 494 {
 495         switch(request)
 496         {
 497                 case CMD_REQUEST_COMMAND:
 498                 {
 499                         if(argv(1) != "")
 500                         {
 501                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 502                                 return;
 503                         }
 504                 }
 505
 506                 default:
 507                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 508                 case CMD_REQUEST_USAGE:
 509                 {
 510                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 511                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 512                         return;
 513                 }
 514         }
 515 }
 516
 517 void ClientCommand_sentcvar(float request, float argc, string command)
 518 {
 519         switch(request)
 520         {
 521                 case CMD_REQUEST_COMMAND:
 522                 {
 523                         if(argv(1) != "")
 524                         {
 525                                 //float tokens;
 526                                 string s;
 527
 528                                 if(argc == 2) // undefined cvar: use the default value on the server then
 529                                 {
 530                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 531                                         tokenize_console(s);
 532                                 }
 533
 534                                 GetCvars(1);
 535
 536                                 return;
 537                         }
 538                 }
 539
 540                 default:
 541                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 542                 case CMD_REQUEST_USAGE:
 543                 {
 544                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 545                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 546                         return;
 547                 }
 548         }
 549 }
 550
 551 void ClientCommand_spectate(float request)
 552 {
 553         switch(request)
 554         {
 555                 case CMD_REQUEST_COMMAND:
 556                 {
 557                         if(IS_CLIENT(self))
 558                         {
 559                                 if(g_lms)
 560                                 {
 561                                         if(self.lms_spectate_warning)
 562                                         {
 563                                                 // for the forfeit message...
 564                                                 self.lms_spectate_warning = 2;
 565                                                 // mark player as spectator
 566                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 567                                         }
 568                                         else
 569                                         {
 570                                                 self.lms_spectate_warning = 1;
 571                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 572                                                 return;
 573                                         }
 574                                 }
 575
 576                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 577                                         ClientKill_TeamChange(-2); // observe
 578
 579                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 580                                 // note: if arena game mode is ever done properly, this needs to be removed.
 581                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 582                                 {
 583                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 584                                         self.caplayer = 0;
 585                                 }
 586                         }
 587                         return; // never fall through to usage
 588                 }
 589
 590                 default:
 591                 case CMD_REQUEST_USAGE:
 592                 {
 593                         sprint(self, "\nUsage:^3 cmd spectate\n");
 594                         sprint(self, "  No arguments required.\n");
 595                         return;
 596                 }
 597         }
 598 }
 599
 600 void ClientCommand_suggestmap(float request, float argc)
 601 {
 602         switch(request)
 603         {
 604                 case CMD_REQUEST_COMMAND:
 605                 {
 606                         if(argv(1) != "")
 607                         {
 608                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 609                                 return;
 610                         }
 611                 }
 612
 613                 default:
 614                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 615                 case CMD_REQUEST_USAGE:
 616                 {
 617                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 618                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 619                         return;
 620                 }
 621         }
 622 }
 623
 624 void ClientCommand_tell(float request, float argc, string command)
 625 {
 626         switch(request)
 627         {
 628                 case CMD_REQUEST_COMMAND:
 629                 {
 630                         if(argc >= 3)
 631                         {
 632                                 entity tell_to = GetIndexedEntity(argc, 1);
 633                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 634
 635                                 if(tell_accepted > 0) // the target is a real client
 636                                 {
 637                                         if(tell_to != self) // and we're allowed to send to them :D
 638                                         {
 639                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 640                                                 return;
 641                                         }
 642                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 643                                 }
 644                                 else if(argv(1) == "#0")
 645                                 {
 646                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 647                                         return;
 648                                 }
 649                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 650                         }
 651                 }
 652
 653                 default:
 654                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 655                 case CMD_REQUEST_USAGE:
 656                 {
 657                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 658                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 659                         return;
 660                 }
 661         }
 662 }
 663
 664 void ClientCommand_voice(float request, float argc, string command)
 665 {
 666         switch(request)
 667         {
 668                 case CMD_REQUEST_COMMAND:
 669                 {
 670                         if(argv(1) != "")
 671                         {
 672                                 if(argc >= 3)
 673                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 674                                 else
 675                                         VoiceMessage(argv(1), "");
 676
 677                                 return;
 678                         }
 679                 }
 680
 681                 default:
 682                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 683                 case CMD_REQUEST_USAGE:
 684                 {
 685                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 686                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 687                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 688                         return;
 689                 }
 690         }
 691 }
 692
 693 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 694 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 695 void ClientCommand_(float request)
 696 {
 697         switch(request)
 698         {
 699                 case CMD_REQUEST_COMMAND:
 700                 {
 701
 702                         return; // never fall through to usage
 703                 }
 704
 705                 default:
 706                 case CMD_REQUEST_USAGE:
 707                 {
 708                         sprint(self, "\nUsage:^3 cmd \n");
 709                         sprint(self, "  No arguments required.\n");
 710                         return;
 711                 }
 712         }
 713 }
 714 */
 715
 716
 717 // =====================================
 718 //  Macro system for networked commands
 719 // =====================================
 720
 721 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 722 #define CLIENT_COMMANDS(request,arguments,command) \
 723         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 724         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 725         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 726         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 727         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 728         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 729         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 730         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 731         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 732         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 733         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 734         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 735         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 736         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 737         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 738         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 739         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 740         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 741         /* nothing */
 742
 743 void ClientCommand_macro_help()
 744 {
 745         #define CLIENT_COMMAND(name,function,description) \
 746                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 747
 748         CLIENT_COMMANDS(0, 0, "")
 749         #undef CLIENT_COMMAND
 750
 751         return;
 752 }
 753
 754 float ClientCommand_macro_command(float argc, string command)
 755 {
 756         #define CLIENT_COMMAND(name,function,description) \
 757                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 758
 759         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 760         #undef CLIENT_COMMAND
 761
 762         return FALSE;
 763 }
 764
 765 float ClientCommand_macro_usage(float argc)
 766 {
 767         #define CLIENT_COMMAND(name,function,description) \
 768                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 769
 770         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 771         #undef CLIENT_COMMAND
 772
 773         return FALSE;
 774 }
 775
 776 void ClientCommand_macro_write_aliases(float fh)
 777 {
 778         #define CLIENT_COMMAND(name,function,description) \
 779                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 780
 781         CLIENT_COMMANDS(0, 0, "")
 782         #undef CLIENT_COMMAND
 783
 784         return;
 785 }
 786
 787 // ======================================
 788 //  Main Function Called By Engine (cmd)
 789 // ======================================
 790 // If this function exists, server game code parses clientcommand before the engine code gets it.
 791
 792 void SV_ParseClientCommand(string command)
 793 {
 794         // if we're banned, don't even parse the command
 795         if(Ban_MaybeEnforceBanOnce(self))
 796                 return;
 797
 798         float argc = tokenize_console(command);
 799
 800         // for the mutator hook system
 801         cmd_name = strtolower(argv(0));
 802         cmd_argc = argc;
 803         cmd_string = command;
 804
 805         // Guide for working with argc arguments by example:
 806         // argc:   1    - 2      - 3     - 4
 807         // argv:   0    - 1      - 2     - 3
 808         // cmd     vote - master - login - password
 809
 810         // for floodcheck
 811         switch(strtolower(argv(0)))
 812         {
 813                 // exempt commands which are not subject to floodcheck
 814                 case "begin": break; // handled by engine in host_cmd.c
 815                 case "download": break; // handled by engine in cl_parse.c
 816                 case "mv_getpicture": break; // handled by server in this file
 817                 case "pause": break; // handled by engine in host_cmd.c
 818                 case "prespawn": break; // handled by engine in host_cmd.c
 819                 case "sentcvar": break; // handled by server in this file
 820                 case "spawn": break; // handled by engine in host_cmd.c
 821
 822                 default:
 823                         if(SV_ParseClientCommand_floodcheck())
 824                                 break; // "TRUE": continue, as we're not flooding yet
 825                         else
 826                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 827         }
 828
 829         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 830         if(argv(0) == "help")
 831         {
 832                 if(argc == 1)
 833                 {
 834                         sprint(self, "\nClient networked commands:\n");
 835                         ClientCommand_macro_help();
 836
 837                         sprint(self, "\nCommon networked commands:\n");
 838                         CommonCommand_macro_help(self);
 839
 840                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 841                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 842                         return;
 843                 }
 844                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 845                 {
 846                         return;
 847                 }
 848                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 849                 {
 850                         return;
 851                 }
 852         }
 853         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 854         {
 855                 return; // handled by a mutator
 856         }
 857         else if(CheatCommand(argc))
 858         {
 859                 return; // handled by server/cheats.qc
 860         }
 861         else if(CommonCommand_macro_command(argc, self, command))
 862         {
 863                 return; // handled by server/command/common.qc
 864         }
 865         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 866         {
 867                 return; // handled by one of the above ClientCommand_* functions
 868         }
 869         else
 870                 clientcommand(self, command);
 871 }