qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "resources.qh"
  11 #include "items.qh"
  12 #include "player.qh"
  13 #include "weapons/accuracy.qh"
  14 #include "weapons/csqcprojectile.qh"
  15 #include "weapons/selection.qh"
  16 #include "../common/command/_mod.qh"
  17 #include "../common/constants.qh"
  18 #include <common/net_linked.qh>
  19 #include <common/weapons/weapon/crylink.qh>
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/mapinfo.qh"
  22 #include "../common/notifications/all.qh"
  23 #include "../common/playerstats.qh"
  24 #include "../common/teams.qh"
  25 #include "../common/mapobjects/subs.qh"
  26 #include "../common/util.qh"
  27 #include "../common/turrets/sv_turrets.qh"
  28 #include <common/weapons/_all.qh>
  29 #include "../common/vehicles/sv_vehicles.qh"
  30 #include "../common/vehicles/vehicle.qh"
  31 #include "../common/items/_mod.qh"
  32 #include "../common/state.qh"
  33 #include "../common/effects/qc/globalsound.qh"
  34 #include "../common/wepent.qh"
  35 #include "../lib/csqcmodel/sv_model.qh"
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/server.qh"
  38
  39 void crosshair_trace(entity pl)
  40 {
  41         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  42 }
  43
  44 void crosshair_trace_plusvisibletriggers(entity pl)
  45 {
  46         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  47 }
  48
  49 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  50 {
  51         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  52 }
  53
  54 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  55 {
  56         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  57         {
  58                 if(it.model != "")
  59                 {
  60                         it.solid = SOLID_BSP;
  61                         IL_PUSH(g_ctrace_changed, it);
  62                 }
  63         });
  64
  65         if (is_wz)
  66                 WarpZone_crosshair_trace(pl);
  67         else
  68                 crosshair_trace(pl);
  69
  70         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  71
  72         IL_CLEAR(g_ctrace_changed);
  73 }
  74
  75 void WarpZone_crosshair_trace(entity pl)
  76 {
  77         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  78 }
  79
  80 void dedicated_print(string input)
  81 {
  82         if (server_is_dedicated) print(input);
  83 }
  84
  85 void GameLogEcho(string s)
  86 {
  87     string fn;
  88     int matches;
  89
  90     if (autocvar_sv_eventlog_files)
  91     {
  92         if (!logfile_open)
  93         {
  94             logfile_open = true;
  95             matches = autocvar_sv_eventlog_files_counter + 1;
  96             cvar_set("sv_eventlog_files_counter", itos(matches));
  97             fn = ftos(matches);
  98             if (strlen(fn) < 8)
  99                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 100             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 101             logfile = fopen(fn, FILE_APPEND);
 102             fputs(logfile, ":logversion:3\n");
 103         }
 104         if (logfile >= 0)
 105         {
 106             if (autocvar_sv_eventlog_files_timestamps)
 107                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 108             else
 109                 fputs(logfile, strcat(s, "\n"));
 110         }
 111     }
 112     if (autocvar_sv_eventlog_console)
 113     {
 114         dedicated_print(strcat(s, "\n"));
 115     }
 116 }
 117
 118 void GameLogInit()
 119 {
 120     logfile_open = 0;
 121     // will be opened later
 122 }
 123
 124 void GameLogClose()
 125 {
 126     if (logfile_open && logfile >= 0)
 127     {
 128         fclose(logfile);
 129         logfile = -1;
 130     }
 131 }
 132
 133 entity findnearest(vector point, bool checkitems, vector axismod)
 134 {
 135     vector dist;
 136     int num_nearest = 0;
 137
 138     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 139     {
 140         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 141             dist = it.oldorigin;
 142         else
 143             dist = it.origin;
 144         dist = dist - point;
 145         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 146         float len = vlen2(dist);
 147
 148         int l;
 149         for (l = 0; l < num_nearest; ++l)
 150         {
 151             if (len < nearest_length[l])
 152                 break;
 153         }
 154
 155         // now i tells us where to insert at
 156         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 157         if (l < NUM_NEAREST_ENTITIES)
 158         {
 159             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 160             {
 161                 nearest_length[j + 1] = nearest_length[j];
 162                 nearest_entity[j + 1] = nearest_entity[j];
 163             }
 164             nearest_length[l] = len;
 165             nearest_entity[l] = it;
 166             if (num_nearest < NUM_NEAREST_ENTITIES)
 167                 num_nearest = num_nearest + 1;
 168         }
 169     });
 170
 171     // now use the first one from our list that we can see
 172     for (int j = 0; j < num_nearest; ++j)
 173     {
 174         traceline(point, nearest_entity[j].origin, true, NULL);
 175         if (trace_fraction == 1)
 176         {
 177             if (j != 0)
 178                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 179             return nearest_entity[j];
 180         }
 181     }
 182
 183     if (num_nearest == 0)
 184         return NULL;
 185
 186     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 187     /* DEBUGGING CODE:
 188     dprint("Candidates were: ");
 189     for(j = 0; j < num_nearest; ++j)
 190     {
 191         if(j != 0)
 192                 dprint(", ");
 193         dprint(nearest_entity[j].netname);
 194     }
 195     dprint("\n");
 196     */
 197
 198     return nearest_entity[0];
 199 }
 200
 201 string NearestLocation(vector p)
 202 {
 203     string ret = "somewhere";
 204     entity loc = findnearest(p, false, '1 1 1');
 205     if (loc)
 206         ret = loc.message;
 207     else
 208     {
 209         loc = findnearest(p, true, '1 1 4');
 210         if (loc)
 211             ret = loc.netname;
 212     }
 213     return ret;
 214 }
 215
 216 string AmmoNameFromWeaponentity(Weapon wep)
 217 {
 218         string ammoitems = "batteries";
 219         switch (wep.ammo_type)
 220         {
 221                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 222                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 223                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 224                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 225                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 226                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 227         }
 228         return ammoitems;
 229 }
 230
 231 string formatmessage(entity this, string msg)
 232 {
 233         float p, p1, p2;
 234         float n;
 235         vector cursor = '0 0 0';
 236         entity cursor_ent = NULL;
 237         string escape;
 238         string replacement;
 239         p = 0;
 240         n = 7;
 241         bool traced = false;
 242
 243         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 244         msg = M_ARGV(1, string);
 245
 246         while (1) {
 247                 if (n < 1)
 248                         break; // too many replacements
 249
 250                 n = n - 1;
 251                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 252                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 253
 254                 if (p1 < 0)
 255                         p1 = p2;
 256
 257                 if (p2 < 0)
 258                         p2 = p1;
 259
 260                 p = min(p1, p2);
 261
 262                 if (p < 0)
 263                         break;
 264
 265                 if(!traced)
 266                 {
 267                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 268                         cursor = trace_endpos;
 269                         cursor_ent = trace_ent;
 270                         traced = true;
 271                 }
 272
 273                 replacement = substring(msg, p, 2);
 274                 escape = substring(msg, p + 1, 1);
 275
 276                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 277
 278                 switch(escape)
 279                 {
 280                         case "%": replacement = "%"; break;
 281                         case "\\":replacement = "\\"; break;
 282                         case "n": replacement = "\n"; break;
 283                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 284                         case "h": replacement = ftos(floor(GetResource(this, RES_HEALTH))); break;
 285                         case "l": replacement = NearestLocation(this.origin); break;
 286                         case "y": replacement = NearestLocation(cursor); break;
 287                         case "d": replacement = NearestLocation(this.death_origin); break;
 288                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 289                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity).m_weapon); break;
 290                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 291                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 292                         case "S": replacement = ftos(vlen(this.velocity)); break;
 293                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 294                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 295                         default:
 296                         {
 297                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 298                                 replacement = M_ARGV(2, string);
 299                                 break;
 300                         }
 301                 }
 302
 303                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 304                 p = p + strlen(replacement);
 305         }
 306         return msg;
 307 }
 308
 309 /*
 310 =============
 311 GetCvars
 312 =============
 313 Called with:
 314   0:  sends the request
 315   >0: receives a cvar from name=argv(f) value=argv(f+1)
 316 */
 317 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 318 {
 319         if (f < 0)
 320         {
 321                 strfree(store.(field));
 322         }
 323         else if (f > 0)
 324         {
 325                 if (thisname == name)
 326                 {
 327                         strcpy(store.(field), argv(f + 1));
 328                 }
 329         }
 330         else
 331                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 332 }
 333 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 334 {
 335         GetCvars_handleString(this, store, thisname, f, field, name);
 336         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 337                 if (thisname == name)
 338                 {
 339                         string s = func(this, strcat1(store.(field)));
 340                         if (s != store.(field))
 341                         {
 342                                 strcpy(store.(field), s);
 343                         }
 344                 }
 345 }
 346 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 347 {
 348         if (f < 0)
 349         {
 350         }
 351         else if (f > 0)
 352         {
 353                 if (thisname == name)
 354                         store.(field) = stof(argv(f + 1));
 355         }
 356         else
 357                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 358 }
 359 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 360 {
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (!store.(field))
 369                         {
 370                                 store.(field) = stof(argv(f + 1));
 371                                 if (!store.(field))
 372                                         store.(field) = -1;
 373                         }
 374                 }
 375         }
 376         else
 377         {
 378                 if (!store.(field))
 379                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 380         }
 381 }
 382 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 383 {
 384         string o = W_FixWeaponOrder_ForceComplete(wo);
 385         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 386         return o;
 387 }
 388
 389 REPLICATE(autoswitch, bool, "cl_autoswitch");
 390
 391 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 392
 393 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 394
 395 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 396
 397 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 398
 399 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 400
 401 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 402
 403 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 404
 405 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 406
 407 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 408
 409 REPLICATE(cvar_cl_physics, string, "cl_physics");
 410
 411 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 412
 413 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 414
 415 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 416
 417 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 418
 419 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 420
 421 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 422
 423 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 424
 425 /**
 426  * @param f -1: cleanup, 0: request, 1: receive
 427  */
 428 void GetCvars(entity this, entity store, int f)
 429 {
 430         string s = string_null;
 431
 432         if (f > 0)
 433                 s = strcat1(argv(f));
 434
 435         get_cvars_f = f;
 436         get_cvars_s = s;
 437         MUTATOR_CALLHOOK(GetCvars);
 438
 439         Notification_GetCvars(this);
 440
 441         ReplicateVars(this, store, s, f);
 442
 443         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 444         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 445         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 446         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 447         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 448         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 449         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 450         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 451         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 452         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 453         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 454
 455         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 456
 457         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 458         if (f > 0)
 459         {
 460                 if (s == "cl_weaponpriority")
 461                 {
 462                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 463                         {
 464                                 .entity weaponentity = weaponentities[slot];
 465                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 466                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 467                         }
 468                 }
 469                 if (s == "cl_allow_uidtracking")
 470                         PlayerStats_GameReport_AddPlayer(this);
 471         }
 472 }
 473
 474 // decolorizes and team colors the player name when needed
 475 string playername(entity p, bool team_colorize)
 476 {
 477     string t;
 478     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 479     {
 480         t = Team_ColorCode(p.team);
 481         return strcat(t, strdecolorize(p.netname));
 482     }
 483     else
 484         return p.netname;
 485 }
 486
 487 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 488 {
 489         int i = weaponinfo.m_id;
 490         int d = 0;
 491         bool allow_mutatorblocked = false;
 492
 493         if(!i)
 494                 return 0;
 495
 496         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 497         d = M_ARGV(1, float);
 498         allguns = M_ARGV(2, bool);
 499         allow_mutatorblocked = M_ARGV(3, bool);
 500
 501         if(allguns)
 502                 d = boolean(weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 503         else if(!mutator_returnvalue)
 504                 d = !(!weaponinfo.weaponstart);
 505
 506         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 507                 d = 0;
 508
 509         float t = weaponinfo.weaponstartoverride;
 510
 511         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 512
 513         // bit order in t:
 514         // 1: want or not
 515         // 2: is default?
 516         // 4: is set by default?
 517         if(t < 0)
 518                 t = 4 | (3 * d);
 519         else
 520                 t |= (2 * d);
 521
 522         return t;
 523 }
 524
 525 void readplayerstartcvars()
 526 {
 527         float i, t;
 528         string s;
 529
 530         // initialize starting values for players
 531         start_weapons = '0 0 0';
 532         start_weapons_default = '0 0 0';
 533         start_weapons_defaultmask = '0 0 0';
 534         start_items = 0;
 535         start_ammo_shells = 0;
 536         start_ammo_nails = 0;
 537         start_ammo_rockets = 0;
 538         start_ammo_cells = 0;
 539         start_ammo_plasma = 0;
 540         if (random_start_ammo == NULL)
 541         {
 542                 random_start_ammo = spawn();
 543         }
 544         start_health = cvar("g_balance_health_start");
 545         start_armorvalue = cvar("g_balance_armor_start");
 546
 547         g_weaponarena = 0;
 548         g_weaponarena_weapons = '0 0 0';
 549
 550         s = cvar_string("g_weaponarena");
 551
 552         MUTATOR_CALLHOOK(SetWeaponArena, s);
 553         s = M_ARGV(0, string);
 554
 555         if (s == "0" || s == "")
 556         {
 557                 // no arena
 558         }
 559         else if (s == "off")
 560         {
 561                 // forcibly turn off weaponarena
 562         }
 563         else if (s == "all" || s == "1")
 564         {
 565                 g_weaponarena = 1;
 566                 g_weaponarena_list = "All Weapons";
 567                 FOREACH(Weapons, it != WEP_Null, {
 568                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 569                                 g_weaponarena_weapons |= (it.m_wepset);
 570                 });
 571         }
 572         else if (s == "devall")
 573         {
 574                 g_weaponarena = 1;
 575                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 576                 FOREACH(Weapons, it != WEP_Null,
 577                 {
 578                         g_weaponarena_weapons |= (it.m_wepset);
 579                 });
 580         }
 581         else if (s == "most")
 582         {
 583                 g_weaponarena = 1;
 584                 g_weaponarena_list = "Most Weapons";
 585                 FOREACH(Weapons, it != WEP_Null, {
 586                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 587                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 588                                         g_weaponarena_weapons |= (it.m_wepset);
 589                 });
 590         }
 591         else if (s == "none")
 592         {
 593                 g_weaponarena = 1;
 594                 g_weaponarena_list = "No Weapons";
 595         }
 596         else
 597         {
 598                 g_weaponarena = 1;
 599                 t = tokenize_console(s);
 600                 g_weaponarena_list = "";
 601                 for (i = 0; i < t; ++i)
 602                 {
 603                         s = argv(i);
 604                         Weapon wep = Weapons_fromstr(s);
 605                         if(wep != WEP_Null)
 606                         {
 607                                 g_weaponarena_weapons |= (wep.m_wepset);
 608                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 609                         }
 610                 }
 611                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 612         }
 613
 614         if (g_weaponarena)
 615         {
 616                 g_weapon_stay = 0; // incompatible
 617                 start_weapons = g_weaponarena_weapons;
 618                 start_items |= IT_UNLIMITED_AMMO;
 619         }
 620         else
 621         {
 622                 FOREACH(Weapons, it != WEP_Null, {
 623                         int w = want_weapon(it, false);
 624                         WepSet s = it.m_wepset;
 625                         if(w & 1)
 626                                 start_weapons |= s;
 627                         if(w & 2)
 628                                 start_weapons_default |= s;
 629                         if(w & 4)
 630                                 start_weapons_defaultmask |= s;
 631                 });
 632         }
 633
 634         if(cvar("g_balance_superweapons_time") < 0)
 635                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 636
 637         if(!cvar("g_use_ammunition"))
 638                 start_items |= IT_UNLIMITED_AMMO;
 639
 640         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 641         {
 642                 start_ammo_shells = 999;
 643                 start_ammo_nails = 999;
 644                 start_ammo_rockets = 999;
 645                 start_ammo_cells = 999;
 646                 start_ammo_plasma = 999;
 647                 start_ammo_fuel = 999;
 648         }
 649         else
 650         {
 651                 start_ammo_shells = cvar("g_start_ammo_shells");
 652                 start_ammo_nails = cvar("g_start_ammo_nails");
 653                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 654                 start_ammo_cells = cvar("g_start_ammo_cells");
 655                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 656                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 657                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 658                 SetResource(random_start_ammo, RES_SHELLS, cvar(
 659                         "g_random_start_shells"));
 660                 SetResource(random_start_ammo, RES_BULLETS, cvar(
 661                         "g_random_start_bullets"));
 662                 SetResource(random_start_ammo, RES_ROCKETS,
 663                         cvar("g_random_start_rockets"));
 664                 SetResource(random_start_ammo, RES_CELLS, cvar(
 665                         "g_random_start_cells"));
 666                 SetResource(random_start_ammo, RES_PLASMA, cvar(
 667                         "g_random_start_plasma"));
 668         }
 669
 670         if (warmup_stage)
 671         {
 672                 warmup_start_ammo_shells = start_ammo_shells;
 673                 warmup_start_ammo_nails = start_ammo_nails;
 674                 warmup_start_ammo_rockets = start_ammo_rockets;
 675                 warmup_start_ammo_cells = start_ammo_cells;
 676                 warmup_start_ammo_plasma = start_ammo_plasma;
 677                 warmup_start_ammo_fuel = start_ammo_fuel;
 678                 warmup_start_health = start_health;
 679                 warmup_start_armorvalue = start_armorvalue;
 680                 warmup_start_weapons = start_weapons;
 681                 warmup_start_weapons_default = start_weapons_default;
 682                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 683
 684                 if (!g_weaponarena && !g_ca && !g_freezetag)
 685                 {
 686                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 687                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 688                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 689                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 690                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 691                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 692                         warmup_start_health = cvar("g_warmup_start_health");
 693                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 694                         warmup_start_weapons = '0 0 0';
 695                         warmup_start_weapons_default = '0 0 0';
 696                         warmup_start_weapons_defaultmask = '0 0 0';
 697                         FOREACH(Weapons, it != WEP_Null, {
 698                                 int w = want_weapon(it, g_warmup_allguns);
 699                                 WepSet s = (it.m_wepset);
 700                                 if(w & 1)
 701                                         warmup_start_weapons |= s;
 702                                 if(w & 2)
 703                                         warmup_start_weapons_default |= s;
 704                                 if(w & 4)
 705                                         warmup_start_weapons_defaultmask |= s;
 706                         });
 707                 }
 708         }
 709
 710         if (g_jetpack)
 711                 start_items |= ITEM_Jetpack.m_itemid;
 712
 713         MUTATOR_CALLHOOK(SetStartItems);
 714
 715         if (start_items & ITEM_Jetpack.m_itemid)
 716         {
 717                 start_items |= ITEM_JetpackRegen.m_itemid;
 718                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 719                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 720         }
 721
 722         WepSet precache_weapons = start_weapons;
 723         if (g_warmup_allguns != 1)
 724                 precache_weapons |= warmup_start_weapons;
 725         FOREACH(Weapons, it != WEP_Null, {
 726                 if(precache_weapons & (it.m_wepset))
 727                         it.wr_init(it);
 728         });
 729
 730         start_ammo_shells = max(0, start_ammo_shells);
 731         start_ammo_nails = max(0, start_ammo_nails);
 732         start_ammo_rockets = max(0, start_ammo_rockets);
 733         start_ammo_cells = max(0, start_ammo_cells);
 734         start_ammo_plasma = max(0, start_ammo_plasma);
 735         start_ammo_fuel = max(0, start_ammo_fuel);
 736         SetResource(random_start_ammo, RES_SHELLS, max(0,
 737                 GetResource(random_start_ammo, RES_SHELLS)));
 738         SetResource(random_start_ammo, RES_BULLETS, max(0,
 739                 GetResource(random_start_ammo, RES_BULLETS)));
 740         SetResource(random_start_ammo, RES_ROCKETS, max(0,
 741                 GetResource(random_start_ammo, RES_ROCKETS)));
 742         SetResource(random_start_ammo, RES_CELLS, max(0,
 743                 GetResource(random_start_ammo, RES_CELLS)));
 744         SetResource(random_start_ammo, RES_PLASMA, max(0,
 745                 GetResource(random_start_ammo, RES_PLASMA)));
 746
 747         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 748         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 749         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 750         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 751         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 752         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 753 }
 754
 755 void precache_playermodel(string m)
 756 {
 757         float globhandle, i, n;
 758         string f;
 759
 760         if(substring(m, -9,5) == "_lod1")
 761                 return;
 762         if(substring(m, -9,5) == "_lod2")
 763                 return;
 764         precache_model(m);
 765         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 766         if(fexists(f))
 767                 precache_model(f);
 768         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 769         if(fexists(f))
 770                 precache_model(f);
 771
 772         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 773         if (globhandle < 0)
 774                 return;
 775         n = search_getsize(globhandle);
 776         for (i = 0; i < n; ++i)
 777         {
 778                 //print(search_getfilename(globhandle, i), "\n");
 779                 f = search_getfilename(globhandle, i);
 780                 PrecachePlayerSounds(f);
 781         }
 782         search_end(globhandle);
 783 }
 784 void precache_all_playermodels(string pattern)
 785 {
 786         int globhandle = search_begin(pattern, true, false);
 787         if (globhandle < 0) return;
 788         int n = search_getsize(globhandle);
 789         for (int i = 0; i < n; ++i)
 790         {
 791                 string s = search_getfilename(globhandle, i);
 792                 precache_playermodel(s);
 793         }
 794         search_end(globhandle);
 795 }
 796
 797 void precache_playermodels(string s)
 798 {
 799         FOREACH_WORD(s, true, { precache_playermodel(it); });
 800 }
 801
 802 void precache()
 803 {
 804     // gamemode related things
 805
 806     // Precache all player models if desired
 807     if (autocvar_sv_precacheplayermodels)
 808     {
 809         PrecachePlayerSounds("sound/player/default.sounds");
 810         precache_all_playermodels("models/player/*.zym");
 811         precache_all_playermodels("models/player/*.dpm");
 812         precache_all_playermodels("models/player/*.md3");
 813         precache_all_playermodels("models/player/*.psk");
 814         precache_all_playermodels("models/player/*.iqm");
 815     }
 816
 817     if (autocvar_sv_defaultcharacter)
 818     {
 819                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 820                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 821                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 822                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 823                 precache_playermodels(autocvar_sv_defaultplayermodel);
 824     }
 825
 826 #if 0
 827     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 828
 829     if (!this.noise && this.music) // quake 3 uses the music field
 830         this.noise = this.music;
 831
 832     // plays music for the level if there is any
 833     if (this.noise)
 834     {
 835         precache_sound (this.noise);
 836         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 837     }
 838 #endif
 839 }
 840
 841
 842 void make_safe_for_remove(entity e)
 843 {
 844     if (e.initialize_entity)
 845     {
 846         entity ent, prev = NULL;
 847         for (ent = initialize_entity_first; ent; )
 848         {
 849             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 850             {
 851                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 852                 // skip it in linked list
 853                 if (prev)
 854                 {
 855                     prev.initialize_entity_next = ent.initialize_entity_next;
 856                     ent = prev.initialize_entity_next;
 857                 }
 858                 else
 859                 {
 860                     initialize_entity_first = ent.initialize_entity_next;
 861                     ent = initialize_entity_first;
 862                 }
 863             }
 864             else
 865             {
 866                 prev = ent;
 867                 ent = ent.initialize_entity_next;
 868             }
 869         }
 870     }
 871 }
 872
 873 .float remove_except_protected_forbidden;
 874 void remove_except_protected(entity e)
 875 {
 876         if(e.remove_except_protected_forbidden)
 877                 error("not allowed to remove this at this point");
 878         builtin_remove(e);
 879 }
 880
 881 void remove_unsafely(entity e)
 882 {
 883     if(e.classname == "spike")
 884         error("Removing spikes is forbidden (crylink bug), please report");
 885     builtin_remove(e);
 886 }
 887
 888 void remove_safely(entity e)
 889 {
 890     make_safe_for_remove(e);
 891     builtin_remove(e);
 892 }
 893
 894 void InitializeEntity(entity e, void(entity this) func, int order)
 895 {
 896     entity prev, cur;
 897
 898     if (!e || e.initialize_entity)
 899     {
 900         // make a proxy initializer entity
 901         entity e_old = e;
 902         e = new(initialize_entity);
 903         e.enemy = e_old;
 904     }
 905
 906     e.initialize_entity = func;
 907     e.initialize_entity_order = order;
 908
 909     cur = initialize_entity_first;
 910     prev = NULL;
 911     for (;;)
 912     {
 913         if (!cur || cur.initialize_entity_order > order)
 914         {
 915             // insert between prev and cur
 916             if (prev)
 917                 prev.initialize_entity_next = e;
 918             else
 919                 initialize_entity_first = e;
 920             e.initialize_entity_next = cur;
 921             return;
 922         }
 923         prev = cur;
 924         cur = cur.initialize_entity_next;
 925     }
 926 }
 927 void InitializeEntitiesRun()
 928 {
 929     entity startoflist = initialize_entity_first;
 930     initialize_entity_first = NULL;
 931     delete_fn = remove_except_protected;
 932     for (entity e = startoflist; e; e = e.initialize_entity_next)
 933     {
 934                 e.remove_except_protected_forbidden = 1;
 935     }
 936     for (entity e = startoflist; e; )
 937     {
 938                 e.remove_except_protected_forbidden = 0;
 939         e.initialize_entity_order = 0;
 940         entity next = e.initialize_entity_next;
 941         e.initialize_entity_next = NULL;
 942         var void(entity this) func = e.initialize_entity;
 943         e.initialize_entity = func_null;
 944         if (e.classname == "initialize_entity")
 945         {
 946             entity wrappee = e.enemy;
 947             builtin_remove(e);
 948             e = wrappee;
 949         }
 950         //dprint("Delayed initialization: ", e.classname, "\n");
 951         if (func)
 952         {
 953                 func(e);
 954         }
 955         else
 956         {
 957             eprint(e);
 958             backtrace(strcat("Null function in: ", e.classname, "\n"));
 959         }
 960         e = next;
 961     }
 962     delete_fn = remove_unsafely;
 963 }
 964
 965 .float(entity) isEliminated;
 966 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 967 {
 968         Stream out = MSG_ENTITY;
 969         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 970         serialize(byte, out, sendflags);
 971         if (sendflags & 1) {
 972                 for (int i = 1; i <= maxclients; i += 8) {
 973                         int f = 0;
 974                         entity e = edict_num(i);
 975                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 976                                 if (eliminatedPlayers.isEliminated(e)) {
 977                                         f |= BIT(b);
 978                                 }
 979                         }
 980                         serialize(byte, out, f);
 981                 }
 982         }
 983         return true;
 984 }
 985
 986 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 987 {
 988         if(eliminatedPlayers)
 989         {
 990                 backtrace("Can't spawn eliminatedPlayers again!");
 991                 return;
 992         }
 993         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 994         eliminatedPlayers.isEliminated = isEliminated_func;
 995 }
 996
 997
 998
 999
