qcsrc/server/item_key.qc

   1 /*
   2 TODO:
   3 - add an unlock sound (here to trigger_keylock and to func_door)
   4 - display available keys on the HUD
   5 - make more tests
   6 - think about adding NOT_EASY/NOT_NORMAL/NOT_HARD for Q1 compatibility
   7 - should keys have a trigger?
   8 */
   9
  10 bool item_keys_usekey(entity l, entity p) {
  11         float valid = l.itemkeys & p.itemkeys;
  12
  13         if (!valid) {
  14                 // other has none of the needed keys
  15                 return false;
  16         } else if (l.itemkeys == valid) {
  17                 // ALL needed keys were given
  18                 l.itemkeys = 0;
  19                 return true;
  20         } else {
  21                 // only some of the needed keys were given
  22                 l.itemkeys &= ~valid;
  23                 return true;
  24         }
  25 }
  26
  27 string item_keys_keylist(float keylist) {
  28         float base, l;
  29         string n;
  30
  31         // no keys
  32         if (!keylist)
  33                 return "";
  34
  35         // one key
  36         if ((keylist & (keylist-1)) != 0)
  37                 return strcat("the ", item_keys_names[lowestbit(keylist)]);
  38
  39         n = "";
  40         base = 0;
  41         while (keylist) {
  42                 l = lowestbit(keylist);
  43                 if (n)
  44                         n = strcat(n, ", the ", item_keys_names[base + l]);
  45                 else
  46                         n = strcat("the ", item_keys_names[base + l]);
  47
  48                 keylist = bitshift(keylist,  -(l + 1));
  49                 base+= l + 1;
  50         }
  51
  52         return n;
  53 }
  54
  55
  56 /*
  57 ================================
  58 item_key
  59 ================================
  60 */
  61
  62 /**
  63  * Key touch handler.
  64  */
  65 void item_key_touch(void) {
  66         if (!IS_PLAYER(other))
  67                 return;
  68
  69         // player already picked up this key
  70         if (other.itemkeys & self.itemkeys)
  71                 return;
  72
  73         other.itemkeys |= self.itemkeys;
  74         play2(other, self.noise);
  75
  76         centerprint(other, self.message);
  77 };
  78
  79 /**
  80  * Spawn a key with given model, key code and color.
  81  */
  82 void spawn_item_key() {
  83         precache_model(self.model);
  84
  85         if (self.spawnflags & 1) // FLOATING
  86                 self.noalign = 1;
  87
  88         if (self.noalign)
  89                 self.movetype = MOVETYPE_NONE;
  90         else
  91                 self.movetype = MOVETYPE_TOSS;
  92
  93         precache_sound(self.noise);
  94
  95         self.mdl = self.model;
  96         self.effects = EF_LOWPRECISION;
  97         setmodel(self, self.model);
  98         //setsize(self, '-16 -16 -24', '16 16 32');
  99         setorigin(self, self.origin + '0 0 32');
 100         setsize(self, '-16 -16 -56', '16 16 0');
 101         self.modelflags |= MF_ROTATE;
 102         self.solid = SOLID_TRIGGER;
 103
 104         if (!self.noalign)
 105         {
 106                 // first nudge it off the floor a little bit to avoid math errors
 107                 setorigin(self, self.origin + '0 0 1');
 108                 // note droptofloor returns false if stuck/or would fall too far
 109                 droptofloor();
 110         }
 111
 112         self.touch = item_key_touch;
 113 };
 114
 115
 116 /*QUAKED item_key (0 .5 .8) (-16 -16 -24) (16 16 32) FLOATING
 117 A key entity.
 118 The itemkeys should contain one of the following key IDs:
 119 1 - GOLD key -
 120 2 - SILVER key
 121 4 - BRONZE key
 122 8 - RED keycard
 123 16 - BLUE keycard
 124 32 - GREEN keycard
 125 Custom keys:
 126 ... - last key is 1<<23
 127 Keys with bigger Id than 32 don't have a default netname and model, if you use one of them, you MUST provide those.
 128 -----------KEYS------------
 129 colormod: color of the key (default: '.9 .9 .9').
 130 itemkeys: a key Id.
 131 message: message to print when player picks up this key.
 132 model: custom key model to use.
 133 netname: the display name of the key.
 134 noise: custom sound to play when player picks up the key.
 135 -------- SPAWNFLAGS --------
 136 FLOATING: the item will float in air, instead of aligning to the floor by falling
 137 ---------NOTES----------
 138 This is the only correct way to put keys on the map!
 139
 140 itemkeys MUST always have exactly one bit set.
 141 */
 142 void spawnfunc_item_key() {
 143         string _netname;
 144         vector _colormod;
 145
 146         // reject this entity if more than one key was set!
 147         if (self.itemkeys>0 && (self.itemkeys & (self.itemkeys-1)) != 0) {
 148                 objerror("item_key.itemkeys must contain only 1 bit set specifying the key it represents!");
 149                 remove(self);
 150                 return;
 151         }
 152
 153         // find default netname and colormod
 154         switch(self.itemkeys) {
 155         case 1:
 156                 _netname = "GOLD key";
 157                 _colormod = '1 .9 0';
 158                 break;
 159
 160         case 2:
 161                 _netname = "SILVER key";
 162                 _colormod = '.9 .9 .9';
 163                 break;
 164
 165         case 4:
 166                 _netname = "BRONZE key";
 167                 _colormod = '.6 .25 0';
 168                 break;
 169
 170         case 8:
 171                 _netname = "RED keycard";
 172                 _colormod = '.9 0 0';
 173                 break;
 174
 175         case 16:
 176                 _netname = "BLUE keycard";
 177                 _colormod = '0 0 .9';
 178                 break;
 179
 180         case 32:
 181                 _netname = "GREEN keycard";
 182                 _colormod = '0 .9 0';
 183                 break;
 184
 185         default:
 186                 _netname = "FLUFFY PINK keycard";
 187                 _colormod = '1 1 1';
 188
 189                 if (self.netname == "") {
 190                         objerror("item_key doesn't have a default name for this key and a custom one was not specified!");
 191                         remove(self);
 192                         return;
 193                 }
 194                 break;
 195
 196         }
 197
 198         // find default model
 199         string _model = string_null;
 200         if (self.itemkeys <= ITEM_KEY_BIT(2)) {
 201                 _model = "models/keys/key.md3";
 202         } else if (self.itemkeys >= ITEM_KEY_BIT(3) && self.itemkeys <= ITEM_KEY_BIT(5)) {
 203                 _model = "models/keys/key.md3"; // FIXME: replace it by a keycard model!
 204         } else if (self.model == "") {
 205                 objerror("item_key doesn't have a default model for this key and a custom one was not specified!");
 206                 remove(self);
 207                 return;
 208         }
 209
 210         // set defailt netname
 211         if (self.netname == "")
 212                 self.netname = _netname;
 213
 214         // set default colormod
 215         if (!self.colormod)
 216                 self.colormod = _colormod;
 217
 218         // set default model
 219         if (self.model == "")
 220                 self.model = _model;
 221
 222         // set default pickup message
 223         if (self.message == "")
 224                 self.message = strzone(strcat("You've picked up the ", self.netname, "!"));
 225
 226         if (self.noise == "")
 227                 self.noise = "misc/itempickup.wav";
 228
 229         // save the name for later
 230         item_keys_names[lowestbit(self.itemkeys)] = self.netname;
 231
 232         // put the key on the map
 233         spawn_item_key();
 234 }
 235
 236 /*QUAKED item_key1 (0 .5 .8) (-16 -16 -24) (16 16 32) FLOATING
 237 SILVER key.
 238 -----------KEYS------------
 239 colormod: color of the key (default: '.9 .9 .9').
 240 message: message to print when player picks up this key.
 241 model: custom model to use.
 242 noise: custom sound to play when player picks up the key.
 243 -------- SPAWNFLAGS --------
 244 FLOATING: the item will float in air, instead of aligning to the floor by falling
 245 ---------NOTES----------
 246 Don't use this entity on new maps! Use item_key instead.
 247 */
 248 void spawnfunc_item_key1(void) {
 249         self.classname = "item_key";
 250         self.itemkeys = ITEM_KEY_BIT(1);
 251         spawnfunc_item_key();
 252 };
 253
 254 /*QUAKED item_key2 (0 .5 .8) (-16 -16 -24) (16 16 32) FLOATING
 255 GOLD key.
 256 -----------KEYS------------
 257 colormod: color of the key (default: '1 .9 0').
 258 message: message to print when player picks up this key.
 259 model: custom model to use.
 260 noise: custom sound to play when player picks up the key.
 261 -------- SPAWNFLAGS --------
 262 FLOATING: the item will float in air, instead of aligning to the floor by falling
 263 ---------NOTES----------
 264 Don't use this entity on new maps! Use item_key instead.
 265 */
 266 void spawnfunc_item_key2(void) {
 267         self.classname = "item_key";
 268         self.itemkeys = ITEM_KEY_BIT(0);
 269         spawnfunc_item_key();
 270 };
 271
 272
 273 /*
 274 ================================
 275 trigger_keylock
 276 ================================
 277 */
 278
 279 /**
 280  * trigger givent targets
 281  */
 282 void trigger_keylock_trigger(string s) {
 283         entity stemp = self;
 284         entity otemp = other;
 285         entity atemp = activator;
 286
 287         entity t;
 288         for(t = world; (t = find(t, targetname, s)); )
 289                 if (t.use) {
 290                         self = t;
 291                         other = stemp;
 292                         activator = atemp;
 293                         self.use();
 294                 }
 295
 296         self = stemp;
 297         other = otemp;
 298         activator = atemp;
 299 };
 300
 301 /**
 302  * kill killtarget of trigger keylock.
 303  */
 304 void trigger_keylock_kill(string s) {
 305         entity t;
 306         for(t = world; (t = find(t, targetname, s)); )
 307                 remove(t);
 308 };
 309
 310 void trigger_keylock_touch(void) {
 311         bool key_used = false;
 312         bool started_delay = false;
 313
 314         // only player may trigger the lock
 315         if (!IS_PLAYER(other))
 316                 return;
 317
 318
 319         // check silver key
 320         if (self.itemkeys)
 321                 key_used = item_keys_usekey(self, other);
 322
 323         activator = other;
 324
 325         if (self.itemkeys) {
 326                 // at least one of the keys is missing
 327                 if (key_used) {
 328                         // one or more keys were given, but others are still missing!
 329                         play2(other, self.noise1);
 330                         Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_DOOR_LOCKED_ALSONEED, item_keys_keylist(self.itemkeys));
 331                         other.key_door_messagetime = time + 2;
 332                 } else if (other.key_door_messagetime <= time) {
 333                         // no keys were given
 334                         play2(other, self.noise2);
 335                         Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_DOOR_LOCKED_NEED, item_keys_keylist(self.itemkeys));
 336                         other.key_door_messagetime = time + 2;
 337                 }
 338
 339                 // trigger target2
 340                 if (self.delay <= time || started_delay == true)
 341                 if (self.target2) {
 342                         trigger_keylock_trigger(self.target2);
 343                         started_delay = true;
 344                         self.delay = time + self.wait;
 345                 }
 346         } else {
 347                 // all keys were given!
 348                 play2(other, self.noise);
 349                 centerprint(other, self.message);
 350
 351                 if (self.target)
 352                         trigger_keylock_trigger(self.target);
 353
 354                 if (self.killtarget)
 355                         trigger_keylock_kill(self.killtarget);
 356
 357                 remove(self);
 358         }
 359
 360 };
 361
 362 /*QUAKED trigger_keylock (.0 .5 .8) ?
 363 Keylock trigger.  Must target other entities.
 364 This trigger will trigger target entities when all required keys are provided.
 365 -------- KEYS --------
 366 itemkeys: A bit field with key IDs that are needed to open this lock.
 367 sounds: 1 to play misc/secret.wav, 2 to play misc/talk.wav, 3 to play misc/trigger1.wav (3 is default)
 368 target: trigger all entities with this targetname when triggered and all keys have been given to it, then remove this trigger
 369 target2: trigger all entities with this targetname when triggered without giving it all the required keys.
 370 killtarget: remove all entities with this targetname when triggered with all the needed keys.
 371 message: print this message to the player who activated the trigger when all needed keys have been given.
 372 message2: print this message to the player who activated the trigger when not all of the needed keys have been given.
 373 noise: sound to play when lock gets unlocked (default: see sounds)
 374 noise1: sound to play when only some of the needed key were used but not all (default: misc/decreasevalue.wav)
 375 noise2: sound to play when a key is missing (default: misc/talk.wav)
 376 wait: prevent triggering again for this amount of time (default: 5) - applies to target2, target3, target4.
 377 ---------NOTES----------
 378 If spawned without any key specified in itemkeys, this trigger will display an error and remove itself.
 379 message2 and noise2 will be resent to the player every 2 seconds while he is in the trigger zone.
 380 */
 381 void spawnfunc_trigger_keylock(void) {
 382         if (!self.itemkeys) {
 383                 remove(self);
 384                 return;
 385         }
 386
 387         // set unlocked message
 388         if (self.message == "")
 389                 self.message = "Unlocked!";
 390
 391         // set default unlock noise
 392         if (self.noise == "") {
 393                 if (self.sounds == 1)
 394                         self.noise = "misc/secret.wav";
 395                 else if (self.sounds == 2)
 396                         self.noise = "misc/talk.wav";
 397                 else //if (self.sounds == 3) {
 398                         self.noise = "misc/trigger1.wav";
 399         }
 400
 401         // set default use key sound
 402         if (self.noise1 == "")
 403                 self.noise1 = "misc/decreasevalue.wav";
 404
 405         // set closed sourd
 406         if (self.noise2 == "")
 407                 self.noise2 = "misc/talk.wav";
 408
 409         // delay between triggering message2 and trigger2
 410         if (!self.wait)
 411                 self.wait = 5;
 412
 413         // precache sounds
 414         precache_sound(self.noise);
 415         precache_sound(self.noise1);
 416         precache_sound(self.noise2);
 417
 418         EXACTTRIGGER_INIT;
 419
 420         self.touch = trigger_keylock_touch;
 421 };
 422
 423