qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 float race_GetTime(float pos);
  20 string race_GetName(float pos);
  21 string race_PlaceName(float pos);
  22 string GetMapname();
  23 string ColoredTeamName(float t);
  24
  25 string admin_name(void)
  26 {
  27         if(cvar_string("sv_adminnick") != "")
  28                 return cvar_string("sv_adminnick");
  29         else
  30                 return "SERVER ADMIN";
  31 }
  32
  33 float DistributeEvenly_amount;
  34 float DistributeEvenly_totalweight;
  35 void DistributeEvenly_Init(float amount, float totalweight)
  36 {
  37     if (DistributeEvenly_amount)
  38     {
  39         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  40         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  41     }
  42     if (totalweight == 0)
  43         DistributeEvenly_amount = 0;
  44     else
  45         DistributeEvenly_amount = amount;
  46     DistributeEvenly_totalweight = totalweight;
  47 }
  48 float DistributeEvenly_Get(float weight)
  49 {
  50     float f;
  51     if (weight <= 0)
  52         return 0;
  53     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  54     DistributeEvenly_totalweight -= weight;
  55     DistributeEvenly_amount -= f;
  56     return f;
  57 }
  58
  59 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  60
  61
  62 string STR_PLAYER = "player";
  63 string STR_SPECTATOR = "spectator";
  64 string STR_OBSERVER = "observer";
  65
  66 #if 0
  67 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  68 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  69 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  70 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  71 #else
  72 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  73 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  74 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  75 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  76 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  77 #endif
  78
  79 // copies a string to a tempstring (so one can strunzone it)
  80 string strcat1(string s) = #115; // FRIK_FILE
  81
  82 float logfile_open;
  83 float logfile;
  84
  85 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  86 {
  87         local float nPlayerHealth = rint(enPlayer.health);
  88         local float nPlayerArmor = rint(enPlayer.armorvalue);
  89         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  90         local float nPlayerPing = rint(enPlayer.ping);
  91         local string strPlayerPingColor;
  92         local string strMessage;
  93         if(nPlayerPing >= 150)
  94                 strPlayerPingColor = "^1";
  95         else
  96                 strPlayerPingColor = "^2";
  97
  98         if((cvar("sv_fragmessage_information_stats")) && (enPlayer.health >= 1))
  99                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
 100
 101         if(cvar("sv_fragmessage_information_ping")) {
 102                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 103                         strMessage = strcat(strMessage, "\n^7(^2Bot");
 104                 else
 105                         strMessage = strcat(strMessage, "\n^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 106                 if(cvar("sv_fragmessage_information_handicap"))
 107                         if(cvar("sv_fragmessage_information_handicap") == 2)
 108                                 if(nPlayerHandicap <= 1)
 109                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 110                                 else
 111                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 112                         else if not(nPlayerHandicap <= 1)
 113                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 114                 else
 115                         strMessage = strcat(strMessage, "^7)");
 116         } else if(cvar("sv_fragmessage_information_handicap")) {
 117                 if(cvar("sv_fragmessage_information_handicap") == 2)
 118                         if(nPlayerHandicap <= 1)
 119                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 120                         else
 121                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 122                 else if(nPlayerHandicap > 1)
 123                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 124         }
 125         return strMessage;
 126 }
 127 void bcenterprint(string s)
 128 {
 129     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 130     entity head;
 131     FOR_EACH_PLAYER(head)
 132     if (clienttype(head) == CLIENTTYPE_REAL)
 133         centerprint(head, s);
 134 }
 135
 136 void GameLogEcho(string s)
 137 {
 138     string fn;
 139     float matches;
 140
 141     if (cvar("sv_eventlog_files"))
 142     {
 143         if (!logfile_open)
 144         {
 145             logfile_open = TRUE;
 146             matches = cvar("sv_eventlog_files_counter") + 1;
 147             cvar_set("sv_eventlog_files_counter", ftos(matches));
 148             fn = ftos(matches);
 149             if (strlen(fn) < 8)
 150                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 151             fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 152             logfile = fopen(fn, FILE_APPEND);
 153             fputs(logfile, ":logversion:3\n");
 154         }
 155         if (logfile >= 0)
 156         {
 157             if (cvar("sv_eventlog_files_timestamps"))
 158                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 159             else
 160                 fputs(logfile, strcat(s, "\n"));
 161         }
 162     }
 163     if (cvar("sv_eventlog_console"))
 164     {
 165         print(s, "\n");
 166     }
 167 }
 168
 169 void GameLogInit()
 170 {
 171     logfile_open = 0;
 172     // will be opened later
 173 }
 174
 175 void GameLogClose()
 176 {
 177     if (logfile_open && logfile >= 0)
 178     {
 179         fclose(logfile);
 180         logfile = -1;
 181     }
 182 }
 183
 184 vector PL_VIEW_OFS;
 185 vector PL_MIN;
 186 vector PL_MAX;
 187 vector PL_CROUCH_VIEW_OFS;
 188 vector PL_CROUCH_MIN;
 189 vector PL_CROUCH_MAX;
 190
 191 float spawnpoint_nag;
 192 void relocate_spawnpoint()
 193 {
 194     PL_VIEW_OFS                             = stov(cvar_string("sv_player_viewoffset"));
 195     PL_MIN                                  = stov(cvar_string("sv_player_mins"));
 196     PL_MAX                                  = stov(cvar_string("sv_player_maxs"));
 197     PL_CROUCH_VIEW_OFS                      = stov(cvar_string("sv_player_crouch_viewoffset"));
 198     PL_CROUCH_MIN                           = stov(cvar_string("sv_player_crouch_mins"));
 199     PL_CROUCH_MAX                           = stov(cvar_string("sv_player_crouch_maxs"));
 200
 201     // nudge off the floor
 202     setorigin(self, self.origin + '0 0 1');
 203
 204     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 205     if (trace_startsolid)
 206     {
 207         vector o;
 208         o = self.origin;
 209         self.mins = PL_MIN;
 210         self.maxs = PL_MAX;
 211         if (!move_out_of_solid(self))
 212             objerror("could not get out of solid at all!");
 213         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 214         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 215         print(" ", ftos(self.origin_y - o_y));
 216         print(" ", ftos(self.origin_z - o_z), "'\n");
 217         if (cvar("g_spawnpoints_auto_move_out_of_solid"))
 218         {
 219             if (!spawnpoint_nag)
 220                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 221             spawnpoint_nag = 1;
 222         }
 223         else
 224         {
 225             setorigin(self, o);
 226             self.mins = self.maxs = '0 0 0';
 227             objerror("player spawn point in solid, mapper sucks!\n");
 228             return;
 229         }
 230     }
 231
 232     if (cvar("g_spawnpoints_autodrop"))
 233     {
 234         setsize(self, PL_MIN, PL_MAX);
 235         droptofloor();
 236     }
 237
 238     self.use = spawnpoint_use;
 239     self.team_saved = self.team;
 240     if (!self.cnt)
 241         self.cnt = 1;
 242
 243     if (have_team_spawns != 0)
 244         if (self.team)
 245             have_team_spawns = 1;
 246
 247     if (cvar("r_showbboxes"))
 248     {
 249         // show where spawnpoints point at too
 250         makevectors(self.angles);
 251         entity e;
 252         e = spawn();
 253         e.classname = "info_player_foo";
 254         setorigin(e, self.origin + v_forward * 24);
 255         setsize(e, '-8 -8 -8', '8 8 8');
 256         e.solid = SOLID_TRIGGER;
 257     }
 258 }
 259
 260 #define strstr strstrofs
 261 /*
 262 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 263 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 264 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 265 // BE CONSTANT OR strzoneD!
 266 float strstr(string haystack, string needle, float offset)
 267 {
 268         float len, endpos;
 269         string found;
 270         len = strlen(needle);
 271         endpos = strlen(haystack) - len;
 272         while(offset <= endpos)
 273         {
 274                 found = substring(haystack, offset, len);
 275                 if(found == needle)
 276                         return offset;
 277                 offset = offset + 1;
 278         }
 279         return -1;
 280 }
 281 */
 282
 283 float NUM_NEAREST_ENTITIES = 4;
 284 entity nearest_entity[NUM_NEAREST_ENTITIES];
 285 float nearest_length[NUM_NEAREST_ENTITIES];
 286 entity findnearest(vector point, .string field, string value, vector axismod)
 287 {
 288     entity localhead;
 289     float i;
 290     float j;
 291     float len;
 292     vector dist;
 293
 294     float num_nearest;
 295     num_nearest = 0;
 296
 297     localhead = find(world, field, value);
 298     while (localhead)
 299     {
 300         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 301             dist = localhead.oldorigin;
 302         else
 303             dist = localhead.origin;
 304         dist = dist - point;
 305         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 306         len = vlen(dist);
 307
 308         for (i = 0; i < num_nearest; ++i)
 309         {
 310             if (len < nearest_length[i])
 311                 break;
 312         }
 313
 314         // now i tells us where to insert at
 315         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 316         if (i < NUM_NEAREST_ENTITIES)
 317         {
 318             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 319             {
 320                 nearest_length[j + 1] = nearest_length[j];
 321                 nearest_entity[j + 1] = nearest_entity[j];
 322             }
 323             nearest_length[i] = len;
 324             nearest_entity[i] = localhead;
 325             if (num_nearest < NUM_NEAREST_ENTITIES)
 326                 num_nearest = num_nearest + 1;
 327         }
 328
 329         localhead = find(localhead, field, value);
 330     }
 331
 332     // now use the first one from our list that we can see
 333     for (i = 0; i < num_nearest; ++i)
 334     {
 335         traceline(point, nearest_entity[i].origin, TRUE, world);
 336         if (trace_fraction == 1)
 337         {
 338             if (i != 0)
 339             {
 340                 dprint("Nearest point (");
 341                 dprint(nearest_entity[0].netname);
 342                 dprint(") is not visible, using a visible one.\n");
 343             }
 344             return nearest_entity[i];
 345         }
 346     }
 347
 348     if (num_nearest == 0)
 349         return world;
 350
 351     dprint("Not seeing any location point, using nearest as fallback.\n");
 352     /* DEBUGGING CODE:
 353     dprint("Candidates were: ");
 354     for(j = 0; j < num_nearest; ++j)
 355     {
 356         if(j != 0)
 357                 dprint(", ");
 358         dprint(nearest_entity[j].netname);
 359     }
 360     dprint("\n");
 361     */
 362
 363     return nearest_entity[0];
 364 }
 365
 366 void spawnfunc_target_location()
 367 {
 368     self.classname = "target_location";
 369     // location name in netname
 370     // eventually support: count, teamgame selectors, line of sight?
 371 };
 372
 373 void spawnfunc_info_location()
 374 {
 375     self.classname = "target_location";
 376     self.message = self.netname;
 377 };
 378
 379 string NearestLocation(vector p)
 380 {
 381     entity loc;
 382     string ret;
 383     ret = "somewhere";
 384     loc = findnearest(p, classname, "target_location", '1 1 1');
 385     if (loc)
 386     {
 387         ret = loc.message;
 388     }
 389     else
 390     {
 391         loc = findnearest(p, target, "###item###", '1 1 4');
 392         if (loc)
 393             ret = loc.netname;
 394     }
 395     return ret;
 396 }
 397
 398 string formatmessage(string msg)
 399 {
 400         float p, p1, p2;
 401         float n;
 402         vector cursor;
 403         entity cursor_ent;
 404         string escape;
 405         string replacement;
 406         p = 0;
 407         n = 7;
 408
 409         WarpZone_crosshair_trace(self);
 410         cursor = trace_endpos;
 411         cursor_ent = trace_ent;
 412
 413         while (1) {
 414                 if (n < 1)
 415                         break; // too many replacements
 416
 417                 n = n - 1;
 418                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 419                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 420
 421                 if (p1 < 0)
 422                         p1 = p2;
 423
 424                 if (p2 < 0)
 425                         p2 = p1;
 426
 427                 p = min(p1, p2);
 428
 429                 if (p < 0)
 430                         break;
 431
 432                 replacement = substring(msg, p, 2);
 433                 escape = substring(msg, p + 1, 1);
 434
 435                 if (escape == "%")
 436                         replacement = "%";
 437                 else if (escape == "\\")
 438                         replacement = "\\";
 439                 else if (escape == "n")
 440                         replacement = "\n";
 441                 else if (escape == "a")
 442                         replacement = ftos(floor(self.armorvalue));
 443                 else if (escape == "h")
 444                         replacement = ftos(floor(self.health));
 445                 else if (escape == "l")
 446                         replacement = NearestLocation(self.origin);
 447                 else if (escape == "y")
 448                         replacement = NearestLocation(cursor);
 449                 else if (escape == "d")
 450                         replacement = NearestLocation(self.death_origin);
 451                 else if (escape == "w") {
 452                         float wep;
 453                         wep = self.weapon;
 454                         if (!wep)
 455                                 wep = self.switchweapon;
 456                         if (!wep)
 457                                 wep = self.cnt;
 458                         replacement = W_Name(wep);
 459                 } else if (escape == "W") {
 460                         if (self.items & IT_SHELLS) replacement = "shells";
 461                         else if (self.items & IT_NAILS) replacement = "bullets";
 462                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 463                         else if (self.items & IT_CELLS) replacement = "cells";
 464                         else replacement = "batteries"; // ;)
 465                 } else if (escape == "x") {
 466                         replacement = cursor_ent.netname;
 467                         if (!replacement || !cursor_ent)
 468                                 replacement = "nothing";
 469                 } else if (escape == "p") {
 470                         if (self.last_selected_player)
 471                                 replacement = self.last_selected_player.netname;
 472                         else
 473                                 replacement = "(nobody)";
 474                 } else if (escape == "s")
 475                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 476                 else if (escape == "S")
 477                         replacement = ftos(vlen(self.velocity));
 478                 else if (escape == "v") {
 479                         float weapon_number;
 480                         local entity stats;
 481
 482                         if(self.classname == "spectator")
 483                                 stats = self.enemy;
 484                         else
 485                                 stats = self;
 486
 487                         weapon_number = stats.weapon;
 488
 489                         if (!weapon_number)
 490                                 weapon_number = stats.switchweapon;
 491
 492                         if (!weapon_number)
 493                                 weapon_number = stats.cnt;
 494
 495                         if(stats.cvar_cl_accuracy_data_share && stats.stats_fired[weapon_number - 1])
 496                                 replacement = ftos(bound(0, floor(100 * stats.stats_hit[weapon_number - 1] / stats.stats_fired[weapon_number - 1]), 100));
 497                         else
 498                                 replacement = "~"; // or something to indicate NULL, not available
 499                 }
 500
 501                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 502                 p = p + strlen(replacement);
 503         }
 504         return msg;
 505 }
 506
 507 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 508         return (value == 0) ? FALSE : TRUE;
 509 }
 510
 511 /*
 512 =============
 513 GetCvars
 514 =============
 515 Called with:
 516   0:  sends the request
 517   >0: receives a cvar from name=argv(f) value=argv(f+1)
 518 */
 519 void GetCvars_handleString(string thisname, float f, .string field, string name)
 520 {
 521         if (f < 0)
 522         {
 523                 if (self.field)
 524                         strunzone(self.field);
 525                 self.field = string_null;
 526         }
 527         else if (f > 0)
 528         {
 529                 if (thisname == name)
 530                 {
 531                         if (self.field)
 532                                 strunzone(self.field);
 533                         self.field = strzone(argv(f + 1));
 534                 }
 535         }
 536         else
 537                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 538 }
 539 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 540 {
 541         GetCvars_handleString(thisname, f, field, name);
 542         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 543                 if (thisname == name)
 544                 {
 545                         string s;
 546                         s = func(strcat1(self.field));
 547                         if (s != self.field)
 548                         {
 549                                 strunzone(self.field);
 550                                 self.field = strzone(s);
 551                         }
 552                 }
 553 }
 554 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 555 {
 556         if (f < 0)
 557         {
 558         }
 559         else if (f > 0)
 560         {
 561                 if (thisname == name)
 562                         self.field = stof(argv(f + 1));
 563         }
 564         else
 565                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 566 }
 567 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 568 {
 569         if (f < 0)
 570         {
 571         }
 572         else if (f > 0)
 573         {
 574                 if (thisname == name)
 575                 {
 576                         if(!self.field)
 577                         {
 578                                 self.field = stof(argv(f + 1));
 579                                 if(!self.field)
 580                                         self.field = -1;
 581                         }
 582                 }
 583         }
 584         else
 585         {
 586                 if(!self.field)
 587                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 588         }
 589 }
 590 string W_FixWeaponOrder_ForceComplete(string s);
 591 string W_FixWeaponOrder_AllowIncomplete(string s);
 592 float w_getbestweapon(entity e);
 593 void GetCvars(float f)
 594 {
 595         string s;
 596
 597         if (f > 0)
 598                 s = strcat1(argv(f));
 599
 600         get_cvars_f = f;
 601         get_cvars_s = s;
 602         MUTATOR_CALLHOOK(GetCvars);
 603         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 604         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 605         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 606         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 607         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 608         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 609         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 610         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 611         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 612         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 613         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 614         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 615         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 616         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 617         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 618         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 619         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 620         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 621         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 622         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 623         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 624         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 625         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 626         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 627         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 628
 629         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 630         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 631
 632 #ifdef ALLOW_FORCEMODELS
 633         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 634         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 635 #endif
 636         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 637
 638         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 639         if (f > 0)
 640         {
 641                 if (s == "cl_weaponpriority")
 642                         self.switchweapon = w_getbestweapon(self);
 643         }
 644 }
 645
 646 float fexists(string f)
 647 {
 648     float fh;
 649     fh = fopen(f, FILE_READ);
 650     if (fh < 0)
 651         return FALSE;
 652     fclose(fh);
 653     return TRUE;
 654 }
 655
 656 void backtrace(string msg)
 657 {
 658     float dev, war;
 659     dev = cvar("developer");
 660     war = cvar("prvm_backtraceforwarnings");
 661     cvar_set("developer", "1");
 662     cvar_set("prvm_backtraceforwarnings", "1");
 663     print("\n");
 664     print("--- CUT HERE ---\nWARNING: ");
 665     print(msg);
 666     print("\n");
 667     remove(world); // isn't there any better way to cause a backtrace?
 668     print("\n--- CUT UNTIL HERE ---\n");
 669     cvar_set("developer", ftos(dev));
 670     cvar_set("prvm_backtraceforwarnings", ftos(war));
 671 }
 672
 673 string Team_ColorCode(float teamid)
 674 {
 675     if (teamid == COLOR_TEAM1)
 676         return "^1";
 677     else if (teamid == COLOR_TEAM2)
 678         return "^4";
 679     else if (teamid == COLOR_TEAM3)
 680         return "^3";
 681     else if (teamid == COLOR_TEAM4)
 682         return "^6";
 683     else
 684         return "^7";
 685 }
 686
 687 string Team_ColorName(float t)
 688 {
 689     // fixme: Search for team entities and get their .netname's!
 690     if (t == COLOR_TEAM1)
 691         return "Red";
 692     if (t == COLOR_TEAM2)
 693         return "Blue";
 694     if (t == COLOR_TEAM3)
 695         return "Yellow";
 696     if (t == COLOR_TEAM4)
 697         return "Pink";
 698     return "Neutral";
 699 }
 700
 701 string Team_ColorNameLowerCase(float t)
 702 {
 703     // fixme: Search for team entities and get their .netname's!
 704     if (t == COLOR_TEAM1)
 705         return "red";
 706     if (t == COLOR_TEAM2)
 707         return "blue";
 708     if (t == COLOR_TEAM3)
 709         return "yellow";
 710     if (t == COLOR_TEAM4)
 711         return "pink";
 712     return "neutral";
 713 }
 714
 715 float ColourToNumber(string team_colour)
 716 {
 717         if (team_colour == "red")
 718                 return COLOR_TEAM1;
 719
 720         if (team_colour == "blue")
 721                 return COLOR_TEAM2;
 722
 723         if (team_colour == "yellow")
 724                 return COLOR_TEAM3;
 725
 726         if (team_colour == "pink")
 727                 return COLOR_TEAM4;
 728
 729         if (team_colour == "auto")
 730                 return 0;
 731
 732         return -1;
 733 }
 734
 735 float NumberToTeamNumber(float number)
 736 {
 737         if (number == 1)
 738                 return COLOR_TEAM1;
 739
 740         if (number == 2)
 741                 return COLOR_TEAM2;
 742
 743         if (number == 3)
 744                 return COLOR_TEAM3;
 745
 746         if (number == 4)
 747                 return COLOR_TEAM4;
 748
 749         return -1;
 750 }
 751
 752 #define CENTERPRIO_POINT 1
 753 #define CENTERPRIO_SPAM 2
 754 #define CENTERPRIO_VOTE 4
 755 #define CENTERPRIO_NORMAL 5
 756 #define CENTERPRIO_SHIELDING 7
 757 #define CENTERPRIO_MAPVOTE 9
 758 #define CENTERPRIO_IDLEKICK 50
 759 #define CENTERPRIO_ADMIN 99
 760 .float centerprint_priority;
 761 .float centerprint_expires;
 762 void centerprint_atprio(entity e, float prio, string s)
 763 {
 764     if (intermission_running)
 765         if (prio < CENTERPRIO_MAPVOTE)
 766             return;
 767     if (time > e.centerprint_expires)
 768         e.centerprint_priority = 0;
 769     if (prio >= e.centerprint_priority)
 770     {
 771         e.centerprint_priority = prio;
 772         if (timeoutStatus == 2)
 773             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 774         else
 775             e.centerprint_expires = time + e.cvar_scr_centertime;
 776         centerprint_builtin(e, s);
 777     }
 778 }
 779 void centerprint_expire(entity e, float prio)
 780 {
 781     if (prio == e.centerprint_priority)
 782     {
 783         e.centerprint_priority = 0;
 784         centerprint_builtin(e, "");
 785     }
 786 }
 787 void centerprint(entity e, string s)
 788 {
 789     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 790 }
 791
 792 // decolorizes and team colors the player name when needed
 793 string playername(entity p)
 794 {
 795     string t;
 796     if (teams_matter && !intermission_running && p.classname == "player")
 797     {
 798         t = Team_ColorCode(p.team);
 799         return strcat(t, strdecolorize(p.netname));
 800     }
 801     else
 802         return p.netname;
 803 }
 804
 805 vector randompos(vector m1, vector m2)
 806 {
 807     local vector v;
 808     m2 = m2 - m1;
 809     v_x = m2_x * random() + m1_x;
 810     v_y = m2_y * random() + m1_y;
 811     v_z = m2_z * random() + m1_z;
 812     return  v;
 813 };
 814
 815 float g_pickup_shells;
 816 float g_pickup_shells_max;
 817 float g_pickup_nails;
 818 float g_pickup_nails_max;
 819 float g_pickup_rockets;
 820 float g_pickup_rockets_max;
 821 float g_pickup_cells;
 822 float g_pickup_cells_max;
 823 float g_pickup_fuel;
 824 float g_pickup_fuel_jetpack;
 825 float g_pickup_fuel_max;
 826 float g_pickup_armorsmall;
 827 float g_pickup_armorsmall_max;
 828 float g_pickup_armorsmall_anyway;
 829 float g_pickup_armormedium;
 830 float g_pickup_armormedium_max;
 831 float g_pickup_armormedium_anyway;
 832 float g_pickup_armorbig;
 833 float g_pickup_armorbig_max;
 834 float g_pickup_armorbig_anyway;
 835 float g_pickup_armorlarge;
 836 float g_pickup_armorlarge_max;
 837 float g_pickup_armorlarge_anyway;
 838 float g_pickup_healthsmall;
 839 float g_pickup_healthsmall_max;
 840 float g_pickup_healthsmall_anyway;
 841 float g_pickup_healthmedium;
 842 float g_pickup_healthmedium_max;
 843 float g_pickup_healthmedium_anyway;
 844 float g_pickup_healthlarge;
 845 float g_pickup_healthlarge_max;
 846 float g_pickup_healthlarge_anyway;
 847 float g_pickup_healthmega;
 848 float g_pickup_healthmega_max;
 849 float g_pickup_healthmega_anyway;
 850 float g_pickup_ammo_anyway;
 851 float g_pickup_weapons_anyway;
 852 float g_weaponarena;
 853 float g_weaponarena_random;
 854 string g_weaponarena_list;
 855 float g_weaponspeedfactor;
 856 float g_weaponratefactor;
 857 float g_weapondamagefactor;
 858 float g_weaponforcefactor;
 859 float g_weaponspreadfactor;
 860
 861 float start_weapons;
 862 float start_items;
 863 float start_ammo_shells;
 864 float start_ammo_nails;
 865 float start_ammo_rockets;
 866 float start_ammo_cells;
 867 float start_ammo_fuel;
 868 float start_health;
 869 float start_armorvalue;
 870 float warmup_start_weapons;
 871 float warmup_start_ammo_shells;
 872 float warmup_start_ammo_nails;
 873 float warmup_start_ammo_rockets;
 874 float warmup_start_ammo_cells;
 875 float warmup_start_ammo_fuel;
 876 float warmup_start_health;
 877 float warmup_start_armorvalue;
 878 float g_weapon_stay;
 879 float g_ghost_items;
 880
 881 entity get_weaponinfo(float w);
 882
 883 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 884 {
 885         var float i = weaponinfo.weapon;
 886
 887         if (!i)
 888                 return 0;
 889
 890         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 891
 892         if (t < 0) // "default" weapon selection
 893         {
 894                 if (g_lms || g_ca || allguns)
 895                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 896                 else if(t < -1)
 897                         t = 0;
 898                 else if (g_race || g_cts)
 899                         t = (i == WEP_LASER);
 900                 else if (g_nexball)
 901                         t = 0; // weapon is set a few lines later
 902                 else
 903                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 904                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 905                         t |= (i == WEP_HOOK);
 906         }
 907
 908         // we cannot disable porto in Nexball, we must force it
 909         if(g_nexball && i == WEP_PORTO)
 910                 t = 1;
 911
 912         return t;
 913 }
 914
 915 void readplayerstartcvars()
 916 {
 917         entity e;
 918         float i, j, t;
 919         string s;
 920
 921         // initialize starting values for players
 922         start_weapons = 0;
 923         start_items = 0;
 924         start_ammo_shells = 0;
 925         start_ammo_nails = 0;
 926         start_ammo_rockets = 0;
 927         start_ammo_cells = 0;
 928         start_health = cvar("g_balance_health_start");
 929         start_armorvalue = cvar("g_balance_armor_start");
 930
 931         g_weaponarena = 0;
 932         s = cvar_string("g_weaponarena");
 933         if (s == "0")
 934         {
 935         }
 936         else if (s == "all")
 937         {
 938                 g_weaponarena_list = "All Weapons";
 939                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 940                 {
 941                         e = get_weaponinfo(j);
 942                         g_weaponarena |= e.weapons;
 943                         weapon_action(e.weapon, WR_PRECACHE);
 944                 }
 945         }
 946         else if (s == "most")
 947         {
 948                 g_weaponarena_list = "Most Weapons";
 949                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 950                 {
 951                         e = get_weaponinfo(j);
 952                         if (e.spawnflags & WEP_FLAG_NORMAL)
 953                         {
 954                                 g_weaponarena |= e.weapons;
 955                                 weapon_action(e.weapon, WR_PRECACHE);
 956                         }
 957                 }
 958         }
 959         else if (s == "none")
 960         {
 961                 g_weaponarena_list = "No Weapons";
 962                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 963         }
 964         else
 965         {
 966                 t = tokenize_console(s);
 967                 g_weaponarena_list = "";
 968                 for (i = 0; i < t; ++i)
 969                 {
 970                         s = argv(i);
 971                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 972                         {
 973                                 e = get_weaponinfo(j);
 974                                 if (e.netname == s)
 975                                 {
 976                                         g_weaponarena |= e.weapons;
 977                                         weapon_action(e.weapon, WR_PRECACHE);
 978                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 979                                         break;
 980                                 }
 981                         }
 982                         if (j > WEP_LAST)
 983                         {
 984                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 985                         }
 986                 }
 987                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 988         }
 989
 990         if(g_weaponarena)
 991                 g_weaponarena_random = cvar("g_weaponarena_random");
 992         else
 993                 g_weaponarena_random = 0;
 994
 995         if (g_weaponarena)
 996         {
 997                 start_weapons = g_weaponarena;
 998                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
 999                         start_ammo_rockets = 999;
1000                 if (g_weaponarena & WEPBIT_SHOTGUN)
1001                         start_ammo_shells = 999;
1002                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
1003                         start_ammo_cells = 999;
1004                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
1005                         start_ammo_nails = 999;
1006                 if (g_weaponarena & WEPBIT_HOOK)
1007                         start_ammo_fuel = 999;
1008                 start_items |= IT_UNLIMITED_AMMO;
1009         }
1010         else if (g_minstagib)
1011         {
1012                 start_health = 100;
1013                 start_armorvalue = 0;
1014                 start_weapons = WEPBIT_MINSTANEX;
1015                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1016                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1017                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1018                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1019
1020                 if (g_minstagib_invis_alpha <= 0)
1021                         g_minstagib_invis_alpha = -1;
1022         }
1023         else
1024         {
1025                 if (g_lms || g_ca)
1026                 {
1027                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1028                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1029                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1030                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1031                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1032                         start_health = cvar("g_lms_start_health");
1033                         start_armorvalue = cvar("g_lms_start_armor");
1034                 }
1035                 else
1036                 {
1037                         start_ammo_shells = cvar("g_start_ammo_shells");
1038                         start_ammo_nails = cvar("g_start_ammo_nails");
1039                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1040                         start_ammo_cells = cvar("g_start_ammo_cells");
1041                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1042                 }
1043
1044                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1045                 {
1046                         e = get_weaponinfo(i);
1047                         if(want_weapon("g_start_weapon_", e, FALSE))
1048                                 start_weapons |= e.weapons;
1049                 }
1050         }
1051
1052         if (inWarmupStage)
1053         {
1054                 warmup_start_ammo_shells = start_ammo_shells;
1055                 warmup_start_ammo_nails = start_ammo_nails;
1056                 warmup_start_ammo_rockets = start_ammo_rockets;
1057                 warmup_start_ammo_cells = start_ammo_cells;
1058                 warmup_start_ammo_fuel = start_ammo_fuel;
1059                 warmup_start_health = start_health;
1060                 warmup_start_armorvalue = start_armorvalue;
1061                 warmup_start_weapons = start_weapons;
1062
1063                 if (!g_weaponarena && !g_minstagib && !g_ca)
1064                 {
1065                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1066                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1067                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1068                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1069                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1070                         warmup_start_health = cvar("g_warmup_start_health");
1071                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1072                         warmup_start_weapons = 0;
1073                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1074                         {
1075                                 e = get_weaponinfo(i);
1076                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1077                                         warmup_start_weapons |= e.weapons;
1078                         }
1079                 }
1080         }
1081
1082         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1083         {
1084                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1085                 start_items |= IT_FUEL_REGEN;
1086                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1087                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1088         }
1089
1090         if(!cvar("g_use_ammunition"))
1091         {
1092                 start_ammo_shells = cvar("g_pickup_shells_max");
1093                 start_ammo_nails = cvar("g_pickup_nails_max");
1094                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1095                 start_ammo_cells = cvar("g_pickup_cells_max");
1096                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1097                 start_items |= IT_UNLIMITED_AMMO;
1098                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1099                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1100                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1101                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1102                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1103                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1104         }
1105
1106         if (g_jetpack)
1107                 start_items |= IT_JETPACK;
1108
1109         if (g_weapon_stay == 2)
1110         {
1111                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1112                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1113                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1114                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1115                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1116                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1117                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1118                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1119                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1120                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1121         }
1122
1123         MUTATOR_CALLHOOK(SetStartItems);
1124
1125         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1126         {
1127                 e = get_weaponinfo(i);
1128                 if(e.weapons & (start_weapons | warmup_start_weapons))
1129                         weapon_action(e.weapon, WR_PRECACHE);
1130         }
1131
1132         start_ammo_shells = max(0, start_ammo_shells);
1133         start_ammo_nails = max(0, start_ammo_nails);
1134         start_ammo_cells = max(0, start_ammo_cells);
1135         start_ammo_rockets = max(0, start_ammo_rockets);
1136         start_ammo_fuel = max(0, start_ammo_fuel);
1137
1138         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1139         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1140         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1141         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1142         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1143 }
1144
1145 float g_bugrigs;
1146 float g_bugrigs_planar_movement;
1147 float g_bugrigs_planar_movement_car_jumping;
1148 float g_bugrigs_reverse_spinning;
1149 float g_bugrigs_reverse_speeding;
1150 float g_bugrigs_reverse_stopping;
1151 float g_bugrigs_air_steering;
1152 float g_bugrigs_angle_smoothing;
1153 float g_bugrigs_friction_floor;
1154 float g_bugrigs_friction_brake;
1155 float g_bugrigs_friction_air;
1156 float g_bugrigs_accel;
1157 float g_bugrigs_speed_ref;
1158 float g_bugrigs_speed_pow;
1159 float g_bugrigs_steer;
1160
1161 float g_touchexplode;
1162 float g_touchexplode_radius;
1163 float g_touchexplode_damage;
1164 float g_touchexplode_edgedamage;
1165 float g_touchexplode_force;
1166
1167 float sv_autotaunt;
1168 float sv_taunt;
1169
1170 float sv_pitch_min;
1171 float sv_pitch_max;
1172 float sv_pitch_fixyaw;
1173
1174 float sv_accuracy_data_share;
1175
1176 void readlevelcvars(void)
1177 {
1178         // first load all the mutators
1179         if(cvar("g_nix"))
1180                 MUTATOR_ADD(mutator_nix);
1181
1182     g_bugrigs = cvar("g_bugrigs");
1183     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1184     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1185     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1186     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1187     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1188     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1189     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1190     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1191     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1192     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1193     g_bugrigs_accel = cvar("g_bugrigs_accel");
1194     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1195     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1196     g_bugrigs_steer = cvar("g_bugrigs_steer");
1197
1198     g_touchexplode = cvar("g_touchexplode");
1199     g_touchexplode_radius = cvar("g_touchexplode_radius");
1200     g_touchexplode_damage = cvar("g_touchexplode_damage");
1201     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1202     g_touchexplode_force = cvar("g_touchexplode_force");
1203
1204 #ifdef ALLOW_FORCEMODELS
1205         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1206 #endif
1207         sv_loddistance1 = cvar("sv_loddistance1");
1208         sv_loddistance2 = cvar("sv_loddistance2");
1209
1210         if(sv_loddistance2 <= sv_loddistance1)
1211                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1212
1213         sv_clones = cvar("sv_clones");
1214         sv_gentle = cvar("sv_gentle");
1215         sv_foginterval = cvar("sv_foginterval");
1216         g_cloaked = cvar("g_cloaked");
1217         g_jump_grunt = cvar("g_jump_grunt");
1218         g_footsteps = cvar("g_footsteps");
1219         g_grappling_hook = cvar("g_grappling_hook");
1220         g_jetpack = cvar("g_jetpack");
1221         g_laserguided_missile = cvar("g_laserguided_missile");
1222         g_midair = cvar("g_midair");
1223         g_minstagib = cvar("g_minstagib");
1224         g_norecoil = cvar("g_norecoil");
1225         g_vampire = cvar("g_vampire");
1226         g_bloodloss = cvar("g_bloodloss");
1227         sv_maxidle = cvar("sv_maxidle");
1228         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1229         sv_pogostick = cvar("sv_pogostick");
1230         sv_doublejump = cvar("sv_doublejump");
1231         g_ctf_reverse = cvar("g_ctf_reverse");
1232         sv_autotaunt = cvar("sv_autotaunt");
1233         sv_taunt = cvar("sv_taunt");
1234
1235         inWarmupStage = cvar("g_warmup");
1236         g_warmup_limit = cvar("g_warmup_limit");
1237         g_warmup_allguns = cvar("g_warmup_allguns");
1238         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1239
1240         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1241                 inWarmupStage = 0; // these modes cannot work together, sorry
1242
1243         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1244         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1245         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1246         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1247         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1248         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1249         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1250         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1251         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1252         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1253         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1254         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1255
1256         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1257         g_weaponratefactor = cvar("g_weaponratefactor");
1258         g_weapondamagefactor = cvar("g_weapondamagefactor");
1259         g_weaponforcefactor = cvar("g_weaponforcefactor");
1260         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1261
1262         g_pickup_shells = cvar("g_pickup_shells");
1263         g_pickup_shells_max = cvar("g_pickup_shells_max");
1264         g_pickup_nails = cvar("g_pickup_nails");
1265         g_pickup_nails_max = cvar("g_pickup_nails_max");
1266         g_pickup_rockets = cvar("g_pickup_rockets");
1267         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1268         g_pickup_cells = cvar("g_pickup_cells");
1269         g_pickup_cells_max = cvar("g_pickup_cells_max");
1270         g_pickup_fuel = cvar("g_pickup_fuel");
1271         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1272         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1273         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1274         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1275         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1276         g_pickup_armormedium = cvar("g_pickup_armormedium");
1277         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1278         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1279         g_pickup_armorbig = cvar("g_pickup_armorbig");
1280         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1281         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1282         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1283         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1284         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1285         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1286         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1287         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1288         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1289         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1290         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1291         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1292         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1293         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1294         g_pickup_healthmega = cvar("g_pickup_healthmega");
1295         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1296         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1297
1298         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1299         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1300
1301         g_pinata = cvar("g_pinata");
1302
1303         g_weapon_stay = cvar("g_weapon_stay");
1304
1305         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1306                 g_weapon_stay = 1;
1307
1308         g_ghost_items = cvar("g_ghost_items");
1309
1310         if(g_ghost_items >= 1)
1311                 g_ghost_items = 0.25; // default alpha value
1312
1313         if not(inWarmupStage && !g_ca)
1314                 game_starttime = cvar("g_start_delay");
1315
1316         sv_pitch_min = cvar("sv_pitch_min");
1317         sv_pitch_max = cvar("sv_pitch_max");
1318         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1319
1320         sv_accuracy_data_share = boolean(cvar("sv_accuracy_data_share"));
1321
1322         readplayerstartcvars();
1323 }
1324
1325 /*
1326 // TODO sound pack system
1327 string soundpack;
1328
1329 string precache_sound_builtin (string s) = #19;
1330 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1331 string precache_sound(string s)
1332 {
1333         return precache_sound_builtin(strcat(soundpack, s));
1334 }
1335 void play2(entity e, string filename)
1336 {
1337         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1338 }
1339 void sound(entity e, float chan, string samp, float vol, float atten)
1340 {
1341         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1342 }
1343 */
1344
1345 // Sound functions
1346 string precache_sound (string s) = #19;
1347 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1348 float precache_sound_index (string s) = #19;
1349
1350 #define SND_VOLUME      1
1351 #define SND_ATTENUATION 2
1352 #define SND_LARGEENTITY 8
1353 #define SND_LARGESOUND  16
1354
1355 float sound_allowed(float dest, entity e)
1356 {
1357     // sounds from world may always pass
1358     for (;;)
1359     {
1360         if (e.classname == "body")
1361             e = e.enemy;
1362         if (e.owner && e.owner != e)
1363             e = e.owner;
1364         else
1365             break;
1366     }
1367     // sounds to self may always pass
1368     if (dest == MSG_ONE)
1369         if (e == msg_entity)
1370             return TRUE;
1371     // sounds by players can be removed
1372     if (cvar("bot_sound_monopoly"))
1373         if (clienttype(e) == CLIENTTYPE_REAL)
1374             return FALSE;
1375     // anything else may pass
1376     return TRUE;
1377 }
1378
1379 void sound(entity e, float chan, string samp, float vol, float atten)
1380 {
1381     if (!sound_allowed(MSG_BROADCAST, e))
1382         return;
1383     sound_builtin(e, chan, samp, vol, atten);
1384 }
1385 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1386 {
1387     float entno, idx;
1388
1389     if (!sound_allowed(dest, e))
1390         return;
1391
1392     entno = num_for_edict(e);
1393     idx = precache_sound_index(samp);
1394
1395     float sflags;
1396     sflags = 0;
1397
1398     atten = floor(atten * 64);
1399     vol = floor(vol * 255);
1400
1401     if (vol != 255)
1402         sflags |= SND_VOLUME;
1403     if (atten != 64)
1404         sflags |= SND_ATTENUATION;
1405     if (entno >= 8192)
1406         sflags |= SND_LARGEENTITY;
1407     if (idx >= 256)
1408         sflags |= SND_LARGESOUND;
1409
1410     WriteByte(dest, SVC_SOUND);
1411     WriteByte(dest, sflags);
1412     if (sflags & SND_VOLUME)
1413         WriteByte(dest, vol);
1414     if (sflags & SND_ATTENUATION)
1415         WriteByte(dest, atten);
1416     if (sflags & SND_LARGEENTITY)
1417     {
1418         WriteShort(dest, entno);
1419         WriteByte(dest, chan);
1420     }
1421     else
1422     {
1423         WriteShort(dest, entno * 8 + chan);
1424     }
1425     if (sflags & SND_LARGESOUND)
1426         WriteShort(dest, idx);
1427     else
1428         WriteByte(dest, idx);
1429
1430     WriteCoord(dest, o_x);
1431     WriteCoord(dest, o_y);
1432     WriteCoord(dest, o_z);
1433 }
1434 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1435 {
1436     vector o;
1437
1438     if (!sound_allowed(dest, e))
1439         return;
1440
1441     o = e.origin + 0.5 * (e.mins + e.maxs);
1442     soundtoat(dest, e, o, chan, samp, vol, atten);
1443 }
1444 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1445 {
1446     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1447 }
1448 void stopsoundto(float dest, entity e, float chan)
1449 {
1450     float entno;
1451
1452     if (!sound_allowed(dest, e))
1453         return;
1454
1455     entno = num_for_edict(e);
1456
1457     if (entno >= 8192)
1458     {
1459         float idx, sflags;
1460         idx = precache_sound_index("misc/null.wav");
1461         sflags = SND_LARGEENTITY;
1462         if (idx >= 256)
1463             sflags |= SND_LARGESOUND;
1464         WriteByte(dest, SVC_SOUND);
1465         WriteByte(dest, sflags);
1466         WriteShort(dest, entno);
1467         WriteByte(dest, chan);
1468         if (sflags & SND_LARGESOUND)
1469             WriteShort(dest, idx);
1470         else
1471             WriteByte(dest, idx);
1472         WriteCoord(dest, e.origin_x);
1473         WriteCoord(dest, e.origin_y);
1474         WriteCoord(dest, e.origin_z);
1475     }
1476     else
1477     {
1478         WriteByte(dest, SVC_STOPSOUND);
1479         WriteShort(dest, entno * 8 + chan);
1480     }
1481 }
1482 void stopsound(entity e, float chan)
1483 {
1484     if (!sound_allowed(MSG_BROADCAST, e))
1485         return;
1486
1487     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1488     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1489 }
1490
1491 void play2(entity e, string filename)
1492 {
1493     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1494     msg_entity = e;
1495     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1496 }
1497
1498 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1499 .float spamtime;
1500 float spamsound(entity e, float chan, string samp, float vol, float atten)
1501 {
1502     if (!sound_allowed(MSG_BROADCAST, e))
1503         return FALSE;
1504
1505     if (time > e.spamtime)
1506     {
1507         e.spamtime = time;
1508         sound(e, chan, samp, vol, atten);
1509         return TRUE;
1510     }
1511     return FALSE;
1512 }
1513
1514 void play2team(float t, string filename)
1515 {
1516     local entity head;
1517
1518     if (cvar("bot_sound_monopoly"))
1519         return;
1520
1521     FOR_EACH_REALPLAYER(head)
1522     {
1523         if (head.team == t)
1524             play2(head, filename);
1525     }
1526 }
1527
1528 void play2all(string samp)
1529 {
1530     if (cvar("bot_sound_monopoly"))
1531         return;
1532
1533     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1534 }
1535
1536 void PrecachePlayerSounds(string f);
1537 void precache_playermodel(string m)
1538 {
1539         float globhandle, i, n;
1540         string f;
1541
1542         if(substring(m, -9,5) == "_lod1")
1543                 return;
1544         if(substring(m, -9,5) == "_lod2")
1545                 return;
1546         precache_model(m);
1547         if(sv_loddistance1)
1548         {
1549                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1550                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1551         }
1552
1553         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1554         if (globhandle < 0)
1555                 return;
1556         n = search_getsize(globhandle);
1557         for (i = 0; i < n; ++i)
1558         {
1559                 //print(search_getfilename(globhandle, i), "\n");
1560                 f = search_getfilename(globhandle, i);
1561                 PrecachePlayerSounds(f);
1562         }
1563         search_end(globhandle);
1564 }
1565 void precache_all_playermodels(string pattern)
1566 {
1567         float globhandle, i, n;
1568         string f;
1569
1570         globhandle = search_begin(pattern, TRUE, FALSE);
1571         if (globhandle < 0)
1572                 return;
1573         n = search_getsize(globhandle);
1574         for (i = 0; i < n; ++i)
1575         {
1576                 //print(search_getfilename(globhandle, i), "\n");
1577                 f = search_getfilename(globhandle, i);
1578                 precache_playermodel(f);
1579         }
1580         search_end(globhandle);
1581 }
1582
1583 void precache()
1584 {
1585     // gamemode related things
1586     precache_model ("models/misc/chatbubble.spr");
1587     precache_model ("models/misc/teambubble.spr");
1588     if (g_runematch)
1589     {
1590         precache_model ("models/runematch/curse.mdl");
1591         precache_model ("models/runematch/rune.mdl");
1592     }
1593
1594 #ifdef TTURRETS_ENABLED
1595     if (cvar("g_turrets"))
1596         turrets_precash();
1597 #endif
1598
1599     // Precache all player models if desired
1600     if (cvar("sv_precacheplayermodels"))
1601     {
1602         PrecachePlayerSounds("sound/player/default.sounds");
1603         precache_all_playermodels("models/player/*.zym");
1604         precache_all_playermodels("models/player/*.dpm");
1605         precache_all_playermodels("models/player/*.md3");
1606         precache_all_playermodels("models/player/*.psk");
1607         precache_all_playermodels("models/player/*.iqm");
1608     }
1609
1610     if (cvar("sv_defaultcharacter"))
1611     {
1612         string s;
1613         s = cvar_string("sv_defaultplayermodel_red");
1614         if (s != "")
1615             precache_playermodel(s);
1616         s = cvar_string("sv_defaultplayermodel_blue");
1617         if (s != "")
1618             precache_playermodel(s);
1619         s = cvar_string("sv_defaultplayermodel_yellow");
1620         if (s != "")
1621             precache_playermodel(s);
1622         s = cvar_string("sv_defaultplayermodel_pink");
1623         if (s != "")
1624             precache_playermodel(s);
1625         s = cvar_string("sv_defaultplayermodel");
1626         if (s != "")
1627             precache_playermodel(s);
1628     }
1629
1630     if (g_footsteps)
1631     {
1632         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1633         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1634     }
1635
1636     // gore and miscellaneous sounds
1637     //precache_sound ("misc/h2ohit.wav");
1638     precache_model ("models/hook.md3");
1639     precache_sound ("misc/armorimpact.wav");
1640     precache_sound ("misc/bodyimpact1.wav");
1641     precache_sound ("misc/bodyimpact2.wav");
1642     precache_sound ("misc/gib.wav");
1643     precache_sound ("misc/gib_splat01.wav");
1644     precache_sound ("misc/gib_splat02.wav");
1645     precache_sound ("misc/gib_splat03.wav");
1646     precache_sound ("misc/gib_splat04.wav");
1647     precache_sound ("misc/hit.wav");
1648         precache_sound ("misc/typehit.wav");
1649     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1650     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1651     precache_sound ("misc/null.wav");
1652     precache_sound ("misc/spawn.wav");
1653     precache_sound ("misc/talk.wav");
1654     precache_sound ("misc/teleport.wav");
1655     precache_sound ("misc/poweroff.wav");
1656     precache_sound ("player/lava.wav");
1657     precache_sound ("player/slime.wav");
1658
1659     if (g_jetpack)
1660         precache_sound ("misc/jetpack_fly.wav");
1661
1662     precache_model ("models/sprites/0.spr32");
1663     precache_model ("models/sprites/1.spr32");
1664     precache_model ("models/sprites/2.spr32");
1665     precache_model ("models/sprites/3.spr32");
1666     precache_model ("models/sprites/4.spr32");
1667     precache_model ("models/sprites/5.spr32");
1668     precache_model ("models/sprites/6.spr32");
1669     precache_model ("models/sprites/7.spr32");
1670     precache_model ("models/sprites/8.spr32");
1671     precache_model ("models/sprites/9.spr32");
1672     precache_model ("models/sprites/10.spr32");
1673
1674     // common weapon precaches
1675     precache_sound ("weapons/weapon_switch.wav");
1676     precache_sound ("weapons/weaponpickup.wav");
1677     precache_sound ("weapons/unavailable.wav");
1678     if (g_grappling_hook)
1679     {
1680         precache_sound ("weapons/hook_fire.wav"); // hook
1681         precache_sound ("weapons/hook_impact.wav"); // hook
1682     }
1683
1684     if(cvar("sv_precacheweapons"))
1685     {
1686         //precache weapon models/sounds
1687         local float wep;
1688         wep = WEP_FIRST;
1689         while (wep <= WEP_LAST)
1690         {
1691             weapon_action(wep, WR_PRECACHE);
1692             wep = wep + 1;
1693         }
1694     }
1695
1696     precache_model("models/elaser.mdl");
1697     precache_model("models/laser.mdl");
1698     precache_model("models/ebomb.mdl");
1699
1700 #if 0
1701     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1702
1703     if (!self.noise && self.music) // quake 3 uses the music field
1704         self.noise = self.music;
1705
1706     // plays music for the level if there is any
1707     if (self.noise)
1708     {
1709         precache_sound (self.noise);
1710         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1711     }
1712 #endif
1713 }
1714
1715 // sorry, but using \ in macros breaks line numbers
1716 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1717 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1718 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1719
1720 // WARNING: this kills the trace globals
1721 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1722 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1723
1724 #define INITPRIO_FIRST              0
1725 #define INITPRIO_GAMETYPE           0
1726 #define INITPRIO_GAMETYPE_FALLBACK  1
1727 #define INITPRIO_CVARS              5
1728 #define INITPRIO_FINDTARGET        10
1729 #define INITPRIO_DROPTOFLOOR       20
1730 #define INITPRIO_SETLOCATION       90
1731 #define INITPRIO_LINKDOORS         91
1732 #define INITPRIO_LAST              99
1733
1734 .void(void) initialize_entity;
1735 .float initialize_entity_order;
1736 .entity initialize_entity_next;
1737 entity initialize_entity_first;
1738
1739 void make_safe_for_remove(entity e)
1740 {
1741     if (e.initialize_entity)
1742     {
1743         entity ent, prev;
1744         for (ent = initialize_entity_first; ent; )
1745         {
1746             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1747             {
1748                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1749                 // skip it in linked list
1750                 if (prev)
1751                 {
1752                     prev.initialize_entity_next = ent.initialize_entity_next;
1753                     ent = prev.initialize_entity_next;
1754                 }
1755                 else
1756                 {
1757                     initialize_entity_first = ent.initialize_entity_next;
1758                     ent = initialize_entity_first;
1759                 }
1760             }
1761             else
1762             {
1763                 prev = ent;
1764                 ent = ent.initialize_entity_next;
1765             }
1766         }
1767     }
1768 }
1769
1770 void objerror(string s)
1771 {
1772     make_safe_for_remove(self);
1773     objerror_builtin(s);
1774 }
1775
1776 void remove_unsafely(entity e)
1777 {
1778     remove_builtin(e);
1779 }
1780
1781 void remove_safely(entity e)
1782 {
1783     make_safe_for_remove(e);
1784     remove_builtin(e);
1785 }
1786
1787 void InitializeEntity(entity e, void(void) func, float order)
1788 {
1789     entity prev, cur;
1790
1791     if (!e || e.initialize_entity)
1792     {
1793         // make a proxy initializer entity
1794         entity e_old;
1795         e_old = e;
1796         e = spawn();
1797         e.classname = "initialize_entity";
1798         e.enemy = e_old;
1799     }
1800
1801     e.initialize_entity = func;
1802     e.initialize_entity_order = order;
1803
1804     cur = initialize_entity_first;
1805     for (;;)
1806     {
1807         if (!cur || cur.initialize_entity_order > order)
1808         {
1809             // insert between prev and cur
1810             if (prev)
1811                 prev.initialize_entity_next = e;
1812             else
1813                 initialize_entity_first = e;
1814             e.initialize_entity_next = cur;
1815             return;
1816         }
1817         prev = cur;
1818         cur = cur.initialize_entity_next;
1819     }
1820 }
1821 void InitializeEntitiesRun()
1822 {
1823     entity startoflist;
1824     startoflist = initialize_entity_first;
1825     initialize_entity_first = world;
1826     for (self = startoflist; self; )
1827     {
1828         entity e;
1829         var void(void) func;
1830         e = self.initialize_entity_next;
1831         func = self.initialize_entity;
1832         self.initialize_entity_order = 0;
1833         self.initialize_entity = func_null;
1834         self.initialize_entity_next = world;
1835         if (self.classname == "initialize_entity")
1836         {
1837             entity e_old;
1838             e_old = self.enemy;
1839             remove_builtin(self);
1840             self = e_old;
1841         }
1842         //dprint("Delayed initialization: ", self.classname, "\n");
1843         func();
1844         self = e;
1845     }
1846 }
1847
1848 .float uncustomizeentityforclient_set;
1849 .void(void) uncustomizeentityforclient;
1850 void(void) SUB_Nullpointer = #0;
1851 void UncustomizeEntitiesRun()
1852 {
1853     entity oldself;
1854     oldself = self;
1855     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1856         self.uncustomizeentityforclient();
1857     self = oldself;
1858 }
1859 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1860 {
1861     e.customizeentityforclient = customizer;
1862     e.uncustomizeentityforclient = uncustomizer;
1863     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1864 }
1865
1866 .float nottargeted;
1867 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1868
1869 void() SUB_Remove;
1870 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1871 {
1872     vector mi, ma;
1873
1874     if (e.classname == "")
1875         e.classname = "net_linked";
1876
1877     if (e.model == "" || self.modelindex == 0)
1878     {
1879         mi = e.mins;
1880         ma = e.maxs;
1881         setmodel(e, "null");
1882         setsize(e, mi, ma);
1883     }
1884
1885     e.SendEntity = sendfunc;
1886     e.SendFlags = 0xFFFFFF;
1887
1888     if (!docull)
1889         e.effects |= EF_NODEPTHTEST;
1890
1891     if (dt)
1892     {
1893         e.nextthink = time + dt;
1894         e.think = SUB_Remove;
1895     }
1896 }
1897
1898 void adaptor_think2touch()
1899 {
1900     entity o;
1901     o = other;
1902     other = world;
1903     self.touch();
1904     other = o;
1905 }
1906
1907 void adaptor_think2use()
1908 {
1909     entity o, a;
1910     o = other;
1911     a = activator;
1912     activator = world;
1913     other = world;
1914     self.use();
1915     other = o;
1916     activator = a;
1917 }
1918
1919 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1920 {
1921         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1922                 self.projectiledeathtype |= HITTYPE_SPLASH;
1923         adaptor_think2use();
1924 }
1925
1926 // deferred dropping
1927 void DropToFloor_Handler()
1928 {
1929     droptofloor_builtin();
1930     self.dropped_origin = self.origin;
1931 }
1932
1933 void droptofloor()
1934 {
1935     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1936 }
1937
1938
1939
1940 float trace_hits_box_a0, trace_hits_box_a1;
1941
1942 float trace_hits_box_1d(float end, float thmi, float thma)
1943 {
1944     if (end == 0)
1945     {
1946         // just check if x is in range
1947         if (0 < thmi)
1948             return FALSE;
1949         if (0 > thma)
1950             return FALSE;
1951     }
1952     else
1953     {
1954         // do the trace with respect to x
1955         // 0 -> end has to stay in thmi -> thma
1956         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1957         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1958         if (trace_hits_box_a0 > trace_hits_box_a1)
1959             return FALSE;
1960     }
1961     return TRUE;
1962 }
1963
1964 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1965 {
1966     end -= start;
1967     thmi -= start;
1968     thma -= start;
1969     // now it is a trace from 0 to end
1970
1971     trace_hits_box_a0 = 0;
1972     trace_hits_box_a1 = 1;
1973
1974     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1975         return FALSE;
1976     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1977         return FALSE;
1978     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1979         return FALSE;
1980
1981     return TRUE;
1982 }
1983
1984 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1985 {
1986     return trace_hits_box(start, end, thmi - ma, thma - mi);
1987 }
1988
1989 float SUB_NoImpactCheck()
1990 {
1991         // zero hitcontents = this is not the real impact, but either the
1992         // mirror-impact of something hitting the projectile instead of the
1993         // projectile hitting the something, or a touchareagrid one. Neither of
1994         // these stop the projectile from moving, so...
1995         if(trace_dphitcontents == 0)
1996         {
1997                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1998                 checkclient();
1999         }
2000     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2001         return 1;
2002     if (other == world && self.size != '0 0 0')
2003     {
2004         vector tic;
2005         tic = self.velocity * sys_frametime;
2006         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2007         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2008         if (trace_fraction >= 1)
2009         {
2010             dprint("Odd... did not hit...?\n");
2011         }
2012         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2013         {
2014             dprint("Detected and prevented the sky-grapple bug.\n");
2015             return 1;
2016         }
2017     }
2018
2019     return 0;
2020 }
2021
2022 #define SUB_OwnerCheck() (other && (other == self.owner))
2023
2024 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2025 {
2026         if(SUB_OwnerCheck())
2027                 return TRUE;
2028         if(SUB_NoImpactCheck())
2029         {
2030                 remove(self);
2031                 return TRUE;
2032         }
2033         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2034                 UpdateCSQCProjectileNextFrame(self);
2035         return FALSE;
2036 }
2037 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2038
2039 float MAX_IPBAN_URIS = 16;
2040
2041 float URI_GET_DISCARD   = 0;
2042 float URI_GET_IPBAN     = 1;
2043 float URI_GET_IPBAN_END = 16;
2044
2045 void URI_Get_Callback(float id, float status, string data)
2046 {
2047     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2048     dprint(data);
2049     dprint("\nEnd of data.\n");
2050
2051     if (id == URI_GET_DISCARD)
2052     {
2053         // discard
2054     }
2055     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2056     {
2057         // online ban list
2058         OnlineBanList_URI_Get_Callback(id, status, data);
2059     }
2060     else
2061     {
2062         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2063     }
2064 }
2065
2066 void print_to(entity e, string s)
2067 {
2068     if (e)
2069         sprint(e, strcat(s, "\n"));
2070     else
2071         print(s, "\n");
2072 }
2073
2074 string getrecords(float page) // 50 records per page
2075 {
2076     float rec;
2077     string h;
2078     float r;
2079     float i;
2080     string s;
2081
2082     rec = 0;
2083
2084     s = "";
2085
2086     if (g_ctf)
2087     {
2088         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2089         {
2090             if (MapInfo_Get_ByID(i))
2091             {
2092                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2093                 if (r == 0)
2094                     continue;
2095                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2096                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2097                 ++rec;
2098             }
2099         }
2100     }
2101
2102     if (g_race)
2103     {
2104         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2105         {
2106             if (MapInfo_Get_ByID(i))
2107             {
2108                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time")));
2109                 if (r == 0)
2110                     continue;
2111                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "netname"));
2112                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2113                 ++rec;
2114             }
2115         }
2116     }
2117
2118     if (g_cts)
2119     {
2120         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2121         {
2122             if (MapInfo_Get_ByID(i))
2123             {
2124                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time")));
2125                 if (r == 0)
2126                     continue;
2127                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "netname"));
2128                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2129                 ++rec;
2130             }
2131         }
2132     }
2133
2134     MapInfo_ClearTemps();
2135
2136     if (s == "" && page == 0)
2137         return "No records are available on this server.\n";
2138     else
2139         return s;
2140 }
2141
2142 string getrankings()
2143 {
2144     string n;
2145     float t;
2146     float i;
2147     string s;
2148     string p;
2149     string map;
2150
2151     s = "";
2152
2153     map = GetMapname();
2154
2155     for (i = 1; i <= RANKINGS_CNT; ++i)
2156     {
2157         t = race_GetTime(i);
2158         if (t == 0)
2159             continue;
2160         n = race_GetName(i);
2161         p = race_PlaceName(i);
2162         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2163     }
2164
2165     MapInfo_ClearTemps();
2166
2167     if (s == "")
2168         return strcat("No records are available for the map: ", map, "\n");
2169     else
2170         return strcat("Records for ", map, ":\n", s);
2171 }
2172
2173 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2174 {
2175     float m, i;
2176     vector start, org, delta, end, enddown, mstart;
2177
2178     m = e.dphitcontentsmask;
2179     e.dphitcontentsmask = goodcontents | badcontents;
2180
2181     org = world.mins;
2182     delta = world.maxs - world.mins;
2183
2184     for (i = 0; i < attempts; ++i)
2185     {
2186         start_x = org_x + random() * delta_x;
2187         start_y = org_y + random() * delta_y;
2188         start_z = org_z + random() * delta_z;
2189
2190         // rule 1: start inside world bounds, and outside
2191         // solid, and don't start from somewhere where you can
2192         // fall down to evil
2193         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2194         if (trace_fraction >= 1)
2195             continue;
2196         if (trace_startsolid)
2197             continue;
2198         if (trace_dphitcontents & badcontents)
2199             continue;
2200         if (trace_dphitq3surfaceflags & badsurfaceflags)
2201             continue;
2202
2203         // rule 2: if we are too high, lower the point
2204         if (trace_fraction * delta_z > maxaboveground)
2205             start = trace_endpos + '0 0 1' * maxaboveground;
2206         enddown = trace_endpos;
2207
2208         // rule 3: make sure we aren't outside the map. This only works
2209         // for somewhat well formed maps. A good rule of thumb is that
2210         // the map should have a convex outside hull.
2211         // these can be traceLINES as we already verified the starting box
2212         mstart = start + 0.5 * (e.mins + e.maxs);
2213         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2214         if (trace_fraction >= 1)
2215             continue;
2216         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2217         if (trace_fraction >= 1)
2218             continue;
2219         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2220         if (trace_fraction >= 1)
2221             continue;
2222         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2223         if (trace_fraction >= 1)
2224             continue;
2225         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2226         if (trace_fraction >= 1)
2227             continue;
2228
2229         // find a random vector to "look at"
2230         end_x = org_x + random() * delta_x;
2231         end_y = org_y + random() * delta_y;
2232         end_z = org_z + random() * delta_z;
2233         end = start + normalize(end - start) * vlen(delta);
2234
2235         // rule 4: start TO end must not be too short
2236         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2237         if (trace_startsolid)
2238             continue;
2239         if (trace_fraction < minviewdistance / vlen(delta))
2240             continue;
2241
2242         // rule 5: don't want to look at sky
2243         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2244             continue;
2245
2246         // rule 6: we must not end up in trigger_hurt
2247         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2248         {
2249             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2250             continue;
2251         }
2252
2253         break;
2254     }
2255
2256     e.dphitcontentsmask = m;
2257
2258     if (i < attempts)
2259     {
2260         setorigin(e, start);
2261         e.angles = vectoangles(end - start);
2262         dprint("Needed ", ftos(i + 1), " attempts\n");
2263         return TRUE;
2264     }
2265     else
2266         return FALSE;
2267 }
2268
2269 float zcurveparticles_effectno;
2270 vector zcurveparticles_start;
2271 float zcurveparticles_spd;
2272
2273 void endzcurveparticles()
2274 {
2275         if(zcurveparticles_effectno)
2276         {
2277                 // terminator
2278                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2279         }
2280         zcurveparticles_effectno = 0;
2281 }
2282
2283 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2284 {
2285         spd = bound(0, floor(spd / 16), 32767);
2286         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2287         {
2288                 endzcurveparticles();
2289                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2290                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2291                 WriteShort(MSG_BROADCAST, effectno);
2292                 WriteCoord(MSG_BROADCAST, start_x);
2293                 WriteCoord(MSG_BROADCAST, start_y);
2294                 WriteCoord(MSG_BROADCAST, start_z);
2295                 zcurveparticles_effectno = effectno;
2296                 zcurveparticles_start = start;
2297         }
2298         else
2299                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2300         WriteCoord(MSG_BROADCAST, end_x);
2301         WriteCoord(MSG_BROADCAST, end_y);
2302         WriteCoord(MSG_BROADCAST, end_z);
2303         WriteCoord(MSG_BROADCAST, end_dz);
2304         zcurveparticles_spd = spd;
2305 }
2306
2307 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2308 {
2309         float end_dz;
2310         vector vecxy, velxy;
2311
2312         vecxy = end - start;
2313         vecxy_z = 0;
2314         velxy = vel;
2315         velxy_z = 0;
2316
2317         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2318         {
2319                 endzcurveparticles();
2320                 trailparticles(world, effectno, start, end);
2321                 return;
2322         }
2323
2324         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2325         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2326 }
2327
2328 string GetGametype(); // g_world.qc
2329 void write_recordmarker(entity pl, float tstart, float dt)
2330 {
2331     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2332
2333     // also write a marker into demo files for demotc-race-record-extractor to find
2334     stuffcmd(pl,
2335              strcat(
2336                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2337                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2338 }
2339
2340 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter)
2341 {
2342         switch(self.owner.cvar_cl_gunalign)
2343         {
2344                 case 1: // right
2345                         break;
2346
2347                 case 2: // left
2348                         vecs_y = -vecs_y;
2349                         break;
2350
2351                 default:
2352                 case 3:
2353                         if(allowcenter) // 2: allow center handedness
2354                         {
2355                                 // center
2356                                 vecs_y = 0;
2357                                 vecs_z -= 2;
2358                         }
2359                         else
2360                         {
2361                                 // right
2362                         }
2363                         break;
2364
2365                 case 4:
2366                         if(allowcenter) // 2: allow center handedness
2367                         {
2368                                 // center
2369                                 vecs_y = 0;
2370                                 vecs_z -= 2;
2371                         }
2372                         else
2373                         {
2374                                 // left
2375                                 vecs_y = -vecs_y;
2376                         }
2377                         break;
2378         }
2379         return vecs;
2380 }
2381
2382 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2383 {
2384         string s;
2385         vector v;
2386
2387         if (cvar("g_shootfromeye"))
2388         {
2389                 if (visual)
2390                 {
2391                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE);
2392                 }
2393                 else
2394                 {
2395                         vecs_y = 0;
2396                         vecs_z = 0;
2397                 }
2398         }
2399         else if (cvar("g_shootfromcenter"))
2400         {
2401                 if (visual)
2402                 {
2403                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE);
2404                 }
2405                 else
2406                 {
2407                         vecs_y = 0;
2408                         vecs_z -= 2;
2409                 }
2410         }
2411         else if ((s = cvar_string("g_shootfromfixedorigin")) != "")
2412         {
2413                 v = stov(s);
2414                 if (y_is_right)
2415                         v_y = -v_y;
2416                 if (v_x != 0)
2417                         vecs_x = v_x;
2418                 vecs_y = v_y;
2419                 vecs_z = v_z;
2420         }
2421         else if (cvar("g_shootfromclient"))
2422         {
2423                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (cvar("g_shootfromclient") >= 2));
2424         }
2425         return vecs;
2426 }
2427
2428
2429
2430 void attach_sameorigin(entity e, entity to, string tag)
2431 {
2432     vector org, t_forward, t_left, t_up, e_forward, e_up;
2433     vector org0, ang0;
2434     float tagscale;
2435
2436     ang0 = e.angles;
2437     org0 = e.origin;
2438
2439     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2440     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2441     t_forward = v_forward * tagscale;
2442     t_left = v_right * -tagscale;
2443     t_up = v_up * tagscale;
2444
2445     e.origin_x = org * t_forward;
2446     e.origin_y = org * t_left;
2447     e.origin_z = org * t_up;
2448
2449     // current forward and up directions
2450     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2451                 e.angles = AnglesTransform_FromVAngles(e.angles);
2452         else
2453                 e.angles = AnglesTransform_FromAngles(e.angles);
2454     fixedmakevectors(e.angles);
2455
2456     // untransform forward, up!
2457     e_forward_x = v_forward * t_forward;
2458     e_forward_y = v_forward * t_left;
2459     e_forward_z = v_forward * t_up;
2460     e_up_x = v_up * t_forward;
2461     e_up_y = v_up * t_left;
2462     e_up_z = v_up * t_up;
2463
2464     e.angles = fixedvectoangles2(e_forward, e_up);
2465     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2466                 e.angles = AnglesTransform_ToVAngles(e.angles);
2467         else
2468                 e.angles = AnglesTransform_ToAngles(e.angles);
2469
2470     setattachment(e, to, tag);
2471     setorigin(e, e.origin);
2472 }
2473
2474 void detach_sameorigin(entity e)
2475 {
2476     vector org;
2477     org = gettaginfo(e, 0);
2478     e.angles = fixedvectoangles2(v_forward, v_up);
2479     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2480                 e.angles = AnglesTransform_ToVAngles(e.angles);
2481         else
2482                 e.angles = AnglesTransform_ToAngles(e.angles);
2483     setorigin(e, org);
2484     setattachment(e, world, "");
2485     setorigin(e, e.origin);
2486 }
2487
2488 void follow_sameorigin(entity e, entity to)
2489 {
2490     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2491     e.aiment = to; // make the hole follow bmodel
2492     e.punchangle = to.angles; // the original angles of bmodel
2493     e.view_ofs = e.origin - to.origin; // relative origin
2494     e.v_angle = e.angles - to.angles; // relative angles
2495 }
2496
2497 void unfollow_sameorigin(entity e)
2498 {
2499     e.movetype = MOVETYPE_NONE;
2500 }
2501
2502 entity gettaginfo_relative_ent;
2503 vector gettaginfo_relative(entity e, float tag)
2504 {
2505     if (!gettaginfo_relative_ent)
2506     {
2507         gettaginfo_relative_ent = spawn();
2508         gettaginfo_relative_ent.effects = EF_NODRAW;
2509     }
2510     gettaginfo_relative_ent.model = e.model;
2511     gettaginfo_relative_ent.modelindex = e.modelindex;
2512     gettaginfo_relative_ent.frame = e.frame;
2513     return gettaginfo(gettaginfo_relative_ent, tag);
2514 }
2515
2516 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2517 {
2518     float p;
2519     p = pow(2, chan);
2520     if (pl.soundentity.cnt & p)
2521         return;
2522     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2523     pl.soundentity.cnt |= p;
2524 }
2525
2526 void SoundEntity_StopSound(entity pl, float chan)
2527 {
2528     float p;
2529     p = pow(2, chan);
2530     if (pl.soundentity.cnt & p)
2531     {
2532         stopsoundto(MSG_ALL, pl.soundentity, chan);
2533         pl.soundentity.cnt &~= p;
2534     }
2535 }
2536
2537 void SoundEntity_Attach(entity pl)
2538 {
2539     pl.soundentity = spawn();
2540     pl.soundentity.classname = "soundentity";
2541     pl.soundentity.owner = pl;
2542     setattachment(pl.soundentity, pl, "");
2543     setmodel(pl.soundentity, "null");
2544 }
2545
2546 void SoundEntity_Detach(entity pl)
2547 {
2548     float i;
2549     for (i = 0; i <= 7; ++i)
2550         SoundEntity_StopSound(pl, i);
2551 }
2552
2553
2554 float ParseCommandPlayerSlotTarget_firsttoken;
2555 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2556 {
2557     string s;
2558     entity e, head;
2559     float n;
2560
2561     s = string_null;
2562
2563     ParseCommandPlayerSlotTarget_firsttoken = -1;
2564
2565     if (tokens > idx)
2566     {
2567         if (substring(argv(idx), 0, 1) == "#")
2568         {
2569             s = substring(argv(idx), 1, -1);
2570             ++idx;
2571             if (s == "")
2572                 if (tokens > idx)
2573                 {
2574                     s = argv(idx);
2575                     ++idx;
2576                 }
2577                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2578             if (s == ftos(stof(s)))
2579             {
2580                 e = edict_num(stof(s));
2581                 if (e.flags & FL_CLIENT)
2582                     return e;
2583             }
2584         }
2585         else
2586         {
2587             // it must be a nick name
2588             s = argv(idx);
2589             ++idx;
2590                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2591
2592             n = 0;
2593             FOR_EACH_CLIENT(head)
2594             if (head.netname == s)
2595             {
2596                 e = head;
2597                 ++n;
2598             }
2599             if (n == 1)
2600                 return e;
2601
2602             s = strdecolorize(s);
2603             n = 0;
2604             FOR_EACH_CLIENT(head)
2605             if (strdecolorize(head.netname) == s)
2606             {
2607                 e = head;
2608                 ++n;
2609             }
2610             if (n == 1)
2611                 return e;
2612         }
2613     }
2614
2615     return world;
2616 }
2617
2618 .float scale2;
2619
2620 float modeleffect_SendEntity(entity to, float sf)
2621 {
2622         float f;
2623         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2624
2625         f = 0;
2626         if(self.velocity != '0 0 0')
2627                 f |= 1;
2628         if(self.angles != '0 0 0')
2629                 f |= 2;
2630         if(self.avelocity != '0 0 0')
2631                 f |= 4;
2632
2633         WriteByte(MSG_ENTITY, f);
2634         WriteShort(MSG_ENTITY, self.modelindex);
2635         WriteByte(MSG_ENTITY, self.skin);
2636         WriteByte(MSG_ENTITY, self.frame);
2637         WriteCoord(MSG_ENTITY, self.origin_x);
2638         WriteCoord(MSG_ENTITY, self.origin_y);
2639         WriteCoord(MSG_ENTITY, self.origin_z);
2640         if(f & 1)
2641         {
2642                 WriteCoord(MSG_ENTITY, self.velocity_x);
2643                 WriteCoord(MSG_ENTITY, self.velocity_y);
2644                 WriteCoord(MSG_ENTITY, self.velocity_z);
2645         }
2646         if(f & 2)
2647         {
2648                 WriteCoord(MSG_ENTITY, self.angles_x);
2649                 WriteCoord(MSG_ENTITY, self.angles_y);
2650                 WriteCoord(MSG_ENTITY, self.angles_z);
2651         }
2652         if(f & 4)
2653         {
2654                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2655                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2656                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2657         }
2658         WriteShort(MSG_ENTITY, self.scale * 256.0);
2659         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2660         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2661         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2662         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2663
2664         return TRUE;
2665 }
2666
2667 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2668 {
2669         entity e;
2670         float sz;
2671         e = spawn();
2672         e.classname = "modeleffect";
2673         setmodel(e, m);
2674         e.frame = f;
2675         setorigin(e, o);
2676         e.velocity = v;
2677         e.angles = ang;
2678         e.avelocity = angv;
2679         e.alpha = a;
2680         e.teleport_time = t1;
2681         e.fade_time = t2;
2682         e.skin = s;
2683         if(s0 >= 0)
2684                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2685         else
2686                 e.scale = -s0;
2687         if(s2 >= 0)
2688                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2689         else
2690                 e.scale2 = -s2;
2691         sz = max(e.scale, e.scale2);
2692         setsize(e, e.mins * sz, e.maxs * sz);
2693         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2694 }
2695
2696 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2697 {
2698         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2699 }
2700
2701 float randombit(float bits)
2702 {
2703         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2704                 return bits;
2705
2706         float n, f, b, r;
2707
2708         r = random();
2709         b = 0;
2710         n = 0;
2711
2712         for(f = 1; f <= bits; f *= 2)
2713         {
2714                 if(bits & f)
2715                 {
2716                         ++n;
2717                         r *= n;
2718                         if(r <= 1)
2719                                 b = f;
2720                         else
2721                                 r = (r - 1) / (n - 1);
2722                 }
2723         }
2724
2725         return b;
2726 }
2727
2728 float randombits(float bits, float k, float error_return)
2729 {
2730         float r;
2731         r = 0;
2732         while(k > 0 && bits != r)
2733         {
2734                 r += randombit(bits - r);
2735                 --k;
2736         }
2737         if(error_return)
2738                 if(k > 0)
2739                         return -1; // all
2740         return r;
2741 }
2742
2743 void randombit_test(float bits, float iter)
2744 {
2745         while(iter > 0)
2746         {
2747                 print(ftos(randombit(bits)), "\n");
2748                 --iter;
2749         }
2750 }
2751
2752 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2753 {
2754         if(halflifedist > 0)
2755                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2756         else if(halflifedist < 0)
2757                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2758         else
2759                 return 1;
2760 }
2761
2762
2763
2764
2765 #ifdef RELEASE
2766 #define cvar_string_normal cvar_string_builtin
2767 #define cvar_normal cvar_builtin
2768 #else
2769 string cvar_string_normal(string n)
2770 {
2771         if not(cvar_type(n) & 1)
2772                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2773         return cvar_string_builtin(n);
2774 }
2775
2776 float cvar_normal(string n)
2777 {
2778         return stof(cvar_string_normal(n));
2779 }
2780 #endif
2781 #define cvar_set_normal cvar_set_builtin
2782
2783 void defer_think()
2784 {
2785     entity oself;
2786
2787     oself           = self;
2788     self            = self.owner;
2789     oself.think     = SUB_Remove;
2790     oself.nextthink = time;
2791
2792     oself.use();
2793 }
2794
2795 /*
2796     Execute func() after time + fdelay.
2797     self when func is executed = self when defer is called
2798 */
2799 void defer(float fdelay, void() func)
2800 {
2801     entity e;
2802
2803     e           = spawn();
2804     e.owner     = self;
2805     e.use       = func;
2806     e.think     = defer_think;
2807     e.nextthink = time + fdelay;
2808 }