qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteByte(MSG_ENTITY, self.team); // player num
   7         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
  10         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  11         return TRUE;
  12 }
  13
  14 // TODO maybe convert this to a TE?
  15 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  16 {
  17         if(g_cts) // no gibs in CTS
  18                 return;
  19
  20         entity e;
  21
  22         e = spawn();
  23         e.classname = "gibsplash";
  24         e.cnt = amount;
  25         e.state = type; // should stay smaller than 15
  26         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  27                 e.state |= 0x40; // "silence" bit
  28         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  29         e.team = num_for_edict(self);
  30         setorigin(e, org);
  31         e.velocity = dir;
  32
  33         e.oldorigin_x = compressShortVector(e.velocity);
  34
  35         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  36 }
  37
  38 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  39 {
  40         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  41 }
  42
  43 float Violence_DamageEffect_SendEntity(entity to, float sf)
  44 {
  45         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
  46         WriteByte(MSG_ENTITY, self.cnt); // the damage weapon
  47         WriteByte(MSG_ENTITY, self.state); // species
  48         WriteByte(MSG_ENTITY, self.team); // player entnum
  49         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  50         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  51         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  52         return TRUE;
  53 }
  54
  55 void Violence_DamageEffect(entity pl, float type)
  56 {
  57         entity e;
  58
  59         e = spawn();
  60         e.classname = "weapondamage";
  61         e.cnt = type;
  62         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  63         e.team = num_for_edict(pl);
  64         setorigin(e, pl.origin);
  65
  66         Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
  67 }
  68
  69 .entity damageeffect_repeater;
  70 .float lifetime;
  71
  72 void Violence_DamageEffect_DoRepeat()
  73 {
  74         if(time > self.lifetime)
  75         {
  76                 self.nextthink = 0;
  77                 remove(self.owner.damageeffect_repeater);
  78                 self.owner.damageeffect_repeater = world;
  79                 return;
  80         }
  81
  82         Violence_DamageEffect(self.owner, self.cnt);
  83         self.nextthink = time + autocvar_sv_damageeffect_tick;
  84 }
  85
  86 void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type)
  87 {
  88         if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
  89                 return;
  90         if(sv_gentle || !type)
  91                 return; // return if gentle mode is enabled or the damage was not caused by a weapon
  92
  93         // if a repeater doesn't exist, spawn one, else update the existing one
  94         if(pl.damageeffect_repeater == world)
  95         {
  96                 pl.damageeffect_repeater = spawn();
  97                 pl.damageeffect_repeater.classname = "damageeffect_repeater";
  98                 pl.damageeffect_repeater.owner = pl;
  99                 pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;
 100
 101                 pl.damageeffect_repeater.lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
 102         }
 103         else
 104         {
 105                 // if the repeater is being updated, increase its lifetime instead of re-setting it entirely
 106                 // this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
 107                 pl.damageeffect_repeater.lifetime += (autocvar_sv_damageeffect_lifetime * damage);
 108         }
 109
 110         pl.damageeffect_repeater.cnt = type;
 111         pl.damageeffect_repeater.nextthink = time;
 112 }