qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if(accepted <= 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_mobbutcher(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 149                         if(g_invasion) { print("This command doesn't work during an invasion.\n"); return; }
 150
 151                         float removed_count = 0;
 152                         entity head;
 153
 154                         FOR_EACH_MONSTER(head)
 155                         {
 156                                 monster_remove(head);
 157                                 ++removed_count;
 158                         }
 159
 160                         FOR_EACH_PLAYER(head)
 161                                 head.monstercount = 0;
 162
 163                         monsters_total = 0; // reset stats?
 164                         monsters_killed = 0;
 165
 166                         totalspawned = 0;
 167
 168                         if(removed_count <= 0)
 169                                 print("No monsters to kill\n");
 170                         else
 171                                 printf("Killed %d monster%s\n", removed_count, ((removed_count == 1) ? "" : "s"));
 172
 173                         return; // never fall through to usage
 174                 }
 175
 176                 default:
 177                 case CMD_REQUEST_USAGE:
 178                 {
 179                         print("\nUsage:^3 sv_cmd mobbutcher\n");
 180                         print("  No arguments required.\n");
 181                         return;
 182                 }
 183         }
 184 }
 185
 186 void GameCommand_allready(float request)
 187 {
 188         switch(request)
 189         {
 190                 case CMD_REQUEST_COMMAND:
 191                 {
 192                         ReadyRestart();
 193                         return;
 194                 }
 195
 196                 default:
 197                 case CMD_REQUEST_USAGE:
 198                 {
 199                         print("\nUsage:^3 sv_cmd allready\n");
 200                         print("  No arguments required.\n");
 201                         return;
 202                 }
 203         }
 204 }
 205
 206 void GameCommand_allspec(float request, float argc)
 207 {
 208         switch(request)
 209         {
 210                 case CMD_REQUEST_COMMAND:
 211                 {
 212                         entity client;
 213                         string reason = argv(1);
 214                         float i = 0;
 215
 216                         FOR_EACH_REALPLAYER(client)
 217                         {
 218                                 self = client;
 219                                 PutObserverInServer();
 220                                 ++i;
 221                         }
 222                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 223                         else { print("No players found to spectate.\n"); }
 224                         return;
 225                 }
 226
 227                 default:
 228                 case CMD_REQUEST_USAGE:
 229                 {
 230                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 231                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 232                         print("See also: ^2moveplayer, shuffleteams^7\n");
 233                         return;
 234                 }
 235         }
 236 }
 237
 238 void GameCommand_anticheat(float request, float argc)
 239 {
 240         switch(request)
 241         {
 242                 case CMD_REQUEST_COMMAND:
 243                 {
 244                         entity client = GetIndexedEntity(argc, 1);
 245                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 246
 247                         if(accepted > 0)
 248                         {
 249                                 self = client;
 250                                 anticheat_report();
 251                                 return;
 252                         }
 253                         else
 254                         {
 255                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 256                         }
 257                 }
 258
 259                 default:
 260                         print("Incorrect parameters for ^2anticheat^7\n");
 261                 case CMD_REQUEST_USAGE:
 262                 {
 263                         print("\nUsage:^3 sv_cmd anticheat client\n");
 264                         print("  'client' is the entity number or name of the player.\n");
 265                         return;
 266                 }
 267         }
 268 }
 269
 270 void GameCommand_bbox(float request)
 271 {
 272         switch(request)
 273         {
 274                 case CMD_REQUEST_COMMAND:
 275                 {
 276                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 277                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 278                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 279                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 280                         print("Solid bounding box size:");
 281
 282                         tracebox('1 0 0' * world.absmin_x,
 283                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 284                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 285                                                         '1 0 0' * world.absmax_x,
 286                                         MOVE_WORLDONLY,
 287                                         world);
 288                         if(trace_startsolid)
 289                                 print(" ", ftos(world.absmin_x));
 290                         else
 291                                 print(" ", ftos(trace_endpos_x));
 292
 293                         tracebox('0 1 0' * world.absmin_y,
 294                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 295                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 296                                                         '0 1 0' * world.absmax_y,
 297                                         MOVE_WORLDONLY,
 298                                         world);
 299                         if(trace_startsolid)
 300                                 print(" ", ftos(world.absmin_y));
 301                         else
 302                                 print(" ", ftos(trace_endpos_y));
 303
 304                         tracebox('0 0 1' * world.absmin_z,
 305                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 306                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 307                                                         '0 0 1' * world.absmax_z,
 308                                         MOVE_WORLDONLY,
 309                                         world);
 310                         if(trace_startsolid)
 311                                 print(" ", ftos(world.absmin_z));
 312                         else
 313                                 print(" ", ftos(trace_endpos_z));
 314
 315                         tracebox('1 0 0' * world.absmax_x,
 316                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 317                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 318                                                         '1 0 0' * world.absmin_x,
 319                                         MOVE_WORLDONLY,
 320                                         world);
 321                         if(trace_startsolid)
 322                                 print(" ", ftos(world.absmax_x));
 323                         else
 324                                 print(" ", ftos(trace_endpos_x));
 325
 326                         tracebox('0 1 0' * world.absmax_y,
 327                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 328                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 329                                                         '0 1 0' * world.absmin_y,
 330                                         MOVE_WORLDONLY,
 331                                         world);
 332                         if(trace_startsolid)
 333                                 print(" ", ftos(world.absmax_y));
 334                         else
 335                                 print(" ", ftos(trace_endpos_y));
 336
 337                         tracebox('0 0 1' * world.absmax_z,
 338                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 339                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 340                                                         '0 0 1' * world.absmin_z,
 341                                         MOVE_WORLDONLY,
 342                                         world);
 343                         if(trace_startsolid)
 344                                 print(" ", ftos(world.absmax_z));
 345                         else
 346                                 print(" ", ftos(trace_endpos_z));
 347
 348                         print("\n");
 349                         return;
 350                 }
 351
 352                 default:
 353                 case CMD_REQUEST_USAGE:
 354                 {
 355                         print("\nUsage:^3 sv_cmd bbox\n");
 356                         print("  No arguments required.\n");
 357                         print("See also: ^2gettaginfo, trace^7\n");
 358                         return;
 359                 }
 360         }
 361 }
 362
 363 void GameCommand_bot_cmd(float request, float argc, string command)
 364 {
 365         switch(request)
 366         {
 367                 case CMD_REQUEST_COMMAND:
 368                 {
 369                         entity bot;
 370
 371                         if(argv(1) == "reset")
 372                         {
 373                                 bot_resetqueues();
 374                                 return;
 375                         }
 376                         else if(argv(1) == "setbots")
 377                         {
 378                                 cvar_settemp("bot_vs_human", "0");
 379                                 cvar_settemp("minplayers", "0");
 380                                 cvar_settemp("bot_number", "0");
 381                                 bot_fixcount();
 382                                 cvar_settemp("bot_number", argv(2));
 383                                 if(!bot_fixcount())
 384                                         print("Sorry, could not set requested bot count\n");
 385                                 return;
 386                         }
 387                         else if(argv(1) == "load" && argc == 3)
 388                         {
 389                                 float fh, i;
 390                                 string s;
 391                                 fh = fopen(argv(2), FILE_READ);
 392                                 if(fh < 0)
 393                                 {
 394                                         print("cannot open the file\n");
 395                                         return;
 396                                 }
 397
 398                                 i = 0;
 399                                 while((s = fgets(fh)))
 400                                 {
 401                                         argc = tokenize_console(s);
 402
 403                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 404                                         {
 405                                                 if(argv(2) == "reset")
 406                                                 {
 407                                                         bot_resetqueues();
 408                                                 }
 409                                                 else if(argv(2) == "setbots")
 410                                                 {
 411                                                         cvar_settemp("bot_vs_human", "0");
 412                                                         cvar_settemp("minplayers", "0");
 413                                                         cvar_settemp("bot_number", "0");
 414                                                         bot_fixcount();
 415                                                         cvar_settemp("bot_number", argv(3));
 416                                                         if(!bot_fixcount())
 417                                                                 print("Sorry, could not set requested bot count\n");
 418                                                 }
 419                                                 else
 420                                                 {
 421                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 422                                                         bot = find_bot_by_number(stof(argv(2)));
 423                                                         if(bot == world)
 424                                                                 bot = find_bot_by_name(argv(2));
 425                                                         if(bot)
 426                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 427                                                 }
 428                                         }
 429                                         else
 430                                                 localcmd(strcat(s, "\n"));
 431
 432                                         ++i;
 433                                 }
 434                                 print(ftos(i), " commands read\n");
 435                                 fclose(fh);
 436                                 return;
 437                         }
 438                         else if(argv(1) == "help")
 439                         {
 440                                 if(argv(2))
 441                                         bot_cmdhelp(argv(2));
 442                                 else
 443                                         bot_list_commands();
 444                                 return;
 445                         }
 446                         else if(argc >= 3) // this comes last
 447                         {
 448                                 bot = find_bot_by_number(stof(argv(1)));
 449                                 if(bot == world)
 450                                         bot = find_bot_by_name(argv(1));
 451                                 if(bot)
 452                                 {
 453                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 454                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 455                                         return;
 456                                 }
 457                                 else
 458                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 459                         }
 460                 }
 461
 462                 default:
 463                         print("Incorrect parameters for ^2bot_cmd^7\n");
 464                 case CMD_REQUEST_USAGE:
 465                 {
 466                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 467                         print("  'client' can be either the name or entity id of the bot\n");
 468                         print("  For full list of commands, see bot_cmd help [command].\n");
 469                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 470                         print("          sv_cmd bot_cmd client presskey jump\n");
 471                         return;
 472                 }
 473         }
 474 }
 475
 476 void GameCommand_cointoss(float request, float argc)
 477 {
 478         switch(request)
 479         {
 480                 case CMD_REQUEST_COMMAND:
 481                 {
 482                         entity client;
 483                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 484                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 485                         string choice = ((random() > 0.5) ? result1 : result2);
 486
 487                         FOR_EACH_CLIENT(client)
 488                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 489                         bprint(strcat("^3Throwing coin... Result: ", choice));
 490                         return;
 491                 }
 492
 493                 default:
 494                 case CMD_REQUEST_USAGE:
 495                 {
 496                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 497                         print("  Where 'result1' and 'result2' are user created options.\n");
 498                         return;
 499                 }
 500         }
 501 }
 502
 503 void GameCommand_database(float request, float argc)
 504 {
 505         switch(request)
 506         {
 507                 case CMD_REQUEST_COMMAND:
 508                 {
 509                         if(argc == 3)
 510                         {
 511                                 if(argv(1) == "save")
 512                                 {
 513                                         db_save(ServerProgsDB, argv(2));
 514                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 515                                         return;
 516                                 }
 517                                 else if(argv(1) == "dump")
 518                                 {
 519                                         db_dump(ServerProgsDB, argv(2));
 520                                         print("DB dumped.\n"); // wtf does this do?
 521                                         return;
 522                                 }
 523                                 else if(argv(1) == "load")
 524                                 {
 525                                         db_close(ServerProgsDB);
 526                                         ServerProgsDB = db_load(argv(2));
 527                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 528                                         return;
 529                                 }
 530                         }
 531                 }
 532
 533                 default:
 534                         print("Incorrect parameters for ^2database^7\n");
 535                 case CMD_REQUEST_USAGE:
 536                 {
 537                         print("\nUsage:^3 sv_cmd database action filename\n");
 538                         print("  Where 'action' is the command to complete,\n");
 539                         print("  and 'filename' is what it acts upon.\n");
 540                         print("  Full list of commands here: \"save, dump, load.\"\n");
 541                         return;
 542                 }
 543         }
 544 }
 545
 546 void GameCommand_defer_clear(float request, float argc)
 547 {
 548         switch(request)
 549         {
 550                 case CMD_REQUEST_COMMAND:
 551                 {
 552                         entity client;
 553                         float accepted;
 554
 555                         if(argc >= 2)
 556                         {
 557                                 client = GetIndexedEntity(argc, 1);
 558                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 559
 560                                 if(accepted > 0)
 561                                 {
 562                                         stuffcmd(client, "defer clear\n");
 563                                         print("defer clear stuffed to ", client.netname, "\n");
 564                                 }
 565                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 566
 567                                 return;
 568                         }
 569                 }
 570
 571                 default:
 572                         print("Incorrect parameters for ^2defer_clear^7\n");
 573                 case CMD_REQUEST_USAGE:
 574                 {
 575                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 576                         print("  'client' is the entity number or name of the player.\n");
 577                         print("See also: ^2defer_clear_all^7\n");
 578                         return;
 579                 }
 580         }
 581 }
 582
 583 void GameCommand_defer_clear_all(float request)
 584 {
 585         switch(request)
 586         {
 587                 case CMD_REQUEST_COMMAND:
 588                 {
 589                         entity client;
 590                         float i = 0;
 591                         float argc;
 592
 593                         FOR_EACH_CLIENT(client)
 594                         {
 595                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 596                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 597                                 ++i;
 598                         }
 599                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 600                         return;
 601                 }
 602
 603                 default:
 604                 case CMD_REQUEST_USAGE:
 605                 {
 606                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 607                         print("  No arguments required.\n");
 608                         print("See also: ^2defer_clear^7\n");
 609                         return;
 610                 }
 611         }
 612 }
 613
 614 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 615 {
 616         switch(request)
 617         {
 618                 case CMD_REQUEST_COMMAND:
 619                 {
 620                         if(argv(1))
 621                         {
 622                                 if(argv(2))
 623                                         race_deleteTime(argv(2), stof(argv(1)));
 624                                 else
 625                                         race_deleteTime(GetMapname(), stof(argv(1)));
 626                                 return;
 627                         }
 628                 }
 629
 630                 default:
 631                         print("Incorrect parameters for ^2delrec^7\n");
 632                 case CMD_REQUEST_USAGE:
 633                 {
 634                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 635                         print("  'ranking' is which ranking level to clear up to, \n");
 636                         print("  it will clear all records up to nth place.\n");
 637                         print("  if 'map' is not provided it will use current map.\n");
 638                         return;
 639                 }
 640         }
 641 }
 642
 643 void GameCommand_effectindexdump(float request)
 644 {
 645         switch(request)
 646         {
 647                 case CMD_REQUEST_COMMAND:
 648                 {
 649                         float fh, d;
 650                         string s;
 651
 652                         d = db_create();
 653                         print("begin of effects list\n");
 654                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 655                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 656                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 657                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 658                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 659                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 660                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 661                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 662                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 663                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 664                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 665                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 666                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 667                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 668                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 669                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 670                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 671                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 672                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 673                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 674                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 675                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 676                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 677                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 678                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 679                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 680                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 681                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 682                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 683                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 684                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 685                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 686                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 687                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 688                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 689                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 690
 691                         fh = fopen("effectinfo.txt", FILE_READ);
 692                         while((s = fgets(fh)))
 693                         {
 694                                 tokenize_console(s);
 695                                 if(argv(0) == "effect")
 696                                 {
 697                                         if(db_get(d, argv(1)) != "1")
 698                                         {
 699                                                 if(particleeffectnum(argv(1)) >= 0)
 700                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 701                                                 db_put(d, argv(1), "1");
 702                                         }
 703                                 }
 704                         }
 705                         print("end of effects list\n");
 706
 707                         db_close(d);
 708                         return;
 709                 }
 710
 711                 default:
 712                 case CMD_REQUEST_USAGE:
 713                 {
 714                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 715                         print("  No arguments required.\n");
 716                         return;
 717                 }
 718         }
 719 }
 720
 721 void GameCommand_extendmatchtime(float request)
 722 {
 723         switch(request)
 724         {
 725                 case CMD_REQUEST_COMMAND:
 726                 {
 727                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 728                         return;
 729                 }
 730
 731                 default:
 732                 case CMD_REQUEST_USAGE:
 733                 {
 734                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 735                         print("  No arguments required.\n");
 736                         print("See also: ^2reducematchtime^7\n");
 737                         return;
 738                 }
 739         }
 740 }
 741
 742 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 743 {
 744         switch(request)
 745         {
 746                 case CMD_REQUEST_COMMAND:
 747                 {
 748                         entity client;
 749
 750                         for(client = world; (client = find(client, classname, argv(1))); )
 751                                 print(etos(client), "\n");
 752
 753                         return;
 754                 }
 755
 756                 default:
 757                         print("Incorrect parameters for ^2find^7\n");
 758                 case CMD_REQUEST_USAGE:
 759                 {
 760                         print("\nUsage:^3 sv_cmd find classname\n");
 761                         print("  Where 'classname' is the classname to search for.\n");
 762                         return;
 763                 }
 764         }
 765 }
 766
 767 void GameCommand_gametype(float request, float argc)
 768 {
 769         switch(request)
 770         {
 771                 case CMD_REQUEST_COMMAND:
 772                 {
 773                         if(argv(1) != "")
 774                         {
 775                                 string s = argv(1);
 776                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 777
 778                                 if(t)
 779                                 {
 780                                         MapInfo_SwitchGameType(t);
 781                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 782                                         if(MapInfo_count > 0)
 783                                         {
 784                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 785                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 786                                                 lsmaps_reply = strzone(getlsmaps());
 787                                                 bprint("Game type successfully switched to ", s, "\n");
 788                                         }
 789                                         else
 790                                         {
 791                                                 bprint("Cannot use this game type: no map for it found\n");
 792                                                 MapInfo_SwitchGameType(tsave);
 793                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 794                                         }
 795                                 }
 796                                 else
 797                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 798
 799                                 return;
 800                         }
 801                 }
 802
 803                 default:
 804                         print("Incorrect parameters for ^2gametype^7\n");
 805                 case CMD_REQUEST_USAGE:
 806                 {
 807                         print("\nUsage:^3 sv_cmd gametype mode\n");
 808                         print("  Where 'mode' is the gametype mode to switch to.\n");
 809                         print("See also: ^2gotomap^7\n");
 810                         return;
 811                 }
 812         }
 813 }
 814
 815 void GameCommand_gettaginfo(float request, float argc)
 816 {
 817         switch(request)
 818         {
 819                 case CMD_REQUEST_COMMAND:
 820                 {
 821                         entity tmp_entity;
 822                         float i;
 823                         vector v;
 824
 825                         if(argc >= 4)
 826                         {
 827                                 tmp_entity = spawn();
 828                                 if(argv(1) == "w")
 829                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 830                                 else
 831                                 {
 832                                         precache_model(argv(1));
 833                                         setmodel(tmp_entity, argv(1));
 834                                 }
 835                                 tmp_entity.frame = stof(argv(2));
 836                                 if(substring(argv(3), 0, 1) == "#")
 837                                         i = stof(substring(argv(3), 1, -1));
 838                                 else
 839                                         i = gettagindex(tmp_entity, argv(3));
 840                                 if(i)
 841                                 {
 842                                         v = gettaginfo(tmp_entity, i);
 843                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 844                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 845                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 846                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 847                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 848                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 849                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 850                                         if(argc >= 6)
 851                                         {
 852                                                 v_y = -v_y;
 853                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 854                                         }
 855                                 }
 856                                 else
 857                                         print("bone not found\n");
 858
 859                                 remove(tmp_entity);
 860                                 return;
 861                         }
 862                 }
 863
 864                 default:
 865                         print("Incorrect parameters for ^2gettaginfo^7\n");
 866                 case CMD_REQUEST_USAGE:
 867                 {
 868                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 869                         print("See also: ^2bbox, trace^7\n");
 870                         return;
 871                 }
 872         }
 873 }
 874
 875 void GameCommand_animbench(float request, float argc)
 876 {
 877         switch(request)
 878         {
 879                 case CMD_REQUEST_COMMAND:
 880                 {
 881                         entity tmp_entity;
 882
 883                         if(argc >= 4)
 884                         {
 885                                 tmp_entity = spawn();
 886                                 if(argv(1) == "w")
 887                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 888                                 else
 889                                 {
 890                                         precache_model(argv(1));
 891                                         setmodel(tmp_entity, argv(1));
 892                                 }
 893                                 float f1 = stof(argv(2));
 894                                 float f2 = stof(argv(3));
 895                                 float t0;
 896                                 float t1 = 0;
 897                                 float t2 = 0;
 898                                 float n = 0;
 899
 900                                 while(t1 + t2 < 1)
 901                                 {
 902                                         tmp_entity.frame = f1;
 903                                         t0 = gettime(GETTIME_HIRES);
 904                                         getsurfacepoint(tmp_entity, 0, 0);
 905                                         t1 += gettime(GETTIME_HIRES) - t0;
 906                                         tmp_entity.frame = f2;
 907                                         t0 = gettime(GETTIME_HIRES);
 908                                         getsurfacepoint(tmp_entity, 0, 0);
 909                                         t2 += gettime(GETTIME_HIRES) - t0;
 910                                         n += 1;
 911                                 }
 912                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 913                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 914
 915                                 remove(tmp_entity);
 916                                 return;
 917                         }
 918                 }
 919
 920                 default:
 921                         print("Incorrect parameters for ^2gettaginfo^7\n");
 922                 case CMD_REQUEST_USAGE:
 923                 {
 924                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 925                         print("See also: ^2bbox, trace^7\n");
 926                         return;
 927                 }
 928         }
 929 }
 930
 931 void GameCommand_gotomap(float request, float argc)
 932 {
 933         switch(request)
 934         {
 935                 case CMD_REQUEST_COMMAND:
 936                 {
 937                         if(argv(1))
 938                         {
 939                                 print(GotoMap(argv(1)), "\n");
 940                                 return;
 941                         }
 942                 }
 943
 944                 default:
 945                         print("Incorrect parameters for ^2gotomap^7\n");
 946                 case CMD_REQUEST_USAGE:
 947                 {
 948                         print("\nUsage:^3 sv_cmd gotomap map\n");
 949                         print("  Where 'map' is the *.bsp file to change to.\n");
 950                         print("See also: ^2gametype^7\n");
 951                         return;
 952                 }
 953         }
 954 }
 955
 956 void GameCommand_lockteams(float request)
 957 {
 958         switch(request)
 959         {
 960                 case CMD_REQUEST_COMMAND:
 961                 {
 962                         if(teamplay)
 963                         {
 964                                 lockteams = 1;
 965                                 bprint("^1The teams are now locked.\n");
 966                         }
 967                         else
 968                         {
 969                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 970                         }
 971                         return;
 972                 }
 973
 974                 default:
 975                 case CMD_REQUEST_USAGE:
 976                 {
 977                         print("\nUsage:^3 sv_cmd lockteams\n");
 978                         print("  No arguments required.\n");
 979                         print("See also: ^2unlockteams^7\n");
 980                         return;
 981                 }
 982         }
 983 }
 984
 985 void GameCommand_make_mapinfo(float request)
 986 {
 987         switch(request)
 988         {
 989                 case CMD_REQUEST_COMMAND:
 990                 {
 991                         entity tmp_entity;
 992
 993                         tmp_entity = spawn();
 994                         tmp_entity.classname = "make_mapinfo";
 995                         tmp_entity.think = make_mapinfo_Think;
 996                         tmp_entity.nextthink = time;
 997                         MapInfo_Enumerate();
 998                         return;
 999                 }
1000
1001                 default:
1002                 case CMD_REQUEST_USAGE:
1003                 {
1004                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1005                         print("  No arguments required.\n");
1006                         print("See also: ^2radarmap^7\n");
1007                         return;
1008                 }
1009         }
1010 }
1011
1012 void GameCommand_moveplayer(float request, float argc)
1013 {
1014         switch(request)
1015         {
1016                 case CMD_REQUEST_COMMAND:
1017                 {
1018                         float accepted;
1019                         entity client;
1020
1021                         string targets = strreplace(",", " ", argv(1));
1022                         string original_targets = strreplace(" ", ", ", targets);
1023                         string destination = argv(2);
1024
1025                         string successful, t;
1026                         successful = string_null;
1027
1028                         // lets see if the target(s) even actually exist.
1029                         if((targets) && (destination))
1030                         {
1031                                 for(;targets;)
1032                                 {
1033                                         t = car(targets); targets = cdr(targets);
1034
1035                                         // Check to see if the player is a valid target
1036                                         client = GetFilteredEntity(t);
1037                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
1038
1039                                         if(accepted <= 0)
1040                                         {
1041                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1042                                                 continue;
1043                                         }
1044
1045                                         // Where are we putting this player?
1046                                         if(destination == "spec" || destination == "spectator")
1047                                         {
1048                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1049                                                 {
1050                                                         self = client;
1051                                                         PutObserverInServer();
1052
1053                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1054                                                 }
1055                                                 else
1056                                                 {
1057                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1058                                                 }
1059                                                 continue;
1060                                         }
1061                                         else
1062                                         {
1063                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1064                                                 {
1065                                                         if(teamplay)
1066                                                         {
1067                                                                 // set up
1068                                                                 float team_id;
1069                                                                 float save = client.team_forced;
1070                                                                 client.team_forced = 0;
1071
1072                                                                 // find the team to move the player to
1073                                                                 team_id = Team_ColorToTeam(destination);
1074                                                                 if(team_id == client.team) // already on the destination team
1075                                                                 {
1076                                                                         // keep the forcing undone
1077                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1078                                                                         continue;
1079                                                                 }
1080                                                                 else if(team_id == 0)  // auto team
1081                                                                 {
1082                                                                         CheckAllowedTeams(client);
1083                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1084                                                                 }
1085                                                                 else
1086                                                                 {
1087                                                                         CheckAllowedTeams(client);
1088                                                                 }
1089                                                                 client.team_forced = save;
1090
1091                                                                 // Check to see if the destination team is even available
1092                                                                 switch(team_id)
1093                                                                 {
1094                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1095                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1096                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1097                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1098
1099                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1100                                                                 }
1101
1102                                                                 // If so, lets continue and finally move the player
1103                                                                 client.team_forced = 0;
1104                                                                 MoveToTeam(client, team_id, 6);
1105                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1106                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1107                                                                 continue;
1108                                                         }
1109                                                         else
1110                                                         {
1111                                                                 print("Can't change teams when currently not playing a team game.\n");
1112                                                                 return;
1113                                                         }
1114                                                 }
1115                                                 else
1116                                                 {
1117                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1118                                                         return;
1119                                                 }
1120                                         }
1121                                 }
1122
1123                                 if(successful)
1124                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1125                                 else
1126                                         print("No players given (", original_targets, ") are able to move.\n");
1127
1128                                 return; // still correct parameters so return to avoid usage print
1129                         }
1130                 }
1131
1132                 default:
1133                         print("Incorrect parameters for ^2moveplayer^7\n");
1134                 case CMD_REQUEST_USAGE:
1135                 {
1136                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1137                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1138                         print("  'destination' is what to send the player to, be it team or spectating\n");
1139                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1140                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1141                         print("          sv_cmd moveplayer 2 spec \n");
1142                         print("See also: ^2allspec, shuffleteams^7\n");
1143                         return;
1144                 }
1145         }
1146 }
1147
1148 void GameCommand_nospectators(float request)
1149 {
1150         switch(request)
1151         {
1152                 case CMD_REQUEST_COMMAND:
1153                 {
1154                         blockSpectators = 1;
1155                         entity plr;
1156                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1157                         {
1158                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1159                                 {
1160                                         plr.spectatortime = time;
1161                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1162                                 }
1163                         }
1164                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1165                         return;
1166                 }
1167
1168                 default:
1169                 case CMD_REQUEST_USAGE:
1170                 {
1171                         print("\nUsage:^3 sv_cmd nospectators\n");
1172                         print("  No arguments required.\n");
1173                         return;
1174                 }
1175         }
1176 }
1177
1178 void GameCommand_playerdemo(float request, float argc)
1179 {
1180         switch(request)
1181         {
1182                 case CMD_REQUEST_COMMAND:
1183                 {
1184                         if(argv(2) && argv(3))
1185                         {
1186                                 entity client;
1187                                 float i, n, accepted;
1188
1189                                 switch(argv(1))
1190                                 {
1191                                         case "read":
1192                                         {
1193                                                 client = GetIndexedEntity(argc, 2);
1194                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1195
1196                                                 if(accepted <= 0)
1197                                                 {
1198                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1199                                                         return;
1200                                                 }
1201
1202                                                 self = client;
1203                                                 playerdemo_open_read(argv(next_token));
1204                                                 return;
1205                                         }
1206
1207                                         case "write":
1208                                         {
1209                                                 client = GetIndexedEntity(argc, 2);
1210                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1211
1212                                                 if(accepted <= 0)
1213                                                 {
1214                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1215                                                         return;
1216                                                 }
1217
1218                                                 self = client;
1219                                                 playerdemo_open_write(argv(next_token));
1220                                                 return;
1221                                         }
1222
1223                                         case "auto_read_and_write":
1224                                         {
1225                                                 n = GetFilteredNumber(argv(3));
1226                                                 cvar_set("bot_number", ftos(n));
1227
1228                                                 localcmd("wait; wait; wait\n");
1229                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1230
1231                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1232                                                 return;
1233                                         }
1234
1235                                         case "auto_read":
1236                                         {
1237                                                 n = GetFilteredNumber(argv(3));
1238                                                 cvar_set("bot_number", ftos(n));
1239
1240                                                 localcmd("wait; wait; wait\n");
1241                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1242                                                 return;
1243                                         }
1244                                 }
1245                         }
1246                 }
1247
1248                 default:
1249                         print("Incorrect parameters for ^2playerdemo^7\n");
1250                 case CMD_REQUEST_USAGE:
1251                 {
1252                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1253                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1254                         return;
1255                 }
1256         }
1257 }
1258
1259 void GameCommand_printstats(float request)
1260 {
1261         switch(request)
1262         {
1263                 case CMD_REQUEST_COMMAND:
1264                 {
1265                         DumpStats(FALSE);
1266                         print("stats dumped.\n");
1267                         return;
1268                 }
1269
1270                 default:
1271                 case CMD_REQUEST_USAGE:
1272                 {
1273                         print("\nUsage:^3 sv_cmd printstats\n");
1274                         print("  No arguments required.\n");
1275                         return;
1276                 }
1277         }
1278 }
1279
1280 void GameCommand_radarmap(float request, float argc)
1281 {
1282         switch(request)
1283         {
1284                 case CMD_REQUEST_COMMAND:
1285                 {
1286                         if(RadarMap_Make(argc))
1287                                 return;
1288                 }
1289
1290                 default:
1291                         print("Incorrect parameters for ^2radarmap^7\n");
1292                 case CMD_REQUEST_USAGE:
1293                 {
1294                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1295                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1296                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1297                         print("See also: ^2make_mapinfo^7\n");
1298                         return;
1299                 }
1300         }
1301 }
1302
1303 void GameCommand_reducematchtime(float request)
1304 {
1305         switch(request)
1306         {
1307                 case CMD_REQUEST_COMMAND:
1308                 {
1309                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1310                         return;
1311                 }
1312
1313                 default:
1314                 case CMD_REQUEST_USAGE:
1315                 {
1316                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1317                         print("  No arguments required.\n");
1318                         print("See also: ^2extendmatchtime^7\n");
1319                         return;
1320                 }
1321         }
1322 }
1323
1324 void GameCommand_setbots(float request, float argc)
1325 {
1326         switch(request)
1327         {
1328                 case CMD_REQUEST_COMMAND:
1329                 {
1330                         if(argc >= 2)
1331                         {
1332                                 cvar_settemp("minplayers", "0");
1333                                 cvar_settemp("bot_number", argv(1));
1334                                 bot_fixcount();
1335                                 return;
1336                         }
1337                 }
1338
1339                 default:
1340                         print("Incorrect parameters for ^2setbots^7\n");
1341                 case CMD_REQUEST_USAGE:
1342                 {
1343                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1344                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1345                         print("See also: ^2bot_cmd^7\n");
1346                         return;
1347                 }
1348         }
1349 }
1350
1351 void GameCommand_shuffleteams(float request)
1352 {
1353         switch(request)
1354         {
1355                 case CMD_REQUEST_COMMAND:
1356                 {
1357                         if(teamplay)
1358                         {
1359                                 entity tmp_player;
1360                                 float i, x, z, t_teams, t_players, team_color;
1361
1362                                 // count the total amount of players and total amount of teams
1363                                 t_players = 0;
1364                                 t_teams = 0;
1365                                 FOR_EACH_PLAYER(tmp_player)
1366                                 {
1367                                         CheckAllowedTeams(tmp_player);
1368
1369                                         if(c1 >= 0) t_teams = max(1, t_teams);
1370                                         if(c2 >= 0) t_teams = max(2, t_teams);
1371                                         if(c3 >= 0) t_teams = max(3, t_teams);
1372                                         if(c4 >= 0) t_teams = max(4, t_teams);
1373
1374                                         ++t_players;
1375                                 }
1376
1377                                 // build a list of the players in a random order
1378                                 FOR_EACH_PLAYER(tmp_player)
1379                                 {
1380                                         for(;;)
1381                                         {
1382                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1383
1384                                                 if(shuffleteams_players[i])
1385                                                 {
1386                                                         continue; // a player is already assigned to this slot
1387                                                 }
1388                                                 else
1389                                                 {
1390                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1391                                                         break;
1392                                                 }
1393                                         }
1394                                 }
1395
1396                                 // finally, from the list made earlier, re-join the players in different order.
1397                                 for(i = 1; i <= t_teams; ++i)
1398                                 {
1399                                         // find out how many players to assign to this team
1400                                         x = (t_players / t_teams);
1401                                         x = ((i == 1) ? ceil(x) : floor(x));
1402
1403                                         team_color = Team_NumberToTeam(i);
1404
1405                                         // sort through the random list of players made earlier
1406                                         for(z = 1; z <= maxclients; ++z)
1407                                         {
1408                                                 if (!(shuffleteams_teams[i] >= x))
1409                                                 {
1410                                                         if (!(shuffleteams_players[z]))
1411                                                                 continue; // not a player, move on to next random slot
1412
1413                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1414                                                                 self = edict_num(shuffleteams_players[z]);
1415
1416                                                         if(self.team != team_color)
1417                                                                 MoveToTeam(self, team_color, 6);
1418
1419                                                         shuffleteams_players[z] = 0;
1420                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1421                                                 }
1422                                                 else
1423                                                 {
1424                                                         break; // move on to next team
1425                                                 }
1426                                         }
1427                                 }
1428
1429                                 bprint("Successfully shuffled the players around randomly.\n");
1430
1431                                 // clear the buffers now
1432                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1433                                         shuffleteams_players[i] = 0;
1434
1435                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1436                                         shuffleteams_teams[i] = 0;
1437                         }
1438                         else
1439                         {
1440                                 print("Can't shuffle teams when currently not playing a team game.\n");
1441                         }
1442
1443                         return;
1444                 }
1445
1446                 default:
1447                 case CMD_REQUEST_USAGE:
1448                 {
1449                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1450                         print("  No arguments required.\n");
1451                         print("See also: ^2moveplayer, allspec^7\n");
1452                         return;
1453                 }
1454         }
1455 }
1456
1457 void GameCommand_stuffto(float request, float argc)
1458 {
1459         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1460         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1461         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1462
1463         #ifdef STUFFTO_ENABLED
1464         #message "stuffto command enabled"
1465         switch(request)
1466         {
1467                 case CMD_REQUEST_COMMAND:
1468                 {
1469                         if(argv(2))
1470                         {
1471                                 entity client = GetIndexedEntity(argc, 1);
1472                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1473
1474                                 if(accepted > 0)
1475                                 {
1476                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1477                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1478                                 }
1479                                 else
1480                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1481
1482                                 return;
1483                         }
1484                 }
1485
1486                 default:
1487                         print("Incorrect parameters for ^2stuffto^7\n");
1488                 case CMD_REQUEST_USAGE:
1489                 {
1490                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1491                         print("  'client' is the entity number or name of the player,\n");
1492                         print("  and 'command' is the command to be sent to that player.\n");
1493                         return;
1494                 }
1495         }
1496         #else
1497         if(request)
1498         {
1499                 print("stuffto command is not enabled on this server.\n");
1500                 return;
1501         }
1502         #endif
1503 }
1504
1505 void GameCommand_trace(float request, float argc)
1506 {
1507         switch(request)
1508         {
1509                 case CMD_REQUEST_COMMAND:
1510                 {
1511                         entity e;
1512                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1513                         float i, f, safe, unsafe, dq, dqf;
1514
1515                         switch(argv(1))
1516                         {
1517                                 case "debug":
1518                                 {
1519                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1520                                         for(;;)
1521                                         {
1522                                                 org = world.mins;
1523                                                 delta = world.maxs - world.mins;
1524
1525                                                 start_x = org_x + random() * delta_x;
1526                                                 start_y = org_y + random() * delta_y;
1527                                                 start_z = org_z + random() * delta_z;
1528
1529                                                 end_x = org_x + random() * delta_x;
1530                                                 end_y = org_y + random() * delta_y;
1531                                                 end_z = org_z + random() * delta_z;
1532
1533                                                 start = stov(vtos(start));
1534                                                 end = stov(vtos(end));
1535
1536                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1537                                                 if(!trace_startsolid)
1538                                                 {
1539                                                         p = trace_endpos;
1540                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1541                                                         if(trace_startsolid || trace_fraction == 1)
1542                                                         {
1543                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1544                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1545
1546                                                                 if(trace_startsolid)
1547                                                                 {
1548                                                                         // how much do we need to back off?
1549                                                                         safe = 1;
1550                                                                         unsafe = 0;
1551                                                                         for(;;)
1552                                                                         {
1553                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1554                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1555                                                                                 if(trace_startsolid)
1556                                                                                 {
1557                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1558                                                                                                 break;
1559                                                                                         unsafe = (safe + unsafe) * 0.5;
1560                                                                                 }
1561                                                                                 else
1562                                                                                 {
1563                                                                                         if((safe + unsafe) * 0.5 == safe)
1564                                                                                                 break;
1565                                                                                         safe = (safe + unsafe) * 0.5;
1566                                                                                 }
1567                                                                         }
1568
1569                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1570                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1571
1572                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1573                                                                         if(trace_startsolid)
1574                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1575                                                                         else
1576                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1577                                                                         break;
1578                                                                 }
1579
1580                                                                 q0 = p;
1581                                                                 dq = 0;
1582                                                                 dqf = 1;
1583                                                                 for(;;)
1584                                                                 {
1585                                                                         q = p + normalize(end - p) * (dq + dqf);
1586                                                                         if(q == q0)
1587                                                                                 break;
1588                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1589                                                                         if(trace_startsolid)
1590                                                                                 error("THIS ONE cannot happen");
1591                                                                         if(trace_fraction > 0)
1592                                                                                 dq += dqf * trace_fraction;
1593                                                                         dqf *= 0.5;
1594                                                                         q0 = q;
1595                                                                 }
1596                                                                 if(dq > 0)
1597                                                                 {
1598                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1599                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1600                                                                         break;
1601                                                                 }
1602                                                         }
1603                                                 }
1604                                         }
1605                                         return;
1606                                 }
1607
1608                                 case "debug2":
1609                                 {
1610                                         e = nextent(world);
1611                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1612                                         vv = trace_endpos;
1613                                         if(trace_fraction == 1)
1614                                         {
1615                                                 print("not above ground, aborting\n");
1616                                                 return;
1617                                         }
1618                                         f = 0;
1619                                         for(i = 0; i < 100000; ++i)
1620                                         {
1621                                                 dv = randomvec();
1622                                                 if(dv_z > 0)
1623                                                         dv = -1 * dv;
1624                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1625                                                 if(trace_startsolid)
1626                                                         print("bug 1\n");
1627                                                 if(trace_fraction == 1)
1628                                                 if(dv_z < f)
1629                                                 {
1630                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1631                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1632                                                         f = dv_z;
1633                                                 }
1634                                         }
1635                                         print("highest possible dist: ", ftos(f), "\n");
1636                                         return;
1637                                 }
1638
1639                                 case "walk":
1640                                 {
1641                                         if(argc == 4)
1642                                         {
1643                                                 e = nextent(world);
1644                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1645                                                         print("can walk\n");
1646                                                 else
1647                                                         print("cannot walk\n");
1648                                                 return;
1649                                         }
1650                                 }
1651
1652                                 case "showline":
1653                                 {
1654                                         if(argc == 4)
1655                                         {
1656                                                 vv = stov(argv(2));
1657                                                 dv = stov(argv(3));
1658                                                 traceline(vv, dv, MOVE_NORMAL, world);
1659                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1660                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1661                                                 return;
1662                                         }
1663                                 }
1664
1665                                 // no default case, just go straight to invalid
1666                         }
1667                 }
1668
1669                 default:
1670                         print("Incorrect parameters for ^2trace^7\n");
1671                 case CMD_REQUEST_USAGE:
1672                 {
1673                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1674                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1675                         print("See also: ^2bbox, gettaginfo^7\n");
1676                         return;
1677                 }
1678         }
1679 }
1680
1681 void GameCommand_unlockteams(float request)
1682 {
1683         switch(request)
1684         {
1685                 case CMD_REQUEST_COMMAND:
1686                 {
1687                         if(teamplay)
1688                         {
1689                                 lockteams = 0;
1690                                 bprint("^1The teams are now unlocked.\n");
1691                         }
1692                         else
1693                         {
1694                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1695                         }
1696                         return;
1697                 }
1698
1699                 default:
1700                 case CMD_REQUEST_USAGE:
1701                 {
1702                         print("\nUsage:^3 sv_cmd unlockteams\n");
1703                         print("  No arguments required.\n");
1704                         print("See also: ^2lockteams^7\n");
1705                         return;
1706                 }
1707         }
1708 }
1709
1710 void GameCommand_warp(float request, float argc)
1711 {
1712         switch (request)
1713         {
1714                 case CMD_REQUEST_COMMAND:
1715                 {
1716                         if(autocvar_g_campaign)
1717                         {
1718                                 if(argc >= 2)
1719                                 {
1720                                         CampaignLevelWarp(stof(argv(1)));
1721                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1722                                 }
1723                                 else
1724                                 {
1725                                         CampaignLevelWarp(-1);
1726                                         print("Successfully warped to next campaign level.\n");
1727                                 }
1728                         }
1729                         else
1730                                 print("Not in campaign, can't level warp\n");
1731                         return;
1732                 }
1733
1734                 default:
1735                 case CMD_REQUEST_USAGE:
1736                 {
1737                         print("\nUsage:^3 sv_cmd warp [level]\n");
1738                         print("  'level' is the level to change campaign mode to.\n");
1739                         print("  if 'level' is not provided it will change to the next level.\n");
1740                         return;
1741                 }
1742         }
1743 }
1744
1745 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1746 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1747 void GameCommand_(float request)
1748 {
1749         switch(request)
1750         {
1751                 case CMD_REQUEST_COMMAND:
1752                 {
1753
1754                         return;
1755                 }
1756
1757                 default:
1758                 case CMD_REQUEST_USAGE:
1759                 {
1760                         print("\nUsage:^3 sv_cmd \n");
1761                         print("  No arguments required.\n");
1762                         return;
1763                 }
1764         }
1765 }
1766 */
1767
1768
1769 // ==================================
1770 //  Macro system for server commands
1771 // ==================================
1772
1773 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1774 #define SERVER_COMMANDS(request,arguments,command) \
1775         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1776         SERVER_COMMAND("mobbutcher", GameCommand_mobbutcher(request), "Instantly removes all monsters on the map") \
1777         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1778         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1779         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1780         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1781         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1782         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1783         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1784         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1785         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1786         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1787         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1788         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1789         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1790         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1791         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1792         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1793         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1794         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1795         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1796         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1797         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1798         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1799         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1800         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1801         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1802         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1803         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1804         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1805         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1806         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1807         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1808         /* nothing */
1809
1810 void GameCommand_macro_help()
1811 {
1812         #define SERVER_COMMAND(name,function,description) \
1813                 { print("  ^2", name, "^7: ", description, "\n"); }
1814
1815         SERVER_COMMANDS(0, 0, "")
1816         #undef SERVER_COMMAND
1817
1818         return;
1819 }
1820
1821 float GameCommand_macro_command(float argc, string command)
1822 {
1823         #define SERVER_COMMAND(name,function,description) \
1824                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1825
1826         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1827         #undef SERVER_COMMAND
1828
1829         return FALSE;
1830 }
1831
1832 float GameCommand_macro_usage(float argc)
1833 {
1834         #define SERVER_COMMAND(name,function,description) \
1835                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1836
1837         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1838         #undef SERVER_COMMAND
1839
1840         return FALSE;
1841 }
1842
1843 void GameCommand_macro_write_aliases(float fh)
1844 {
1845         #define SERVER_COMMAND(name,function,description) \
1846                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1847
1848         SERVER_COMMANDS(0, 0, "")
1849         #undef SERVER_COMMAND
1850
1851         return;
1852 }
1853
1854
1855 // =========================================
1856 //  Main Function Called By Engine (sv_cmd)
1857 // =========================================
1858 // If this function exists, game code handles gamecommand instead of the engine code.
1859
1860 void GameCommand(string command)
1861 {
1862         float argc = tokenize_console(command);
1863
1864         // Guide for working with argc arguments by example:
1865         // argc:   1    - 2      - 3     - 4
1866         // argv:   0    - 1      - 2     - 3
1867         // cmd     vote - master - login - password
1868
1869         if(strtolower(argv(0)) == "help")
1870         {
1871                 if(argc == 1)
1872                 {
1873                         print("\nServer console commands:\n");
1874                         GameCommand_macro_help();
1875
1876                         print("\nBanning commands:\n");
1877                         BanCommand_macro_help();
1878
1879                         print("\nCommon networked commands:\n");
1880                         CommonCommand_macro_help(world);
1881
1882                         print("\nGeneric commands shared by all programs:\n");
1883                         GenericCommand_macro_help();
1884
1885                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1886                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1887
1888                         return;
1889                 }
1890                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1891                 {
1892                         return;
1893                 }
1894                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1895                 {
1896                         return;
1897                 }
1898                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1899                 {
1900                         return;
1901                 }
1902                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1903                 {
1904                         return;
1905                 }
1906         }
1907         else if(BanCommand(command))
1908         {
1909                 return; // handled by server/command/ipban.qc
1910         }
1911         else if(CommonCommand_macro_command(argc, world, command))
1912         {
1913                 return; // handled by server/command/common.qc
1914         }
1915         else if(GenericCommand(command))
1916         {
1917                 return; // handled by common/command/generic.qc
1918         }
1919         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1920         {
1921                 return; // handled by one of the above GameCommand_* functions
1922         }
1923
1924         // nothing above caught the command, must be invalid
1925         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1926
1927         return;
1928 }