qcsrc/server/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "g_world.qh"
   4 #include "command/cmd.qh"
   5 #include "command/getreplies.qh"
   6 #include "../common/constants.qh"
   7 #include "../common/mapinfo.qh"
   8 #include "../common/playerstats.qh"
   9 #include "../common/util.qh"
  10
  11
  12 // definitions
  13
  14 float mapvote_nextthink;
  15 float mapvote_keeptwotime;
  16 float mapvote_timeout;
  17 string mapvote_message;
  18 const float MAPVOTE_SCREENSHOT_DIRS_COUNT = 4;
  19 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
  20 float mapvote_screenshot_dirs_count;
  21
  22 float mapvote_count;
  23 float mapvote_count_real;
  24 string mapvote_maps[MAPVOTE_COUNT];
  25 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
  26 string mapvote_maps_pakfile[MAPVOTE_COUNT];
  27 float mapvote_maps_suggested[MAPVOTE_COUNT];
  28 string mapvote_suggestions[MAPVOTE_COUNT];
  29 float mapvote_suggestion_ptr;
  30 float mapvote_voters;
  31 float mapvote_selections[MAPVOTE_COUNT];
  32 float mapvote_maps_flags[MAPVOTE_COUNT];
  33 float mapvote_run;
  34 float mapvote_detail;
  35 float mapvote_abstain;
  36 .float mapvote;
  37
  38 entity mapvote_ent;
  39
  40 /**
  41  * Returns the gamtype ID from its name, if type_name isn't a real gametype it
  42  * checks for sv_vote_gametype_(type_name)_type
  43  */
  44 float GameTypeVote_Type_FromString(string type_name)
  45 {
  46         float type = MapInfo_Type_FromString(type_name);
  47         if ( type == 0 )
  48                 type = MapInfo_Type_FromString(cvar_string(
  49                         strcat("sv_vote_gametype_",type_name,"_type")));
  50         return type;
  51 }
  52
  53 int GameTypeVote_AvailabilityStatus(string type_name)
  54 {
  55         int flag = GTV_FORBIDDEN;
  56
  57         float type = MapInfo_Type_FromString(type_name);
  58         if ( type == 0 )
  59         {
  60                 type = MapInfo_Type_FromString(cvar_string(
  61                         strcat("sv_vote_gametype_",type_name,"_type")));
  62                 flag |= GTV_CUSTOM;
  63         }
  64
  65         if( type == 0 )
  66                 return flag;
  67
  68         if ( autocvar_nextmap != "" )
  69         {
  70                 if ( !MapInfo_Get_ByName(autocvar_nextmap, false, 0) )
  71                         return flag;
  72                 if (!(MapInfo_Map_supportedGametypes & type))
  73                         return flag;
  74         }
  75
  76         return flag | GTV_AVAILABLE;
  77 }
  78
  79 float GameTypeVote_GetMask()
  80 {
  81         float n, j, gametype_mask;
  82         n = tokenizebyseparator(autocvar_sv_vote_gametype_options, " ");
  83         n = min(MAPVOTE_COUNT, n);
  84         gametype_mask = 0;
  85         for(j = 0; j < n; ++j)
  86                 gametype_mask |= GameTypeVote_Type_FromString(argv(j));
  87         return gametype_mask;
  88 }
  89
  90 string GameTypeVote_MapInfo_FixName(string m)
  91 {
  92         if ( autocvar_sv_vote_gametype )
  93         {
  94                 MapInfo_Enumerate();
  95                 MapInfo_FilterGametype(GameTypeVote_GetMask(), 0, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  96         }
  97         return MapInfo_FixName(m);
  98 }
  99
 100 void MapVote_ClearAllVotes()
 101 {
 102         FOR_EACH_CLIENT(other)
 103                 other.mapvote = 0;
 104 }
 105
 106 void MapVote_UnzoneStrings()
 107 {
 108         float j;
 109         for(j = 0; j < mapvote_count; ++j)
 110         {
 111                 if ( mapvote_maps[j] )
 112                 {
 113                         strunzone(mapvote_maps[j]);
 114                         mapvote_maps[j] = string_null;
 115                 }
 116                 if ( mapvote_maps_pakfile[j] )
 117                 {
 118                         strunzone(mapvote_maps_pakfile[j]);
 119                         mapvote_maps_pakfile[j] = string_null;
 120                 }
 121         }
 122 }
 123
 124 string MapVote_Suggest(string m)
 125 {SELFPARAM();
 126         float i;
 127         if(m == "")
 128                 return "That's not how to use this command.";
 129         if(!autocvar_g_maplist_votable_suggestions)
 130                 return "Suggestions are not accepted on this server.";
 131         if(mapvote_initialized)
 132         if(!gametypevote)
 133                 return "Can't suggest - voting is already in progress!";
 134         m = GameTypeVote_MapInfo_FixName(m);
 135         if (!m)
 136                 return "The map you suggested is not available on this server.";
 137         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
 138                 if(Map_IsRecent(m))
 139                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
 140
 141         if (!autocvar_sv_vote_gametype)
 142         if(!MapInfo_CheckMap(m))
 143                 return "The map you suggested does not support the current game mode.";
 144         for(i = 0; i < mapvote_suggestion_ptr; ++i)
 145                 if(mapvote_suggestions[i] == m)
 146                         return "This map was already suggested.";
 147         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
 148         {
 149                 i = floor(random() * mapvote_suggestion_ptr);
 150         }
 151         else
 152         {
 153                 i = mapvote_suggestion_ptr;
 154                 mapvote_suggestion_ptr += 1;
 155         }
 156         if(mapvote_suggestions[i] != "")
 157                 strunzone(mapvote_suggestions[i]);
 158         mapvote_suggestions[i] = strzone(m);
 159         if(autocvar_sv_eventlog)
 160                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
 161         return strcat("Suggestion of ", m, " accepted.");
 162 }
 163
 164 void MapVote_AddVotable(string nextMap, float isSuggestion)
 165 {
 166         float j, i, o;
 167         string pakfile, mapfile;
 168
 169         if(nextMap == "")
 170                 return;
 171         for(j = 0; j < mapvote_count; ++j)
 172                 if(mapvote_maps[j] == nextMap)
 173                         return;
 174         // suggestions might be no longer valid/allowed after gametype switch!
 175         if(isSuggestion)
 176                 if(!MapInfo_CheckMap(nextMap))
 177                         return;
 178         mapvote_maps[mapvote_count] = strzone(nextMap);
 179         mapvote_maps_suggested[mapvote_count] = isSuggestion;
 180
 181         pakfile = string_null;
 182         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
 183         {
 184                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
 185                 pakfile = whichpack(strcat(mapfile, ".tga"));
 186                 if(pakfile == "")
 187                         pakfile = whichpack(strcat(mapfile, ".jpg"));
 188                 if(pakfile == "")
 189                         pakfile = whichpack(strcat(mapfile, ".png"));
 190                 if(pakfile != "")
 191                         break;
 192         }
 193         if(i >= mapvote_screenshot_dirs_count)
 194                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
 195         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
 196                 pakfile = substring(pakfile, o, -1);
 197
 198         mapvote_maps_screenshot_dir[mapvote_count] = i;
 199         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
 200         mapvote_maps_flags[mapvote_count] = GTV_AVAILABLE;
 201
 202         mapvote_count += 1;
 203 }
 204
 205 void MapVote_Init()
 206 {
 207         float i;
 208         float nmax, smax;
 209
 210         MapVote_ClearAllVotes();
 211         MapVote_UnzoneStrings();
 212
 213         mapvote_count = 0;
 214         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
 215         mapvote_abstain = autocvar_g_maplist_votable_abstain;
 216
 217         if(mapvote_abstain)
 218                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
 219         else
 220                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
 221         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
 222
 223         // we need this for AddVotable, as that cycles through the screenshot dirs
 224         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
 225         if(mapvote_screenshot_dirs_count == 0)
 226                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
 227         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
 228         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
 229                 mapvote_screenshot_dirs[i] = strzone(argv(i));
 230
 231         if(mapvote_suggestion_ptr)
 232                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
 233                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], true);
 234
 235         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
 236                 MapVote_AddVotable(GetNextMap(), false);
 237
 238         if(mapvote_count == 0)
 239         {
 240                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 241                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_CurrentGametype(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
 242                 if(autocvar_g_maplist_shuffle)
 243                         ShuffleMaplist();
 244                 localcmd("\nmenu_cmd sync\n");
 245                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
 246                         MapVote_AddVotable(GetNextMap(), false);
 247         }
 248
 249         mapvote_count_real = mapvote_count;
 250         if(mapvote_abstain)
 251                 MapVote_AddVotable("don't care", 0);
 252
 253         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
 254
 255         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
 256         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
 257         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
 258                 mapvote_keeptwotime = 0;
 259         mapvote_message = "Choose a map and press its key!";
 260
 261         MapVote_Spawn();
 262 }
 263
 264 void MapVote_SendPicture(float id)
 265 {SELFPARAM();
 266         msg_entity = self;
 267         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 268         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
 269         WriteByte(MSG_ONE, id);
 270         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
 271 }
 272
 273
 274 void MapVote_WriteMask()
 275 {
 276         float i;
 277         if ( mapvote_count < 24 )
 278         {
 279                 float mask,power;
 280                 mask = 0;
 281                 for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
 282                         if(mapvote_maps_flags[i] & GTV_AVAILABLE )
 283                                 mask |= power;
 284
 285                 if(mapvote_count < 8)
 286                         WriteByte(MSG_ENTITY, mask);
 287                 else if (mapvote_count < 16)
 288                         WriteShort(MSG_ENTITY,mask);
 289                 else
 290                         WriteLong(MSG_ENTITY, mask);
 291         }
 292         else
 293         {
 294                 for ( i = 0; i < mapvote_count; ++i )
 295                         WriteByte(MSG_ENTITY, mapvote_maps_flags[i]);
 296         }
 297 }
 298
 299 /*
 300  * Sends a single map vote option to the client
 301  */
 302 void MapVote_SendOption(int i)
 303 {
 304         // abstain
 305         if(mapvote_abstain && i == mapvote_count - 1)
 306         {
 307                 WriteString(MSG_ENTITY, ""); // abstain needs no text
 308                 WriteString(MSG_ENTITY, ""); // abstain needs no pack
 309                 WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
 310         }
 311         else
 312         {
 313                 WriteString(MSG_ENTITY, mapvote_maps[i]);
 314                 WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
 315                 WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
 316         }
 317 }
 318
 319 /*
 320  * Sends a single gametype vote option to the client
 321  */
 322 void GameTypeVote_SendOption(int i)
 323 {
 324         // abstain
 325         if(mapvote_abstain && i == mapvote_count - 1)
 326         {
 327                 WriteString(MSG_ENTITY, ""); // abstain needs no text
 328                 WriteByte(MSG_ENTITY, GTV_AVAILABLE);
 329         }
 330         else
 331         {
 332                 string type_name = mapvote_maps[i];
 333                 WriteString(MSG_ENTITY, type_name);
 334                 WriteByte(MSG_ENTITY, mapvote_maps_flags[i]);
 335                 if ( mapvote_maps_flags[i] & GTV_CUSTOM )
 336                 {
 337                         WriteString(MSG_ENTITY, cvar_string(
 338                                 strcat("sv_vote_gametype_",type_name,"_name")));
 339                         WriteString(MSG_ENTITY, cvar_string(
 340                                 strcat("sv_vote_gametype_",type_name,"_description")));
 341                 }
 342         }
 343 }
 344
 345 bool MapVote_SendEntity(entity this, entity to, int sf)
 346 {
 347         float i;
 348
 349         if(sf & 1)
 350                 sf &= ~2; // if we send 1, we don't need to also send 2
 351
 352         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
 353         WriteByte(MSG_ENTITY, sf);
 354
 355         if(sf & 1)
 356         {
 357                 // flag 1 == initialization
 358                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
 359                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
 360                 WriteString(MSG_ENTITY, "");
 361                 WriteByte(MSG_ENTITY, mapvote_count);
 362                 WriteByte(MSG_ENTITY, mapvote_abstain);
 363                 WriteByte(MSG_ENTITY, mapvote_detail);
 364                 WriteCoord(MSG_ENTITY, mapvote_timeout);
 365
 366                 if ( gametypevote )
 367                 {
 368                         // gametype vote
 369                         WriteByte(MSG_ENTITY, 1);
 370                         WriteString(MSG_ENTITY, autocvar_nextmap);
 371                 }
 372                 else if ( autocvar_sv_vote_gametype )
 373                 {
 374                         // map vote but gametype has been chosen via voting screen
 375                         WriteByte(MSG_ENTITY, 2);
 376                         WriteString(MSG_ENTITY, MapInfo_Type_ToText(MapInfo_CurrentGametype()));
 377                 }
 378                 else
 379                         WriteByte(MSG_ENTITY, 0); // map vote
 380
 381                 MapVote_WriteMask();
 382
 383                 // Send data for the vote options
 384                 for(i = 0; i < mapvote_count; ++i)
 385                 {
 386                         if(gametypevote)
 387                                 GameTypeVote_SendOption(i);
 388                         else
 389                                 MapVote_SendOption(i);
 390                 }
 391         }
 392
 393         if(sf & 2)
 394         {
 395                 // flag 2 == update of mask
 396                 MapVote_WriteMask();
 397         }
 398
 399         if(sf & 4)
 400         {
 401                 if(mapvote_detail)
 402                         for(i = 0; i < mapvote_count; ++i)
 403                                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 404                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
 405
 406                 WriteByte(MSG_ENTITY, to.mapvote);
 407         }
 408
 409         return true;
 410 }
 411
 412 void MapVote_Spawn()
 413 {
 414         Net_LinkEntity(mapvote_ent = spawn(), false, 0, MapVote_SendEntity);
 415 }
 416
 417 void MapVote_TouchMask()
 418 {
 419         mapvote_ent.SendFlags |= 2;
 420 }
 421
 422 void MapVote_TouchVotes(entity voter)
 423 {
 424         mapvote_ent.SendFlags |= 4;
 425 }
 426
 427 float MapVote_Finished(float mappos)
 428 {
 429         if(alreadychangedlevel)
 430                 return false;
 431
 432         string result;
 433         float i;
 434         float didntvote;
 435
 436         if(autocvar_sv_eventlog)
 437         {
 438                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
 439                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
 440                 didntvote = mapvote_voters;
 441                 for(i = 0; i < mapvote_count; ++i)
 442                         if(mapvote_maps_flags[i] & GTV_AVAILABLE )
 443                         {
 444                                 didntvote -= mapvote_selections[i];
 445                                 if(i != mappos)
 446                                 {
 447                                         result = strcat(result, ":", mapvote_maps[i]);
 448                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
 449                                 }
 450                         }
 451                 result = strcat(result, ":didn't vote:", ftos(didntvote));
 452
 453                 GameLogEcho(result);
 454                 if(mapvote_maps_suggested[mappos])
 455                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
 456         }
 457
 458         FOR_EACH_REALCLIENT(other)
 459                 FixClientCvars(other);
 460
 461         if(gametypevote)
 462         {
 463                 if ( GameTypeVote_Finished(mappos) )
 464                 {
 465                         gametypevote = false;
 466                         if(autocvar_nextmap != "")
 467                         {
 468                                 Map_Goto_SetStr(autocvar_nextmap);
 469                                 Map_Goto(0);
 470                                 alreadychangedlevel = true;
 471                                 return true;
 472                         }
 473                         else
 474                                 MapVote_Init();
 475                 }
 476                 return false;
 477         }
 478
 479         Map_Goto_SetStr(mapvote_maps[mappos]);
 480         Map_Goto(0);
 481         alreadychangedlevel = true;
 482
 483         return true;
 484 }
 485
 486 void MapVote_CheckRules_1()
 487 {
 488         float i;
 489
 490         for(i = 0; i < mapvote_count; ++i)
 491                 if( mapvote_maps_flags[i] & GTV_AVAILABLE )
 492                 {
 493                         //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
 494                         mapvote_selections[i] = 0;
 495                 }
 496
 497         mapvote_voters = 0;
 498         FOR_EACH_REALCLIENT(other)
 499         {
 500                 ++mapvote_voters;
 501                 if(other.mapvote)
 502                 {
 503                         i = other.mapvote - 1;
 504                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
 505                         mapvote_selections[i] = mapvote_selections[i] + 1;
 506                 }
 507         }
 508 }
 509
 510 float MapVote_CheckRules_2()
 511 {
 512         float i;
 513         float firstPlace, secondPlace, currentPlace;
 514         float firstPlaceVotes, secondPlaceVotes, currentVotes;
 515         float mapvote_voters_real;
 516         string result;
 517
 518         if(mapvote_count_real == 1)
 519                 return MapVote_Finished(0);
 520
 521         mapvote_voters_real = mapvote_voters;
 522         if(mapvote_abstain)
 523                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
 524
 525         RandomSelection_Init();
 526         currentPlace = 0;
 527         currentVotes = -1;
 528         for(i = 0; i < mapvote_count_real; ++i)
 529                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 530                 {
 531                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
 532                         if ( gametypevote &&  mapvote_maps[i] == MapInfo_Type_ToString(MapInfo_CurrentGametype()) )
 533                         {
 534                                 currentVotes = mapvote_selections[i];
 535                                 currentPlace = i;
 536                         }
 537                 }
 538         firstPlaceVotes = RandomSelection_best_priority;
 539         if ( autocvar_sv_vote_gametype_default_current && currentVotes == firstPlaceVotes )
 540                 firstPlace = currentPlace;
 541         else
 542                 firstPlace = RandomSelection_chosen_float;
 543
 544         //dprint("First place: ", ftos(firstPlace), "\n");
 545         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
 546
 547         RandomSelection_Init();
 548         for(i = 0; i < mapvote_count_real; ++i)
 549                 if(i != firstPlace)
 550                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 551                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
 552         secondPlace = RandomSelection_chosen_float;
 553         secondPlaceVotes = RandomSelection_best_priority;
 554         //dprint("Second place: ", ftos(secondPlace), "\n");
 555         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
 556
 557         if(firstPlace == -1)
 558                 error("No first place in map vote... WTF?");
 559
 560         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
 561                 return MapVote_Finished(firstPlace);
 562
 563         if(mapvote_keeptwotime)
 564                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
 565                 {
 566                         float didntvote;
 567                         MapVote_TouchMask();
 568                         mapvote_message = "Now decide between the TOP TWO!";
 569                         mapvote_keeptwotime = 0;
 570                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
 571                         result = strcat(result, ":", ftos(firstPlaceVotes));
 572                         result = strcat(result, ":", mapvote_maps[secondPlace]);
 573                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
 574                         didntvote = mapvote_voters;
 575                         for(i = 0; i < mapvote_count; ++i)
 576                         {
 577                                 didntvote -= mapvote_selections[i];
 578                                 if(i != firstPlace)
 579                                         if(i != secondPlace)
 580                                         {
 581                                                 result = strcat(result, ":", mapvote_maps[i]);
 582                                                 result = strcat(result, ":", ftos(mapvote_selections[i]));
 583                                                 if(i < mapvote_count_real)
 584                                                 {
 585                                                         mapvote_maps_flags[i] &= ~GTV_AVAILABLE;
 586                                                 }
 587                                         }
 588                         }
 589                         result = strcat(result, ":didn't vote:", ftos(didntvote));
 590                         if(autocvar_sv_eventlog)
 591                                 GameLogEcho(result);
 592                 }
 593
 594         return false;
 595 }
 596
 597 void MapVote_Tick()
 598 {
 599         float keeptwo;
 600         float totalvotes;
 601
 602         keeptwo = mapvote_keeptwotime;
 603         MapVote_CheckRules_1(); // count
 604         if(MapVote_CheckRules_2()) // decide
 605                 return;
 606
 607         totalvotes = 0;
 608         FOR_EACH_REALCLIENT(other)
 609         {
 610                 // hide scoreboard again
 611                 if(other.health != 2342)
 612                 {
 613                         other.health = 2342;
 614                         other.impulse = 0;
 615                         if(IS_REAL_CLIENT(other))
 616                         {
 617                                 msg_entity = other;
 618                                 WriteByte(MSG_ONE, SVC_FINALE);
 619                                 WriteString(MSG_ONE, "");
 620                         }
 621                 }
 622
 623                 // clear possibly invalid votes
 624                 if ( !(mapvote_maps_flags[other.mapvote-1] & GTV_AVAILABLE) )
 625                         other.mapvote = 0;
 626                 // use impulses as new vote
 627                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
 628                         if( mapvote_maps_flags[other.impulse - 1] & GTV_AVAILABLE )
 629                         {
 630                                 other.mapvote = other.impulse;
 631                                 MapVote_TouchVotes(other);
 632                         }
 633                 other.impulse = 0;
 634
 635                 if(other.mapvote)
 636                         ++totalvotes;
 637         }
 638
 639         MapVote_CheckRules_1(); // just count
 640 }
 641
 642 void MapVote_Start()
 643 {
 644         // if mapvote is already running, don't do this initialization again
 645         if(mapvote_run) { return; }
 646
 647         // don't start mapvote until after playerstats gamereport is sent
 648         if(PlayerStats_GameReport_DelayMapVote) { return; }
 649
 650         MapInfo_Enumerate();
 651         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
 652                 mapvote_run = true;
 653 }
 654
 655 void MapVote_Think()
 656 {
 657         if(!mapvote_run)
 658                 return;
 659
 660         if(alreadychangedlevel)
 661                 return;
 662
 663         if(time < mapvote_nextthink)
 664                 return;
 665         //dprint("tick\n");
 666
 667         mapvote_nextthink = time + 0.5;
 668
 669         if(!mapvote_initialized)
 670         {
 671                 if(autocvar_rescan_pending == 1)
 672                 {
 673                         cvar_set("rescan_pending", "2");
 674                         localcmd("fs_rescan\nrescan_pending 3\n");
 675                         return;
 676                 }
 677                 else if(autocvar_rescan_pending == 2)
 678                 {
 679                         return;
 680                 }
 681                 else if(autocvar_rescan_pending == 3)
 682                 {
 683                         // now build missing mapinfo files
 684                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
 685                                 return;
 686
 687                         // we're done, start the timer
 688                         cvar_set("rescan_pending", "0");
 689                 }
 690
 691                 mapvote_initialized = true;
 692                 if(DoNextMapOverride(0))
 693                         return;
 694                 if(!autocvar_g_maplist_votable || player_count <= 0)
 695                 {
 696                         GotoNextMap(0);
 697                         return;
 698                 }
 699
 700                 if(autocvar_sv_vote_gametype) { GameTypeVote_Start(); }
 701                 else if(autocvar_nextmap == "") { MapVote_Init(); }
 702         }
 703
 704         MapVote_Tick();
 705 }
 706
 707 float GameTypeVote_SetGametype(float type)
 708 {
 709         if (MapInfo_CurrentGametype() == type)
 710                 return true;
 711
 712         float tsave = MapInfo_CurrentGametype();
 713
 714         MapInfo_SwitchGameType(type);
 715
 716         MapInfo_Enumerate();
 717         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 718         if(MapInfo_count > 0)
 719         {
 720                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 721                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 722                 lsmaps_reply = strzone(getlsmaps());
 723                 bprint("Game type successfully switched to ", MapInfo_Type_ToString(type), "\n");
 724         }
 725         else
 726         {
 727                 bprint("Cannot use this game type: no map for it found\n");
 728                 MapInfo_SwitchGameType(tsave);
 729                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 730                 return false;
 731         }
 732
 733         //localcmd("gametype ", MapInfo_Type_ToString(type), "\n");
 734
 735         cvar_set("g_maplist", MapInfo_ListAllowedMaps(type, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()) );
 736         if(autocvar_g_maplist_shuffle)
 737                 ShuffleMaplist();
 738
 739         return true;
 740 }
 741
 742 float gametypevote_finished;
 743 float GameTypeVote_Finished(float pos)
 744 {
 745         if(!gametypevote || gametypevote_finished)
 746                 return false;
 747
 748         if ( !GameTypeVote_SetGametype(GameTypeVote_Type_FromString(mapvote_maps[pos])) )
 749         {
 750                 LOG_TRACE("Selected gametype is not supported by any map");
 751         }
 752
 753         localcmd("sv_vote_gametype_hook_all\n");
 754         localcmd("sv_vote_gametype_hook_", mapvote_maps[pos], "\n");
 755
 756         gametypevote_finished = true;
 757
 758         return true;
 759 }
 760
 761 float GameTypeVote_AddVotable(string nextMode)
 762 {
 763         float j;
 764         if ( nextMode == "" || GameTypeVote_Type_FromString(nextMode) == 0 )
 765                 return false;
 766         for(j = 0; j < mapvote_count; ++j)
 767                 if(mapvote_maps[j] == nextMode)
 768                         return false;
 769
 770         mapvote_maps[mapvote_count] = strzone(nextMode);
 771         mapvote_maps_suggested[mapvote_count] = false;
 772
 773         mapvote_maps_screenshot_dir[mapvote_count] = 0;
 774         mapvote_maps_pakfile[mapvote_count] = strzone("");
 775         mapvote_maps_flags[mapvote_count] = GameTypeVote_AvailabilityStatus(nextMode);
 776
 777         mapvote_count += 1;
 778
 779         return true;
 780
 781 }
 782
 783 float GameTypeVote_Start()
 784 {
 785         float j;
 786         MapVote_ClearAllVotes();
 787         MapVote_UnzoneStrings();
 788
 789         mapvote_count = 0;
 790         mapvote_timeout = time + autocvar_sv_vote_gametype_timeout;
 791         mapvote_abstain = 0;
 792         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
 793
 794         float n = tokenizebyseparator(autocvar_sv_vote_gametype_options, " ");
 795         n = min(MAPVOTE_COUNT, n);
 796
 797         float really_available, which_available;
 798         really_available = 0;
 799         which_available = -1;
 800         for(j = 0; j < n; ++j)
 801         {
 802                 if ( GameTypeVote_AddVotable(argv(j)) )
 803                 if ( mapvote_maps_flags[j] & GTV_AVAILABLE )
 804                 {
 805                         really_available++;
 806                         which_available = j;
 807                 }
 808         }
 809
 810         mapvote_count_real = mapvote_count;
 811
 812         gametypevote = 1;
 813
 814         if ( really_available == 0 )
 815         {
 816                 if ( mapvote_count > 0 )
 817                         strunzone(mapvote_maps[0]);
 818                 mapvote_maps[0] = strzone(MapInfo_Type_ToString(MapInfo_CurrentGametype()));
 819                 //GameTypeVote_Finished(0);
 820                 MapVote_Finished(0);
 821                 return false;
 822         }
 823         if ( really_available == 1 )
 824         {
 825                 //GameTypeVote_Finished(which_available);
 826                 MapVote_Finished(which_available);
 827                 return false;
 828         }
 829
 830         mapvote_count_real = mapvote_count;
 831
 832         mapvote_keeptwotime = time + autocvar_sv_vote_gametype_keeptwotime;
 833         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
 834                 mapvote_keeptwotime = 0;
 835
 836         MapVote_Spawn();
 837
 838         return true;
 839 }