qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   7         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  10         return TRUE;
  11 }
  12
  13 // TODO maybe convert this to a TE?
  14 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  15 {
  16         if(g_cts) // no gibs in CTS
  17                 return;
  18
  19         entity e;
  20
  21         e = spawn();
  22         e.classname = "gibsplash";
  23         e.cnt = amount;
  24         e.state = type; // should stay smaller than 15
  25         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  26                 e.state |= 0x40; // "silence" bit
  27         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  28         setorigin(e, org);
  29         e.velocity = dir;
  30
  31         e.oldorigin_x = compressShortVector(e.velocity);
  32
  33         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  34 }
  35
  36 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  37 {
  38         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  39 }
  40
  41 float Violence_WeaponDamage_SendEntity(entity to, float sf)
  42 {
  43         WriteByte(MSG_ENTITY, ENT_CLIENT_WEAPONDAMAGE);
  44         WriteByte(MSG_ENTITY, self.cnt); // the damage weapon
  45         WriteByte(MSG_ENTITY, self.state); // species
  46         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  47         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  48         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  49         return TRUE;
  50 }
  51
  52 void Violence_WeaponDamage(entity pl, float type)
  53 {
  54         entity e;
  55
  56         e = spawn();
  57         e.classname = "weapondamage";
  58         e.cnt = type;
  59         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  60         setorigin(e, pl.origin);
  61
  62         Net_LinkEntity(e, FALSE, 0.2, Violence_WeaponDamage_SendEntity);
  63 }
  64
  65 .float lifetime;
  66
  67 void Violence_WeaponDamage_DoRepeat()
  68 {
  69         if(time > self.lifetime)
  70         {
  71                 self.nextthink = 0;
  72                 remove(self);
  73                 return;
  74         }
  75
  76         Violence_WeaponDamage(self.owner, self.cnt);
  77         self.nextthink = time + 0.5; // TO BE CVARED
  78 }
  79
  80 void Violence_WeaponDamage_SetRepeat(entity pl, float type)
  81 {
  82         entity repeater;
  83         repeater = spawn();
  84         repeater.classname = "weapondamage_repeater";
  85         repeater.owner = pl;
  86         repeater.origin = pl.origin;
  87         repeater.cnt = type;
  88         repeater.lifetime = time + 3; // TO BE CVARED
  89         repeater.think = Violence_WeaponDamage_DoRepeat;
  90         repeater.nextthink = time;
  91 }