qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteByte(MSG_ENTITY, self.team); // player num
   7         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
  10         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  11         return TRUE;
  12 }
  13
  14 // TODO maybe convert this to a TE?
  15 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  16 {
  17         if(g_cts) // no gibs in CTS
  18                 return;
  19
  20         entity e;
  21
  22         e = spawn();
  23         e.classname = "gibsplash";
  24         e.cnt = amount;
  25         e.state = type; // should stay smaller than 15
  26         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  27                 e.state |= 0x40; // "silence" bit
  28         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  29
  30         // if this is a copied dead body, send the num of its player instead
  31         if(self.classname == "body")
  32                 e.team = num_for_edict(self.owner);
  33         else
  34                 e.team = num_for_edict(self);
  35
  36         setorigin(e, org);
  37         e.velocity = dir;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  42 }
  43
  44 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  45 {
  46         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  47 }
  48
  49 // damage effect
  50
  51 .float lifetime;
  52 .entity damageeffect_repeater;
  53
  54 float Violence_DamageEffect_SendEntity(entity to, float sf)
  55 {
  56         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
  57         WriteByte(MSG_ENTITY, self.cnt); // the damage weapon
  58         WriteByte(MSG_ENTITY, self.state); // species
  59         WriteByte(MSG_ENTITY, self.team); // player entnum
  60         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  61         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  62         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  63         return TRUE;
  64 }
  65
  66 void Violence_DamageEffect(entity pl, float type)
  67 {
  68         entity e;
  69
  70         e = spawn();
  71         e.classname = "damageeffect";
  72         e.cnt = type;
  73         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  74
  75         // if this is a copied dead body, send the num of its player instead
  76         if(pl.classname == "body")
  77                 e.team = num_for_edict(pl.owner);
  78         else
  79                 e.team = num_for_edict(pl);
  80
  81         setorigin(e, pl.origin);
  82
  83         Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
  84 }
  85
  86 void Violence_DamageEffect_Remove(entity pl);
  87 void Violence_DamageEffect_DoRepeat()
  88 {
  89         if(time > self.lifetime || (self.owner.classname != "player" && self.owner.classname != "body"))
  90         {
  91                 Violence_DamageEffect_Remove(self.owner);
  92                 return;
  93         }
  94
  95         Violence_DamageEffect(self.owner, self.cnt);
  96         self.nextthink = time + autocvar_sv_damageeffect_tick;
  97 }
  98
  99 void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type)
 100 {
 101         if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
 102                 return;
 103         if(sv_gentle || !type)
 104                 return; // return if gentle mode is enabled or the damage was not caused by a weapon
 105
 106         // if a repeater doesn't exist, spawn one, else update the existing one
 107         if(pl.damageeffect_repeater == world)
 108         {
 109                 pl.damageeffect_repeater = spawn();
 110                 pl.damageeffect_repeater.classname = "damageeffect_repeater";
 111                 pl.damageeffect_repeater.owner = pl;
 112                 pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;
 113
 114                 pl.damageeffect_repeater.lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
 115         }
 116         else
 117         {
 118                 // if the repeater is being updated, increase its lifetime instead of re-setting it entirely
 119                 // this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
 120                 pl.damageeffect_repeater.lifetime += (autocvar_sv_damageeffect_lifetime * damage);
 121         }
 122
 123         if(autocvar_sv_damageeffect_lifetime_max)
 124                 pl.damageeffect_repeater.lifetime = bound(0, pl.damageeffect_repeater.lifetime, time + autocvar_sv_damageeffect_lifetime_max);
 125
 126         pl.damageeffect_repeater.cnt = type;
 127         pl.damageeffect_repeater.nextthink = time;
 128 }
 129
 130 void Violence_DamageEffect_Remove(entity pl)
 131 {
 132         pl.damageeffect_repeater.nextthink = 0;
 133         remove(pl.damageeffect_repeater);
 134         pl.damageeffect_repeater = world;
 135 }
 136
 137 void Violence_DamageEffect_Copy(entity old_pl, entity pl)
 138 {
 139         if(pl.damageeffect_repeater != world)
 140                 Violence_DamageEffect_Remove(pl);
 141
 142         Violence_DamageEffect_SetRepeat(pl, 0, old_pl.damageeffect_repeater.cnt); // spawn a new repeater
 143         pl.damageeffect_repeater.lifetime = old_pl.damageeffect_repeater.lifetime; // copy the lifetime
 144 }