qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70
  71 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  72
  73
  74 string STR_PLAYER = "player";
  75 string STR_SPECTATOR = "spectator";
  76 string STR_OBSERVER = "observer";
  77
  78 #if 0
  79 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  80 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  81 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  82 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 #else
  84 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  85 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  86 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  87 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  88 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  89 #endif
  90
  91 // copies a string to a tempstring (so one can strunzone it)
  92 string strcat1(string s) = #115; // FRIK_FILE
  93
  94 float logfile_open;
  95 float logfile;
  96
  97 void bcenterprint(string s)
  98 {
  99     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 100     entity head;
 101     FOR_EACH_PLAYER(head)
 102     if (clienttype(head) == CLIENTTYPE_REAL)
 103         centerprint(head, s);
 104 }
 105
 106 void GameLogEcho(string s)
 107 {
 108     string fn;
 109     float matches;
 110
 111     if (autocvar_sv_eventlog_files)
 112     {
 113         if (!logfile_open)
 114         {
 115             logfile_open = TRUE;
 116             matches = autocvar_sv_eventlog_files_counter + 1;
 117             cvar_set("sv_eventlog_files_counter", ftos(matches));
 118             fn = ftos(matches);
 119             if (strlen(fn) < 8)
 120                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 121             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 122             logfile = fopen(fn, FILE_APPEND);
 123             fputs(logfile, ":logversion:3\n");
 124         }
 125         if (logfile >= 0)
 126         {
 127             if (autocvar_sv_eventlog_files_timestamps)
 128                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 129             else
 130                 fputs(logfile, strcat(s, "\n"));
 131         }
 132     }
 133     if (autocvar_sv_eventlog_console)
 134     {
 135         print(s, "\n");
 136     }
 137 }
 138
 139 void GameLogInit()
 140 {
 141     logfile_open = 0;
 142     // will be opened later
 143 }
 144
 145 void GameLogClose()
 146 {
 147     if (logfile_open && logfile >= 0)
 148     {
 149         fclose(logfile);
 150         logfile = -1;
 151     }
 152 }
 153
 154 float spawnpoint_nag;
 155 void relocate_spawnpoint()
 156 {
 157     // nudge off the floor
 158     setorigin(self, self.origin + '0 0 1');
 159
 160     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 161     if (trace_startsolid)
 162     {
 163         vector o;
 164         o = self.origin;
 165         self.mins = PL_MIN;
 166         self.maxs = PL_MAX;
 167         if (!move_out_of_solid(self))
 168             objerror("could not get out of solid at all!");
 169         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 170         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 171         print(" ", ftos(self.origin_y - o_y));
 172         print(" ", ftos(self.origin_z - o_z), "'\n");
 173         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 174         {
 175             if (!spawnpoint_nag)
 176                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 177             spawnpoint_nag = 1;
 178         }
 179         else
 180         {
 181             setorigin(self, o);
 182             self.mins = self.maxs = '0 0 0';
 183             objerror("player spawn point in solid, mapper sucks!\n");
 184             return;
 185         }
 186     }
 187
 188     self.use = spawnpoint_use;
 189     self.team_saved = self.team;
 190     if (!self.cnt)
 191         self.cnt = 1;
 192
 193     if (have_team_spawns != 0)
 194         if (self.team)
 195             have_team_spawns = 1;
 196     have_team_spawns_forteam[self.team] = 1;
 197
 198     if (autocvar_r_showbboxes)
 199     {
 200         // show where spawnpoints point at too
 201         makevectors(self.angles);
 202         entity e;
 203         e = spawn();
 204         e.classname = "info_player_foo";
 205         setorigin(e, self.origin + v_forward * 24);
 206         setsize(e, '-8 -8 -8', '8 8 8');
 207         e.solid = SOLID_TRIGGER;
 208     }
 209 }
 210
 211 #define strstr strstrofs
 212 /*
 213 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 214 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 215 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 216 // BE CONSTANT OR strzoneD!
 217 float strstr(string haystack, string needle, float offset)
 218 {
 219         float len, endpos;
 220         string found;
 221         len = strlen(needle);
 222         endpos = strlen(haystack) - len;
 223         while(offset <= endpos)
 224         {
 225                 found = substring(haystack, offset, len);
 226                 if(found == needle)
 227                         return offset;
 228                 offset = offset + 1;
 229         }
 230         return -1;
 231 }
 232 */
 233
 234 float NUM_NEAREST_ENTITIES = 4;
 235 entity nearest_entity[NUM_NEAREST_ENTITIES];
 236 float nearest_length[NUM_NEAREST_ENTITIES];
 237 entity findnearest(vector point, .string field, string value, vector axismod)
 238 {
 239     entity localhead;
 240     float i;
 241     float j;
 242     float len;
 243     vector dist;
 244
 245     float num_nearest;
 246     num_nearest = 0;
 247
 248     localhead = find(world, field, value);
 249     while (localhead)
 250     {
 251         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 252             dist = localhead.oldorigin;
 253         else
 254             dist = localhead.origin;
 255         dist = dist - point;
 256         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 257         len = vlen(dist);
 258
 259         for (i = 0; i < num_nearest; ++i)
 260         {
 261             if (len < nearest_length[i])
 262                 break;
 263         }
 264
 265         // now i tells us where to insert at
 266         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 267         if (i < NUM_NEAREST_ENTITIES)
 268         {
 269             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 270             {
 271                 nearest_length[j + 1] = nearest_length[j];
 272                 nearest_entity[j + 1] = nearest_entity[j];
 273             }
 274             nearest_length[i] = len;
 275             nearest_entity[i] = localhead;
 276             if (num_nearest < NUM_NEAREST_ENTITIES)
 277                 num_nearest = num_nearest + 1;
 278         }
 279
 280         localhead = find(localhead, field, value);
 281     }
 282
 283     // now use the first one from our list that we can see
 284     for (i = 0; i < num_nearest; ++i)
 285     {
 286         traceline(point, nearest_entity[i].origin, TRUE, world);
 287         if (trace_fraction == 1)
 288         {
 289             if (i != 0)
 290             {
 291                 dprint("Nearest point (");
 292                 dprint(nearest_entity[0].netname);
 293                 dprint(") is not visible, using a visible one.\n");
 294             }
 295             return nearest_entity[i];
 296         }
 297     }
 298
 299     if (num_nearest == 0)
 300         return world;
 301
 302     dprint("Not seeing any location point, using nearest as fallback.\n");
 303     /* DEBUGGING CODE:
 304     dprint("Candidates were: ");
 305     for(j = 0; j < num_nearest; ++j)
 306     {
 307         if(j != 0)
 308                 dprint(", ");
 309         dprint(nearest_entity[j].netname);
 310     }
 311     dprint("\n");
 312     */
 313
 314     return nearest_entity[0];
 315 }
 316
 317 void spawnfunc_target_location()
 318 {
 319     self.classname = "target_location";
 320     // location name in netname
 321     // eventually support: count, teamgame selectors, line of sight?
 322 }
 323
 324 void spawnfunc_info_location()
 325 {
 326     self.classname = "target_location";
 327     self.message = self.netname;
 328 }
 329
 330 string NearestLocation(vector p)
 331 {
 332     entity loc;
 333     string ret;
 334     ret = "somewhere";
 335     loc = findnearest(p, classname, "target_location", '1 1 1');
 336     if (loc)
 337     {
 338         ret = loc.message;
 339     }
 340     else
 341     {
 342         loc = findnearest(p, target, "###item###", '1 1 4');
 343         if (loc)
 344             ret = loc.netname;
 345     }
 346     return ret;
 347 }
 348
 349 string formatmessage(string msg)
 350 {
 351         float p, p1, p2;
 352         float n;
 353         vector cursor;
 354         entity cursor_ent;
 355         string escape;
 356         string replacement;
 357         p = 0;
 358         n = 7;
 359
 360         WarpZone_crosshair_trace(self);
 361         cursor = trace_endpos;
 362         cursor_ent = trace_ent;
 363
 364         while (1) {
 365                 if (n < 1)
 366                         break; // too many replacements
 367
 368                 n = n - 1;
 369                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 370                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 371
 372                 if (p1 < 0)
 373                         p1 = p2;
 374
 375                 if (p2 < 0)
 376                         p2 = p1;
 377
 378                 p = min(p1, p2);
 379
 380                 if (p < 0)
 381                         break;
 382
 383                 replacement = substring(msg, p, 2);
 384                 escape = substring(msg, p + 1, 1);
 385
 386                 if (escape == "%")
 387                         replacement = "%";
 388                 else if (escape == "\\")
 389                         replacement = "\\";
 390                 else if (escape == "n")
 391                         replacement = "\n";
 392                 else if (escape == "a")
 393                         replacement = ftos(floor(self.armorvalue));
 394                 else if (escape == "h")
 395                         replacement = ftos(floor(self.health));
 396                 else if (escape == "l")
 397                         replacement = NearestLocation(self.origin);
 398                 else if (escape == "y")
 399                         replacement = NearestLocation(cursor);
 400                 else if (escape == "d")
 401                         replacement = NearestLocation(self.death_origin);
 402                 else if (escape == "w") {
 403                         float wep;
 404                         wep = self.weapon;
 405                         if (!wep)
 406                                 wep = self.switchweapon;
 407                         if (!wep)
 408                                 wep = self.cnt;
 409                         replacement = W_Name(wep);
 410                 } else if (escape == "W") {
 411                         if (self.items & IT_SHELLS) replacement = "shells";
 412                         else if (self.items & IT_NAILS) replacement = "bullets";
 413                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 414                         else if (self.items & IT_CELLS) replacement = "cells";
 415                         else replacement = "batteries"; // ;)
 416                 } else if (escape == "x") {
 417                         replacement = cursor_ent.netname;
 418                         if (!replacement || !cursor_ent)
 419                                 replacement = "nothing";
 420                 } else if (escape == "s")
 421                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 422                 else if (escape == "S")
 423                         replacement = ftos(vlen(self.velocity));
 424
 425                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 426                 p = p + strlen(replacement);
 427         }
 428         return msg;
 429 }
 430
 431 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 432         return (value == 0) ? FALSE : TRUE;
 433 }
 434
 435 /*
 436 =============
 437 GetCvars
 438 =============
 439 Called with:
 440   0:  sends the request
 441   >0: receives a cvar from name=argv(f) value=argv(f+1)
 442 */
 443 void GetCvars_handleString(string thisname, float f, .string field, string name)
 444 {
 445         if (f < 0)
 446         {
 447                 if (self.field)
 448                         strunzone(self.field);
 449                 self.field = string_null;
 450         }
 451         else if (f > 0)
 452         {
 453                 if (thisname == name)
 454                 {
 455                         if (self.field)
 456                                 strunzone(self.field);
 457                         self.field = strzone(argv(f + 1));
 458                 }
 459         }
 460         else
 461                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462 }
 463 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 464 {
 465         GetCvars_handleString(thisname, f, field, name);
 466         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 467                 if (thisname == name)
 468                 {
 469                         string s;
 470                         s = func(strcat1(self.field));
 471                         if (s != self.field)
 472                         {
 473                                 strunzone(self.field);
 474                                 self.field = strzone(s);
 475                         }
 476                 }
 477 }
 478 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 479 {
 480         if (f < 0)
 481         {
 482         }
 483         else if (f > 0)
 484         {
 485                 if (thisname == name)
 486                         self.field = stof(argv(f + 1));
 487         }
 488         else
 489                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 490 }
 491 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                 {
 500                         if(!self.field)
 501                         {
 502                                 self.field = stof(argv(f + 1));
 503                                 if(!self.field)
 504                                         self.field = -1;
 505                         }
 506                 }
 507         }
 508         else
 509         {
 510                 if(!self.field)
 511                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 512         }
 513 }
 514 float w_getbestweapon(entity e);
 515 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 516 {
 517         string o;
 518         o = W_FixWeaponOrder_ForceComplete(wo);
 519         if(self.weaponorder_byimpulse)
 520         {
 521                 strunzone(self.weaponorder_byimpulse);
 522                 self.weaponorder_byimpulse = string_null;
 523         }
 524         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 525         return o;
 526 }
 527 void GetCvars(float f)
 528 {
 529         string s;
 530
 531         if (f > 0)
 532                 s = strcat1(argv(f));
 533
 534         get_cvars_f = f;
 535         get_cvars_s = s;
 536         MUTATOR_CALLHOOK(GetCvars);
 537         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 538         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 539         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 541         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 554         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 555         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 556         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 558         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 559         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 560
 561         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 562         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 563
 564 #ifdef ALLOW_FORCEMODELS
 565         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 566         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 567 #endif
 568         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 569         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 570         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 571         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 572         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 573
 574         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 575         if (f > 0)
 576         {
 577                 if (s == "cl_weaponpriority")
 578                         self.switchweapon = w_getbestweapon(self);
 579                 if (s == "cl_allow_uidtracking")
 580                         PlayerStats_AddPlayer(self);
 581         }
 582 }
 583
 584 void backtrace(string msg)
 585 {
 586     float dev, war;
 587     dev = autocvar_developer;
 588     war = autocvar_prvm_backtraceforwarnings;
 589     cvar_set("developer", "1");
 590     cvar_set("prvm_backtraceforwarnings", "1");
 591     print("\n");
 592     print("--- CUT HERE ---\nWARNING: ");
 593     print(msg);
 594     print("\n");
 595     remove(world); // isn't there any better way to cause a backtrace?
 596     print("\n--- CUT UNTIL HERE ---\n");
 597     cvar_set("developer", ftos(dev));
 598     cvar_set("prvm_backtraceforwarnings", ftos(war));
 599 }
 600
 601 string Team_ColorCode(float teamid)
 602 {
 603     if (teamid == COLOR_TEAM1)
 604         return "^1";
 605     else if (teamid == COLOR_TEAM2)
 606         return "^4";
 607     else if (teamid == COLOR_TEAM3)
 608         return "^3";
 609     else if (teamid == COLOR_TEAM4)
 610         return "^6";
 611     else
 612         return "^7";
 613 }
 614
 615 string Team_ColorName(float t)
 616 {
 617     // fixme: Search for team entities and get their .netname's!
 618     if (t == COLOR_TEAM1)
 619         return "Red";
 620     if (t == COLOR_TEAM2)
 621         return "Blue";
 622     if (t == COLOR_TEAM3)
 623         return "Yellow";
 624     if (t == COLOR_TEAM4)
 625         return "Pink";
 626     return "Neutral";
 627 }
 628
 629 string Team_ColorNameLowerCase(float t)
 630 {
 631     // fixme: Search for team entities and get their .netname's!
 632     if (t == COLOR_TEAM1)
 633         return "red";
 634     if (t == COLOR_TEAM2)
 635         return "blue";
 636     if (t == COLOR_TEAM3)
 637         return "yellow";
 638     if (t == COLOR_TEAM4)
 639         return "pink";
 640     return "neutral";
 641 }
 642
 643 float ColourToNumber(string team_colour)
 644 {
 645         if (team_colour == "red")
 646                 return COLOR_TEAM1;
 647
 648         if (team_colour == "blue")
 649                 return COLOR_TEAM2;
 650
 651         if (team_colour == "yellow")
 652                 return COLOR_TEAM3;
 653
 654         if (team_colour == "pink")
 655                 return COLOR_TEAM4;
 656
 657         if (team_colour == "auto")
 658                 return 0;
 659
 660         return -1;
 661 }
 662
 663 float NumberToTeamNumber(float number)
 664 {
 665         if (number == 1)
 666                 return COLOR_TEAM1;
 667
 668         if (number == 2)
 669                 return COLOR_TEAM2;
 670
 671         if (number == 3)
 672                 return COLOR_TEAM3;
 673
 674         if (number == 4)
 675                 return COLOR_TEAM4;
 676
 677         return -1;
 678 }
 679
 680 // decolorizes and team colors the player name when needed
 681 string playername(entity p)
 682 {
 683     string t;
 684     if (teamplay && !intermission_running && p.classname == "player")
 685     {
 686         t = Team_ColorCode(p.team);
 687         return strcat(t, strdecolorize(p.netname));
 688     }
 689     else
 690         return p.netname;
 691 }
 692
 693 vector randompos(vector m1, vector m2)
 694 {
 695     vector v;
 696     m2 = m2 - m1;
 697     v_x = m2_x * random() + m1_x;
 698     v_y = m2_y * random() + m1_y;
 699     v_z = m2_z * random() + m1_z;
 700     return  v;
 701 }
 702
 703 //#NO AUTOCVARS START
 704
 705 float g_pickup_shells;
 706 float g_pickup_shells_max;
 707 float g_pickup_nails;
 708 float g_pickup_nails_max;
 709 float g_pickup_rockets;
 710 float g_pickup_rockets_max;
 711 float g_pickup_cells;
 712 float g_pickup_cells_max;
 713 float g_pickup_fuel;
 714 float g_pickup_fuel_jetpack;
 715 float g_pickup_fuel_max;
 716 float g_pickup_armorsmall;
 717 float g_pickup_armorsmall_max;
 718 float g_pickup_armorsmall_anyway;
 719 float g_pickup_armormedium;
 720 float g_pickup_armormedium_max;
 721 float g_pickup_armormedium_anyway;
 722 float g_pickup_armorbig;
 723 float g_pickup_armorbig_max;
 724 float g_pickup_armorbig_anyway;
 725 float g_pickup_armorlarge;
 726 float g_pickup_armorlarge_max;
 727 float g_pickup_armorlarge_anyway;
 728 float g_pickup_healthsmall;
 729 float g_pickup_healthsmall_max;
 730 float g_pickup_healthsmall_anyway;
 731 float g_pickup_healthmedium;
 732 float g_pickup_healthmedium_max;
 733 float g_pickup_healthmedium_anyway;
 734 float g_pickup_healthlarge;
 735 float g_pickup_healthlarge_max;
 736 float g_pickup_healthlarge_anyway;
 737 float g_pickup_healthmega;
 738 float g_pickup_healthmega_max;
 739 float g_pickup_healthmega_anyway;
 740 float g_pickup_ammo_anyway;
 741 float g_pickup_weapons_anyway;
 742 float g_weaponarena;
 743 WEPSET_DECLARE_A(g_weaponarena_weapons);
 744 float g_weaponarena_random;
 745 float g_weaponarena_random_with_laser;
 746 string g_weaponarena_list;
 747 float g_weaponspeedfactor;
 748 float g_weaponratefactor;
 749 float g_weapondamagefactor;
 750 float g_weaponforcefactor;
 751 float g_weaponspreadfactor;
 752
 753 WEPSET_DECLARE_A(start_weapons);
 754 float start_items;
 755 float start_ammo_shells;
 756 float start_ammo_nails;
 757 float start_ammo_rockets;
 758 float start_ammo_cells;
 759 float start_ammo_fuel;
 760 float start_health;
 761 float start_armorvalue;
 762 WEPSET_DECLARE_A(warmup_start_weapons);
 763 float warmup_start_ammo_shells;
 764 float warmup_start_ammo_nails;
 765 float warmup_start_ammo_rockets;
 766 float warmup_start_ammo_cells;
 767 float warmup_start_ammo_fuel;
 768 float warmup_start_health;
 769 float warmup_start_armorvalue;
 770 float g_weapon_stay;
 771 float g_ghost_items;
 772
 773 entity get_weaponinfo(float w);
 774
 775 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 776 {
 777         var float i = weaponinfo.weapon;
 778
 779         if (!i)
 780                 return 0;
 781
 782         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 783
 784         if (t < 0) // "default" weapon selection
 785         {
 786                 if (g_lms || g_ca || allguns)
 787                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 788                 else if(t < -1)
 789                         t = 0;
 790                 else if (g_cts)
 791                         t = (i == WEP_SHOTGUN);
 792                 else if (g_nexball)
 793                         t = 0; // weapon is set a few lines later
 794                 else
 795                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 796                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 797                         t |= (i == WEP_HOOK);
 798         }
 799
 800         return t;
 801 }
 802
 803 void readplayerstartcvars()
 804 {
 805         entity e;
 806         float i, j, t;
 807         string s;
 808
 809         // initialize starting values for players
 810         WEPSET_CLEAR_A(start_weapons);
 811         start_items = 0;
 812         start_ammo_shells = 0;
 813         start_ammo_nails = 0;
 814         start_ammo_rockets = 0;
 815         start_ammo_cells = 0;
 816         start_health = cvar("g_balance_health_start");
 817         start_armorvalue = cvar("g_balance_armor_start");
 818
 819         g_weaponarena = 0;
 820         WEPSET_CLEAR_A(g_weaponarena_weapons);
 821
 822         s = cvar_string("g_weaponarena");
 823         if (s == "0" || s == "")
 824         {
 825                 if(g_lms || g_ca)
 826                         s = "most";
 827         }
 828
 829         if (s == "0" || s == "")
 830         {
 831                 // no arena
 832         }
 833         else if (s == "off")
 834         {
 835                 // forcibly turn off weaponarena
 836         }
 837         else if (s == "all")
 838         {
 839                 g_weaponarena = 1;
 840                 g_weaponarena_list = "All Weapons";
 841                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 842                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 843         }
 844         else if (s == "most")
 845         {
 846                 g_weaponarena = 1;
 847                 g_weaponarena_list = "Most Weapons";
 848                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 849                 {
 850                         e = get_weaponinfo(j);
 851                         if (e.spawnflags & WEP_FLAG_NORMAL)
 852                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 853                 }
 854         }
 855         else if (s == "none")
 856         {
 857                 g_weaponarena = 1;
 858                 g_weaponarena_list = "No Weapons";
 859         }
 860         else
 861         {
 862                 g_weaponarena = 1;
 863                 t = tokenize_console(s);
 864                 g_weaponarena_list = "";
 865                 for (i = 0; i < t; ++i)
 866                 {
 867                         s = argv(i);
 868                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 869                         {
 870                                 e = get_weaponinfo(j);
 871                                 if (e.netname == s)
 872                                 {
 873                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 874                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 875                                         break;
 876                                 }
 877                         }
 878                         if (j > WEP_LAST)
 879                         {
 880                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 881                         }
 882                 }
 883                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 884         }
 885
 886         if(g_weaponarena)
 887                 g_weaponarena_random = cvar("g_weaponarena_random");
 888         else
 889                 g_weaponarena_random = 0;
 890         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 891
 892         if (g_weaponarena)
 893         {
 894                 g_minstagib = 0; // incompatible
 895                 g_pinata = 0; // incompatible
 896                 g_weapon_stay = 0; // incompatible
 897                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 898                 if(!(g_lms || g_ca))
 899                         start_items |= IT_UNLIMITED_AMMO;
 900         }
 901         else if (g_minstagib)
 902         {
 903                 g_pinata = 0; // incompatible
 904                 g_weapon_stay = 0; // incompatible
 905                 g_bloodloss = 0; // incompatible
 906                 start_health = 100;
 907                 start_armorvalue = 0;
 908                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 909                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 910                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 911
 912                 if (g_minstagib_invis_alpha <= 0)
 913                         g_minstagib_invis_alpha = -1;
 914         }
 915         else
 916         {
 917                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 918                 {
 919                         e = get_weaponinfo(i);
 920                         if(want_weapon("g_start_weapon_", e, FALSE))
 921                                 WEPSET_OR_AW(start_weapons, e.weapons);
 922                 }
 923         }
 924
 925         if(!cvar("g_use_ammunition"))
 926                 start_items |= IT_UNLIMITED_AMMO;
 927
 928         if(cvar("g_nexball"))
 929                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 930
 931         if(g_minstagib)
 932         {
 933                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 934                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 935         }
 936         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 937         {
 938                 start_ammo_rockets = 999;
 939                 start_ammo_shells = 999;
 940                 start_ammo_cells = 999;
 941                 start_ammo_nails = 999;
 942                 start_ammo_fuel = 999;
 943         }
 944         else
 945         {
 946                 if(g_lms || g_ca)
 947                 {
 948                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 949                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 950                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 951                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 952                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 953                 }
 954                 else
 955                 {
 956                         start_ammo_shells = cvar("g_start_ammo_shells");
 957                         start_ammo_nails = cvar("g_start_ammo_nails");
 958                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 959                         start_ammo_cells = cvar("g_start_ammo_cells");
 960                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 961                 }
 962         }
 963
 964         if (g_lms || g_ca)
 965         {
 966                 start_health = cvar("g_lms_start_health");
 967                 start_armorvalue = cvar("g_lms_start_armor");
 968         }
 969
 970         if (inWarmupStage)
 971         {
 972                 warmup_start_ammo_shells = start_ammo_shells;
 973                 warmup_start_ammo_nails = start_ammo_nails;
 974                 warmup_start_ammo_rockets = start_ammo_rockets;
 975                 warmup_start_ammo_cells = start_ammo_cells;
 976                 warmup_start_ammo_fuel = start_ammo_fuel;
 977                 warmup_start_health = start_health;
 978                 warmup_start_armorvalue = start_armorvalue;
 979                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 980
 981                 if (!g_weaponarena && !g_minstagib && !g_ca)
 982                 {
 983                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 984                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 985                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 986                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 987                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 988                         warmup_start_health = cvar("g_warmup_start_health");
 989                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 990                         WEPSET_CLEAR_A(warmup_start_weapons);
 991                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 992                         {
 993                                 e = get_weaponinfo(i);
 994                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
 995                                         WEPSET_OR_AW(warmup_start_weapons, j);
 996                         }
 997                 }
 998         }
 999
1000         if (g_jetpack || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEPBIT_HOOK)))
1001         {
1002                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1003                 start_items |= IT_FUEL_REGEN;
1004                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1005                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1006         }
1007
1008         if (g_jetpack)
1009                 start_items |= IT_JETPACK;
1010
1011         MUTATOR_CALLHOOK(SetStartItems);
1012
1013         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1014         {
1015                 e = get_weaponinfo(i);
1016                 if(WEPSET_CONTAINS_AW(start_weapons, j) || WEPSET_CONTAINS_AW(warmup_start_weapons, j))
1017                         weapon_action(e.weapon, WR_PRECACHE);
1018         }
1019
1020         start_ammo_shells = max(0, start_ammo_shells);
1021         start_ammo_nails = max(0, start_ammo_nails);
1022         start_ammo_cells = max(0, start_ammo_cells);
1023         start_ammo_rockets = max(0, start_ammo_rockets);
1024         start_ammo_fuel = max(0, start_ammo_fuel);
1025
1026         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1027         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1028         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1029         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1030         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1031 }
1032
1033 float g_bugrigs;
1034 float g_bugrigs_planar_movement;
1035 float g_bugrigs_planar_movement_car_jumping;
1036 float g_bugrigs_reverse_spinning;
1037 float g_bugrigs_reverse_speeding;
1038 float g_bugrigs_reverse_stopping;
1039 float g_bugrigs_air_steering;
1040 float g_bugrigs_angle_smoothing;
1041 float g_bugrigs_friction_floor;
1042 float g_bugrigs_friction_brake;
1043 float g_bugrigs_friction_air;
1044 float g_bugrigs_accel;
1045 float g_bugrigs_speed_ref;
1046 float g_bugrigs_speed_pow;
1047 float g_bugrigs_steer;
1048
1049 float g_touchexplode;
1050 float g_touchexplode_radius;
1051 float g_touchexplode_damage;
1052 float g_touchexplode_edgedamage;
1053 float g_touchexplode_force;
1054
1055 float sv_autotaunt;
1056 float sv_taunt;
1057
1058 float sv_pitch_min;
1059 float sv_pitch_max;
1060 float sv_pitch_fixyaw;
1061
1062 string GetGametype(); // g_world.qc
1063 void readlevelcvars(void)
1064 {
1065         // first load all the mutators
1066         if(cvar("g_invincible_projectiles"))
1067                 MUTATOR_ADD(mutator_invincibleprojectiles);
1068         if(cvar("g_nix"))
1069                 MUTATOR_ADD(mutator_nix);
1070         if(cvar("g_dodging"))
1071                 MUTATOR_ADD(mutator_dodging);
1072         if(cvar("g_rocket_flying"))
1073                 MUTATOR_ADD(mutator_rocketflying);
1074         if(cvar("g_vampire"))
1075                 MUTATOR_ADD(mutator_vampire);
1076         if(cvar("g_spawn_near_teammate"))
1077                 MUTATOR_ADD(mutator_spawn_near_teammate);
1078
1079         // is this a mutator? is this a mode?
1080         if(cvar("g_sandbox"))
1081                 MUTATOR_ADD(sandbox);
1082
1083         if(cvar("sv_allow_fullbright"))
1084                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1085
1086     g_bugrigs = cvar("g_bugrigs");
1087     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1088     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1089     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1090     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1091     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1092     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1093     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1094     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1095     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1096     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1097     g_bugrigs_accel = cvar("g_bugrigs_accel");
1098     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1099     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1100     g_bugrigs_steer = cvar("g_bugrigs_steer");
1101
1102     g_touchexplode = cvar("g_touchexplode");
1103     g_touchexplode_radius = cvar("g_touchexplode_radius");
1104     g_touchexplode_damage = cvar("g_touchexplode_damage");
1105     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1106     g_touchexplode_force = cvar("g_touchexplode_force");
1107
1108 #ifdef ALLOW_FORCEMODELS
1109         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1110 #endif
1111
1112         sv_clones = cvar("sv_clones");
1113         sv_gentle = cvar("sv_gentle");
1114         sv_foginterval = cvar("sv_foginterval");
1115         g_cloaked = cvar("g_cloaked");
1116     if(g_cts)
1117         g_cloaked = 1; // always enable cloak in CTS
1118         g_jump_grunt = cvar("g_jump_grunt");
1119         g_footsteps = cvar("g_footsteps");
1120         g_grappling_hook = cvar("g_grappling_hook");
1121         g_jetpack = cvar("g_jetpack");
1122         g_midair = cvar("g_midair");
1123         g_minstagib = cvar("g_minstagib");
1124         g_norecoil = cvar("g_norecoil");
1125         g_bloodloss = cvar("g_bloodloss");
1126         sv_maxidle = cvar("sv_maxidle");
1127         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1128         g_ctf_reverse = cvar("g_ctf_reverse");
1129         sv_autotaunt = cvar("sv_autotaunt");
1130         sv_taunt = cvar("sv_taunt");
1131
1132         inWarmupStage = cvar("g_warmup");
1133         g_warmup_limit = cvar("g_warmup_limit");
1134         g_warmup_allguns = cvar("g_warmup_allguns");
1135         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1136
1137         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1138                 inWarmupStage = 0; // these modes cannot work together, sorry
1139
1140         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1141         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1142         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1143         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1144         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1145         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1146         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1147         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1148         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1149         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1150         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1151         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1152         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1153         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1154
1155         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1156         g_weaponratefactor = cvar("g_weaponratefactor");
1157         g_weapondamagefactor = cvar("g_weapondamagefactor");
1158         g_weaponforcefactor = cvar("g_weaponforcefactor");
1159         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1160
1161         g_pickup_shells = cvar("g_pickup_shells");
1162         g_pickup_shells_max = cvar("g_pickup_shells_max");
1163         g_pickup_nails = cvar("g_pickup_nails");
1164         g_pickup_nails_max = cvar("g_pickup_nails_max");
1165         g_pickup_rockets = cvar("g_pickup_rockets");
1166         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1167         g_pickup_cells = cvar("g_pickup_cells");
1168         g_pickup_cells_max = cvar("g_pickup_cells_max");
1169         g_pickup_fuel = cvar("g_pickup_fuel");
1170         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1171         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1172         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1173         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1174         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1175         g_pickup_armormedium = cvar("g_pickup_armormedium");
1176         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1177         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1178         g_pickup_armorbig = cvar("g_pickup_armorbig");
1179         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1180         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1181         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1182         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1183         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1184         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1185         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1186         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1187         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1188         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1189         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1190         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1191         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1192         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1193         g_pickup_healthmega = cvar("g_pickup_healthmega");
1194         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1195         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1196
1197         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1198         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1199
1200         g_pinata = cvar("g_pinata");
1201
1202     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1203     if(!g_weapon_stay)
1204         g_weapon_stay = cvar("g_weapon_stay");
1205
1206         g_ghost_items = cvar("g_ghost_items");
1207
1208         if(g_ghost_items >= 1)
1209                 g_ghost_items = 0.25; // default alpha value
1210
1211         if not(inWarmupStage && !g_ca)
1212                 game_starttime = cvar("g_start_delay");
1213
1214         sv_pitch_min = cvar("sv_pitch_min");
1215         sv_pitch_max = cvar("sv_pitch_max");
1216         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1217
1218         readplayerstartcvars();
1219 }
1220
1221 //#NO AUTOCVARS END
1222
1223 // Sound functions
1224 string precache_sound (string s) = #19;
1225 float precache_sound_index (string s) = #19;
1226
1227 #define SND_VOLUME      1
1228 #define SND_ATTENUATION 2
1229 #define SND_LARGEENTITY 8
1230 #define SND_LARGESOUND  16
1231
1232 float sound_allowed(float dest, entity e)
1233 {
1234     // sounds from world may always pass
1235     for (;;)
1236     {
1237         if (e.classname == "body")
1238             e = e.enemy;
1239         else if (e.realowner && e.realowner != e)
1240             e = e.realowner;
1241         else if (e.owner && e.owner != e)
1242             e = e.owner;
1243         else
1244             break;
1245     }
1246     // sounds to self may always pass
1247     if (dest == MSG_ONE)
1248         if (e == msg_entity)
1249             return TRUE;
1250     // sounds by players can be removed
1251     if (autocvar_bot_sound_monopoly)
1252         if (clienttype(e) == CLIENTTYPE_REAL)
1253             return FALSE;
1254     // anything else may pass
1255     return TRUE;
1256 }
1257
1258 #ifdef COMPAT_XON010_CHANNELS
1259 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1260 void sound(entity e, float chan, string samp, float vol, float atten)
1261 {
1262     if (!sound_allowed(MSG_BROADCAST, e))
1263         return;
1264     builtin_sound(e, chan, samp, vol, atten);
1265 }
1266 #else
1267 #undef sound
1268 void sound(entity e, float chan, string samp, float vol, float atten)
1269 {
1270     if (!sound_allowed(MSG_BROADCAST, e))
1271         return;
1272     sound7(e, chan, samp, vol, atten, 0, 0);
1273 }
1274 #endif
1275
1276 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1277 {
1278     float entno, idx;
1279
1280     if (!sound_allowed(dest, e))
1281         return;
1282
1283     entno = num_for_edict(e);
1284     idx = precache_sound_index(samp);
1285
1286     float sflags;
1287     sflags = 0;
1288
1289     atten = floor(atten * 64);
1290     vol = floor(vol * 255);
1291
1292     if (vol != 255)
1293         sflags |= SND_VOLUME;
1294     if (atten != 64)
1295         sflags |= SND_ATTENUATION;
1296     if (entno >= 8192 || chan < 0 || chan > 7)
1297         sflags |= SND_LARGEENTITY;
1298     if (idx >= 256)
1299         sflags |= SND_LARGESOUND;
1300
1301     WriteByte(dest, SVC_SOUND);
1302     WriteByte(dest, sflags);
1303     if (sflags & SND_VOLUME)
1304         WriteByte(dest, vol);
1305     if (sflags & SND_ATTENUATION)
1306         WriteByte(dest, atten);
1307     if (sflags & SND_LARGEENTITY)
1308     {
1309         WriteShort(dest, entno);
1310         WriteByte(dest, chan);
1311     }
1312     else
1313     {
1314         WriteShort(dest, entno * 8 + chan);
1315     }
1316     if (sflags & SND_LARGESOUND)
1317         WriteShort(dest, idx);
1318     else
1319         WriteByte(dest, idx);
1320
1321     WriteCoord(dest, o_x);
1322     WriteCoord(dest, o_y);
1323     WriteCoord(dest, o_z);
1324 }
1325 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1326 {
1327     vector o;
1328
1329     if (!sound_allowed(dest, e))
1330         return;
1331
1332     o = e.origin + 0.5 * (e.mins + e.maxs);
1333     soundtoat(dest, e, o, chan, samp, vol, atten);
1334 }
1335 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1336 {
1337     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1338 }
1339 void stopsoundto(float dest, entity e, float chan)
1340 {
1341     float entno;
1342
1343     if (!sound_allowed(dest, e))
1344         return;
1345
1346     entno = num_for_edict(e);
1347
1348     if (entno >= 8192 || chan < 0 || chan > 7)
1349     {
1350         float idx, sflags;
1351         idx = precache_sound_index("misc/null.wav");
1352         sflags = SND_LARGEENTITY;
1353         if (idx >= 256)
1354             sflags |= SND_LARGESOUND;
1355         WriteByte(dest, SVC_SOUND);
1356         WriteByte(dest, sflags);
1357         WriteShort(dest, entno);
1358         WriteByte(dest, chan);
1359         if (sflags & SND_LARGESOUND)
1360             WriteShort(dest, idx);
1361         else
1362             WriteByte(dest, idx);
1363         WriteCoord(dest, e.origin_x);
1364         WriteCoord(dest, e.origin_y);
1365         WriteCoord(dest, e.origin_z);
1366     }
1367     else
1368     {
1369         WriteByte(dest, SVC_STOPSOUND);
1370         WriteShort(dest, entno * 8 + chan);
1371     }
1372 }
1373 void stopsound(entity e, float chan)
1374 {
1375     if (!sound_allowed(MSG_BROADCAST, e))
1376         return;
1377
1378     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1379     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1380 }
1381
1382 void play2(entity e, string filename)
1383 {
1384     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1385     msg_entity = e;
1386     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1387 }
1388
1389 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1390 .float spamtime;
1391 float spamsound(entity e, float chan, string samp, float vol, float atten)
1392 {
1393     if (!sound_allowed(MSG_BROADCAST, e))
1394         return FALSE;
1395
1396     if (time > e.spamtime)
1397     {
1398         e.spamtime = time;
1399         sound(e, chan, samp, vol, atten);
1400         return TRUE;
1401     }
1402     return FALSE;
1403 }
1404
1405 void play2team(float t, string filename)
1406 {
1407     entity head;
1408
1409     if (autocvar_bot_sound_monopoly)
1410         return;
1411
1412     FOR_EACH_REALPLAYER(head)
1413     {
1414         if (head.team == t)
1415             play2(head, filename);
1416     }
1417 }
1418
1419 void play2all(string samp)
1420 {
1421     if (autocvar_bot_sound_monopoly)
1422         return;
1423
1424     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1425 }
1426
1427 void PrecachePlayerSounds(string f);
1428 void precache_playermodel(string m)
1429 {
1430         float globhandle, i, n;
1431         string f;
1432
1433         if(substring(m, -9,5) == "_lod1")
1434                 return;
1435         if(substring(m, -9,5) == "_lod2")
1436                 return;
1437         precache_model(m);
1438         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1439         if(fexists(f))
1440                 precache_model(f);
1441         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1442         if(fexists(f))
1443                 precache_model(f);
1444
1445         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1446         if (globhandle < 0)
1447                 return;
1448         n = search_getsize(globhandle);
1449         for (i = 0; i < n; ++i)
1450         {
1451                 //print(search_getfilename(globhandle, i), "\n");
1452                 f = search_getfilename(globhandle, i);
1453                 PrecachePlayerSounds(f);
1454         }
1455         search_end(globhandle);
1456 }
1457 void precache_all_playermodels(string pattern)
1458 {
1459         float globhandle, i, n;
1460         string f;
1461
1462         globhandle = search_begin(pattern, TRUE, FALSE);
1463         if (globhandle < 0)
1464                 return;
1465         n = search_getsize(globhandle);
1466         for (i = 0; i < n; ++i)
1467         {
1468                 //print(search_getfilename(globhandle, i), "\n");
1469                 f = search_getfilename(globhandle, i);
1470                 precache_playermodel(f);
1471         }
1472         search_end(globhandle);
1473 }
1474
1475 void precache()
1476 {
1477     // gamemode related things
1478     precache_model ("models/misc/chatbubble.spr");
1479     if (g_runematch)
1480     {
1481         precache_model ("models/runematch/curse.mdl");
1482         precache_model ("models/runematch/rune.mdl");
1483     }
1484
1485 #ifdef TTURRETS_ENABLED
1486     if (autocvar_g_turrets)
1487         turrets_precash();
1488 #endif
1489
1490     // Precache all player models if desired
1491     if (autocvar_sv_precacheplayermodels)
1492     {
1493         PrecachePlayerSounds("sound/player/default.sounds");
1494         precache_all_playermodels("models/player/*.zym");
1495         precache_all_playermodels("models/player/*.dpm");
1496         precache_all_playermodels("models/player/*.md3");
1497         precache_all_playermodels("models/player/*.psk");
1498         precache_all_playermodels("models/player/*.iqm");
1499     }
1500
1501     if (autocvar_sv_defaultcharacter)
1502     {
1503         string s;
1504         s = autocvar_sv_defaultplayermodel_red;
1505         if (s != "")
1506             precache_playermodel(s);
1507         s = autocvar_sv_defaultplayermodel_blue;
1508         if (s != "")
1509             precache_playermodel(s);
1510         s = autocvar_sv_defaultplayermodel_yellow;
1511         if (s != "")
1512             precache_playermodel(s);
1513         s = autocvar_sv_defaultplayermodel_pink;
1514         if (s != "")
1515             precache_playermodel(s);
1516         s = autocvar_sv_defaultplayermodel;
1517         if (s != "")
1518             precache_playermodel(s);
1519     }
1520
1521     if (g_footsteps)
1522     {
1523         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1524         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1525     }
1526
1527     // gore and miscellaneous sounds
1528     //precache_sound ("misc/h2ohit.wav");
1529     precache_model ("models/hook.md3");
1530     precache_sound ("misc/armorimpact.wav");
1531     precache_sound ("misc/bodyimpact1.wav");
1532     precache_sound ("misc/bodyimpact2.wav");
1533     precache_sound ("misc/gib.wav");
1534     precache_sound ("misc/gib_splat01.wav");
1535     precache_sound ("misc/gib_splat02.wav");
1536     precache_sound ("misc/gib_splat03.wav");
1537     precache_sound ("misc/gib_splat04.wav");
1538     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1539     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1540     precache_sound ("misc/null.wav");
1541     precache_sound ("misc/spawn.wav");
1542     precache_sound ("misc/talk.wav");
1543     precache_sound ("misc/teleport.wav");
1544     precache_sound ("misc/poweroff.wav");
1545     precache_sound ("player/lava.wav");
1546     precache_sound ("player/slime.wav");
1547
1548     if (g_jetpack)
1549         precache_sound ("misc/jetpack_fly.wav");
1550
1551     precache_model ("models/sprites/0.spr32");
1552     precache_model ("models/sprites/1.spr32");
1553     precache_model ("models/sprites/2.spr32");
1554     precache_model ("models/sprites/3.spr32");
1555     precache_model ("models/sprites/4.spr32");
1556     precache_model ("models/sprites/5.spr32");
1557     precache_model ("models/sprites/6.spr32");
1558     precache_model ("models/sprites/7.spr32");
1559     precache_model ("models/sprites/8.spr32");
1560     precache_model ("models/sprites/9.spr32");
1561     precache_model ("models/sprites/10.spr32");
1562
1563     // common weapon precaches
1564         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1565     precache_sound ("weapons/weapon_switch.wav");
1566     precache_sound ("weapons/weaponpickup.wav");
1567     precache_sound ("weapons/unavailable.wav");
1568     precache_sound ("weapons/dryfire.wav");
1569     if (g_grappling_hook)
1570     {
1571         precache_sound ("weapons/hook_fire.wav"); // hook
1572         precache_sound ("weapons/hook_impact.wav"); // hook
1573     }
1574
1575     if(autocvar_sv_precacheweapons)
1576     {
1577         //precache weapon models/sounds
1578         float wep;
1579         wep = WEP_FIRST;
1580         while (wep <= WEP_LAST)
1581         {
1582             weapon_action(wep, WR_PRECACHE);
1583             wep = wep + 1;
1584         }
1585     }
1586
1587     precache_model("models/elaser.mdl");
1588     precache_model("models/laser.mdl");
1589     precache_model("models/ebomb.mdl");
1590
1591 #if 0
1592     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1593
1594     if (!self.noise && self.music) // quake 3 uses the music field
1595         self.noise = self.music;
1596
1597     // plays music for the level if there is any
1598     if (self.noise)
1599     {
1600         precache_sound (self.noise);
1601         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1602     }
1603 #endif
1604 }
1605
1606 // sorry, but using \ in macros breaks line numbers
1607 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1608 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1609 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1610
1611
1612 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1613 {
1614         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
1615         {
1616                 msg_entity = e;
1617                 WRITESPECTATABLE_MSG_ONE({
1618                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1619                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1620                         WriteByte(MSG_ONE, id);
1621                         WriteString(MSG_ONE, s);
1622                         if (id != 0 && s != "")
1623                         {
1624                                 WriteByte(MSG_ONE, duration);
1625                                 WriteByte(MSG_ONE, countdown_num);
1626                         }
1627                 });
1628         }
1629 }
1630 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1631 {
1632         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1633 }
1634 // WARNING: this kills the trace globals
1635 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1636 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1637
1638 #define INITPRIO_FIRST              0
1639 #define INITPRIO_GAMETYPE           0
1640 #define INITPRIO_GAMETYPE_FALLBACK  1
1641 #define INITPRIO_FINDTARGET        10
1642 #define INITPRIO_DROPTOFLOOR       20
1643 #define INITPRIO_SETLOCATION       90
1644 #define INITPRIO_LINKDOORS         91
1645 #define INITPRIO_LAST              99
1646
1647 .void(void) initialize_entity;
1648 .float initialize_entity_order;
1649 .entity initialize_entity_next;
1650 entity initialize_entity_first;
1651
1652 void make_safe_for_remove(entity e)
1653 {
1654     if (e.initialize_entity)
1655     {
1656         entity ent, prev;
1657         for (ent = initialize_entity_first; ent; )
1658         {
1659             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1660             {
1661                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1662                 // skip it in linked list
1663                 if (prev)
1664                 {
1665                     prev.initialize_entity_next = ent.initialize_entity_next;
1666                     ent = prev.initialize_entity_next;
1667                 }
1668                 else
1669                 {
1670                     initialize_entity_first = ent.initialize_entity_next;
1671                     ent = initialize_entity_first;
1672                 }
1673             }
1674             else
1675             {
1676                 prev = ent;
1677                 ent = ent.initialize_entity_next;
1678             }
1679         }
1680     }
1681 }
1682
1683 void objerror(string s)
1684 {
1685     make_safe_for_remove(self);
1686     builtin_objerror(s);
1687 }
1688
1689 .float remove_except_protected_forbidden;
1690 void remove_except_protected(entity e)
1691 {
1692         if(e.remove_except_protected_forbidden)
1693                 error("not allowed to remove this at this point");
1694         builtin_remove(e);
1695 }
1696
1697 void remove_unsafely(entity e)
1698 {
1699     if(e.classname == "spike")
1700         error("Removing spikes is forbidden (crylink bug), please report");
1701     builtin_remove(e);
1702 }
1703
1704 void remove_safely(entity e)
1705 {
1706     make_safe_for_remove(e);
1707     builtin_remove(e);
1708 }
1709
1710 void InitializeEntity(entity e, void(void) func, float order)
1711 {
1712     entity prev, cur;
1713
1714     if (!e || e.initialize_entity)
1715     {
1716         // make a proxy initializer entity
1717         entity e_old;
1718         e_old = e;
1719         e = spawn();
1720         e.classname = "initialize_entity";
1721         e.enemy = e_old;
1722     }
1723
1724     e.initialize_entity = func;
1725     e.initialize_entity_order = order;
1726
1727     cur = initialize_entity_first;
1728     for (;;)
1729     {
1730         if (!cur || cur.initialize_entity_order > order)
1731         {
1732             // insert between prev and cur
1733             if (prev)
1734                 prev.initialize_entity_next = e;
1735             else
1736                 initialize_entity_first = e;
1737             e.initialize_entity_next = cur;
1738             return;
1739         }
1740         prev = cur;
1741         cur = cur.initialize_entity_next;
1742     }
1743 }
1744 void InitializeEntitiesRun()
1745 {
1746     entity startoflist;
1747     startoflist = initialize_entity_first;
1748     initialize_entity_first = world;
1749     remove = remove_except_protected;
1750     for (self = startoflist; self; self = self.initialize_entity_next)
1751     {
1752         self.remove_except_protected_forbidden = 1;
1753     }
1754     for (self = startoflist; self; )
1755     {
1756         entity e;
1757         var void(void) func;
1758         e = self.initialize_entity_next;
1759         func = self.initialize_entity;
1760         self.initialize_entity_order = 0;
1761         self.initialize_entity = func_null;
1762         self.initialize_entity_next = world;
1763         self.remove_except_protected_forbidden = 0;
1764         if (self.classname == "initialize_entity")
1765         {
1766             entity e_old;
1767             e_old = self.enemy;
1768             builtin_remove(self);
1769             self = e_old;
1770         }
1771         //dprint("Delayed initialization: ", self.classname, "\n");
1772         if(func != func_null)
1773             func();
1774         else
1775         {
1776             eprint(self);
1777             backtrace(strcat("Null function in: ", self.classname, "\n"));
1778         }
1779         self = e;
1780     }
1781     remove = remove_unsafely;
1782 }
1783
1784 .float uncustomizeentityforclient_set;
1785 .void(void) uncustomizeentityforclient;
1786 void(void) SUB_Nullpointer = #0;
1787 void UncustomizeEntitiesRun()
1788 {
1789     entity oldself;
1790     oldself = self;
1791     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1792         self.uncustomizeentityforclient();
1793     self = oldself;
1794 }
1795 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1796 {
1797     e.customizeentityforclient = customizer;
1798     e.uncustomizeentityforclient = uncustomizer;
1799     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1800 }
1801
1802 .float nottargeted;
1803 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1804
1805 void() SUB_Remove;
1806 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1807 {
1808     vector mi, ma;
1809
1810     if (e.classname == "")
1811         e.classname = "net_linked";
1812
1813     if (e.model == "" || self.modelindex == 0)
1814     {
1815         mi = e.mins;
1816         ma = e.maxs;
1817         setmodel(e, "null");
1818         setsize(e, mi, ma);
1819     }
1820
1821     e.SendEntity = sendfunc;
1822     e.SendFlags = 0xFFFFFF;
1823
1824     if (!docull)
1825         e.effects |= EF_NODEPTHTEST;
1826
1827     if (dt)
1828     {
1829         e.nextthink = time + dt;
1830         e.think = SUB_Remove;
1831     }
1832 }
1833
1834 void adaptor_think2touch()
1835 {
1836     entity o;
1837     o = other;
1838     other = world;
1839     self.touch();
1840     other = o;
1841 }
1842
1843 void adaptor_think2use()
1844 {
1845     entity o, a;
1846     o = other;
1847     a = activator;
1848     activator = world;
1849     other = world;
1850     self.use();
1851     other = o;
1852     activator = a;
1853 }
1854
1855 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1856 {
1857         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1858                 self.projectiledeathtype |= HITTYPE_SPLASH;
1859         adaptor_think2use();
1860 }
1861
1862 // deferred dropping
1863 void DropToFloor_Handler()
1864 {
1865     builtin_droptofloor();
1866     self.dropped_origin = self.origin;
1867 }
1868
1869 void droptofloor()
1870 {
1871     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1872 }
1873
1874
1875
1876 float trace_hits_box_a0, trace_hits_box_a1;
1877
1878 float trace_hits_box_1d(float end, float thmi, float thma)
1879 {
1880     if (end == 0)
1881     {
1882         // just check if x is in range
1883         if (0 < thmi)
1884             return FALSE;
1885         if (0 > thma)
1886             return FALSE;
1887     }
1888     else
1889     {
1890         // do the trace with respect to x
1891         // 0 -> end has to stay in thmi -> thma
1892         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1893         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1894         if (trace_hits_box_a0 > trace_hits_box_a1)
1895             return FALSE;
1896     }
1897     return TRUE;
1898 }
1899
1900 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1901 {
1902     end -= start;
1903     thmi -= start;
1904     thma -= start;
1905     // now it is a trace from 0 to end
1906
1907     trace_hits_box_a0 = 0;
1908     trace_hits_box_a1 = 1;
1909
1910     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1911         return FALSE;
1912     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1913         return FALSE;
1914     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1915         return FALSE;
1916
1917     return TRUE;
1918 }
1919
1920 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1921 {
1922     return trace_hits_box(start, end, thmi - ma, thma - mi);
1923 }
1924
1925 float SUB_NoImpactCheck()
1926 {
1927         // zero hitcontents = this is not the real impact, but either the
1928         // mirror-impact of something hitting the projectile instead of the
1929         // projectile hitting the something, or a touchareagrid one. Neither of
1930         // these stop the projectile from moving, so...
1931         if(trace_dphitcontents == 0)
1932         {
1933                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1934                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1935                 checkclient();
1936         }
1937     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1938         return 1;
1939     if (other == world && self.size != '0 0 0')
1940     {
1941         vector tic;
1942         tic = self.velocity * sys_frametime;
1943         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1944         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1945         if (trace_fraction >= 1)
1946         {
1947             dprint("Odd... did not hit...?\n");
1948         }
1949         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1950         {
1951             dprint("Detected and prevented the sky-grapple bug.\n");
1952             return 1;
1953         }
1954     }
1955
1956     return 0;
1957 }
1958
1959 #define SUB_OwnerCheck() (other && (other == self.owner))
1960
1961 void RemoveGrapplingHook(entity pl);
1962 void W_Crylink_Dequeue(entity e);
1963 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1964 {
1965         if(SUB_OwnerCheck())
1966                 return TRUE;
1967         if(SUB_NoImpactCheck())
1968         {
1969                 if(self.classname == "grapplinghook")
1970                         RemoveGrapplingHook(self.realowner);
1971                 else if(self.classname == "spike")
1972                 {
1973                         W_Crylink_Dequeue(self);
1974                         remove(self);
1975                 }
1976                 else
1977                         remove(self);
1978                 return TRUE;
1979         }
1980         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1981                 UpdateCSQCProjectile(self);
1982         return FALSE;
1983 }
1984 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1985
1986 void URI_Get_Callback(float id, float status, string data)
1987 {
1988         if(url_URI_Get_Callback(id, status, data))
1989         {
1990                 // handled
1991         }
1992         else if (id == URI_GET_DISCARD)
1993         {
1994                 // discard
1995         }
1996         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1997         {
1998                 // sv_cmd curl
1999                 Curl_URI_Get_Callback(id, status, data);
2000         }
2001         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2002         {
2003                 // online ban list
2004                 OnlineBanList_URI_Get_Callback(id, status, data);
2005         }
2006         else
2007         {
2008                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2009         }
2010 }
2011
2012 string uid2name(string myuid) {
2013         string s;
2014         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2015
2016         // FIXME remove this later after 0.6 release
2017         // convert old style broken records to correct style
2018         if(s == "")
2019         {
2020                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2021                 if(s != "")
2022                 {
2023                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2024                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2025                 }
2026         }
2027
2028         if(s == "")
2029                 s = "^1Unregistered Player";
2030         return s;
2031 }
2032
2033 float race_readTime(string map, float pos)
2034 {
2035         string rr;
2036         if(g_cts)
2037                 rr = CTS_RECORD;
2038         else
2039                 rr = RACE_RECORD;
2040
2041         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2042 }
2043
2044 string race_readUID(string map, float pos)
2045 {
2046         string rr;
2047         if(g_cts)
2048                 rr = CTS_RECORD;
2049         else
2050                 rr = RACE_RECORD;
2051
2052         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2053 }
2054
2055 float race_readPos(string map, float t) {
2056         float i;
2057         for (i = 1; i <= RANKINGS_CNT; ++i)
2058                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2059                         return i;
2060
2061         return 0; // pos is zero if unranked
2062 }
2063
2064 void race_writeTime(string map, float t, string myuid)
2065 {
2066         string rr;
2067         if(g_cts)
2068                 rr = CTS_RECORD;
2069         else
2070                 rr = RACE_RECORD;
2071
2072         float newpos;
2073         newpos = race_readPos(map, t);
2074
2075         float i, prevpos;
2076         for(i = 1; i <= RANKINGS_CNT; ++i)
2077         {
2078                 if(race_readUID(map, i) == myuid)
2079                         prevpos = i;
2080         }
2081         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2082                 for (i = prevpos; i > newpos; --i) {
2083                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2084                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2085                 }
2086         } else { // player has no ranked record yet
2087                 for (i = RANKINGS_CNT; i > newpos; --i) {
2088                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2089                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2090                 }
2091         }
2092
2093         // store new time itself
2094         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2095         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2096 }
2097
2098 string race_readName(string map, float pos)
2099 {
2100         string rr;
2101         if(g_cts)
2102                 rr = CTS_RECORD;
2103         else
2104                 rr = RACE_RECORD;
2105
2106         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2107 }
2108
2109 string race_placeName(float pos) {
2110         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2111         {
2112                 if(mod(pos, 10) == 1)
2113                         return strcat(ftos(pos), "st");
2114                 else if(mod(pos, 10) == 2)
2115                         return strcat(ftos(pos), "nd");
2116                 else if(mod(pos, 10) == 3)
2117                         return strcat(ftos(pos), "rd");
2118                 else
2119                         return strcat(ftos(pos), "th");
2120         }
2121         else
2122                 return strcat(ftos(pos), "th");
2123 }
2124
2125 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2126 {
2127     float m, i;
2128     vector start, org, delta, end, enddown, mstart;
2129     entity sp;
2130
2131     m = e.dphitcontentsmask;
2132     e.dphitcontentsmask = goodcontents | badcontents;
2133
2134     org = world.mins;
2135     delta = world.maxs - world.mins;
2136
2137     for (i = 0; i < attempts; ++i)
2138     {
2139         start_x = org_x + random() * delta_x;
2140         start_y = org_y + random() * delta_y;
2141         start_z = org_z + random() * delta_z;
2142
2143         // rule 1: start inside world bounds, and outside
2144         // solid, and don't start from somewhere where you can
2145         // fall down to evil
2146         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2147         if (trace_fraction >= 1)
2148             continue;
2149         if (trace_startsolid)
2150             continue;
2151         if (trace_dphitcontents & badcontents)
2152             continue;
2153         if (trace_dphitq3surfaceflags & badsurfaceflags)
2154             continue;
2155
2156         // rule 2: if we are too high, lower the point
2157         if (trace_fraction * delta_z > maxaboveground)
2158             start = trace_endpos + '0 0 1' * maxaboveground;
2159         enddown = trace_endpos;
2160
2161         // rule 3: make sure we aren't outside the map. This only works
2162         // for somewhat well formed maps. A good rule of thumb is that
2163         // the map should have a convex outside hull.
2164         // these can be traceLINES as we already verified the starting box
2165         mstart = start + 0.5 * (e.mins + e.maxs);
2166         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2167         if (trace_fraction >= 1)
2168             continue;
2169         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2170         if (trace_fraction >= 1)
2171             continue;
2172         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2173         if (trace_fraction >= 1)
2174             continue;
2175         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2176         if (trace_fraction >= 1)
2177             continue;
2178         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2179         if (trace_fraction >= 1)
2180             continue;
2181
2182         // rule 4: we must "see" some spawnpoint
2183         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2184                 if(checkpvs(mstart, sp))
2185                         break;
2186         if(!sp)
2187         {
2188                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2189                         if(checkpvs(mstart, sp))
2190                                 break;
2191                 if(!sp)
2192                         continue;
2193         }
2194
2195         // find a random vector to "look at"
2196         end_x = org_x + random() * delta_x;
2197         end_y = org_y + random() * delta_y;
2198         end_z = org_z + random() * delta_z;
2199         end = start + normalize(end - start) * vlen(delta);
2200
2201         // rule 4: start TO end must not be too short
2202         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2203         if (trace_startsolid)
2204             continue;
2205         if (trace_fraction < minviewdistance / vlen(delta))
2206             continue;
2207
2208         // rule 5: don't want to look at sky
2209         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2210             continue;
2211
2212         // rule 6: we must not end up in trigger_hurt
2213         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2214             continue;
2215
2216         break;
2217     }
2218
2219     e.dphitcontentsmask = m;
2220
2221     if (i < attempts)
2222     {
2223         setorigin(e, start);
2224         e.angles = vectoangles(end - start);
2225         dprint("Needed ", ftos(i + 1), " attempts\n");
2226         return TRUE;
2227     }
2228     else
2229         return FALSE;
2230 }
2231
2232 float zcurveparticles_effectno;
2233 vector zcurveparticles_start;
2234 float zcurveparticles_spd;
2235
2236 void endzcurveparticles()
2237 {
2238         if(zcurveparticles_effectno)
2239         {
2240                 // terminator
2241                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2242         }
2243         zcurveparticles_effectno = 0;
2244 }
2245
2246 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2247 {
2248         spd = bound(0, floor(spd / 16), 32767);
2249         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2250         {
2251                 endzcurveparticles();
2252                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2253                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2254                 WriteShort(MSG_BROADCAST, effectno);
2255                 WriteCoord(MSG_BROADCAST, start_x);
2256                 WriteCoord(MSG_BROADCAST, start_y);
2257                 WriteCoord(MSG_BROADCAST, start_z);
2258                 zcurveparticles_effectno = effectno;
2259                 zcurveparticles_start = start;
2260         }
2261         else
2262                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2263         WriteCoord(MSG_BROADCAST, end_x);
2264         WriteCoord(MSG_BROADCAST, end_y);
2265         WriteCoord(MSG_BROADCAST, end_z);
2266         WriteCoord(MSG_BROADCAST, end_dz);
2267         zcurveparticles_spd = spd;
2268 }
2269
2270 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2271 {
2272         float end_dz;
2273         vector vecxy, velxy;
2274
2275         vecxy = end - start;
2276         vecxy_z = 0;
2277         velxy = vel;
2278         velxy_z = 0;
2279
2280         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2281         {
2282                 endzcurveparticles();
2283                 trailparticles(world, effectno, start, end);
2284                 return;
2285         }
2286
2287         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2288         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2289 }
2290
2291 void write_recordmarker(entity pl, float tstart, float dt)
2292 {
2293     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2294
2295     // also write a marker into demo files for demotc-race-record-extractor to find
2296     stuffcmd(pl,
2297              strcat(
2298                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2299                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2300 }
2301
2302 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2303 {
2304         switch(algn)
2305         {
2306                 default:
2307                 case 3: // right
2308                         break;
2309
2310                 case 4: // left
2311                         vecs_y = -vecs_y;
2312                         break;
2313
2314                 case 1:
2315                         if(allowcenter) // 2: allow center handedness
2316                         {
2317                                 // center
2318                                 vecs_y = 0;
2319                                 vecs_z -= 2;
2320                         }
2321                         else
2322                         {
2323                                 // right
2324                         }
2325                         break;
2326
2327                 case 2:
2328                         if(allowcenter) // 2: allow center handedness
2329                         {
2330                                 // center
2331                                 vecs_y = 0;
2332                                 vecs_z -= 2;
2333                         }
2334                         else
2335                         {
2336                                 // left
2337                                 vecs_y = -vecs_y;
2338                         }
2339                         break;
2340         }
2341         return vecs;
2342 }
2343
2344 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2345 {
2346         string s;
2347         vector v;
2348
2349         if (autocvar_g_shootfromeye)
2350         {
2351                 if (visual)
2352                 {
2353                         vecs_y = 0;
2354                         vecs_z -= 2;
2355                 }
2356                 else
2357                 {
2358                         vecs_y = 0;
2359                         vecs_z = 0;
2360                 }
2361         }
2362         else if (autocvar_g_shootfromcenter)
2363         {
2364                 vecs_y = 0;
2365                 vecs_z -= 2;
2366         }
2367         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2368         {
2369                 v = stov(s);
2370                 if (y_is_right)
2371                         v_y = -v_y;
2372                 if (v_x != 0)
2373                         vecs_x = v_x;
2374                 vecs_y = v_y;
2375                 vecs_z = v_z;
2376         }
2377         else if (autocvar_g_shootfromclient)
2378         {
2379                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2380         }
2381         return vecs;
2382 }
2383
2384 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2385 {
2386         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2387 }
2388
2389
2390 void attach_sameorigin(entity e, entity to, string tag)
2391 {
2392     vector org, t_forward, t_left, t_up, e_forward, e_up;
2393     vector org0, ang0;
2394     float tagscale;
2395
2396     ang0 = e.angles;
2397     org0 = e.origin;
2398
2399     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2400     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2401     t_forward = v_forward * tagscale;
2402     t_left = v_right * -tagscale;
2403     t_up = v_up * tagscale;
2404
2405     e.origin_x = org * t_forward;
2406     e.origin_y = org * t_left;
2407     e.origin_z = org * t_up;
2408
2409     // current forward and up directions
2410     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2411                 e.angles = AnglesTransform_FromVAngles(e.angles);
2412         else
2413                 e.angles = AnglesTransform_FromAngles(e.angles);
2414     fixedmakevectors(e.angles);
2415
2416     // untransform forward, up!
2417     e_forward_x = v_forward * t_forward;
2418     e_forward_y = v_forward * t_left;
2419     e_forward_z = v_forward * t_up;
2420     e_up_x = v_up * t_forward;
2421     e_up_y = v_up * t_left;
2422     e_up_z = v_up * t_up;
2423
2424     e.angles = fixedvectoangles2(e_forward, e_up);
2425     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2426                 e.angles = AnglesTransform_ToVAngles(e.angles);
2427         else
2428                 e.angles = AnglesTransform_ToAngles(e.angles);
2429
2430     setattachment(e, to, tag);
2431     setorigin(e, e.origin);
2432 }
2433
2434 void detach_sameorigin(entity e)
2435 {
2436     vector org;
2437     org = gettaginfo(e, 0);
2438     e.angles = fixedvectoangles2(v_forward, v_up);
2439     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2440                 e.angles = AnglesTransform_ToVAngles(e.angles);
2441         else
2442                 e.angles = AnglesTransform_ToAngles(e.angles);
2443     setorigin(e, org);
2444     setattachment(e, world, "");
2445     setorigin(e, e.origin);
2446 }
2447
2448 void follow_sameorigin(entity e, entity to)
2449 {
2450     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2451     e.aiment = to; // make the hole follow bmodel
2452     e.punchangle = to.angles; // the original angles of bmodel
2453     e.view_ofs = e.origin - to.origin; // relative origin
2454     e.v_angle = e.angles - to.angles; // relative angles
2455 }
2456
2457 void unfollow_sameorigin(entity e)
2458 {
2459     e.movetype = MOVETYPE_NONE;
2460 }
2461
2462 entity gettaginfo_relative_ent;
2463 vector gettaginfo_relative(entity e, float tag)
2464 {
2465     if (!gettaginfo_relative_ent)
2466     {
2467         gettaginfo_relative_ent = spawn();
2468         gettaginfo_relative_ent.effects = EF_NODRAW;
2469     }
2470     gettaginfo_relative_ent.model = e.model;
2471     gettaginfo_relative_ent.modelindex = e.modelindex;
2472     gettaginfo_relative_ent.frame = e.frame;
2473     return gettaginfo(gettaginfo_relative_ent, tag);
2474 }
2475
2476 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2477 {
2478     float p;
2479     p = pow(2, chan);
2480     if (pl.soundentity.cnt & p)
2481         return;
2482     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2483     pl.soundentity.cnt |= p;
2484 }
2485
2486 void SoundEntity_StopSound(entity pl, float chan)
2487 {
2488     float p;
2489     p = pow(2, chan);
2490     if (pl.soundentity.cnt & p)
2491     {
2492         stopsoundto(MSG_ALL, pl.soundentity, chan);
2493         pl.soundentity.cnt &~= p;
2494     }
2495 }
2496
2497 void SoundEntity_Attach(entity pl)
2498 {
2499     pl.soundentity = spawn();
2500     pl.soundentity.classname = "soundentity";
2501     pl.soundentity.owner = pl;
2502     setattachment(pl.soundentity, pl, "");
2503     setmodel(pl.soundentity, "null");
2504 }
2505
2506 void SoundEntity_Detach(entity pl)
2507 {
2508     float i;
2509     for (i = 0; i <= 7; ++i)
2510         SoundEntity_StopSound(pl, i);
2511 }
2512
2513 .float scale2;
2514
2515 float modeleffect_SendEntity(entity to, float sf)
2516 {
2517         float f;
2518         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2519
2520         f = 0;
2521         if(self.velocity != '0 0 0')
2522                 f |= 1;
2523         if(self.angles != '0 0 0')
2524                 f |= 2;
2525         if(self.avelocity != '0 0 0')
2526                 f |= 4;
2527
2528         WriteByte(MSG_ENTITY, f);
2529         WriteShort(MSG_ENTITY, self.modelindex);
2530         WriteByte(MSG_ENTITY, self.skin);
2531         WriteByte(MSG_ENTITY, self.frame);
2532         WriteCoord(MSG_ENTITY, self.origin_x);
2533         WriteCoord(MSG_ENTITY, self.origin_y);
2534         WriteCoord(MSG_ENTITY, self.origin_z);
2535         if(f & 1)
2536         {
2537                 WriteCoord(MSG_ENTITY, self.velocity_x);
2538                 WriteCoord(MSG_ENTITY, self.velocity_y);
2539                 WriteCoord(MSG_ENTITY, self.velocity_z);
2540         }
2541         if(f & 2)
2542         {
2543                 WriteCoord(MSG_ENTITY, self.angles_x);
2544                 WriteCoord(MSG_ENTITY, self.angles_y);
2545                 WriteCoord(MSG_ENTITY, self.angles_z);
2546         }
2547         if(f & 4)
2548         {
2549                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2550                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2551                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2552         }
2553         WriteShort(MSG_ENTITY, self.scale * 256.0);
2554         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2555         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2556         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2557         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2558
2559         return TRUE;
2560 }
2561
2562 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2563 {
2564         entity e;
2565         float sz;
2566         e = spawn();
2567         e.classname = "modeleffect";
2568         setmodel(e, m);
2569         e.frame = f;
2570         setorigin(e, o);
2571         e.velocity = v;
2572         e.angles = ang;
2573         e.avelocity = angv;
2574         e.alpha = a;
2575         e.teleport_time = t1;
2576         e.fade_time = t2;
2577         e.skin = s;
2578         if(s0 >= 0)
2579                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2580         else
2581                 e.scale = -s0;
2582         if(s2 >= 0)
2583                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2584         else
2585                 e.scale2 = -s2;
2586         sz = max(e.scale, e.scale2);
2587         setsize(e, e.mins * sz, e.maxs * sz);
2588         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2589 }
2590
2591 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2592 {
2593         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2594 }
2595
2596 float randombit(float bits)
2597 {
2598         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2599                 return bits;
2600
2601         float n, f, b, r;
2602
2603         r = random();
2604         b = 0;
2605         n = 0;
2606
2607         for(f = 1; f <= bits; f *= 2)
2608         {
2609                 if(bits & f)
2610                 {
2611                         ++n;
2612                         r *= n;
2613                         if(r <= 1)
2614                                 b = f;
2615                         else
2616                                 r = (r - 1) / (n - 1);
2617                 }
2618         }
2619
2620         return b;
2621 }
2622
2623 float randombits(float bits, float k, float error_return)
2624 {
2625         float r;
2626         r = 0;
2627         while(k > 0 && bits != r)
2628         {
2629                 r += randombit(bits - r);
2630                 --k;
2631         }
2632         if(error_return)
2633                 if(k > 0)
2634                         return -1; // all
2635         return r;
2636 }
2637
2638 void randombit_test(float bits, float iter)
2639 {
2640         while(iter > 0)
2641         {
2642                 print(ftos(randombit(bits)), "\n");
2643                 --iter;
2644         }
2645 }
2646
2647 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2648 {
2649         if(halflifedist > 0)
2650                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2651         else if(halflifedist < 0)
2652                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2653         else
2654                 return 1;
2655 }
2656
2657
2658
2659
2660 #ifdef RELEASE
2661 #define cvar_string_normal builtin_cvar_string
2662 #define cvar_normal builtin_cvar
2663 #else
2664 string cvar_string_normal(string n)
2665 {
2666         if not(cvar_type(n) & 1)
2667                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2668         return builtin_cvar_string(n);
2669 }
2670
2671 float cvar_normal(string n)
2672 {
2673         return stof(cvar_string_normal(n));
2674 }
2675 #endif
2676 #define cvar_set_normal builtin_cvar_set
2677
2678 void defer_think()
2679 {
2680     entity oself;
2681
2682     oself           = self;
2683     self            = self.owner;
2684     oself.think     = SUB_Remove;
2685     oself.nextthink = time;
2686
2687     oself.use();
2688 }
2689
2690 /*
2691     Execute func() after time + fdelay.
2692     self when func is executed = self when defer is called
2693 */
2694 void defer(float fdelay, void() func)
2695 {
2696     entity e;
2697
2698     e           = spawn();
2699     e.owner     = self;
2700     e.use       = func;
2701     e.think     = defer_think;
2702     e.nextthink = time + fdelay;
2703 }
2704
2705 .string aiment_classname;
2706 .float aiment_deadflag;
2707 void SetMovetypeFollow(entity ent, entity e)
2708 {
2709         // FIXME this may not be warpzone aware
2710         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2711         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2712         ent.aiment = e; // make the hole follow bmodel
2713         ent.punchangle = e.angles; // the original angles of bmodel
2714         ent.view_ofs = ent.origin - e.origin; // relative origin
2715         ent.v_angle = ent.angles - e.angles; // relative angles
2716         ent.aiment_classname = strzone(e.classname);
2717         ent.aiment_deadflag = e.deadflag;
2718 }
2719 void UnsetMovetypeFollow(entity ent)
2720 {
2721         ent.movetype = MOVETYPE_FLY;
2722         PROJECTILE_MAKETRIGGER(ent);
2723         ent.aiment = world;
2724 }
2725 float LostMovetypeFollow(entity ent)
2726 {
2727 /*
2728         if(ent.movetype != MOVETYPE_FOLLOW)
2729                 if(ent.aiment)
2730                         error("???");
2731 */
2732         if(ent.aiment)
2733         {
2734                 if(ent.aiment.classname != ent.aiment_classname)
2735                         return 1;
2736                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2737                         return 1;
2738         }
2739         return 0;
2740 }
2741
2742 float isPushable(entity e)
2743 {
2744         if(e.iscreature)
2745                 return TRUE;
2746         switch(e.classname)
2747         {
2748                 case "body":
2749                 case "droppedweapon":
2750                 case "keepawayball":
2751                 case "nexball_basketball":
2752                 case "nexball_football":
2753                         return TRUE;
2754                 case "bullet": // antilagged bullets can't hit this either
2755                         return FALSE;
2756         }
2757         if (e.projectiledeathtype)
2758                 return TRUE;
2759         return FALSE;
2760 }