qcsrc/server/command/common.qc

   1 #include "common.qh"
   2 #include <common/command/command.qh>
   3 #include "common.qh"
   4
   5 #include "../scores.qh"
   6
   7 #include <common/monsters/all.qh>
   8 #include <common/notifications/all.qh>
   9 #include <lib/warpzone/common.qh>
  10
  11
  12 // ====================================================
  13 //  Shared code for server commands, written by Samual
  14 //  Last updated: December 27th, 2011
  15 // ====================================================
  16
  17 // select the proper prefix for usage and other messages
  18 string GetCommandPrefix(entity caller)
  19 {
  20         if (caller) return "cmd";
  21         else return "sv_cmd";
  22 }
  23
  24 // if client return player nickname, or if server return admin nickname
  25 string GetCallerName(entity caller)
  26 {
  27         if (caller) return caller.netname;
  28         else return admin_name();  // ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  29 }
  30
  31 // verify that the client provided is acceptable for kicking
  32 float VerifyKickableEntity(entity client)
  33 {
  34         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  35         return CLIENT_ACCEPTABLE;
  36 }
  37
  38 // verify that the client provided is acceptable for use
  39 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  40 {
  41         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  42         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  43         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  44
  45         return CLIENT_ACCEPTABLE;
  46 }
  47
  48 // if the client is not acceptable, return a string to be used for error messages
  49 string GetClientErrorString_color(float clienterror, string original_input, string col)
  50 {
  51         switch (clienterror)
  52         {
  53                 case CLIENT_DOESNT_EXIST:
  54                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  55                 }
  56                 case CLIENT_NOT_REAL:
  57                 { return strcat(col, "Client '", original_input, col, "' is not real");
  58                 }
  59                 case CLIENT_NOT_BOT:
  60                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  61                 }
  62                 default:
  63                 { return "Incorrect usage of GetClientErrorString";
  64                 }
  65         }
  66 }
  67
  68 // is this entity number even in the possible range of entities?
  69 float VerifyClientNumber(float tmp_number)
  70 {
  71         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  72         else return true;
  73 }
  74
  75 entity GetIndexedEntity(float argc, float start_index)
  76 {
  77         entity selection;
  78         float tmp_number, index;
  79         string tmp_string;
  80
  81         next_token = -1;
  82         index = start_index;
  83         selection = world;
  84
  85         if (argc > start_index)
  86         {
  87                 if (substring(argv(index), 0, 1) == "#")
  88                 {
  89                         tmp_string = substring(argv(index), 1, -1);
  90                         ++index;
  91
  92                         if (tmp_string != "")  // is it all one token? like #1
  93                         {
  94                                 tmp_number = stof(tmp_string);
  95                         }
  96                         else if (argc > index)  // no, it's two tokens? # 1
  97                         {
  98                                 tmp_number = stof(argv(index));
  99                                 ++index;
 100                         }
 101                         else
 102                         {
 103                                 tmp_number = 0;
 104                         }
 105                 }
 106                 else  // maybe it's ONLY a number?
 107                 {
 108                         tmp_number = stof(argv(index));
 109                         ++index;
 110                 }
 111
 112                 if (VerifyClientNumber(tmp_number))
 113                 {
 114                         selection = edict_num(tmp_number);  // yes, it was a number
 115                 }
 116                 else  // no, maybe it's a name?
 117                 {
 118                         FOREACH_CLIENT(true, LAMBDA(
 119                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 120                                 {
 121                                         selection = it;
 122                                         break; // no reason to keep looking
 123                                 }
 124                         ));
 125
 126                         index = (start_index + 1);
 127                 }
 128         }
 129
 130         next_token = index;
 131         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 132         return selection;
 133 }
 134
 135 // find a player which matches the input string, and return their entity
 136 entity GetFilteredEntity(string input)
 137 {
 138         entity selection;
 139         float tmp_number;
 140
 141         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 142         else tmp_number = stof(input);
 143
 144         if (VerifyClientNumber(tmp_number))
 145         {
 146                 selection = edict_num(tmp_number);
 147         }
 148         else
 149         {
 150                 selection = world;
 151                 FOREACH_CLIENT(true, LAMBDA(
 152                         if(strdecolorize(it.netname) == strdecolorize(input))
 153                         {
 154                                 selection = it;
 155                                 break; // no reason to keep looking
 156                         }
 157                 ));
 158         }
 159
 160         return selection;
 161 }
 162
 163 // same thing, but instead return their edict number
 164 float GetFilteredNumber(string input)
 165 {
 166         entity selection = GetFilteredEntity(input);
 167         float output;
 168
 169         output = etof(selection);
 170
 171         return output;
 172 }
 173
 174 // switch between sprint and print depending on whether the receiver is the server or a player
 175 void print_to(entity to, string input)
 176 {
 177         if (to) sprint(to, strcat(input, "\n"));
 178         else LOG_INFO(input, "\n");
 179 }
 180
 181 // ==========================================
 182 //  Supporting functions for common commands
 183 // ==========================================
 184
 185 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 186 void timeout_handler_reset()
 187 {
 188         SELFPARAM();
 189         timeout_caller = world;
 190         timeout_time = 0;
 191         timeout_leadtime = 0;
 192
 193         remove(self);
 194 }
 195
 196 void timeout_handler_think(entity this)
 197 {
 198         switch (timeout_status)
 199         {
 200                 case TIMEOUT_ACTIVE:
 201                 {
 202                         if (timeout_time > 0)  // countdown is still going
 203                         {
 204                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 205
 206                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 207                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 208
 209                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 210                                 timeout_time -= 1;                                  // decrease the time counter
 211                         }
 212                         else  // time to end the timeout
 213                         {
 214                                 timeout_status = TIMEOUT_INACTIVE;
 215
 216                                 // reset the slowmo value back to normal
 217                                 cvar_set("slowmo", ftos(orig_slowmo));
 218
 219                                 // unlock the view for players so they can move around again
 220                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 221                                         it.fixangle = false;
 222                                 ));
 223
 224                                 timeout_handler_reset();
 225                         }
 226
 227                         return;
 228                 }
 229
 230                 case TIMEOUT_LEADTIME:
 231                 {
 232                         if (timeout_leadtime > 0)  // countdown is still going
 233                         {
 234                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 235
 236                                 self.nextthink = time + 1; // think again in one second
 237                                 timeout_leadtime -= 1;     // decrease the time counter
 238                         }
 239                         else  // time to begin the timeout
 240                         {
 241                                 timeout_status = TIMEOUT_ACTIVE;
 242
 243                                 // set the slowmo value to the timeout default slowmo value
 244                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 245
 246                                 // reset all the flood variables
 247                                 FOREACH_CLIENT(true, LAMBDA(
 248                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 249                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 250                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 251                                 ));
 252
 253                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 254                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 255                                         it.lastV_angle = it.v_angle;
 256                                 ));
 257
 258                                 self.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 259                         }
 260
 261                         return;
 262                 }
 263
 264
 265                 case TIMEOUT_INACTIVE:
 266                 default:
 267                 {
 268                         timeout_handler_reset();
 269                         return;
 270                 }
 271         }
 272 }
 273
 274
 275 // ===================================================
 276 //  Common commands used in both sv_cmd.qc and cmd.qc
 277 // ===================================================
 278
 279 void CommonCommand_cvar_changes(float request, entity caller)
 280 {
 281         switch (request)
 282         {
 283                 case CMD_REQUEST_COMMAND:
 284                 {
 285                         print_to(caller, cvar_changes);
 286                         return;  // never fall through to usage
 287                 }
 288
 289                 default:
 290                 case CMD_REQUEST_USAGE:
 291                 {
 292                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 293                         print_to(caller, "  No arguments required.");
 294                         print_to(caller, "See also: ^2cvar_purechanges^7");
 295                         return;
 296                 }
 297         }
 298 }
 299
 300 void CommonCommand_cvar_purechanges(float request, entity caller)
 301 {
 302         switch (request)
 303         {
 304                 case CMD_REQUEST_COMMAND:
 305                 {
 306                         print_to(caller, cvar_purechanges);
 307                         return;  // never fall through to usage
 308                 }
 309
 310                 default:
 311                 case CMD_REQUEST_USAGE:
 312                 {
 313                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 314                         print_to(caller, "  No arguments required.");
 315                         print_to(caller, "See also: ^2cvar_changes^7");
 316                         return;
 317                 }
 318         }
 319 }
 320
 321 void CommonCommand_editmob(int request, entity caller, int argc)
 322 {
 323         switch (request)
 324         {
 325                 case CMD_REQUEST_COMMAND:
 326                 {
 327                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 328                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 329
 330                         if (caller)
 331                         {
 332                                 makevectors(caller.v_angle);
 333                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 334                         }
 335
 336                         entity mon = trace_ent;
 337                         bool is_visible = IS_MONSTER(mon);
 338                         string argument = argv(2);
 339
 340                         switch (argv(1))
 341                         {
 342                                 case "name":
 343                                 {
 344                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 345                                         if (!argument)   break;  // escape to usage
 346                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 347                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 348                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 349
 350                                         string mon_oldname = mon.monster_name;
 351
 352                                         mon.monster_name = argument;
 353                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 354                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 355                                         return;
 356                                 }
 357                                 case "spawn":
 358                                 {
 359                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 360                                         if (!argv(2))   break;  // escape to usage
 361
 362                                         int moveflag, tmp_moncount = 0;
 363                                         string arg_lower = strtolower(argument);
 364                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 365                                         ret_string = "Monster spawning is currently disabled by a mutator";
 366
 367                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 368
 369                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 370                                                 if(it.realowner == caller)
 371                                                         ++tmp_moncount;
 372                                         ));
 373
 374                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 375                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 376                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 377                                         if (MUTATOR_CALLHOOK(AllowMobSpawning)) { print_to(caller, ret_string); return; }
 378                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 379                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 380                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 381                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 382                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 383
 384                                         bool found = false;
 385                                         for (int i = MON_FIRST; i <= MON_LAST; ++i)
 386                                         {
 387                                                 mon = get_monsterinfo(i);
 388                                                 if (mon.netname == arg_lower) { found = true; break; }
 389                                         }
 390
 391                                         if (!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 392
 393                                         totalspawned += 1;
 394                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 395                                         mon = spawnmonster(arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 396                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 397                                         return;
 398                                 }
 399                                 case "kill":
 400                                 {
 401                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 402                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 403                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 404
 405                                         Damage(mon, world, world, mon.health + mon.max_health + 200, DEATH_KILL.m_id, mon.origin, '0 0 0');
 406                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 407                                         return;
 408                                 }
 409                                 case "skin":
 410                                 {
 411                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 412                                         if (!argument)   break;  // escape to usage
 413                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 414                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 415                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 416                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 417
 418                                         mon.skin = stof(argument);
 419                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 420                                         return;
 421                                 }
 422                                 case "movetarget":
 423                                 {
 424                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 425                                         if (!argument)   break;  // escape to usage
 426                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 427                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 428                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 429
 430                                         mon.monster_moveflags = stof(argument);
 431                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 432                                         return;
 433                                 }
 434                                 case "butcher":
 435                                 {
 436                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 437                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(ret_string, "\n"); return; }
 438
 439                                         int tmp_remcount = 0;
 440
 441                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 442                                                 Monster_Remove(it);
 443                                                 ++tmp_remcount;
 444                                         ));
 445
 446                                         monsters_total = monsters_killed = totalspawned = 0;
 447
 448                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 449                                         return;
 450                                 }
 451                         }
 452                 }
 453
 454                 default:
 455                 case CMD_REQUEST_USAGE:
 456                 {
 457                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 458                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 459                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 460                         print_to(caller, "  spawn also takes arguments list and random");
 461                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 462                         return;
 463                 }
 464         }
 465 }
 466
 467 void CommonCommand_info(float request, entity caller, float argc)
 468 {
 469         switch (request)
 470         {
 471                 case CMD_REQUEST_COMMAND:
 472                 {
 473                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 474
 475                         if (command) wordwrap_sprint(command, 1000);
 476                         else print_to(caller, "ERROR: unsupported info command");
 477
 478                         return;  // never fall through to usage
 479                 }
 480
 481                 default:
 482                 case CMD_REQUEST_USAGE:
 483                 {
 484                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 485                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 486                         return;
 487                 }
 488         }
 489 }
 490
 491 void CommonCommand_ladder(float request, entity caller)
 492 {
 493         switch (request)
 494         {
 495                 case CMD_REQUEST_COMMAND:
 496                 {
 497                         print_to(caller, ladder_reply);
 498                         return;  // never fall through to usage
 499                 }
 500
 501                 default:
 502                 case CMD_REQUEST_USAGE:
 503                 {
 504                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 505                         print_to(caller, "  No arguments required.");
 506                         return;
 507                 }
 508         }
 509 }
 510
 511 void CommonCommand_lsmaps(float request, entity caller)
 512 {
 513         switch (request)
 514         {
 515                 case CMD_REQUEST_COMMAND:
 516                 {
 517                         print_to(caller, lsmaps_reply);
 518                         return;  // never fall through to usage
 519                 }
 520
 521                 default:
 522                 case CMD_REQUEST_USAGE:
 523                 {
 524                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 525                         print_to(caller, "  No arguments required.");
 526                         return;
 527                 }
 528         }
 529 }
 530
 531 void CommonCommand_printmaplist(float request, entity caller)
 532 {
 533         switch (request)
 534         {
 535                 case CMD_REQUEST_COMMAND:
 536                 {
 537                         print_to(caller, maplist_reply);
 538                         return;  // never fall through to usage
 539                 }
 540
 541                 default:
 542                 case CMD_REQUEST_USAGE:
 543                 {
 544                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 545                         print_to(caller, "  No arguments required.");
 546                         return;
 547                 }
 548         }
 549 }
 550
 551 void CommonCommand_rankings(float request, entity caller)
 552 {
 553         switch (request)
 554         {
 555                 case CMD_REQUEST_COMMAND:
 556                 {
 557                         print_to(caller, rankings_reply);
 558                         return;  // never fall through to usage
 559                 }
 560
 561                 default:
 562                 case CMD_REQUEST_USAGE:
 563                 {
 564                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 565                         print_to(caller, "  No arguments required.");
 566                         return;
 567                 }
 568         }
 569 }
 570
 571 void CommonCommand_records(float request, entity caller)
 572 {
 573         switch (request)
 574         {
 575                 case CMD_REQUEST_COMMAND:
 576                 {
 577                         for (int i = 0; i < 10; ++i)
 578                                 if (records_reply[i] != "") print_to(caller, records_reply[i]);
 579
 580                         return;  // never fall through to usage
 581                 }
 582
 583                 default:
 584                 case CMD_REQUEST_USAGE:
 585                 {
 586                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 587                         print_to(caller, "  No arguments required.");
 588                         return;
 589                 }
 590         }
 591 }
 592
 593 void CommonCommand_teamstatus(float request, entity caller)
 594 {
 595         switch (request)
 596         {
 597                 case CMD_REQUEST_COMMAND:
 598                 {
 599                         Score_NicePrint(caller);
 600                         return;  // never fall through to usage
 601                 }
 602
 603                 default:
 604                 case CMD_REQUEST_USAGE:
 605                 {
 606                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 607                         print_to(caller, "  No arguments required.");
 608                         return;
 609                 }
 610         }
 611 }
 612
 613 void CommonCommand_time(float request, entity caller)
 614 {
 615         switch (request)
 616         {
 617                 case CMD_REQUEST_COMMAND:
 618                 {
 619                         print_to(caller, strcat("time = ", ftos(time)));
 620                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 621                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 622                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 623                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 624                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 625                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 626                         return;
 627                 }
 628
 629                 default:
 630                 case CMD_REQUEST_USAGE:
 631                 {
 632                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 633                         print_to(caller, "  No arguments required.");
 634                         return;
 635                 }
 636         }
 637 }
 638
 639 void CommonCommand_timein(float request, entity caller)
 640 {
 641         switch (request)
 642         {
 643                 case CMD_REQUEST_COMMAND:
 644                 {
 645                         if (!caller || autocvar_sv_timeout)
 646                         {
 647                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 648                                 else if (caller && (caller != timeout_caller))
 649                                 {
 650                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 651                                 }
 652
 653                                 else  // everything should be okay, continue aborting timeout
 654                                 {
 655                                         switch (timeout_status)
 656                                         {
 657                                                 case TIMEOUT_LEADTIME:
 658                                                 {
 659                                                         timeout_status = TIMEOUT_INACTIVE;
 660                                                         timeout_time = 0;
 661                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 662                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 663                                                         return;
 664                                                 }
 665
 666                                                 case TIMEOUT_ACTIVE:
 667                                                 {
 668                                                         timeout_time = autocvar_sv_timeout_resumetime;
 669                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 670                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 671                                                         return;
 672                                                 }
 673
 674                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 675                                                         return;
 676                                         }
 677                                 }
 678                         }
 679                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 680
 681                         return;  // never fall through to usage
 682                 }
 683
 684                 default:
 685                 case CMD_REQUEST_USAGE:
 686                 {
 687                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 688                         print_to(caller, "  No arguments required.");
 689                         return;
 690                 }
 691         }
 692 }
 693
 694 void CommonCommand_timeout(float request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 695 {
 696         switch (request)
 697         {
 698                 case CMD_REQUEST_COMMAND:
 699                 {
 700                         if (!caller || autocvar_sv_timeout)
 701                         {
 702                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 703
 704                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 705                                 else if (vote_called)
 706                                 {
 707                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 708                                 }
 709                                 else if (warmup_stage && !g_warmup_allow_timeout)
 710                                 {
 711                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 712                                 }
 713                                 else if (time < game_starttime)
 714                                 {
 715                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 716                                 }
 717                                 else if (caller && (caller.allowed_timeouts < 1))
 718                                 {
 719                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 720                                 }
 721                                 else if (caller && !IS_PLAYER(caller))
 722                                 {
 723                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 724                                 }
 725                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 726                                 {
 727                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 728                                 }
 729
 730                                 else  // everything should be okay, proceed with starting the timeout
 731                                 {
 732                                         if (caller)   caller.allowed_timeouts -= 1;
 733                                         // write a bprint who started the timeout (and how many they have left)
 734                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 735
 736                                         timeout_status = TIMEOUT_LEADTIME;
 737                                         timeout_caller = caller;
 738                                         timeout_time = autocvar_sv_timeout_length;
 739                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 740
 741                                         timeout_handler = spawn();
 742                                         setthink(timeout_handler, timeout_handler_think);
 743                                         timeout_handler.nextthink = time;  // always let the entity think asap
 744
 745                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 746                                 }
 747                         }
 748                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 749
 750                         return;  // never fall through to usage
 751                 }
 752
 753                 default:
 754                 case CMD_REQUEST_USAGE:
 755                 {
 756                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 757                         print_to(caller, "  No arguments required.");
 758                         return;
 759                 }
 760         }
 761 }
 762
 763 void CommonCommand_who(float request, entity caller, float argc)
 764 {
 765         switch (request)
 766         {
 767                 case CMD_REQUEST_COMMAND:
 768                 {
 769                         float total_listed_players, is_bot;
 770
 771                         float privacy = (caller && autocvar_sv_status_privacy);
 772                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 773                         string tmp_netaddress, tmp_crypto_idfp;
 774
 775                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 776                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 777                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 778
 779                         total_listed_players = 0;
 780                         FOREACH_CLIENT(true, LAMBDA(
 781                                 is_bot = (IS_BOT_CLIENT(it));
 782
 783                                 if (is_bot)
 784                                 {
 785                                         tmp_netaddress = "null/botclient";
 786                                         tmp_crypto_idfp = "null/botclient";
 787                                 }
 788                                 else if (privacy)
 789                                 {
 790                                         tmp_netaddress = "hidden";
 791                                         tmp_crypto_idfp = "hidden";
 792                                 }
 793                                 else
 794                                 {
 795                                         tmp_netaddress = it.netaddress;
 796                                         tmp_crypto_idfp = it.crypto_idfp;
 797                                 }
 798
 799                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 800                                         etof(it),
 801                                         it.netname,
 802                                         it.ping,
 803                                         it.ping_packetloss,
 804                                         process_time(1, time - it.jointime),
 805                                         tmp_netaddress,
 806                                         tmp_crypto_idfp));
 807
 808                                 ++total_listed_players;
 809                         ));
 810
 811                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 812
 813                         return;  // never fall through to usage
 814                 }
 815
 816                 default:
 817                 case CMD_REQUEST_USAGE:
 818                 {
 819                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 820                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 821                         return;
 822                 }
 823         }
 824 }
 825
 826 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 827 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 828 void CommonCommand_(float request, entity caller)
 829 {
 830     switch(request)
 831     {
 832         case CMD_REQUEST_COMMAND:
 833         {
 834
 835             return; // never fall through to usage
 836         }
 837
 838         default:
 839         case CMD_REQUEST_USAGE:
 840         {
 841             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 842             print_to(caller, "  No arguments required.");
 843             return;
 844         }
 845     }
 846 }
 847 */