qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(g_ca) { self.caplayer = 1; }
 158                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 159
 160                                                 self.classname = "player";
 161                                                 PlayerScore_Clear(self);
 162                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 163                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 164                                                 PutClientInServer();
 165                                         }
 166                                         else
 167                                         {
 168                                                 //player may not join because of g_maxplayers is set
 169                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 170                                         }
 171                                 }
 172                         }
 173                         return; // never fall through to usage
 174                 }
 175
 176                 default:
 177                 case CMD_REQUEST_USAGE:
 178                 {
 179                         sprint(self, "\nUsage:^3 cmd join\n");
 180                         sprint(self, "  No arguments required.\n");
 181                         return;
 182                 }
 183         }
 184 }
 185
 186 void ClientCommand_mobedit(float request, float argc)
 187 {
 188         switch(request)
 189         {
 190                 case CMD_REQUEST_COMMAND:
 191                 {
 192                         makevectors(self.v_angle);
 193                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 194
 195                         if not(trace_ent.flags & FL_MONSTER) { sprint(self, "You need to aim at your monster to edit its properties.\n"); return; }
 196                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 197
 198                         switch(argv(1))
 199                         {
 200                                 case "name": trace_ent.netname = strzone(strdecolorize(argv(2))); if(trace_ent.sprite) WaypointSprite_UpdateSprites(trace_ent.sprite, trace_ent.netname, "", ""); break;
 201                                 case "skin": trace_ent.skin = stof(argv(2)); trace_ent.SendFlags |= MSF_STATUS; break;
 202                                 case "movetarget": trace_ent.monster_moveflags = stof(argv(2)); break;
 203                                 default: sprint(self, "Unknown parameter\n"); break;
 204                         }
 205
 206                         return; // never fall through to usage
 207                 }
 208                 default:
 209                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 210                 case CMD_REQUEST_USAGE:
 211                 {
 212                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 213                         sprint(self, "  Where 'argument' can be name, skin, color or movetarget.\n");
 214                         return;
 215                 }
 216         }
 217 }
 218
 219 void ClientCommand_mobkill(float request)
 220 {
 221         switch(request)
 222         {
 223                 case CMD_REQUEST_COMMAND:
 224                 {
 225                         makevectors(self.v_angle);
 226                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 227
 228                         if(trace_ent.flags & FL_MONSTER)
 229                         {
 230                                 if(trace_ent.realowner != self)
 231                                 {
 232                                         sprint(self, "That monster does not belong to you.\n");
 233                                         return;
 234                                 }
 235                                 sprint(self, strcat("Your pet '", trace_ent.netname, "' has been brutally mutilated.\n"));
 236                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 237                                 return;
 238                         }
 239                         else
 240                                 sprint(self, "You need to aim at your monster to kill it.\n");
 241
 242                         return;
 243                 }
 244
 245                 default:
 246                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 247                 case CMD_REQUEST_USAGE:
 248                 {
 249                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 250                         sprint(self, "  Aim at your monster to kill it.\n");
 251                         return;
 252                 }
 253         }
 254 }
 255
 256 void ClientCommand_mobspawn(float request, float argc)
 257 {
 258         switch(request)
 259         {
 260                 case CMD_REQUEST_COMMAND:
 261                 {
 262                         entity e;
 263                         string tospawn, mname;
 264                         float moveflag;
 265
 266                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 267                         tospawn = strtolower(argv(1));
 268                         mname = argv(3);
 269
 270                         if(tospawn == "list")
 271                         {
 272                                 sprint(self, "Available monsters:\n");
 273                                 sprint(self, strcat(autocvar_g_monsters_spawn_list, "\n"));
 274                                 return;
 275                         }
 276
 277                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
 278                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
 279                         else if not(autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
 280                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
 281                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
 282                         else if(g_td) { sprint(self, "You can't spawn monsters in Tower Defense mode.\n"); }
 283                         else if(self.deadflag) { sprint(self, "You can't spawn monsters while dead.\n"); }
 284                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
 285                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
 286                         else // all worked out, so continue
 287                         {
 288                                 self.monstercount += 1;
 289                                 totalspawned += 1;
 290
 291                                 makevectors(self.v_angle);
 292                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 293
 294                                 e = spawnmonster(tospawn, self, self, trace_endpos, FALSE, moveflag);
 295                                 if(mname) e.netname = strzone(mname);
 296
 297                                 sprint(self, strcat("Spawned 1 ", tospawn, "\n"));
 298                         }
 299
 300                         return;
 301                 }
 302
 303                 default:
 304                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 305                 case CMD_REQUEST_USAGE:
 306                 {
 307                         sprint(self, "\nUsage:^3 cmd mobspawn monster\n");
 308                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
 309                         return;
 310                 }
 311         }
 312 }
 313
 314 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 315 {
 316         switch(request)
 317         {
 318                 case CMD_REQUEST_COMMAND:
 319                 {
 320                         if(self.flags & FL_CLIENT)
 321                         {
 322                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 323                                 {
 324                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 325                                         {
 326                                                 if (self.ready) // toggle
 327                                                 {
 328                                                         self.ready = FALSE;
 329                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 330                                                 }
 331                                                 else
 332                                                 {
 333                                                         self.ready = TRUE;
 334                                                         bprint(self.netname, "^2 is ready\n");
 335                                                 }
 336
 337                                                 // cannot reset the game while a timeout is active!
 338                                                 if not(timeout_status)
 339                                                         ReadyCount();
 340                                         } else {
 341                                                 sprint(self, "^1Game has already been restarted\n");
 342                                         }
 343                                 }
 344                         }
 345                         return; // never fall through to usage
 346                 }
 347
 348                 default:
 349                 case CMD_REQUEST_USAGE:
 350                 {
 351                         sprint(self, "\nUsage:^3 cmd ready\n");
 352                         sprint(self, "  No arguments required.\n");
 353                         return;
 354                 }
 355         }
 356 }
 357
 358 void ClientCommand_say(float request, float argc, string command)
 359 {
 360         switch(request)
 361         {
 362                 case CMD_REQUEST_COMMAND:
 363                 {
 364                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 365                         return; // never fall through to usage
 366                 }
 367
 368                 default:
 369                 case CMD_REQUEST_USAGE:
 370                 {
 371                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 372                         sprint(self, "  Where 'message' is the string of text to say.\n");
 373                         return;
 374                 }
 375         }
 376 }
 377
 378 void ClientCommand_say_team(float request, float argc, string command)
 379 {
 380         switch(request)
 381         {
 382                 case CMD_REQUEST_COMMAND:
 383                 {
 384                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 385                         return; // never fall through to usage
 386                 }
 387
 388                 default:
 389                 case CMD_REQUEST_USAGE:
 390                 {
 391                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 392                         sprint(self, "  Where 'message' is the string of text to say.\n");
 393                         return;
 394                 }
 395         }
 396 }
 397
 398 void ClientCommand_selectteam(float request, float argc)
 399 {
 400         switch(request)
 401         {
 402                 case CMD_REQUEST_COMMAND:
 403                 {
 404                         if(argv(1) != "")
 405                         {
 406                                 if(self.flags & FL_CLIENT)
 407                                 {
 408                                         if(teamplay)
 409                                                 if not(self.team_forced > 0)
 410                                                         if not(lockteams)
 411                                                         {
 412                                                                 float selection;
 413
 414                                                                 switch(argv(1))
 415                                                                 {
 416                                                                         case "red": selection = NUM_TEAM_1; break;
 417                                                                         case "blue": selection = NUM_TEAM_2; break;
 418                                                                         case "yellow": selection = NUM_TEAM_3; break;
 419                                                                         case "pink": selection = NUM_TEAM_4; break;
 420                                                                         case "auto": selection = (-1); break;
 421
 422                                                                         default: selection = 0; break;
 423                                                                 }
 424
 425                                                                 if(selection)
 426                                                                 {
 427                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 428                                                                                 sprint(self, "^7You already are on that team.\n");
 429                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 430                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 431                                                                         else
 432                                                                                 ClientKill_TeamChange(selection);
 433                                                                 }
 434                                                         }
 435                                                         else
 436                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 437                                                 else
 438                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 439                                         else
 440                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 441                                 }
 442                                 return;
 443                         }
 444                 }
 445
 446                 default:
 447                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 448                 case CMD_REQUEST_USAGE:
 449                 {
 450                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 451                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 452                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 453                         return;
 454                 }
 455         }
 456 }
 457
 458 void ClientCommand_selfstuff(float request, string command)
 459 {
 460         switch(request)
 461         {
 462                 case CMD_REQUEST_COMMAND:
 463                 {
 464                         if(argv(1) != "")
 465                         {
 466                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 467                                 return;
 468                         }
 469                 }
 470
 471                 default:
 472                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 473                 case CMD_REQUEST_USAGE:
 474                 {
 475                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 476                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 477                         return;
 478                 }
 479         }
 480 }
 481
 482 void ClientCommand_sentcvar(float request, float argc, string command)
 483 {
 484         switch(request)
 485         {
 486                 case CMD_REQUEST_COMMAND:
 487                 {
 488                         if(argv(1) != "")
 489                         {
 490                                 //float tokens;
 491                                 string s;
 492
 493                                 if(argc == 2) // undefined cvar: use the default value on the server then
 494                                 {
 495                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 496                                         tokenize_console(s);
 497                                 }
 498
 499                                 GetCvars(1);
 500
 501                                 return;
 502                         }
 503                 }
 504
 505                 default:
 506                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 507                 case CMD_REQUEST_USAGE:
 508                 {
 509                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 510                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 511                         return;
 512                 }
 513         }
 514 }
 515
 516 void ClientCommand_spectate(float request)
 517 {
 518         switch(request)
 519         {
 520                 case CMD_REQUEST_COMMAND:
 521                 {
 522                         if(self.flags & FL_CLIENT)
 523                         {
 524                                 if(g_arena) { return; }
 525                                 if(g_lms)
 526                                 {
 527                                         if(self.lms_spectate_warning)
 528                                         {
 529                                                 // for the forfeit message...
 530                                                 self.lms_spectate_warning = 2;
 531                                                 // mark player as spectator
 532                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 533                                         }
 534                                         else
 535                                         {
 536                                                 self.lms_spectate_warning = 1;
 537                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 538                                                 return;
 539                                         }
 540                                 }
 541
 542                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 543                                         ClientKill_TeamChange(-2); // observe
 544
 545                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 546                                 // note: if arena game mode is ever done properly, this needs to be removed.
 547                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 548                                 {
 549                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 550                                         self.caplayer = 0;
 551                                 }
 552                         }
 553                         return; // never fall through to usage
 554                 }
 555
 556                 default:
 557                 case CMD_REQUEST_USAGE:
 558                 {
 559                         sprint(self, "\nUsage:^3 cmd spectate\n");
 560                         sprint(self, "  No arguments required.\n");
 561                         return;
 562                 }
 563         }
 564 }
 565
 566 void ClientCommand_suggestmap(float request, float argc)
 567 {
 568         switch(request)
 569         {
 570                 case CMD_REQUEST_COMMAND:
 571                 {
 572                         if(argv(1) != "")
 573                         {
 574                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 575                                 return;
 576                         }
 577                 }
 578
 579                 default:
 580                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 581                 case CMD_REQUEST_USAGE:
 582                 {
 583                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 584                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 585                         return;
 586                 }
 587         }
 588 }
 589
 590 void ClientCommand_tell(float request, float argc, string command)
 591 {
 592         switch(request)
 593         {
 594                 case CMD_REQUEST_COMMAND:
 595                 {
 596                         if(argc >= 3)
 597                         {
 598                                 entity tell_to = GetIndexedEntity(argc, 1);
 599                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 600
 601                                 if(tell_accepted > 0) // the target is a real client
 602                                 {
 603                                         if(tell_to != self) // and we're allowed to send to them :D
 604                                         {
 605                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 606                                                 return;
 607                                         }
 608                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 609                                 }
 610                                 else if(argv(1) == "#0")
 611                                 {
 612                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 613                                         return;
 614                                 }
 615                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 616                         }
 617                 }
 618
 619                 default:
 620                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 621                 case CMD_REQUEST_USAGE:
 622                 {
 623                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 624                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 625                         return;
 626                 }
 627         }
 628 }
 629
 630 void ClientCommand_voice(float request, float argc, string command)
 631 {
 632         switch(request)
 633         {
 634                 case CMD_REQUEST_COMMAND:
 635                 {
 636                         if(argv(1) != "")
 637                         {
 638                                 if(argc >= 3)
 639                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 640                                 else
 641                                         VoiceMessage(argv(1), "");
 642
 643                                 return;
 644                         }
 645                 }
 646
 647                 default:
 648                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 649                 case CMD_REQUEST_USAGE:
 650                 {
 651                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 652                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 653                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 654                         return;
 655                 }
 656         }
 657 }
 658
 659 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 660 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 661 void ClientCommand_(float request)
 662 {
 663         switch(request)
 664         {
 665                 case CMD_REQUEST_COMMAND:
 666                 {
 667
 668                         return; // never fall through to usage
 669                 }
 670
 671                 default:
 672                 case CMD_REQUEST_USAGE:
 673                 {
 674                         sprint(self, "\nUsage:^3 cmd \n");
 675                         sprint(self, "  No arguments required.\n");
 676                         return;
 677                 }
 678         }
 679 }
 680 */
 681
 682
 683 // =====================================
 684 //  Macro system for networked commands
 685 // =====================================
 686
 687 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 688 #define CLIENT_COMMANDS(request,arguments,command) \
 689         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 690         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 691         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 692         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 693         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 694         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 695         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 696         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 697         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 698         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 699         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 700         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 701         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 702         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 703         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 704         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 705         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 706         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 707         /* nothing */
 708
 709 void ClientCommand_macro_help()
 710 {
 711         #define CLIENT_COMMAND(name,function,description) \
 712                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 713
 714         CLIENT_COMMANDS(0, 0, "")
 715         #undef CLIENT_COMMAND
 716
 717         return;
 718 }
 719
 720 float ClientCommand_macro_command(float argc, string command)
 721 {
 722         #define CLIENT_COMMAND(name,function,description) \
 723                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 724
 725         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 726         #undef CLIENT_COMMAND
 727
 728         return FALSE;
 729 }
 730
 731 float ClientCommand_macro_usage(float argc)
 732 {
 733         #define CLIENT_COMMAND(name,function,description) \
 734                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 735
 736         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 737         #undef CLIENT_COMMAND
 738
 739         return FALSE;
 740 }
 741
 742 void ClientCommand_macro_write_aliases(float fh)
 743 {
 744         #define CLIENT_COMMAND(name,function,description) \
 745                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 746
 747         CLIENT_COMMANDS(0, 0, "")
 748         #undef CLIENT_COMMAND
 749
 750         return;
 751 }
 752
 753 // ======================================
 754 //  Main Function Called By Engine (cmd)
 755 // ======================================
 756 // If this function exists, server game code parses clientcommand before the engine code gets it.
 757
 758 void SV_ParseClientCommand(string command)
 759 {
 760         // if we're banned, don't even parse the command
 761         if(Ban_MaybeEnforceBanOnce(self))
 762                 return;
 763
 764         float argc = tokenize_console(command);
 765
 766         // for the mutator hook system
 767         cmd_name = strtolower(argv(0));
 768         cmd_argc = argc;
 769         cmd_string = command;
 770
 771         // Guide for working with argc arguments by example:
 772         // argc:   1    - 2      - 3     - 4
 773         // argv:   0    - 1      - 2     - 3
 774         // cmd     vote - master - login - password
 775
 776         // for floodcheck
 777         switch(strtolower(argv(0)))
 778         {
 779                 // exempt commands which are not subject to floodcheck
 780                 case "begin": break; // handled by engine in host_cmd.c
 781                 case "download": break; // handled by engine in cl_parse.c
 782                 case "mv_getpicture": break; // handled by server in this file
 783                 case "pause": break; // handled by engine in host_cmd.c
 784                 case "prespawn": break; // handled by engine in host_cmd.c
 785                 case "sentcvar": break; // handled by server in this file
 786                 case "spawn": break; // handled by engine in host_cmd.c
 787
 788                 default:
 789                         if(SV_ParseClientCommand_floodcheck())
 790                                 break; // "TRUE": continue, as we're not flooding yet
 791                         else
 792                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 793         }
 794
 795         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 796         if(argv(0) == "help")
 797         {
 798                 if(argc == 1)
 799                 {
 800                         sprint(self, "\nClient networked commands:\n");
 801                         ClientCommand_macro_help();
 802
 803                         sprint(self, "\nCommon networked commands:\n");
 804                         CommonCommand_macro_help(self);
 805
 806                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 807                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 808                         return;
 809                 }
 810                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 811                 {
 812                         return;
 813                 }
 814                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 815                 {
 816                         return;
 817                 }
 818         }
 819         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 820         {
 821                 return; // handled by a mutator
 822         }
 823         else if(CheatCommand(argc))
 824         {
 825                 return; // handled by server/cheats.qc
 826         }
 827         else if(CommonCommand_macro_command(argc, self, command))
 828         {
 829                 return; // handled by server/command/common.qc
 830         }
 831         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 832         {
 833                 return; // handled by one of the above ClientCommand_* functions
 834         }
 835         else
 836                 clientcommand(self, command);
 837 }