qcsrc/server/command/common.qc

   1 #include "../../common/command/command.qh"
   2 #include "common.qh"
   3
   4 #include "../scores.qh"
   5
   6 #include "../../common/monsters/all.qh"
   7 #include "../../common/notifications.qh"
   8 #include "../../lib/warpzone/common.qh"
   9
  10
  11 // ====================================================
  12 //  Shared code for server commands, written by Samual
  13 //  Last updated: December 27th, 2011
  14 // ====================================================
  15
  16 // select the proper prefix for usage and other messages
  17 string GetCommandPrefix(entity caller)
  18 {
  19         if (caller) return "cmd";
  20         else return "sv_cmd";
  21 }
  22
  23 // if client return player nickname, or if server return admin nickname
  24 string GetCallerName(entity caller)
  25 {
  26         if (caller) return caller.netname;
  27         else return admin_name();  // ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  28 }
  29
  30 // verify that the client provided is acceptable for kicking
  31 float VerifyKickableEntity(entity client)
  32 {
  33         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  34         return CLIENT_ACCEPTABLE;
  35 }
  36
  37 // verify that the client provided is acceptable for use
  38 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  39 {
  40         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  41         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  42         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  43
  44         return CLIENT_ACCEPTABLE;
  45 }
  46
  47 // if the client is not acceptable, return a string to be used for error messages
  48 string GetClientErrorString_color(float clienterror, string original_input, string col)
  49 {
  50         switch (clienterror)
  51         {
  52                 case CLIENT_DOESNT_EXIST:
  53                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  54                 }
  55                 case CLIENT_NOT_REAL:
  56                 { return strcat(col, "Client '", original_input, col, "' is not real");
  57                 }
  58                 case CLIENT_NOT_BOT:
  59                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  60                 }
  61                 default:
  62                 { return "Incorrect usage of GetClientErrorString";
  63                 }
  64         }
  65 }
  66
  67 // is this entity number even in the possible range of entities?
  68 float VerifyClientNumber(float tmp_number)
  69 {
  70         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  71         else return true;
  72 }
  73
  74 entity GetIndexedEntity(float argc, float start_index)
  75 {
  76         entity selection;
  77         float tmp_number, index;
  78         string tmp_string;
  79
  80         next_token = -1;
  81         index = start_index;
  82         selection = world;
  83
  84         if (argc > start_index)
  85         {
  86                 if (substring(argv(index), 0, 1) == "#")
  87                 {
  88                         tmp_string = substring(argv(index), 1, -1);
  89                         ++index;
  90
  91                         if (tmp_string != "")  // is it all one token? like #1
  92                         {
  93                                 tmp_number = stof(tmp_string);
  94                         }
  95                         else if (argc > index)  // no, it's two tokens? # 1
  96                         {
  97                                 tmp_number = stof(argv(index));
  98                                 ++index;
  99                         }
 100                         else
 101                         {
 102                                 tmp_number = 0;
 103                         }
 104                 }
 105                 else  // maybe it's ONLY a number?
 106                 {
 107                         tmp_number = stof(argv(index));
 108                         ++index;
 109                 }
 110
 111                 if (VerifyClientNumber(tmp_number))
 112                 {
 113                         selection = edict_num(tmp_number);  // yes, it was a number
 114                 }
 115                 else  // no, maybe it's a name?
 116                 {
 117                         FOREACH_CLIENT(true, LAMBDA(
 118                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 119                                 {
 120                                         selection = it;
 121                                         break; // no reason to keep looking
 122                                 }
 123                         ));
 124
 125                         index = (start_index + 1);
 126                 }
 127         }
 128
 129         next_token = index;
 130         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 131         return selection;
 132 }
 133
 134 // find a player which matches the input string, and return their entity
 135 entity GetFilteredEntity(string input)
 136 {
 137         entity selection;
 138         float tmp_number;
 139
 140         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 141         else tmp_number = stof(input);
 142
 143         if (VerifyClientNumber(tmp_number))
 144         {
 145                 selection = edict_num(tmp_number);
 146         }
 147         else
 148         {
 149                 selection = world;
 150                 FOREACH_CLIENT(true, LAMBDA(
 151                         if(strdecolorize(it.netname) == strdecolorize(input))
 152                         {
 153                                 selection = it;
 154                                 break; // no reason to keep looking
 155                         }
 156                 ));
 157         }
 158
 159         return selection;
 160 }
 161
 162 // same thing, but instead return their edict number
 163 float GetFilteredNumber(string input)
 164 {
 165         entity selection = GetFilteredEntity(input);
 166         float output;
 167
 168         output = etof(selection);
 169
 170         return output;
 171 }
 172
 173 // switch between sprint and print depending on whether the receiver is the server or a player
 174 void print_to(entity to, string input)
 175 {
 176         if (to) sprint(to, strcat(input, "\n"));
 177         else LOG_INFO(input, "\n");
 178 }
 179
 180 // ==========================================
 181 //  Supporting functions for common commands
 182 // ==========================================
 183
 184 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 185 void timeout_handler_reset()
 186 {
 187         SELFPARAM();
 188         timeout_caller = world;
 189         timeout_time = 0;
 190         timeout_leadtime = 0;
 191
 192         remove(self);
 193 }
 194
 195 void timeout_handler_think()
 196 {
 197         SELFPARAM();
 198         switch (timeout_status)
 199         {
 200                 case TIMEOUT_ACTIVE:
 201                 {
 202                         if (timeout_time > 0)  // countdown is still going
 203                         {
 204                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 205
 206                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 207                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 208
 209                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 210                                 timeout_time -= 1;                                  // decrease the time counter
 211                         }
 212                         else  // time to end the timeout
 213                         {
 214                                 timeout_status = TIMEOUT_INACTIVE;
 215
 216                                 // reset the slowmo value back to normal
 217                                 cvar_set("slowmo", ftos(orig_slowmo));
 218
 219                                 // unlock the view for players so they can move around again
 220                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 221                                         it.fixangle = false;
 222                                 ));
 223
 224                                 timeout_handler_reset();
 225                         }
 226
 227                         return;
 228                 }
 229
 230                 case TIMEOUT_LEADTIME:
 231                 {
 232                         if (timeout_leadtime > 0)  // countdown is still going
 233                         {
 234                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 235
 236                                 self.nextthink = time + 1; // think again in one second
 237                                 timeout_leadtime -= 1;     // decrease the time counter
 238                         }
 239                         else  // time to begin the timeout
 240                         {
 241                                 timeout_status = TIMEOUT_ACTIVE;
 242
 243                                 // set the slowmo value to the timeout default slowmo value
 244                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 245
 246                                 // reset all the flood variables
 247                                 FOREACH_CLIENT(true, LAMBDA(
 248                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 249                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 250                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 251                                 ));
 252
 253                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 254                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 255                                         it.lastV_angle = it.v_angle;
 256                                 ));
 257
 258                                 self.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 259                         }
 260
 261                         return;
 262                 }
 263
 264
 265                 case TIMEOUT_INACTIVE:
 266                 default:
 267                 {
 268                         timeout_handler_reset();
 269                         return;
 270                 }
 271         }
 272 }
 273
 274
 275 // ===================================================
 276 //  Common commands used in both sv_cmd.qc and cmd.qc
 277 // ===================================================
 278
 279 void CommonCommand_cvar_changes(float request, entity caller)
 280 {
 281         switch (request)
 282         {
 283                 case CMD_REQUEST_COMMAND:
 284                 {
 285                         print_to(caller, cvar_changes);
 286                         return;  // never fall through to usage
 287                 }
 288
 289                 default:
 290                 case CMD_REQUEST_USAGE:
 291                 {
 292                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 293                         print_to(caller, "  No arguments required.");
 294                         print_to(caller, "See also: ^2cvar_purechanges^7");
 295                         return;
 296                 }
 297         }
 298 }
 299
 300 void CommonCommand_cvar_purechanges(float request, entity caller)
 301 {
 302         switch (request)
 303         {
 304                 case CMD_REQUEST_COMMAND:
 305                 {
 306                         print_to(caller, cvar_purechanges);
 307                         return;  // never fall through to usage
 308                 }
 309
 310                 default:
 311                 case CMD_REQUEST_USAGE:
 312                 {
 313                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 314                         print_to(caller, "  No arguments required.");
 315                         print_to(caller, "See also: ^2cvar_changes^7");
 316                         return;
 317                 }
 318         }
 319 }
 320
 321 void CommonCommand_editmob(int request, entity caller, int argc)
 322 {
 323         SELFPARAM();
 324         switch (request)
 325         {
 326                 case CMD_REQUEST_COMMAND:
 327                 {
 328                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 329                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 330
 331                         if (caller)
 332                         {
 333                                 makevectors(self.v_angle);
 334                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 335                         }
 336
 337                         entity mon = trace_ent;
 338                         bool is_visible = IS_MONSTER(mon);
 339                         string argument = argv(2);
 340
 341                         switch (argv(1))
 342                         {
 343                                 case "name":
 344                                 {
 345                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 346                                         if (!argument)   break;  // escape to usage
 347                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 348                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 349                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 350
 351                                         string mon_oldname = mon.monster_name;
 352
 353                                         mon.monster_name = argument;
 354                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 355                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 356                                         return;
 357                                 }
 358                                 case "spawn":
 359                                 {
 360                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 361                                         if (!argv(2))   break;  // escape to usage
 362
 363                                         int moveflag, tmp_moncount = 0;
 364                                         string arg_lower = strtolower(argument);
 365                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 366                                         ret_string = "Monster spawning is currently disabled by a mutator";
 367
 368                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 369
 370                                         FOR_EACH_MONSTER(mon)
 371                                         {
 372                                                 if (mon.realowner == caller) ++tmp_moncount;
 373                                         }
 374
 375                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 376                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 377                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 378                                         if (MUTATOR_CALLHOOK(AllowMobSpawning)) { print_to(caller, ret_string); return; }
 379                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 380                                         if (caller.frozen) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 381                                         if (caller.deadflag != DEAD_NO) { print_to(caller, "You can't spawn monsters while dead"); return; }
 382                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 383                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 384
 385                                         bool found = false;
 386                                         for (int i = MON_FIRST; i <= MON_LAST; ++i)
 387                                         {
 388                                                 mon = get_monsterinfo(i);
 389                                                 if (mon.netname == arg_lower) { found = true; break; }
 390                                         }
 391
 392                                         if (!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 393
 394                                         totalspawned += 1;
 395                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 396                                         mon = spawnmonster(arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 397                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 398                                         return;
 399                                 }
 400                                 case "kill":
 401                                 {
 402                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 403                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 404                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 405
 406                                         Damage(mon, world, world, mon.health + mon.max_health + 200, DEATH_KILL.m_id, mon.origin, '0 0 0');
 407                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 408                                         return;
 409                                 }
 410                                 case "skin":
 411                                 {
 412                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 413                                         if (!argument)   break;  // escape to usage
 414                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 415                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 416                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 417                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 418
 419                                         mon.skin = stof(argument);
 420                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 421                                         return;
 422                                 }
 423                                 case "movetarget":
 424                                 {
 425                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 426                                         if (!argument)   break;  // escape to usage
 427                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 428                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 429                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 430
 431                                         mon.monster_moveflags = stof(argument);
 432                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 433                                         return;
 434                                 }
 435                                 case "butcher":
 436                                 {
 437                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 438                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(ret_string, "\n"); return; }
 439
 440                                         int tmp_remcount = 0;
 441                                         entity tmp_entity;
 442
 443                                         FOR_EACH_MONSTER(tmp_entity)
 444                                         {
 445                                                 Monster_Remove(tmp_entity);
 446                                                 ++tmp_remcount;
 447                                         }
 448
 449                                         monsters_total = monsters_killed = totalspawned = 0;
 450
 451                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 452                                         return;
 453                                 }
 454                         }
 455                 }
 456
 457                 default:
 458                 case CMD_REQUEST_USAGE:
 459                 {
 460                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 461                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 462                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 463                         print_to(caller, "  spawn also takes arguments list and random");
 464                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 465                         return;
 466                 }
 467         }
 468 }
 469
 470 void CommonCommand_info(float request, entity caller, float argc)
 471 {
 472         switch (request)
 473         {
 474                 case CMD_REQUEST_COMMAND:
 475                 {
 476                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 477
 478                         if (command) wordwrap_sprint(command, 1000);
 479                         else print_to(caller, "ERROR: unsupported info command");
 480
 481                         return;  // never fall through to usage
 482                 }
 483
 484                 default:
 485                 case CMD_REQUEST_USAGE:
 486                 {
 487                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 488                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 489                         return;
 490                 }
 491         }
 492 }
 493
 494 void CommonCommand_ladder(float request, entity caller)
 495 {
 496         switch (request)
 497         {
 498                 case CMD_REQUEST_COMMAND:
 499                 {
 500                         print_to(caller, ladder_reply);
 501                         return;  // never fall through to usage
 502                 }
 503
 504                 default:
 505                 case CMD_REQUEST_USAGE:
 506                 {
 507                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 508                         print_to(caller, "  No arguments required.");
 509                         return;
 510                 }
 511         }
 512 }
 513
 514 void CommonCommand_lsmaps(float request, entity caller)
 515 {
 516         switch (request)
 517         {
 518                 case CMD_REQUEST_COMMAND:
 519                 {
 520                         print_to(caller, lsmaps_reply);
 521                         return;  // never fall through to usage
 522                 }
 523
 524                 default:
 525                 case CMD_REQUEST_USAGE:
 526                 {
 527                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 528                         print_to(caller, "  No arguments required.");
 529                         return;
 530                 }
 531         }
 532 }
 533
 534 void CommonCommand_printmaplist(float request, entity caller)
 535 {
 536         switch (request)
 537         {
 538                 case CMD_REQUEST_COMMAND:
 539                 {
 540                         print_to(caller, maplist_reply);
 541                         return;  // never fall through to usage
 542                 }
 543
 544                 default:
 545                 case CMD_REQUEST_USAGE:
 546                 {
 547                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 548                         print_to(caller, "  No arguments required.");
 549                         return;
 550                 }
 551         }
 552 }
 553
 554 void CommonCommand_rankings(float request, entity caller)
 555 {
 556         switch (request)
 557         {
 558                 case CMD_REQUEST_COMMAND:
 559                 {
 560                         print_to(caller, rankings_reply);
 561                         return;  // never fall through to usage
 562                 }
 563
 564                 default:
 565                 case CMD_REQUEST_USAGE:
 566                 {
 567                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 568                         print_to(caller, "  No arguments required.");
 569                         return;
 570                 }
 571         }
 572 }
 573
 574 void CommonCommand_records(float request, entity caller)
 575 {
 576         switch (request)
 577         {
 578                 case CMD_REQUEST_COMMAND:
 579                 {
 580                         for (int i = 0; i < 10; ++i)
 581                                 if (records_reply[i] != "") print_to(caller, records_reply[i]);
 582
 583                         return;  // never fall through to usage
 584                 }
 585
 586                 default:
 587                 case CMD_REQUEST_USAGE:
 588                 {
 589                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 590                         print_to(caller, "  No arguments required.");
 591                         return;
 592                 }
 593         }
 594 }
 595
 596 void CommonCommand_teamstatus(float request, entity caller)
 597 {
 598         switch (request)
 599         {
 600                 case CMD_REQUEST_COMMAND:
 601                 {
 602                         Score_NicePrint(caller);
 603                         return;  // never fall through to usage
 604                 }
 605
 606                 default:
 607                 case CMD_REQUEST_USAGE:
 608                 {
 609                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 610                         print_to(caller, "  No arguments required.");
 611                         return;
 612                 }
 613         }
 614 }
 615
 616 void CommonCommand_time(float request, entity caller)
 617 {
 618         switch (request)
 619         {
 620                 case CMD_REQUEST_COMMAND:
 621                 {
 622                         print_to(caller, strcat("time = ", ftos(time)));
 623                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 624                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 625                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 626                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 627                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 628                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 629                         return;
 630                 }
 631
 632                 default:
 633                 case CMD_REQUEST_USAGE:
 634                 {
 635                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 636                         print_to(caller, "  No arguments required.");
 637                         return;
 638                 }
 639         }
 640 }
 641
 642 void CommonCommand_timein(float request, entity caller)
 643 {
 644         switch (request)
 645         {
 646                 case CMD_REQUEST_COMMAND:
 647                 {
 648                         if (!caller || autocvar_sv_timeout)
 649                         {
 650                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 651                                 else if (caller && (caller != timeout_caller))
 652                                 {
 653                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 654                                 }
 655
 656                                 else  // everything should be okay, continue aborting timeout
 657                                 {
 658                                         switch (timeout_status)
 659                                         {
 660                                                 case TIMEOUT_LEADTIME:
 661                                                 {
 662                                                         timeout_status = TIMEOUT_INACTIVE;
 663                                                         timeout_time = 0;
 664                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 665                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 666                                                         return;
 667                                                 }
 668
 669                                                 case TIMEOUT_ACTIVE:
 670                                                 {
 671                                                         timeout_time = autocvar_sv_timeout_resumetime;
 672                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 673                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 674                                                         return;
 675                                                 }
 676
 677                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 678                                                         return;
 679                                         }
 680                                 }
 681                         }
 682                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 683
 684                         return;  // never fall through to usage
 685                 }
 686
 687                 default:
 688                 case CMD_REQUEST_USAGE:
 689                 {
 690                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 691                         print_to(caller, "  No arguments required.");
 692                         return;
 693                 }
 694         }
 695 }
 696
 697 void CommonCommand_timeout(float request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 698 {
 699         switch (request)
 700         {
 701                 case CMD_REQUEST_COMMAND:
 702                 {
 703                         if (!caller || autocvar_sv_timeout)
 704                         {
 705                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 706
 707                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 708                                 else if (vote_called)
 709                                 {
 710                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 711                                 }
 712                                 else if (warmup_stage && !g_warmup_allow_timeout)
 713                                 {
 714                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 715                                 }
 716                                 else if (time < game_starttime)
 717                                 {
 718                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 719                                 }
 720                                 else if (caller && (caller.allowed_timeouts < 1))
 721                                 {
 722                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 723                                 }
 724                                 else if (caller && !IS_PLAYER(caller))
 725                                 {
 726                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 727                                 }
 728                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 729                                 {
 730                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 731                                 }
 732
 733                                 else  // everything should be okay, proceed with starting the timeout
 734                                 {
 735                                         if (caller)   caller.allowed_timeouts -= 1;
 736                                         // write a bprint who started the timeout (and how many they have left)
 737                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 738
 739                                         timeout_status = TIMEOUT_LEADTIME;
 740                                         timeout_caller = caller;
 741                                         timeout_time = autocvar_sv_timeout_length;
 742                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 743
 744                                         timeout_handler = spawn();
 745                                         timeout_handler.think = timeout_handler_think;
 746                                         timeout_handler.nextthink = time;  // always let the entity think asap
 747
 748                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 749                                 }
 750                         }
 751                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 752
 753                         return;  // never fall through to usage
 754                 }
 755
 756                 default:
 757                 case CMD_REQUEST_USAGE:
 758                 {
 759                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 760                         print_to(caller, "  No arguments required.");
 761                         return;
 762                 }
 763         }
 764 }
 765
 766 void CommonCommand_who(float request, entity caller, float argc)
 767 {
 768         switch (request)
 769         {
 770                 case CMD_REQUEST_COMMAND:
 771                 {
 772                         float total_listed_players, is_bot;
 773
 774                         float privacy = (caller && autocvar_sv_status_privacy);
 775                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 776                         string tmp_netaddress, tmp_crypto_idfp;
 777
 778                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 779                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 780                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 781
 782                         total_listed_players = 0;
 783                         FOREACH_CLIENT(true, LAMBDA(
 784                                 is_bot = (IS_BOT_CLIENT(it));
 785
 786                                 if (is_bot)
 787                                 {
 788                                         tmp_netaddress = "null/botclient";
 789                                         tmp_crypto_idfp = "null/botclient";
 790                                 }
 791                                 else if (privacy)
 792                                 {
 793                                         tmp_netaddress = "hidden";
 794                                         tmp_crypto_idfp = "hidden";
 795                                 }
 796                                 else
 797                                 {
 798                                         tmp_netaddress = it.netaddress;
 799                                         tmp_crypto_idfp = it.crypto_idfp;
 800                                 }
 801
 802                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 803                                         etof(it),
 804                                         it.netname,
 805                                         it.ping,
 806                                         it.ping_packetloss,
 807                                         process_time(1, time - it.jointime),
 808                                         tmp_netaddress,
 809                                         tmp_crypto_idfp));
 810
 811                                 ++total_listed_players;
 812                         ));
 813
 814                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 815
 816                         return;  // never fall through to usage
 817                 }
 818
 819                 default:
 820                 case CMD_REQUEST_USAGE:
 821                 {
 822                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 823                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 824                         return;
 825                 }
 826         }
 827 }
 828
 829 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 830 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 831 void CommonCommand_(float request, entity caller)
 832 {
 833     switch(request)
 834     {
 835         case CMD_REQUEST_COMMAND:
 836         {
 837
 838             return; // never fall through to usage
 839         }
 840
 841         default:
 842         case CMD_REQUEST_USAGE:
 843         {
 844             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 845             print_to(caller, "  No arguments required.");
 846             return;
 847         }
 848     }
 849 }
 850 */