qcsrc/server/command/common.qc

   1 #include "common.qh"
   2
   3 #include <server/client.qh>
   4 #include <server/defs.qh>
   5 #include <server/g_world.qh>
   6 #include <server/miscfunctions.qh>
   7
   8 #include <common/command/_mod.qh>
   9 #include "common.qh"
  10
  11 #include "../scores.qh"
  12
  13 #include <common/monsters/_mod.qh>
  14 #include <common/notifications/all.qh>
  15 #include <lib/warpzone/common.qh>
  16
  17
  18 // ====================================================
  19 //  Shared code for server commands, written by Samual
  20 //  Last updated: December 27th, 2011
  21 // ====================================================
  22
  23 // select the proper prefix for usage and other messages
  24 string GetCommandPrefix(entity caller)
  25 {
  26         if (caller) return "cmd";
  27         else return "sv_cmd";
  28 }
  29
  30 // if client return player nickname, or if server return admin nickname
  31 string GetCallerName(entity caller)
  32 {
  33         if (caller) return playername(caller, false);
  34         else return ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : "SERVER ADMIN"); // autocvar_hostname
  35 }
  36
  37 // verify that the client provided is acceptable for kicking
  38 float VerifyKickableEntity(entity client)
  39 {
  40         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  41         return CLIENT_ACCEPTABLE;
  42 }
  43
  44 // verify that the client provided is acceptable for use
  45 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  46 {
  47         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  48         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  49         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  50
  51         return CLIENT_ACCEPTABLE;
  52 }
  53
  54 // if the client is not acceptable, return a string to be used for error messages
  55 string GetClientErrorString_color(float clienterror, string original_input, string col)
  56 {
  57         switch (clienterror)
  58         {
  59                 case CLIENT_DOESNT_EXIST:
  60                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  61                 }
  62                 case CLIENT_NOT_REAL:
  63                 { return strcat(col, "Client '", original_input, col, "' is not real");
  64                 }
  65                 case CLIENT_NOT_BOT:
  66                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  67                 }
  68                 default:
  69                 { return "Incorrect usage of GetClientErrorString";
  70                 }
  71         }
  72 }
  73
  74 // is this entity number even in the possible range of entities?
  75 float VerifyClientNumber(float tmp_number)
  76 {
  77         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  78         else return true;
  79 }
  80
  81 entity GetIndexedEntity(int argc, float start_index)
  82 {
  83         entity selection;
  84         float tmp_number, index;
  85         string tmp_string;
  86
  87         next_token = -1;
  88         index = start_index;
  89         selection = NULL;
  90
  91         if (argc > start_index)
  92         {
  93                 if (substring(argv(index), 0, 1) == "#")
  94                 {
  95                         tmp_string = substring(argv(index), 1, -1);
  96                         ++index;
  97
  98                         if (tmp_string != "")  // is it all one token? like #1
  99                         {
 100                                 tmp_number = stof(tmp_string);
 101                         }
 102                         else if (argc > index)  // no, it's two tokens? # 1
 103                         {
 104                                 tmp_number = stof(argv(index));
 105                                 ++index;
 106                         }
 107                         else
 108                         {
 109                                 tmp_number = 0;
 110                         }
 111                 }
 112                 else  // maybe it's ONLY a number?
 113                 {
 114                         tmp_number = stof(argv(index));
 115                         ++index;
 116                 }
 117
 118                 if (VerifyClientNumber(tmp_number))
 119                 {
 120                         selection = edict_num(tmp_number);  // yes, it was a number
 121                 }
 122                 else  // no, maybe it's a name?
 123                 {
 124                         FOREACH_CLIENT(true, {
 125                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 126                                 {
 127                                         selection = it;
 128                                         break; // no reason to keep looking
 129                                 }
 130                         });
 131
 132                         index = (start_index + 1);
 133                 }
 134         }
 135
 136         next_token = index;
 137         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 138         return selection;
 139 }
 140
 141 // find a player which matches the input string, and return their entity
 142 entity GetFilteredEntity(string input)
 143 {
 144         entity selection;
 145         float tmp_number;
 146
 147         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 148         else tmp_number = stof(input);
 149
 150         if (VerifyClientNumber(tmp_number))
 151         {
 152                 selection = edict_num(tmp_number);
 153         }
 154         else
 155         {
 156                 selection = NULL;
 157                 FOREACH_CLIENT(true, {
 158                         if(strdecolorize(it.netname) == strdecolorize(input))
 159                         {
 160                                 selection = it;
 161                                 break; // no reason to keep looking
 162                         }
 163                 });
 164         }
 165
 166         return selection;
 167 }
 168
 169 // same thing, but instead return their edict number
 170 float GetFilteredNumber(string input)
 171 {
 172         entity selection = GetFilteredEntity(input);
 173         float output;
 174
 175         output = etof(selection);
 176
 177         return output;
 178 }
 179
 180 // switch between sprint and print depending on whether the receiver is the server or a player
 181 void print_to(entity to, string input)
 182 {
 183         if (to) sprint(to, strcat(input, "\n"));
 184         else print(input, "\n");
 185 }
 186
 187 // ==========================================
 188 //  Supporting functions for common commands
 189 // ==========================================
 190
 191 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 192 void timeout_handler_reset(entity this)
 193 {
 194         timeout_caller = NULL;
 195         timeout_time = 0;
 196         timeout_leadtime = 0;
 197
 198         delete(this);
 199 }
 200
 201 void timeout_handler_think(entity this)
 202 {
 203         switch (timeout_status)
 204         {
 205                 case TIMEOUT_ACTIVE:
 206                 {
 207                         if (timeout_time > 0)  // countdown is still going
 208                         {
 209                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 210
 211                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 212                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_PREPARE);
 213
 214                                 this.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 215                                 timeout_time -= 1;                                  // decrease the time counter
 216                         }
 217                         else  // time to end the timeout
 218                         {
 219                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_TIMEIN);
 220                                 timeout_status = TIMEOUT_INACTIVE;
 221
 222                                 // reset the slowmo value back to normal
 223                                 cvar_set("slowmo", ftos(orig_slowmo));
 224
 225                                 // unlock the view for players so they can move around again
 226                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 227                                         it.fixangle = false;
 228                                 });
 229
 230                                 timeout_handler_reset(this);
 231                         }
 232
 233                         return;
 234                 }
 235
 236                 case TIMEOUT_LEADTIME:
 237                 {
 238                         if (timeout_leadtime > 0)  // countdown is still going
 239                         {
 240                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 241
 242                                 this.nextthink = time + 1; // think again in one second
 243                                 timeout_leadtime -= 1;     // decrease the time counter
 244                         }
 245                         else  // time to begin the timeout
 246                         {
 247                                 timeout_status = TIMEOUT_ACTIVE;
 248
 249                                 // set the slowmo value to the timeout default slowmo value
 250                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 251
 252                                 // reset all the flood variables
 253                                 FOREACH_CLIENT(true, {
 254                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 255                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 256                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 257                                 });
 258
 259                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 260                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 261                                         it.lastV_angle = it.v_angle;
 262                                 });
 263
 264                                 this.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 265                         }
 266
 267                         return;
 268                 }
 269
 270
 271                 case TIMEOUT_INACTIVE:
 272                 default:
 273                 {
 274                         timeout_handler_reset(this);
 275                         return;
 276                 }
 277         }
 278 }
 279
 280
 281 // ===================================================
 282 //  Common commands used in both sv_cmd.qc and cmd.qc
 283 // ===================================================
 284
 285 void CommonCommand_cvar_changes(int request, entity caller)
 286 {
 287         switch (request)
 288         {
 289                 case CMD_REQUEST_COMMAND:
 290                 {
 291                         print_to(caller, cvar_changes);
 292                         return;  // never fall through to usage
 293                 }
 294
 295                 default:
 296                 case CMD_REQUEST_USAGE:
 297                 {
 298                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 299                         print_to(caller, "  No arguments required.");
 300                         print_to(caller, "See also: ^2cvar_purechanges^7");
 301                         return;
 302                 }
 303         }
 304 }
 305
 306 void CommonCommand_cvar_purechanges(int request, entity caller)
 307 {
 308         switch (request)
 309         {
 310                 case CMD_REQUEST_COMMAND:
 311                 {
 312                         print_to(caller, cvar_purechanges);
 313                         return;  // never fall through to usage
 314                 }
 315
 316                 default:
 317                 case CMD_REQUEST_USAGE:
 318                 {
 319                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 320                         print_to(caller, "  No arguments required.");
 321                         print_to(caller, "See also: ^2cvar_changes^7");
 322                         return;
 323                 }
 324         }
 325 }
 326
 327 void CommonCommand_editmob(int request, entity caller, int argc)
 328 {
 329         switch (request)
 330         {
 331                 case CMD_REQUEST_COMMAND:
 332                 {
 333                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 334                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 335
 336                         if (caller)
 337                         {
 338                                 makevectors(caller.v_angle);
 339                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 340                         }
 341
 342                         entity mon = trace_ent;
 343                         bool is_visible = IS_MONSTER(mon);
 344                         string argument = argv(2);
 345
 346                         switch (argv(1))
 347                         {
 348                                 case "name":
 349                                 {
 350                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 351                                         if (!argument)   break;  // escape to usage
 352                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 353                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 354                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 355
 356                                         string mon_oldname = mon.monster_name;
 357
 358                                         mon.monster_name = argument;
 359                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 360                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 361                                         return;
 362                                 }
 363                                 case "spawn":
 364                                 {
 365                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 366                                         if (!argv(2))   break;  // escape to usage
 367
 368                                         int moveflag, tmp_moncount = 0;
 369                                         string arg_lower = strtolower(argument);
 370                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 371
 372                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 373
 374                                         IL_EACH(g_monsters, it.realowner == caller,
 375                                         {
 376                                                 ++tmp_moncount;
 377                                         });
 378
 379                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 380                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 381                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 382                                         if (MUTATOR_CALLHOOK(AllowMobSpawning, caller)) { print_to(caller, M_ARGV(1, string)); return; }
 383                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 384                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 385                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 386                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 387                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 388
 389                                         bool found = false;
 390                                         FOREACH(Monsters, it != MON_Null && it.netname == arg_lower,
 391                                         {
 392                                                 found = true;
 393                                                 break;
 394                                         });
 395
 396                                         if (!found && arg_lower != "random" && arg_lower != "anyrandom") { print_to(caller, "Invalid monster"); return; }
 397
 398                                         totalspawned += 1;
 399                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 400                                         mon = spawnmonster(spawn(), arg_lower, MON_Null, caller, caller, trace_endpos, false, false, moveflag);
 401                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 402                                         return;
 403                                 }
 404                                 case "kill":
 405                                 {
 406                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 407                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 408                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 409
 410                                         Damage(mon, NULL, NULL, GetResource(mon, RES_HEALTH) + mon.max_health + 200, DEATH_KILL.m_id, DMG_NOWEP, mon.origin, '0 0 0');
 411                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 412                                         return;
 413                                 }
 414                                 case "skin":
 415                                 {
 416                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 417                                         if (!argument)   break;  // escape to usage
 418                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 419                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 420                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 421                                         if (mon.monsterdef == MON_MAGE) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 422
 423                                         mon.skin = stof(argument);
 424                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 425                                         return;
 426                                 }
 427                                 case "movetarget":
 428                                 {
 429                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 430                                         if (!argument)   break;  // escape to usage
 431                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 432                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 433                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 434
 435                                         mon.monster_moveflags = stof(argument);
 436                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 437                                         return;
 438                                 }
 439                                 case "butcher":
 440                                 {
 441                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 442                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(M_ARGV(0, string)); return; }
 443
 444                                         int tmp_remcount = 0;
 445
 446                                         IL_EACH(g_monsters, true,
 447                                         {
 448                                                 Monster_Remove(it);
 449                                                 ++tmp_remcount;
 450                                         });
 451                                         IL_CLEAR(g_monsters);
 452
 453                                         monsters_total = monsters_killed = totalspawned = 0;
 454
 455                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 456                                         return;
 457                                 }
 458                         }
 459                 }
 460
 461                 default:
 462                 case CMD_REQUEST_USAGE:
 463                 {
 464                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 465                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 466                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 467                         print_to(caller, "  spawn also takes arguments list and random");
 468                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 469                         return;
 470                 }
 471         }
 472 }
 473
 474 void CommonCommand_info(int request, entity caller, int argc)
 475 {
 476         switch (request)
 477         {
 478                 case CMD_REQUEST_COMMAND:
 479                 {
 480                         string command = cvar_string(strcat("sv_info_", argv(1)));
 481
 482                         if (command) wordwrap_sprint(caller, command, 1000);
 483                         else print_to(caller, "ERROR: unsupported info command");
 484
 485                         return;  // never fall through to usage
 486                 }
 487
 488                 default:
 489                 case CMD_REQUEST_USAGE:
 490                 {
 491                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 492                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 493                         return;
 494                 }
 495         }
 496 }
 497
 498 void CommonCommand_ladder(int request, entity caller)
 499 {
 500         switch (request)
 501         {
 502                 case CMD_REQUEST_COMMAND:
 503                 {
 504                         print_to(caller, ladder_reply);
 505                         return;  // never fall through to usage
 506                 }
 507
 508                 default:
 509                 case CMD_REQUEST_USAGE:
 510                 {
 511                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 512                         print_to(caller, "  No arguments required.");
 513                         return;
 514                 }
 515         }
 516 }
 517
 518 void CommonCommand_lsmaps(int request, entity caller)
 519 {
 520         switch (request)
 521         {
 522                 case CMD_REQUEST_COMMAND:
 523                 {
 524                         print_to(caller, lsmaps_reply);
 525                         return;  // never fall through to usage
 526                 }
 527
 528                 default:
 529                 case CMD_REQUEST_USAGE:
 530                 {
 531                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 532                         print_to(caller, "  No arguments required.");
 533                         return;
 534                 }
 535         }
 536 }
 537
 538 void CommonCommand_printmaplist(int request, entity caller)
 539 {
 540         switch (request)
 541         {
 542                 case CMD_REQUEST_COMMAND:
 543                 {
 544                         print_to(caller, maplist_reply);
 545                         return;  // never fall through to usage
 546                 }
 547
 548                 default:
 549                 case CMD_REQUEST_USAGE:
 550                 {
 551                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 552                         print_to(caller, "  No arguments required.");
 553                         return;
 554                 }
 555         }
 556 }
 557
 558 void CommonCommand_rankings(int request, entity caller)
 559 {
 560         switch (request)
 561         {
 562                 case CMD_REQUEST_COMMAND:
 563                 {
 564                         print_to(caller, rankings_reply);
 565                         return;  // never fall through to usage
 566                 }
 567
 568                 default:
 569                 case CMD_REQUEST_USAGE:
 570                 {
 571                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 572                         print_to(caller, "  No arguments required.");
 573                         return;
 574                 }
 575         }
 576 }
 577
 578 void CommonCommand_records(int request, entity caller)
 579 {
 580         switch (request)
 581         {
 582                 case CMD_REQUEST_COMMAND:
 583                 {
 584                         int num = stoi(argv(1));
 585                         if(num > 0 && num <= 10 && records_reply[num - 1] != "")
 586                                 print_to(caller, records_reply[num - 1]);
 587                         else
 588                         {
 589                                 for (int i = 0; i < 10; ++i)
 590                                         if (records_reply[i] != "") print_to(caller, records_reply[i]);
 591                         }
 592
 593                         return;  // never fall through to usage
 594                 }
 595
 596                 default:
 597                 case CMD_REQUEST_USAGE:
 598                 {
 599                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 600                         print_to(caller, "  No arguments required.");
 601                         return;
 602                 }
 603         }
 604 }
 605
 606 void CommonCommand_teamstatus(int request, entity caller)
 607 {
 608         switch (request)
 609         {
 610                 case CMD_REQUEST_COMMAND:
 611                 {
 612                         Score_NicePrint(caller);
 613                         return;  // never fall through to usage
 614                 }
 615
 616                 default:
 617                 case CMD_REQUEST_USAGE:
 618                 {
 619                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 620                         print_to(caller, "  No arguments required.");
 621                         return;
 622                 }
 623         }
 624 }
 625
 626 void CommonCommand_time(int request, entity caller)
 627 {
 628         switch (request)
 629         {
 630                 case CMD_REQUEST_COMMAND:
 631                 {
 632                         print_to(caller, strcat("time = ", ftos(time)));
 633                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 634                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 635                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 636                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 637                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %d %H:%M:%S %Z %Y")));
 638                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %d %H:%M:%S %Z %Y")));
 639                         return;
 640                 }
 641
 642                 default:
 643                 case CMD_REQUEST_USAGE:
 644                 {
 645                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 646                         print_to(caller, "  No arguments required.");
 647                         return;
 648                 }
 649         }
 650 }
 651
 652 void CommonCommand_timein(int request, entity caller)
 653 {
 654         switch (request)
 655         {
 656                 case CMD_REQUEST_COMMAND:
 657                 {
 658                         if (!caller || autocvar_sv_timeout)
 659                         {
 660                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 661                                 else if (caller && (caller != timeout_caller))
 662                                 {
 663                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 664                                 }
 665
 666                                 else  // everything should be okay, continue aborting timeout
 667                                 {
 668                                         switch (timeout_status)
 669                                         {
 670                                                 case TIMEOUT_LEADTIME:
 671                                                 {
 672                                                         timeout_status = TIMEOUT_INACTIVE;
 673                                                         timeout_time = 0;
 674                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 675                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 676                                                         return;
 677                                                 }
 678
 679                                                 case TIMEOUT_ACTIVE:
 680                                                 {
 681                                                         timeout_time = autocvar_sv_timeout_resumetime;
 682                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 683                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 684                                                         return;
 685                                                 }
 686
 687                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 688                                                         return;
 689                                         }
 690                                 }
 691                         }
 692                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 693
 694                         return;  // never fall through to usage
 695                 }
 696
 697                 default:
 698                 case CMD_REQUEST_USAGE:
 699                 {
 700                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 701                         print_to(caller, "  No arguments required.");
 702                         return;
 703                 }
 704         }
 705 }
 706
 707 void CommonCommand_timeout(int request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 708 {
 709         switch (request)
 710         {
 711                 case CMD_REQUEST_COMMAND:
 712                 {
 713                         if (!caller || autocvar_sv_timeout)
 714                         {
 715                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 716
 717                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 718                                 else if (vote_called)
 719                                 {
 720                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 721                                 }
 722                                 else if (warmup_stage && !g_warmup_allow_timeout)
 723                                 {
 724                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 725                                 }
 726                                 else if (time < game_starttime)
 727                                 {
 728                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 729                                 }
 730                                 else if (caller && (CS(caller).allowed_timeouts < 1))
 731                                 {
 732                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 733                                 }
 734                                 else if (caller && !IS_PLAYER(caller))
 735                                 {
 736                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 737                                 }
 738                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 739                                 {
 740                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 741                                 }
 742
 743                                 else  // everything should be okay, proceed with starting the timeout
 744                                 {
 745                                         if (caller)   CS(caller).allowed_timeouts -= 1;
 746                                         // write a bprint who started the timeout (and how many they have left)
 747                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(CS(caller).allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 748
 749                                         timeout_status = TIMEOUT_LEADTIME;
 750                                         timeout_caller = caller;
 751                                         timeout_time = autocvar_sv_timeout_length;
 752                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 753
 754                                         timeout_handler = spawn();
 755                                         setthink(timeout_handler, timeout_handler_think);
 756                                         timeout_handler.nextthink = time;  // always let the entity think asap
 757
 758                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_TIMEOUT);
 759                                 }
 760                         }
 761                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 762
 763                         return;  // never fall through to usage
 764                 }
 765
 766                 default:
 767                 case CMD_REQUEST_USAGE:
 768                 {
 769                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 770                         print_to(caller, "  No arguments required.");
 771                         return;
 772                 }
 773         }
 774 }
 775
 776 void CommonCommand_who(int request, entity caller, int argc)
 777 {
 778         switch (request)
 779         {
 780                 case CMD_REQUEST_COMMAND:
 781                 {
 782                         float total_listed_players, is_bot;
 783
 784                         float privacy = (caller && autocvar_sv_status_privacy);
 785                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 786                         string tmp_netaddress, tmp_crypto_idfp;
 787
 788                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 789                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 790                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 791
 792                         total_listed_players = 0;
 793                         FOREACH_CLIENT(true, {
 794                                 is_bot = (IS_BOT_CLIENT(it));
 795
 796                                 if (is_bot)
 797                                 {
 798                                         tmp_netaddress = "null/botclient";
 799                                         tmp_crypto_idfp = "null/botclient";
 800                                 }
 801                                 else if (privacy)
 802                                 {
 803                                         tmp_netaddress = "hidden";
 804                                         tmp_crypto_idfp = "hidden";
 805                                 }
 806                                 else
 807                                 {
 808                                         tmp_netaddress = it.netaddress;
 809                                         tmp_crypto_idfp = it.crypto_idfp;
 810                                 }
 811
 812                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 813                                         etof(it),
 814                                         it.netname,
 815                                         CS(it).ping,
 816                                         CS(it).ping_packetloss,
 817                                         process_time(1, time - CS(it).jointime),
 818                                         tmp_netaddress,
 819                                         tmp_crypto_idfp));
 820
 821                                 ++total_listed_players;
 822                         });
 823
 824                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 825
 826                         return;  // never fall through to usage
 827                 }
 828
 829                 default:
 830                 case CMD_REQUEST_USAGE:
 831                 {
 832                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 833                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 834                         return;
 835                 }
 836         }
 837 }
 838
 839 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 840 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 841 void CommonCommand_(int request, entity caller)
 842 {
 843     switch(request)
 844     {
 845         case CMD_REQUEST_COMMAND:
 846         {
 847
 848             return; // never fall through to usage
 849         }
 850
 851         default:
 852         case CMD_REQUEST_USAGE:
 853         {
 854             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 855             print_to(caller, "  No arguments required.");
 856             return;
 857         }
 858     }
 859 }
 860 */