qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = W_Name(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else replacement = "batteries"; // ;)
 363                 } else if (escape == "x") {
 364                         replacement = cursor_ent.netname;
 365                         if (replacement == "" || !cursor_ent)
 366                                 replacement = "nothing";
 367                 } else if (escape == "s")
 368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 369                 else if (escape == "S")
 370                         replacement = ftos(vlen(self.velocity));
 371
 372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 373                 p = p + strlen(replacement);
 374         }
 375         return msg;
 376 }
 377
 378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 379         return (value == 0) ? FALSE : TRUE;
 380 }
 381
 382 /*
 383 =============
 384 GetCvars
 385 =============
 386 Called with:
 387   0:  sends the request
 388   >0: receives a cvar from name=argv(f) value=argv(f+1)
 389 */
 390 void GetCvars_handleString(string thisname, float f, .string field, string name)
 391 {
 392         if (f < 0)
 393         {
 394                 if (self.field)
 395                         strunzone(self.field);
 396                 self.field = string_null;
 397         }
 398         else if (f > 0)
 399         {
 400                 if (thisname == name)
 401                 {
 402                         if (self.field)
 403                                 strunzone(self.field);
 404                         self.field = strzone(argv(f + 1));
 405                 }
 406         }
 407         else
 408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 409 }
 410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 411 {
 412         GetCvars_handleString(thisname, f, field, name);
 413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 414                 if (thisname == name)
 415                 {
 416                         string s;
 417                         s = func(strcat1(self.field));
 418                         if (s != self.field)
 419                         {
 420                                 strunzone(self.field);
 421                                 self.field = strzone(s);
 422                         }
 423                 }
 424 }
 425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 426 {
 427         if (f < 0)
 428         {
 429         }
 430         else if (f > 0)
 431         {
 432                 if (thisname == name)
 433                         self.field = stof(argv(f + 1));
 434         }
 435         else
 436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 437 }
 438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 439 {
 440         if (f < 0)
 441         {
 442         }
 443         else if (f > 0)
 444         {
 445                 if (thisname == name)
 446                 {
 447                         if(!self.field)
 448                         {
 449                                 self.field = stof(argv(f + 1));
 450                                 if(!self.field)
 451                                         self.field = -1;
 452                         }
 453                 }
 454         }
 455         else
 456         {
 457                 if(!self.field)
 458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 459         }
 460 }
 461 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 462 {
 463         string o;
 464         o = W_FixWeaponOrder_ForceComplete(wo);
 465         if(self.weaponorder_byimpulse)
 466         {
 467                 strunzone(self.weaponorder_byimpulse);
 468                 self.weaponorder_byimpulse = string_null;
 469         }
 470         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 471         return o;
 472 }
 473 void GetCvars(float f)
 474 {
 475         string s = string_null;
 476
 477         if (f > 0)
 478                 s = strcat1(argv(f));
 479
 480         get_cvars_f = f;
 481         get_cvars_s = s;
 482
 483         MUTATOR_CALLHOOK(GetCvars);
 484
 485         Notification_GetCvars();
 486
 487         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 488         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 489         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 490         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 491         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 492         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 504         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 505         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 506         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 508         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 510
 511         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 512         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 513
 514         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 515         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 516         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 517         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 518         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 519
 520         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 521         if (f > 0)
 522         {
 523                 if (s == "cl_weaponpriority")
 524                         self.switchweapon = w_getbestweapon(self);
 525                 if (s == "cl_allow_uidtracking")
 526                         PlayerStats_AddPlayer(self);
 527         }
 528 }
 529
 530 // decolorizes and team colors the player name when needed
 531 string playername(entity p)
 532 {
 533     string t;
 534     if (teamplay && !intermission_running && IS_PLAYER(p))
 535     {
 536         t = Team_ColorCode(p.team);
 537         return strcat(t, strdecolorize(p.netname));
 538     }
 539     else
 540         return p.netname;
 541 }
 542
 543 vector randompos(vector m1, vector m2)
 544 {
 545     vector v;
 546     m2 = m2 - m1;
 547     v_x = m2_x * random() + m1_x;
 548     v_y = m2_y * random() + m1_y;
 549     v_z = m2_z * random() + m1_z;
 550     return  v;
 551 }
 552
 553 //#NO AUTOCVARS START
 554
 555 float g_pickup_shells;
 556 float g_pickup_shells_max;
 557 float g_pickup_nails;
 558 float g_pickup_nails_max;
 559 float g_pickup_rockets;
 560 float g_pickup_rockets_max;
 561 float g_pickup_cells;
 562 float g_pickup_cells_max;
 563 float g_pickup_fuel;
 564 float g_pickup_fuel_jetpack;
 565 float g_pickup_fuel_max;
 566 float g_pickup_armorsmall;
 567 float g_pickup_armorsmall_max;
 568 float g_pickup_armorsmall_anyway;
 569 float g_pickup_armormedium;
 570 float g_pickup_armormedium_max;
 571 float g_pickup_armormedium_anyway;
 572 float g_pickup_armorbig;
 573 float g_pickup_armorbig_max;
 574 float g_pickup_armorbig_anyway;
 575 float g_pickup_armorlarge;
 576 float g_pickup_armorlarge_max;
 577 float g_pickup_armorlarge_anyway;
 578 float g_pickup_healthsmall;
 579 float g_pickup_healthsmall_max;
 580 float g_pickup_healthsmall_anyway;
 581 float g_pickup_healthmedium;
 582 float g_pickup_healthmedium_max;
 583 float g_pickup_healthmedium_anyway;
 584 float g_pickup_healthlarge;
 585 float g_pickup_healthlarge_max;
 586 float g_pickup_healthlarge_anyway;
 587 float g_pickup_healthmega;
 588 float g_pickup_healthmega_max;
 589 float g_pickup_healthmega_anyway;
 590 float g_pickup_ammo_anyway;
 591 float g_pickup_weapons_anyway;
 592 float g_weaponarena;
 593 WEPSET_DECLARE_A(g_weaponarena_weapons);
 594 float g_weaponarena_random;
 595 float g_weaponarena_random_with_laser;
 596 string g_weaponarena_list;
 597 float g_weaponspeedfactor;
 598 float g_weaponratefactor;
 599 float g_weapondamagefactor;
 600 float g_weaponforcefactor;
 601 float g_weaponspreadfactor;
 602
 603 WEPSET_DECLARE_A(start_weapons);
 604 WEPSET_DECLARE_A(start_weapons_default);
 605 WEPSET_DECLARE_A(start_weapons_defaultmask);
 606 float start_items;
 607 float start_ammo_shells;
 608 float start_ammo_nails;
 609 float start_ammo_rockets;
 610 float start_ammo_cells;
 611 float start_ammo_fuel;
 612 float start_health;
 613 float start_armorvalue;
 614 WEPSET_DECLARE_A(warmup_start_weapons);
 615 WEPSET_DECLARE_A(warmup_start_weapons_default);
 616 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 617 float warmup_start_ammo_shells;
 618 float warmup_start_ammo_nails;
 619 float warmup_start_ammo_rockets;
 620 float warmup_start_ammo_cells;
 621 float warmup_start_ammo_fuel;
 622 float warmup_start_health;
 623 float warmup_start_armorvalue;
 624 float g_weapon_stay;
 625
 626 entity get_weaponinfo(float w);
 627
 628 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 629 {
 630         var float i = weaponinfo.weapon;
 631         var float d = 0;
 632
 633         if (!i)
 634                 return 0;
 635
 636         if (g_lms || g_ca || allguns)
 637         {
 638                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 639                         d = TRUE;
 640                 else
 641                         d = FALSE;
 642         }
 643         else if (g_cts)
 644                 d = (i == WEP_SHOTGUN); // todo: how to handle shotgun in CTS mode? we're removing it.. so....
 645         else if (g_nexball)
 646                 d = 0; // weapon is set a few lines later
 647         else
 648                 d = (i == WEP_LASER);
 649
 650         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 651                 d |= (i == WEP_HOOK);
 652         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 653                 d = 0;
 654
 655         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 656
 657         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 658
 659         // bit order in t:
 660         // 1: want or not
 661         // 2: is default?
 662         // 4: is set by default?
 663         if(t < 0)
 664                 t = 4 | (3 * d);
 665         else
 666                 t |= (2 * d);
 667
 668         return t;
 669 }
 670
 671 void readplayerstartcvars()
 672 {
 673         entity e;
 674         float i, j, t;
 675         string s;
 676
 677         // initialize starting values for players
 678         WEPSET_CLEAR_A(start_weapons);
 679         WEPSET_CLEAR_A(start_weapons_default);
 680         WEPSET_CLEAR_A(start_weapons_defaultmask);
 681         start_items = 0;
 682         start_ammo_shells = 0;
 683         start_ammo_nails = 0;
 684         start_ammo_rockets = 0;
 685         start_ammo_cells = 0;
 686         start_health = cvar("g_balance_health_start");
 687         start_armorvalue = cvar("g_balance_armor_start");
 688
 689         g_weaponarena = 0;
 690         WEPSET_CLEAR_A(g_weaponarena_weapons);
 691
 692         s = cvar_string("g_weaponarena");
 693         if (s == "0" || s == "")
 694         {
 695                 if(g_ca)
 696                         s = "most";
 697         }
 698
 699         if (s == "0" || s == "")
 700         {
 701                 // no arena
 702         }
 703         else if (s == "off")
 704         {
 705                 // forcibly turn off weaponarena
 706         }
 707         else if (s == "all")
 708         {
 709                 g_weaponarena = 1;
 710                 g_weaponarena_list = "All Weapons";
 711                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 712                 {
 713                         e = get_weaponinfo(j);
 714                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 715                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 716                 }
 717         }
 718         else if (s == "most")
 719         {
 720                 g_weaponarena = 1;
 721                 g_weaponarena_list = "Most Weapons";
 722                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 723                 {
 724                         e = get_weaponinfo(j);
 725                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 726                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 727                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 728                 }
 729         }
 730         else if (s == "none")
 731         {
 732                 g_weaponarena = 1;
 733                 g_weaponarena_list = "No Weapons";
 734         }
 735         else
 736         {
 737                 g_weaponarena = 1;
 738                 t = tokenize_console(s);
 739                 g_weaponarena_list = "";
 740                 for (i = 0; i < t; ++i)
 741                 {
 742                         s = argv(i);
 743                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 744                         {
 745                                 e = get_weaponinfo(j);
 746                                 if (e.netname == s)
 747                                 {
 748                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 749                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 750                                         break;
 751                                 }
 752                         }
 753                         if (j > WEP_LAST)
 754                         {
 755                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 756                         }
 757                 }
 758                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 759         }
 760
 761         if(g_weaponarena)
 762                 g_weaponarena_random = cvar("g_weaponarena_random");
 763         else
 764                 g_weaponarena_random = 0;
 765         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 766
 767         if (g_weaponarena)
 768         {
 769                 g_pinata = 0; // incompatible
 770                 g_weapon_stay = 0; // incompatible
 771                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 772                 start_items |= IT_UNLIMITED_AMMO;
 773         }
 774         else
 775         {
 776                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 777                 {
 778                         e = get_weaponinfo(i);
 779                         float w = want_weapon("g_start_weapon_", e, FALSE);
 780                         if(w & 1)
 781                                 WEPSET_OR_AW(start_weapons, i);
 782                         if(w & 2)
 783                                 WEPSET_OR_AW(start_weapons_default, i);
 784                         if(w & 4)
 785                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 786                 }
 787         }
 788
 789         if(!cvar("g_use_ammunition"))
 790                 start_items |= IT_UNLIMITED_AMMO;
 791
 792         if(cvar("g_nexball"))
 793                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 794
 795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 796         {
 797                 start_ammo_rockets = 999;
 798                 start_ammo_shells = 999;
 799                 start_ammo_cells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_fuel = 999;
 802         }
 803         else
 804         {
 805                 start_ammo_shells = cvar("g_start_ammo_shells");
 806                 start_ammo_nails = cvar("g_start_ammo_nails");
 807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 808                 start_ammo_cells = cvar("g_start_ammo_cells");
 809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 810         }
 811
 812         if (inWarmupStage)
 813         {
 814                 warmup_start_ammo_shells = start_ammo_shells;
 815                 warmup_start_ammo_nails = start_ammo_nails;
 816                 warmup_start_ammo_rockets = start_ammo_rockets;
 817                 warmup_start_ammo_cells = start_ammo_cells;
 818                 warmup_start_ammo_fuel = start_ammo_fuel;
 819                 warmup_start_health = start_health;
 820                 warmup_start_armorvalue = start_armorvalue;
 821                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 822                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 823                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 824
 825                 if (!g_weaponarena && !g_ca)
 826                 {
 827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 832                         warmup_start_health = cvar("g_warmup_start_health");
 833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 834                         WEPSET_CLEAR_A(warmup_start_weapons);
 835                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 836                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 838                         {
 839                                 e = get_weaponinfo(i);
 840                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 841                                 if(w & 1)
 842                                         WEPSET_OR_AW(warmup_start_weapons, i);
 843                                 if(w & 2)
 844                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 845                                 if(w & 4)
 846                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 847                         }
 848                 }
 849         }
 850
 851         if (g_jetpack)
 852                 start_items |= IT_JETPACK;
 853
 854         MUTATOR_CALLHOOK(SetStartItems);
 855
 856         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 857         {
 858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 859                 start_items |= IT_FUEL_REGEN;
 860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862         }
 863
 864         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 865         {
 866                 e = get_weaponinfo(i);
 867                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 868                         WEP_ACTION(i, WR_INIT);
 869         }
 870
 871         start_ammo_shells = max(0, start_ammo_shells);
 872         start_ammo_nails = max(0, start_ammo_nails);
 873         start_ammo_cells = max(0, start_ammo_cells);
 874         start_ammo_rockets = max(0, start_ammo_rockets);
 875         start_ammo_fuel = max(0, start_ammo_fuel);
 876
 877         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 878         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 879         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 880         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 881         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 882 }
 883
 884 float g_bugrigs;
 885 float g_bugrigs_planar_movement;
 886 float g_bugrigs_planar_movement_car_jumping;
 887 float g_bugrigs_reverse_spinning;
 888 float g_bugrigs_reverse_speeding;
 889 float g_bugrigs_reverse_stopping;
 890 float g_bugrigs_air_steering;
 891 float g_bugrigs_angle_smoothing;
 892 float g_bugrigs_friction_floor;
 893 float g_bugrigs_friction_brake;
 894 float g_bugrigs_friction_air;
 895 float g_bugrigs_accel;
 896 float g_bugrigs_speed_ref;
 897 float g_bugrigs_speed_pow;
 898 float g_bugrigs_steer;
 899
 900 float sv_autotaunt;
 901 float sv_taunt;
 902
 903 string GetGametype(); // g_world.qc
 904 void readlevelcvars(void)
 905 {
 906         // load mutators
 907         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 908                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 909
 910         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 911         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, 1);
 912         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 913         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 914         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 915         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 916         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 917         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 918         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 921         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 922
 923         #undef CHECK_MUTATOR_ADD
 924
 925         if(cvar("sv_allow_fullbright"))
 926                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 927
 928     g_bugrigs = cvar("g_bugrigs");
 929     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 930     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 931     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 932     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 933     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 934     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 935     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 936     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 937     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 938     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 939     g_bugrigs_accel = cvar("g_bugrigs_accel");
 940     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 941     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 942     g_bugrigs_steer = cvar("g_bugrigs_steer");
 943
 944         g_minstagib = cvar("g_minstagib");
 945
 946         sv_clones = cvar("sv_clones");
 947         sv_foginterval = cvar("sv_foginterval");
 948         g_cloaked = cvar("g_cloaked");
 949     if(g_cts)
 950         g_cloaked = 1; // always enable cloak in CTS
 951         g_jump_grunt = cvar("g_jump_grunt");
 952         g_footsteps = cvar("g_footsteps");
 953         g_grappling_hook = cvar("g_grappling_hook");
 954         g_jetpack = cvar("g_jetpack");
 955         g_midair = cvar("g_midair");
 956         g_norecoil = cvar("g_norecoil");
 957         g_bloodloss = cvar("g_bloodloss");
 958         sv_maxidle = cvar("sv_maxidle");
 959         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 960         sv_autotaunt = cvar("sv_autotaunt");
 961         sv_taunt = cvar("sv_taunt");
 962
 963         inWarmupStage = cvar("g_warmup");
 964         g_warmup_limit = cvar("g_warmup_limit");
 965         g_warmup_allguns = cvar("g_warmup_allguns");
 966         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 967
 968         if ((g_race && g_race_qualifying == 2) || g_arena || g_minstagib || g_assault || cvar("g_campaign"))
 969                 inWarmupStage = 0; // these modes cannot work together, sorry
 970
 971         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 972         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 973         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 974         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 975         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 976         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 977         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 978         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 979         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 980         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 981         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 982         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 983         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 984         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 985
 986         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 987         g_weaponratefactor = cvar("g_weaponratefactor");
 988         g_weapondamagefactor = cvar("g_weapondamagefactor");
 989         g_weaponforcefactor = cvar("g_weaponforcefactor");
 990         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 991
 992         g_pickup_shells = cvar("g_pickup_shells");
 993         g_pickup_shells_max = cvar("g_pickup_shells_max");
 994         g_pickup_nails = cvar("g_pickup_nails");
 995         g_pickup_nails_max = cvar("g_pickup_nails_max");
 996         g_pickup_rockets = cvar("g_pickup_rockets");
 997         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 998         g_pickup_cells = cvar("g_pickup_cells");
 999         g_pickup_cells_max = cvar("g_pickup_cells_max");
