qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if not(accepted > 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_butcher(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         if(g_td) { print("This command doesn't work in Tower Defense.\n"); return; }
 149
 150             float removed_count = 0;
 151                         entity montokill, head;
 152
 153             FOR_EACH_MONSTER(montokill)
 154             {
 155                                 WaypointSprite_Kill(montokill.sprite);
 156
 157                 remove(montokill);
 158                 removed_count += 1;
 159             }
 160
 161                         FOR_EACH_PLAYER(head)
 162                                 head.monstercount = 0;
 163
 164                         totalspawned = 0;
 165
 166                         if(removed_count <= 0)
 167                                 print("No monsters to kill\n");
 168                         else
 169                                 print(strcat("Killed ", ftos(removed_count), " monster", ((removed_count == 1) ? "\n" : "s\n")));
 170
 171                         return; // never fall through to usage
 172                 }
 173
 174                 default:
 175                 case CMD_REQUEST_USAGE:
 176                 {
 177                         print("\nUsage:^3 sv_cmd butcher\n");
 178                         print("  No arguments required.\n");
 179                         return;
 180                 }
 181         }
 182 }
 183
 184 void GameCommand_allready(float request)
 185 {
 186         switch(request)
 187         {
 188                 case CMD_REQUEST_COMMAND:
 189                 {
 190                         ReadyRestart();
 191                         return;
 192                 }
 193
 194                 default:
 195                 case CMD_REQUEST_USAGE:
 196                 {
 197                         print("\nUsage:^3 sv_cmd allready\n");
 198                         print("  No arguments required.\n");
 199                         return;
 200                 }
 201         }
 202 }
 203
 204 void GameCommand_allspec(float request, float argc)
 205 {
 206         switch(request)
 207         {
 208                 case CMD_REQUEST_COMMAND:
 209                 {
 210                         entity client;
 211                         string reason = argv(1);
 212                         float i = 0;
 213
 214                         FOR_EACH_REALPLAYER(client)
 215                         {
 216                                 self = client;
 217                                 PutObserverInServer();
 218                                 ++i;
 219                         }
 220                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 221                         else { print("No players found to spectate.\n"); }
 222                         return;
 223                 }
 224
 225                 default:
 226                 case CMD_REQUEST_USAGE:
 227                 {
 228                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 229                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 230                         print("See also: ^2moveplayer, shuffleteams^7\n");
 231                         return;
 232                 }
 233         }
 234 }
 235
 236 void GameCommand_anticheat(float request, float argc)
 237 {
 238         switch(request)
 239         {
 240                 case CMD_REQUEST_COMMAND:
 241                 {
 242                         entity client = GetIndexedEntity(argc, 1);
 243                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 244
 245                         if(accepted > 0)
 246                         {
 247                                 self = client;
 248                                 anticheat_report();
 249                                 return;
 250                         }
 251                         else
 252                         {
 253                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 254                         }
 255                 }
 256
 257                 default:
 258                         print("Incorrect parameters for ^2anticheat^7\n");
 259                 case CMD_REQUEST_USAGE:
 260                 {
 261                         print("\nUsage:^3 sv_cmd anticheat client\n");
 262                         print("  'client' is the entity number or name of the player.\n");
 263                         return;
 264                 }
 265         }
 266 }
 267
 268 void GameCommand_bbox(float request)
 269 {
 270         switch(request)
 271         {
 272                 case CMD_REQUEST_COMMAND:
 273                 {
 274                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 275                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 276                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 277                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 278                         print("Solid bounding box size:");
 279
 280                         tracebox('1 0 0' * world.absmin_x,
 281                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 282                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 283                                                         '1 0 0' * world.absmax_x,
 284                                         MOVE_WORLDONLY,
 285                                         world);
 286                         if(trace_startsolid)
 287                                 print(" ", ftos(world.absmin_x));
 288                         else
 289                                 print(" ", ftos(trace_endpos_x));
 290
 291                         tracebox('0 1 0' * world.absmin_y,
 292                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 293                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 294                                                         '0 1 0' * world.absmax_y,
 295                                         MOVE_WORLDONLY,
 296                                         world);
 297                         if(trace_startsolid)
 298                                 print(" ", ftos(world.absmin_y));
 299                         else
 300                                 print(" ", ftos(trace_endpos_y));
 301
 302                         tracebox('0 0 1' * world.absmin_z,
 303                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 304                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 305                                                         '0 0 1' * world.absmax_z,
 306                                         MOVE_WORLDONLY,
 307                                         world);
 308                         if(trace_startsolid)
 309                                 print(" ", ftos(world.absmin_z));
 310                         else
 311                                 print(" ", ftos(trace_endpos_z));
 312
 313                         tracebox('1 0 0' * world.absmax_x,
 314                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 315                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 316                                                         '1 0 0' * world.absmin_x,
 317                                         MOVE_WORLDONLY,
 318                                         world);
 319                         if(trace_startsolid)
 320                                 print(" ", ftos(world.absmax_x));
 321                         else
 322                                 print(" ", ftos(trace_endpos_x));
 323
 324                         tracebox('0 1 0' * world.absmax_y,
 325                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 326                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 327                                                         '0 1 0' * world.absmin_y,
 328                                         MOVE_WORLDONLY,
 329                                         world);
 330                         if(trace_startsolid)
 331                                 print(" ", ftos(world.absmax_y));
 332                         else
 333                                 print(" ", ftos(trace_endpos_y));
 334
 335                         tracebox('0 0 1' * world.absmax_z,
 336                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 337                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 338                                                         '0 0 1' * world.absmin_z,
 339                                         MOVE_WORLDONLY,
 340                                         world);
 341                         if(trace_startsolid)
 342                                 print(" ", ftos(world.absmax_z));
 343                         else
 344                                 print(" ", ftos(trace_endpos_z));
 345
 346                         print("\n");
 347                         return;
 348                 }
 349
 350                 default:
 351                 case CMD_REQUEST_USAGE:
 352                 {
 353                         print("\nUsage:^3 sv_cmd bbox\n");
 354                         print("  No arguments required.\n");
 355                         print("See also: ^2gettaginfo, trace^7\n");
 356                         return;
 357                 }
 358         }
 359 }
 360
 361 void GameCommand_bot_cmd(float request, float argc, string command)
 362 {
 363         switch(request)
 364         {
 365                 case CMD_REQUEST_COMMAND:
 366                 {
 367                         entity bot;
 368
 369                         if(argv(1) == "reset")
 370                         {
 371                                 bot_resetqueues();
 372                                 return;
 373                         }
 374                         else if(argv(1) == "setbots")
 375                         {
 376                                 cvar_settemp("bot_vs_human", "0");
 377                                 cvar_settemp("minplayers", "0");
 378                                 cvar_settemp("bot_number", "0");
 379                                 bot_fixcount();
 380                                 cvar_settemp("bot_number", argv(2));
 381                                 if(!bot_fixcount())
 382                                         print("Sorry, could not set requested bot count\n");
 383                                 return;
 384                         }
 385                         else if(argv(1) == "load" && argc == 3)
 386                         {
 387                                 float fh, i;
 388                                 string s;
 389                                 fh = fopen(argv(2), FILE_READ);
 390                                 if(fh < 0)
 391                                 {
 392                                         print("cannot open the file\n");
 393                                         return;
 394                                 }
 395
 396                                 i = 0;
 397                                 while((s = fgets(fh)))
 398                                 {
 399                                         argc = tokenize_console(s);
 400
 401                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 402                                         {
 403                                                 if(argv(2) == "reset")
 404                                                 {
 405                                                         bot_resetqueues();
 406                                                 }
 407                                                 else if(argv(2) == "setbots")
 408                                                 {
 409                                                         cvar_settemp("bot_vs_human", "0");
 410                                                         cvar_settemp("minplayers", "0");
 411                                                         cvar_settemp("bot_number", "0");
 412                                                         bot_fixcount();
 413                                                         cvar_settemp("bot_number", argv(3));
 414                                                         if(!bot_fixcount())
 415                                                                 print("Sorry, could not set requested bot count\n");
 416                                                 }
 417                                                 else
 418                                                 {
 419                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 420                                                         bot = find_bot_by_number(stof(argv(2)));
 421                                                         if(bot == world)
 422                                                                 bot = find_bot_by_name(argv(2));
 423                                                         if(bot)
 424                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 425                                                 }
 426                                         }
 427                                         else
 428                                                 localcmd(strcat(s, "\n"));
 429
 430                                         ++i;
 431                                 }
 432                                 print(ftos(i), " commands read\n");
 433                                 fclose(fh);
 434                                 return;
 435                         }
 436                         else if(argv(1) == "help")
 437                         {
 438                                 if(argv(2))
 439                                         bot_cmdhelp(argv(2));
 440                                 else
 441                                         bot_list_commands();
 442                                 return;
 443                         }
 444                         else if(argc >= 3) // this comes last
 445                         {
 446                                 bot = find_bot_by_number(stof(argv(1)));
 447                                 if(bot == world)
 448                                         bot = find_bot_by_name(argv(1));
 449                                 if(bot)
 450                                 {
 451                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 452                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 453                                         return;
 454                                 }
 455                                 else
 456                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 457                         }
 458                 }
 459
 460                 default:
 461                         print("Incorrect parameters for ^2bot_cmd^7\n");
 462                 case CMD_REQUEST_USAGE:
 463                 {
 464                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 465                         print("  'client' can be either the name or entity id of the bot\n");
 466                         print("  For full list of commands, see bot_cmd help [command].\n");
 467                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 468                         print("          sv_cmd bot_cmd client presskey jump\n");
 469                         return;
 470                 }
 471         }
 472 }
 473
 474 void GameCommand_cointoss(float request, float argc)
 475 {
 476         switch(request)
 477         {
 478                 case CMD_REQUEST_COMMAND:
 479                 {
 480                         entity client;
 481                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 482                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 483                         string choice = ((random() > 0.5) ? result1 : result2);
 484
 485                         FOR_EACH_CLIENT(client)
 486                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 487                         bprint(strcat("^3Throwing coin... Result: ", choice));
 488                         return;
 489                 }
 490
 491                 default:
 492                 case CMD_REQUEST_USAGE:
 493                 {
 494                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 495                         print("  Where 'result1' and 'result2' are user created options.\n");
 496                         return;
 497                 }
 498         }
 499 }
 500
 501 void GameCommand_database(float request, float argc)
 502 {
 503         switch(request)
 504         {
 505                 case CMD_REQUEST_COMMAND:
 506                 {
 507                         if(argc == 3)
 508                         {
 509                                 if(argv(1) == "save")
 510                                 {
 511                                         db_save(ServerProgsDB, argv(2));
 512                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 513                                         return;
 514                                 }
 515                                 else if(argv(1) == "dump")
 516                                 {
 517                                         db_dump(ServerProgsDB, argv(2));
 518                                         print("DB dumped.\n"); // wtf does this do?
 519                                         return;
 520                                 }
 521                                 else if(argv(1) == "load")
 522                                 {
 523                                         db_close(ServerProgsDB);
 524                                         ServerProgsDB = db_load(argv(2));
 525                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 526                                         return;
 527                                 }
 528                         }
 529                 }
 530
 531                 default:
 532                         print("Incorrect parameters for ^2database^7\n");
 533                 case CMD_REQUEST_USAGE:
 534                 {
 535                         print("\nUsage:^3 sv_cmd database action filename\n");
 536                         print("  Where 'action' is the command to complete,\n");
 537                         print("  and 'filename' is what it acts upon.\n");
 538                         print("  Full list of commands here: \"save, dump, load.\"\n");
 539                         return;
 540                 }
 541         }
 542 }
 543
 544 void GameCommand_defer_clear(float request, float argc)
 545 {
 546         switch(request)
 547         {
 548                 case CMD_REQUEST_COMMAND:
 549                 {
 550                         entity client;
 551                         float accepted;
 552
 553                         if(argc >= 2)
 554                         {
 555                                 client = GetIndexedEntity(argc, 1);
 556                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 557
 558                                 if(accepted > 0)
 559                                 {
 560                                         stuffcmd(client, "defer clear\n");
 561                                         print("defer clear stuffed to ", client.netname, "\n");
 562                                 }
 563                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 564
 565                                 return;
 566                         }
 567                 }
 568
 569                 default:
 570                         print("Incorrect parameters for ^2defer_clear^7\n");
 571                 case CMD_REQUEST_USAGE:
 572                 {
 573                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 574                         print("  'client' is the entity number or name of the player.\n");
 575                         print("See also: ^2defer_clear_all^7\n");
 576                         return;
 577                 }
 578         }
 579 }
 580
 581 void GameCommand_defer_clear_all(float request)
 582 {
 583         switch(request)
 584         {
 585                 case CMD_REQUEST_COMMAND:
 586                 {
 587                         entity client;
 588                         float i = 0;
 589                         float argc;
 590
 591                         FOR_EACH_CLIENT(client)
 592                         {
 593                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 594                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 595                                 ++i;
 596                         }
 597                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 598                         return;
 599                 }
 600
 601                 default:
 602                 case CMD_REQUEST_USAGE:
 603                 {
 604                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 605                         print("  No arguments required.\n");
 606                         print("See also: ^2defer_clear^7\n");
 607                         return;
 608                 }
 609         }
 610 }
 611
 612 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 613 {
 614         switch(request)
 615         {
 616                 case CMD_REQUEST_COMMAND:
 617                 {
 618                         if(argv(1))
 619                         {
 620                                 if(argv(2))
 621                                         race_deleteTime(argv(2), stof(argv(1)));
 622                                 else
 623                                         race_deleteTime(GetMapname(), stof(argv(1)));
 624                                 return;
 625                         }
 626                 }
 627
 628                 default:
 629                         print("Incorrect parameters for ^2delrec^7\n");
 630                 case CMD_REQUEST_USAGE:
 631                 {
 632                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 633                         print("  'ranking' is which ranking level to clear up to, \n");
 634                         print("  it will clear all records up to nth place.\n");
 635                         print("  if 'map' is not provided it will use current map.\n");
 636                         return;
 637                 }
 638         }
 639 }
 640
 641 void GameCommand_effectindexdump(float request)
 642 {
 643         switch(request)
 644         {
 645                 case CMD_REQUEST_COMMAND:
 646                 {
 647                         float fh, d;
 648                         string s;
 649
 650                         d = db_create();
 651                         print("begin of effects list\n");
 652                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 653                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 654                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 655                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 656                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 657                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 658                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 659                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 660                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 661                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 662                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 663                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 664                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 665                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 666                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 667                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 668                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 669                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 670                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 671                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 672                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 673                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 674                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 675                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 676                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 677                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 678                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 679                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 680                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 681                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 682                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 683                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 684                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 685                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 686                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 687                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 688
 689                         fh = fopen("effectinfo.txt", FILE_READ);
 690                         while((s = fgets(fh)))
 691                         {
 692                                 tokenize_console(s);
 693                                 if(argv(0) == "effect")
 694                                 {
 695                                         if(db_get(d, argv(1)) != "1")
 696                                         {
 697                                                 if(particleeffectnum(argv(1)) >= 0)
 698                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 699                                                 db_put(d, argv(1), "1");
 700                                         }
 701                                 }
 702                         }
 703                         print("end of effects list\n");
 704
 705                         db_close(d);
 706                         return;
 707                 }
 708
 709                 default:
 710                 case CMD_REQUEST_USAGE:
 711                 {
 712                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 713                         print("  No arguments required.\n");
 714                         return;
 715                 }
 716         }
 717 }
 718
 719 void GameCommand_extendmatchtime(float request)
 720 {
 721         switch(request)
 722         {
 723                 case CMD_REQUEST_COMMAND:
 724                 {
 725                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 726                         return;
 727                 }
 728
 729                 default:
 730                 case CMD_REQUEST_USAGE:
 731                 {
 732                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 733                         print("  No arguments required.\n");
 734                         print("See also: ^2reducematchtime^7\n");
 735                         return;
 736                 }
 737         }
 738 }
 739
 740 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 741 {
 742         switch(request)
 743         {
 744                 case CMD_REQUEST_COMMAND:
 745                 {
 746                         entity client;
 747
 748                         for(client = world; (client = find(client, classname, argv(1))); )
 749                                 print(etos(client), "\n");
 750
 751                         return;
 752                 }
 753
 754                 default:
 755                         print("Incorrect parameters for ^2find^7\n");
 756                 case CMD_REQUEST_USAGE:
 757                 {
 758                         print("\nUsage:^3 sv_cmd find classname\n");
 759                         print("  Where 'classname' is the classname to search for.\n");
 760                         return;
 761                 }
 762         }
 763 }
 764
 765 void GameCommand_gametype(float request, float argc)
 766 {
 767         switch(request)
 768         {
 769                 case CMD_REQUEST_COMMAND:
 770                 {
 771                         if(argv(1) != "")
 772                         {
 773                                 string s = argv(1);
 774                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 775
 776                                 if(t)
 777                                 {
 778                                         MapInfo_SwitchGameType(t);
 779                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 780                                         if(MapInfo_count > 0)
 781                                                 bprint("Game type successfully switched to ", s, "\n");
 782                                         else
 783                                         {
 784                                                 bprint("Cannot use this game type: no map for it found\n");
 785                                                 MapInfo_SwitchGameType(tsave);
 786                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 787                                         }
 788                                 }
 789                                 else
 790                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 791
 792                                 return;
 793                         }
 794                 }
 795
 796                 default:
 797                         print("Incorrect parameters for ^2gametype^7\n");
 798                 case CMD_REQUEST_USAGE:
 799                 {
 800                         print("\nUsage:^3 sv_cmd gametype mode\n");
 801                         print("  Where 'mode' is the gametype mode to switch to.\n");
 802                         print("See also: ^2gotomap^7\n");
 803                         return;
 804                 }
 805         }
 806 }
 807
 808 void GameCommand_gettaginfo(float request, float argc)
 809 {
 810         switch(request)
 811         {
 812                 case CMD_REQUEST_COMMAND:
 813                 {
 814                         entity tmp_entity;
 815                         float i;
 816                         vector v;
 817
 818                         if(argc >= 4)
 819                         {
 820                                 tmp_entity = spawn();
 821                                 if(argv(1) == "w")
 822                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 823                                 else
 824                                 {
 825                                         precache_model(argv(1));
 826                                         setmodel(tmp_entity, argv(1));
 827                                 }
 828                                 tmp_entity.frame = stof(argv(2));
 829                                 if(substring(argv(3), 0, 1) == "#")
 830                                         i = stof(substring(argv(3), 1, -1));
 831                                 else
 832                                         i = gettagindex(tmp_entity, argv(3));
 833                                 if(i)
 834                                 {
 835                                         v = gettaginfo(tmp_entity, i);
 836                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 837                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 838                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 839                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 840                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 841                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 842                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 843                                         if(argc >= 6)
 844                                         {
 845                                                 v_y = -v_y;
 846                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 847                                         }
 848                                 }
 849                                 else
 850                                         print("bone not found\n");
 851
 852                                 remove(tmp_entity);
 853                                 return;
 854                         }
 855                 }
 856
 857                 default:
 858                         print("Incorrect parameters for ^2gettaginfo^7\n");
 859                 case CMD_REQUEST_USAGE:
 860                 {
 861                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 862                         print("See also: ^2bbox, trace^7\n");
 863                         return;
 864                 }
 865         }
 866 }
 867
 868 void GameCommand_animbench(float request, float argc)
 869 {
 870         switch(request)
 871         {
 872                 case CMD_REQUEST_COMMAND:
 873                 {
 874                         entity tmp_entity;
 875
 876                         if(argc >= 4)
 877                         {
 878                                 tmp_entity = spawn();
 879                                 if(argv(1) == "w")
 880                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 881                                 else
 882                                 {
 883                                         precache_model(argv(1));
 884                                         setmodel(tmp_entity, argv(1));
 885                                 }
 886                                 float f1 = stof(argv(2));
 887                                 float f2 = stof(argv(3));
 888                                 float t0;
 889                                 float t1 = 0;
 890                                 float t2 = 0;
 891                                 float n = 0;
 892
 893                                 while(t1 + t2 < 1)
 894                                 {
 895                                         tmp_entity.frame = f1;
 896                                         t0 = gettime(GETTIME_HIRES);
 897                                         getsurfacepoint(tmp_entity, 0, 0);
 898                                         t1 += gettime(GETTIME_HIRES) - t0;
 899                                         tmp_entity.frame = f2;
 900                                         t0 = gettime(GETTIME_HIRES);
 901                                         getsurfacepoint(tmp_entity, 0, 0);
 902                                         t2 += gettime(GETTIME_HIRES) - t0;
 903                                         n += 1;
 904                                 }
 905                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 906                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 907
 908                                 remove(tmp_entity);
 909                                 return;
 910                         }
 911                 }
 912
 913                 default:
 914                         print("Incorrect parameters for ^2gettaginfo^7\n");
 915                 case CMD_REQUEST_USAGE:
 916                 {
 917                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 918                         print("See also: ^2bbox, trace^7\n");
 919                         return;
 920                 }
 921         }
 922 }
 923
 924 void GameCommand_gotomap(float request, float argc)
 925 {
 926         switch(request)
 927         {
 928                 case CMD_REQUEST_COMMAND:
 929                 {
 930                         if(argv(1))
 931                         {
 932                                 print(GotoMap(argv(1)), "\n");
 933                                 return;
 934                         }
 935                 }
 936
 937                 default:
 938                         print("Incorrect parameters for ^2gotomap^7\n");
 939                 case CMD_REQUEST_USAGE:
 940                 {
 941                         print("\nUsage:^3 sv_cmd gotomap map\n");
 942                         print("  Where 'map' is the *.bsp file to change to.\n");
 943                         print("See also: ^2gametype^7\n");
 944                         return;
 945                 }
 946         }
 947 }
 948
 949 void GameCommand_lockteams(float request)
 950 {
 951         switch(request)
 952         {
 953                 case CMD_REQUEST_COMMAND:
 954                 {
 955                         if(teamplay)
 956                         {
 957                                 lockteams = 1;
 958                                 bprint("^1The teams are now locked.\n");
 959                         }
 960                         else
 961                         {
 962                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 963                         }
 964                         return;
 965                 }
 966
 967                 default:
 968                 case CMD_REQUEST_USAGE:
 969                 {
 970                         print("\nUsage:^3 sv_cmd lockteams\n");
 971                         print("  No arguments required.\n");
 972                         print("See also: ^2unlockteams^7\n");
 973                         return;
 974                 }
 975         }
 976 }
 977
 978 void GameCommand_make_mapinfo(float request)
 979 {
 980         switch(request)
 981         {
 982                 case CMD_REQUEST_COMMAND:
 983                 {
 984                         entity tmp_entity;
 985
 986                         tmp_entity = spawn();
 987                         tmp_entity.classname = "make_mapinfo";
 988                         tmp_entity.think = make_mapinfo_Think;
 989                         tmp_entity.nextthink = time;
 990                         MapInfo_Enumerate();
 991                         return;
 992                 }
 993
 994                 default:
 995                 case CMD_REQUEST_USAGE:
 996                 {
 997                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
 998                         print("  No arguments required.\n");
 999                         print("See also: ^2radarmap^7\n");
1000                         return;
1001                 }
1002         }
1003 }
1004
1005 void GameCommand_moveplayer(float request, float argc)
1006 {
1007         switch(request)
1008         {
1009                 case CMD_REQUEST_COMMAND:
1010                 {
1011                         float accepted;
1012                         entity client;
1013
1014                         string targets = strreplace(",", " ", argv(1));
1015                         string original_targets = strreplace(" ", ", ", targets);
1016                         string destination = argv(2);
1017
1018                         string successful, t;
1019                         successful = string_null;
1020
1021                         // lets see if the target(s) even actually exist.
1022                         if((targets) && (destination))
1023                         {
1024                                 for(;targets;)
1025                                 {
1026                                         t = car(targets); targets = cdr(targets);
1027
1028                                         // Check to see if the player is a valid target
1029                                         client = GetFilteredEntity(t);
1030                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
1031
1032                                         if not(accepted > 0)
1033                                         {
1034                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1035                                                 continue;
1036                                         }
1037
1038                                         // Where are we putting this player?
1039                                         if(destination == "spec" || destination == "spectator")
1040                                         {
1041                                                 if(client.classname != "spectator" && client.classname != "observer")
1042                                                 {
1043                                                         self = client;
1044                                                         PutObserverInServer();
1045
1046                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1047                                                 }
1048                                                 else
1049                                                 {
1050                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1051                                                 }
1052                                                 continue;
1053                                         }
1054                                         else
1055                                         {
1056                                                 if(client.classname != "spectator" && client.classname != "observer")
1057                                                 {
1058                                                         if(teamplay)
1059                                                         {
1060                                                                 // set up
1061                                                                 float team_id;
1062                                                                 float save = client.team_forced;
1063                                                                 client.team_forced = 0;
1064
1065                                                                 // find the team to move the player to
1066                                                                 team_id = Team_ColorToTeam(destination);
1067                                                                 if(team_id == client.team) // already on the destination team
1068                                                                 {
1069                                                                         // keep the forcing undone
1070                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1071                                                                         continue;
1072                                                                 }
1073                                                                 else if(team_id == 0)  // auto team
1074                                                                 {
1075                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1076                                                                 }
1077                                                                 else
1078                                                                 {
1079                                                                         CheckAllowedTeams(client);
1080                                                                 }
1081                                                                 client.team_forced = save;
1082
1083                                                                 // Check to see if the destination team is even available
1084                                                                 switch(team_id)
1085                                                                 {
1086                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1087                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1088                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1089                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1090
1091                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1092                                                                 }
1093
1094                                                                 // If so, lets continue and finally move the player
1095                                                                 client.team_forced = 0;
1096                                                                 MoveToTeam(client, team_id, 6);
1097                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1098                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1099                                                                 continue;
1100                                                         }
1101                                                         else
1102                                                         {
1103                                                                 print("Can't change teams when currently not playing a team game.\n");
1104                                                                 return;
1105                                                         }
1106                                                 }
1107                                                 else
1108                                                 {
1109                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1110                                                         return;
1111                                                 }
1112                                         }
1113                                 }
1114
1115                                 if(successful)
1116                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1117                                 else
1118                                         print("No players given (", original_targets, ") are able to move.\n");
1119
1120                                 return; // still correct parameters so return to avoid usage print
1121                         }
1122                 }
1123
1124                 default:
1125                         print("Incorrect parameters for ^2moveplayer^7\n");
1126                 case CMD_REQUEST_USAGE:
1127                 {
1128                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1129                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1130                         print("  'destination' is what to send the player to, be it team or spectating\n");
1131                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1132                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1133                         print("          sv_cmd moveplayer 2 spec \n");
1134                         print("See also: ^2allspec, shuffleteams^7\n");
1135                         return;
1136                 }
1137         }
1138 }
1139
1140 void GameCommand_nospectators(float request)
1141 {
1142         switch(request)
1143         {
1144                 case CMD_REQUEST_COMMAND:
1145                 {
1146                         blockSpectators = 1;
1147                         entity plr;
1148                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1149                         {
1150                                 if(plr.classname == "spectator" || plr.classname == "observer")
1151                                 {
1152                                         plr.spectatortime = time;
1153                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1154                                 }
1155                         }
1156                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1157                         return;
1158                 }
1159
1160                 default:
1161                 case CMD_REQUEST_USAGE:
1162                 {
1163                         print("\nUsage:^3 sv_cmd nospectators\n");
1164                         print("  No arguments required.\n");
1165                         return;
1166                 }
1167         }
1168 }
1169
1170 void GameCommand_playerdemo(float request, float argc)
1171 {
1172         switch(request)
1173         {
1174                 case CMD_REQUEST_COMMAND:
1175                 {
1176                         if(argv(2) && argv(3))
1177                         {
1178                                 entity client;
1179                                 float i, n, accepted;
1180
1181                                 switch(argv(1))
1182                                 {
1183                                         case "read":
1184                                         {
1185                                                 client = GetIndexedEntity(argc, 2);
1186                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1187
1188                                                 if not(accepted > 0)
1189                                                 {
1190                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1191                                                         return;
1192                                                 }
1193
1194                                                 self = client;
1195                                                 playerdemo_open_read(argv(next_token));
1196                                                 return;
1197                                         }
1198
1199                                         case "write":
1200                                         {
1201                                                 client = GetIndexedEntity(argc, 2);
1202                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1203
1204                                                 if not(accepted > 0)
1205                                                 {
1206                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1207                                                         return;
1208                                                 }
1209
1210                                                 self = client;
1211                                                 playerdemo_open_write(argv(next_token));
1212                                                 return;
1213                                         }
1214
1215                                         case "auto_read_and_write":
1216                                         {
1217                                                 n = GetFilteredNumber(argv(3));
1218                                                 cvar_set("bot_number", ftos(n));
1219
1220                                                 localcmd("wait; wait; wait\n");
1221                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1222
1223                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1224                                                 return;
1225                                         }
1226
1227                                         case "auto_read":
1228                                         {
1229                                                 n = GetFilteredNumber(argv(3));
1230                                                 cvar_set("bot_number", ftos(n));
1231
1232                                                 localcmd("wait; wait; wait\n");
1233                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1234                                                 return;
1235                                         }
1236                                 }
1237                         }
1238                 }
1239
1240                 default:
1241                         print("Incorrect parameters for ^2playerdemo^7\n");
1242                 case CMD_REQUEST_USAGE:
1243                 {
1244                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1245                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1246                         return;
1247                 }
1248         }
1249 }
1250
1251 void GameCommand_printstats(float request)
1252 {
1253         switch(request)
1254         {
1255                 case CMD_REQUEST_COMMAND:
1256                 {
1257                         DumpStats(FALSE);
1258                         print("stats dumped.\n");
1259                         return;
1260                 }
1261
1262                 default:
1263                 case CMD_REQUEST_USAGE:
1264                 {
1265                         print("\nUsage:^3 sv_cmd printstats\n");
1266                         print("  No arguments required.\n");
1267                         return;
1268                 }
1269         }
1270 }
1271
1272 void GameCommand_radarmap(float request, float argc)
1273 {
1274         switch(request)
1275         {
1276                 case CMD_REQUEST_COMMAND:
1277                 {
1278                         if(RadarMap_Make(argc))
1279                                 return;
1280                 }
1281
1282                 default:
1283                         print("Incorrect parameters for ^2radarmap^7\n");
1284                 case CMD_REQUEST_USAGE:
1285                 {
1286                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1287                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1288                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1289                         print("See also: ^2make_mapinfo^7\n");
1290                         return;
1291                 }
1292         }
1293 }
1294
1295 void GameCommand_reducematchtime(float request)
1296 {
1297         switch(request)
1298         {
1299                 case CMD_REQUEST_COMMAND:
1300                 {
1301                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1302                         return;
1303                 }
1304
1305                 default:
1306                 case CMD_REQUEST_USAGE:
1307                 {
1308                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1309                         print("  No arguments required.\n");
1310                         print("See also: ^2extendmatchtime^7\n");
1311                         return;
1312                 }
1313         }
1314 }
1315
1316 void GameCommand_setbots(float request, float argc)
1317 {
1318         switch(request)
1319         {
1320                 case CMD_REQUEST_COMMAND:
1321                 {
1322                         if(argc >= 2)
1323                         {
1324                                 cvar_settemp("minplayers", "0");
1325                                 cvar_settemp("bot_number", argv(1));
1326                                 bot_fixcount();
1327                                 return;
1328                         }
1329                 }
1330
1331                 default:
1332                         print("Incorrect parameters for ^2setbots^7\n");
1333                 case CMD_REQUEST_USAGE:
1334                 {
1335                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1336                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1337                         print("See also: ^2bot_cmd^7\n");
1338                         return;
1339                 }
1340         }
1341 }
1342
1343 void GameCommand_shuffleteams(float request)
1344 {
1345         switch(request)
1346         {
1347                 case CMD_REQUEST_COMMAND:
1348                 {
1349                         if(teamplay)
1350                         {
1351                                 entity tmp_player;
1352                                 float i, x, z, t_teams, t_players, team_color;
1353
1354                                 // count the total amount of players and total amount of teams
1355                                 t_players = 0;
1356                                 t_teams = 0;
1357                                 FOR_EACH_PLAYER(tmp_player)
1358                                 {
1359                                         CheckAllowedTeams(tmp_player);
1360
1361                                         if(c1 >= 0) t_teams = max(1, t_teams);
1362                                         if(c2 >= 0) t_teams = max(2, t_teams);
1363                                         if(c3 >= 0) t_teams = max(3, t_teams);
1364                                         if(c4 >= 0) t_teams = max(4, t_teams);
1365
1366                                         ++t_players;
1367                                 }
1368
1369                                 // build a list of the players in a random order
1370                                 FOR_EACH_PLAYER(tmp_player)
1371                                 {
1372                                         for(;;)
1373                                         {
1374                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1375
1376                                                 if(shuffleteams_players[i])
1377                                                 {
1378                                                         continue; // a player is already assigned to this slot
1379                                                 }
1380                                                 else
1381                                                 {
1382                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1383                                                         break;
1384                                                 }
1385                                         }
1386                                 }
1387
1388                                 // finally, from the list made earlier, re-join the players in different order.
1389                                 for(i = 1; i <= t_teams; ++i)
1390                                 {
1391                                         // find out how many players to assign to this team
1392                                         x = (t_players / t_teams);
1393                                         x = ((i == 1) ? ceil(x) : floor(x));
1394
1395                                         team_color = Team_NumberToTeam(i);
1396
1397                                         // sort through the random list of players made earlier
1398                                         for(z = 1; z <= maxclients; ++z)
1399                                         {
1400                                                 if not(shuffleteams_teams[i] >= x)
1401                                                 {
1402                                                         if not(shuffleteams_players[z])
1403                                                                 continue; // not a player, move on to next random slot
1404
1405                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1406                                                                 self = edict_num(shuffleteams_players[z]);
1407
1408                                                         if(self.team != team_color)
1409                                                                 MoveToTeam(self, team_color, 6);
1410
1411                                                         shuffleteams_players[z] = 0;
1412                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1413                                                 }
1414                                                 else
1415                                                 {
1416                                                         break; // move on to next team
1417                                                 }
1418                                         }
1419                                 }
1420
1421                                 bprint("Successfully shuffled the players around randomly.\n");
1422
1423                                 // clear the buffers now
1424                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1425                                         shuffleteams_players[i] = 0;
1426
1427                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1428                                         shuffleteams_teams[i] = 0;
1429                         }
1430                         else
1431                         {
1432                                 print("Can't shuffle teams when currently not playing a team game.\n");
1433                         }
1434
1435                         return;
1436                 }
1437
1438                 default:
1439                 case CMD_REQUEST_USAGE:
1440                 {
1441                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1442                         print("  No arguments required.\n");
1443                         print("See also: ^2moveplayer, allspec^7\n");
1444                         return;
1445                 }
1446         }
1447 }
1448
1449 void GameCommand_stuffto(float request, float argc)
1450 {
1451         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1452         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1453         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1454
1455         #ifdef STUFFTO_ENABLED
1456         #message "stuffto command enabled"
1457         switch(request)
1458         {
1459                 case CMD_REQUEST_COMMAND:
1460                 {
1461                         if(argv(2))
1462                         {
1463                                 entity client = GetIndexedEntity(argc, 1);
1464                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1465
1466                                 if(accepted > 0)
1467                                 {
1468                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1469                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1470                                 }
1471                                 else
1472                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1473
1474                                 return;
1475                         }
1476                 }
1477
1478                 default:
1479                         print("Incorrect parameters for ^2stuffto^7\n");
1480                 case CMD_REQUEST_USAGE:
1481                 {
1482                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1483                         print("  'client' is the entity number or name of the player,\n");
1484                         print("  and 'command' is the command to be sent to that player.\n");
1485                         return;
1486                 }
1487         }
1488         #else
1489         if(request)
1490         {
1491                 print("stuffto command is not enabled on this server.\n");
1492                 return;
1493         }
1494         #endif
1495 }
1496
1497 void GameCommand_trace(float request, float argc)
1498 {
1499         switch(request)
1500         {
1501                 case CMD_REQUEST_COMMAND:
1502                 {
1503                         entity e;
1504                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1505                         float i, f, safe, unsafe, dq, dqf;
1506
1507                         switch(argv(1))
1508                         {
1509                                 case "debug":
1510                                 {
1511                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1512                                         for(;;)
1513                                         {
1514                                                 org = world.mins;
1515                                                 delta = world.maxs - world.mins;
1516
1517                                                 start_x = org_x + random() * delta_x;
1518                                                 start_y = org_y + random() * delta_y;
1519                                                 start_z = org_z + random() * delta_z;
1520
1521                                                 end_x = org_x + random() * delta_x;
1522                                                 end_y = org_y + random() * delta_y;
1523                                                 end_z = org_z + random() * delta_z;
1524
1525                                                 start = stov(vtos(start));
1526                                                 end = stov(vtos(end));
1527
1528                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1529                                                 if(!trace_startsolid)
1530                                                 {
1531                                                         p = trace_endpos;
1532                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1533                                                         if(trace_startsolid || trace_fraction == 1)
1534                                                         {
1535                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1536                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1537
1538                                                                 if(trace_startsolid)
1539                                                                 {
1540                                                                         // how much do we need to back off?
1541                                                                         safe = 1;
1542                                                                         unsafe = 0;
1543                                                                         for(;;)
1544                                                                         {
1545                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1546                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1547                                                                                 if(trace_startsolid)
1548                                                                                 {
1549                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1550                                                                                                 break;
1551                                                                                         unsafe = (safe + unsafe) * 0.5;
1552                                                                                 }
1553                                                                                 else
1554                                                                                 {
1555                                                                                         if((safe + unsafe) * 0.5 == safe)
1556                                                                                                 break;
1557                                                                                         safe = (safe + unsafe) * 0.5;
1558                                                                                 }
1559                                                                         }
1560
1561                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1562                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1563
1564                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1565                                                                         if(trace_startsolid)
1566                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1567                                                                         else
1568                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1569                                                                         break;
1570                                                                 }
1571
1572                                                                 q0 = p;
1573                                                                 dq = 0;
1574                                                                 dqf = 1;
1575                                                                 for(;;)
1576                                                                 {
1577                                                                         q = p + normalize(end - p) * (dq + dqf);
1578                                                                         if(q == q0)
1579                                                                                 break;
1580                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1581                                                                         if(trace_startsolid)
1582                                                                                 error("THIS ONE cannot happen");
1583                                                                         if(trace_fraction > 0)
1584                                                                                 dq += dqf * trace_fraction;
1585                                                                         dqf *= 0.5;
1586                                                                         q0 = q;
1587                                                                 }
1588                                                                 if(dq > 0)
1589                                                                 {
1590                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1591                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1592                                                                         break;
1593                                                                 }
1594                                                         }
1595                                                 }
1596                                         }
1597                                         return;
1598                                 }
1599
1600                                 case "debug2":
1601                                 {
1602                                         e = nextent(world);
1603                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1604                                         vv = trace_endpos;
1605                                         if(trace_fraction == 1)
1606                                         {
1607                                                 print("not above ground, aborting\n");
1608                                                 return;
1609                                         }
1610                                         f = 0;
1611                                         for(i = 0; i < 100000; ++i)
1612                                         {
1613                                                 dv = randomvec();
1614                                                 if(dv_z > 0)
1615                                                         dv = -1 * dv;
1616                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1617                                                 if(trace_startsolid)
1618                                                         print("bug 1\n");
1619                                                 if(trace_fraction == 1)
1620                                                 if(dv_z < f)
1621                                                 {
1622                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1623                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1624                                                         f = dv_z;
1625                                                 }
1626                                         }
1627                                         print("highest possible dist: ", ftos(f), "\n");
1628                                         return;
1629                                 }
1630
1631                                 case "walk":
1632                                 {
1633                                         if(argc == 3)
1634                                         {
1635                                                 e = nextent(world);
1636                                                 if(tracewalk(e, stov(argv(1)), e.mins, e.maxs, stov(argv(2)), MOVE_NORMAL))
1637                                                         print("can walk\n");
1638                                                 else
1639                                                         print("cannot walk\n");
1640                                                 return;
1641                                         }
1642                                 }
1643
1644                                 case "showline":
1645                                 {
1646                                         if(argc == 3)
1647                                         {
1648                                                 vv = stov(argv(1));
1649                                                 dv = stov(argv(2));
1650                                                 traceline(vv, dv, MOVE_NORMAL, world);
1651                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1652                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1653                                                 return;
1654                                         }
1655                                 }
1656
1657                                 // no default case, just go straight to invalid
1658                         }
1659                 }
1660
1661                 default:
1662                         print("Incorrect parameters for ^2trace^7\n");
1663                 case CMD_REQUEST_USAGE:
1664                 {
1665                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1666                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1667                         print("See also: ^2bbox, gettaginfo^7\n");
1668                         return;
1669                 }
1670         }
1671 }
1672
1673 void GameCommand_unlockteams(float request)
1674 {
1675         switch(request)
1676         {
1677                 case CMD_REQUEST_COMMAND:
1678                 {
1679                         if(teamplay)
1680                         {
1681                                 lockteams = 0;
1682                                 bprint("^1The teams are now unlocked.\n");
1683                         }
1684                         else
1685                         {
1686                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1687                         }
1688                         return;
1689                 }
1690
1691                 default:
1692                 case CMD_REQUEST_USAGE:
1693                 {
1694                         print("\nUsage:^3 sv_cmd unlockteams\n");
1695                         print("  No arguments required.\n");
1696                         print("See also: ^2lockteams^7\n");
1697                         return;
1698                 }
1699         }
1700 }
1701
1702 void GameCommand_warp(float request, float argc)
1703 {
1704         switch (request)
1705         {
1706                 case CMD_REQUEST_COMMAND:
1707                 {
1708                         if(autocvar_g_campaign)
1709                         {
1710                                 if(argc >= 2)
1711                                 {
1712                                         CampaignLevelWarp(stof(argv(1)));
1713                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1714                                 }
1715                                 else
1716                                 {
1717                                         CampaignLevelWarp(-1);
1718                                         print("Successfully warped to next campaign level.\n");
1719                                 }
1720                         }
1721                         else
1722                                 print("Not in campaign, can't level warp\n");
1723                         return;
1724                 }
1725
1726                 default:
1727                 case CMD_REQUEST_USAGE:
1728                 {
1729                         print("\nUsage:^3 sv_cmd warp [level]\n");
1730                         print("  'level' is the level to change campaign mode to.\n");
1731                         print("  if 'level' is not provided it will change to the next level.\n");
1732                         return;
1733                 }
1734         }
1735 }
1736
1737 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1738 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1739 void GameCommand_(float request)
1740 {
1741         switch(request)
1742         {
1743                 case CMD_REQUEST_COMMAND:
1744                 {
1745
1746                         return;
1747                 }
1748
1749                 default:
1750                 case CMD_REQUEST_USAGE:
1751                 {
1752                         print("\nUsage:^3 sv_cmd \n");
1753                         print("  No arguments required.\n");
1754                         return;
1755                 }
1756         }
1757 }
1758 */
1759
1760
1761 // ==================================
1762 //  Macro system for server commands
1763 // ==================================
1764
1765 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1766 // Common commands have double indentation to separate them a bit.
1767 #define SERVER_COMMANDS(request,arguments,command) \
1768         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1769         SERVER_COMMAND("butcher", GameCommand_butcher(request), "Instantly removes all monsters on the map") \
1770         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1771         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1772         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1773         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1774         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1775         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1776         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1777         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1778         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1779         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1780         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1781         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1782         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1783         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1784         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1785         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1786         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1787         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1788         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1789         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1790         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1791         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1792         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1793         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1794         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1795         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1796         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1797         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1798         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1799         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1800         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1801         /* nothing */
1802
1803 void GameCommand_macro_help()
1804 {
1805         #define SERVER_COMMAND(name,function,description) \
1806                 { print("  ^2", name, "^7: ", description, "\n"); }
1807
1808         SERVER_COMMANDS(0, 0, "")
1809         #undef SERVER_COMMAND
1810
1811         return;
1812 }
1813
1814 float GameCommand_macro_command(float argc, string command)
1815 {
1816         #define SERVER_COMMAND(name,function,description) \
1817                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1818
1819         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1820         #undef SERVER_COMMAND
1821
1822         return FALSE;
1823 }
1824
1825 float GameCommand_macro_usage(float argc)
1826 {
1827         #define SERVER_COMMAND(name,function,description) \
1828                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1829
1830         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1831         #undef SERVER_COMMAND
1832
1833         return FALSE;
1834 }
1835
1836 void GameCommand_macro_write_aliases(float fh)
1837 {
1838         #define SERVER_COMMAND(name,function,description) \
1839                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1840
1841         SERVER_COMMANDS(0, 0, "")
1842         #undef SERVER_COMMAND
1843
1844         return;
1845 }
1846
1847
1848 // =========================================
1849 //  Main Function Called By Engine (sv_cmd)
1850 // =========================================
1851 // If this function exists, game code handles gamecommand instead of the engine code.
1852
1853 void GameCommand(string command)
1854 {
1855         float argc = tokenize_console(command);
1856
1857         // Guide for working with argc arguments by example:
1858         // argc:   1    - 2      - 3     - 4
1859         // argv:   0    - 1      - 2     - 3
1860         // cmd     vote - master - login - password
1861
1862         if(strtolower(argv(0)) == "help")
1863         {
1864                 if(argc == 1)
1865                 {
1866                         print("\nServer console commands:\n");
1867                         GameCommand_macro_help();
1868
1869                         print("\nBanning commands:\n");
1870                         BanCommand_macro_help();
1871
1872                         print("\nCommon networked commands:\n");
1873                         CommonCommand_macro_help(world);
1874
1875                         print("\nGeneric commands shared by all programs:\n");
1876                         GenericCommand_macro_help();
1877
1878                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1879                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1880
1881                         return;
1882                 }
1883                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1884                 {
1885                         return;
1886                 }
1887                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1888                 {
1889                         return;
1890                 }
1891                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1892                 {
1893                         return;
1894                 }
1895                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1896                 {
1897                         return;
1898                 }
1899         }
1900         else if(BanCommand(command))
1901         {
1902                 return; // handled by server/command/ipban.qc
1903         }
1904         else if(CommonCommand_macro_command(argc, world, command))
1905         {
1906                 return; // handled by server/command/common.qc
1907         }
1908         else if(GenericCommand(command))
1909         {
1910                 return; // handled by common/command/generic.qc
1911         }
1912         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1913         {
1914                 return; // handled by one of the above GameCommand_* functions
1915         }
1916
1917         // nothing above caught the command, must be invalid
1918         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1919
1920         return;
1921 }