qcsrc/server/command/common.qc

   1 #include "common.qh"
   2 #include <common/command/command.qh>
   3 #include "common.qh"
   4
   5 #include "../scores.qh"
   6
   7 #include <common/monsters/all.qh>
   8 #include <common/notifications/all.qh>
   9 #include <lib/warpzone/common.qh>
  10
  11
  12 // ====================================================
  13 //  Shared code for server commands, written by Samual
  14 //  Last updated: December 27th, 2011
  15 // ====================================================
  16
  17 // select the proper prefix for usage and other messages
  18 string GetCommandPrefix(entity caller)
  19 {
  20         if (caller) return "cmd";
  21         else return "sv_cmd";
  22 }
  23
  24 // if client return player nickname, or if server return admin nickname
  25 string GetCallerName(entity caller)
  26 {
  27         if (caller) return caller.netname;
  28         else return admin_name();  // ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  29 }
  30
  31 // verify that the client provided is acceptable for kicking
  32 float VerifyKickableEntity(entity client)
  33 {
  34         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  35         return CLIENT_ACCEPTABLE;
  36 }
  37
  38 // verify that the client provided is acceptable for use
  39 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  40 {
  41         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  42         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  43         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  44
  45         return CLIENT_ACCEPTABLE;
  46 }
  47
  48 // if the client is not acceptable, return a string to be used for error messages
  49 string GetClientErrorString_color(float clienterror, string original_input, string col)
  50 {
  51         switch (clienterror)
  52         {
  53                 case CLIENT_DOESNT_EXIST:
  54                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  55                 }
  56                 case CLIENT_NOT_REAL:
  57                 { return strcat(col, "Client '", original_input, col, "' is not real");
  58                 }
  59                 case CLIENT_NOT_BOT:
  60                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  61                 }
  62                 default:
  63                 { return "Incorrect usage of GetClientErrorString";
  64                 }
  65         }
  66 }
  67
  68 // is this entity number even in the possible range of entities?
  69 float VerifyClientNumber(float tmp_number)
  70 {
  71         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  72         else return true;
  73 }
  74
  75 entity GetIndexedEntity(float argc, float start_index)
  76 {
  77         entity selection;
  78         float tmp_number, index;
  79         string tmp_string;
  80
  81         next_token = -1;
  82         index = start_index;
  83         selection = world;
  84
  85         if (argc > start_index)
  86         {
  87                 if (substring(argv(index), 0, 1) == "#")
  88                 {
  89                         tmp_string = substring(argv(index), 1, -1);
  90                         ++index;
  91
  92                         if (tmp_string != "")  // is it all one token? like #1
  93                         {
  94                                 tmp_number = stof(tmp_string);
  95                         }
  96                         else if (argc > index)  // no, it's two tokens? # 1
  97                         {
  98                                 tmp_number = stof(argv(index));
  99                                 ++index;
 100                         }
 101                         else
 102                         {
 103                                 tmp_number = 0;
 104                         }
 105                 }
 106                 else  // maybe it's ONLY a number?
 107                 {
 108                         tmp_number = stof(argv(index));
 109                         ++index;
 110                 }
 111
 112                 if (VerifyClientNumber(tmp_number))
 113                 {
 114                         selection = edict_num(tmp_number);  // yes, it was a number
 115                 }
 116                 else  // no, maybe it's a name?
 117                 {
 118                         FOREACH_CLIENT(true, LAMBDA(
 119                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 120                                 {
 121                                         selection = it;
 122                                         break; // no reason to keep looking
 123                                 }
 124                         ));
 125
 126                         index = (start_index + 1);
 127                 }
 128         }
 129
 130         next_token = index;
 131         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 132         return selection;
 133 }
 134
 135 // find a player which matches the input string, and return their entity
 136 entity GetFilteredEntity(string input)
 137 {
 138         entity selection;
 139         float tmp_number;
 140
 141         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 142         else tmp_number = stof(input);
 143
 144         if (VerifyClientNumber(tmp_number))
 145         {
 146                 selection = edict_num(tmp_number);
 147         }
 148         else
 149         {
 150                 selection = world;
 151                 FOREACH_CLIENT(true, LAMBDA(
 152                         if(strdecolorize(it.netname) == strdecolorize(input))
 153                         {
 154                                 selection = it;
 155                                 break; // no reason to keep looking
 156                         }
 157                 ));
 158         }
 159
 160         return selection;
 161 }
 162
 163 // same thing, but instead return their edict number
 164 float GetFilteredNumber(string input)
 165 {
 166         entity selection = GetFilteredEntity(input);
 167         float output;
 168
 169         output = etof(selection);
 170
 171         return output;
 172 }
 173
 174 // switch between sprint and print depending on whether the receiver is the server or a player
 175 void print_to(entity to, string input)
 176 {
 177         if (to) sprint(to, strcat(input, "\n"));
 178         else LOG_INFO(input, "\n");
 179 }
 180
 181 // ==========================================
 182 //  Supporting functions for common commands
 183 // ==========================================
 184
 185 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 186 void timeout_handler_reset(entity this)
 187 {
 188         timeout_caller = NULL;
 189         timeout_time = 0;
 190         timeout_leadtime = 0;
 191
 192         remove(this);
 193 }
 194
 195 void timeout_handler_think(entity this)
 196 {
 197         switch (timeout_status)
 198         {
 199                 case TIMEOUT_ACTIVE:
 200                 {
 201                         if (timeout_time > 0)  // countdown is still going
 202                         {
 203                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 204
 205                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 206                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 207
 208                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 209                                 timeout_time -= 1;                                  // decrease the time counter
 210                         }
 211                         else  // time to end the timeout
 212                         {
 213                                 timeout_status = TIMEOUT_INACTIVE;
 214
 215                                 // reset the slowmo value back to normal
 216                                 cvar_set("slowmo", ftos(orig_slowmo));
 217
 218                                 // unlock the view for players so they can move around again
 219                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 220                                         it.fixangle = false;
 221                                 ));
 222
 223                                 timeout_handler_reset(this);
 224                         }
 225
 226                         return;
 227                 }
 228
 229                 case TIMEOUT_LEADTIME:
 230                 {
 231                         if (timeout_leadtime > 0)  // countdown is still going
 232                         {
 233                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 234
 235                                 self.nextthink = time + 1; // think again in one second
 236                                 timeout_leadtime -= 1;     // decrease the time counter
 237                         }
 238                         else  // time to begin the timeout
 239                         {
 240                                 timeout_status = TIMEOUT_ACTIVE;
 241
 242                                 // set the slowmo value to the timeout default slowmo value
 243                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 244
 245                                 // reset all the flood variables
 246                                 FOREACH_CLIENT(true, LAMBDA(
 247                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 248                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 249                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 250                                 ));
 251
 252                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 253                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 254                                         it.lastV_angle = it.v_angle;
 255                                 ));
 256
 257                                 self.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 258                         }
 259
 260                         return;
 261                 }
 262
 263
 264                 case TIMEOUT_INACTIVE:
 265                 default:
 266                 {
 267                         timeout_handler_reset(this);
 268                         return;
 269                 }
 270         }
 271 }
 272
 273
 274 // ===================================================
 275 //  Common commands used in both sv_cmd.qc and cmd.qc
 276 // ===================================================
 277
 278 void CommonCommand_cvar_changes(float request, entity caller)
 279 {
 280         switch (request)
 281         {
 282                 case CMD_REQUEST_COMMAND:
 283                 {
 284                         print_to(caller, cvar_changes);
 285                         return;  // never fall through to usage
 286                 }
 287
 288                 default:
 289                 case CMD_REQUEST_USAGE:
 290                 {
 291                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 292                         print_to(caller, "  No arguments required.");
 293                         print_to(caller, "See also: ^2cvar_purechanges^7");
 294                         return;
 295                 }
 296         }
 297 }
 298
 299 void CommonCommand_cvar_purechanges(float request, entity caller)
 300 {
 301         switch (request)
 302         {
 303                 case CMD_REQUEST_COMMAND:
 304                 {
 305                         print_to(caller, cvar_purechanges);
 306                         return;  // never fall through to usage
 307                 }
 308
 309                 default:
 310                 case CMD_REQUEST_USAGE:
 311                 {
 312                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 313                         print_to(caller, "  No arguments required.");
 314                         print_to(caller, "See also: ^2cvar_changes^7");
 315                         return;
 316                 }
 317         }
 318 }
 319
 320 void CommonCommand_editmob(int request, entity caller, int argc)
 321 {
 322         switch (request)
 323         {
 324                 case CMD_REQUEST_COMMAND:
 325                 {
 326                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 327                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 328
 329                         if (caller)
 330                         {
 331                                 makevectors(caller.v_angle);
 332                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 333                         }
 334
 335                         entity mon = trace_ent;
 336                         bool is_visible = IS_MONSTER(mon);
 337                         string argument = argv(2);
 338
 339                         switch (argv(1))
 340                         {
 341                                 case "name":
 342                                 {
 343                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 344                                         if (!argument)   break;  // escape to usage
 345                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 346                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 347                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 348
 349                                         string mon_oldname = mon.monster_name;
 350
 351                                         mon.monster_name = argument;
 352                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 353                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 354                                         return;
 355                                 }
 356                                 case "spawn":
 357                                 {
 358                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 359                                         if (!argv(2))   break;  // escape to usage
 360
 361                                         int moveflag, tmp_moncount = 0;
 362                                         string arg_lower = strtolower(argument);
 363                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 364                                         ret_string = "Monster spawning is currently disabled by a mutator";
 365
 366                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 367
 368                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 369                                                 if(it.realowner == caller)
 370                                                         ++tmp_moncount;
 371                                         ));
 372
 373                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 374                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 375                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 376                                         if (MUTATOR_CALLHOOK(AllowMobSpawning)) { print_to(caller, ret_string); return; }
 377                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 378                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 379                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 380                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 381                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 382
 383                                         bool found = false;
 384                                         for (int i = MON_FIRST; i <= MON_LAST; ++i)
 385                                         {
 386                                                 mon = get_monsterinfo(i);
 387                                                 if (mon.netname == arg_lower) { found = true; break; }
 388                                         }
 389
 390                                         if (!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 391
 392                                         totalspawned += 1;
 393                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 394                                         mon = spawnmonster(arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 395                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 396                                         return;
 397                                 }
 398                                 case "kill":
 399                                 {
 400                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 401                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 402                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 403
 404                                         Damage(mon, world, world, mon.health + mon.max_health + 200, DEATH_KILL.m_id, mon.origin, '0 0 0');
 405                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 406                                         return;
 407                                 }
 408                                 case "skin":
 409                                 {
 410                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 411                                         if (!argument)   break;  // escape to usage
 412                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 413                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 414                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 415                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 416
 417                                         mon.skin = stof(argument);
 418                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 419                                         return;
 420                                 }
 421                                 case "movetarget":
 422                                 {
 423                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 424                                         if (!argument)   break;  // escape to usage
 425                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 426                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 427                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 428
 429                                         mon.monster_moveflags = stof(argument);
 430                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 431                                         return;
 432                                 }
 433                                 case "butcher":
 434                                 {
 435                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 436                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(ret_string, "\n"); return; }
 437
 438                                         int tmp_remcount = 0;
 439
 440                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 441                                                 Monster_Remove(it);
 442                                                 ++tmp_remcount;
 443                                         ));
 444
 445                                         monsters_total = monsters_killed = totalspawned = 0;
 446
 447                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 448                                         return;
 449                                 }
 450                         }
 451                 }
 452
 453                 default:
 454                 case CMD_REQUEST_USAGE:
 455                 {
 456                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 457                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 458                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 459                         print_to(caller, "  spawn also takes arguments list and random");
 460                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 461                         return;
 462                 }
 463         }
 464 }
 465
 466 void CommonCommand_info(float request, entity caller, float argc)
 467 {
 468         switch (request)
 469         {
 470                 case CMD_REQUEST_COMMAND:
 471                 {
 472                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 473
 474                         if (command) wordwrap_sprint(caller, command, 1000);
 475                         else print_to(caller, "ERROR: unsupported info command");
 476
 477                         return;  // never fall through to usage
 478                 }
 479
 480                 default:
 481                 case CMD_REQUEST_USAGE:
 482                 {
 483                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 484                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 485                         return;
 486                 }
 487         }
 488 }
 489
 490 void CommonCommand_ladder(float request, entity caller)
 491 {
 492         switch (request)
 493         {
 494                 case CMD_REQUEST_COMMAND:
 495                 {
 496                         print_to(caller, ladder_reply);
 497                         return;  // never fall through to usage
 498                 }
 499
 500                 default:
 501                 case CMD_REQUEST_USAGE:
 502                 {
 503                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 504                         print_to(caller, "  No arguments required.");
 505                         return;
 506                 }
 507         }
 508 }
 509
 510 void CommonCommand_lsmaps(float request, entity caller)
 511 {
 512         switch (request)
 513         {
 514                 case CMD_REQUEST_COMMAND:
 515                 {
 516                         print_to(caller, lsmaps_reply);
 517                         return;  // never fall through to usage
 518                 }
 519
 520                 default:
 521                 case CMD_REQUEST_USAGE:
 522                 {
 523                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 524                         print_to(caller, "  No arguments required.");
 525                         return;
 526                 }
 527         }
 528 }
 529
 530 void CommonCommand_printmaplist(float request, entity caller)
 531 {
 532         switch (request)
 533         {
 534                 case CMD_REQUEST_COMMAND:
 535                 {
 536                         print_to(caller, maplist_reply);
 537                         return;  // never fall through to usage
 538                 }
 539
 540                 default:
 541                 case CMD_REQUEST_USAGE:
 542                 {
 543                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 544                         print_to(caller, "  No arguments required.");
 545                         return;
 546                 }
 547         }
 548 }
 549
 550 void CommonCommand_rankings(float request, entity caller)
 551 {
 552         switch (request)
 553         {
 554                 case CMD_REQUEST_COMMAND:
 555                 {
 556                         print_to(caller, rankings_reply);
 557                         return;  // never fall through to usage
 558                 }
 559
 560                 default:
 561                 case CMD_REQUEST_USAGE:
 562                 {
 563                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 564                         print_to(caller, "  No arguments required.");
 565                         return;
 566                 }
 567         }
 568 }
 569
 570 void CommonCommand_records(float request, entity caller)
 571 {
 572         switch (request)
 573         {
 574                 case CMD_REQUEST_COMMAND:
 575                 {
 576                         for (int i = 0; i < 10; ++i)
 577                                 if (records_reply[i] != "") print_to(caller, records_reply[i]);
 578
 579                         return;  // never fall through to usage
 580                 }
 581
 582                 default:
 583                 case CMD_REQUEST_USAGE:
 584                 {
 585                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 586                         print_to(caller, "  No arguments required.");
 587                         return;
 588                 }
 589         }
 590 }
 591
 592 void CommonCommand_teamstatus(float request, entity caller)
 593 {
 594         switch (request)
 595         {
 596                 case CMD_REQUEST_COMMAND:
 597                 {
 598                         Score_NicePrint(caller);
 599                         return;  // never fall through to usage
 600                 }
 601
 602                 default:
 603                 case CMD_REQUEST_USAGE:
 604                 {
 605                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 606                         print_to(caller, "  No arguments required.");
 607                         return;
 608                 }
 609         }
 610 }
 611
 612 void CommonCommand_time(float request, entity caller)
 613 {
 614         switch (request)
 615         {
 616                 case CMD_REQUEST_COMMAND:
 617                 {
 618                         print_to(caller, strcat("time = ", ftos(time)));
 619                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 620                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 621                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 622                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 623                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 624                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 625                         return;
 626                 }
 627
 628                 default:
 629                 case CMD_REQUEST_USAGE:
 630                 {
 631                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 632                         print_to(caller, "  No arguments required.");
 633                         return;
 634                 }
 635         }
 636 }
 637
 638 void CommonCommand_timein(float request, entity caller)
 639 {
 640         switch (request)
 641         {
 642                 case CMD_REQUEST_COMMAND:
 643                 {
 644                         if (!caller || autocvar_sv_timeout)
 645                         {
 646                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 647                                 else if (caller && (caller != timeout_caller))
 648                                 {
 649                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 650                                 }
 651
 652                                 else  // everything should be okay, continue aborting timeout
 653                                 {
 654                                         switch (timeout_status)
 655                                         {
 656                                                 case TIMEOUT_LEADTIME:
 657                                                 {
 658                                                         timeout_status = TIMEOUT_INACTIVE;
 659                                                         timeout_time = 0;
 660                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 661                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 662                                                         return;
 663                                                 }
 664
 665                                                 case TIMEOUT_ACTIVE:
 666                                                 {
 667                                                         timeout_time = autocvar_sv_timeout_resumetime;
 668                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 669                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 670                                                         return;
 671                                                 }
 672
 673                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 674                                                         return;
 675                                         }
 676                                 }
 677                         }
 678                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 679
 680                         return;  // never fall through to usage
 681                 }
 682
 683                 default:
 684                 case CMD_REQUEST_USAGE:
 685                 {
 686                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 687                         print_to(caller, "  No arguments required.");
 688                         return;
 689                 }
 690         }
 691 }
 692
 693 void CommonCommand_timeout(float request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 694 {
 695         switch (request)
 696         {
 697                 case CMD_REQUEST_COMMAND:
 698                 {
 699                         if (!caller || autocvar_sv_timeout)
 700                         {
 701                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 702
 703                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 704                                 else if (vote_called)
 705                                 {
 706                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 707                                 }
 708                                 else if (warmup_stage && !g_warmup_allow_timeout)
 709                                 {
 710                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 711                                 }
 712                                 else if (time < game_starttime)
 713                                 {
 714                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 715                                 }
 716                                 else if (caller && (caller.allowed_timeouts < 1))
 717                                 {
 718                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 719                                 }
 720                                 else if (caller && !IS_PLAYER(caller))
 721                                 {
 722                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 723                                 }
 724                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 725                                 {
 726                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 727                                 }
 728
 729                                 else  // everything should be okay, proceed with starting the timeout
 730                                 {
 731                                         if (caller)   caller.allowed_timeouts -= 1;
 732                                         // write a bprint who started the timeout (and how many they have left)
 733                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 734
 735                                         timeout_status = TIMEOUT_LEADTIME;
 736                                         timeout_caller = caller;
 737                                         timeout_time = autocvar_sv_timeout_length;
 738                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 739
 740                                         timeout_handler = spawn();
 741                                         setthink(timeout_handler, timeout_handler_think);
 742                                         timeout_handler.nextthink = time;  // always let the entity think asap
 743
 744                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 745                                 }
 746                         }
 747                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 748
 749                         return;  // never fall through to usage
 750                 }
 751
 752                 default:
 753                 case CMD_REQUEST_USAGE:
 754                 {
 755                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 756                         print_to(caller, "  No arguments required.");
 757                         return;
 758                 }
 759         }
 760 }
 761
 762 void CommonCommand_who(float request, entity caller, float argc)
 763 {
 764         switch (request)
 765         {
 766                 case CMD_REQUEST_COMMAND:
 767                 {
 768                         float total_listed_players, is_bot;
 769
 770                         float privacy = (caller && autocvar_sv_status_privacy);
 771                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 772                         string tmp_netaddress, tmp_crypto_idfp;
 773
 774                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 775                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 776                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 777
 778                         total_listed_players = 0;
 779                         FOREACH_CLIENT(true, LAMBDA(
 780                                 is_bot = (IS_BOT_CLIENT(it));
 781
 782                                 if (is_bot)
 783                                 {
 784                                         tmp_netaddress = "null/botclient";
 785                                         tmp_crypto_idfp = "null/botclient";
 786                                 }
 787                                 else if (privacy)
 788                                 {
 789                                         tmp_netaddress = "hidden";
 790                                         tmp_crypto_idfp = "hidden";
 791                                 }
 792                                 else
 793                                 {
 794                                         tmp_netaddress = it.netaddress;
 795                                         tmp_crypto_idfp = it.crypto_idfp;
 796                                 }
 797
 798                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 799                                         etof(it),
 800                                         it.netname,
 801                                         it.ping,
 802                                         it.ping_packetloss,
 803                                         process_time(1, time - it.jointime),
 804                                         tmp_netaddress,
 805                                         tmp_crypto_idfp));
 806
 807                                 ++total_listed_players;
 808                         ));
 809
 810                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 811
 812                         return;  // never fall through to usage
 813                 }
 814
 815                 default:
 816                 case CMD_REQUEST_USAGE:
 817                 {
 818                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 819                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 820                         return;
 821                 }
 822         }
 823 }
 824
 825 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 826 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 827 void CommonCommand_(float request, entity caller)
 828 {
 829     switch(request)
 830     {
 831         case CMD_REQUEST_COMMAND:
 832         {
 833
 834             return; // never fall through to usage
 835         }
 836
 837         default:
 838         case CMD_REQUEST_USAGE:
 839         {
 840             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 841             print_to(caller, "  No arguments required.");
 842             return;
 843         }
 844     }
 845 }
 846 */