qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteByte(MSG_ENTITY, self.team); // player num
   7         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
  10         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  11         return TRUE;
  12 }
  13
  14 // TODO maybe convert this to a TE?
  15 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  16 {
  17         if(g_cts) // no gibs in CTS
  18                 return;
  19
  20         entity e;
  21
  22         e = spawn();
  23         e.classname = "gibsplash";
  24         e.cnt = amount;
  25         e.state = type; // should stay smaller than 15
  26         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  27                 e.state |= 0x40; // "silence" bit
  28         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  29         e.team = num_for_edict(self);
  30         setorigin(e, org);
  31         e.velocity = dir;
  32
  33         e.oldorigin_x = compressShortVector(e.velocity);
  34
  35         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  36 }
  37
  38 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  39 {
  40         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  41 }
  42
  43 // damage effect
  44
  45 .float lifetime;
  46 .entity damageeffect_repeater;
  47
  48 void Violence_DamageEffect_Remove(entity pl)
  49 {
  50         pl.damageeffect_repeater.nextthink = 0;
  51         remove(pl.damageeffect_repeater);
  52         pl.damageeffect_repeater = world;
  53 }
  54
  55 void Violence_DamageEffect_Copy(entity old_pl, entity pl)
  56 {
  57         if(pl.damageeffect_repeater != world)
  58                 Violence_DamageEffect_Remove(pl);
  59
  60         pl.damageeffect_repeater = spawn();
  61         copyentity(old_pl.damageeffect_repeater, pl.damageeffect_repeater);
  62         pl.damageeffect_repeater.owner = pl;
  63 }
  64
  65 float Violence_DamageEffect_SendEntity(entity to, float sf)
  66 {
  67         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
  68         WriteByte(MSG_ENTITY, self.cnt); // the damage weapon
  69         WriteByte(MSG_ENTITY, self.state); // species
  70         WriteByte(MSG_ENTITY, self.team); // player entnum
  71         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  72         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  73         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  74         return TRUE;
  75 }
  76
  77 void Violence_DamageEffect(entity pl, float type)
  78 {
  79         entity e;
  80
  81         e = spawn();
  82         e.classname = "weapondamage";
  83         e.cnt = type;
  84         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  85
  86         // if this is a dead body, send the num of its player
  87         if(pl.classname == "body")
  88                 e.team = num_for_edict(pl.owner);
  89         else
  90                 e.team = num_for_edict(pl);
  91
  92         setorigin(e, pl.origin);
  93
  94         Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
  95 }
  96
  97 void Violence_DamageEffect_DoRepeat()
  98 {
  99         if(time > self.lifetime || (self.owner.classname != "player" && self.owner.classname != "body"))
 100         {
 101                 Violence_DamageEffect_Remove(self.owner);
 102                 return;
 103         }
 104
 105         Violence_DamageEffect(self.owner, self.cnt);
 106         self.nextthink = time + autocvar_sv_damageeffect_tick;
 107 }
 108
 109 void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type)
 110 {
 111         if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
 112                 return;
 113         if(sv_gentle || !type)
 114                 return; // return if gentle mode is enabled or the damage was not caused by a weapon
 115
 116         // if a repeater doesn't exist, spawn one, else update the existing one
 117         if(pl.damageeffect_repeater == world)
 118         {
 119                 pl.damageeffect_repeater = spawn();
 120                 pl.damageeffect_repeater.classname = "damageeffect_repeater";
 121                 pl.damageeffect_repeater.owner = pl;
 122                 pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;
 123
 124                 pl.damageeffect_repeater.lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
 125         }
 126         else
 127         {
 128                 // if the repeater is being updated, increase its lifetime instead of re-setting it entirely
 129                 // this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
 130                 pl.damageeffect_repeater.lifetime += (autocvar_sv_damageeffect_lifetime * damage);
 131         }
 132
 133         pl.damageeffect_repeater.cnt = type;
 134         pl.damageeffect_repeater.nextthink = time;
 135 }