qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(argv(1) && argv(2))
 192                         {
 193                                 makevectors(self.v_angle);
 194                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 195
 196                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 197                                 if(trace_ent.flags & FL_MONSTER)
 198                                 {
 199                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 200                                         switch(argv(1))
 201                                         {
 202                                                 case "skin":
 203                                                 {
 204                                                         if(trace_ent.monsterid != MON_MAGE)
 205                                                                 trace_ent.skin = stof(argv(2));
 206                                                         return;
 207                                                 }
 208                                                 case "movetarget":
 209                                                 {
 210                                                         trace_ent.monster_moveflags = stof(argv(2));
 211                                                         return;
 212                                                 }
 213                                         }
 214                                 }
 215                         }
 216                 }
 217                 default:
 218                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 219                 case CMD_REQUEST_USAGE:
 220                 {
 221                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 222                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 223                         sprint(self, "  Aim at your monster to edit its properties.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void ClientCommand_mobkill(float request)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         makevectors(self.v_angle);
 236                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 237
 238                         if(trace_ent.flags & FL_MONSTER)
 239                         {
 240                                 if(trace_ent.realowner != self)
 241                                 {
 242                                         sprint(self, "That monster does not belong to you.\n");
 243                                         return;
 244                                 }
 245                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 246                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 247                                 return;
 248                         }
 249                 }
 250
 251                 default:
 252                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 253                 case CMD_REQUEST_USAGE:
 254                 {
 255                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 256                         sprint(self, "  Aim at your monster to kill it.\n");
 257                         return;
 258                 }
 259         }
 260 }
 261
 262 void ClientCommand_mobspawn(float request, float argc)
 263 {
 264         switch(request)
 265         {
 266                 case CMD_REQUEST_COMMAND:
 267                 {
 268                         entity e;
 269                         string tospawn;
 270                         float moveflag, monstercount = 0;
 271
 272                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 273                         tospawn = strtolower(argv(1));
 274
 275                         if(tospawn == "list")
 276                         {
 277                                 sprint(self, monsterlist_reply);
 278                                 return;
 279                         }
 280
 281                         FOR_EACH_MONSTER(e)
 282                         {
 283                                 if(e.realowner == self)
 284                                         ++monstercount;
 285                         }
 286
 287                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 288                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 289                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 290                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 291                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 292                         else if(self.freezetag_frozen) { sprint(self, "You can't spawn monsters while frozen.\n"); return; }
 293                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 294                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 295                         else if(monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 296                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 297                         else if(tospawn != "")
 298                         {
 299                                 float found = 0, i;
 300                                 entity mon;
 301
 302                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 303                                 {
 304                                         mon = get_monsterinfo(i);
 305                                         if(mon.netname == tospawn)
 306                                         {
 307                                                 found = TRUE;
 308                                                 break;
 309                                         }
 310                                 }
 311
 312                                 if(found || tospawn == "random")
 313                                 {
 314                                         totalspawned += 1;
 315
 316                                         makevectors(self.v_angle);
 317                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 318                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 319
 320                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, FALSE, moveflag);
 321
 322                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 323
 324                                         return;
 325                                 }
 326                         }
 327                 }
 328
 329                 default:
 330                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 331                 case CMD_REQUEST_USAGE:
 332                 {
 333                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 334                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 335                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 336                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 337                         return;
 338                 }
 339         }
 340 }
 341
 342 void ClientCommand_physics(float request, float argc)
 343 {
 344         switch(request)
 345         {
 346                 case CMD_REQUEST_COMMAND:
 347                 {
 348                         string command = strtolower(argv(1));
 349
 350                         if(!autocvar_g_physics_clientselect)
 351                         {
 352                                 sprint(self, "Client physics selection is currently disabled.\n");
 353                                 return;
 354                         }
 355
 356                         if(command == "list" || command == "help")
 357                         {
 358                                 sprint(self, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 359                                 return;
 360                         }
 361
 362                         if(Physics_Valid(command) || command == "default")
 363                         {
 364                                 stuffcmd(self, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 365                                 sprint(self, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 366                                 return;
 367                         }
 368                 }
 369
 370                 default:
 371                         sprint(self, strcat("Current physics set: ^3", self.cvar_cl_physics, "\n"));
 372                 case CMD_REQUEST_USAGE:
 373                 {
 374                         sprint(self, "\nUsage:^3 cmd physics <physics>\n");
 375                         sprint(self, "  See 'cmd physics list' for available physics sets.\n");
 376                         sprint(self, "  Argument 'default' resets to standard physics.\n");
 377                         return;
 378                 }
 379         }
 380 }
 381
 382 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 383 {
 384         switch(request)
 385         {
 386                 case CMD_REQUEST_COMMAND:
 387                 {
 388                         if(IS_CLIENT(self))
 389                         {
 390                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 391                                 {
 392                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 393                                         {
 394                                                 if(time < game_starttime) // game is already restarting
 395                                                         return;
 396                                                 if (self.ready) // toggle
 397                                                 {
 398                                                         self.ready = FALSE;
 399                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 400                                                 }
 401                                                 else
 402                                                 {
 403                                                         self.ready = TRUE;
 404                                                         bprint(self.netname, "^2 is ready\n");
 405                                                 }
 406
 407                                                 // cannot reset the game while a timeout is active!
 408                                                 if (!timeout_status)
 409                                                         ReadyCount();
 410                                         } else {
 411                                                 sprint(self, "^1Game has already been restarted\n");
 412                                         }
 413                                 }
 414                         }
 415                         return; // never fall through to usage
 416                 }
 417
 418                 default:
 419                 case CMD_REQUEST_USAGE:
 420                 {
 421                         sprint(self, "\nUsage:^3 cmd ready\n");
 422                         sprint(self, "  No arguments required.\n");
 423                         return;
 424                 }
 425         }
 426 }
 427
 428 void ClientCommand_say(float request, float argc, string command)
 429 {
 430         switch(request)
 431         {
 432                 case CMD_REQUEST_COMMAND:
 433                 {
 434                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 435                         return; // never fall through to usage
 436                 }
 437
 438                 default:
 439                 case CMD_REQUEST_USAGE:
 440                 {
 441                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 442                         sprint(self, "  Where 'message' is the string of text to say.\n");
 443                         return;
 444                 }
 445         }
 446 }
 447
 448 void ClientCommand_say_team(float request, float argc, string command)
 449 {
 450         switch(request)
 451         {
 452                 case CMD_REQUEST_COMMAND:
 453                 {
 454                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 455                         return; // never fall through to usage
 456                 }
 457
 458                 default:
 459                 case CMD_REQUEST_USAGE:
 460                 {
 461                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 462                         sprint(self, "  Where 'message' is the string of text to say.\n");
 463                         return;
 464                 }
 465         }
 466 }
 467
 468 void ClientCommand_selectteam(float request, float argc)
 469 {
 470         switch(request)
 471         {
 472                 case CMD_REQUEST_COMMAND:
 473                 {
 474                         if(argv(1) != "")
 475                         {
 476                                 if(IS_CLIENT(self))
 477                                 {
 478                                         if(teamplay)
 479                                                 if(self.team_forced <= 0)
 480                                                         if (!lockteams)
 481                                                         {
 482                                                                 float selection;
 483
 484                                                                 switch(argv(1))
 485                                                                 {
 486                                                                         case "red": selection = NUM_TEAM_1; break;
 487                                                                         case "blue": selection = NUM_TEAM_2; break;
 488                                                                         case "yellow": selection = NUM_TEAM_3; break;
 489                                                                         case "pink": selection = NUM_TEAM_4; break;
 490                                                                         case "auto": selection = (-1); break;
 491
 492                                                                         default: selection = 0; break;
 493                                                                 }
 494
 495                                                                 if(selection)
 496                                                                 {
 497                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 498                                                                                 sprint(self, "^7You already are on that team.\n");
 499                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 500                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 501                                                                         else
 502                                                                         {
 503                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 504                                                                                 {
 505                                                                                         CheckAllowedTeams(self);
 506                                                                                         GetTeamCounts(self);
 507                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 508                                                                                         {
 509                                                                                                 sprint(self, "Cannot change to a larger/better/shinier team\n");
 510                                                                                                 return;
 511                                                                                         }
 512                                                                                 }
 513                                                                                 ClientKill_TeamChange(selection);
 514                                                                         }
 515                                                                 }
 516                                                         }
 517                                                         else
 518                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 519                                                 else
 520                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 521                                         else
 522                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 523                                 }
 524                                 return;
 525                         }
 526                 }
 527
 528                 default:
 529                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 530                 case CMD_REQUEST_USAGE:
 531                 {
 532                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 533                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 534                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 535                         return;
 536                 }
 537         }
 538 }
 539
 540 void ClientCommand_selfstuff(float request, string command)
 541 {
 542         switch(request)
 543         {
 544                 case CMD_REQUEST_COMMAND:
 545                 {
 546                         if(argv(1) != "")
 547                         {
 548                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 549                                 return;
 550                         }
 551                 }
 552
 553                 default:
 554                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 555                 case CMD_REQUEST_USAGE:
 556                 {
 557                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 558                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 559                         return;
 560                 }
 561         }
 562 }
 563
 564 void ClientCommand_sentcvar(float request, float argc, string command)
 565 {
 566         switch(request)
 567         {
 568                 case CMD_REQUEST_COMMAND:
 569                 {
 570                         if(argv(1) != "")
 571                         {
 572                                 //float tokens;
 573                                 string s;
 574
 575                                 if(argc == 2) // undefined cvar: use the default value on the server then
 576                                 {
 577                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 578                                         tokenize_console(s);
 579                                 }
 580
 581                                 GetCvars(1);
 582
 583                                 return;
 584                         }
 585                 }
 586
 587                 default:
 588                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 589                 case CMD_REQUEST_USAGE:
 590                 {
 591                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 592                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 593                         return;
 594                 }
 595         }
 596 }
 597
 598 void ClientCommand_spectate(float request)
 599 {
 600         switch(request)
 601         {
 602                 case CMD_REQUEST_COMMAND:
 603                 {
 604                         if(IS_CLIENT(self))
 605                         {
 606                                 if(g_lms)
 607                                 {
 608                                         if(self.lms_spectate_warning)
 609                                         {
 610                                                 // for the forfeit message...
 611                                                 self.lms_spectate_warning = 2;
 612                                                 // mark player as spectator
 613                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 614                                         }
 615                                         else
 616                                         {
 617                                                 self.lms_spectate_warning = 1;
 618                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 619                                                 return;
 620                                         }
 621                                 }
 622
 623                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 624                                         ClientKill_TeamChange(-2); // observe
 625
 626                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 627                                 // note: if arena game mode is ever done properly, this needs to be removed.
 628                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 629                                 {
 630                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 631                                         self.caplayer = 0;
 632                                 }
 633                         }
 634                         return; // never fall through to usage
 635                 }
 636
 637                 default:
 638                 case CMD_REQUEST_USAGE:
 639                 {
 640                         sprint(self, "\nUsage:^3 cmd spectate\n");
 641                         sprint(self, "  No arguments required.\n");
 642                         return;
 643                 }
 644         }
 645 }
 646
 647 void ClientCommand_suggestmap(float request, float argc)
 648 {
 649         switch(request)
 650         {
 651                 case CMD_REQUEST_COMMAND:
 652                 {
 653                         if(argv(1) != "")
 654                         {
 655                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 656                                 return;
 657                         }
 658                 }
 659
 660                 default:
 661                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 662                 case CMD_REQUEST_USAGE:
 663                 {
 664                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 665                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 666                         return;
 667                 }
 668         }
 669 }
 670
 671 void ClientCommand_tell(float request, float argc, string command)
 672 {
 673         switch(request)
 674         {
 675                 case CMD_REQUEST_COMMAND:
 676                 {
 677                         if(argc >= 3)
 678                         {
 679                                 entity tell_to = GetIndexedEntity(argc, 1);
 680                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 681
 682                                 if(tell_accepted > 0) // the target is a real client
 683                                 {
 684                                         if(tell_to != self) // and we're allowed to send to them :D
 685                                         {
 686                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 687                                                 return;
 688                                         }
 689                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 690                                 }
 691                                 else if(argv(1) == "#0")
 692                                 {
 693                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 694                                         return;
 695                                 }
 696                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 697                         }
 698                 }
 699
 700                 default:
 701                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 702                 case CMD_REQUEST_USAGE:
 703                 {
 704                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 705                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 706                         return;
 707                 }
 708         }
 709 }
 710
 711 void ClientCommand_voice(float request, float argc, string command)
 712 {
 713         switch(request)
 714         {
 715                 case CMD_REQUEST_COMMAND:
 716                 {
 717                         if(argv(1) != "")
 718                         {
 719                                 if(argc >= 3)
 720                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 721                                 else
 722                                         VoiceMessage(argv(1), "");
 723
 724                                 return;
 725                         }
 726                 }
 727
 728                 default:
 729                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 730                 case CMD_REQUEST_USAGE:
 731                 {
 732                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 733                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 734                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 735                         return;
 736                 }
 737         }
 738 }
 739
 740 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 741 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 742 void ClientCommand_(float request)
 743 {
 744         switch(request)
 745         {
 746                 case CMD_REQUEST_COMMAND:
 747                 {
 748
 749                         return; // never fall through to usage
 750                 }
 751
 752                 default:
 753                 case CMD_REQUEST_USAGE:
 754                 {
 755                         sprint(self, "\nUsage:^3 cmd \n");
 756                         sprint(self, "  No arguments required.\n");
 757                         return;
 758                 }
 759         }
 760 }
 761 */
 762
 763
 764 // =====================================
 765 //  Macro system for networked commands
 766 // =====================================
 767
 768 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 769 #define CLIENT_COMMANDS(request,arguments,command) \
 770         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 771         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 772         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 773         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 774         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 775         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 776         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 777         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 778         CLIENT_COMMAND("physics", ClientCommand_physics(request, arguments), "Change physics set") \
 779         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 780         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 781         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 782         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 783         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 784         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 785         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 786         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 787         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 788         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 789         /* nothing */
 790
 791 void ClientCommand_macro_help()
 792 {
 793         #define CLIENT_COMMAND(name,function,description) \
 794                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 795
 796         CLIENT_COMMANDS(0, 0, "")
 797         #undef CLIENT_COMMAND
 798
 799         return;
 800 }
 801
 802 float ClientCommand_macro_command(float argc, string command)
 803 {
 804         #define CLIENT_COMMAND(name,function,description) \
 805                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 806
 807         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 808         #undef CLIENT_COMMAND
 809
 810         return FALSE;
 811 }
 812
 813 float ClientCommand_macro_usage(float argc)
 814 {
 815         #define CLIENT_COMMAND(name,function,description) \
 816                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 817
 818         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 819         #undef CLIENT_COMMAND
 820
 821         return FALSE;
 822 }
 823
 824 void ClientCommand_macro_write_aliases(float fh)
 825 {
 826         #define CLIENT_COMMAND(name,function,description) \
 827                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 828
 829         CLIENT_COMMANDS(0, 0, "")
 830         #undef CLIENT_COMMAND
 831
 832         return;
 833 }
 834
 835 // ======================================
 836 //  Main Function Called By Engine (cmd)
 837 // ======================================
 838 // If this function exists, server game code parses clientcommand before the engine code gets it.
 839
 840 void SV_ParseClientCommand(string command)
 841 {
 842         // if we're banned, don't even parse the command
 843         if(Ban_MaybeEnforceBanOnce(self))
 844                 return;
 845
 846         float argc = tokenize_console(command);
 847
 848         // for the mutator hook system
 849         cmd_name = strtolower(argv(0));
 850         cmd_argc = argc;
 851         cmd_string = command;
 852
 853         // Guide for working with argc arguments by example:
 854         // argc:   1    - 2      - 3     - 4
 855         // argv:   0    - 1      - 2     - 3
 856         // cmd     vote - master - login - password
 857
 858         // for floodcheck
 859         switch(strtolower(argv(0)))
 860         {
 861                 // exempt commands which are not subject to floodcheck
 862                 case "begin": break; // handled by engine in host_cmd.c
 863                 case "download": break; // handled by engine in cl_parse.c
 864                 case "mv_getpicture": break; // handled by server in this file
 865                 case "pause": break; // handled by engine in host_cmd.c
 866                 case "prespawn": break; // handled by engine in host_cmd.c
 867                 case "sentcvar": break; // handled by server in this file
 868                 case "spawn": break; // handled by engine in host_cmd.c
 869
 870                 default:
 871                         if(SV_ParseClientCommand_floodcheck())
 872                                 break; // "TRUE": continue, as we're not flooding yet
 873                         else
 874                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 875         }
 876
 877         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 878         if(argv(0) == "help")
 879         {
 880                 if(argc == 1)
 881                 {
 882                         sprint(self, "\nClient networked commands:\n");
 883                         ClientCommand_macro_help();
 884
 885                         sprint(self, "\nCommon networked commands:\n");
 886                         CommonCommand_macro_help(self);
 887
 888                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 889                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 890                         return;
 891                 }
 892                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 893                 {
 894                         return;
 895                 }
 896                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 897                 {
 898                         return;
 899                 }
 900         }
 901         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 902         {
 903                 return; // handled by a mutator
 904         }
 905         else if(CheatCommand(argc))
 906         {
 907                 return; // handled by server/cheats.qc
 908         }
 909         else if(CommonCommand_macro_command(argc, self, command))
 910         {
 911                 return; // handled by server/command/common.qc
 912         }
 913         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 914         {
 915                 return; // handled by one of the above ClientCommand_* functions
 916         }
 917         else
 918                 clientcommand(self, command);
 919 }