qcsrc/server/command/common.qc

   1 // ====================================================
   2 //  Shared code for server commands, written by Samual
   3 //  Last updated: December 27th, 2011
   4 // ====================================================
   5
   6 // select the proper prefix for usage and other messages
   7 string GetCommandPrefix(entity caller)
   8 {
   9         if(caller)
  10                 return "cmd";
  11         else
  12                 return "sv_cmd";
  13 }
  14
  15 // if client return player nickname, or if server return admin nickname
  16 string GetCallerName(entity caller)
  17 {
  18         if(caller)
  19                 return caller.netname;
  20         else
  21                 return admin_name(); //((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  22 }
  23
  24 // verify that the client provided is acceptable for use
  25 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  26 {
  27         if not(IS_CLIENT(client))
  28                 return CLIENT_DOESNT_EXIST;
  29         else if(must_be_real && !IS_REAL_CLIENT(client))
  30                 return CLIENT_NOT_REAL;
  31         else if(must_be_bots && !IS_BOT_CLIENT(client))
  32                 return CLIENT_NOT_BOT;
  33
  34         return CLIENT_ACCEPTABLE;
  35 }
  36
  37 // if the client is not acceptable, return a string to be used for error messages
  38 string GetClientErrorString(float clienterror, string original_input)
  39 {
  40         switch(clienterror)
  41         {
  42                 case CLIENT_DOESNT_EXIST: { return strcat("Client '", original_input, "' doesn't exist"); }
  43                 case CLIENT_NOT_REAL: { return strcat("Client '", original_input, "' is not real"); }
  44                 case CLIENT_NOT_BOT: { return strcat("Client '", original_input, "' is not a bot"); }
  45                 default: { return "Incorrect usage of GetClientErrorString"; }
  46         }
  47 }
  48
  49 // is this entity number even in the possible range of entities?
  50 float VerifyClientNumber(float tmp_number)
  51 {
  52         if((tmp_number < 1) || (tmp_number > maxclients))
  53                 return FALSE;
  54         else
  55                 return TRUE;
  56 }
  57
  58 entity GetIndexedEntity(float argc, float start_index)
  59 {
  60         entity tmp_player, selection;
  61         float tmp_number, index;
  62         string tmp_string;
  63
  64         next_token = -1;
  65         index = start_index;
  66         selection = world;
  67
  68         if(argc > start_index)
  69         {
  70                 if(substring(argv(index), 0, 1) == "#")
  71                 {
  72                         tmp_string = substring(argv(index), 1, -1);
  73                         ++index;
  74
  75                         if(tmp_string != "") // is it all one token? like #1
  76                         {
  77                                 tmp_number = stof(tmp_string);
  78                         }
  79                         else if(argc > index) // no, it's two tokens? # 1
  80                         {
  81                                 tmp_number = stof(argv(index));
  82                                 ++index;
  83                         }
  84                         else
  85                                 tmp_number = 0;
  86                 }
  87                 else // maybe it's ONLY a number?
  88                 {
  89                         tmp_number = stof(argv(index));
  90                         ++index;
  91                 }
  92
  93                 if(VerifyClientNumber(tmp_number))
  94                 {
  95                         selection = edict_num(tmp_number); // yes, it was a number
  96                 }
  97                 else // no, maybe it's a name?
  98                 {
  99                         FOR_EACH_CLIENT(tmp_player)
 100                                 if (strdecolorize(tmp_player.netname) == strdecolorize(argv(start_index)))
 101                                         selection = tmp_player;
 102
 103                         index = (start_index + 1);
 104                 }
 105         }
 106
 107         next_token = index;
 108         //print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 109         return selection;
 110 }
 111
 112 // find a player which matches the input string, and return their entity
 113 entity GetFilteredEntity(string input)
 114 {
 115         entity tmp_player, selection;
 116         float tmp_number;
 117
 118         if(substring(input, 0, 1) == "#")
 119                 tmp_number = stof(substring(input, 1, -1));
 120         else
 121                 tmp_number = stof(input);
 122
 123         if(VerifyClientNumber(tmp_number))
 124         {
 125                 selection = edict_num(tmp_number);
 126         }
 127         else
 128         {
 129                 selection = world;
 130                 FOR_EACH_CLIENT(tmp_player)
 131                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
 132                                 selection = tmp_player;
 133         }
 134
 135         return selection;
 136 }
 137
 138 // same thing, but instead return their edict number
 139 float GetFilteredNumber(string input)
 140 {
 141         entity selection = GetFilteredEntity(input);
 142         float output;
 143
 144         output = num_for_edict(selection);
 145
 146         return output;
 147 }
 148
 149 // switch between sprint and print depending on whether the receiver is the server or a player
 150 void print_to(entity to, string input)
 151 {
 152     if(to)
 153         sprint(to, strcat(input, "\n"));
 154     else
 155         print(input, "\n");
 156 }
 157
 158 // ==========================================
 159 //  Supporting functions for common commands
 160 // ==========================================
 161
 162 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 163 void timeout_handler_reset()
 164 {
 165         entity tmp_player;
 166
 167         timeout_caller = world;
 168         timeout_time = 0;
 169         timeout_leadtime = 0;
 170
 171         FOR_EACH_REALPLAYER(tmp_player)
 172                 Send_CSQC_Centerprint_Generic_Expire(tmp_player, CPID_TIMEOUT_COUNTDOWN);
 173
 174         remove(self);
 175 }
 176
 177 void timeout_handler_think()
 178 {
 179         entity tmp_player;
 180
 181         switch(timeout_status)
 182         {
 183                 case TIMEOUT_ACTIVE:
 184                 {
 185                         if(timeout_time > 0) // countdown is still going
 186                         {
 187                                 FOR_EACH_REALPLAYER(tmp_player)
 188                                         Send_CSQC_Centerprint_Generic(tmp_player, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, timeout_time);
 189
 190                                 if(timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 191                                         Announce("prepareforbattle");
 192
 193                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE; // think again in one second
 194                                 timeout_time -= 1; // decrease the time counter
 195                         }
 196                         else // time to end the timeout
 197                         {
 198                                 timeout_status = TIMEOUT_INACTIVE;
 199
 200                                 // reset the slowmo value back to normal
 201                                 cvar_set("slowmo", ftos(orig_slowmo));
 202
 203                                 // unlock the view for players so they can move around again
 204                                 FOR_EACH_REALPLAYER(tmp_player)
 205                                         tmp_player.fixangle = FALSE;
 206
 207                                 timeout_handler_reset();
 208                         }
 209
 210                         return;
 211                 }
 212
 213                 case TIMEOUT_LEADTIME:
 214                 {
 215                         if(timeout_leadtime > 0) // countdown is still going
 216                         {
 217                                 // centerprint the information to every player
 218                                 FOR_EACH_REALPLAYER(tmp_player)
 219                                         Send_CSQC_Centerprint_Generic(tmp_player, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, timeout_leadtime);
 220
 221                                 self.nextthink = time + 1; // think again in one second
 222                                 timeout_leadtime -= 1; // decrease the time counter
 223                         }
 224                         else // time to begin the timeout
 225                         {
 226                                 timeout_status = TIMEOUT_ACTIVE;
 227
 228                                 // set the slowmo value to the timeout default slowmo value
 229                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 230
 231                                 // reset all the flood variables
 232                                 FOR_EACH_CLIENT(tmp_player)
 233                                         tmp_player.nickspamcount = tmp_player.nickspamtime = tmp_player.floodcontrol_chat =
 234                                         tmp_player.floodcontrol_chatteam = tmp_player.floodcontrol_chattell =
 235                                         tmp_player.floodcontrol_voice = tmp_player.floodcontrol_voiceteam = 0;
 236
 237                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 238                                 FOR_EACH_REALPLAYER(tmp_player)
 239                                         tmp_player.lastV_angle = tmp_player.v_angle;
 240
 241                                 self.nextthink = time; // think again next frame to handle it under TIMEOUT_ACTIVE code
 242                         }
 243
 244                         return;
 245                 }
 246
 247
 248                 case TIMEOUT_INACTIVE:
 249                 default:
 250                 {
 251                         timeout_handler_reset();
 252                         return;
 253                 }
 254         }
 255 }
 256
 257
 258
 259 // ===================================================
 260 //  Common commands used in both sv_cmd.qc and cmd.qc
 261 // ===================================================
 262
 263 void CommonCommand_cvar_changes(float request, entity caller)
 264 {
 265         switch(request)
 266         {
 267                 case CMD_REQUEST_COMMAND:
 268                 {
 269                         print_to(caller, cvar_changes);
 270                         return; // never fall through to usage
 271                 }
 272
 273                 default:
 274                 case CMD_REQUEST_USAGE:
 275                 {
 276                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 277                         print_to(caller, "  No arguments required.");
 278                         print_to(caller, "See also: ^2cvar_purechanges^7");
 279                         return;
 280                 }
 281         }
 282 }
 283
 284 void CommonCommand_cvar_purechanges(float request, entity caller)
 285 {
 286         switch(request)
 287         {
 288                 case CMD_REQUEST_COMMAND:
 289                 {
 290                         print_to(caller, cvar_purechanges);
 291                         return; // never fall through to usage
 292                 }
 293
 294                 default:
 295                 case CMD_REQUEST_USAGE:
 296                 {
 297                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 298                         print_to(caller, "  No arguments required.");
 299                         print_to(caller, "See also: ^2cvar_changes^7");
 300                         return;
 301                 }
 302         }
 303 }
 304
 305 void CommonCommand_info(float request, entity caller, float argc)
 306 {
 307         switch(request)
 308         {
 309                 case CMD_REQUEST_COMMAND:
 310                 {
 311                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 312
 313                         if(command)
 314                                 wordwrap_sprint(command, 1000);
 315                         else
 316                                 print_to(caller, "ERROR: unsupported info command");
 317
 318                         return; // never fall through to usage
 319                 }
 320
 321                 default:
 322                 case CMD_REQUEST_USAGE:
 323                 {
 324                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 325                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 326                         return;
 327                 }
 328         }
 329 }
 330
 331 void CommonCommand_ladder(float request, entity caller)
 332 {
 333         switch(request)
 334         {
 335                 case CMD_REQUEST_COMMAND:
 336                 {
 337                         print_to(caller, ladder_reply);
 338                         return; // never fall through to usage
 339                 }
 340
 341                 default:
 342                 case CMD_REQUEST_USAGE:
 343                 {
 344                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 345                         print_to(caller, "  No arguments required.");
 346                         return;
 347                 }
 348         }
 349 }
 350
 351 void CommonCommand_lsmaps(float request, entity caller)
 352 {
 353         switch(request)
 354         {
 355                 case CMD_REQUEST_COMMAND:
 356                 {
 357                         print_to(caller, lsmaps_reply);
 358                         return; // never fall through to usage
 359                 }
 360
 361                 default:
 362                 case CMD_REQUEST_USAGE:
 363                 {
 364                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 365                         print_to(caller, "  No arguments required.");
 366                         return;
 367                 }
 368         }
 369 }
 370
 371 void CommonCommand_lsnewmaps(float request, entity caller)
 372 {
 373         switch(request)
 374         {
 375                 case CMD_REQUEST_COMMAND:
 376                 {
 377                         print_to(caller, lsnewmaps_reply);
 378                         return; // never fall through to usage
 379                 }
 380
 381                 default:
 382                 case CMD_REQUEST_USAGE:
 383                 {
 384                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsnewmaps"));
 385                         print_to(caller, "  No arguments required.");
 386                         return;
 387                 }
 388         }
 389 }
 390
 391 void CommonCommand_printmaplist(float request, entity caller)
 392 {
 393         switch(request)
 394         {
 395                 case CMD_REQUEST_COMMAND:
 396                 {
 397                         print_to(caller, maplist_reply);
 398                         return; // never fall through to usage
 399                 }
 400
 401                 default:
 402                 case CMD_REQUEST_USAGE:
 403                 {
 404                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 405                         print_to(caller, "  No arguments required.");
 406                         return;
 407                 }
 408         }
 409 }
 410
 411 void CommonCommand_rankings(float request, entity caller)
 412 {
 413         switch(request)
 414         {
 415                 case CMD_REQUEST_COMMAND:
 416                 {
 417                         print_to(caller, rankings_reply);
 418                         return; // never fall through to usage
 419                 }
 420
 421                 default:
 422                 case CMD_REQUEST_USAGE:
 423                 {
 424                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 425                         print_to(caller, "  No arguments required.");
 426                         return;
 427                 }
 428         }
 429 }
 430
 431 void CommonCommand_records(float request, entity caller)
 432 {
 433         switch(request)
 434         {
 435                 case CMD_REQUEST_COMMAND:
 436                 {
 437                         float i;
 438
 439                         for(i = 0; i < 10; ++i)
 440                                 if(records_reply[i] != "")
 441                                         print_to(caller, records_reply[i]);
 442
 443                         return; // never fall through to usage
 444                 }
 445
 446                 default:
 447                 case CMD_REQUEST_USAGE:
 448                 {
 449                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 450                         print_to(caller, "  No arguments required.");
 451                         return;
 452                 }
 453         }
 454 }
 455
 456 void CommonCommand_teamstatus(float request, entity caller)
 457 {
 458         switch(request)
 459         {
 460                 case CMD_REQUEST_COMMAND:
 461                 {
 462                         Score_NicePrint(caller);
 463                         return; // never fall through to usage
 464                 }
 465
 466                 default:
 467                 case CMD_REQUEST_USAGE:
 468                 {
 469                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 470                         print_to(caller, "  No arguments required.");
 471                         return;
 472                 }
 473         }
 474 }
 475
 476 void CommonCommand_time(float request, entity caller)
 477 {
 478         switch(request)
 479         {
 480                 case CMD_REQUEST_COMMAND:
 481                 {
 482                         print_to(caller, strcat("time = ", ftos(time)));
 483                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 484                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 485                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 486                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 487                         print_to(caller, strcat("localtime = ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y")));
 488                         print_to(caller, strcat("gmtime = ", strftime(FALSE, "%a %b %e %H:%M:%S %Z %Y")));
 489                         return;
 490                 }
 491
 492                 default:
 493                 case CMD_REQUEST_USAGE:
 494                 {
 495                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 496                         print_to(caller, "  No arguments required.");
 497                         return;
 498                 }
 499         }
 500 }
 501
 502 void CommonCommand_timein(float request, entity caller)
 503 {
 504         switch(request)
 505         {
 506                 case CMD_REQUEST_COMMAND:
 507                 {
 508                         if(!caller || autocvar_sv_timeout)
 509                         {
 510                                 if not(timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 511                                 else if(caller && (caller != timeout_caller)) { print_to(caller, "^7Error: You are not allowed to stop the active timeout."); }
 512
 513                                 else // everything should be okay, continue aborting timeout
 514                                 {
 515                                         switch(timeout_status)
 516                                         {
 517                                                 case TIMEOUT_LEADTIME:
 518                                                 {
 519                                                         timeout_status = TIMEOUT_INACTIVE;
 520                                                         timeout_time = 0;
 521                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 522                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 523                                                         return;
 524                                                 }
 525
 526                                                 case TIMEOUT_ACTIVE:
 527                                                 {
 528                                                         timeout_time = autocvar_sv_timeout_resumetime;
 529                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 530                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 531                                                         return;
 532                                                 }
 533
 534                                                 default: dprint("timeout status was inactive, but this code was executed anyway?"); return;
 535                                         }
 536                                 }
 537                         }
 538                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 539
 540                         return; // never fall through to usage
 541                 }
 542
 543                 default:
 544                 case CMD_REQUEST_USAGE:
 545                 {
 546                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 547                         print_to(caller, "  No arguments required.");
 548                         return;
 549                 }
 550         }
 551 }
 552
 553 void CommonCommand_timeout(float request, entity caller) // DEAR GOD THIS COMMAND IS TERRIBLE.
 554 {
 555         switch(request)
 556         {
 557                 case CMD_REQUEST_COMMAND:
 558                 {
 559                         if(!caller || autocvar_sv_timeout)
 560                         {
 561                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 562
 563                                 if(timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 564                                 else if(vote_called) { print_to(caller, "^7Error: You can not call a timeout while a vote is active."); }
 565                                 else if(inWarmupStage && !g_warmup_allow_timeout) { print_to(caller, "^7Error: You can not call a timeout in warmup-stage."); }
 566                                 else if(time < game_starttime) { print_to(caller, "^7Error: You can not call a timeout while the map is being restarted."); }
 567                                 else if(caller && (caller.allowed_timeouts < 1)) { print_to(caller, "^7Error: You already used all your timeout calls for this map."); }
 568                                 else if(caller && !IS_PLAYER(caller)) { print_to(caller, "^7Error: You must be a player to call a timeout."); }
 569                                 else if((autocvar_timelimit) && (last_possible_timeout < time - game_starttime)) { print_to(caller, "^7Error: It is too late to call a timeout now!"); }
 570
 571                                 else // everything should be okay, proceed with starting the timeout
 572                                 {
 573                                         if(caller) { caller.allowed_timeouts -= 1; }
 574
 575                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n"); // write a bprint who started the timeout (and how many they have left)
 576
 577                                         timeout_status = TIMEOUT_LEADTIME;
 578                                         timeout_caller = caller;
 579                                         timeout_time = autocvar_sv_timeout_length;
 580                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 581
 582                                         timeout_handler = spawn();
 583                                         timeout_handler.think = timeout_handler_think;
 584                                         timeout_handler.nextthink = time; // always let the entity think asap
 585
 586                                         Announce("timeoutcalled");
 587                                 }
 588                         }
 589                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 590
 591                         return; // never fall through to usage
 592                 }
 593
 594                 default:
 595                 case CMD_REQUEST_USAGE:
 596                 {
 597                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 598                         print_to(caller, "  No arguments required.");
 599                         return;
 600                 }
 601         }
 602 }
 603
 604 void CommonCommand_who(float request, entity caller, float argc)
 605 {
 606         switch(request)
 607         {
 608                 case CMD_REQUEST_COMMAND:
 609                 {
 610                         float total_listed_players, tmp_hours, tmp_minutes, tmp_seconds, is_bot;
 611                         entity tmp_player;
 612
 613                         float privacy = (caller && autocvar_sv_status_privacy);
 614                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 615                         string tmp_netaddress, tmp_crypto_idfp;
 616
 617                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 618                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 619                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 620
 621                         total_listed_players = 0;
 622                         FOR_EACH_CLIENT(tmp_player)
 623                         {
 624                                 is_bot = (IS_BOT_CLIENT(tmp_player));
 625
 626                                 if(is_bot)
 627                                 {
 628                                         tmp_netaddress = "null/botclient";
 629                                         tmp_crypto_idfp = "null/botclient";
 630                                 }
 631                                 else if(privacy)
 632                                 {
 633                                         tmp_netaddress = "hidden";
 634                                         tmp_crypto_idfp = "hidden";
 635                                 }
 636                                 else
 637                                 {
 638                                         tmp_netaddress = tmp_player.netaddress;
 639                                         tmp_crypto_idfp = tmp_player.crypto_idfp;
 640                                 }
 641
 642                                 tmp_hours = tmp_minutes = tmp_seconds = 0;
 643
 644                                 tmp_seconds = floor(time - tmp_player.jointime);
 645                                 tmp_minutes = floor(tmp_seconds / 60);
 646                                 tmp_hours = floor(tmp_minutes / 60);
 647
 648                                 if(tmp_minutes) { tmp_seconds -= (tmp_minutes * 60); }
 649                                 if(tmp_hours) { tmp_minutes -= (tmp_hours * 60); }
 650
 651                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 652                                         num_for_edict(tmp_player),
 653                                         tmp_player.netname,
 654                                         tmp_player.ping,
 655                                         tmp_player.ping_packetloss,
 656                                         sprintf("%02d:%02d:%02d", tmp_hours, tmp_minutes, tmp_seconds),
 657                                         tmp_netaddress,
 658                                         tmp_crypto_idfp));
 659
 660                                 ++total_listed_players;
 661                         }
 662
 663                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 664
 665                         return; // never fall through to usage
 666                 }
 667
 668                 default:
 669                 case CMD_REQUEST_USAGE:
 670                 {
 671                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 672                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 673                         return;
 674                 }
 675         }
 676 }
 677
 678 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 679 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 680 void CommonCommand_(float request, entity caller)
 681 {
 682         switch(request)
 683         {
 684                 case CMD_REQUEST_COMMAND:
 685                 {
 686
 687                         return; // never fall through to usage
 688                 }
 689
 690                 default:
 691                 case CMD_REQUEST_USAGE:
 692                 {
 693                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 694                         print_to(caller, "  No arguments required.");
 695                         return;
 696                 }
 697         }
 698 }
 699 */
 700
 701
 702 // ==================================
 703 //  Macro system for common commands
 704 // ==================================
 705
 706 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 707 #define COMMON_COMMANDS(request,caller,arguments,command) \
 708         COMMON_COMMAND("cvar_changes", CommonCommand_cvar_changes(request, caller), "Prints a list of all changed server cvars") \
 709         COMMON_COMMAND("cvar_purechanges", CommonCommand_cvar_purechanges(request, caller), "Prints a list of all changed gameplay cvars") \
 710         COMMON_COMMAND("info", CommonCommand_info(request, caller, arguments), "Request for unique server information set up by admin") \
 711         COMMON_COMMAND("ladder", CommonCommand_ladder(request, caller), "Get information about top players if supported") \
 712         COMMON_COMMAND("lsmaps", CommonCommand_lsmaps(request, caller), "List maps which can be used with the current game mode") \
 713         COMMON_COMMAND("lsnewmaps", CommonCommand_lsnewmaps(request, caller), "List maps which have no records or are seemingly unplayed yet") \
 714         COMMON_COMMAND("printmaplist", CommonCommand_printmaplist(request, caller), "Display full server maplist reply") \
 715         COMMON_COMMAND("rankings", CommonCommand_rankings(request, caller), "Print information about rankings") \
 716         COMMON_COMMAND("records", CommonCommand_records(request, caller), "List top 10 records for the current map") \
 717         COMMON_COMMAND("teamstatus", CommonCommand_teamstatus(request, caller), "Show information about player and team scores") \
 718         COMMON_COMMAND("time", CommonCommand_time(request, caller), "Print different formats/readouts of time") \
 719         COMMON_COMMAND("timein", CommonCommand_timein(request, caller), "Resume the game from being paused with a timeout") \
 720         COMMON_COMMAND("timeout", CommonCommand_timeout(request, caller), "Call a timeout which pauses the game for certain amount of time unless unpaused") \
 721         COMMON_COMMAND("vote", VoteCommand(request, caller, arguments, command), "Request an action to be voted upon by players") \
 722         COMMON_COMMAND("who", CommonCommand_who(request, caller, arguments), "Display detailed client information about all players") \
 723         /* nothing */
 724
 725 void CommonCommand_macro_help(entity caller)
 726 {
 727         #define COMMON_COMMAND(name,function,description) \
 728                 { print_to(caller, strcat("  ^2", name, "^7: ", description)); }
 729
 730         COMMON_COMMANDS(0, caller, 0, "")
 731         #undef COMMON_COMMAND
 732
 733         return;
 734 }
 735
 736 float CommonCommand_macro_command(float argc, entity caller, string command)
 737 {
 738         #define COMMON_COMMAND(name,function,description) \
 739                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 740
 741         COMMON_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, command)
 742         #undef COMMON_COMMAND
 743
 744         return FALSE;
 745 }
 746
 747 float CommonCommand_macro_usage(float argc, entity caller)
 748 {
 749         #define COMMON_COMMAND(name,function,description) \
 750                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 751
 752         COMMON_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
 753         #undef COMMON_COMMAND
 754
 755         return FALSE;
 756 }
 757
 758 void CommonCommand_macro_write_aliases(float fh)
 759 {
 760         #define COMMON_COMMAND(name,function,description) \
 761                 { CMD_Write_Alias("qc_cmd_svcmd", name, description); }
 762
 763         COMMON_COMMANDS(0, world, 0, "")
 764         #undef COMMON_COMMAND
 765
 766         return;
 767 }