qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   7         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  10         return TRUE;
  11 }
  12
  13 // TODO maybe convert this to a TE?
  14 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  15 {
  16         if(g_cts) // no gibs in CTS
  17                 return;
  18
  19         entity e;
  20
  21         e = spawn();
  22         e.classname = "gibsplash";
  23         e.cnt = amount;
  24         e.state = type; // should stay smaller than 15
  25         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  26                 e.state |= 0x40; // "silence" bit
  27         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  28         setorigin(e, org);
  29         e.velocity = dir;
  30
  31         e.oldorigin_x = compressShortVector(e.velocity);
  32
  33         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  34 }
  35
  36 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  37 {
  38         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  39 }
  40
  41 float Violence_DamageEffect_SendEntity(entity to, float sf)
  42 {
  43         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
  44         WriteByte(MSG_ENTITY, self.cnt); // the damage weapon
  45         WriteByte(MSG_ENTITY, self.state); // species
  46         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  47         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  48         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  49         return TRUE;
  50 }
  51
  52 void Violence_DamageEffect(entity pl, float type)
  53 {
  54         entity e;
  55
  56         e = spawn();
  57         e.classname = "weapondamage";
  58         e.cnt = type;
  59         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  60         setorigin(e, pl.origin);
  61
  62         Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
  63 }
  64
  65 .entity damageeffect_repeater;
  66 .float lifetime;
  67
  68 void Violence_DamageEffect_DoRepeat()
  69 {
  70         if(time > self.lifetime)
  71         {
  72                 self.nextthink = 0;
  73                 remove(self.owner.damageeffect_repeater);
  74                 self.owner.damageeffect_repeater = world;
  75                 return;
  76         }
  77
  78         Violence_DamageEffect(self.owner, self.cnt);
  79         self.nextthink = time + autocvar_sv_damageeffect_tick;
  80 }
  81
  82 void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type)
  83 {
  84         if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
  85                 return;
  86         if(sv_gentle || !type)
  87                 return; // return if gentle mode is enabled or the damage was not caused by a weapon
  88
  89         // if a repeater doesn't exist, spawn one, else update the existing one
  90         if(pl.damageeffect_repeater == world)
  91         {
  92                 pl.damageeffect_repeater = spawn();
  93                 pl.damageeffect_repeater.classname = "damageeffect_repeater";
  94                 pl.damageeffect_repeater.owner = pl;
  95                 pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;
  96
  97                 pl.damageeffect_repeater.lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
  98         }
  99         else
 100         {
 101                 // if the repeater is being updated, increase its lifetime instead of re-setting it entirely
 102                 // this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
 103                 pl.damageeffect_repeater.lifetime += (autocvar_sv_damageeffect_lifetime * damage);
 104         }
 105
 106         pl.damageeffect_repeater.cnt = type;
 107         pl.damageeffect_repeater.nextthink = time;
 108 }