qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2 #include "antilag.qh"
   3 #include "command/common.qh"
   4 #include "constants.qh"
   5 #include "g_hook.qh"
   6 #include "ipban.qh"
   7 #include "mutators/all.qh"
   8 #include "t_items.qh"
   9 #include "weapons/accuracy.qh"
  10 #include "weapons/csqcprojectile.qh"
  11 #include "weapons/selection.qh"
  12 #include "../common/command/generic.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/deathtypes/all.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/notifications.qh"
  17 #include "../common/playerstats.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/triggers/subs.qh"
  20 #include "../common/util.qh"
  21 #include "../common/turrets/sv_turrets.qh"
  22 #include "../common/weapons/all.qh"
  23 #include "../common/vehicles/sv_vehicles.qh"
  24 #include "../common/vehicles/vehicle.qh"
  25 #include "../common/items/all.qc"
  26 #include "../lib/csqcmodel/sv_model.qh"
  27 #include "../lib/warpzone/anglestransform.qh"
  28 #include "../lib/warpzone/server.qh"
  29
  30 void crosshair_trace(entity pl)
  31 {
  32         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  33 }
  34 void crosshair_trace_plusvisibletriggers(entity pl)
  35 {
  36         entity first;
  37         entity e;
  38         first = findchainfloat(solid, SOLID_TRIGGER);
  39
  40         for (e = first; e; e = e.chain)
  41                 if (e.model != "")
  42                         e.solid = SOLID_BSP;
  43
  44         crosshair_trace(pl);
  45
  46         for (e = first; e; e = e.chain)
  47                 e.solid = SOLID_TRIGGER;
  48 }
  49 void WarpZone_crosshair_trace(entity pl)
  50 {
  51         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  52 }
  53
  54
  55 string admin_name()
  56 {
  57         if(autocvar_sv_adminnick != "")
  58                 return autocvar_sv_adminnick;
  59         else
  60                 return "SERVER ADMIN";
  61 }
  62
  63
  64 void GameLogEcho(string s)
  65 {
  66     string fn;
  67     int matches;
  68
  69     if (autocvar_sv_eventlog_files)
  70     {
  71         if (!logfile_open)
  72         {
  73             logfile_open = true;
  74             matches = autocvar_sv_eventlog_files_counter + 1;
  75             cvar_set("sv_eventlog_files_counter", itos(matches));
  76             fn = ftos(matches);
  77             if (strlen(fn) < 8)
  78                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  79             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  80             logfile = fopen(fn, FILE_APPEND);
  81             fputs(logfile, ":logversion:3\n");
  82         }
  83         if (logfile >= 0)
  84         {
  85             if (autocvar_sv_eventlog_files_timestamps)
  86                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  87             else
  88                 fputs(logfile, strcat(s, "\n"));
  89         }
  90     }
  91     if (autocvar_sv_eventlog_console)
  92     {
  93         LOG_INFO(s, "\n");
  94     }
  95 }
  96
  97 void GameLogInit()
  98 {
  99     logfile_open = 0;
 100     // will be opened later
 101 }
 102
 103 void GameLogClose()
 104 {
 105     if (logfile_open && logfile >= 0)
 106     {
 107         fclose(logfile);
 108         logfile = -1;
 109     }
 110 }
 111
 112 entity findnearest(vector point, .string field, string value, vector axismod)
 113 {
 114     entity localhead;
 115     float i;
 116     float j;
 117     float len;
 118     vector dist;
 119
 120     float num_nearest;
 121     num_nearest = 0;
 122
 123     localhead = find(world, field, value);
 124     while (localhead)
 125     {
 126         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 127             dist = localhead.oldorigin;
 128         else
 129             dist = localhead.origin;
 130         dist = dist - point;
 131         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 132         len = vlen(dist);
 133
 134         for (i = 0; i < num_nearest; ++i)
 135         {
 136             if (len < nearest_length[i])
 137                 break;
 138         }
 139
 140         // now i tells us where to insert at
 141         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 142         if (i < NUM_NEAREST_ENTITIES)
 143         {
 144             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 145             {
 146                 nearest_length[j + 1] = nearest_length[j];
 147                 nearest_entity[j + 1] = nearest_entity[j];
 148             }
 149             nearest_length[i] = len;
 150             nearest_entity[i] = localhead;
 151             if (num_nearest < NUM_NEAREST_ENTITIES)
 152                 num_nearest = num_nearest + 1;
 153         }
 154
 155         localhead = find(localhead, field, value);
 156     }
 157
 158     // now use the first one from our list that we can see
 159     for (i = 0; i < num_nearest; ++i)
 160     {
 161         traceline(point, nearest_entity[i].origin, true, world);
 162         if (trace_fraction == 1)
 163         {
 164             if (i != 0)
 165             {
 166                 LOG_TRACE("Nearest point (");
 167                 LOG_TRACE(nearest_entity[0].netname);
 168                 LOG_TRACE(") is not visible, using a visible one.\n");
 169             }
 170             return nearest_entity[i];
 171         }
 172     }
 173
 174     if (num_nearest == 0)
 175         return world;
 176
 177     LOG_TRACE("Not seeing any location point, using nearest as fallback.\n");
 178     /* DEBUGGING CODE:
 179     dprint("Candidates were: ");
 180     for(j = 0; j < num_nearest; ++j)
 181     {
 182         if(j != 0)
 183                 dprint(", ");
 184         dprint(nearest_entity[j].netname);
 185     }
 186     dprint("\n");
 187     */
 188
 189     return nearest_entity[0];
 190 }
 191
 192 string NearestLocation(vector p)
 193 {
 194     entity loc;
 195     string ret;
 196     ret = "somewhere";
 197     loc = findnearest(p, classname, "target_location", '1 1 1');
 198     if (loc)
 199     {
 200         ret = loc.message;
 201     }
 202     else
 203     {
 204         loc = findnearest(p, target, "###item###", '1 1 4');
 205         if (loc)
 206             ret = loc.netname;
 207     }
 208     return ret;
 209 }
 210
 211 string formatmessage(string msg)
 212 {SELFPARAM();
 213         float p, p1, p2;
 214         float n;
 215         vector cursor;
 216         entity cursor_ent;
 217         string escape;
 218         string replacement;
 219         string ammoitems;
 220         p = 0;
 221         n = 7;
 222
 223         ammoitems = "batteries";
 224         if(self.items & ITEM_Plasma.m_itemid) ammoitems = ITEM_Plasma.m_name;
 225         if(self.items & ITEM_Cells.m_itemid) ammoitems = ITEM_Cells.m_name;
 226         if(self.items & ITEM_Rockets.m_itemid) ammoitems = ITEM_Rockets.m_name;
 227         if(self.items & ITEM_Shells.m_itemid) ammoitems = ITEM_Shells.m_name;
 228
 229         WarpZone_crosshair_trace(self);
 230         cursor = trace_endpos;
 231         cursor_ent = trace_ent;
 232
 233         while (1) {
 234                 if (n < 1)
 235                         break; // too many replacements
 236
 237                 n = n - 1;
 238                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 239                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 240
 241                 if (p1 < 0)
 242                         p1 = p2;
 243
 244                 if (p2 < 0)
 245                         p2 = p1;
 246
 247                 p = min(p1, p2);
 248
 249                 if (p < 0)
 250                         break;
 251
 252                 replacement = substring(msg, p, 2);
 253                 escape = substring(msg, p + 1, 1);
 254
 255                 switch(escape)
 256                 {
 257                         case "%": replacement = "%"; break;
 258                         case "\\":replacement = "\\"; break;
 259                         case "n": replacement = "\n"; break;
 260                         case "a": replacement = ftos(floor(self.armorvalue)); break;
 261                         case "h": replacement = ftos(floor(self.health)); break;
 262                         case "l": replacement = NearestLocation(self.origin); break;
 263                         case "y": replacement = NearestLocation(cursor); break;
 264                         case "d": replacement = NearestLocation(self.death_origin); break;
 265                         case "w": replacement = ((PS(self).m_weapon == WEP_Null) ? ((PS(self).m_switchweapon == WEP_Null) ? Weapons_from(self.cnt) : PS(self).m_switchweapon) : PS(self).m_weapon).m_name; break;
 266                         case "W": replacement = ammoitems; break;
 267                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 268                         case "s": replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1')); break;
 269                         case "S": replacement = ftos(vlen(self.velocity)); break;
 270                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 271                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 272                         default:
 273                         {
 274                                 MUTATOR_CALLHOOK(FormatMessage, escape, replacement, msg);
 275                                 escape = format_escape;
 276                                 replacement = format_replacement;
 277                                 break;
 278                         }
 279                 }
 280
 281                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 282                 p = p + strlen(replacement);
 283         }
 284         return msg;
 285 }
 286
 287 /*
 288 =============
 289 GetCvars
 290 =============
 291 Called with:
 292   0:  sends the request
 293   >0: receives a cvar from name=argv(f) value=argv(f+1)
 294 */
 295 void GetCvars_handleString(string thisname, float f, .string field, string name)
 296 {SELFPARAM();
 297         if (f < 0)
 298         {
 299                 if (self.(field))
 300                         strunzone(self.(field));
 301                 self.(field) = string_null;
 302         }
 303         else if (f > 0)
 304         {
 305                 if (thisname == name)
 306                 {
 307                         if (self.(field))
 308                                 strunzone(self.(field));
 309                         self.(field) = strzone(argv(f + 1));
 310                 }
 311         }
 312         else
 313                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 314 }
 315 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 316 {SELFPARAM();
 317         GetCvars_handleString(thisname, f, field, name);
 318         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 319                 if (thisname == name)
 320                 {
 321                         string s = func(strcat1(self.(field)));
 322                         if (s != self.(field))
 323                         {
 324                                 strunzone(self.(field));
 325                                 self.(field) = strzone(s);
 326                         }
 327                 }
 328 }
 329 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 330 {SELFPARAM();
 331         if (f < 0)
 332         {
 333         }
 334         else if (f > 0)
 335         {
 336                 if (thisname == name)
 337                         self.(field) = stof(argv(f + 1));
 338         }
 339         else
 340                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 341 }
 342 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 343 {SELFPARAM();
 344         if (f < 0)
 345         {
 346         }
 347         else if (f > 0)
 348         {
 349                 if (thisname == name)
 350                 {
 351                         if (!self.(field))
 352                         {
 353                                 self.(field) = stof(argv(f + 1));
 354                                 if (!self.(field))
 355                                         self.(field) = -1;
 356                         }
 357                 }
 358         }
 359         else
 360         {
 361                 if (!self.(field))
 362                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 363         }
 364 }
 365 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 366 {SELFPARAM();
 367         string o;
 368         o = W_FixWeaponOrder_ForceComplete(wo);
 369         if(self.weaponorder_byimpulse)
 370         {
 371                 strunzone(self.weaponorder_byimpulse);
 372                 self.weaponorder_byimpulse = string_null;
 373         }
 374         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 375         return o;
 376 }
 377
 378 /**
 379  * @param f -1: cleanup, 0: request, 1: receive
 380  */
 381 void GetCvars(int f)
 382 {SELFPARAM();
 383         string s = string_null;
 384
 385         if (f > 0)
 386                 s = strcat1(argv(f));
 387
 388         get_cvars_f = f;
 389         get_cvars_s = s;
 390         MUTATOR_CALLHOOK(GetCvars);
 391
 392         Notification_GetCvars();
 393
 394         ReplicateVars(this, s, f);
 395
 396         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 397         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 398         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 399         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 400         GetCvars_handleString(s, f, cvar_cl_physics, "cl_physics");
 401         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 402         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 403         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 404         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 405         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 406         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 407         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 408         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 409         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 410         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 411         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 412         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 413         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 414         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 415         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 416         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 417         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 418         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 419
 420         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 421         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 422         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 423         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 424
 425         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 426         if (f > 0)
 427         {
 428                 if (s == "cl_weaponpriority")
 429                         if (PS(self)) PS(self).m_switchweapon = w_getbestweapon(self);
 430                 if (s == "cl_allow_uidtracking")
 431                         PlayerStats_GameReport_AddPlayer(self);
 432         }
 433 }
 434
 435 // decolorizes and team colors the player name when needed
 436 string playername(entity p)
 437 {
 438     string t;
 439     if (teamplay && !intermission_running && IS_PLAYER(p))
 440     {
 441         t = Team_ColorCode(p.team);
 442         return strcat(t, strdecolorize(p.netname));
 443     }
 444     else
 445         return p.netname;
 446 }
 447
 448 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 449 {
 450         int i = weaponinfo.m_id;
 451         int d = 0;
 452         bool allow_mutatorblocked = false;
 453
 454         if(!i)
 455                 return 0;
 456
 457         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 458         d = ret_float;
 459         allguns = want_allguns;
 460         allow_mutatorblocked = false;
 461
 462         if(allguns)
 463         {
 464                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 465                         d = true;
 466                 else
 467                         d = false;
 468         }
 469         else if(!mutator_returnvalue)
 470                 d = !(!weaponinfo.weaponstart);
 471
 472         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 473                 d = 0;
 474
 475         float t = weaponinfo.weaponstartoverride;
 476
 477         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 478
 479         // bit order in t:
 480         // 1: want or not
 481         // 2: is default?
 482         // 4: is set by default?
 483         if(t < 0)
 484                 t = 4 | (3 * d);
 485         else
 486                 t |= (2 * d);
 487
 488         return t;
 489 }
 490
 491 void readplayerstartcvars()
 492 {
 493         entity e;
 494         float i, j, t;
 495         string s;
 496
 497         // initialize starting values for players
 498         start_weapons = '0 0 0';
 499         start_weapons_default = '0 0 0';
 500         start_weapons_defaultmask = '0 0 0';
 501         start_items = 0;
 502         start_ammo_shells = 0;
 503         start_ammo_nails = 0;
 504         start_ammo_rockets = 0;
 505         start_ammo_cells = 0;
 506         start_ammo_plasma = 0;
 507         start_health = cvar("g_balance_health_start");
 508         start_armorvalue = cvar("g_balance_armor_start");
 509
 510         g_weaponarena = 0;
 511         g_weaponarena_weapons = '0 0 0';
 512
 513         s = cvar_string("g_weaponarena");
 514
 515         MUTATOR_CALLHOOK(SetWeaponArena, s);
 516         s = ret_string;
 517
 518         if (s == "0" || s == "")
 519         {
 520                 // no arena
 521         }
 522         else if (s == "off")
 523         {
 524                 // forcibly turn off weaponarena
 525         }
 526         else if (s == "all" || s == "1")
 527         {
 528                 g_weaponarena = 1;
 529                 g_weaponarena_list = "All Weapons";
 530                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 531                 {
 532                         e = Weapons_from(j);
 533                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 534                                 g_weaponarena_weapons |= (e.m_wepset);
 535                 }
 536         }
 537         else if (s == "most")
 538         {
 539                 g_weaponarena = 1;
 540                 g_weaponarena_list = "Most Weapons";
 541                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 542                 {
 543                         e = Weapons_from(j);
 544                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 545                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 546                                         g_weaponarena_weapons |= (e.m_wepset);
 547                 }
 548         }
 549         else if (s == "none")
 550         {
 551                 g_weaponarena = 1;
 552                 g_weaponarena_list = "No Weapons";
 553         }
 554         else
 555         {
 556                 g_weaponarena = 1;
 557                 t = tokenize_console(s);
 558                 g_weaponarena_list = "";
 559                 for (i = 0; i < t; ++i)
 560                 {
 561                         s = argv(i);
 562                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 563                         {
 564                                 e = Weapons_from(j);
 565                                 if (e.netname == s)
 566                                 {
 567                                         g_weaponarena_weapons |= (e.m_wepset);
 568                                         g_weaponarena_list = strcat(g_weaponarena_list, e.m_name, " & ");
 569                                         break;
 570                                 }
 571                         }
 572                         if (j > WEP_LAST)
 573                         {
 574                                 LOG_INFO("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 575                         }
 576                 }
 577                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 578         }
 579
 580         if(g_weaponarena)
 581                 g_weaponarena_random = cvar("g_weaponarena_random");
 582         else
 583                 g_weaponarena_random = 0;
 584         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 585
 586         if (g_weaponarena)
 587         {
 588                 g_weapon_stay = 0; // incompatible
 589                 start_weapons = g_weaponarena_weapons;
 590                 start_items |= IT_UNLIMITED_AMMO;
 591         }
 592         else
 593         {
 594                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 595                 {
 596                         e = Weapons_from(i);
 597                         int w = want_weapon(e, false);
 598                         WepSet s = e.m_wepset;
 599                         if(w & 1)
 600                                 start_weapons |= s;
 601                         if(w & 2)
 602                                 start_weapons_default |= s;
 603                         if(w & 4)
 604                                 start_weapons_defaultmask |= s;
 605                 }
 606         }
 607
 608         if(!cvar("g_use_ammunition"))
 609                 start_items |= IT_UNLIMITED_AMMO;
 610
 611         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 612         {
 613                 start_ammo_shells = 999;
 614                 start_ammo_nails = 999;
 615                 start_ammo_rockets = 999;
 616                 start_ammo_cells = 999;
 617                 start_ammo_plasma = 999;
 618                 start_ammo_fuel = 999;
 619         }
 620         else
 621         {
 622                 start_ammo_shells = cvar("g_start_ammo_shells");
 623                 start_ammo_nails = cvar("g_start_ammo_nails");
 624                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 625                 start_ammo_cells = cvar("g_start_ammo_cells");
 626                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 627                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 628         }
 629
 630         if (warmup_stage)
 631         {
 632                 warmup_start_ammo_shells = start_ammo_shells;
 633                 warmup_start_ammo_nails = start_ammo_nails;
 634                 warmup_start_ammo_rockets = start_ammo_rockets;
 635                 warmup_start_ammo_cells = start_ammo_cells;
 636                 warmup_start_ammo_plasma = start_ammo_plasma;
 637                 warmup_start_ammo_fuel = start_ammo_fuel;
 638                 warmup_start_health = start_health;
 639                 warmup_start_armorvalue = start_armorvalue;
 640                 warmup_start_weapons = start_weapons;
 641                 warmup_start_weapons_default = start_weapons_default;
 642                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 643
 644                 if (!g_weaponarena && !g_ca && !g_freezetag)
 645                 {
 646                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 647                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 648                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 649                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 650                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 651                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 652                         warmup_start_health = cvar("g_warmup_start_health");
 653                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 654                         warmup_start_weapons = '0 0 0';
 655                         warmup_start_weapons_default = '0 0 0';
 656                         warmup_start_weapons_defaultmask = '0 0 0';
 657                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 658                         {
 659                                 e = Weapons_from(i);
 660                                 int w = want_weapon(e, g_warmup_allguns);
 661                                 WepSet s = (e.m_wepset);
 662                                 if(w & 1)
 663                                         warmup_start_weapons |= s;
 664                                 if(w & 2)
 665                                         warmup_start_weapons_default |= s;
 666                                 if(w & 4)
 667                                         warmup_start_weapons_defaultmask |= s;
 668                         }
 669                 }
 670         }
 671
 672         if (g_jetpack)
 673                 start_items |= ITEM_Jetpack.m_itemid;
 674
 675         MUTATOR_CALLHOOK(SetStartItems);
 676
 677         if (start_items & ITEM_Jetpack.m_itemid)
 678         {
 679                 start_items |= ITEM_JetpackRegen.m_itemid;
 680                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 681                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 682         }
 683
 684         WepSet precache_weapons = start_weapons;
 685         if (g_warmup_allguns != 1)
 686                 precache_weapons |= warmup_start_weapons;
 687         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 688         {
 689                 e = Weapons_from(i);
 690                 if(precache_weapons & (e.m_wepset)) {
 691                         e.wr_init(e);
 692                 }
 693         }
 694
 695         start_ammo_shells = max(0, start_ammo_shells);
 696         start_ammo_nails = max(0, start_ammo_nails);
 697         start_ammo_rockets = max(0, start_ammo_rockets);
 698         start_ammo_cells = max(0, start_ammo_cells);
 699         start_ammo_plasma = max(0, start_ammo_plasma);
 700         start_ammo_fuel = max(0, start_ammo_fuel);
 701
 702         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 703         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 704         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 705         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 706         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 707         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 708 }
 709
 710 void precache_playermodel(string m)
 711 {
 712         float globhandle, i, n;
 713         string f;
 714
 715         if(substring(m, -9,5) == "_lod1")
 716                 return;
 717         if(substring(m, -9,5) == "_lod2")
 718                 return;
 719         precache_model(m);
 720         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 721         if(fexists(f))
 722                 precache_model(f);
 723         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 724         if(fexists(f))
 725                 precache_model(f);
 726
 727         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 728         if (globhandle < 0)
 729                 return;
 730         n = search_getsize(globhandle);
 731         for (i = 0; i < n; ++i)
 732         {
 733                 //print(search_getfilename(globhandle, i), "\n");
 734                 f = search_getfilename(globhandle, i);
 735                 PrecachePlayerSounds(f);
 736         }
 737         search_end(globhandle);
 738 }
 739 void precache_all_playermodels(string pattern)
 740 {
 741         int globhandle = search_begin(pattern, true, false);
 742         if (globhandle < 0) return;
 743         int n = search_getsize(globhandle);
 744         for (int i = 0; i < n; ++i)
 745         {
 746                 string s = search_getfilename(globhandle, i);
 747                 precache_playermodel(s);
 748         }
 749         search_end(globhandle);
 750 }
 751
 752 void precache_playermodels(string s)
 753 {
 754         FOREACH_WORD(s, true, LAMBDA(precache_playermodel(it)));
 755 }
 756
 757 void precache()
 758 {SELFPARAM();
 759     // gamemode related things
 760
 761     // Precache all player models if desired
 762     if (autocvar_sv_precacheplayermodels)
 763     {
 764         PrecachePlayerSounds("sound/player/default.sounds");
 765         precache_all_playermodels("models/player/*.zym");
 766         precache_all_playermodels("models/player/*.dpm");
 767         precache_all_playermodels("models/player/*.md3");
 768         precache_all_playermodels("models/player/*.psk");
 769         precache_all_playermodels("models/player/*.iqm");
 770     }
 771
 772     if (autocvar_sv_defaultcharacter)
 773     {
 774                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 775                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 776                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 777                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 778                 precache_playermodels(autocvar_sv_defaultplayermodel);
 779     }
 780
 781 #if 0
 782     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 783
 784     if (!self.noise && self.music) // quake 3 uses the music field
 785         self.noise = self.music;
 786
 787     // plays music for the level if there is any
 788     if (self.noise)
 789     {
 790         precache_sound (self.noise);
 791         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
 792     }
 793 #endif
 794 }
 795
 796
 797 void make_safe_for_remove(entity e)
 798 {
 799     if (e.initialize_entity)
 800     {
 801         entity ent, prev = world;
 802         for (ent = initialize_entity_first; ent; )
 803         {
 804             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 805             {
 806                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 807                 // skip it in linked list
 808                 if (prev)
 809                 {
 810                     prev.initialize_entity_next = ent.initialize_entity_next;
 811                     ent = prev.initialize_entity_next;
 812                 }
 813                 else
 814                 {
 815                     initialize_entity_first = ent.initialize_entity_next;
 816                     ent = initialize_entity_first;
 817                 }
 818             }
 819             else
 820             {
 821                 prev = ent;
 822                 ent = ent.initialize_entity_next;
 823             }
 824         }
 825     }
 826 }
 827
 828 void objerror(string s)
 829 {SELFPARAM();
 830     make_safe_for_remove(self);
 831     builtin_objerror(s);
 832 }
 833
 834 .float remove_except_protected_forbidden;
 835 void remove_except_protected(entity e)
 836 {
 837         if(e.remove_except_protected_forbidden)
 838                 error("not allowed to remove this at this point");
 839         builtin_remove(e);
 840 }
 841
 842 void remove_unsafely(entity e)
 843 {
 844     if(e.classname == "spike")
 845         error("Removing spikes is forbidden (crylink bug), please report");
 846     builtin_remove(e);
 847 }
 848
 849 void remove_safely(entity e)
 850 {
 851     make_safe_for_remove(e);
 852     builtin_remove(e);
 853 }
 854
 855 void InitializeEntity(entity e, void() func, float order)
 856 {
 857     entity prev, cur;
 858
 859     if (!e || e.initialize_entity)
 860     {
 861         // make a proxy initializer entity
 862         entity e_old = e;
 863         e = new(initialize_entity);
 864         e.enemy = e_old;
 865     }
 866
 867     e.initialize_entity = func;
 868     e.initialize_entity_order = order;
 869
 870     cur = initialize_entity_first;
 871     prev = world;
 872     for (;;)
 873     {
 874         if (!cur || cur.initialize_entity_order > order)
 875         {
 876             // insert between prev and cur
 877             if (prev)
 878                 prev.initialize_entity_next = e;
 879             else
 880                 initialize_entity_first = e;
 881             e.initialize_entity_next = cur;
 882             return;
 883         }
 884         prev = cur;
 885         cur = cur.initialize_entity_next;
 886     }
 887 }
 888 void InitializeEntitiesRun()
 889 {SELFPARAM();
 890     entity startoflist = initialize_entity_first;
 891     initialize_entity_first = NULL;
 892     remove = remove_except_protected;
 893     for (entity e = startoflist; e; e = e.initialize_entity_next)
 894     {
 895                 e.remove_except_protected_forbidden = 1;
 896     }
 897     for (entity e = startoflist; e; )
 898     {
 899                 e.remove_except_protected_forbidden = 0;
 900         e.initialize_entity_order = 0;
 901         entity next = e.initialize_entity_next;
 902         e.initialize_entity_next = NULL;
 903         var void() func = e.initialize_entity;
 904         e.initialize_entity = func_null;
 905         if (e.classname == "initialize_entity")
 906         {
 907             entity wrappee = e.enemy;
 908             builtin_remove(e);
 909             e = wrappee;
 910         }
 911         //dprint("Delayed initialization: ", e.classname, "\n");
 912         if (func)
 913         {
 914                 WITH(entity, self, e, func());
 915         }
 916         else
 917         {
 918             eprint(e);
 919             backtrace(strcat("Null function in: ", e.classname, "\n"));
 920         }
 921         e = next;
 922     }
 923     remove = remove_unsafely;
 924 }
 925
 926 .float(entity) isEliminated;
 927 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 928 {
 929         float i, f, b;
 930         entity e;
 931         WriteHeader(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
 932         WriteByte(MSG_ENTITY, sendflags);
 933
 934         if(sendflags & 1)
 935         {
 936                 for(i = 1; i <= maxclients; i += 8)
 937                 {
 938                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
 939                         {
 940                                 if(eliminatedPlayers.isEliminated(e))
 941                                         f |= b;
 942                         }
 943                         WriteByte(MSG_ENTITY, f);
 944                 }
 945         }
 946
 947         return true;
 948 }
 949
 950 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 951 {
 952         if(eliminatedPlayers)
 953         {
 954                 backtrace("Can't spawn eliminatedPlayers again!");
 955                 return;
 956         }
 957         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 958         eliminatedPlayers.isEliminated = isEliminated_func;
 959 }
 960
 961
 962 void adaptor_think2touch()
 963 {SELFPARAM();
 964     entity o;
 965     o = other;
 966     other = world;
 967     self.touch();
 968     other = o;
 969 }
 970
 971 void adaptor_think2use()
 972 {SELFPARAM();
 973     entity o, a;
 974     o = other;
 975     a = activator;
 976     activator = world;
 977     other = world;
 978     self.use();
 979     other = o;
 980     activator = a;
 981 }
 982
 983 void adaptor_think2use_hittype_splash() // for timed projectile detonation
 984 {SELFPARAM();
 985         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 986                 self.projectiledeathtype |= HITTYPE_SPLASH;
 987         adaptor_think2use();
 988 }
 989
 990 // deferred dropping
 991 void DropToFloor_Handler()
 992 {SELFPARAM();
 993     builtin_droptofloor();
 994     self.dropped_origin = self.origin;
 995 }
 996
 997 void droptofloor()
 998 {SELFPARAM();
 999     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1000 }
1001
1002
1003
1004 float trace_hits_box_a0, trace_hits_box_a1;
1005
1006 float trace_hits_box_1d(float end, float thmi, float thma)
1007 {
1008     if (end == 0)
1009     {
1010         // just check if x is in range
1011         if (0 < thmi)
1012             return false;
1013         if (0 > thma)
1014             return false;
1015     }
1016     else
1017     {
1018         // do the trace with respect to x
1019         // 0 -> end has to stay in thmi -> thma
1020         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1021         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1022         if (trace_hits_box_a0 > trace_hits_box_a1)
1023             return false;
1024     }
1025     return true;
1026 }
1027
1028 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1029 {
1030     end -= start;
1031     thmi -= start;
1032     thma -= start;
1033     // now it is a trace from 0 to end
1034
1035     trace_hits_box_a0 = 0;
1036     trace_hits_box_a1 = 1;
1037
1038     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1039         return false;
1040     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1041         return false;
1042     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1043         return false;
1044
1045     return true;
1046 }
1047
1048 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1049 {
1050     return trace_hits_box(start, end, thmi - ma, thma - mi);
1051 }
1052
1053 float SUB_NoImpactCheck()
1054 {SELFPARAM();
1055         // zero hitcontents = this is not the real impact, but either the
1056         // mirror-impact of something hitting the projectile instead of the
1057         // projectile hitting the something, or a touchareagrid one. Neither of
1058         // these stop the projectile from moving, so...
1059         if(trace_dphitcontents == 0)
1060         {
1061                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1062                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", etof(self), self.classname, vtos(self.origin));
1063                 checkclient();
1064         }
1065     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1066         return 1;
1067     if (other == world && self.size != '0 0 0')
1068     {
1069         vector tic;
1070         tic = self.velocity * sys_frametime;
1071         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1072         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1073         if (trace_fraction >= 1)
1074         {
1075             LOG_TRACE("Odd... did not hit...?\n");
1076         }
1077         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1078         {
1079             LOG_TRACE("Detected and prevented the sky-grapple bug.\n");
1080             return 1;
1081         }
1082     }
1083
1084     return 0;
1085 }
1086
1087 #define SUB_OwnerCheck() (other && (other == self.owner))
1088
1089 void W_Crylink_Dequeue(entity e);
1090 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1091 {SELFPARAM();
1092         if(SUB_OwnerCheck())
1093                 return true;
1094         if(SUB_NoImpactCheck())
1095         {
1096                 if(self.classname == "nade")
1097                         return false; // no checks here
1098                 else if(self.classname == "grapplinghook")
1099                         RemoveGrapplingHook(self.realowner);
1100                 else if(self.classname == "spike")
1101                 {
1102                         W_Crylink_Dequeue(self);
1103                         remove(self);
1104                 }
1105                 else
1106                         remove(self);
1107                 return true;
1108         }
1109         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1110                 UpdateCSQCProjectile(self);
1111         return false;
1112 }
1113
1114 /** engine callback */
1115 void URI_Get_Callback(float id, float status, string data)
1116 {
1117         if(url_URI_Get_Callback(id, status, data))
1118         {
1119                 // handled
1120         }
1121         else if (id == URI_GET_DISCARD)
1122         {
1123                 // discard
1124         }
1125         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1126         {
1127                 // sv_cmd curl
1128                 Curl_URI_Get_Callback(id, status, data);
1129         }
1130         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1131         {
1132                 // online ban list
1133                 OnlineBanList_URI_Get_Callback(id, status, data);
1134         }
1135         else
1136         {
1137                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1138         }
1139 }
1140
1141 string uid2name(string myuid) {
1142         string s;
1143         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1144
1145         // FIXME remove this later after 0.6 release
1146         // convert old style broken records to correct style
1147         if(s == "")
1148         {
1149                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1150                 if(s != "")
1151                 {
1152                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1153                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1154                 }
1155         }
1156
1157         if(s == "")
1158                 s = "^1Unregistered Player";
1159         return s;
1160 }
1161
1162 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1163 {
1164     float m, i;
1165     vector start, org, delta, end, enddown, mstart;
1166     entity sp;
1167
1168     m = e.dphitcontentsmask;
1169     e.dphitcontentsmask = goodcontents | badcontents;
1170
1171     org = boundmin;
1172     delta = boundmax - boundmin;
1173
1174     start = end = org;
1175
1176     for (i = 0; i < attempts; ++i)
1177     {
1178         start.x = org.x + random() * delta.x;
1179         start.y = org.y + random() * delta.y;
1180         start.z = org.z + random() * delta.z;
1181
1182         // rule 1: start inside world bounds, and outside
1183         // solid, and don't start from somewhere where you can
1184         // fall down to evil
1185         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1186         if (trace_fraction >= 1)
1187             continue;
1188         if (trace_startsolid)
1189             continue;
1190         if (trace_dphitcontents & badcontents)
1191             continue;
1192         if (trace_dphitq3surfaceflags & badsurfaceflags)
1193             continue;
1194
1195         // rule 2: if we are too high, lower the point
1196         if (trace_fraction * delta.z > maxaboveground)
1197             start = trace_endpos + '0 0 1' * maxaboveground;
1198         enddown = trace_endpos;
1199
1200         // rule 3: make sure we aren't outside the map. This only works
1201         // for somewhat well formed maps. A good rule of thumb is that
1202         // the map should have a convex outside hull.
1203         // these can be traceLINES as we already verified the starting box
1204         mstart = start + 0.5 * (e.mins + e.maxs);
1205         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1206         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1207             continue;
1208         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1209         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1210             continue;
1211         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1212         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1213             continue;
1214         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1215         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1216             continue;
1217         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1218         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1219             continue;
1220
1221         // rule 4: we must "see" some spawnpoint or item
1222         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1223                 if(checkpvs(mstart, sp))
1224                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1225                                 break;
1226         if(!sp)
1227         {
1228                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1229                         if(checkpvs(mstart, sp))
1230                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1231                                         break;
1232                 if(!sp)
1233                         continue;
1234         }
1235
1236         // find a random vector to "look at"
1237         end.x = org.x + random() * delta.x;
1238         end.y = org.y + random() * delta.y;
1239         end.z = org.z + random() * delta.z;
1240         end = start + normalize(end - start) * vlen(delta);
1241
1242         // rule 4: start TO end must not be too short
1243         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1244         if (trace_startsolid)
1245             continue;
1246         if (trace_fraction < minviewdistance / vlen(delta))
1247             continue;
1248
1249         // rule 5: don't want to look at sky
1250         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1251             continue;
1252
1253         // rule 6: we must not end up in trigger_hurt
1254         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1255             continue;
1256
1257         break;
1258     }
1259
1260     e.dphitcontentsmask = m;
1261
1262     if (i < attempts)
1263     {
1264         setorigin(e, start);
1265         e.angles = vectoangles(end - start);
1266         LOG_TRACE("Needed ", ftos(i + 1), " attempts\n");
1267         return true;
1268     }
1269     else
1270         return false;
1271 }
1272
1273 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1274 {
1275         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1276 }
1277
1278 void write_recordmarker(entity pl, float tstart, float dt)
1279 {
1280     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1281
1282     // also write a marker into demo files for demotc-race-record-extractor to find
1283     stuffcmd(pl,
1284              strcat(
1285                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1286                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1287 }
1288
1289 void attach_sameorigin(entity e, entity to, string tag)
1290 {
1291     vector org, t_forward, t_left, t_up, e_forward, e_up;
1292     float tagscale;
1293
1294     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1295     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1296     t_forward = v_forward * tagscale;
1297     t_left = v_right * -tagscale;
1298     t_up = v_up * tagscale;
1299
1300     e.origin_x = org * t_forward;
1301     e.origin_y = org * t_left;
1302     e.origin_z = org * t_up;
1303
1304     // current forward and up directions
1305     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1306                 e.angles = AnglesTransform_FromVAngles(e.angles);
1307         else
1308                 e.angles = AnglesTransform_FromAngles(e.angles);
1309     fixedmakevectors(e.angles);
1310
1311     // untransform forward, up!
1312     e_forward.x = v_forward * t_forward;
1313     e_forward.y = v_forward * t_left;
1314     e_forward.z = v_forward * t_up;
1315     e_up.x = v_up * t_forward;
1316     e_up.y = v_up * t_left;
1317     e_up.z = v_up * t_up;
1318
1319     e.angles = fixedvectoangles2(e_forward, e_up);
1320     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1321                 e.angles = AnglesTransform_ToVAngles(e.angles);
1322         else
1323                 e.angles = AnglesTransform_ToAngles(e.angles);
1324
1325     setattachment(e, to, tag);
1326     setorigin(e, e.origin);
1327 }
1328
1329 void detach_sameorigin(entity e)
1330 {
1331     vector org;
1332     org = gettaginfo(e, 0);
1333     e.angles = fixedvectoangles2(v_forward, v_up);
1334     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1335                 e.angles = AnglesTransform_ToVAngles(e.angles);
1336         else
1337                 e.angles = AnglesTransform_ToAngles(e.angles);
1338     setorigin(e, org);
1339     setattachment(e, world, "");
1340     setorigin(e, e.origin);
1341 }
1342
1343 void follow_sameorigin(entity e, entity to)
1344 {
1345     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1346     e.aiment = to; // make the hole follow bmodel
1347     e.punchangle = to.angles; // the original angles of bmodel
1348     e.view_ofs = e.origin - to.origin; // relative origin
1349     e.v_angle = e.angles - to.angles; // relative angles
1350 }
1351
1352 void unfollow_sameorigin(entity e)
1353 {
1354     e.movetype = MOVETYPE_NONE;
1355 }
1356
1357 entity gettaginfo_relative_ent;
1358 vector gettaginfo_relative(entity e, float tag)
1359 {
1360     if (!gettaginfo_relative_ent)
1361     {
1362         gettaginfo_relative_ent = spawn();
1363         gettaginfo_relative_ent.effects = EF_NODRAW;
1364     }
1365     gettaginfo_relative_ent.model = e.model;
1366     gettaginfo_relative_ent.modelindex = e.modelindex;
1367     gettaginfo_relative_ent.frame = e.frame;
1368     return gettaginfo(gettaginfo_relative_ent, tag);
1369 }
1370
1371 .string aiment_classname;
1372 .float aiment_deadflag;
1373 void SetMovetypeFollow(entity ent, entity e)
1374 {
1375         // FIXME this may not be warpzone aware
1376         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
1377         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1378         ent.aiment = e; // make the hole follow bmodel
1379         ent.punchangle = e.angles; // the original angles of bmodel
1380         ent.view_ofs = ent.origin - e.origin; // relative origin
1381         ent.v_angle = ent.angles - e.angles; // relative angles
1382         ent.aiment_classname = strzone(e.classname);
1383         ent.aiment_deadflag = e.deadflag;
1384 }
1385 void UnsetMovetypeFollow(entity ent)
1386 {
1387         ent.movetype = MOVETYPE_FLY;
1388         PROJECTILE_MAKETRIGGER(ent);
1389         ent.aiment = world;
1390 }
1391 float LostMovetypeFollow(entity ent)
1392 {
1393 /*
1394         if(ent.movetype != MOVETYPE_FOLLOW)
1395                 if(ent.aiment)
1396                         error("???");
1397 */
1398         if(ent.aiment)
1399         {
1400                 if(ent.aiment.classname != ent.aiment_classname)
1401                         return 1;
1402                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1403                         return 1;
1404         }
1405         return 0;
1406 }
1407
1408 float isPushable(entity e)
1409 {
1410         if(e.pushable)
1411                 return true;
1412         if(IS_VEHICLE(e))
1413                 return false;
1414         if(e.iscreature)
1415                 return true;
1416         switch(e.classname)
1417         {
1418                 case "body":
1419                 case "droppedweapon":
1420                 case "keepawayball":
1421                 case "nexball_basketball":
1422                 case "nexball_football":
1423                         return true;
1424                 case "bullet": // antilagged bullets can't hit this either
1425                         return false;
1426         }
1427         if (e.projectiledeathtype)
1428                 return true;
1429         return false;
1430 }