qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteByte(MSG_ENTITY, self.team); // player num
   7         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
  10         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  11         return TRUE;
  12 }
  13
  14 // TODO maybe convert this to a TE?
  15 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  16 {
  17         if(g_cts) // no gibs in CTS
  18                 return;
  19
  20         entity e;
  21
  22         e = spawn();
  23         e.classname = "gibsplash";
  24         e.cnt = amount;
  25         e.state = type; // should stay smaller than 15
  26         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  27                 e.state |= 0x40; // "silence" bit
  28         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  29
  30         // if this is a copied dead body, send the num of its player instead
  31         if(self.classname == "body")
  32                 e.team = num_for_edict(self.owner);
  33         else
  34                 e.team = num_for_edict(self);
  35
  36         setorigin(e, org);
  37         e.velocity = dir;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  42 }
  43
  44 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  45 {
  46         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  47 }
  48
  49 // damage effect
  50
  51 .float lifetime;
  52 .entity damageeffect_repeater;
  53
  54 void Violence_DamageEffect_Remove(entity pl)
  55 {
  56         pl.damageeffect_repeater.nextthink = 0;
  57         remove(pl.damageeffect_repeater);
  58         pl.damageeffect_repeater = world;
  59 }
  60
  61 void Violence_DamageEffect_Copy(entity old_pl, entity pl)
  62 {
  63         if(pl.damageeffect_repeater != world)
  64                 Violence_DamageEffect_Remove(pl);
  65
  66         pl.damageeffect_repeater = spawn();
  67         copyentity(old_pl.damageeffect_repeater, pl.damageeffect_repeater);
  68         pl.damageeffect_repeater.owner = pl;
  69 }
  70
  71 float Violence_DamageEffect_SendEntity(entity to, float sf)
  72 {
  73         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
  74         WriteByte(MSG_ENTITY, self.cnt); // the damage weapon
  75         WriteByte(MSG_ENTITY, self.state); // species
  76         WriteByte(MSG_ENTITY, self.team); // player entnum
  77         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  78         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  79         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  80         return TRUE;
  81 }
  82
  83 void Violence_DamageEffect(entity pl, float type)
  84 {
  85         entity e;
  86
  87         e = spawn();
  88         e.classname = "weapondamage";
  89         e.cnt = type;
  90         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  91
  92         e.team = num_for_edict(pl);
  93
  94         // if this is a copied dead body, send the num of its player instead
  95         if(pl.classname == "body")
  96                 e.team = num_for_edict(pl.owner);
  97         else
  98                 e.team = num_for_edict(pl);
  99
 100         setorigin(e, pl.origin);
 101
 102         Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
 103 }
 104
 105 void Violence_DamageEffect_DoRepeat()
 106 {
 107         if(time > self.lifetime || (self.owner.classname != "player" && self.owner.classname != "body"))
 108         {
 109                 Violence_DamageEffect_Remove(self.owner);
 110                 return;
 111         }
 112
 113         Violence_DamageEffect(self.owner, self.cnt);
 114         self.nextthink = time + autocvar_sv_damageeffect_tick;
 115 }
 116
 117 void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type)
 118 {
 119         if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
 120                 return;
 121         if(sv_gentle || !type)
 122                 return; // return if gentle mode is enabled or the damage was not caused by a weapon
 123
 124         // if a repeater doesn't exist, spawn one, else update the existing one
 125         if(pl.damageeffect_repeater == world)
 126         {
 127                 pl.damageeffect_repeater = spawn();
 128                 pl.damageeffect_repeater.classname = "damageeffect_repeater";
 129                 pl.damageeffect_repeater.owner = pl;
 130                 pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;
 131
 132                 pl.damageeffect_repeater.lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
 133         }
 134         else
 135         {
 136                 // if the repeater is being updated, increase its lifetime instead of re-setting it entirely
 137                 // this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
 138                 pl.damageeffect_repeater.lifetime += (autocvar_sv_damageeffect_lifetime * damage);
 139         }
 140
 141         pl.damageeffect_repeater.cnt = type;
 142         pl.damageeffect_repeater.nextthink = time;
 143 }