qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         makevectors(self.v_angle);
 192                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 193
 194                         if not(trace_ent.flags & FL_MONSTER) { sprint(self, "You need to aim at your monster to edit its properties.\n"); return; }
 195                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 196
 197                         switch(argv(1))
 198                         {
 199                                 case "name": trace_ent.netname = strzone(strdecolorize(argv(2))); if(trace_ent.sprite) WaypointSprite_UpdateSprites(trace_ent.sprite, trace_ent.netname, "", ""); return;
 200                                 case "skin": if(trace_ent.monsterid != MONSTER_MAGE) { trace_ent.skin = stof(argv(2)); trace_ent.SendFlags |= MSF_STATUS; } return;
 201                                 case "movetarget": trace_ent.monster_moveflags = stof(argv(2)); return;
 202                         }
 203                 }
 204                 default:
 205                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 206                 case CMD_REQUEST_USAGE:
 207                 {
 208                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 209                         sprint(self, "  Where 'argument' can be name, color or movetarget.\n");
 210                         return;
 211                 }
 212         }
 213 }
 214
 215 void ClientCommand_mobkill(float request)
 216 {
 217         switch(request)
 218         {
 219                 case CMD_REQUEST_COMMAND:
 220                 {
 221                         makevectors(self.v_angle);
 222                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 223
 224                         if(trace_ent.flags & FL_MONSTER)
 225                         {
 226                                 if(trace_ent.realowner != self)
 227                                 {
 228                                         sprint(self, "That monster does not belong to you.\n");
 229                                         return;
 230                                 }
 231                                 sprint(self, strcat("Your pet '", trace_ent.netname, "' has been brutally mutilated.\n"));
 232                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 233                                 return;
 234                         }
 235                         else
 236                                 sprint(self, "You need to aim at your monster to kill it.\n");
 237
 238                         return;
 239                 }
 240
 241                 default:
 242                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 243                 case CMD_REQUEST_USAGE:
 244                 {
 245                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 246                         sprint(self, "  Aim at your monster to kill it.\n");
 247                         return;
 248                 }
 249         }
 250 }
 251
 252 void ClientCommand_mobspawn(float request, float argc)
 253 {
 254         switch(request)
 255         {
 256                 case CMD_REQUEST_COMMAND:
 257                 {
 258                         entity e;
 259                         string tospawn, mname;
 260                         float moveflag;
 261
 262                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 263                         tospawn = strtolower(argv(1));
 264                         mname = argv(3);
 265
 266                         if(tospawn == "list")
 267                         {
 268                                 float i;
 269                                 string list = "Available monsters:";
 270
 271                                 for(i = MONSTER_FIRST + 1; i < MONSTER_LAST; ++i)
 272                                         list = strcat(list, " ", monster_id2string(i));
 273
 274                                 sprint(self, strcat(list, "\n"));
 275
 276                                 return;
 277                         }
 278
 279                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
 280                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
 281                         else if not(autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
 282                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
 283                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
 284                         else if(g_td) { sprint(self, "You can't spawn monsters in Tower Defense mode.\n"); }
 285                         else if(self.deadflag) { sprint(self, "You can't spawn monsters while dead.\n"); }
 286                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
 287                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
 288                         else // all worked out, so continue
 289                         {
 290                                 self.monstercount += 1;
 291                                 totalspawned += 1;
 292
 293                                 makevectors(self.v_angle);
 294                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 295
 296                                 e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
 297                                 if(mname) e.netname = strzone(mname);
 298
 299                                 sprint(self, strcat("Spawned ", e.netname, "\n"));
 300                         }
 301
 302                         return;
 303                 }
 304
 305                 default:
 306                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 307                 case CMD_REQUEST_USAGE:
 308                 {
 309                         sprint(self, "\nUsage:^3 cmd mobspawn monster\n");
 310                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 317 {
 318         switch(request)
 319         {
 320                 case CMD_REQUEST_COMMAND:
 321                 {
 322                         if(IS_CLIENT(self))
 323                         {
 324                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 325                                 {
 326                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 327                                         {
 328                                                 if(time < game_starttime) // game is already restarting
 329                                                         return;
 330                                                 if (self.ready) // toggle
 331                                                 {
 332                                                         self.ready = FALSE;
 333                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 334                                                 }
 335                                                 else
 336                                                 {
 337                                                         self.ready = TRUE;
 338                                                         bprint(self.netname, "^2 is ready\n");
 339                                                 }
 340
 341                                                 // cannot reset the game while a timeout is active!
 342                                                 if not(timeout_status)
 343                                                         ReadyCount();
 344                                         } else {
 345                                                 sprint(self, "^1Game has already been restarted\n");
 346                                         }
 347                                 }
 348                         }
 349                         return; // never fall through to usage
 350                 }
 351
 352                 default:
 353                 case CMD_REQUEST_USAGE:
 354                 {
 355                         sprint(self, "\nUsage:^3 cmd ready\n");
 356                         sprint(self, "  No arguments required.\n");
 357                         return;
 358                 }
 359         }
 360 }
 361
 362 void ClientCommand_say(float request, float argc, string command)
 363 {
 364         switch(request)
 365         {
 366                 case CMD_REQUEST_COMMAND:
 367                 {
 368                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 369                         return; // never fall through to usage
 370                 }
 371
 372                 default:
 373                 case CMD_REQUEST_USAGE:
 374                 {
 375                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 376                         sprint(self, "  Where 'message' is the string of text to say.\n");
 377                         return;
 378                 }
 379         }
 380 }
 381
 382 void ClientCommand_say_team(float request, float argc, string command)
 383 {
 384         switch(request)
 385         {
 386                 case CMD_REQUEST_COMMAND:
 387                 {
 388                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 389                         return; // never fall through to usage
 390                 }
 391
 392                 default:
 393                 case CMD_REQUEST_USAGE:
 394                 {
 395                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 396                         sprint(self, "  Where 'message' is the string of text to say.\n");
 397                         return;
 398                 }
 399         }
 400 }
 401
 402 void ClientCommand_selectteam(float request, float argc)
 403 {
 404         switch(request)
 405         {
 406                 case CMD_REQUEST_COMMAND:
 407                 {
 408                         if(argv(1) != "")
 409                         {
 410                                 if(IS_CLIENT(self))
 411                                 {
 412                                         if(teamplay)
 413                                                 if not(self.team_forced > 0)
 414                                                         if not(lockteams)
 415                                                         {
 416                                                                 float selection;
 417
 418                                                                 switch(argv(1))
 419                                                                 {
 420                                                                         case "red": selection = NUM_TEAM_1; break;
 421                                                                         case "blue": selection = NUM_TEAM_2; break;
 422                                                                         case "yellow": selection = NUM_TEAM_3; break;
 423                                                                         case "pink": selection = NUM_TEAM_4; break;
 424                                                                         case "auto": selection = (-1); break;
 425
 426                                                                         default: selection = 0; break;
 427                                                                 }
 428
 429                                                                 if(selection)
 430                                                                 {
 431                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 432                                                                                 sprint(self, "^7You already are on that team.\n");
 433                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 434                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 435                                                                         else
 436                                                                                 ClientKill_TeamChange(selection);
 437                                                                 }
 438                                                         }
 439                                                         else
 440                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 441                                                 else
 442                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 443                                         else
 444                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 445                                 }
 446                                 return;
 447                         }
 448                 }
 449
 450                 default:
 451                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 452                 case CMD_REQUEST_USAGE:
 453                 {
 454                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 455                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 456                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 457                         return;
 458                 }
 459         }
 460 }
 461
 462 void ClientCommand_selfstuff(float request, string command)
 463 {
 464         switch(request)
 465         {
 466                 case CMD_REQUEST_COMMAND:
 467                 {
 468                         if(argv(1) != "")
 469                         {
 470                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 471                                 return;
 472                         }
 473                 }
 474
 475                 default:
 476                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 477                 case CMD_REQUEST_USAGE:
 478                 {
 479                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 480                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 481                         return;
 482                 }
 483         }
 484 }
 485
 486 void ClientCommand_sentcvar(float request, float argc, string command)
 487 {
 488         switch(request)
 489         {
 490                 case CMD_REQUEST_COMMAND:
 491                 {
 492                         if(argv(1) != "")
 493                         {
 494                                 //float tokens;
 495                                 string s;
 496
 497                                 if(argc == 2) // undefined cvar: use the default value on the server then
 498                                 {
 499                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 500                                         tokenize_console(s);
 501                                 }
 502
 503                                 GetCvars(1);
 504
 505                                 return;
 506                         }
 507                 }
 508
 509                 default:
 510                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 511                 case CMD_REQUEST_USAGE:
 512                 {
 513                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 514                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 515                         return;
 516                 }
 517         }
 518 }
 519
 520 void ClientCommand_spectate(float request)
 521 {
 522         switch(request)
 523         {
 524                 case CMD_REQUEST_COMMAND:
 525                 {
 526                         if(IS_CLIENT(self))
 527                         {
 528                                 if(g_arena) { return; }
 529                                 if(g_lms)
 530                                 {
 531                                         if(self.lms_spectate_warning)
 532                                         {
 533                                                 // for the forfeit message...
 534                                                 self.lms_spectate_warning = 2;
 535                                                 // mark player as spectator
 536                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 537                                         }
 538                                         else
 539                                         {
 540                                                 self.lms_spectate_warning = 1;
 541                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 542                                                 return;
 543                                         }
 544                                 }
 545
 546                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 547                                         ClientKill_TeamChange(-2); // observe
 548
 549                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 550                                 // note: if arena game mode is ever done properly, this needs to be removed.
 551                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 552                                 {
 553                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 554                                         self.caplayer = 0;
 555                                 }
 556                         }
 557                         return; // never fall through to usage
 558                 }
 559
 560                 default:
 561                 case CMD_REQUEST_USAGE:
 562                 {
 563                         sprint(self, "\nUsage:^3 cmd spectate\n");
 564                         sprint(self, "  No arguments required.\n");
 565                         return;
 566                 }
 567         }
 568 }
 569
 570 void ClientCommand_suggestmap(float request, float argc)
 571 {
 572         switch(request)
 573         {
 574                 case CMD_REQUEST_COMMAND:
 575                 {
 576                         if(argv(1) != "")
 577                         {
 578                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 579                                 return;
 580                         }
 581                 }
 582
 583                 default:
 584                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 585                 case CMD_REQUEST_USAGE:
 586                 {
 587                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 588                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 589                         return;
 590                 }
 591         }
 592 }
 593
 594 void ClientCommand_tell(float request, float argc, string command)
 595 {
 596         switch(request)
 597         {
 598                 case CMD_REQUEST_COMMAND:
 599                 {
 600                         if(argc >= 3)
 601                         {
 602                                 entity tell_to = GetIndexedEntity(argc, 1);
 603                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 604
 605                                 if(tell_accepted > 0) // the target is a real client
 606                                 {
 607                                         if(tell_to != self) // and we're allowed to send to them :D
 608                                         {
 609                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 610                                                 return;
 611                                         }
 612                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 613                                 }
 614                                 else if(argv(1) == "#0")
 615                                 {
 616                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 617                                         return;
 618                                 }
 619                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 620                         }
 621                 }
 622
 623                 default:
 624                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 625                 case CMD_REQUEST_USAGE:
 626                 {
 627                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 628                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 629                         return;
 630                 }
 631         }
 632 }
 633
 634 void ClientCommand_voice(float request, float argc, string command)
 635 {
 636         switch(request)
 637         {
 638                 case CMD_REQUEST_COMMAND:
 639                 {
 640                         if(argv(1) != "")
 641                         {
 642                                 if(argc >= 3)
 643                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 644                                 else
 645                                         VoiceMessage(argv(1), "");
 646
 647                                 return;
 648                         }
 649                 }
 650
 651                 default:
 652                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 653                 case CMD_REQUEST_USAGE:
 654                 {
 655                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 656                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 657                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 658                         return;
 659                 }
 660         }
 661 }
 662
 663 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 664 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 665 void ClientCommand_(float request)
 666 {
 667         switch(request)
 668         {
 669                 case CMD_REQUEST_COMMAND:
 670                 {
 671
 672                         return; // never fall through to usage
 673                 }
 674
 675                 default:
 676                 case CMD_REQUEST_USAGE:
 677                 {
 678                         sprint(self, "\nUsage:^3 cmd \n");
 679                         sprint(self, "  No arguments required.\n");
 680                         return;
 681                 }
 682         }
 683 }
 684 */
 685
 686
 687 // =====================================
 688 //  Macro system for networked commands
 689 // =====================================
 690
 691 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 692 #define CLIENT_COMMANDS(request,arguments,command) \
 693         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 694         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 695         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 696         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 697         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 698         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 699         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 700         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 701         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 702         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 703         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 704         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 705         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 706         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 707         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 708         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 709         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 710         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 711         /* nothing */
 712
 713 void ClientCommand_macro_help()
 714 {
 715         #define CLIENT_COMMAND(name,function,description) \
 716                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 717
 718         CLIENT_COMMANDS(0, 0, "")
 719         #undef CLIENT_COMMAND
 720
 721         return;
 722 }
 723
 724 float ClientCommand_macro_command(float argc, string command)
 725 {
 726         #define CLIENT_COMMAND(name,function,description) \
 727                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 728
 729         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 730         #undef CLIENT_COMMAND
 731
 732         return FALSE;
 733 }
 734
 735 float ClientCommand_macro_usage(float argc)
 736 {
 737         #define CLIENT_COMMAND(name,function,description) \
 738                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 739
 740         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 741         #undef CLIENT_COMMAND
 742
 743         return FALSE;
 744 }
 745
 746 void ClientCommand_macro_write_aliases(float fh)
 747 {
 748         #define CLIENT_COMMAND(name,function,description) \
 749                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 750
 751         CLIENT_COMMANDS(0, 0, "")
 752         #undef CLIENT_COMMAND
 753
 754         return;
 755 }
 756
 757 // ======================================
 758 //  Main Function Called By Engine (cmd)
 759 // ======================================
 760 // If this function exists, server game code parses clientcommand before the engine code gets it.
 761
 762 void SV_ParseClientCommand(string command)
 763 {
 764         // if we're banned, don't even parse the command
 765         if(Ban_MaybeEnforceBanOnce(self))
 766                 return;
 767
 768         float argc = tokenize_console(command);
 769
 770         // for the mutator hook system
 771         cmd_name = strtolower(argv(0));
 772         cmd_argc = argc;
 773         cmd_string = command;
 774
 775         // Guide for working with argc arguments by example:
 776         // argc:   1    - 2      - 3     - 4
 777         // argv:   0    - 1      - 2     - 3
 778         // cmd     vote - master - login - password
 779
 780         // for floodcheck
 781         switch(strtolower(argv(0)))
 782         {
 783                 // exempt commands which are not subject to floodcheck
 784                 case "begin": break; // handled by engine in host_cmd.c
 785                 case "download": break; // handled by engine in cl_parse.c
 786                 case "mv_getpicture": break; // handled by server in this file
 787                 case "pause": break; // handled by engine in host_cmd.c
 788                 case "prespawn": break; // handled by engine in host_cmd.c
 789                 case "sentcvar": break; // handled by server in this file
 790                 case "spawn": break; // handled by engine in host_cmd.c
 791
 792                 default:
 793                         if(SV_ParseClientCommand_floodcheck())
 794                                 break; // "TRUE": continue, as we're not flooding yet
 795                         else
 796                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 797         }
 798
 799         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 800         if(argv(0) == "help")
 801         {
 802                 if(argc == 1)
 803                 {
 804                         sprint(self, "\nClient networked commands:\n");
 805                         ClientCommand_macro_help();
 806
 807                         sprint(self, "\nCommon networked commands:\n");
 808                         CommonCommand_macro_help(self);
 809
 810                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 811                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 812                         return;
 813                 }
 814                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 815                 {
 816                         return;
 817                 }
 818                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 819                 {
 820                         return;
 821                 }
 822         }
 823         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 824         {
 825                 return; // handled by a mutator
 826         }
 827         else if(CheatCommand(argc))
 828         {
 829                 return; // handled by server/cheats.qc
 830         }
 831         else if(CommonCommand_macro_command(argc, self, command))
 832         {
 833                 return; // handled by server/command/common.qc
 834         }
 835         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 836         {
 837                 return; // handled by one of the above ClientCommand_* functions
 838         }
 839         else
 840                 clientcommand(self, command);
 841 }