qcsrc/server/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/playerstats.qh>
   7 #include <common/state.qh>
   8 #include <common/stats.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <server/client.qh>
  12 #include <server/command/cmd.qh>
  13 #include <server/command/getreplies.qh>
  14 #include <server/gamelog.qh>
  15 #include <server/world.qh>
  16
  17 // definitions
  18
  19 float mapvote_nextthink;
  20 float mapvote_keeptwotime;
  21 float mapvote_timeout;
  22 const int MAPVOTE_SCREENSHOT_DIRS_COUNT = 4;
  23 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
  24 int mapvote_screenshot_dirs_count;
  25
  26 int mapvote_count;
  27 int mapvote_count_real;
  28 string mapvote_maps[MAPVOTE_COUNT];
  29 int mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
  30 string mapvote_maps_pakfile[MAPVOTE_COUNT];
  31 bool mapvote_maps_suggested[MAPVOTE_COUNT];
  32 string mapvote_suggestions[MAPVOTE_COUNT];
  33 int mapvote_suggestion_ptr;
  34 int mapvote_voters;
  35 int mapvote_selections[MAPVOTE_COUNT];
  36 int mapvote_maps_flags[MAPVOTE_COUNT];
  37 bool mapvote_run;
  38 bool mapvote_detail;
  39 bool mapvote_abstain;
  40 .int mapvote;
  41
  42 entity mapvote_ent;
  43
  44 /**
  45  * Returns the gamtype ID from its name, if type_name isn't a real gametype it
  46  * checks for sv_vote_gametype_(type_name)_type
  47  */
  48 Gametype GameTypeVote_Type_FromString(string type_name)
  49 {
  50         Gametype type = MapInfo_Type_FromString(type_name, false, false);
  51         if (type == NULL)
  52                 type = MapInfo_Type_FromString(cvar_string(
  53                         strcat("sv_vote_gametype_",type_name,"_type")), false, false);
  54         return type;
  55 }
  56
  57 int GameTypeVote_AvailabilityStatus(string type_name)
  58 {
  59         int flag = GTV_FORBIDDEN;
  60
  61         Gametype type = MapInfo_Type_FromString(type_name, false, false);
  62         if ( type == NULL )
  63         {
  64                 type = MapInfo_Type_FromString(cvar_string(
  65                         strcat("sv_vote_gametype_",type_name,"_type")), false, false);
  66                 flag |= GTV_CUSTOM;
  67         }
  68
  69         if( type == NULL )
  70                 return flag;
  71
  72         if ( autocvar_nextmap != "" )
  73         {
  74                 if ( !MapInfo_Get_ByName(autocvar_nextmap, false, NULL) )
  75                         return flag;
  76                 if (!(MapInfo_Map_supportedGametypes & type.m_flags))
  77                         return flag;
  78         }
  79
  80         return flag | GTV_AVAILABLE;
  81 }
  82
  83 int GameTypeVote_GetMask()
  84 {
  85         int n, j, gametype_mask;
  86         n = tokenizebyseparator(autocvar_sv_vote_gametype_options, " ");
  87         n = min(MAPVOTE_COUNT, n);
  88         gametype_mask = 0;
  89         for(j = 0; j < n; ++j)
  90                 gametype_mask |= GameTypeVote_Type_FromString(argv(j)).m_flags;
  91
  92         if (gametype_mask == 0)
  93                 gametype_mask |= MapInfo_CurrentGametype().m_flags;
  94
  95         return gametype_mask;
  96 }
  97
  98 string GameTypeVote_MapInfo_FixName(string m)
  99 {
 100         if ( autocvar_sv_vote_gametype )
 101         {
 102                 MapInfo_Enumerate();
 103                 _MapInfo_FilterGametype(GameTypeVote_GetMask(), 0, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 104         }
 105         return MapInfo_FixName(m);
 106 }
 107
 108 void MapVote_ClearAllVotes()
 109 {
 110         FOREACH_CLIENT(true, { it.mapvote = 0; });
 111 }
 112
 113 void MapVote_UnzoneStrings()
 114 {
 115         for(int j = 0; j < mapvote_count; ++j)
 116         {
 117                 strfree(mapvote_maps[j]);
 118                 strfree(mapvote_maps_pakfile[j]);
 119         }
 120 }
 121
 122 string MapVote_Suggest(entity this, string m)
 123 {
 124         int i;
 125         if(m == "")
 126                 return "That's not how to use this command.";
 127         if(!autocvar_g_maplist_votable_suggestions)
 128                 return "Suggestions are not accepted on this server.";
 129         if(mapvote_initialized)
 130         if(!gametypevote)
 131                 return "Can't suggest - voting is already in progress!";
 132         m = GameTypeVote_MapInfo_FixName(m);
 133         if (!m)
 134                 return "The map you suggested is not available on this server.";
 135         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
 136                 if(Map_IsRecent(m))
 137                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
 138
 139         if (!autocvar_sv_vote_gametype)
 140         if(!MapInfo_CheckMap(m))
 141                 return "The map you suggested does not support the current game mode.";
 142         for(i = 0; i < mapvote_suggestion_ptr; ++i)
 143                 if(mapvote_suggestions[i] == m)
 144                         return "This map was already suggested.";
 145         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
 146         {
 147                 i = floor(random() * mapvote_suggestion_ptr);
 148         }
 149         else
 150         {
 151                 i = mapvote_suggestion_ptr;
 152                 mapvote_suggestion_ptr += 1;
 153         }
 154         if(mapvote_suggestions[i] != "")
 155                 strunzone(mapvote_suggestions[i]);
 156         mapvote_suggestions[i] = strzone(m);
 157         if(autocvar_sv_eventlog)
 158                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(this.playerid)));
 159         return strcat("Suggestion of ", m, " accepted.");
 160 }
 161
 162 void MapVote_AddVotable(string nextMap, bool isSuggestion)
 163 {
 164         int j, i, o;
 165         string pakfile, mapfile;
 166
 167         if(nextMap == "")
 168                 return;
 169         for(j = 0; j < mapvote_count; ++j)
 170                 if(mapvote_maps[j] == nextMap)
 171                         return;
 172         // suggestions might be no longer valid/allowed after gametype switch!
 173         if(isSuggestion)
 174                 if(!MapInfo_CheckMap(nextMap))
 175                         return;
 176         mapvote_maps[mapvote_count] = strzone(nextMap);
 177         mapvote_maps_suggested[mapvote_count] = isSuggestion;
 178
 179         pakfile = string_null;
 180         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
 181         {
 182                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", nextMap);
 183                 pakfile = whichpack(strcat(mapfile, ".tga"));
 184                 if(pakfile == "")
 185                         pakfile = whichpack(strcat(mapfile, ".jpg"));
 186                 if(pakfile == "")
 187                         pakfile = whichpack(strcat(mapfile, ".png"));
 188                 if(pakfile != "")
 189                         break;
 190         }
 191         if(i >= mapvote_screenshot_dirs_count)
 192                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
 193         for(o = strstrofs(pakfile, "/", 0)+1; o > 0; o = strstrofs(pakfile, "/", 0)+1)
 194                 pakfile = substring(pakfile, o, -1);
 195
 196         mapvote_maps_screenshot_dir[mapvote_count] = i;
 197         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
 198         mapvote_maps_flags[mapvote_count] = GTV_AVAILABLE;
 199
 200         mapvote_count += 1;
 201 }
 202
 203 void MapVote_AddVotableMaps(int nmax, int smax)
 204 {
 205         int available_maps = Maplist_Init();
 206         int max_attempts = available_maps;
 207         if (available_maps >= 2)
 208                 max_attempts = min(available_maps * 5, 100);
 209
 210         if (smax && mapvote_suggestion_ptr)
 211                 for(int i = 0; i < max_attempts && mapvote_count < smax; ++i)
 212                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], true);
 213
 214         for (int i = 0; i < max_attempts && mapvote_count < nmax; ++i)
 215                 MapVote_AddVotable(GetNextMap(), false);
 216 }
 217
 218 bool GameTypeVote_SetGametype(Gametype type);
 219 void GameTypeVote_ApplyGameType(Gametype type)
 220 {
 221         localcmd("sv_vote_gametype_hook_all\n");
 222         localcmd("sv_vote_gametype_hook_", MapInfo_Type_ToString(type), "\n");
 223
 224         if (!GameTypeVote_SetGametype(type))
 225                 LOG_TRACE("Selected gametype is not supported by any map");
 226 }
 227
 228 Gametype voted_gametype;
 229 Gametype match_gametype;
 230 void MapVote_Init()
 231 {
 232         int nmax, smax;
 233
 234         MapVote_ClearAllVotes();
 235         MapVote_UnzoneStrings();
 236
 237         mapvote_count = 0;
 238         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
 239         mapvote_abstain = boolean(autocvar_g_maplist_votable_abstain);
 240
 241         if(mapvote_abstain)
 242                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
 243         else
 244                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
 245         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
 246
 247         // we need this for AddVotable, as that cycles through the screenshot dirs
 248         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
 249         if(mapvote_screenshot_dirs_count == 0)
 250                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
 251         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
 252         for(int i = 0; i < mapvote_screenshot_dirs_count; ++i)
 253                 mapvote_screenshot_dirs[i] = strzone(argv(i));
 254
 255         MapVote_AddVotableMaps(nmax, smax);
 256
 257         mapvote_count_real = mapvote_count;
 258         if(mapvote_abstain)
 259                 MapVote_AddVotable("don't care", false);
 260
 261         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
 262
 263         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
 264         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
 265         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
 266                 mapvote_keeptwotime = 0;
 267
 268         MapVote_Spawn();
 269
 270         // If match_gametype is set it means voted_gametype has just been applied (on game type vote end).
 271         // In this case apply back match_gametype here so that the "restart" command, if called,
 272         // properly restarts the map applying the current game type.
 273         // Applying voted_gametype before map vote start is needed to properly initialize map vote.
 274         if (match_gametype)
 275                 GameTypeVote_ApplyGameType(match_gametype);
 276 }
 277
 278 void MapVote_SendPicture(entity to, int id)
 279 {
 280         msg_entity = to;
 281         WriteHeader(MSG_ONE, TE_CSQC_PICTURE);
 282         WriteByte(MSG_ONE, id);
 283         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
 284 }
 285
 286
 287 void MapVote_WriteMask()
 288 {
 289         if ( mapvote_count < 24 )
 290         {
 291                 int mask = 0;
 292                 for(int j = 0; j < mapvote_count; ++j)
 293                 {
 294                         if(mapvote_maps_flags[j] & GTV_AVAILABLE)
 295                                 mask |= BIT(j);
 296                 }
 297
 298                 if(mapvote_count < 8)
 299                         WriteByte(MSG_ENTITY, mask);
 300                 else if (mapvote_count < 16)
 301                         WriteShort(MSG_ENTITY,mask);
 302                 else
 303                         WriteLong(MSG_ENTITY, mask);
 304         }
 305         else
 306         {
 307                 for (int j = 0; j < mapvote_count; ++j)
 308                         WriteByte(MSG_ENTITY, mapvote_maps_flags[j]);
 309         }
 310 }
 311
 312 /*
 313  * Sends a single map vote option to the client
 314  */
 315 void MapVote_SendOption(int i)
 316 {
 317         // abstain
 318         if(mapvote_abstain && i == mapvote_count - 1)
 319         {
 320                 WriteString(MSG_ENTITY, ""); // abstain needs no text
 321                 WriteString(MSG_ENTITY, ""); // abstain needs no pack
 322                 WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
 323         }
 324         else
 325         {
 326                 WriteString(MSG_ENTITY, mapvote_maps[i]);
 327                 WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
 328                 WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
 329         }
 330 }
 331
 332 /*
 333  * Sends a single gametype vote option to the client
 334  */
 335 void GameTypeVote_SendOption(int i)
 336 {
 337         // abstain
 338         if(mapvote_abstain && i == mapvote_count - 1)
 339         {
 340                 WriteString(MSG_ENTITY, ""); // abstain needs no text
 341                 WriteByte(MSG_ENTITY, GTV_AVAILABLE);
 342         }
 343         else
 344         {
 345                 string type_name = mapvote_maps[i];
 346                 WriteString(MSG_ENTITY, type_name);
 347                 WriteByte(MSG_ENTITY, mapvote_maps_flags[i]);
 348                 if ( mapvote_maps_flags[i] & GTV_CUSTOM )
 349                 {
 350                         WriteString(MSG_ENTITY, cvar_string(
 351                                 strcat("sv_vote_gametype_",type_name,"_name")));
 352                         WriteString(MSG_ENTITY, cvar_string(
 353                                 strcat("sv_vote_gametype_",type_name,"_description")));
 354                         WriteString(MSG_ENTITY, cvar_string(
 355                                 strcat("sv_vote_gametype_",type_name,"_type")));
 356                 }
 357         }
 358 }
 359
 360 int mapvote_winner;
 361 float mapvote_winner_time;
 362 bool MapVote_SendEntity(entity this, entity to, int sf)
 363 {
 364         int i;
 365
 366         if(sf & 1)
 367                 sf &= ~2; // if we send 1, we don't need to also send 2
 368
 369         if (!mapvote_winner_time)
 370                 sf &= ~8; // no winner yet
 371
 372         WriteHeader(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
 373         WriteByte(MSG_ENTITY, sf);
 374
 375         if(sf & 1)
 376         {
 377                 // flag 1 == initialization
 378                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
 379                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
 380                 WriteString(MSG_ENTITY, "");
 381                 WriteByte(MSG_ENTITY, mapvote_count);
 382                 WriteByte(MSG_ENTITY, mapvote_abstain);
 383                 WriteByte(MSG_ENTITY, mapvote_detail);
 384                 WriteCoord(MSG_ENTITY, mapvote_timeout);
 385
 386                 if ( gametypevote )
 387                 {
 388                         // gametype vote
 389                         WriteByte(MSG_ENTITY, BIT(0)); // gametypevote_flags
 390                         WriteString(MSG_ENTITY, autocvar_nextmap);
 391                 }
 392                 else if ( autocvar_sv_vote_gametype )
 393                 {
 394                         // map vote but gametype has been chosen via voting screen
 395                         WriteByte(MSG_ENTITY, BIT(1)); // gametypevote_flags
 396                         WriteString(MSG_ENTITY, MapInfo_Type_ToText(voted_gametype));
 397                 }
 398                 else
 399                         WriteByte(MSG_ENTITY, 0); // map vote
 400
 401                 MapVote_WriteMask();
 402
 403                 // Send data for the vote options
 404                 for(i = 0; i < mapvote_count; ++i)
 405                 {
 406                         if(gametypevote)
 407                                 GameTypeVote_SendOption(i);
 408                         else
 409                                 MapVote_SendOption(i);
 410                 }
 411         }
 412
 413         if(sf & 2)
 414         {
 415                 // flag 2 == update of mask
 416                 MapVote_WriteMask();
 417         }
 418
 419         if(sf & 4)
 420         {
 421                 if(mapvote_detail)
 422                         for(i = 0; i < mapvote_count; ++i)
 423                                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 424                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
 425
 426                 WriteByte(MSG_ENTITY, to.mapvote);
 427         }
 428
 429         if(sf & 8)
 430         {
 431                 WriteByte(MSG_ENTITY, mapvote_winner + 1);
 432         }
 433
 434         return true;
 435 }
 436
 437 void MapVote_Spawn()
 438 {
 439         Net_LinkEntity(mapvote_ent = new(mapvote_ent), false, 0, MapVote_SendEntity);
 440 }
 441
 442 void MapVote_TouchMask()
 443 {
 444         mapvote_ent.SendFlags |= 2;
 445 }
 446
 447 void MapVote_TouchVotes(entity voter)
 448 {
 449         mapvote_ent.SendFlags |= 4;
 450 }
 451
 452 void MapVote_Winner(int mappos)
 453 {
 454         mapvote_ent.SendFlags |= 8;
 455         mapvote_winner_time = time;
 456         mapvote_winner = mappos;
 457 }
 458
 459 bool MapVote_Finished(int mappos)
 460 {
 461         if(alreadychangedlevel)
 462                 return false;
 463
 464         string result;
 465         int i;
 466         int didntvote;
 467
 468         if(autocvar_sv_eventlog)
 469         {
 470                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
 471                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
 472                 didntvote = mapvote_voters;
 473                 for(i = 0; i < mapvote_count; ++i)
 474                         if(mapvote_maps_flags[i] & GTV_AVAILABLE )
 475                         {
 476                                 didntvote -= mapvote_selections[i];
 477                                 if(i != mappos)
 478                                 {
 479                                         result = strcat(result, ":", mapvote_maps[i]);
 480                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
 481                                 }
 482                         }
 483                 result = strcat(result, ":didn't vote:", ftos(didntvote));
 484
 485                 GameLogEcho(result);
 486                 if(mapvote_maps_suggested[mappos])
 487                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
 488         }
 489
 490         FOREACH_CLIENT(IS_REAL_CLIENT(it), { FixClientCvars(it); });
 491
 492         if(gametypevote)
 493         {
 494                 if ( GameTypeVote_Finished(mappos) )
 495                 {
 496                         gametypevote = false;
 497                         if(autocvar_nextmap != "")
 498                         {
 499                                 Map_Goto_SetStr(autocvar_nextmap);
 500                                 Map_Goto(0);
 501                                 alreadychangedlevel = true;
 502                                 return true;
 503                         }
 504                         else
 505                                 MapVote_Init();
 506                 }
 507                 return false;
 508         }
 509
 510         MapVote_Winner(mappos);
 511         alreadychangedlevel = true;
 512
 513         return true;
 514 }
 515
 516 void MapVote_CheckRules_1()
 517 {
 518         for (int i = 0; i < mapvote_count; ++i)
 519                 if (mapvote_maps_flags[i] & GTV_AVAILABLE)
 520                 {
 521                         //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
 522                         mapvote_selections[i] = 0;
 523                 }
 524
 525         mapvote_voters = 0;
 526         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 527                 ++mapvote_voters;
 528                 if (it.mapvote)
 529                 {
 530                         int idx = it.mapvote - 1;
 531                         //dprint("Player ", it.netname, " vote = ", ftos(idx), "\n");
 532                         ++mapvote_selections[idx];
 533                 }
 534         });
 535 }
 536
 537 bool MapVote_CheckRules_2()
 538 {
 539         int i;
 540         int firstPlace, secondPlace, currentPlace;
 541         int firstPlaceVotes, secondPlaceVotes, currentVotes;
 542         int mapvote_voters_real;
 543         string result;
 544
 545         if(mapvote_count_real == 1)
 546                 return MapVote_Finished(0);
 547
 548         mapvote_voters_real = mapvote_voters;
 549         if(mapvote_abstain)
 550                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
 551
 552         RandomSelection_Init();
 553         currentPlace = 0;
 554         currentVotes = -1;
 555         for(i = 0; i < mapvote_count_real; ++i)
 556                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 557                 {
 558                         RandomSelection_AddFloat(i, 1, mapvote_selections[i]);
 559                         if ( gametypevote && mapvote_maps[i] == MapInfo_Type_ToString(MapInfo_CurrentGametype()) )
 560                         {
 561                                 currentVotes = mapvote_selections[i];
 562                                 currentPlace = i;
 563                         }
 564                 }
 565         firstPlaceVotes = RandomSelection_best_priority;
 566         if (gametypevote && autocvar_sv_vote_gametype_default_current && firstPlaceVotes == 0)
 567                 firstPlace = currentPlace;
 568         else
 569                 firstPlace = RandomSelection_chosen_float;
 570
 571         //dprint("First place: ", ftos(firstPlace), "\n");
 572         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
 573
 574         RandomSelection_Init();
 575         for(i = 0; i < mapvote_count_real; ++i)
 576                 if(i != firstPlace)
 577                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 578                         RandomSelection_AddFloat(i, 1, mapvote_selections[i]);
 579         secondPlace = RandomSelection_chosen_float;
 580         secondPlaceVotes = RandomSelection_best_priority;
 581         //dprint("Second place: ", ftos(secondPlace), "\n");
 582         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
 583
 584         if(firstPlace == -1)
 585                 error("No first place in map vote... WTF?");
 586
 587         if(secondPlace == -1 || time > mapvote_timeout
 588                 || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes
 589                 || mapvote_selections[mapvote_count - 1] == mapvote_voters)
 590         {
 591                 return MapVote_Finished(firstPlace);
 592         }
 593
 594         if(mapvote_keeptwotime)
 595                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
 596                 {
 597                         MapVote_TouchMask();
 598                         mapvote_keeptwotime = 0;
 599                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
 600                         result = strcat(result, ":", ftos(firstPlaceVotes));
 601                         result = strcat(result, ":", mapvote_maps[secondPlace]);
 602                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
 603                         int didntvote = mapvote_voters;
 604                         for(i = 0; i < mapvote_count; ++i)
 605                         {
 606                                 didntvote -= mapvote_selections[i];
 607                                 if(i != firstPlace)
 608                                         if(i != secondPlace)
 609                                         {
 610                                                 result = strcat(result, ":", mapvote_maps[i]);
 611                                                 result = strcat(result, ":", ftos(mapvote_selections[i]));
 612                                                 if(i < mapvote_count_real)
 613                                                 {
 614                                                         mapvote_maps_flags[i] &= ~GTV_AVAILABLE;
 615                                                 }
 616                                         }
 617                         }
 618                         result = strcat(result, ":didn't vote:", ftos(didntvote));
 619                         if(autocvar_sv_eventlog)
 620                                 GameLogEcho(result);
 621                 }
 622
 623         return false;
 624 }
 625
 626 void MapVote_Tick()
 627 {
 628         MapVote_CheckRules_1(); // count
 629         if(MapVote_CheckRules_2()) // decide
 630                 return;
 631
 632         int totalvotes = 0;
 633         FOREACH_CLIENT(true, {
 634                 if(!IS_REAL_CLIENT(it))
 635                 {
 636                         // apply the same special health value to bots too for consistency's sake
 637                         if(GetResource(it, RES_HEALTH) != 2342)
 638                                 SetResourceExplicit(it, RES_HEALTH, 2342);
 639                         continue;
 640                 }
 641                 // hide scoreboard again
 642                 if(GetResource(it, RES_HEALTH) != 2342)
 643                 {
 644                         SetResourceExplicit(it, RES_HEALTH, 2342); // health in the voting phase
 645                         CS(it).impulse = 0;
 646
 647                         msg_entity = it;
 648                         WriteByte(MSG_ONE, SVC_FINALE);
 649                         WriteString(MSG_ONE, "");
 650                 }
 651
 652                 // clear possibly invalid votes
 653                 if ( !(mapvote_maps_flags[it.mapvote-1] & GTV_AVAILABLE) )
 654                         it.mapvote = 0;
 655                 // use impulses as new vote
 656                 if(CS(it).impulse >= 1 && CS(it).impulse <= mapvote_count)
 657                         if( mapvote_maps_flags[CS(it).impulse - 1] & GTV_AVAILABLE )
 658                         {
 659                                 it.mapvote = CS(it).impulse;
 660                                 MapVote_TouchVotes(it);
 661                         }
 662                 CS(it).impulse = 0;
 663
 664                 if(it.mapvote)
 665                         ++totalvotes;
 666         });
 667
 668         MapVote_CheckRules_1(); // just count
 669 }
 670
 671 void MapVote_Start()
 672 {
 673         // if mapvote is already running, don't do this initialization again
 674         if(mapvote_run) { return; }
 675
 676         // don't start mapvote until after playerstats gamereport is sent
 677         if(PlayerStats_GameReport_DelayMapVote) { return; }
 678
 679         MapInfo_Enumerate();
 680         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
 681                 mapvote_run = true;
 682 }
 683
 684 void MapVote_Think()
 685 {
 686         if(!mapvote_run)
 687                 return;
 688
 689         if (mapvote_winner_time)
 690         {
 691                 if (time > mapvote_winner_time + 1)
 692                 {
 693                         if (voted_gametype)
 694                         {
 695                                 // clear match_gametype so that GameTypeVote_ApplyGameType
 696                                 // prints the game type switch message
 697                                 match_gametype = NULL;
 698                                 GameTypeVote_ApplyGameType(voted_gametype);
 699                         }
 700
 701                         Map_Goto_SetStr(mapvote_maps[mapvote_winner]);
 702                         Map_Goto(0);
 703                 }
 704                 return;
 705         }
 706
 707         if(alreadychangedlevel)
 708                 return;
 709
 710         if(time < mapvote_nextthink)
 711                 return;
 712         //dprint("tick\n");
 713
 714         mapvote_nextthink = time + 0.5;
 715         if (mapvote_nextthink > mapvote_timeout - 0.1) // make sure there's no delay when map vote times out
 716                 mapvote_nextthink = mapvote_timeout + 0.001;
 717
 718         if(!mapvote_initialized)
 719         {
 720                 if(autocvar_rescan_pending == 1)
 721                 {
 722                         cvar_set("rescan_pending", "2");
 723                         localcmd("fs_rescan\nrescan_pending 3\n");
 724                         return;
 725                 }
 726                 else if(autocvar_rescan_pending == 2)
 727                 {
 728                         return;
 729                 }
 730                 else if(autocvar_rescan_pending == 3)
 731                 {
 732                         // now build missing mapinfo files
 733                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
 734                                 return;
 735
 736                         // we're done, start the timer
 737                         cvar_set("rescan_pending", "0");
 738                 }
 739
 740                 mapvote_initialized = true;
 741                 if(DoNextMapOverride(0))
 742                         return;
 743                 if(!autocvar_g_maplist_votable || player_count <= 0)
 744                 {
 745                         GotoNextMap(0);
 746                         return;
 747                 }
 748
 749                 if(autocvar_sv_vote_gametype) { GameTypeVote_Start(); }
 750                 else if(autocvar_nextmap == "") { MapVote_Init(); }
 751         }
 752
 753         MapVote_Tick();
 754 }
 755
 756 bool GameTypeVote_SetGametype(Gametype type)
 757 {
 758         if (MapInfo_CurrentGametype() == type)
 759                 return true;
 760
 761         Gametype tsave = MapInfo_CurrentGametype();
 762
 763         MapInfo_SwitchGameType(type);
 764
 765         MapInfo_Enumerate();
 766         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 767         if(MapInfo_count > 0)
 768         {
 769                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 770                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 771                 lsmaps_reply = strzone(getlsmaps());
 772
 773                 if (!match_gametype) // don't show this msg if we are temporarily switching game type
 774                         bprint("Game type successfully switched to ", MapInfo_Type_ToString(type), "\n");
 775         }
 776         else
 777         {
 778                 bprint("Cannot use this game type: no map for it found\n");
 779                 MapInfo_SwitchGameType(tsave);
 780                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 781                 return false;
 782         }
 783
 784         cvar_set("g_maplist", MapInfo_ListAllowedMaps(type, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()) );
 785
 786         return true;
 787 }
 788
 789 bool gametypevote_finished;
 790 bool GameTypeVote_Finished(int pos)
 791 {
 792         if(!gametypevote || gametypevote_finished)
 793                 return false;
 794
 795         match_gametype = MapInfo_CurrentGametype();
 796         voted_gametype = MapInfo_Type_FromString(mapvote_maps[pos], false, false);
 797
 798         GameTypeVote_ApplyGameType(voted_gametype);
 799
 800         gametypevote_finished = true;
 801
 802         return true;
 803 }
 804
 805 bool GameTypeVote_AddVotable(string nextMode)
 806 {
 807         if ( nextMode == "" || GameTypeVote_Type_FromString(nextMode) == NULL )
 808                 return false;
 809
 810         for(int j = 0; j < mapvote_count; ++j)
 811                 if(mapvote_maps[j] == nextMode)
 812                         return false;
 813
 814         mapvote_maps[mapvote_count] = strzone(nextMode);
 815         mapvote_maps_suggested[mapvote_count] = false;
 816
 817         mapvote_maps_screenshot_dir[mapvote_count] = 0;
 818         mapvote_maps_pakfile[mapvote_count] = strzone("");
 819         mapvote_maps_flags[mapvote_count] = GameTypeVote_AvailabilityStatus(nextMode);
 820
 821         mapvote_count += 1;
 822
 823         return true;
 824
 825 }
 826
 827 bool GameTypeVote_Start()
 828 {
 829         MapVote_ClearAllVotes();
 830         MapVote_UnzoneStrings();
 831
 832         mapvote_count = 0;
 833         mapvote_timeout = time + autocvar_sv_vote_gametype_timeout;
 834         mapvote_abstain = false;
 835         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
 836
 837         int n = tokenizebyseparator(autocvar_sv_vote_gametype_options, " ");
 838         n = min(MAPVOTE_COUNT, n);
 839
 840         int really_available, which_available;
 841         really_available = 0;
 842         which_available = -1;
 843         for(int j = 0; j < n; ++j)
 844         {
 845                 if ( GameTypeVote_AddVotable(argv(j)) )
 846                 if ( mapvote_maps_flags[j] & GTV_AVAILABLE )
 847                 {
 848                         really_available++;
 849                         which_available = j;
 850                 }
 851         }
 852
 853         mapvote_count_real = mapvote_count;
 854
 855         gametypevote = true;
 856
 857         if ( really_available == 0 )
 858         {
 859                 if ( mapvote_count > 0 )
 860                         strunzone(mapvote_maps[0]);
 861                 mapvote_maps[0] = strzone(MapInfo_Type_ToString(MapInfo_CurrentGametype()));
 862                 //GameTypeVote_Finished(0);
 863                 MapVote_Finished(0);
 864                 return false;
 865         }
 866         if ( really_available == 1 )
 867         {
 868                 //GameTypeVote_Finished(which_available);
 869                 MapVote_Finished(which_available);
 870                 return false;
 871         }
 872
 873         mapvote_count_real = mapvote_count;
 874
 875         mapvote_keeptwotime = time + autocvar_sv_vote_gametype_keeptwotime;
 876         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
 877                 mapvote_keeptwotime = 0;
 878
 879         MapVote_Spawn();
 880
 881         return true;
 882 }