Remove some more g_lms checks & add a use for mega health (disabled by default)
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_damage.qc
1 .float dmg;
2 .float dmg_edge;
3 .float dmg_force;
4 .float dmg_radius;
5
6 float Damage_DamageInfo_SendEntity(entity to, float sf)
7 {
8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
16         WriteShort(MSG_ENTITY, self.oldorigin_x);
17         WriteByte(MSG_ENTITY, self.species);
18         return TRUE;
19 }
20
21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
22 {
23         // TODO maybe call this from non-edgedamage too?
24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
25
26         entity e;
27
28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
29                 deathtype |= 0x8000;
30
31         e = spawn();
32         setorigin(e, org);
33         e.projectiledeathtype = deathtype;
34         e.dmg = coredamage;
35         e.dmg_edge = edgedamage;
36         e.dmg_radius = rad;
37         e.dmg_force = vlen(force);
38         e.velocity = force;
39         e.oldorigin_x = compressShortVector(e.velocity);
40         e.species = bloodtype;
41
42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
43 }
44
45 float checkrules_firstblood;
46
47 float yoda;
48 float damage_goodhits;
49 float damage_gooddamage;
50
51 .float dmg_team;
52 .float teamkill_complain;
53 .float teamkill_soundtime;
54 .entity teamkill_soundsource;
55 .entity pusher;
56 .float istypefrag;
57 .float taunt_soundtime;
58
59
60 float IsDifferentTeam(entity a, entity b)
61 {
62         if(teamplay)
63         {
64                 if(a.team == b.team)
65                         return 0;
66         }
67         else
68         {
69                 if(a == b)
70                         return 0;
71         }
72         return 1;
73 }
74
75 float IsFlying(entity a)
76 {
77         if(a.flags & FL_ONGROUND)
78                 return 0;
79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
80                 return 0;
81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
82         if(trace_fraction < 1)
83                 return 0;
84         return 1;
85 }
86
87 void UpdateFrags(entity player, float f)
88 {
89         PlayerTeamScore_AddScore(player, f);
90 }
91
92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
93 void W_SwitchWeapon_Force(entity e, float w);
94 entity GiveFrags_randomweapons;
95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
96 {
97         // TODO route through PlayerScores instead
98         if(gameover) return;
99
100         if(f < 0)
101         {
102                 if(targ == attacker)
103                 {
104                         // suicide
105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
106                 }
107                 else
108                 {
109                         // teamkill
110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
111                 }
112         }
113         else
114         {
115                 // regular frag
116                 PlayerScore_Add(attacker, SP_KILLS, 1);
117                 if(targ.playerid)
118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
119         }
120
121         PlayerScore_Add(targ, SP_DEATHS, 1);
122
123         if(g_arena || g_ca)
124                 if(autocvar_g_arena_roundbased)
125                         return;
126
127         if(targ != attacker) // not for suicides
128         if(g_weaponarena_random)
129         {
130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
131                 float culprit;
132                 culprit = DEATH_WEAPONOF(deathtype);
133                 if(!culprit)
134                         culprit = attacker.weapon;
135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
136                         culprit = attacker.weapon;
137
138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
139                 {
140                         // no exchange
141                 }
142                 else
143                 {
144                         if(!GiveFrags_randomweapons)
145                         {
146                                 GiveFrags_randomweapons = spawn();
147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
148                         }
149
150                         if(inWarmupStage)
151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
152                         else
153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
154
155                         // all others (including the culprit): remove
156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
158
159                         // among the remaining ones, choose one by random
160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
161
162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
163                         {
164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
165                                 WEPSET_ANDNOT_EW(attacker, culprit);
166                         }
167                 }
168
169                 // after a frag, choose another random weapon set
170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
172         }
173
174         // FIXME fix the mess this is (we have REAL points now!)
175         entity oldself;
176         oldself = self;
177         self = attacker;
178         frag_attacker = attacker;
179         frag_target = targ;
180         frag_score = f;
181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
182         {
183                 f = frag_score;
184                 self = oldself;
185         }
186         else
187         {
188                 self = oldself;
189         }
190
191         attacker.totalfrags += f;
192
193         if(f)
194                 UpdateFrags(attacker, f);
195 }
196
197 string AppendItemcodes(string s, entity player)
198 {
199         float w;
200         w = player.weapon;
201         //if(w == 0)
202         //      w = player.switchweapon;
203         if(w == 0)
204                 w = player.cnt; // previous weapon!
205         s = strcat(s, ftos(w));
206         if(time < player.strength_finished)
207                 s = strcat(s, "S");
208         if(time < player.invincible_finished)
209                 s = strcat(s, "I");
210         if(player.flagcarried != world)
211                 s = strcat(s, "F");
212         if(player.BUTTON_CHAT)
213                 s = strcat(s, "T");
214         if(player.kh_next)
215                 s = strcat(s, "K");
216         return s;
217 }
218
219 void LogDeath(string mode, float deathtype, entity killer, entity killed)
220 {
221         string s;
222         if(!autocvar_sv_eventlog)
223                 return;
224         s = strcat(":kill:", mode);
225         s = strcat(s, ":", ftos(killer.playerid));
226         s = strcat(s, ":", ftos(killed.playerid));
227         s = strcat(s, ":type=", Deathtype_Name(deathtype));
228         s = strcat(s, ":items=");
229         s = AppendItemcodes(s, killer);
230         if(killed != killer)
231         {
232                 s = strcat(s, ":victimitems=");
233                 s = AppendItemcodes(s, killed);
234         }
235         GameLogEcho(s);
236 }
237
238 void Obituary_SpecialDeath(
239         entity notif_target,
240         float murder,
241         float deathtype,
242         string s1, string s2, string s3,
243         float f1, float f2, float f3)
244 {
245         if(DEATH_ISSPECIAL(deathtype))
246         {
247                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
248                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
249
250                 if(murder)
251                 {
252                         if(deathent.death_msgmurder)
253                         {
254                                 Send_Notification_WOVA(
255                                         NOTIF_ONE,
256                                         notif_target,
257                                         MSG_MULTI,
258                                         deathent.death_msgmurder.nent_id,
259                                         s1, s2, s3, "",
260                                         f1, f2, f3, 0
261                                 );
262                                 Send_Notification_WOVA(
263                                         NOTIF_ALL_EXCEPT,
264                                         notif_target,
265                                         MSG_INFO,
266                                         deathent.death_msgmurder.nent_msginfo.nent_id,
267                                         s1, s2, s3, "",
268                                         f1, f2, f3, 0
269                                 );
270                         }
271                 }
272                 else
273                 {
274                         if(deathent.death_msgself)
275                         {
276                                 Send_Notification_WOVA(
277                                         NOTIF_ONE,
278                                         notif_target,
279                                         MSG_MULTI,
280                                         deathent.death_msgself.nent_id,
281                                         s1, s2, s3, "",
282                                         f1, f2, f3, 0
283                                 );
284                                 Send_Notification_WOVA(
285                                         NOTIF_ALL_EXCEPT,
286                                         notif_target,
287                                         MSG_INFO,
288                                         deathent.death_msgself.nent_msginfo.nent_id,
289                                         s1, s2, s3, "",
290                                         f1, f2, f3, 0
291                                 );
292                         }
293                 }
294         }
295         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
296 }
297
298 float w_deathtype;
299 float Obituary_WeaponDeath(
300         entity notif_target,
301         float murder,
302         float deathtype,
303         string s1, string s2, string s3,
304         float f1, float f2)
305 {
306         float death_weapon = DEATH_WEAPONOF(deathtype);
307         if(death_weapon)
308         {
309                 w_deathtype = deathtype;
310                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
311                 w_deathtype = FALSE;
312
313                 if(death_message)
314                 {
315                         Send_Notification_WOVA(
316                                 NOTIF_ONE,
317                                 notif_target,
318                                 MSG_MULTI,
319                                 death_message,
320                                 s1, s2, s3, "",
321                                 f1, f2, 0, 0
322                         );
323                         Send_Notification_WOVA(
324                                 NOTIF_ALL_EXCEPT,
325                                 notif_target,
326                                 MSG_INFO,
327                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
328                                 s1, s2, s3, "",
329                                 f1, f2, 0, 0
330                         );
331                 }
332                 else
333                 {
334                         dprint(sprintf(
335                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
336                                 deathtype,
337                                 death_weapon
338                         ));
339                 }
340
341                 return TRUE;
342         }
343         return FALSE;
344 }
345
346 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
347 {
348         // Sanity check
349         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
350
351         // Declarations
352         float notif_firstblood = FALSE;
353         float kill_count_to_attacker, kill_count_to_target;
354
355         // Set final information for the death
356         targ.death_origin = targ.origin;
357         if(targ != attacker) { targ.killer_origin = attacker.origin; }
358         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
359
360         #ifdef NOTIFICATIONS_DEBUG
361         Debug_Notification(
362                 sprintf(
363                         "Obituary(%s, %s, %s, %s = %d);\n",
364                         attacker.netname,
365                         inflictor.netname,
366                         targ.netname,
367                         Deathtype_Name(deathtype),
368                         deathtype
369                 )
370         );
371         #endif
372         
373         // =======
374         // SUICIDE
375         // =======
376         if(targ == attacker)
377         {
378                 if(DEATH_ISSPECIAL(deathtype))
379                 {
380                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
381                         {
382                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
383                         }
384                         else
385                         {
386                                 switch(deathtype)
387                                 {
388                                         case DEATH_MIRRORDAMAGE:
389                                         {
390                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
391                                                 break;
392                                         }
393                                         
394                                         default:
395                                         {
396                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
397                                                 break;
398                                         }
399                                 }
400                         }
401                 }
402                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
403                 {
404                         backtrace("SUICIDE: what the hell happened here?\n");
405                         return;
406                 }
407                 LogDeath("suicide", deathtype, targ, targ);
408                 GiveFrags(attacker, targ, -1, deathtype);
409         }
410
411         // ======
412         // MURDER
413         // ======
414         else if(IS_PLAYER(attacker))
415         {
416                 if(!IsDifferentTeam(attacker, targ))
417                 {
418                         LogDeath("tk", deathtype, attacker, targ);
419                         GiveFrags(attacker, targ, -1, deathtype);
420
421                         attacker.killcount = 0;
422                         
423                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
424                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
425                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
426
427                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
428                         // No need for specific death/weapon messages...
429                 }
430                 else
431                 {
432                         LogDeath("frag", deathtype, attacker, targ);
433                         GiveFrags(attacker, targ, 1, deathtype);
434
435                         attacker.taunt_soundtime = time + 1;
436                         attacker.killcount = attacker.killcount + 1;
437
438                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
439                                 case counta: \
440                                 { \
441                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
442                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
443                                         break; \
444                                 }
445                         switch(attacker.killcount)
446                         {
447                                 KILL_SPREE_LIST
448                                 default: break;
449                         }
450                         #undef SPREE_ITEM
451
452                         if(!checkrules_firstblood)
453                         {
454                                 checkrules_firstblood = TRUE;
455                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
456                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
457                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
458
459                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
460                                 kill_count_to_attacker = -1;
461                                 kill_count_to_target = -2;
462                         }
463                         else
464                         {
465                                 kill_count_to_attacker = attacker.killcount;
466                                 kill_count_to_target = 0;
467                         }
468
469                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
470                         if(targ.istypefrag)
471                         {
472                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
473                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
474                                 else
475                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
476
477                                 if(targ.FRAG_VERBOSE && verbose_allowed)
478                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
479                                 else
480                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
481                         }
482                         else
483                         {
484                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
485                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
486                                 else
487                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
488
489                                 if(targ.FRAG_VERBOSE && verbose_allowed)
490                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
491                                 else
492                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
493                         }
494
495                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
496                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
497                 }
498         }
499
500         // =============
501         // ACCIDENT/TRAP
502         // =============
503         else
504         {
505                 switch(deathtype)
506                 {
507                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
508                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
509                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
510                         /*case DEATH_HURTTRIGGER:
511                         {
512                                 s1 = targ.netname;
513                                 s2 = inflictor.message;
514                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
515                                 break;
516                         }*/
517
518                         case DEATH_CUSTOM:
519                         {
520                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
521                                         targ.netname,
522                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
523                                         deathlocation,
524                                         targ.killcount,
525                                         0,
526                                         0);
527                                 break;
528                         }
529                         
530                         default:
531                         {
532                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
533                                 break;
534                         }
535                 }
536
537                 LogDeath("accident", deathtype, targ, targ);
538                 GiveFrags(targ, targ, -1, deathtype);
539
540                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
541                 {
542                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
543                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
544                 }
545         }
546
547         // reset target kill count
548         if(targ.killcount) { targ.killcount = 0; }
549 }
550
551 // these are updated by each Damage call for use in button triggering and such
552 entity damage_targ;
553 entity damage_inflictor;
554 entity damage_attacker;
555
556 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
557 {
558         float mirrordamage;
559         float mirrorforce;
560         float complainteamdamage = 0; 
561         entity attacker_save;
562         mirrordamage = 0;
563         mirrorforce = 0;
564
565         if (gameover || targ.killcount == -666)
566                 return;
567
568         entity oldself;
569         oldself = self;
570         self = targ;
571         damage_targ = targ;
572         damage_inflictor = inflictor;
573         damage_attacker = attacker;
574                 attacker_save = attacker;
575
576         if(targ.classname == "player")
577                 if(targ.hook)
578                         if(targ.hook.aiment)
579                                 if(targ.hook.aiment == attacker)
580                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
581
582         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
583         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
584         {
585                 if(targ.classname == "player")
586                         if not(IsDifferentTeam(targ, attacker))
587                         {
588                                 self = oldself;
589                                 return;
590                         }
591         }
592
593         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
594         {
595                 // These are ALWAYS lethal
596                 // No damage modification here
597                 // Instead, prepare the victim for his death...
598                 targ.armorvalue = 0;
599                 targ.spawnshieldtime = 0;
600                 targ.health = 0.9; // this is < 1
601                 targ.flags -= targ.flags & FL_GODMODE;
602                 damage = 100000;
603         }
604         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
605         {
606                 // no processing
607         }
608         else
609         {
610                 /*
611                 skill based bot damage? gtfo. (tZork)
612                 if (targ.classname == "player")
613                 if (attacker.classname == "player")
614                 if (!targ.isbot)
615                 if (attacker.isbot)
616                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
617         */
618         
619                 // nullify damage if teamplay is on
620                 if(deathtype != DEATH_TELEFRAG)
621                 if(attacker.classname == "player")
622                 {
623                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
624                         {
625                                 damage = 0;
626                                 force = '0 0 0';
627                         }
628                         else if(!IsDifferentTeam(attacker, targ))
629                         {
630                                 if(autocvar_teamplay_mode == 1)
631                                         damage = 0;
632                                 else if(attacker != targ)
633                                 {
634                                         if(autocvar_teamplay_mode == 3)
635                                                 damage = 0;
636                                         else if(autocvar_teamplay_mode == 4)
637                                         {
638                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
639                                                 {
640                                                         attacker.dmg_team = attacker.dmg_team + damage;
641                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
642                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
643                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
644                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
645                                                         if(g_minstagib)
646                                                         {
647                                                                 if(autocvar_g_friendlyfire == 0)
648                                                                         damage = 0;
649                                                         }
650                                                         else if(g_ca)
651                                                                 damage = 0;
652                                                         else
653                                                                 damage = autocvar_g_friendlyfire * damage;
654                                                         // mirrordamage will be used LATER
655
656                                                         if(autocvar_g_mirrordamage_virtual)
657                                                         {
658                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
659                                                                 attacker.dmg_take += v_x;
660                                                                 attacker.dmg_save += v_y;
661                                                                 attacker.dmg_inflictor = inflictor;
662                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
663                                                                 mirrorforce = 0;
664                                                         }
665
666                                                         if(autocvar_g_friendlyfire_virtual)
667                                                         {
668                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
669                                                                 targ.dmg_take += v_x;
670                                                                 targ.dmg_save += v_y;
671                                                                 targ.dmg_inflictor = inflictor;
672                                                                 damage = 0;
673                                                                 if(!autocvar_g_friendlyfire_virtual_force)
674                                                                         force = '0 0 0';
675                                                         }
676                                                 }
677                                                 else
678                                                         damage = 0;
679                                         }
680                                 }
681                         }
682                 }
683
684                 if(targ.classname == "player")
685                 if (g_minstagib)
686                 {
687                         if ((deathtype == DEATH_FALL)  ||
688                                 (deathtype == DEATH_DROWN) ||
689                                 (deathtype == DEATH_SLIME) ||
690                                 (deathtype == DEATH_LAVA)  ||
691                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
692                         {
693                                 self = oldself;
694                                 return;
695                         }
696                         if(damage > 0)
697                             damage = 10000;
698                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
699                         {
700                                 targ.armorvalue -= 1;
701                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
702                                 damage = 0;
703                                 targ.hitsound += 1;
704                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
705                         }
706                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
707                         {
708                                 damage = 0;
709                                 mirrordamage = 0;
710                                 complainteamdamage = 0;
711                                 if (targ != attacker)
712                                 {
713                                         if ((targ.health >= 1) && (targ.classname == "player"))
714                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
715                                         force = '0 0 0';
716                                         // keep mirrorforce
717                                         attacker = targ;
718                                 }
719                         }
720                 }
721
722                 if not(DEATH_ISSPECIAL(deathtype))
723                 {
724                         damage *= g_weapondamagefactor;
725                         mirrordamage *= g_weapondamagefactor;
726                         complainteamdamage *= g_weapondamagefactor;
727                         force = force * g_weaponforcefactor;
728                         mirrorforce *= g_weaponforcefactor;
729                 }
730                 
731                 // should this be changed at all? If so, in what way?
732                 frag_attacker = attacker;
733                 frag_target = targ;
734                 frag_damage = damage;
735                 frag_force = force;
736         frag_deathtype = deathtype;
737                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
738                 damage = frag_damage;
739                 force = frag_force;
740                 
741                 // apply strength multiplier
742                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
743                 {
744                         if(targ == attacker)
745                         {
746                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
747                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
748                         }
749                         else
750                         {
751                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
752                                 force = force * autocvar_g_balance_powerup_strength_force;
753                         }
754                 }
755
756                 // apply invincibility multiplier
757                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
758                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
759
760                 if (targ == attacker)
761                 {
762                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
763                                 damage = 0;
764                         else
765                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
766                 }
767
768                 // count the damage
769                 if(attacker)
770                 if(!targ.deadflag)
771                 if(targ.takedamage == DAMAGE_AIM)
772                 if(targ != attacker)
773                 {
774                         entity victim;
775                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
776                                 victim = targ.owner;
777                         else
778                                 victim = targ;
779
780                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
781                         {
782                                 if(IsDifferentTeam(victim, attacker))
783                                 {
784                                         if(damage > 0)
785                                         {
786                                                 if(deathtype != DEATH_FIRE)
787                                                 {
788                                                         if(victim.BUTTON_CHAT)
789                                                                 attacker.typehitsound += 1;
790                                                         else
791                                                                 attacker.hitsound += 1;
792                                                 }
793
794                                                 damage_goodhits += 1;
795                                                 damage_gooddamage += damage;
796
797                                                 if not(DEATH_ISSPECIAL(deathtype))
798                                                 {
799                                                         if(targ.classname == "player") // don't do this for vehicles
800                                                         if(!g_minstagib)
801                                                         if(IsFlying(victim))
802                                                                 yoda = 1;
803
804                                                         if(g_minstagib)
805                                                         if(victim.items & IT_STRENGTH)
806                                                                 yoda = 1;
807                                                 }
808                                         }
809                                 }
810                                 else
811                                 {
812                                         if(deathtype != DEATH_FIRE)
813                                         {
814                                                 attacker.typehitsound += 1;
815                                         }
816                                         if(complainteamdamage > 0)
817                                                 if(time > attacker.teamkill_complain)
818                                                 {
819                                                         attacker.teamkill_complain = time + 5;
820                                                         attacker.teamkill_soundtime = time + 0.4;
821                                                         attacker.teamkill_soundsource = targ;
822                                                 }
823                                 }
824                         }
825                 }
826         }
827
828         // apply push
829         if (self.damageforcescale)
830         if (vlen(force))
831         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
832         {
833                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
834                 if(self.movetype == MOVETYPE_PHYSICS)
835                 {
836                         entity farcent;
837                         farcent = spawn();
838                         farcent.classname = "farce";
839                         farcent.enemy = self;
840                         farcent.movedir = farce * 10;
841                         if(self.mass)
842                                 farcent.movedir = farcent.movedir * self.mass;
843                         farcent.origin = hitloc;
844                         farcent.forcetype = FORCETYPE_FORCEATPOS;
845                         farcent.nextthink = time + 0.1;
846                         farcent.think = SUB_Remove;
847                 }
848                 else
849                         self.velocity = self.velocity + farce;
850                 self.flags &~= FL_ONGROUND;
851                 UpdateCSQCProjectile(self);
852         }
853         // apply damage
854         if (damage != 0 || (self.damageforcescale && vlen(force)))
855         if (self.event_damage)
856                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
857         self = oldself;
858
859         // apply mirror damage if any
860         if(mirrordamage > 0 || mirrorforce > 0)
861         {
862                 attacker = attacker_save;
863                 if(g_minstagib)
864                 if(mirrordamage > 0)
865                 {
866                         // just lose extra LIVES, don't kill the player for mirror damage
867                         if(attacker.armorvalue > 0)
868                         {
869                                 attacker.armorvalue = attacker.armorvalue - 1;
870                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
871                                 attacker.hitsound += 1;
872                         }
873                         mirrordamage = 0;
874                 }
875
876                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
877                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
878         }
879 }
880
881 float RadiusDamage_running;
882 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
883         // Returns total damage applies to creatures
884 {
885         entity  targ;
886         vector  blastorigin;
887         vector  force;
888         float   total_damage_to_creatures;
889         entity  next;
890         float   tfloordmg;
891         float   tfloorforce;
892
893         float stat_damagedone;
894
895         if(RadiusDamage_running)
896         {
897                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
898                 return 0;
899         }
900
901         RadiusDamage_running = 1;
902
903         tfloordmg = autocvar_g_throughfloor_damage;
904         tfloorforce = autocvar_g_throughfloor_force;
905
906         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
907         total_damage_to_creatures = 0;
908
909         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
910                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
911                 {
912                         force = inflictor.velocity;
913                         if(vlen(force) == 0)
914                                 force = '0 0 -1';
915                         else
916                                 force = normalize(force);
917                         if(forceintensity >= 0)
918                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
919                         else
920                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
921                 }
922
923         stat_damagedone = 0;
924
925         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
926         while (targ)
927         {
928                 next = targ.chain;
929                 if (targ != inflictor)
930                         if (ignore != targ) if(targ.takedamage)
931                         {
932                                 vector nearest;
933                                 vector diff;
934                                 float power;
935
936                                 // LordHavoc: measure distance to nearest point on target (not origin)
937                                 // (this guarentees 100% damage on a touch impact)
938                                 nearest = targ.WarpZone_findradius_nearest;
939                                 diff = targ.WarpZone_findradius_dist;
940                                 // round up a little on the damage to ensure full damage on impacts
941                                 // and turn the distance into a fraction of the radius
942                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
943                                 //bprint(" ");
944                                 //bprint(ftos(power));
945                                 //if (targ == attacker)
946                                 //      print(ftos(power), "\n");
947                                 if (power > 0)
948                                 {
949                                         float finaldmg;
950                                         if (power > 1)
951                                                 power = 1;
952                                         finaldmg = coredamage * power + edgedamage * (1 - power);
953                                         if (finaldmg > 0)
954                                         {
955                                                 float a;
956                                                 float c;
957                                                 vector hitloc;
958                                                 vector myblastorigin;
959                                                 vector center;
960
961                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
962
963                                                 // if it's a player, use the view origin as reference
964                                                 center = CENTER_OR_VIEWOFS(targ);
965
966                                                 force = normalize(center - myblastorigin);
967                                                 force = force * (finaldmg / coredamage) * forceintensity;
968                                                 hitloc = nearest;
969
970                                                 if(targ != directhitentity)
971                                                 {
972                                                         float hits;
973                                                         float total;
974                                                         float hitratio;
975                                                         float mininv_f, mininv_d;
976
977                                                         // test line of sight to multiple positions on box,
978                                                         // and do damage if any of them hit
979                                                         hits = 0;
980
981                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
982                                                         // so for a given max stddev:
983                                                         // n = (1 / (2 * max stddev of hitratio))^2
984
985                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
986                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
987
988                                                         if(autocvar_g_throughfloor_debug)
989                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
990
991                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
992
993                                                         if(autocvar_g_throughfloor_debug)
994                                                                 print(sprintf(" steps=%f", total));
995
996                                                         if (targ.classname == "player")
997                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
998                                                         else
999                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1000
1001                                                         if(autocvar_g_throughfloor_debug)
1002                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1003
1004                                                         for(c = 0; c < total; ++c)
1005                                                         {
1006                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1007                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1008                                                                 if (trace_fraction == 1 || trace_ent == targ)
1009                                                                 {
1010                                                                         ++hits;
1011                                                                         if (hits > 1)
1012                                                                                 hitloc = hitloc + nearest;
1013                                                                         else
1014                                                                                 hitloc = nearest;
1015                                                                 }
1016                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1017                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1018                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1019                                                         }
1020
1021                                                         nearest = hitloc * (1 / max(1, hits));
1022                                                         hitratio = (hits / total);
1023                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1024                                                         finaldmg = finaldmg * a;
1025                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1026                                                         force = force * a;
1027
1028                                                         if(autocvar_g_throughfloor_debug)
1029                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1030                                                 }
1031
1032                                                 // laser force adjustments :P
1033                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1034                                                 {
1035                                                         if (targ == attacker)
1036                                                         {
1037                                                                 vector vel;
1038
1039                                                                 float force_zscale;
1040                                                                 float force_velocitybiasramp;
1041                                                                 float force_velocitybias;
1042
1043                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1044                                                                 if(deathtype & HITTYPE_SECONDARY)
1045                                                                 {
1046                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1047                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1048                                                                 }
1049                                                                 else
1050                                                                 {
1051                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1052                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1053                                                                 }
1054
1055                                                                 vel = targ.velocity;
1056                                                                 vel_z = 0;
1057                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1058                                                                 force =
1059                                                                         vlen(force)
1060                                                                         *
1061                                                                         normalize(normalize(force) + vel);
1062
1063                                                                 force_z *= force_zscale;
1064                                                         }
1065                                                         else
1066                                                         {
1067                                                                 if(deathtype & HITTYPE_SECONDARY)
1068                                                                 {
1069                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1070                                                                 }
1071                                                                 else
1072                                                                 {
1073                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1074                                                                 }
1075                                                         }
1076                                                 }
1077
1078                                                 //if (targ == attacker)
1079                                                 //{
1080                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1081                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1082                                                 //      print(" (", ftos(a), ")\n");
1083                                                 //}
1084                                                 if(finaldmg || vlen(force))
1085                                                 {
1086                                                         if(targ.iscreature)
1087                                                         {
1088                                                                 total_damage_to_creatures += finaldmg;
1089
1090                                                                 if(accuracy_isgooddamage(attacker, targ))
1091                                                                         stat_damagedone += finaldmg;
1092                                                         }
1093
1094                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1095                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1096                                                         else
1097                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1098                                                 }
1099                                         }
1100                                 }
1101                         }
1102                 targ = next;
1103         }
1104
1105         RadiusDamage_running = 0;
1106
1107         if(!DEATH_ISSPECIAL(deathtype))
1108                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1109
1110         return total_damage_to_creatures;
1111 }
1112
1113 .float fire_damagepersec;
1114 .float fire_endtime;
1115 .float fire_deathtype;
1116 .entity fire_owner;
1117 .float fire_hitsound;
1118 .entity fire_burner;
1119
1120 void fireburner_think();
1121
1122 float Fire_IsBurning(entity e)
1123 {
1124         return (time < e.fire_endtime);
1125 }
1126
1127 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1128 {
1129         float dps;
1130         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1131
1132         if(e.classname == "player")
1133         {
1134                 if(e.deadflag)
1135                         return -1;
1136         }
1137         else
1138         {
1139                 if(!e.fire_burner)
1140                 {
1141                         // print("adding a fire burner to ", e.classname, "\n");
1142                         e.fire_burner = spawn();
1143                         e.fire_burner.classname = "fireburner";
1144                         e.fire_burner.think = fireburner_think;
1145                         e.fire_burner.nextthink = time;
1146                         e.fire_burner.owner = e;
1147                 }
1148         }
1149
1150         t = max(t, 0.1);
1151         dps = d / t;
1152         if(Fire_IsBurning(e))
1153         {
1154                 mintime = e.fire_endtime - time;
1155                 maxtime = max(mintime, t);
1156
1157                 mindps = e.fire_damagepersec;
1158                 maxdps = max(mindps, dps);
1159
1160                 if(maxtime > mintime || maxdps > mindps)
1161                 {
1162                         // Constraints:
1163                         
1164                         // damage we have right now
1165                         mindamage = mindps * mintime;
1166
1167                         // damage we want to get
1168                         maxdamage = mindamage + d;
1169
1170                         // but we can't exceed maxtime * maxdps!
1171                         totaldamage = min(maxdamage, maxtime * maxdps);
1172
1173                         // LEMMA:
1174                         // Look at:
1175                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1176                         // We see:
1177                         // totaldamage <= maxtime * maxdps
1178                         // ==> totaldamage / maxdps <= maxtime.
1179                         // We also see:
1180                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1181                         //                     >= min(mintime, maxtime)
1182                         // ==> totaldamage / maxdps >= mintime.
1183
1184                         /*
1185                         // how long do we damage then?
1186                         // at least as long as before
1187                         // but, never exceed maxdps
1188                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1189                         */
1190
1191                         // alternate:
1192                         // at most as long as maximum allowed
1193                         // but, never below mindps
1194                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1195
1196                         // assuming t > mintime, dps > mindps:
1197                         // we get d = t * dps = maxtime * maxdps
1198                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1199                         // totaldamage / maxdps = maxtime
1200                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1201                         // FROM THIS:
1202                         // a) totaltime = max(mintime, maxtime) = maxtime
1203                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1204
1205                         // assuming t <= mintime:
1206                         // we get maxtime = mintime
1207                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1208                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1209
1210                         // assuming dps <= mindps:
1211                         // we get mindps = maxdps.
1212                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1213                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1214                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1215
1216                         e.fire_damagepersec = totaldamage / totaltime;
1217                         e.fire_endtime = time + totaltime;
1218                         if(totaldamage > 1.2 * mindamage)
1219                         {
1220                                 e.fire_deathtype = dt;
1221                                 if(e.fire_owner != o)
1222                                 {
1223                                         e.fire_owner = o;
1224                                         e.fire_hitsound = FALSE;
1225                                 }
1226                         }
1227                         if(accuracy_isgooddamage(o, e))
1228                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1229                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1230                 }
1231                 else
1232                         return 0;
1233         }
1234         else
1235         {
1236                 e.fire_damagepersec = dps;
1237                 e.fire_endtime = time + t;
1238                 e.fire_deathtype = dt;
1239                 e.fire_owner = o;
1240                 e.fire_hitsound = FALSE;
1241                 if(accuracy_isgooddamage(o, e))
1242                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1243                 return d;
1244         }
1245 }
1246
1247 void Fire_ApplyDamage(entity e)
1248 {
1249         float t, d, hi, ty;
1250         entity o;
1251
1252         if not(Fire_IsBurning(e))
1253                 return;
1254
1255         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1256         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1257                 o = e.fire_owner;
1258
1259         // water and slime stop fire
1260         if(e.waterlevel)
1261         if(e.watertype != CONTENT_LAVA)
1262                 e.fire_endtime = 0;
1263
1264         // ice stops fire
1265         if(e.freezetag_frozen)
1266                 e.fire_endtime = 0;
1267
1268         t = min(frametime, e.fire_endtime - time);
1269         d = e.fire_damagepersec * t;
1270
1271         hi = e.fire_owner.hitsound;
1272         ty = e.fire_owner.typehitsound;
1273         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1274         if(e.fire_hitsound && e.fire_owner)
1275         {
1276                 e.fire_owner.hitsound = hi;
1277                 e.fire_owner.typehitsound = ty;
1278         }
1279         e.fire_hitsound = TRUE;
1280
1281         if not(IS_INDEPENDENT_PLAYER(e))
1282         FOR_EACH_PLAYER(other) if(e != other)
1283         {
1284                 if(other.classname == "player")
1285                 if(other.deadflag == DEAD_NO)
1286                 if not(IS_INDEPENDENT_PLAYER(other))
1287                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1288                 {
1289                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1290                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1291                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1292                 }
1293         }
1294 }
1295
1296 void Fire_ApplyEffect(entity e)
1297 {
1298         if(Fire_IsBurning(e))
1299                 e.effects |= EF_FLAME;
1300         else
1301                 e.effects &~= EF_FLAME;
1302 }
1303
1304 void fireburner_think()
1305 {
1306         // for players, this is done in the regular loop
1307         if(wasfreed(self.owner))
1308         {
1309                 remove(self);
1310                 return;
1311         }
1312         Fire_ApplyEffect(self.owner);
1313         if(!Fire_IsBurning(self.owner))
1314         {
1315                 self.owner.fire_burner = world;
1316                 remove(self);
1317                 return;
1318         }
1319         Fire_ApplyDamage(self.owner);
1320         self.nextthink = time;
1321 }