qcsrc/server/command/common.qc

   1 #include "../../common/command/command.qh"
   2 #include "common.qh"
   3 #include "../_all.qh"
   4
   5 #include "../scores.qh"
   6
   7 #include "../../common/notifications.qh"
   8
   9
  10 // ====================================================
  11 //  Shared code for server commands, written by Samual
  12 //  Last updated: December 27th, 2011
  13 // ====================================================
  14
  15 // select the proper prefix for usage and other messages
  16 string GetCommandPrefix(entity caller)
  17 {
  18         if(caller)
  19                 return "cmd";
  20         else
  21                 return "sv_cmd";
  22 }
  23
  24 // if client return player nickname, or if server return admin nickname
  25 string GetCallerName(entity caller)
  26 {
  27         if(caller)
  28                 return caller.netname;
  29         else
  30                 return admin_name(); //((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  31 }
  32
  33 // verify that the client provided is acceptable for kicking
  34 float VerifyKickableEntity(entity client)
  35 {
  36         if (!IS_REAL_CLIENT(client))
  37                 return CLIENT_NOT_REAL;
  38         return CLIENT_ACCEPTABLE;
  39 }
  40
  41 // verify that the client provided is acceptable for use
  42 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  43 {
  44         if (!IS_CLIENT(client))
  45                 return CLIENT_DOESNT_EXIST;
  46         else if(must_be_real && !IS_REAL_CLIENT(client))
  47                 return CLIENT_NOT_REAL;
  48         else if(must_be_bots && !IS_BOT_CLIENT(client))
  49                 return CLIENT_NOT_BOT;
  50
  51         return CLIENT_ACCEPTABLE;
  52 }
  53
  54 // if the client is not acceptable, return a string to be used for error messages
  55 string GetClientErrorString_color(float clienterror, string original_input, string col)
  56 {
  57         switch(clienterror)
  58         {
  59                 case CLIENT_DOESNT_EXIST: { return strcat(col, "Client '", original_input, col, "' doesn't exist"); }
  60                 case CLIENT_NOT_REAL: { return strcat(col, "Client '", original_input, col, "' is not real"); }
  61                 case CLIENT_NOT_BOT: { return strcat(col, "Client '", original_input, col, "' is not a bot"); }
  62                 default: { return "Incorrect usage of GetClientErrorString"; }
  63         }
  64 }
  65
  66 // is this entity number even in the possible range of entities?
  67 float VerifyClientNumber(float tmp_number)
  68 {
  69         if((tmp_number < 1) || (tmp_number > maxclients))
  70                 return false;
  71         else
  72                 return true;
  73 }
  74
  75 entity GetIndexedEntity(float argc, float start_index)
  76 {
  77         entity tmp_player, selection;
  78         float tmp_number, index;
  79         string tmp_string;
  80
  81         next_token = -1;
  82         index = start_index;
  83         selection = world;
  84
  85         if(argc > start_index)
  86         {
  87                 if(substring(argv(index), 0, 1) == "#")
  88                 {
  89                         tmp_string = substring(argv(index), 1, -1);
  90                         ++index;
  91
  92                         if(tmp_string != "") // is it all one token? like #1
  93                         {
  94                                 tmp_number = stof(tmp_string);
  95                         }
  96                         else if(argc > index) // no, it's two tokens? # 1
  97                         {
  98                                 tmp_number = stof(argv(index));
  99                                 ++index;
 100                         }
 101                         else
 102                                 tmp_number = 0;
 103                 }
 104                 else // maybe it's ONLY a number?
 105                 {
 106                         tmp_number = stof(argv(index));
 107                         ++index;
 108                 }
 109
 110                 if(VerifyClientNumber(tmp_number))
 111                 {
 112                         selection = edict_num(tmp_number); // yes, it was a number
 113                 }
 114                 else // no, maybe it's a name?
 115                 {
 116                         FOR_EACH_CLIENT(tmp_player)
 117                                 if (strdecolorize(tmp_player.netname) == strdecolorize(argv(start_index)))
 118                                         selection = tmp_player;
 119
 120                         index = (start_index + 1);
 121                 }
 122         }
 123
 124         next_token = index;
 125         //print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 126         return selection;
 127 }
 128
 129 // find a player which matches the input string, and return their entity
 130 entity GetFilteredEntity(string input)
 131 {
 132         entity tmp_player, selection;
 133         float tmp_number;
 134
 135         if(substring(input, 0, 1) == "#")
 136                 tmp_number = stof(substring(input, 1, -1));
 137         else
 138                 tmp_number = stof(input);
 139
 140         if(VerifyClientNumber(tmp_number))
 141         {
 142                 selection = edict_num(tmp_number);
 143         }
 144         else
 145         {
 146                 selection = world;
 147                 FOR_EACH_CLIENT(tmp_player)
 148                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
 149                                 selection = tmp_player;
 150         }
 151
 152         return selection;
 153 }
 154
 155 // same thing, but instead return their edict number
 156 float GetFilteredNumber(string input)
 157 {
 158         entity selection = GetFilteredEntity(input);
 159         float output;
 160
 161         output = num_for_edict(selection);
 162
 163         return output;
 164 }
 165
 166 // switch between sprint and print depending on whether the receiver is the server or a player
 167 void print_to(entity to, string input)
 168 {
 169     if(to)
 170         sprint(to, strcat(input, "\n"));
 171     else
 172         LOG_INFO(input, "\n");
 173 }
 174
 175 // ==========================================
 176 //  Supporting functions for common commands
 177 // ==========================================
 178
 179 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 180 void timeout_handler_reset()
 181 {
 182         timeout_caller = world;
 183         timeout_time = 0;
 184         timeout_leadtime = 0;
 185
 186         remove(self);
 187 }
 188
 189 void timeout_handler_think()
 190 {
 191         entity tmp_player;
 192
 193         switch(timeout_status)
 194         {
 195                 case TIMEOUT_ACTIVE:
 196                 {
 197                         if(timeout_time > 0) // countdown is still going
 198                         {
 199                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 200
 201                                 if(timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 202                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 203
 204                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE; // think again in one second
 205                                 timeout_time -= 1; // decrease the time counter
 206                         }
 207                         else // time to end the timeout
 208                         {
 209                                 timeout_status = TIMEOUT_INACTIVE;
 210
 211                                 // reset the slowmo value back to normal
 212                                 cvar_set("slowmo", ftos(orig_slowmo));
 213
 214                                 // unlock the view for players so they can move around again
 215                                 FOR_EACH_REALPLAYER(tmp_player)
 216                                         tmp_player.fixangle = false;
 217
 218                                 timeout_handler_reset();
 219                         }
 220
 221                         return;
 222                 }
 223
 224                 case TIMEOUT_LEADTIME:
 225                 {
 226                         if(timeout_leadtime > 0) // countdown is still going
 227                         {
 228                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 229
 230                                 self.nextthink = time + 1; // think again in one second
 231                                 timeout_leadtime -= 1; // decrease the time counter
 232                         }
 233                         else // time to begin the timeout
 234                         {
 235                                 timeout_status = TIMEOUT_ACTIVE;
 236
 237                                 // set the slowmo value to the timeout default slowmo value
 238                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 239
 240                                 // reset all the flood variables
 241                                 FOR_EACH_CLIENT(tmp_player)
 242                                         tmp_player.nickspamcount = tmp_player.nickspamtime = tmp_player.floodcontrol_chat =
 243                                         tmp_player.floodcontrol_chatteam = tmp_player.floodcontrol_chattell =
 244                                         tmp_player.floodcontrol_voice = tmp_player.floodcontrol_voiceteam = 0;
 245
 246                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 247                                 FOR_EACH_REALPLAYER(tmp_player)
 248                                         tmp_player.lastV_angle = tmp_player.v_angle;
 249
 250                                 self.nextthink = time; // think again next frame to handle it under TIMEOUT_ACTIVE code
 251                         }
 252
 253                         return;
 254                 }
 255
 256
 257                 case TIMEOUT_INACTIVE:
 258                 default:
 259                 {
 260                         timeout_handler_reset();
 261                         return;
 262                 }
 263         }
 264 }
 265
 266
 267
 268 // ===================================================
 269 //  Common commands used in both sv_cmd.qc and cmd.qc
 270 // ===================================================
 271
 272 void CommonCommand_cvar_changes(float request, entity caller)
 273 {
 274         switch(request)
 275         {
 276                 case CMD_REQUEST_COMMAND:
 277                 {
 278                         print_to(caller, cvar_changes);
 279                         return; // never fall through to usage
 280                 }
 281
 282                 default:
 283                 case CMD_REQUEST_USAGE:
 284                 {
 285                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 286                         print_to(caller, "  No arguments required.");
 287                         print_to(caller, "See also: ^2cvar_purechanges^7");
 288                         return;
 289                 }
 290         }
 291 }
 292
 293 void CommonCommand_cvar_purechanges(float request, entity caller)
 294 {
 295         switch(request)
 296         {
 297                 case CMD_REQUEST_COMMAND:
 298                 {
 299                         print_to(caller, cvar_purechanges);
 300                         return; // never fall through to usage
 301                 }
 302
 303                 default:
 304                 case CMD_REQUEST_USAGE:
 305                 {
 306                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 307                         print_to(caller, "  No arguments required.");
 308                         print_to(caller, "See also: ^2cvar_changes^7");
 309                         return;
 310                 }
 311         }
 312 }
 313
 314 void CommonCommand_editmob(int request, entity caller, int argc)
 315 {
 316         switch(request)
 317         {
 318                 case CMD_REQUEST_COMMAND:
 319                 {
 320                         if(autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 321                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 322
 323                         if(caller)
 324                         {
 325                                 makevectors(self.v_angle);
 326                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 327                         }
 328
 329                         entity mon = trace_ent;
 330                         bool is_visible = IS_MONSTER(mon);
 331                         string argument = argv(2);
 332
 333                         switch(argv(1))
 334                         {
 335                                 case "name":
 336                                 {
 337                                         if(!caller) { print_to(caller, "Only players can edit monsters"); return; }
 338                                         if(!argument) { break; } // escape to usage
 339                                         if(!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 340                                         if(mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 341                                         if(!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 342
 343                                         string mon_oldname = mon.monster_name;
 344
 345                                         mon.monster_name = argument;
 346                                         if(mon.sprite) { WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null); }
 347                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 348                                         return;
 349                                 }
 350                                 case "spawn":
 351                                 {
 352                                         if(!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 353                                         if(!argv(2)) { break; } // escape to usage
 354
 355                                         int moveflag, tmp_moncount = 0;
 356                                         string arg_lower = strtolower(argument);
 357                                         moveflag = (argv(3)) ? stof(argv(3)) : 1; // follow owner if not defined
 358                                         ret_string = "Monster spawning is currently disabled by a mutator";
 359
 360                                         if(arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 361
 362                                         FOR_EACH_MONSTER(mon) { if(mon.realowner == caller) ++tmp_moncount; }
 363
 364                                         if(!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 365                                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 366                                         if(!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 367                                         if(MUTATOR_CALLHOOK(AllowMobSpawning)) { print_to(caller, ret_string); return; }
 368                                         if(caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 369                                         if(caller.frozen) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 370                                         if(caller.deadflag != DEAD_NO) { print_to(caller, "You can't spawn monsters while dead"); return; }
 371                                         if(tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 372                                         if(tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 373
 374                                         bool found = false;
 375                                         for(int i = MON_FIRST; i <= MON_LAST; ++i)
 376                                         {
 377                                                 mon = get_monsterinfo(i);
 378                                                 if(mon.netname == arg_lower) { found = true; break; }
 379                                         }
 380
 381                                         if(!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 382
 383                                         totalspawned += 1;
 384                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 385                                         mon = spawnmonster(arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 386                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 387                                         return;
 388                                 }
 389                                 case "kill":
 390                                 {
 391                                         if(!caller) { print_to(caller, "Only players can kill monsters"); return; }
 392                                         if(mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 393                                         if(!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 394
 395                                         Damage (mon, world, world, mon.health + mon.max_health + 200, DEATH_KILL, mon.origin, '0 0 0');
 396                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 397                                         return;
 398                                 }
 399                                 case "skin":
 400                                 {
 401                                         if(!caller) { print_to(caller, "Only players can edit monsters"); return; }
 402                                         if(!argument) { break; } // escape to usage
 403                                         if(!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 404                                         if(!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 405                                         if(mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 406                                         if(mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; } // TODO
 407
 408                                         mon.skin = stof(argument);
 409                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 410                                         return;
 411                                 }
 412                                 case "movetarget":
 413                                 {
 414                                         if(!caller) { print_to(caller, "Only players can edit monsters"); return; }
 415                                         if(!argument) { break; } // escape to usage
 416                                         if(!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 417                                         if(!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 418                                         if(mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 419
 420                                         mon.monster_moveflags = stof(argument);
 421                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 422                                         return;
 423                                 }
 424                                 case "butcher":
 425                                 {
 426                                         if(caller) { print_to(caller, "This command is not available to players"); return; }
 427                                         if(g_invasion) { print_to(caller, "This command does not work during an invasion!"); return; }
 428
 429                                         int tmp_remcount = 0;
 430                                         entity tmp_entity;
 431
 432                                         FOR_EACH_MONSTER(tmp_entity) { Monster_Remove(tmp_entity); ++tmp_remcount; }
 433
 434                                         monsters_total = monsters_killed = totalspawned = 0;
 435
 436                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 437                                         return;
 438                                 }
 439                         }
 440                 }
 441
 442                 default:
 443                 case CMD_REQUEST_USAGE:
 444                 {
 445                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 446                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 447                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 448                         print_to(caller, "  spawn also takes arguments list and random");
 449                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 450                         return;
 451                 }
 452         }
 453 }
 454
 455 void CommonCommand_info(float request, entity caller, float argc)
 456 {
 457         switch(request)
 458         {
 459                 case CMD_REQUEST_COMMAND:
 460                 {
 461                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 462
 463                         if(command)
 464                                 wordwrap_sprint(command, 1000);
 465                         else
 466                                 print_to(caller, "ERROR: unsupported info command");
 467
 468                         return; // never fall through to usage
 469                 }
 470
 471                 default:
 472                 case CMD_REQUEST_USAGE:
 473                 {
 474                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 475                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 476                         return;
 477                 }
 478         }
 479 }
 480
 481 void CommonCommand_ladder(float request, entity caller)
 482 {
 483         switch(request)
 484         {
 485                 case CMD_REQUEST_COMMAND:
 486                 {
 487                         print_to(caller, ladder_reply);
 488                         return; // never fall through to usage
 489                 }
 490
 491                 default:
 492                 case CMD_REQUEST_USAGE:
 493                 {
 494                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 495                         print_to(caller, "  No arguments required.");
 496                         return;
 497                 }
 498         }
 499 }
 500
 501 void CommonCommand_lsmaps(float request, entity caller)
 502 {
 503         switch(request)
 504         {
 505                 case CMD_REQUEST_COMMAND:
 506                 {
 507                         print_to(caller, lsmaps_reply);
 508                         return; // never fall through to usage
 509                 }
 510
 511                 default:
 512                 case CMD_REQUEST_USAGE:
 513                 {
 514                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 515                         print_to(caller, "  No arguments required.");
 516                         return;
 517                 }
 518         }
 519 }
 520
 521 void CommonCommand_printmaplist(float request, entity caller)
 522 {
 523         switch(request)
 524         {
 525                 case CMD_REQUEST_COMMAND:
 526                 {
 527                         print_to(caller, maplist_reply);
 528                         return; // never fall through to usage
 529                 }
 530
 531                 default:
 532                 case CMD_REQUEST_USAGE:
 533                 {
 534                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 535                         print_to(caller, "  No arguments required.");
 536                         return;
 537                 }
 538         }
 539 }
 540
 541 void CommonCommand_rankings(float request, entity caller)
 542 {
 543         switch(request)
 544         {
 545                 case CMD_REQUEST_COMMAND:
 546                 {
 547                         print_to(caller, rankings_reply);
 548                         return; // never fall through to usage
 549                 }
 550
 551                 default:
 552                 case CMD_REQUEST_USAGE:
 553                 {
 554                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 555                         print_to(caller, "  No arguments required.");
 556                         return;
 557                 }
 558         }
 559 }
 560
 561 void CommonCommand_records(float request, entity caller)
 562 {
 563         switch(request)
 564         {
 565                 case CMD_REQUEST_COMMAND:
 566                 {
 567                         for(int i = 0; i < 10; ++i)
 568                                 if(records_reply[i] != "")
 569                                         print_to(caller, records_reply[i]);
 570
 571                         return; // never fall through to usage
 572                 }
 573
 574                 default:
 575                 case CMD_REQUEST_USAGE:
 576                 {
 577                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 578                         print_to(caller, "  No arguments required.");
 579                         return;
 580                 }
 581         }
 582 }
 583
 584 void CommonCommand_teamstatus(float request, entity caller)
 585 {
 586         switch(request)
 587         {
 588                 case CMD_REQUEST_COMMAND:
 589                 {
 590                         Score_NicePrint(caller);
 591                         return; // never fall through to usage
 592                 }
 593
 594                 default:
 595                 case CMD_REQUEST_USAGE:
 596                 {
 597                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 598                         print_to(caller, "  No arguments required.");
 599                         return;
 600                 }
 601         }
 602 }
 603
 604 void CommonCommand_time(float request, entity caller)
 605 {
 606         switch(request)
 607         {
 608                 case CMD_REQUEST_COMMAND:
 609                 {
 610                         print_to(caller, strcat("time = ", ftos(time)));
 611                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 612                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 613                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 614                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 615                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 616                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 617                         return;
 618                 }
 619
 620                 default:
 621                 case CMD_REQUEST_USAGE:
 622                 {
 623                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 624                         print_to(caller, "  No arguments required.");
 625                         return;
 626                 }
 627         }
 628 }
 629
 630 void CommonCommand_timein(float request, entity caller)
 631 {
 632         switch(request)
 633         {
 634                 case CMD_REQUEST_COMMAND:
 635                 {
 636                         if(!caller || autocvar_sv_timeout)
 637                         {
 638                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 639                                 else if(caller && (caller != timeout_caller)) { print_to(caller, "^7Error: You are not allowed to stop the active timeout."); }
 640
 641                                 else // everything should be okay, continue aborting timeout
 642                                 {
 643                                         switch(timeout_status)
 644                                         {
 645                                                 case TIMEOUT_LEADTIME:
 646                                                 {
 647                                                         timeout_status = TIMEOUT_INACTIVE;
 648                                                         timeout_time = 0;
 649                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 650                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 651                                                         return;
 652                                                 }
 653
 654                                                 case TIMEOUT_ACTIVE:
 655                                                 {
 656                                                         timeout_time = autocvar_sv_timeout_resumetime;
 657                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 658                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 659                                                         return;
 660                                                 }
 661
 662                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?"); return;
 663                                         }
 664                                 }
 665                         }
 666                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 667
 668                         return; // never fall through to usage
 669                 }
 670
 671                 default:
 672                 case CMD_REQUEST_USAGE:
 673                 {
 674                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 675                         print_to(caller, "  No arguments required.");
 676                         return;
 677                 }
 678         }
 679 }
 680
 681 void CommonCommand_timeout(float request, entity caller) // DEAR GOD THIS COMMAND IS TERRIBLE.
 682 {
 683         switch(request)
 684         {
 685                 case CMD_REQUEST_COMMAND:
 686                 {
 687                         if(!caller || autocvar_sv_timeout)
 688                         {
 689                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 690
 691                                 if(timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 692                                 else if(vote_called) { print_to(caller, "^7Error: You can not call a timeout while a vote is active."); }
 693                                 else if(warmup_stage && !g_warmup_allow_timeout) { print_to(caller, "^7Error: You can not call a timeout in warmup-stage."); }
 694                                 else if(time < game_starttime) { print_to(caller, "^7Error: You can not call a timeout while the map is being restarted."); }
 695                                 else if(caller && (caller.allowed_timeouts < 1)) { print_to(caller, "^7Error: You already used all your timeout calls for this map."); }
 696                                 else if(caller && !IS_PLAYER(caller)) { print_to(caller, "^7Error: You must be a player to call a timeout."); }
 697                                 else if((autocvar_timelimit) && (last_possible_timeout < time - game_starttime)) { print_to(caller, "^7Error: It is too late to call a timeout now!"); }
 698
 699                                 else // everything should be okay, proceed with starting the timeout
 700                                 {
 701                                         if(caller) { caller.allowed_timeouts -= 1; }
 702
 703                                         // write a bprint who started the timeout (and how many they have left)
 704                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 705
 706                                         timeout_status = TIMEOUT_LEADTIME;
 707                                         timeout_caller = caller;
 708                                         timeout_time = autocvar_sv_timeout_length;
 709                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 710
 711                                         timeout_handler = spawn();
 712                                         timeout_handler.think = timeout_handler_think;
 713                                         timeout_handler.nextthink = time; // always let the entity think asap
 714
 715                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 716                                 }
 717                         }
 718                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 719
 720                         return; // never fall through to usage
 721                 }
 722
 723                 default:
 724                 case CMD_REQUEST_USAGE:
 725                 {
 726                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 727                         print_to(caller, "  No arguments required.");
 728                         return;
 729                 }
 730         }
 731 }
 732
 733 void CommonCommand_who(float request, entity caller, float argc)
 734 {
 735         switch(request)
 736         {
 737                 case CMD_REQUEST_COMMAND:
 738                 {
 739                         float total_listed_players, is_bot;
 740                         entity tmp_player;
 741
 742                         float privacy = (caller && autocvar_sv_status_privacy);
 743                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 744                         string tmp_netaddress, tmp_crypto_idfp;
 745
 746                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 747                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 748                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 749
 750                         total_listed_players = 0;
 751                         FOR_EACH_CLIENT(tmp_player)
 752                         {
 753                                 is_bot = (IS_BOT_CLIENT(tmp_player));
 754
 755                                 if(is_bot)
 756                                 {
 757                                         tmp_netaddress = "null/botclient";
 758                                         tmp_crypto_idfp = "null/botclient";
 759                                 }
 760                                 else if(privacy)
 761                                 {
 762                                         tmp_netaddress = "hidden";
 763                                         tmp_crypto_idfp = "hidden";
 764                                 }
 765                                 else
 766                                 {
 767                                         tmp_netaddress = tmp_player.netaddress;
 768                                         tmp_crypto_idfp = tmp_player.crypto_idfp;
 769                                 }
 770
 771                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 772                                         num_for_edict(tmp_player),
 773                                         tmp_player.netname,
 774                                         tmp_player.ping,
 775                                         tmp_player.ping_packetloss,
 776                                         process_time(1, time - tmp_player.jointime),
 777                                         tmp_netaddress,
 778                                         tmp_crypto_idfp));
 779
 780                                 ++total_listed_players;
 781                         }
 782
 783                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 784
 785                         return; // never fall through to usage
 786                 }
 787
 788                 default:
 789                 case CMD_REQUEST_USAGE:
 790                 {
 791                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 792                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 793                         return;
 794                 }
 795         }
 796 }
 797
 798 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 799 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 800 void CommonCommand_(float request, entity caller)
 801 {
 802         switch(request)
 803         {
 804                 case CMD_REQUEST_COMMAND:
 805                 {
 806
 807                         return; // never fall through to usage
 808                 }
 809
 810                 default:
 811                 case CMD_REQUEST_USAGE:
 812                 {
 813                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 814                         print_to(caller, "  No arguments required.");
 815                         return;
 816                 }
 817         }
 818 }
 819 */