qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteByte(MSG_ENTITY, self.team); // player num
   7         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
  10         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  11         return TRUE;
  12 }
  13
  14 // TODO maybe convert this to a TE?
  15 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  16 {
  17         if(g_cts) // no gibs in CTS
  18                 return;
  19
  20         entity e;
  21
  22         e = spawn();
  23         e.classname = "gibsplash";
  24         e.cnt = amount;
  25         e.state = type; // should stay smaller than 15
  26         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  27                 e.state |= 0x40; // "silence" bit
  28         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  29
  30         // if this is a copied dead body, send the num of its player instead
  31         if(self.classname == "body")
  32                 e.team = num_for_edict(self.owner);
  33         else
  34                 e.team = num_for_edict(self);
  35
  36         setorigin(e, org);
  37         e.velocity = dir;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  42 }
  43
  44 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  45 {
  46         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  47 }
  48
  49 // damage effect
  50
  51 .float damageeffect_lifetime;
  52 .entity damageeffect_repeater;
  53
  54 float Violence_DamageEffect_SendEntity(entity to, float sf)
  55 {
  56         // if the client doesn't have the effect enabled, don't send to him and waste bandwidth
  57         if not(to.cvar_cl_damageeffect)
  58                 return FALSE;
  59         // if the client cannot see the damaged player, avoid sending and further save bandwidth
  60         if not(checkpvs(to.origin + to.view_ofs, self))
  61                 return FALSE;
  62
  63         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
  64         WriteByte(MSG_ENTITY, self.cnt); // damage weapon
  65         WriteByte(MSG_ENTITY, self.state); // player species
  66         WriteByte(MSG_ENTITY, self.team); // player entnum
  67         WriteByte(MSG_ENTITY, self.deadflag); // is dead body / gibbed
  68         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  69         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  70         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  71         return TRUE;
  72 }
  73
  74 void Violence_DamageEffect(entity pl, float type)
  75 {
  76         entity e;
  77
  78         e = spawn();
  79         e.classname = "damageeffect";
  80         e.cnt = type;
  81         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  82
  83         // if this is a copied dead body, send the num of its player instead
  84         if(pl.classname == "body")
  85                 e.team = num_for_edict(pl.owner);
  86         else
  87                 e.team = num_for_edict(pl);
  88
  89         // is this a whole dead body, or a gibbed body / player?
  90         if(!pl.modelindex) // gibbed
  91                 e.deadflag = 2;
  92         else if(pl.classname == "body")
  93                 e.deadflag = 1;
  94
  95         // if the player is dead, show the effect lower, else it appears floating above the body
  96         if(pl.health <= 0)
  97                 setorigin(e, pl.origin - '0 0 25');
  98         else
  99                 setorigin(e, pl.origin);
 100
 101         Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
 102 }
 103
 104 void Violence_DamageEffect_Remove(entity pl);
 105 void Violence_DamageEffect_DoRepeat()
 106 {
 107         if(time > self.damageeffect_lifetime || (self.owner.classname != "player" && self.owner.classname != "body"))
 108         {
 109                 Violence_DamageEffect_Remove(self.owner);
 110                 return;
 111         }
 112
 113         Violence_DamageEffect(self.owner, self.cnt);
 114         self.nextthink = time + autocvar_sv_damageeffect_tick;
 115 }
 116
 117 void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type)
 118 {
 119         if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
 120                 return;
 121         if(sv_gentle || !type)
 122                 return; // return if gentle mode is enabled or the damage was not caused by a weapon
 123
 124         // if a repeater doesn't exist, spawn one, else update the existing one
 125         if(pl.damageeffect_repeater == world)
 126         {
 127                 pl.damageeffect_repeater = spawn();
 128                 pl.damageeffect_repeater.classname = "damageeffect_repeater";
 129                 pl.damageeffect_repeater.owner = pl;
 130                 pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;
 131
 132                 pl.damageeffect_repeater.damageeffect_lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
 133         }
 134         else
 135         {
 136                 // if the repeater is being updated, increase its lifetime instead of re-setting it entirely
 137                 // this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
 138                 pl.damageeffect_repeater.damageeffect_lifetime += (autocvar_sv_damageeffect_lifetime * damage);
 139         }
 140
 141         if(autocvar_sv_damageeffect_lifetime_max)
 142                 pl.damageeffect_repeater.damageeffect_lifetime = bound(0, pl.damageeffect_repeater.damageeffect_lifetime, time + autocvar_sv_damageeffect_lifetime_max);
 143
 144         pl.damageeffect_repeater.cnt = type;
 145         pl.damageeffect_repeater.nextthink = time;
 146 }
 147
 148 void Violence_DamageEffect_Remove(entity pl)
 149 {
 150         pl.damageeffect_repeater.nextthink = 0;
 151         remove(pl.damageeffect_repeater);
 152         pl.damageeffect_repeater = world;
 153 }
 154
 155 void Violence_DamageEffect_Copy(entity old_pl, entity pl)
 156 {
 157         if(pl.damageeffect_repeater != world)
 158                 Violence_DamageEffect_Remove(pl);
 159
 160         Violence_DamageEffect_SetRepeat(pl, 0, old_pl.damageeffect_repeater.cnt); // spawn a new repeater
 161         pl.damageeffect_repeater.damageeffect_lifetime = old_pl.damageeffect_repeater.damageeffect_lifetime; // copy the lifetime
 162 }