1000         g_pickup_fuel = cvar("g_pickup_fuel");
1001         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1002         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1003         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1004         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1005         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1006         g_pickup_armormedium = cvar("g_pickup_armormedium");
1007         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1008         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1009         g_pickup_armorbig = cvar("g_pickup_armorbig");
1010         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1011         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1012         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1013         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1014         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1015         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1016         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1017         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1018         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1019         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1020         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1021         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1022         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1023         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1024         g_pickup_healthmega = cvar("g_pickup_healthmega");
1025         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1026         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1027
1028         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1029         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1030
1031         g_pinata = cvar("g_pinata");
1032
1033     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1034     if(!g_weapon_stay)
1035         g_weapon_stay = cvar("g_weapon_stay");
1036
1037         if not(inWarmupStage)
1038                 game_starttime = time + cvar("g_start_delay");
1039
1040         readplayerstartcvars();
1041 }
1042
1043 //#NO AUTOCVARS END
1044
1045 // Sound functions
1046 string precache_sound (string s) = #19;
1047 float precache_sound_index (string s) = #19;
1048
1049 #define SND_VOLUME      1
1050 #define SND_ATTENUATION 2
1051 #define SND_LARGEENTITY 8
1052 #define SND_LARGESOUND  16
1053
1054 float sound_allowed(float dest, entity e)
1055 {
1056     // sounds from world may always pass
1057     for (;;)
1058     {
1059         if (e.classname == "body")
1060             e = e.enemy;
1061         else if (e.realowner && e.realowner != e)
1062             e = e.realowner;
1063         else if (e.owner && e.owner != e)
1064             e = e.owner;
1065         else
1066             break;
1067     }
1068     // sounds to self may always pass
1069     if (dest == MSG_ONE)
1070         if (e == msg_entity)
1071             return TRUE;
1072     // sounds by players can be removed
1073     if (autocvar_bot_sound_monopoly)
1074         if (IS_REAL_CLIENT(e))
1075             return FALSE;
1076     // anything else may pass
1077     return TRUE;
1078 }
1079
1080 #ifdef COMPAT_XON010_CHANNELS
1081 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1082 void sound(entity e, float chan, string samp, float vol, float atten)
1083 {
1084     if (!sound_allowed(MSG_BROADCAST, e))
1085         return;
1086     builtin_sound(e, chan, samp, vol, atten);
1087 }
1088 #else
1089 #undef sound
1090 void sound(entity e, float chan, string samp, float vol, float atten)
1091 {
1092     if (!sound_allowed(MSG_BROADCAST, e))
1093         return;
1094     sound7(e, chan, samp, vol, atten, 0, 0);
1095 }
1096 #endif
1097
1098 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1099 {
1100     float entno, idx;
1101
1102     if (!sound_allowed(dest, e))
1103         return;
1104
1105     entno = num_for_edict(e);
1106     idx = precache_sound_index(samp);
1107
1108     float sflags;
1109     sflags = 0;
1110
1111     atten = floor(atten * 64);
1112     vol = floor(vol * 255);
1113
1114     if (vol != 255)
1115         sflags |= SND_VOLUME;
1116     if (atten != 64)
1117         sflags |= SND_ATTENUATION;
1118     if (entno >= 8192 || chan < 0 || chan > 7)
1119         sflags |= SND_LARGEENTITY;
1120     if (idx >= 256)
1121         sflags |= SND_LARGESOUND;
1122
1123     WriteByte(dest, SVC_SOUND);
1124     WriteByte(dest, sflags);
1125     if (sflags & SND_VOLUME)
1126         WriteByte(dest, vol);
1127     if (sflags & SND_ATTENUATION)
1128         WriteByte(dest, atten);
1129     if (sflags & SND_LARGEENTITY)
1130     {
1131         WriteShort(dest, entno);
1132         WriteByte(dest, chan);
1133     }
1134     else
1135     {
1136         WriteShort(dest, entno * 8 + chan);
1137     }
1138     if (sflags & SND_LARGESOUND)
1139         WriteShort(dest, idx);
1140     else
1141         WriteByte(dest, idx);
1142
1143     WriteCoord(dest, o_x);
1144     WriteCoord(dest, o_y);
1145     WriteCoord(dest, o_z);
1146 }
1147 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1148 {
1149     vector o;
1150
1151     if (!sound_allowed(dest, e))
1152         return;
1153
1154     o = e.origin + 0.5 * (e.mins + e.maxs);
1155     soundtoat(dest, e, o, chan, samp, vol, atten);
1156 }
1157 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1158 {
1159     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1160 }
1161 void stopsoundto(float dest, entity e, float chan)
1162 {
1163     float entno;
1164
1165     if (!sound_allowed(dest, e))
1166         return;
1167
1168     entno = num_for_edict(e);
1169
1170     if (entno >= 8192 || chan < 0 || chan > 7)
1171     {
1172         float idx, sflags;
1173         idx = precache_sound_index("misc/null.wav");
1174         sflags = SND_LARGEENTITY;
1175         if (idx >= 256)
1176             sflags |= SND_LARGESOUND;
1177         WriteByte(dest, SVC_SOUND);
1178         WriteByte(dest, sflags);
1179         WriteShort(dest, entno);
1180         WriteByte(dest, chan);
1181         if (sflags & SND_LARGESOUND)
1182             WriteShort(dest, idx);
1183         else
1184             WriteByte(dest, idx);
1185         WriteCoord(dest, e.origin_x);
1186         WriteCoord(dest, e.origin_y);
1187         WriteCoord(dest, e.origin_z);
1188     }
1189     else
1190     {
1191         WriteByte(dest, SVC_STOPSOUND);
1192         WriteShort(dest, entno * 8 + chan);
1193     }
1194 }
1195 void stopsound(entity e, float chan)
1196 {
1197     if (!sound_allowed(MSG_BROADCAST, e))
1198         return;
1199
1200     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1201     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1202 }
1203
1204 void play2(entity e, string filename)
1205 {
1206     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1207     msg_entity = e;
1208     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1209 }
1210
1211 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1212 .float spamtime;
1213 float spamsound(entity e, float chan, string samp, float vol, float atten)
1214 {
1215     if (!sound_allowed(MSG_BROADCAST, e))
1216         return FALSE;
1217
1218     if (time > e.spamtime)
1219     {
1220         e.spamtime = time;
1221         sound(e, chan, samp, vol, atten);
1222         return TRUE;
1223     }
1224     return FALSE;
1225 }
1226
1227 void play2team(float t, string filename)
1228 {
1229     entity head;
1230
1231     if (autocvar_bot_sound_monopoly)
1232         return;
1233
1234     FOR_EACH_REALPLAYER(head)
1235     {
1236         if (head.team == t)
1237             play2(head, filename);
1238     }
1239 }
1240
1241 void play2all(string samp)
1242 {
1243     if (autocvar_bot_sound_monopoly)
1244         return;
1245
1246     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1247 }
1248
1249 void PrecachePlayerSounds(string f);
1250 void precache_playermodel(string m)
1251 {
1252         float globhandle, i, n;
1253         string f;
1254
1255         if(substring(m, -9,5) == "_lod1")
1256                 return;
1257         if(substring(m, -9,5) == "_lod2")
1258                 return;
1259         precache_model(m);
1260         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1261         if(fexists(f))
1262                 precache_model(f);
1263         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1264         if(fexists(f))
1265                 precache_model(f);
1266
1267         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1268         if (globhandle < 0)
1269                 return;
1270         n = search_getsize(globhandle);
1271         for (i = 0; i < n; ++i)
1272         {
1273                 //print(search_getfilename(globhandle, i), "\n");
1274                 f = search_getfilename(globhandle, i);
1275                 PrecachePlayerSounds(f);
1276         }
1277         search_end(globhandle);
1278 }
1279 void precache_all_playermodels(string pattern)
1280 {
1281         float globhandle, i, n;
1282         string f;
1283
1284         globhandle = search_begin(pattern, TRUE, FALSE);
1285         if (globhandle < 0)
1286                 return;
1287         n = search_getsize(globhandle);
1288         for (i = 0; i < n; ++i)
1289         {
1290                 //print(search_getfilename(globhandle, i), "\n");
1291                 f = search_getfilename(globhandle, i);
1292                 precache_playermodel(f);
1293         }
1294         search_end(globhandle);
1295 }
1296
1297 void precache()
1298 {
1299     // gamemode related things
1300     precache_model ("models/misc/chatbubble.spr");
1301
1302 #ifdef TTURRETS_ENABLED
1303     if (autocvar_g_turrets)
1304         turrets_precash();
1305 #endif
1306
1307     // Precache all player models if desired
1308     if (autocvar_sv_precacheplayermodels)
1309     {
1310         PrecachePlayerSounds("sound/player/default.sounds");
1311         precache_all_playermodels("models/player/*.zym");
1312         precache_all_playermodels("models/player/*.dpm");
1313         precache_all_playermodels("models/player/*.md3");
1314         precache_all_playermodels("models/player/*.psk");
1315         precache_all_playermodels("models/player/*.iqm");
1316     }
1317
1318     if (autocvar_sv_defaultcharacter)
1319     {
1320         string s;
1321         s = autocvar_sv_defaultplayermodel_red;
1322         if (s != "")
1323             precache_playermodel(s);
1324         s = autocvar_sv_defaultplayermodel_blue;
1325         if (s != "")
1326             precache_playermodel(s);
1327         s = autocvar_sv_defaultplayermodel_yellow;
1328         if (s != "")
1329             precache_playermodel(s);
1330         s = autocvar_sv_defaultplayermodel_pink;
1331         if (s != "")
1332             precache_playermodel(s);
1333         s = autocvar_sv_defaultplayermodel;
1334         if (s != "")
1335             precache_playermodel(s);
1336     }
1337
1338     if (g_footsteps)
1339     {
1340         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1341         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1342     }
1343
1344     // gore and miscellaneous sounds
1345     //precache_sound ("misc/h2ohit.wav");
1346     precache_model ("models/hook.md3");
1347     precache_sound ("misc/armorimpact.wav");
1348     precache_sound ("misc/bodyimpact1.wav");
1349     precache_sound ("misc/bodyimpact2.wav");
1350     precache_sound ("misc/gib.wav");
1351     precache_sound ("misc/gib_splat01.wav");
1352     precache_sound ("misc/gib_splat02.wav");
1353     precache_sound ("misc/gib_splat03.wav");
1354     precache_sound ("misc/gib_splat04.wav");
1355     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1356     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1357     precache_sound ("misc/null.wav");
1358     precache_sound ("misc/spawn.wav");
1359     precache_sound ("misc/talk.wav");
1360     precache_sound ("misc/teleport.wav");
1361     precache_sound ("misc/poweroff.wav");
1362     precache_sound ("player/lava.wav");
1363     precache_sound ("player/slime.wav");
1364
1365     precache_model ("models/sprites/0.spr32");
1366     precache_model ("models/sprites/1.spr32");
1367     precache_model ("models/sprites/2.spr32");
1368     precache_model ("models/sprites/3.spr32");
1369     precache_model ("models/sprites/4.spr32");
1370     precache_model ("models/sprites/5.spr32");
1371     precache_model ("models/sprites/6.spr32");
1372     precache_model ("models/sprites/7.spr32");
1373     precache_model ("models/sprites/8.spr32");
1374     precache_model ("models/sprites/9.spr32");
1375     precache_model ("models/sprites/10.spr32");
1376
1377     // common weapon precaches
1378         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1379     precache_sound ("weapons/weapon_switch.wav");
1380     precache_sound ("weapons/weaponpickup.wav");
1381     precache_sound ("weapons/unavailable.wav");
1382     precache_sound ("weapons/dryfire.wav");
1383     if (g_grappling_hook)
1384     {
1385         precache_sound ("weapons/hook_fire.wav"); // hook
1386         precache_sound ("weapons/hook_impact.wav"); // hook
1387     }
1388
1389     precache_model("models/elaser.mdl");
1390     precache_model("models/laser.mdl");
1391     precache_model("models/ebomb.mdl");
1392
1393 #if 0
1394     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1395
1396     if (!self.noise && self.music) // quake 3 uses the music field
1397         self.noise = self.music;
1398
1399     // plays music for the level if there is any
1400     if (self.noise)
1401     {
1402         precache_sound (self.noise);
1403         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1404     }
1405 #endif
1406
1407 #include "precache-for-csqc.inc"
1408 }
1409
1410 // WARNING: this kills the trace globals
1411 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1412 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1413
1414 #define INITPRIO_FIRST              0
1415 #define INITPRIO_GAMETYPE           0
1416 #define INITPRIO_GAMETYPE_FALLBACK  1
1417 #define INITPRIO_FINDTARGET        10
1418 #define INITPRIO_DROPTOFLOOR       20
1419 #define INITPRIO_SETLOCATION       90
1420 #define INITPRIO_LINKDOORS         91
1421 #define INITPRIO_LAST              99
1422
1423 .void(void) initialize_entity;
1424 .float initialize_entity_order;
1425 .entity initialize_entity_next;
1426 entity initialize_entity_first;
1427
1428 void make_safe_for_remove(entity e)
1429 {
1430     if (e.initialize_entity)
1431     {
1432         entity ent, prev = world;
1433         for (ent = initialize_entity_first; ent; )
1434         {
1435             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1436             {
1437                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1438                 // skip it in linked list
1439                 if (prev)
1440                 {
1441                     prev.initialize_entity_next = ent.initialize_entity_next;
1442                     ent = prev.initialize_entity_next;
1443                 }
1444                 else
1445                 {
1446                     initialize_entity_first = ent.initialize_entity_next;
1447                     ent = initialize_entity_first;
1448                 }
1449             }
1450             else
1451             {
1452                 prev = ent;
1453                 ent = ent.initialize_entity_next;
1454             }
1455         }
1456     }
1457 }
1458
1459 void objerror(string s)
1460 {
1461     make_safe_for_remove(self);
1462     builtin_objerror(s);
1463 }
1464
1465 .float remove_except_protected_forbidden;
1466 void remove_except_protected(entity e)
1467 {
1468         if(e.remove_except_protected_forbidden)
1469                 error("not allowed to remove this at this point");
1470         builtin_remove(e);
1471 }
1472
1473 void remove_unsafely(entity e)
1474 {
1475     if(e.classname == "spike")
1476         error("Removing spikes is forbidden (crylink bug), please report");
1477     builtin_remove(e);
1478 }
1479
1480 void remove_safely(entity e)
1481 {
1482     make_safe_for_remove(e);
1483     builtin_remove(e);
1484 }
1485
1486 void InitializeEntity(entity e, void(void) func, float order)
1487 {
1488     entity prev, cur;
1489
1490     if (!e || e.initialize_entity)
1491     {
1492         // make a proxy initializer entity
1493         entity e_old;
1494         e_old = e;
1495         e = spawn();
1496         e.classname = "initialize_entity";
1497         e.enemy = e_old;
1498     }
1499
1500     e.initialize_entity = func;
1501     e.initialize_entity_order = order;
1502
1503     cur = initialize_entity_first;
1504     prev = world;
1505     for (;;)
1506     {
1507         if (!cur || cur.initialize_entity_order > order)
1508         {
1509             // insert between prev and cur
1510             if (prev)
1511                 prev.initialize_entity_next = e;
1512             else
1513                 initialize_entity_first = e;
1514             e.initialize_entity_next = cur;
1515             return;
1516         }
1517         prev = cur;
1518         cur = cur.initialize_entity_next;
1519     }
1520 }
1521 void InitializeEntitiesRun()
1522 {
1523     entity startoflist;
1524     startoflist = initialize_entity_first;
1525     initialize_entity_first = world;
1526     remove = remove_except_protected;
1527     for (self = startoflist; self; self = self.initialize_entity_next)
1528     {
1529         self.remove_except_protected_forbidden = 1;
1530     }
1531     for (self = startoflist; self; )
1532     {
1533         entity e;
1534         var void(void) func;
1535         e = self.initialize_entity_next;
1536         func = self.initialize_entity;
1537         self.initialize_entity_order = 0;
1538         self.initialize_entity = func_null;
1539         self.initialize_entity_next = world;
1540         self.remove_except_protected_forbidden = 0;
1541         if (self.classname == "initialize_entity")
1542         {
1543             entity e_old;
1544             e_old = self.enemy;
1545             builtin_remove(self);
1546             self = e_old;
1547         }
1548         //dprint("Delayed initialization: ", self.classname, "\n");
1549         if(func)
1550             func();
1551         else
1552         {
1553             eprint(self);
1554             backtrace(strcat("Null function in: ", self.classname, "\n"));
1555         }
1556         self = e;
1557     }
1558     remove = remove_unsafely;
1559 }
1560
1561 .float uncustomizeentityforclient_set;
1562 .void(void) uncustomizeentityforclient;
1563 void UncustomizeEntitiesRun()
1564 {
1565     entity oldself;
1566     oldself = self;
1567     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1568         self.uncustomizeentityforclient();
1569     self = oldself;
1570 }
1571 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1572 {
1573     e.customizeentityforclient = customizer;
1574     e.uncustomizeentityforclient = uncustomizer;
1575     e.uncustomizeentityforclient_set = !!uncustomizer;
1576 }
1577
1578 .float nottargeted;
1579 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1580
1581 void() SUB_Remove;
1582 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1583 {
1584     vector mi, ma;
1585
1586     if (e.classname == "")
1587         e.classname = "net_linked";
1588
1589     if (e.model == "" || self.modelindex == 0)
1590     {
1591         mi = e.mins;
1592         ma = e.maxs;
1593         setmodel(e, "null");
1594         setsize(e, mi, ma);
1595     }
1596
1597     e.SendEntity = sendfunc;
1598     e.SendFlags = 0xFFFFFF;
1599
1600     if (!docull)
1601         e.effects |= EF_NODEPTHTEST;
1602
1603     if (dt)
1604     {
1605         e.nextthink = time + dt;
1606         e.think = SUB_Remove;
1607     }
1608 }
1609
1610 void adaptor_think2touch()
1611 {
1612     entity o;
1613     o = other;
1614     other = world;
1615     self.touch();
1616     other = o;
1617 }
1618
1619 void adaptor_think2use()
1620 {
1621     entity o, a;
1622     o = other;
1623     a = activator;
1624     activator = world;
1625     other = world;
1626     self.use();
1627     other = o;
1628     activator = a;
1629 }
1630
1631 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1632 {
1633         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1634                 self.projectiledeathtype |= HITTYPE_SPLASH;
1635         adaptor_think2use();
1636 }
1637
1638 // deferred dropping
1639 void DropToFloor_Handler()
1640 {
1641     builtin_droptofloor();
1642     self.dropped_origin = self.origin;
1643 }
1644
1645 void droptofloor()
1646 {
1647     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1648 }
1649
1650
1651
1652 float trace_hits_box_a0, trace_hits_box_a1;
1653
1654 float trace_hits_box_1d(float end, float thmi, float thma)
1655 {
1656     if (end == 0)
1657     {
1658         // just check if x is in range
1659         if (0 < thmi)
1660             return FALSE;
1661         if (0 > thma)
1662             return FALSE;
1663     }
1664     else
1665     {
1666         // do the trace with respect to x
1667         // 0 -> end has to stay in thmi -> thma
1668         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1669         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1670         if (trace_hits_box_a0 > trace_hits_box_a1)
1671             return FALSE;
1672     }
1673     return TRUE;
1674 }
1675
1676 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1677 {
1678     end -= start;
1679     thmi -= start;
1680     thma -= start;
1681     // now it is a trace from 0 to end
1682
1683     trace_hits_box_a0 = 0;
1684     trace_hits_box_a1 = 1;
1685
1686     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1687         return FALSE;
1688     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1689         return FALSE;
1690     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1691         return FALSE;
1692
1693     return TRUE;
1694 }
1695
1696 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1697 {
1698     return trace_hits_box(start, end, thmi - ma, thma - mi);
1699 }
1700
1701 float SUB_NoImpactCheck()
1702 {
1703         // zero hitcontents = this is not the real impact, but either the
1704         // mirror-impact of something hitting the projectile instead of the
1705         // projectile hitting the something, or a touchareagrid one. Neither of
1706         // these stop the projectile from moving, so...
1707         if(trace_dphitcontents == 0)
1708         {
1709                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1710                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1711                 checkclient();
1712         }
1713     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1714         return 1;
1715     if (other == world && self.size != '0 0 0')
1716     {
1717         vector tic;
1718         tic = self.velocity * sys_frametime;
1719         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1720         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1721         if (trace_fraction >= 1)
1722         {
1723             dprint("Odd... did not hit...?\n");
1724         }
1725         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1726         {
1727             dprint("Detected and prevented the sky-grapple bug.\n");
1728             return 1;
1729         }
1730     }
1731
1732     return 0;
1733 }
1734
1735 #define SUB_OwnerCheck() (other && (other == self.owner))
1736
1737 void RemoveGrapplingHook(entity pl);
1738 void W_Crylink_Dequeue(entity e);
1739 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1740 {
1741         if(SUB_OwnerCheck())
1742                 return TRUE;
1743         if(SUB_NoImpactCheck())
1744         {
1745                 if(self.classname == "grapplinghook")
1746                         RemoveGrapplingHook(self.realowner);
1747                 else if(self.classname == "spike")
1748                 {
1749                         W_Crylink_Dequeue(self);
1750                         remove(self);
1751                 }
1752                 else
1753                         remove(self);
1754                 return TRUE;
1755         }
1756         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1757                 UpdateCSQCProjectile(self);
1758         return FALSE;
1759 }
1760 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1761
1762 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1763 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1764
1765 void URI_Get_Callback(float id, float status, string data)
1766 {
1767         if(url_URI_Get_Callback(id, status, data))
1768         {
1769                 // handled
1770         }
1771         else if (id == URI_GET_DISCARD)
1772         {
1773                 // discard
1774         }
1775         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1776         {
1777                 // sv_cmd curl
1778                 Curl_URI_Get_Callback(id, status, data);
1779         }
1780         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1781         {
1782                 // online ban list
1783                 OnlineBanList_URI_Get_Callback(id, status, data);
1784         }
1785         else
1786         {
1787                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1788         }
1789 }
1790
1791 string uid2name(string myuid) {
1792         string s;
1793         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1794
1795         // FIXME remove this later after 0.6 release
1796         // convert old style broken records to correct style
1797         if(s == "")
1798         {
1799                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1800                 if(s != "")
1801                 {
1802                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1803                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1804                 }
1805         }
1806
1807         if(s == "")
1808                 s = "^1Unregistered Player";
1809         return s;
1810 }
1811
1812 float race_readTime(string map, float pos)
1813 {
1814         string rr;
1815         if(g_cts)
1816                 rr = CTS_RECORD;
1817         else
1818                 rr = RACE_RECORD;
1819
1820         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1821 }
1822
1823 string race_readUID(string map, float pos)
1824 {
1825         string rr;
1826         if(g_cts)
1827                 rr = CTS_RECORD;
1828         else
1829                 rr = RACE_RECORD;
1830
1831         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1832 }
1833
1834 float race_readPos(string map, float t) {
1835         float i;
1836         for (i = 1; i <= RANKINGS_CNT; ++i)
1837                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1838                         return i;
1839
1840         return 0; // pos is zero if unranked
1841 }
1842
1843 void race_writeTime(string map, float t, string myuid)
1844 {
1845         string rr;
1846         if(g_cts)
1847                 rr = CTS_RECORD;
1848         else
1849                 rr = RACE_RECORD;
1850
1851         float newpos;
1852         newpos = race_readPos(map, t);
1853
1854         float i, prevpos = 0;
1855         for(i = 1; i <= RANKINGS_CNT; ++i)
1856         {
1857                 if(race_readUID(map, i) == myuid)
1858                         prevpos = i;
1859         }
1860         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1861                 for (i = prevpos; i > newpos; --i) {
1862                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1863                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1864                 }
1865         } else { // player has no ranked record yet
1866                 for (i = RANKINGS_CNT; i > newpos; --i) {
1867                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1868                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1869                 }
1870         }
1871
1872         // store new time itself
1873         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1874         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1875 }
1876
1877 string race_readName(string map, float pos)
1878 {
1879         string rr;
1880         if(g_cts)
1881                 rr = CTS_RECORD;
1882         else
1883                 rr = RACE_RECORD;
1884
1885         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1886 }
1887
1888 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1889 {
1890     float m, i;
1891     vector start, org, delta, end, enddown, mstart;
1892     entity sp;
1893
1894     m = e.dphitcontentsmask;
1895     e.dphitcontentsmask = goodcontents | badcontents;
1896
1897     org = world.mins;
1898     delta = world.maxs - world.mins;
1899
1900     start = end = org;
1901
1902     for (i = 0; i < attempts; ++i)
1903     {
1904         start_x = org_x + random() * delta_x;
1905         start_y = org_y + random() * delta_y;
1906         start_z = org_z + random() * delta_z;
1907
1908         // rule 1: start inside world bounds, and outside
1909         // solid, and don't start from somewhere where you can
1910         // fall down to evil
1911         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1912         if (trace_fraction >= 1)
1913             continue;
1914         if (trace_startsolid)
1915             continue;
1916         if (trace_dphitcontents & badcontents)
1917             continue;
1918         if (trace_dphitq3surfaceflags & badsurfaceflags)
1919             continue;
1920
1921         // rule 2: if we are too high, lower the point
1922         if (trace_fraction * delta_z > maxaboveground)
1923             start = trace_endpos + '0 0 1' * maxaboveground;
1924         enddown = trace_endpos;
1925
1926         // rule 3: make sure we aren't outside the map. This only works
1927         // for somewhat well formed maps. A good rule of thumb is that
1928         // the map should have a convex outside hull.
1929         // these can be traceLINES as we already verified the starting box
1930         mstart = start + 0.5 * (e.mins + e.maxs);
1931         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1932         if (trace_fraction >= 1)
1933             continue;
1934         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1935         if (trace_fraction >= 1)
1936             continue;
1937         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1938         if (trace_fraction >= 1)
1939             continue;
1940         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1941         if (trace_fraction >= 1)
1942             continue;
1943         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1944         if (trace_fraction >= 1)
1945             continue;
1946
1947         // rule 4: we must "see" some spawnpoint
1948         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1949                 if(checkpvs(mstart, sp))
1950                         break;
1951         if(!sp)
1952         {
1953                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1954                         if(checkpvs(mstart, sp))
1955                                 break;
1956                 if(!sp)
1957                         continue;
1958         }
1959
1960         // find a random vector to "look at"
1961         end_x = org_x + random() * delta_x;
1962         end_y = org_y + random() * delta_y;
1963         end_z = org_z + random() * delta_z;
1964         end = start + normalize(end - start) * vlen(delta);
1965
1966         // rule 4: start TO end must not be too short
1967         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1968         if (trace_startsolid)
1969             continue;
1970         if (trace_fraction < minviewdistance / vlen(delta))
1971             continue;
1972
1973         // rule 5: don't want to look at sky
1974         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1975             continue;
1976
1977         // rule 6: we must not end up in trigger_hurt
1978         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1979             continue;
1980
1981         break;
1982     }
1983
1984     e.dphitcontentsmask = m;
1985
1986     if (i < attempts)
1987     {
1988         setorigin(e, start);
1989         e.angles = vectoangles(end - start);
1990         dprint("Needed ", ftos(i + 1), " attempts\n");
1991         return TRUE;
1992     }
1993     else
1994         return FALSE;
1995 }
1996
1997 float zcurveparticles_effectno;
1998 vector zcurveparticles_start;
1999 float zcurveparticles_spd;
2000
2001 void endzcurveparticles()
2002 {
2003         if(zcurveparticles_effectno)
2004         {
2005                 // terminator
2006                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2007         }
2008         zcurveparticles_effectno = 0;
2009 }
2010
2011 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2012 {
2013         spd = bound(0, floor(spd / 16), 32767);
2014         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2015         {
2016                 endzcurveparticles();
2017                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2018                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2019                 WriteShort(MSG_BROADCAST, effectno);
2020                 WriteCoord(MSG_BROADCAST, start_x);
2021                 WriteCoord(MSG_BROADCAST, start_y);
2022                 WriteCoord(MSG_BROADCAST, start_z);
2023                 zcurveparticles_effectno = effectno;
2024                 zcurveparticles_start = start;
2025         }
2026         else
2027                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2028         WriteCoord(MSG_BROADCAST, end_x);
2029         WriteCoord(MSG_BROADCAST, end_y);
2030         WriteCoord(MSG_BROADCAST, end_z);
2031         WriteCoord(MSG_BROADCAST, end_dz);
2032         zcurveparticles_spd = spd;
2033 }
2034
2035 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2036 {
2037         float end_dz;
2038         vector vecxy, velxy;
2039
2040         vecxy = end - start;
2041         vecxy_z = 0;
2042         velxy = vel;
2043         velxy_z = 0;
2044
2045         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2046         {
2047                 endzcurveparticles();
2048                 trailparticles(world, effectno, start, end);
2049                 return;
2050         }
2051
2052         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2053         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2054 }
2055
2056 void write_recordmarker(entity pl, float tstart, float dt)
2057 {
2058     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2059
2060     // also write a marker into demo files for demotc-race-record-extractor to find
2061     stuffcmd(pl,
2062              strcat(
2063                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2064                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2065 }
2066
2067 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2068 {
2069         switch(algn)
2070         {
2071                 default:
2072                 case 3: // right
2073                         break;
2074
2075                 case 4: // left
2076                         vecs_y = -vecs_y;
2077                         break;
2078
2079                 case 1:
2080                         if(allowcenter) // 2: allow center handedness
2081                         {
2082                                 // center
2083                                 vecs_y = 0;
2084                                 vecs_z -= 2;
2085                         }
2086                         else
2087                         {
2088                                 // right
2089                         }
2090                         break;
2091
2092                 case 2:
2093                         if(allowcenter) // 2: allow center handedness
2094                         {
2095                                 // center
2096                                 vecs_y = 0;
2097                                 vecs_z -= 2;
2098                         }
2099                         else
2100                         {
2101                                 // left
2102                                 vecs_y = -vecs_y;
2103                         }
2104                         break;
2105         }
2106         return vecs;
2107 }
2108
2109 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2110 {
2111         string s;
2112         vector v;
2113
2114         if (autocvar_g_shootfromeye)
2115         {
2116                 if (visual)
2117                 {
2118                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2119                         else { vecs_y = 0; vecs_z -= 2; }
2120                 }
2121                 else
2122                 {
2123                         vecs_y = 0;
2124                         vecs_z = 0;
2125                 }
2126         }
2127         else if (autocvar_g_shootfromcenter)
2128         {
2129                 vecs_y = 0;
2130                 vecs_z -= 2;
2131         }
2132         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2133         {
2134                 v = stov(s);
2135                 if (y_is_right)
2136                         v_y = -v_y;
2137                 if (v_x != 0)
2138                         vecs_x = v_x;
2139                 vecs_y = v_y;
2140                 vecs_z = v_z;
2141         }
2142         else if (autocvar_g_shootfromclient)
2143         {
2144                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2145         }
2146         return vecs;
2147 }
2148
2149 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2150 {
2151         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2152 }
2153
2154
2155 void attach_sameorigin(entity e, entity to, string tag)
2156 {
2157     vector org, t_forward, t_left, t_up, e_forward, e_up;
2158     float tagscale;
2159
2160     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2161     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2162     t_forward = v_forward * tagscale;
2163     t_left = v_right * -tagscale;
2164     t_up = v_up * tagscale;
2165
2166     e.origin_x = org * t_forward;
2167     e.origin_y = org * t_left;
2168     e.origin_z = org * t_up;
2169
2170     // current forward and up directions
2171     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2172                 e.angles = AnglesTransform_FromVAngles(e.angles);
2173         else
2174                 e.angles = AnglesTransform_FromAngles(e.angles);
2175     fixedmakevectors(e.angles);
2176
2177     // untransform forward, up!
2178     e_forward_x = v_forward * t_forward;
2179     e_forward_y = v_forward * t_left;
2180     e_forward_z = v_forward * t_up;
2181     e_up_x = v_up * t_forward;
2182     e_up_y = v_up * t_left;
2183     e_up_z = v_up * t_up;
2184
2185     e.angles = fixedvectoangles2(e_forward, e_up);
2186     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2187                 e.angles = AnglesTransform_ToVAngles(e.angles);
2188         else
2189                 e.angles = AnglesTransform_ToAngles(e.angles);
2190
2191     setattachment(e, to, tag);
2192     setorigin(e, e.origin);
2193 }
2194
2195 void detach_sameorigin(entity e)
2196 {
2197     vector org;
2198     org = gettaginfo(e, 0);
2199     e.angles = fixedvectoangles2(v_forward, v_up);
2200     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2201                 e.angles = AnglesTransform_ToVAngles(e.angles);
2202         else
2203                 e.angles = AnglesTransform_ToAngles(e.angles);
2204     setorigin(e, org);
2205     setattachment(e, world, "");
2206     setorigin(e, e.origin);
2207 }
2208
2209 void follow_sameorigin(entity e, entity to)
2210 {
2211     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2212     e.aiment = to; // make the hole follow bmodel
2213     e.punchangle = to.angles; // the original angles of bmodel
2214     e.view_ofs = e.origin - to.origin; // relative origin
2215     e.v_angle = e.angles - to.angles; // relative angles
2216 }
2217
2218 void unfollow_sameorigin(entity e)
2219 {
2220     e.movetype = MOVETYPE_NONE;
2221 }
2222
2223 entity gettaginfo_relative_ent;
2224 vector gettaginfo_relative(entity e, float tag)
2225 {
2226     if (!gettaginfo_relative_ent)
2227     {
2228         gettaginfo_relative_ent = spawn();
2229         gettaginfo_relative_ent.effects = EF_NODRAW;
2230     }
2231     gettaginfo_relative_ent.model = e.model;
2232     gettaginfo_relative_ent.modelindex = e.modelindex;
2233     gettaginfo_relative_ent.frame = e.frame;
2234     return gettaginfo(gettaginfo_relative_ent, tag);
2235 }
2236
2237 .float scale2;
2238
2239 float modeleffect_SendEntity(entity to, float sf)
2240 {
2241         float f;
2242         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2243
2244         f = 0;
2245         if(self.velocity != '0 0 0')
2246                 f |= 1;
2247         if(self.angles != '0 0 0')
2248                 f |= 2;
2249         if(self.avelocity != '0 0 0')
2250                 f |= 4;
2251
2252         WriteByte(MSG_ENTITY, f);
2253         WriteShort(MSG_ENTITY, self.modelindex);
2254         WriteByte(MSG_ENTITY, self.skin);
2255         WriteByte(MSG_ENTITY, self.frame);
2256         WriteCoord(MSG_ENTITY, self.origin_x);
2257         WriteCoord(MSG_ENTITY, self.origin_y);
2258         WriteCoord(MSG_ENTITY, self.origin_z);
2259         if(f & 1)
2260         {
2261                 WriteCoord(MSG_ENTITY, self.velocity_x);
2262                 WriteCoord(MSG_ENTITY, self.velocity_y);
2263                 WriteCoord(MSG_ENTITY, self.velocity_z);
2264         }
2265         if(f & 2)
2266         {
2267                 WriteCoord(MSG_ENTITY, self.angles_x);
2268                 WriteCoord(MSG_ENTITY, self.angles_y);
2269                 WriteCoord(MSG_ENTITY, self.angles_z);
2270         }
2271         if(f & 4)
2272         {
2273                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2274                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2275                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2276         }
2277         WriteShort(MSG_ENTITY, self.scale * 256.0);
2278         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2279         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2280         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2281         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2282
2283         return TRUE;
2284 }
2285
2286 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2287 {
2288         entity e;
2289         float sz;
2290         e = spawn();
2291         e.classname = "modeleffect";
2292         setmodel(e, m);
2293         e.frame = f;
2294         setorigin(e, o);
2295         e.velocity = v;
2296         e.angles = ang;
2297         e.avelocity = angv;
2298         e.alpha = a;
2299         e.teleport_time = t1;
2300         e.fade_time = t2;
2301         e.skin = s;
2302         if(s0 >= 0)
2303                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2304         else
2305                 e.scale = -s0;
2306         if(s2 >= 0)
2307                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2308         else
2309                 e.scale2 = -s2;
2310         sz = max(e.scale, e.scale2);
2311         setsize(e, e.mins * sz, e.maxs * sz);
2312         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2313 }
2314
2315 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2316 {
2317         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2318 }
2319
2320 float randombit(float bits)
2321 {
2322         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2323                 return bits;
2324
2325         float n, f, b, r;
2326
2327         r = random();
2328         b = 0;
2329         n = 0;
2330
2331         for(f = 1; f <= bits; f *= 2)
2332         {
2333                 if(bits & f)
2334                 {
2335                         ++n;
2336                         r *= n;
2337                         if(r <= 1)
2338                                 b = f;
2339                         else
2340                                 r = (r - 1) / (n - 1);
2341                 }
2342         }
2343
2344         return b;
2345 }
2346
2347 float randombits(float bits, float k, float error_return)
2348 {
2349         float r;
2350         r = 0;
2351         while(k > 0 && bits != r)
2352         {
2353                 r += randombit(bits - r);
2354                 --k;
2355         }
2356         if(error_return)
2357                 if(k > 0)
2358                         return -1; // all
2359         return r;
2360 }
2361
2362 void randombit_test(float bits, float iter)
2363 {
2364         while(iter > 0)
2365         {
2366                 print(ftos(randombit(bits)), "\n");
2367                 --iter;
2368         }
2369 }
2370
2371 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2372 {
2373         if(halflifedist > 0)
2374                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2375         else if(halflifedist < 0)
2376                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2377         else
2378                 return 1;
2379 }
2380
2381
2382
2383
2384 #ifdef RELEASE
2385 #define cvar_string_normal builtin_cvar_string
2386 #define cvar_normal builtin_cvar
2387 #else
2388 string cvar_string_normal(string n)
2389 {
2390         if not(cvar_type(n) & 1)
2391                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2392         return builtin_cvar_string(n);
2393 }
2394
2395 float cvar_normal(string n)
2396 {
2397         return stof(cvar_string_normal(n));
2398 }
2399 #endif
2400 #define cvar_set_normal builtin_cvar_set
2401
2402 void defer_think()
2403 {
2404     entity oself;
2405
2406     oself           = self;
2407     self            = self.owner;
2408     oself.think     = SUB_Remove;
2409     oself.nextthink = time;
2410
2411     oself.use();
2412 }
2413
2414 /*
2415     Execute func() after time + fdelay.
2416     self when func is executed = self when defer is called
2417 */
2418 void defer(float fdelay, void() func)
2419 {
2420     entity e;
2421
2422     e           = spawn();
2423     e.owner     = self;
2424     e.use       = func;
2425     e.think     = defer_think;
2426     e.nextthink = time + fdelay;
2427 }
2428
2429 .string aiment_classname;
2430 .float aiment_deadflag;
2431 void SetMovetypeFollow(entity ent, entity e)
2432 {
2433         // FIXME this may not be warpzone aware
2434         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2435         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2436         ent.aiment = e; // make the hole follow bmodel
2437         ent.punchangle = e.angles; // the original angles of bmodel
2438         ent.view_ofs = ent.origin - e.origin; // relative origin
2439         ent.v_angle = ent.angles - e.angles; // relative angles
2440         ent.aiment_classname = strzone(e.classname);
2441         ent.aiment_deadflag = e.deadflag;
2442 }
2443 void UnsetMovetypeFollow(entity ent)
2444 {
2445         ent.movetype = MOVETYPE_FLY;
2446         PROJECTILE_MAKETRIGGER(ent);
2447         ent.aiment = world;
2448 }
2449 float LostMovetypeFollow(entity ent)
2450 {
2451 /*
2452         if(ent.movetype != MOVETYPE_FOLLOW)
2453                 if(ent.aiment)
2454                         error("???");
2455 */
2456         if(ent.aiment)
2457         {
2458                 if(ent.aiment.classname != ent.aiment_classname)
2459                         return 1;
2460                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2461                         return 1;
2462         }
2463         return 0;
2464 }
2465
2466 float isPushable(entity e)
2467 {
2468         if(e.iscreature)
2469                 return TRUE;
2470         if(e.pushable)
2471                 return TRUE;
2472         switch(e.classname)
2473         {
2474                 case "body":
2475                 case "droppedweapon":
2476                 case "keepawayball":
2477                 case "nexball_basketball":
2478                 case "nexball_football":
2479                         return TRUE;
2480                 case "bullet": // antilagged bullets can't hit this either
2481                         return FALSE;
2482         }
2483         if (e.projectiledeathtype)
2484                 return TRUE;
2485         return FALSE;
2486 }