1000 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1001 {
1002         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1003                 this.projectiledeathtype |= HITTYPE_SPLASH;
1004         adaptor_think2use(this);
1005 }
1006
1007 // deferred dropping
1008 void DropToFloor_Handler(entity this)
1009 {
1010     WITHSELF(this, builtin_droptofloor());
1011     this.dropped_origin = this.origin;
1012 }
1013
1014 void droptofloor(entity this)
1015 {
1016     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1017 }
1018
1019
1020
1021 float trace_hits_box_a0, trace_hits_box_a1;
1022
1023 float trace_hits_box_1d(float end, float thmi, float thma)
1024 {
1025     if (end == 0)
1026     {
1027         // just check if x is in range
1028         if (0 < thmi)
1029             return false;
1030         if (0 > thma)
1031             return false;
1032     }
1033     else
1034     {
1035         // do the trace with respect to x
1036         // 0 -> end has to stay in thmi -> thma
1037         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1038         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1039         if (trace_hits_box_a0 > trace_hits_box_a1)
1040             return false;
1041     }
1042     return true;
1043 }
1044
1045 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1046 {
1047     end -= start;
1048     thmi -= start;
1049     thma -= start;
1050     // now it is a trace from 0 to end
1051
1052     trace_hits_box_a0 = 0;
1053     trace_hits_box_a1 = 1;
1054
1055     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1056         return false;
1057     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1058         return false;
1059     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1060         return false;
1061
1062     return true;
1063 }
1064
1065 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1066 {
1067     return trace_hits_box(start, end, thmi - ma, thma - mi);
1068 }
1069
1070 bool SUB_NoImpactCheck(entity this, entity toucher)
1071 {
1072         // zero hitcontents = this is not the real impact, but either the
1073         // mirror-impact of something hitting the projectile instead of the
1074         // projectile hitting the something, or a touchareagrid one. Neither of
1075         // these stop the projectile from moving, so...
1076         if(trace_dphitcontents == 0)
1077         {
1078                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1079                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1080         }
1081     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1082         return true;
1083     if (toucher == NULL && this.size != '0 0 0')
1084     {
1085         vector tic;
1086         tic = this.velocity * sys_frametime;
1087         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1088         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1089         if (trace_fraction >= 1)
1090         {
1091             LOG_TRACE("Odd... did not hit...?");
1092         }
1093         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1094         {
1095             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1096             return true;
1097         }
1098     }
1099
1100     return false;
1101 }
1102
1103 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1104
1105 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1106 {
1107         if(SUB_OwnerCheck(this, toucher))
1108                 return true;
1109         if(SUB_NoImpactCheck(this, toucher))
1110         {
1111                 if(this.classname == "nade")
1112                         return false; // no checks here
1113                 else if(this.classname == "grapplinghook")
1114                         RemoveHook(this);
1115                 else if(this.classname == "spike")
1116                 {
1117                         W_Crylink_Dequeue(this);
1118                         delete(this);
1119                 }
1120                 else
1121                         delete(this);
1122                 return true;
1123         }
1124         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1125                 UpdateCSQCProjectile(this);
1126         return false;
1127 }
1128
1129 /** engine callback */
1130 void URI_Get_Callback(float id, float status, string data)
1131 {
1132         if(url_URI_Get_Callback(id, status, data))
1133         {
1134                 // handled
1135         }
1136         else if (id == URI_GET_DISCARD)
1137         {
1138                 // discard
1139         }
1140         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1141         {
1142                 // sv_cmd curl
1143                 Curl_URI_Get_Callback(id, status, data);
1144         }
1145         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1146         {
1147                 // online ban list
1148                 OnlineBanList_URI_Get_Callback(id, status, data);
1149         }
1150         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1151         {
1152                 // handled by a mutator
1153         }
1154         else
1155         {
1156                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1157         }
1158 }
1159
1160 string uid2name(string myuid) {
1161         string s;
1162         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1163
1164         // FIXME remove this later after 0.6 release
1165         // convert old style broken records to correct style
1166         if(s == "")
1167         {
1168                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1169                 if(s != "")
1170                 {
1171                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1172                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1173                 }
1174         }
1175
1176         if(s == "")
1177                 s = "^1Unregistered Player";
1178         return s;
1179 }
1180
1181 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1182 {
1183     float m, i;
1184     vector start, org, delta, end, enddown, mstart;
1185
1186     m = e.dphitcontentsmask;
1187     e.dphitcontentsmask = goodcontents | badcontents;
1188
1189     org = boundmin;
1190     delta = boundmax - boundmin;
1191
1192     start = end = org;
1193
1194     for (i = 0; i < attempts; ++i)
1195     {
1196         start.x = org.x + random() * delta.x;
1197         start.y = org.y + random() * delta.y;
1198         start.z = org.z + random() * delta.z;
1199
1200         // rule 1: start inside world bounds, and outside
1201         // solid, and don't start from somewhere where you can
1202         // fall down to evil
1203         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1204         if (trace_fraction >= 1)
1205             continue;
1206         if (trace_startsolid)
1207             continue;
1208         if (trace_dphitcontents & badcontents)
1209             continue;
1210         if (trace_dphitq3surfaceflags & badsurfaceflags)
1211             continue;
1212
1213         // rule 2: if we are too high, lower the point
1214         if (trace_fraction * delta.z > maxaboveground)
1215             start = trace_endpos + '0 0 1' * maxaboveground;
1216         enddown = trace_endpos;
1217
1218         // rule 3: make sure we aren't outside the map. This only works
1219         // for somewhat well formed maps. A good rule of thumb is that
1220         // the map should have a convex outside hull.
1221         // these can be traceLINES as we already verified the starting box
1222         mstart = start + 0.5 * (e.mins + e.maxs);
1223         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1224         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1225             continue;
1226         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1227         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1228             continue;
1229         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1230         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1231             continue;
1232         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1233         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1234             continue;
1235         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1236         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1237             continue;
1238
1239         // rule 4: we must "see" some spawnpoint or item
1240     entity sp = NULL;
1241     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1242     {
1243         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1244         {
1245                 sp = it;
1246                 break;
1247         }
1248     });
1249         if(!sp)
1250         {
1251                 int items_checked = 0;
1252                 IL_EACH(g_items, checkpvs(mstart, it),
1253                 {
1254                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1255                         {
1256                                 sp = it;
1257                                 break;
1258                         }
1259
1260                         ++items_checked;
1261                         if(items_checked >= attempts)
1262                                 break; // sanity
1263                 });
1264
1265                 if(!sp)
1266                         continue;
1267         }
1268
1269         // find a random vector to "look at"
1270         end.x = org.x + random() * delta.x;
1271         end.y = org.y + random() * delta.y;
1272         end.z = org.z + random() * delta.z;
1273         end = start + normalize(end - start) * vlen(delta);
1274
1275         // rule 4: start TO end must not be too short
1276         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1277         if (trace_startsolid)
1278             continue;
1279         if (trace_fraction < minviewdistance / vlen(delta))
1280             continue;
1281
1282         // rule 5: don't want to look at sky
1283         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1284             continue;
1285
1286         // rule 6: we must not end up in trigger_hurt
1287         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1288             continue;
1289
1290         break;
1291     }
1292
1293     e.dphitcontentsmask = m;
1294
1295     if (i < attempts)
1296     {
1297         setorigin(e, start);
1298         e.angles = vectoangles(end - start);
1299         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1300         return true;
1301     }
1302     else
1303         return false;
1304 }
1305
1306 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1307 {
1308         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1309 }
1310
1311 void write_recordmarker(entity pl, float tstart, float dt)
1312 {
1313     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1314
1315     // also write a marker into demo files for demotc-race-record-extractor to find
1316     stuffcmd(pl,
1317              strcat(
1318                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1319                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1320 }
1321
1322 void attach_sameorigin(entity e, entity to, string tag)
1323 {
1324     vector org, t_forward, t_left, t_up, e_forward, e_up;
1325     float tagscale;
1326
1327     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1328     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1329     t_forward = v_forward * tagscale;
1330     t_left = v_right * -tagscale;
1331     t_up = v_up * tagscale;
1332
1333     e.origin_x = org * t_forward;
1334     e.origin_y = org * t_left;
1335     e.origin_z = org * t_up;
1336
1337     // current forward and up directions
1338     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1339                 e.angles = AnglesTransform_FromVAngles(e.angles);
1340         else
1341                 e.angles = AnglesTransform_FromAngles(e.angles);
1342     fixedmakevectors(e.angles);
1343
1344     // untransform forward, up!
1345     e_forward.x = v_forward * t_forward;
1346     e_forward.y = v_forward * t_left;
1347     e_forward.z = v_forward * t_up;
1348     e_up.x = v_up * t_forward;
1349     e_up.y = v_up * t_left;
1350     e_up.z = v_up * t_up;
1351
1352     e.angles = fixedvectoangles2(e_forward, e_up);
1353     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1354                 e.angles = AnglesTransform_ToVAngles(e.angles);
1355         else
1356                 e.angles = AnglesTransform_ToAngles(e.angles);
1357
1358     setattachment(e, to, tag);
1359     setorigin(e, e.origin);
1360 }
1361
1362 void detach_sameorigin(entity e)
1363 {
1364     vector org;
1365     org = gettaginfo(e, 0);
1366     e.angles = fixedvectoangles2(v_forward, v_up);
1367     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1368                 e.angles = AnglesTransform_ToVAngles(e.angles);
1369         else
1370                 e.angles = AnglesTransform_ToAngles(e.angles);
1371     setorigin(e, org);
1372     setattachment(e, NULL, "");
1373     setorigin(e, e.origin);
1374 }
1375
1376 void follow_sameorigin(entity e, entity to)
1377 {
1378     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1379     e.aiment = to; // make the hole follow bmodel
1380     e.punchangle = to.angles; // the original angles of bmodel
1381     e.view_ofs = e.origin - to.origin; // relative origin
1382     e.v_angle = e.angles - to.angles; // relative angles
1383 }
1384
1385 void unfollow_sameorigin(entity e)
1386 {
1387     set_movetype(e, MOVETYPE_NONE);
1388 }
1389
1390 entity gettaginfo_relative_ent;
1391 vector gettaginfo_relative(entity e, float tag)
1392 {
1393     if (!gettaginfo_relative_ent)
1394     {
1395         gettaginfo_relative_ent = spawn();
1396         gettaginfo_relative_ent.effects = EF_NODRAW;
1397     }
1398     gettaginfo_relative_ent.model = e.model;
1399     gettaginfo_relative_ent.modelindex = e.modelindex;
1400     gettaginfo_relative_ent.frame = e.frame;
1401     return gettaginfo(gettaginfo_relative_ent, tag);
1402 }
1403
1404 .string aiment_classname;
1405 .float aiment_deadflag;
1406 void SetMovetypeFollow(entity ent, entity e)
1407 {
1408         // FIXME this may not be warpzone aware
1409         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1410         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1411         ent.aiment = e; // make the hole follow bmodel
1412         ent.punchangle = e.angles; // the original angles of bmodel
1413         ent.view_ofs = ent.origin - e.origin; // relative origin
1414         ent.v_angle = ent.angles - e.angles; // relative angles
1415         ent.aiment_classname = strzone(e.classname);
1416         ent.aiment_deadflag = e.deadflag;
1417 }
1418 void UnsetMovetypeFollow(entity ent)
1419 {
1420         set_movetype(ent, MOVETYPE_FLY);
1421         PROJECTILE_MAKETRIGGER(ent);
1422         ent.aiment = NULL;
1423 }
1424 float LostMovetypeFollow(entity ent)
1425 {
1426 /*
1427         if(ent.move_movetype != MOVETYPE_FOLLOW)
1428                 if(ent.aiment)
1429                         error("???");
1430 */
1431         if(ent.aiment)
1432         {
1433                 if(ent.aiment.classname != ent.aiment_classname)
1434                         return 1;
1435                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1436                         return 1;
1437         }
1438         return 0;
1439 }
1440
1441 .bool pushable;
1442 bool isPushable(entity e)
1443 {
1444         if(e.pushable)
1445                 return true;
1446         if(IS_VEHICLE(e))
1447                 return false;
1448         if(e.iscreature)
1449                 return true;
1450         if (Item_IsLoot(e))
1451         {
1452                 return true;
1453         }
1454         switch(e.classname)
1455         {
1456                 case "body":
1457                         return true;
1458                 case "bullet": // antilagged bullets can't hit this either
1459                         return false;
1460         }
1461         if (e.projectiledeathtype)
1462                 return true;
1463         return false;
1464 }