qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2 #include "_all.qh"
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/mutators_include.qh"
   9 #include "t_items.qh"
  10 #include "weapons/accuracy.qh"
  11 #include "weapons/csqcprojectile.qh"
  12 #include "weapons/selection.qh"
  13 #include "../common/command/generic.qh"
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes.qh"
  16 #include "../common/mapinfo.qh"
  17 #include "../common/notifications.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../common/teams.qh"
  20 #include "../common/triggers/subs.qh"
  21 #include "../common/util.qh"
  22 #include "../common/turrets/sv_turrets.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../csqcmodellib/sv_model.qh"
  25 #include "../warpzonelib/anglestransform.qh"
  26 #include "../warpzonelib/server.qh"
  27
  28 void crosshair_trace(entity pl)
  29 {
  30         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  31 }
  32 void crosshair_trace_plusvisibletriggers(entity pl)
  33 {
  34         entity first;
  35         entity e;
  36         first = findchainfloat(solid, SOLID_TRIGGER);
  37
  38         for (e = first; e; e = e.chain)
  39                 if (e.model != "")
  40                         e.solid = SOLID_BSP;
  41
  42         crosshair_trace(pl);
  43
  44         for (e = first; e; e = e.chain)
  45                 e.solid = SOLID_TRIGGER;
  46 }
  47 void WarpZone_crosshair_trace(entity pl)
  48 {
  49         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  50 }
  51
  52
  53 string admin_name(void)
  54 {
  55         if(autocvar_sv_adminnick != "")
  56                 return autocvar_sv_adminnick;
  57         else
  58                 return "SERVER ADMIN";
  59 }
  60
  61 void DistributeEvenly_Init(float amount, float totalweight)
  62 {
  63     if (DistributeEvenly_amount)
  64     {
  65         LOG_TRACE("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  66         LOG_TRACE(ftos(DistributeEvenly_totalweight), " left!)\n");
  67     }
  68     if (totalweight == 0)
  69         DistributeEvenly_amount = 0;
  70     else
  71         DistributeEvenly_amount = amount;
  72     DistributeEvenly_totalweight = totalweight;
  73 }
  74 float DistributeEvenly_Get(float weight)
  75 {
  76     float f;
  77     if (weight <= 0)
  78         return 0;
  79     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  80     DistributeEvenly_totalweight -= weight;
  81     DistributeEvenly_amount -= f;
  82     return f;
  83 }
  84 float DistributeEvenly_GetRandomized(float weight)
  85 {
  86     float f;
  87     if (weight <= 0)
  88         return 0;
  89     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  90     DistributeEvenly_totalweight -= weight;
  91     DistributeEvenly_amount -= f;
  92     return f;
  93 }
  94
  95
  96 void GameLogEcho(string s)
  97 {
  98     string fn;
  99     int matches;
 100
 101     if (autocvar_sv_eventlog_files)
 102     {
 103         if (!logfile_open)
 104         {
 105             logfile_open = true;
 106             matches = autocvar_sv_eventlog_files_counter + 1;
 107             cvar_set("sv_eventlog_files_counter", itos(matches));
 108             fn = ftos(matches);
 109             if (strlen(fn) < 8)
 110                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 111             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 112             logfile = fopen(fn, FILE_APPEND);
 113             fputs(logfile, ":logversion:3\n");
 114         }
 115         if (logfile >= 0)
 116         {
 117             if (autocvar_sv_eventlog_files_timestamps)
 118                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 119             else
 120                 fputs(logfile, strcat(s, "\n"));
 121         }
 122     }
 123     if (autocvar_sv_eventlog_console)
 124     {
 125         LOG_INFO(s, "\n");
 126     }
 127 }
 128
 129 void GameLogInit()
 130 {
 131     logfile_open = 0;
 132     // will be opened later
 133 }
 134
 135 void GameLogClose()
 136 {
 137     if (logfile_open && logfile >= 0)
 138     {
 139         fclose(logfile);
 140         logfile = -1;
 141     }
 142 }
 143
 144 entity findnearest(vector point, .string field, string value, vector axismod)
 145 {
 146     entity localhead;
 147     float i;
 148     float j;
 149     float len;
 150     vector dist;
 151
 152     float num_nearest;
 153     num_nearest = 0;
 154
 155     localhead = find(world, field, value);
 156     while (localhead)
 157     {
 158         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 159             dist = localhead.oldorigin;
 160         else
 161             dist = localhead.origin;
 162         dist = dist - point;
 163         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 164         len = vlen(dist);
 165
 166         for (i = 0; i < num_nearest; ++i)
 167         {
 168             if (len < nearest_length[i])
 169                 break;
 170         }
 171
 172         // now i tells us where to insert at
 173         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 174         if (i < NUM_NEAREST_ENTITIES)
 175         {
 176             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 177             {
 178                 nearest_length[j + 1] = nearest_length[j];
 179                 nearest_entity[j + 1] = nearest_entity[j];
 180             }
 181             nearest_length[i] = len;
 182             nearest_entity[i] = localhead;
 183             if (num_nearest < NUM_NEAREST_ENTITIES)
 184                 num_nearest = num_nearest + 1;
 185         }
 186
 187         localhead = find(localhead, field, value);
 188     }
 189
 190     // now use the first one from our list that we can see
 191     for (i = 0; i < num_nearest; ++i)
 192     {
 193         traceline(point, nearest_entity[i].origin, true, world);
 194         if (trace_fraction == 1)
 195         {
 196             if (i != 0)
 197             {
 198                 LOG_TRACE("Nearest point (");
 199                 LOG_TRACE(nearest_entity[0].netname);
 200                 LOG_TRACE(") is not visible, using a visible one.\n");
 201             }
 202             return nearest_entity[i];
 203         }
 204     }
 205
 206     if (num_nearest == 0)
 207         return world;
 208
 209     LOG_TRACE("Not seeing any location point, using nearest as fallback.\n");
 210     /* DEBUGGING CODE:
 211     dprint("Candidates were: ");
 212     for(j = 0; j < num_nearest; ++j)
 213     {
 214         if(j != 0)
 215                 dprint(", ");
 216         dprint(nearest_entity[j].netname);
 217     }
 218     dprint("\n");
 219     */
 220
 221     return nearest_entity[0];
 222 }
 223
 224 string NearestLocation(vector p)
 225 {
 226     entity loc;
 227     string ret;
 228     ret = "somewhere";
 229     loc = findnearest(p, classname, "target_location", '1 1 1');
 230     if (loc)
 231     {
 232         ret = loc.message;
 233     }
 234     else
 235     {
 236         loc = findnearest(p, target, "###item###", '1 1 4');
 237         if (loc)
 238             ret = loc.netname;
 239     }
 240     return ret;
 241 }
 242
 243 string formatmessage(string msg)
 244 {SELFPARAM();
 245         float p, p1, p2;
 246         float n;
 247         vector cursor;
 248         entity cursor_ent;
 249         string escape;
 250         string replacement;
 251         string ammoitems;
 252         p = 0;
 253         n = 7;
 254
 255         ammoitems = "batteries";
 256         if(self.items & ITEM_Plasma.m_itemid) ammoitems = ITEM_Plasma.m_name;
 257         if(self.items & ITEM_Cells.m_itemid) ammoitems = ITEM_Cells.m_name;
 258         if(self.items & ITEM_Rockets.m_itemid) ammoitems = ITEM_Rockets.m_name;
 259         if(self.items & ITEM_Shells.m_itemid) ammoitems = ITEM_Shells.m_name;
 260
 261         WarpZone_crosshair_trace(self);
 262         cursor = trace_endpos;
 263         cursor_ent = trace_ent;
 264
 265         while (1) {
 266                 if (n < 1)
 267                         break; // too many replacements
 268
 269                 n = n - 1;
 270                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 271                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 272
 273                 if (p1 < 0)
 274                         p1 = p2;
 275
 276                 if (p2 < 0)
 277                         p2 = p1;
 278
 279                 p = min(p1, p2);
 280
 281                 if (p < 0)
 282                         break;
 283
 284                 replacement = substring(msg, p, 2);
 285                 escape = substring(msg, p + 1, 1);
 286
 287                 switch(escape)
 288                 {
 289                         case "%": replacement = "%"; break;
 290                         case "\\":replacement = "\\"; break;
 291                         case "n": replacement = "\n"; break;
 292                         case "a": replacement = ftos(floor(self.armorvalue)); break;
 293                         case "h": replacement = ftos(floor(self.health)); break;
 294                         case "l": replacement = NearestLocation(self.origin); break;
 295                         case "y": replacement = NearestLocation(cursor); break;
 296                         case "d": replacement = NearestLocation(self.death_origin); break;
 297                         case "w": replacement = WEP_NAME((!self.weapon) ? (!self.switchweapon ? self.cnt : self.switchweapon) : self.weapon); break;
 298                         case "W": replacement = ammoitems; break;
 299                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 300                         case "s": replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1')); break;
 301                         case "S": replacement = ftos(vlen(self.velocity)); break;
 302                         default:
 303                         {
 304                                 MUTATOR_CALLHOOK(FormatMessage, escape, replacement, msg);
 305                                 escape = format_escape;
 306                                 replacement = format_replacement;
 307                                 break;
 308                         }
 309                 }
 310
 311                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 312                 p = p + strlen(replacement);
 313         }
 314         return msg;
 315 }
 316
 317 /*
 318 =============
 319 GetCvars
 320 =============
 321 Called with:
 322   0:  sends the request
 323   >0: receives a cvar from name=argv(f) value=argv(f+1)
 324 */
 325 void GetCvars_handleString(string thisname, float f, .string field, string name)
 326 {SELFPARAM();
 327         if (f < 0)
 328         {
 329                 if (self.(field))
 330                         strunzone(self.(field));
 331                 self.(field) = string_null;
 332         }
 333         else if (f > 0)
 334         {
 335                 if (thisname == name)
 336                 {
 337                         if (self.(field))
 338                                 strunzone(self.(field));
 339                         self.(field) = strzone(argv(f + 1));
 340                 }
 341         }
 342         else
 343                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 344 }
 345 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 346 {SELFPARAM();
 347         GetCvars_handleString(thisname, f, field, name);
 348         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 349                 if (thisname == name)
 350                 {
 351                         string s = func(strcat1(self.(field)));
 352                         if (s != self.(field))
 353                         {
 354                                 strunzone(self.(field));
 355                                 self.(field) = strzone(s);
 356                         }
 357                 }
 358 }
 359 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 360 {SELFPARAM();
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                         self.(field) = stof(argv(f + 1));
 368         }
 369         else
 370                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 371 }
 372 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 373 {SELFPARAM();
 374         if (f < 0)
 375         {
 376         }
 377         else if (f > 0)
 378         {
 379                 if (thisname == name)
 380                 {
 381                         if (!self.(field))
 382                         {
 383                                 self.(field) = stof(argv(f + 1));
 384                                 if (!self.(field))
 385                                         self.(field) = -1;
 386                         }
 387                 }
 388         }
 389         else
 390         {
 391                 if (!self.(field))
 392                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 393         }
 394 }
 395 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 396 {SELFPARAM();
 397         string o;
 398         o = W_FixWeaponOrder_ForceComplete(wo);
 399         if(self.weaponorder_byimpulse)
 400         {
 401                 strunzone(self.weaponorder_byimpulse);
 402                 self.weaponorder_byimpulse = string_null;
 403         }
 404         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 405         return o;
 406 }
 407 void GetCvars(float f)
 408 {SELFPARAM();
 409         string s = string_null;
 410
 411         if (f > 0)
 412                 s = strcat1(argv(f));
 413
 414         get_cvars_f = f;
 415         get_cvars_s = s;
 416         MUTATOR_CALLHOOK(GetCvars);
 417
 418         Notification_GetCvars();
 419
 420         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 421         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 422         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 423         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 424         GetCvars_handleString(s, f, cvar_cl_physics, "cl_physics");
 425         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 426         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 427         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 428         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 429         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 434         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 436         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 437         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 438         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 439         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 440         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 441         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 442         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 443         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 444         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 445
 446         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 447         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 448
 449         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 450         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 451         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 452         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 453         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 454
 455         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 456         if (f > 0)
 457         {
 458                 if (s == "cl_weaponpriority")
 459                         self.switchweapon = w_getbestweapon(self);
 460                 if (s == "cl_allow_uidtracking")
 461                         PlayerStats_GameReport_AddPlayer(self);
 462         }
 463 }
 464
 465 // decolorizes and team colors the player name when needed
 466 string playername(entity p)
 467 {
 468     string t;
 469     if (teamplay && !intermission_running && IS_PLAYER(p))
 470     {
 471         t = Team_ColorCode(p.team);
 472         return strcat(t, strdecolorize(p.netname));
 473     }
 474     else
 475         return p.netname;
 476 }
 477
 478 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 479 {
 480         int i = weaponinfo.weapon;
 481         int d = 0;
 482
 483         if (!i)
 484                 return 0;
 485
 486         if (g_lms || g_ca || allguns)
 487         {
 488                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 489                         d = true;
 490                 else
 491                         d = false;
 492         }
 493         else if (g_cts)
 494                 d = (i == WEP_SHOTGUN.m_id);
 495         else if (g_nexball)
 496                 d = 0; // weapon is set a few lines later
 497         else
 498                 d = !(!weaponinfo.weaponstart);
 499
 500         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 501                 d |= (i == WEP_HOOK.m_id);
 502         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 503                 d = 0;
 504
 505         float t = weaponinfo.weaponstartoverride;
 506
 507         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 508
 509         // bit order in t:
 510         // 1: want or not
 511         // 2: is default?
 512         // 4: is set by default?
 513         if(t < 0)
 514                 t = 4 | (3 * d);
 515         else
 516                 t |= (2 * d);
 517
 518         return t;
 519 }
 520
 521 void readplayerstartcvars()
 522 {
 523         entity e;
 524         float i, j, t;
 525         string s;
 526
 527         // initialize starting values for players
 528         start_weapons = '0 0 0';
 529         start_weapons_default = '0 0 0';
 530         start_weapons_defaultmask = '0 0 0';
 531         start_items = 0;
 532         start_ammo_shells = 0;
 533         start_ammo_nails = 0;
 534         start_ammo_rockets = 0;
 535         start_ammo_cells = 0;
 536         start_ammo_plasma = 0;
 537         start_health = cvar("g_balance_health_start");
 538         start_armorvalue = cvar("g_balance_armor_start");
 539
 540         g_weaponarena = 0;
 541         g_weaponarena_weapons = '0 0 0';
 542
 543         s = cvar_string("g_weaponarena");
 544         if (s == "0" || s == "")
 545         {
 546                 if(g_ca || g_freezetag)
 547                         s = "most";
 548         }
 549
 550         if (s == "0" || s == "")
 551         {
 552                 // no arena
 553         }
 554         else if (s == "off")
 555         {
 556                 // forcibly turn off weaponarena
 557         }
 558         else if (s == "all" || s == "1")
 559         {
 560                 g_weaponarena = 1;
 561                 g_weaponarena_list = "All Weapons";
 562                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 563                 {
 564                         e = get_weaponinfo(j);
 565                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 566                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 567                 }
 568         }
 569         else if (s == "most")
 570         {
 571                 g_weaponarena = 1;
 572                 g_weaponarena_list = "Most Weapons";
 573                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 574                 {
 575                         e = get_weaponinfo(j);
 576                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 577                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 578                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 579                 }
 580         }
 581         else if (s == "none")
 582         {
 583                 g_weaponarena = 1;
 584                 g_weaponarena_list = "No Weapons";
 585         }
 586         else
 587         {
 588                 g_weaponarena = 1;
 589                 t = tokenize_console(s);
 590                 g_weaponarena_list = "";
 591                 for (i = 0; i < t; ++i)
 592                 {
 593                         s = argv(i);
 594                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 595                         {
 596                                 e = get_weaponinfo(j);
 597                                 if (e.netname == s)
 598                                 {
 599                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 600                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 601                                         break;
 602                                 }
 603                         }
 604                         if (j > WEP_LAST)
 605                         {
 606                                 LOG_INFO("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 607                         }
 608                 }
 609                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 610         }
 611
 612         if(g_weaponarena)
 613                 g_weaponarena_random = cvar("g_weaponarena_random");
 614         else
 615                 g_weaponarena_random = 0;
 616         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 617
 618         if (g_weaponarena)
 619         {
 620                 g_weapon_stay = 0; // incompatible
 621                 start_weapons = g_weaponarena_weapons;
 622                 start_items |= IT_UNLIMITED_AMMO;
 623         }
 624         else
 625         {
 626                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 627                 {
 628                         e = get_weaponinfo(i);
 629                         int w = want_weapon(e, false);
 630                         if(w & 1)
 631                                 start_weapons |= WepSet_FromWeapon(i);
 632                         if(w & 2)
 633                                 start_weapons_default |= WepSet_FromWeapon(i);
 634                         if(w & 4)
 635                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 636                 }
 637         }
 638
 639         if(!cvar("g_use_ammunition"))
 640                 start_items |= IT_UNLIMITED_AMMO;
 641
 642         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 643         {
 644                 start_ammo_shells = 999;
 645                 start_ammo_nails = 999;
 646                 start_ammo_rockets = 999;
 647                 start_ammo_cells = 999;
 648                 start_ammo_plasma = 999;
 649                 start_ammo_fuel = 999;
 650         }
 651         else
 652         {
 653                 start_ammo_shells = cvar("g_start_ammo_shells");
 654                 start_ammo_nails = cvar("g_start_ammo_nails");
 655                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 656                 start_ammo_cells = cvar("g_start_ammo_cells");
 657                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 658                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 659         }
 660
 661         if (warmup_stage)
 662         {
 663                 warmup_start_ammo_shells = start_ammo_shells;
 664                 warmup_start_ammo_nails = start_ammo_nails;
 665                 warmup_start_ammo_rockets = start_ammo_rockets;
 666                 warmup_start_ammo_cells = start_ammo_cells;
 667                 warmup_start_ammo_plasma = start_ammo_plasma;
 668                 warmup_start_ammo_fuel = start_ammo_fuel;
 669                 warmup_start_health = start_health;
 670                 warmup_start_armorvalue = start_armorvalue;
 671                 warmup_start_weapons = start_weapons;
 672                 warmup_start_weapons_default = start_weapons_default;
 673                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 674
 675                 if (!g_weaponarena && !g_ca && !g_freezetag)
 676                 {
 677                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 678                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 679                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 680                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 681                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 682                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 683                         warmup_start_health = cvar("g_warmup_start_health");
 684                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 685                         warmup_start_weapons = '0 0 0';
 686                         warmup_start_weapons_default = '0 0 0';
 687                         warmup_start_weapons_defaultmask = '0 0 0';
 688                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 689                         {
 690                                 e = get_weaponinfo(i);
 691                                 int w = want_weapon(e, g_warmup_allguns);
 692                                 if(w & 1)
 693                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 694                                 if(w & 2)
 695                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 696                                 if(w & 4)
 697                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 698                         }
 699                 }
 700         }
 701
 702         if (g_jetpack)
 703                 start_items |= ITEM_Jetpack.m_itemid;
 704
 705         MUTATOR_CALLHOOK(SetStartItems);
 706
 707         if ((start_items & ITEM_Jetpack.m_itemid) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 708         {
 709                 start_items |= ITEM_JetpackRegen.m_itemid;
 710                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 711                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 712         }
 713
 714         WepSet precache_weapons = start_weapons;
 715         if (g_warmup_allguns != 1)
 716                 precache_weapons |= warmup_start_weapons;
 717         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 718         {
 719                 e = get_weaponinfo(i);
 720                 if(precache_weapons & WepSet_FromWeapon(i))
 721                         WEP_ACTION(i, WR_INIT);
 722         }
 723
 724         start_ammo_shells = max(0, start_ammo_shells);
 725         start_ammo_nails = max(0, start_ammo_nails);
 726         start_ammo_rockets = max(0, start_ammo_rockets);
 727         start_ammo_cells = max(0, start_ammo_cells);
 728         start_ammo_plasma = max(0, start_ammo_plasma);
 729         start_ammo_fuel = max(0, start_ammo_fuel);
 730
 731         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 732         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 733         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 734         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 735         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 736         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 737 }
 738
 739 float sound_allowed(float destin, entity e)
 740 {
 741     // sounds from world may always pass
 742     for (;;)
 743     {
 744         if (e.classname == "body")
 745             e = e.enemy;
 746         else if (e.realowner && e.realowner != e)
 747             e = e.realowner;
 748         else if (e.owner && e.owner != e)
 749             e = e.owner;
 750         else
 751             break;
 752     }
 753     // sounds to self may always pass
 754     if (destin == MSG_ONE)
 755         if (e == msg_entity)
 756             return true;
 757     // sounds by players can be removed
 758     if (autocvar_bot_sound_monopoly)
 759         if (IS_REAL_CLIENT(e))
 760             return false;
 761     // anything else may pass
 762     return true;
 763 }
 764
 765 #undef sound
 766 void sound(entity e, float chan, string samp, float vol, float attenu)
 767 {
 768     if (!sound_allowed(MSG_BROADCAST, e))
 769         return;
 770     sound7(e, chan, samp, vol, attenu, 0, 0);
 771 }
 772
 773 void soundtoat(float _dest, entity e, vector o, float chan, string samp, float vol, float attenu)
 774 {
 775     float entno, idx;
 776
 777     if (!sound_allowed(_dest, e))
 778         return;
 779
 780     entno = num_for_edict(e);
 781     idx = precache_sound_index(samp);
 782
 783     int sflags;
 784     sflags = 0;
 785
 786     attenu = floor(attenu * 64);
 787     vol = floor(vol * 255);
 788
 789     if (vol != 255)
 790         sflags |= SND_VOLUME;
 791     if (attenu != 64)
 792         sflags |= SND_ATTENUATION;
 793     if (entno >= 8192 || chan < 0 || chan > 7)
 794         sflags |= SND_LARGEENTITY;
 795     if (idx >= 256)
 796         sflags |= SND_LARGESOUND;
 797
 798     WriteByte(_dest, SVC_SOUND);
 799     WriteByte(_dest, sflags);
 800     if (sflags & SND_VOLUME)
 801         WriteByte(_dest, vol);
 802     if (sflags & SND_ATTENUATION)
 803         WriteByte(_dest, attenu);
 804     if (sflags & SND_LARGEENTITY)
 805     {
 806         WriteShort(_dest, entno);
 807         WriteByte(_dest, chan);
 808     }
 809     else
 810     {
 811         WriteShort(_dest, entno * 8 + chan);
 812     }
 813     if (sflags & SND_LARGESOUND)
 814         WriteShort(_dest, idx);
 815     else
 816         WriteByte(_dest, idx);
 817
 818     WriteCoord(_dest, o.x);
 819     WriteCoord(_dest, o.y);
 820     WriteCoord(_dest, o.z);
 821 }
 822 void soundto(float _dest, entity e, float chan, string samp, float vol, float _atten)
 823 {
 824     vector o;
 825
 826     if (!sound_allowed(_dest, e))
 827         return;
 828
 829     o = e.origin + 0.5 * (e.mins + e.maxs);
 830     soundtoat(_dest, e, o, chan, samp, vol, _atten);
 831 }
 832 void soundat(entity e, vector o, float chan, string samp, float vol, float _atten)
 833 {
 834     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, _atten);
 835 }
 836 void stopsoundto(float _dest, entity e, float chan)
 837 {
 838     float entno;
 839
 840     if (!sound_allowed(_dest, e))
 841         return;
 842
 843     entno = num_for_edict(e);
 844
 845     if (entno >= 8192 || chan < 0 || chan > 7)
 846     {
 847         float idx, sflags;
 848         idx = precache_sound_index("misc/null.wav");
 849         sflags = SND_LARGEENTITY;
 850         if (idx >= 256)
 851             sflags |= SND_LARGESOUND;
 852         WriteByte(_dest, SVC_SOUND);
 853         WriteByte(_dest, sflags);
 854         WriteShort(_dest, entno);
 855         WriteByte(_dest, chan);
 856         if (sflags & SND_LARGESOUND)
 857             WriteShort(_dest, idx);
 858         else
 859             WriteByte(_dest, idx);
 860         WriteCoord(_dest, e.origin.x);
 861         WriteCoord(_dest, e.origin.y);
 862         WriteCoord(_dest, e.origin.z);
 863     }
 864     else
 865     {
 866         WriteByte(_dest, SVC_STOPSOUND);
 867         WriteShort(_dest, entno * 8 + chan);
 868     }
 869 }
 870 void stopsound(entity e, float chan)
 871 {
 872     if (!sound_allowed(MSG_BROADCAST, e))
 873         return;
 874
 875     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
 876     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
 877 }
 878
 879 void play2(entity e, string filename)
 880 {
 881     //stuffcmd(e, strcat("play2 ", filename, "\n"));
 882     msg_entity = e;
 883     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
 884 }
 885
 886 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
 887 .float spamtime;
 888 float spamsound(entity e, float chan, string samp, float vol, float _atten)
 889 {
 890     if (!sound_allowed(MSG_BROADCAST, e))
 891         return false;
 892
 893     if (time > e.spamtime)
 894     {
 895         e.spamtime = time;
 896         sound(e, chan, samp, vol, _atten);
 897         return true;
 898     }
 899     return false;
 900 }
 901
 902 void play2team(float t, string filename)
 903 {
 904     entity head;
 905
 906     if (autocvar_bot_sound_monopoly)
 907         return;
 908
 909     FOR_EACH_REALPLAYER(head)
 910     {
 911         if (head.team == t)
 912             play2(head, filename);
 913     }
 914 }
 915
 916 void play2all(string samp)
 917 {
 918     if (autocvar_bot_sound_monopoly)
 919         return;
 920
 921     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
 922 }
 923
 924 void PrecachePlayerSounds(string f);
 925 void precache_playermodel(string m)
 926 {
 927         float globhandle, i, n;
 928         string f;
 929
 930         if(substring(m, -9,5) == "_lod1")
 931                 return;
 932         if(substring(m, -9,5) == "_lod2")
 933                 return;
 934         precache_model(m);
 935         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 936         if(fexists(f))
 937                 precache_model(f);
 938         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 939         if(fexists(f))
 940                 precache_model(f);
 941
 942         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 943         if (globhandle < 0)
 944                 return;
 945         n = search_getsize(globhandle);
 946         for (i = 0; i < n; ++i)
 947         {
 948                 //print(search_getfilename(globhandle, i), "\n");
 949                 f = search_getfilename(globhandle, i);
 950                 PrecachePlayerSounds(f);
 951         }
 952         search_end(globhandle);
 953 }
 954 void precache_all_playermodels(string pattern)
 955 {
 956         float globhandle, i, n;
 957         string f;
 958
 959         globhandle = search_begin(pattern, true, false);
 960         if (globhandle < 0)
 961                 return;
 962         n = search_getsize(globhandle);
 963         for (i = 0; i < n; ++i)
 964         {
 965                 //print(search_getfilename(globhandle, i), "\n");
 966                 f = search_getfilename(globhandle, i);
 967                 precache_playermodel(f);
 968         }
 969         search_end(globhandle);
 970 }
 971
 972 void precache()
 973 {SELFPARAM();
 974     // gamemode related things
 975
 976     // Precache all player models if desired
 977     if (autocvar_sv_precacheplayermodels)
 978     {
 979         PrecachePlayerSounds("sound/player/default.sounds");
 980         precache_all_playermodels("models/player/*.zym");
 981         precache_all_playermodels("models/player/*.dpm");
 982         precache_all_playermodels("models/player/*.md3");
 983         precache_all_playermodels("models/player/*.psk");
 984         precache_all_playermodels("models/player/*.iqm");
 985     }
 986
 987     if (autocvar_sv_defaultcharacter)
 988     {
 989         string s;
 990         s = autocvar_sv_defaultplayermodel_red;
 991         if (s != "")
 992             precache_playermodel(s);
 993         s = autocvar_sv_defaultplayermodel_blue;
 994         if (s != "")
 995             precache_playermodel(s);
 996         s = autocvar_sv_defaultplayermodel_yellow;
 997         if (s != "")
 998             precache_playermodel(s);
 999         s = autocvar_sv_defaultplayermodel_pink;
1000         if (s != "")
1001             precache_playermodel(s);
1002         s = autocvar_sv_defaultplayermodel;
1003         if (s != "")
1004             precache_playermodel(s);
1005     }
1006
1007     if (g_footsteps)
1008     {
1009         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1010         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1011     }
1012
1013     // gore and miscellaneous sounds
1014     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1015     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1016
1017 #if 0
1018     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1019
1020     if (!self.noise && self.music) // quake 3 uses the music field
1021         self.noise = self.music;
1022
1023     // plays music for the level if there is any
1024     if (self.noise)
1025     {
1026         precache_sound (self.noise);
1027         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1028     }
1029 #endif
1030 }
1031
1032
1033 void make_safe_for_remove(entity e)
1034 {
1035     if (e.initialize_entity)
1036     {
1037         entity ent, prev = world;
1038         for (ent = initialize_entity_first; ent; )
1039         {
1040             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1041             {
1042                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1043                 // skip it in linked list
1044                 if (prev)
1045                 {
1046                     prev.initialize_entity_next = ent.initialize_entity_next;
1047                     ent = prev.initialize_entity_next;
1048                 }
1049                 else
1050                 {
1051                     initialize_entity_first = ent.initialize_entity_next;
1052                     ent = initialize_entity_first;
1053                 }
1054             }
1055             else
1056             {
1057                 prev = ent;
1058                 ent = ent.initialize_entity_next;
1059             }
1060         }
1061     }
1062 }
1063
1064 void objerror(string s)
1065 {SELFPARAM();
1066     make_safe_for_remove(self);
1067     builtin_objerror(s);
1068 }
1069
1070 .float remove_except_protected_forbidden;
1071 void remove_except_protected(entity e)
1072 {
1073         if(e.remove_except_protected_forbidden)
1074                 error("not allowed to remove this at this point");
1075         builtin_remove(e);
1076 }
1077
1078 void remove_unsafely(entity e)
1079 {
1080     if(e.classname == "spike")
1081         error("Removing spikes is forbidden (crylink bug), please report");
1082     builtin_remove(e);
1083 }
1084
1085 void remove_safely(entity e)
1086 {
1087     make_safe_for_remove(e);
1088     builtin_remove(e);
1089 }
1090
1091 void InitializeEntity(entity e, void(void) func, float order)
1092 {
1093     entity prev, cur;
1094
1095     if (!e || e.initialize_entity)
1096     {
1097         // make a proxy initializer entity
1098         entity e_old = e;
1099         e = new(initialize_entity);
1100         e.enemy = e_old;
1101     }
1102
1103     e.initialize_entity = func;
1104     e.initialize_entity_order = order;
1105
1106     cur = initialize_entity_first;
1107     prev = world;
1108     for (;;)
1109     {
1110         if (!cur || cur.initialize_entity_order > order)
1111         {
1112             // insert between prev and cur
1113             if (prev)
1114                 prev.initialize_entity_next = e;
1115             else
1116                 initialize_entity_first = e;
1117             e.initialize_entity_next = cur;
1118             return;
1119         }
1120         prev = cur;
1121         cur = cur.initialize_entity_next;
1122     }
1123 }
1124 void InitializeEntitiesRun()
1125 {SELFPARAM();
1126     entity startoflist = initialize_entity_first;
1127     initialize_entity_first = NULL;
1128     remove = remove_except_protected;
1129     for (entity e = startoflist; e; e = e.initialize_entity_next)
1130     {
1131                 e.remove_except_protected_forbidden = 1;
1132     }
1133     for (entity e = startoflist; e; )
1134     {
1135                 e.remove_except_protected_forbidden = 0;
1136         e.initialize_entity_order = 0;
1137         entity next = e.initialize_entity_next;
1138         e.initialize_entity_next = NULL;
1139         var void() func = e.initialize_entity;
1140         e.initialize_entity = func_null;
1141         if (e.classname == "initialize_entity")
1142         {
1143             entity wrappee = e.enemy;
1144             builtin_remove(e);
1145             e = wrappee;
1146         }
1147         //dprint("Delayed initialization: ", e.classname, "\n");
1148         if (func)
1149         {
1150                 WITH(entity, self, e, func());
1151         }
1152         else
1153         {
1154             eprint(e);
1155             backtrace(strcat("Null function in: ", e.classname, "\n"));
1156         }
1157         e = next;
1158     }
1159     remove = remove_unsafely;
1160 }
1161
1162 void UncustomizeEntitiesRun()
1163 {SELFPARAM();
1164     for (entity e = NULL; (e = findfloat(e, uncustomizeentityforclient_set, 1)); )
1165     {
1166         WITH(entity, self, e, e.uncustomizeentityforclient());
1167     }
1168 }
1169 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1170 {
1171     e.customizeentityforclient = customizer;
1172     e.uncustomizeentityforclient = uncustomizer;
1173     e.uncustomizeentityforclient_set = !!uncustomizer;
1174 }
1175
1176 void Net_LinkEntity(entity e, bool docull, float dt, bool(entity, int) sendfunc)
1177 {SELFPARAM();
1178     vector mi, ma;
1179
1180     if (e.classname == "")
1181         e.classname = "net_linked";
1182
1183     if (e.model == "" || self.modelindex == 0)
1184     {
1185         mi = e.mins;
1186         ma = e.maxs;
1187         setmodel(e, MDL_Null);
1188         setsize(e, mi, ma);
1189     }
1190
1191     e.SendEntity = sendfunc;
1192     e.SendFlags = 0xFFFFFF;
1193
1194     if (!docull)
1195         e.effects |= EF_NODEPTHTEST;
1196
1197     if (dt)
1198     {
1199         e.nextthink = time + dt;
1200         e.think = SUB_Remove;
1201     }
1202 }
1203
1204
1205 .float(entity) isEliminated;
1206 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1207 {
1208         float i, f, b;
1209         entity e;
1210         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1211         WriteByte(MSG_ENTITY, sendflags);
1212
1213         if(sendflags & 1)
1214         {
1215                 for(i = 1; i <= maxclients; i += 8)
1216                 {
1217                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1218                         {
1219                                 if(eliminatedPlayers.isEliminated(e))
1220                                         f |= b;
1221                         }
1222                         WriteByte(MSG_ENTITY, f);
1223                 }
1224         }
1225
1226         return true;
1227 }
1228
1229 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1230 {
1231         if(eliminatedPlayers)
1232         {
1233                 backtrace("Can't spawn eliminatedPlayers again!");
1234                 return;
1235         }
1236         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1237         eliminatedPlayers.isEliminated = isEliminated_func;
1238 }
1239
1240
1241 void adaptor_think2touch()
1242 {SELFPARAM();
1243     entity o;
1244     o = other;
1245     other = world;
1246     self.touch();
1247     other = o;
1248 }
1249
1250 void adaptor_think2use()
1251 {SELFPARAM();
1252     entity o, a;
1253     o = other;
1254     a = activator;
1255     activator = world;
1256     other = world;
1257     self.use();
1258     other = o;
1259     activator = a;
1260 }
1261
1262 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1263 {SELFPARAM();
1264         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1265                 self.projectiledeathtype |= HITTYPE_SPLASH;
1266         adaptor_think2use();
1267 }
1268
1269 // deferred dropping
1270 void DropToFloor_Handler()
1271 {SELFPARAM();
1272     builtin_droptofloor();
1273     self.dropped_origin = self.origin;
1274 }
1275
1276 void droptofloor()
1277 {SELFPARAM();
1278     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1279 }
1280
1281
1282
1283 float trace_hits_box_a0, trace_hits_box_a1;
1284
1285 float trace_hits_box_1d(float end, float thmi, float thma)
1286 {
1287     if (end == 0)
1288     {
1289         // just check if x is in range
1290         if (0 < thmi)
1291             return false;
1292         if (0 > thma)
1293             return false;
1294     }
1295     else
1296     {
1297         // do the trace with respect to x
1298         // 0 -> end has to stay in thmi -> thma
1299         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1300         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1301         if (trace_hits_box_a0 > trace_hits_box_a1)
1302             return false;
1303     }
1304     return true;
1305 }
1306
1307 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1308 {
1309     end -= start;
1310     thmi -= start;
1311     thma -= start;
1312     // now it is a trace from 0 to end
1313
1314     trace_hits_box_a0 = 0;
1315     trace_hits_box_a1 = 1;
1316
1317     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1318         return false;
1319     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1320         return false;
1321     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1322         return false;
1323
1324     return true;
1325 }
1326
1327 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1328 {
1329     return trace_hits_box(start, end, thmi - ma, thma - mi);
1330 }
1331
1332 float SUB_NoImpactCheck()
1333 {SELFPARAM();
1334         // zero hitcontents = this is not the real impact, but either the
1335         // mirror-impact of something hitting the projectile instead of the
1336         // projectile hitting the something, or a touchareagrid one. Neither of
1337         // these stop the projectile from moving, so...
1338         if(trace_dphitcontents == 0)
1339         {
1340                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1341                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1342                 checkclient();
1343         }
1344     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1345         return 1;
1346     if (other == world && self.size != '0 0 0')
1347     {
1348         vector tic;
1349         tic = self.velocity * sys_frametime;
1350         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1351         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1352         if (trace_fraction >= 1)
1353         {
1354             LOG_TRACE("Odd... did not hit...?\n");
1355         }
1356         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1357         {
1358             LOG_TRACE("Detected and prevented the sky-grapple bug.\n");
1359             return 1;
1360         }
1361     }
1362
1363     return 0;
1364 }
1365
1366 #define SUB_OwnerCheck() (other && (other == self.owner))
1367
1368 void W_Crylink_Dequeue(entity e);
1369 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1370 {SELFPARAM();
1371         if(SUB_OwnerCheck())
1372                 return true;
1373         if(SUB_NoImpactCheck())
1374         {
1375                 if(self.classname == "nade")
1376                         return false; // no checks here
1377                 else if(self.classname == "grapplinghook")
1378                         RemoveGrapplingHook(self.realowner);
1379                 else if(self.classname == "spike")
1380                 {
1381                         W_Crylink_Dequeue(self);
1382                         remove(self);
1383                 }
1384                 else
1385                         remove(self);
1386                 return true;
1387         }
1388         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1389                 UpdateCSQCProjectile(self);
1390         return false;
1391 }
1392
1393
1394 void URI_Get_Callback(float id, float status, string data)
1395 {
1396         if(url_URI_Get_Callback(id, status, data))
1397         {
1398                 // handled
1399         }
1400         else if (id == URI_GET_DISCARD)
1401         {
1402                 // discard
1403         }
1404         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1405         {
1406                 // sv_cmd curl
1407                 Curl_URI_Get_Callback(id, status, data);
1408         }
1409         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1410         {
1411                 // online ban list
1412                 OnlineBanList_URI_Get_Callback(id, status, data);
1413         }
1414         else
1415         {
1416                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1417         }
1418 }
1419
1420 string uid2name(string myuid) {
1421         string s;
1422         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1423
1424         // FIXME remove this later after 0.6 release
1425         // convert old style broken records to correct style
1426         if(s == "")
1427         {
1428                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1429                 if(s != "")
1430                 {
1431                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1432                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1433                 }
1434         }
1435
1436         if(s == "")
1437                 s = "^1Unregistered Player";
1438         return s;
1439 }
1440
1441 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1442 {
1443     float m, i;
1444     vector start, org, delta, end, enddown, mstart;
1445     entity sp;
1446
1447     m = e.dphitcontentsmask;
1448     e.dphitcontentsmask = goodcontents | badcontents;
1449
1450     org = world.mins;
1451     delta = world.maxs - world.mins;
1452
1453     start = end = org;
1454
1455     for (i = 0; i < attempts; ++i)
1456     {
1457         start.x = org.x + random() * delta.x;
1458         start.y = org.y + random() * delta.y;
1459         start.z = org.z + random() * delta.z;
1460
1461         // rule 1: start inside world bounds, and outside
1462         // solid, and don't start from somewhere where you can
1463         // fall down to evil
1464         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1465         if (trace_fraction >= 1)
1466             continue;
1467         if (trace_startsolid)
1468             continue;
1469         if (trace_dphitcontents & badcontents)
1470             continue;
1471         if (trace_dphitq3surfaceflags & badsurfaceflags)
1472             continue;
1473
1474         // rule 2: if we are too high, lower the point
1475         if (trace_fraction * delta.z > maxaboveground)
1476             start = trace_endpos + '0 0 1' * maxaboveground;
1477         enddown = trace_endpos;
1478
1479         // rule 3: make sure we aren't outside the map. This only works
1480         // for somewhat well formed maps. A good rule of thumb is that
1481         // the map should have a convex outside hull.
1482         // these can be traceLINES as we already verified the starting box
1483         mstart = start + 0.5 * (e.mins + e.maxs);
1484         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1485         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1486             continue;
1487         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1488         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1489             continue;
1490         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1491         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1492             continue;
1493         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1494         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1495             continue;
1496         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1497         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1498             continue;
1499
1500         // rule 4: we must "see" some spawnpoint or item
1501         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1502                 if(checkpvs(mstart, sp))
1503                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1504                                 break;
1505         if(!sp)
1506         {
1507                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1508                         if(checkpvs(mstart, sp))
1509                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1510                                         break;
1511                 if(!sp)
1512                         continue;
1513         }
1514
1515         // find a random vector to "look at"
1516         end.x = org.x + random() * delta.x;
1517         end.y = org.y + random() * delta.y;
1518         end.z = org.z + random() * delta.z;
1519         end = start + normalize(end - start) * vlen(delta);
1520
1521         // rule 4: start TO end must not be too short
1522         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1523         if (trace_startsolid)
1524             continue;
1525         if (trace_fraction < minviewdistance / vlen(delta))
1526             continue;
1527
1528         // rule 5: don't want to look at sky
1529         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1530             continue;
1531
1532         // rule 6: we must not end up in trigger_hurt
1533         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1534             continue;
1535
1536         break;
1537     }
1538
1539     e.dphitcontentsmask = m;
1540
1541     if (i < attempts)
1542     {
1543         setorigin(e, start);
1544         e.angles = vectoangles(end - start);
1545         LOG_TRACE("Needed ", ftos(i + 1), " attempts\n");
1546         return true;
1547     }
1548     else
1549         return false;
1550 }
1551
1552 void write_recordmarker(entity pl, float tstart, float dt)
1553 {
1554     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1555
1556     // also write a marker into demo files for demotc-race-record-extractor to find
1557     stuffcmd(pl,
1558              strcat(
1559                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1560                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1561 }
1562
1563 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1564 {
1565         switch(algn)
1566         {
1567                 default:
1568                 case 3: // right
1569                         break;
1570
1571                 case 4: // left
1572                         vecs.y = -vecs.y;
1573                         break;
1574
1575                 case 1:
1576                         if(allowcenter) // 2: allow center handedness
1577                         {
1578                                 // center
1579                                 vecs.y = 0;
1580                                 vecs.z -= 2;
1581                         }
1582                         else
1583                         {
1584                                 // right
1585                         }
1586                         break;
1587
1588                 case 2:
1589                         if(allowcenter) // 2: allow center handedness
1590                         {
1591                                 // center
1592                                 vecs.y = 0;
1593                                 vecs.z -= 2;
1594                         }
1595                         else
1596                         {
1597                                 // left
1598                                 vecs.y = -vecs.y;
1599                         }
1600                         break;
1601         }
1602         return vecs;
1603 }
1604
1605 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1606 {
1607         string s;
1608         vector v;
1609
1610         if (autocvar_g_shootfromeye)
1611         {
1612                 if (visual)
1613                 {
1614                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
1615                         else { vecs.y = 0; vecs.z -= 2; }
1616                 }
1617                 else
1618                 {
1619                         vecs.y = 0;
1620                         vecs.z = 0;
1621                 }
1622         }
1623         else if (autocvar_g_shootfromcenter)
1624         {
1625                 vecs.y = 0;
1626                 vecs.z -= 2;
1627         }
1628         else if ((s = autocvar_g_shootfromfixedorigin) != "")
1629         {
1630                 v = stov(s);
1631                 if (y_is_right)
1632                         v.y = -v.y;
1633                 if (v.x != 0)
1634                         vecs.x = v.x;
1635                 vecs.y = v.y;
1636                 vecs.z = v.z;
1637         }
1638         else if (autocvar_g_shootfromclient)
1639         {
1640                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
1641         }
1642         return vecs;
1643 }
1644
1645 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
1646 {SELFPARAM();
1647         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
1648 }
1649
1650
1651 void attach_sameorigin(entity e, entity to, string tag)
1652 {
1653     vector org, t_forward, t_left, t_up, e_forward, e_up;
1654     float tagscale;
1655
1656     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1657     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1658     t_forward = v_forward * tagscale;
1659     t_left = v_right * -tagscale;
1660     t_up = v_up * tagscale;
1661
1662     e.origin_x = org * t_forward;
1663     e.origin_y = org * t_left;
1664     e.origin_z = org * t_up;
1665
1666     // current forward and up directions
1667     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1668                 e.angles = AnglesTransform_FromVAngles(e.angles);
1669         else
1670                 e.angles = AnglesTransform_FromAngles(e.angles);
1671     fixedmakevectors(e.angles);
1672
1673     // untransform forward, up!
1674     e_forward.x = v_forward * t_forward;
1675     e_forward.y = v_forward * t_left;
1676     e_forward.z = v_forward * t_up;
1677     e_up.x = v_up * t_forward;
1678     e_up.y = v_up * t_left;
1679     e_up.z = v_up * t_up;
1680
1681     e.angles = fixedvectoangles2(e_forward, e_up);
1682     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1683                 e.angles = AnglesTransform_ToVAngles(e.angles);
1684         else
1685                 e.angles = AnglesTransform_ToAngles(e.angles);
1686
1687     setattachment(e, to, tag);
1688     setorigin(e, e.origin);
1689 }
1690
1691 void detach_sameorigin(entity e)
1692 {
1693     vector org;
1694     org = gettaginfo(e, 0);
1695     e.angles = fixedvectoangles2(v_forward, v_up);
1696     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1697                 e.angles = AnglesTransform_ToVAngles(e.angles);
1698         else
1699                 e.angles = AnglesTransform_ToAngles(e.angles);
1700     setorigin(e, org);
1701     setattachment(e, world, "");
1702     setorigin(e, e.origin);
1703 }
1704
1705 void follow_sameorigin(entity e, entity to)
1706 {
1707     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1708     e.aiment = to; // make the hole follow bmodel
1709     e.punchangle = to.angles; // the original angles of bmodel
1710     e.view_ofs = e.origin - to.origin; // relative origin
1711     e.v_angle = e.angles - to.angles; // relative angles
1712 }
1713
1714 void unfollow_sameorigin(entity e)
1715 {
1716     e.movetype = MOVETYPE_NONE;
1717 }
1718
1719 entity gettaginfo_relative_ent;
1720 vector gettaginfo_relative(entity e, float tag)
1721 {
1722     if (!gettaginfo_relative_ent)
1723     {
1724         gettaginfo_relative_ent = spawn();
1725         gettaginfo_relative_ent.effects = EF_NODRAW;
1726     }
1727     gettaginfo_relative_ent.model = e.model;
1728     gettaginfo_relative_ent.modelindex = e.modelindex;
1729     gettaginfo_relative_ent.frame = e.frame;
1730     return gettaginfo(gettaginfo_relative_ent, tag);
1731 }
1732
1733 .float scale2;
1734
1735 float modeleffect_SendEntity(entity to, int sf)
1736 {SELFPARAM();
1737         float f;
1738         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
1739
1740         f = 0;
1741         if(self.velocity != '0 0 0')
1742                 f |= 1;
1743         if(self.angles != '0 0 0')
1744                 f |= 2;
1745         if(self.avelocity != '0 0 0')
1746                 f |= 4;
1747
1748         WriteByte(MSG_ENTITY, f);
1749         WriteShort(MSG_ENTITY, self.modelindex);
1750         WriteByte(MSG_ENTITY, self.skin);
1751         WriteByte(MSG_ENTITY, self.frame);
1752         WriteCoord(MSG_ENTITY, self.origin.x);
1753         WriteCoord(MSG_ENTITY, self.origin.y);
1754         WriteCoord(MSG_ENTITY, self.origin.z);
1755         if(f & 1)
1756         {
1757                 WriteCoord(MSG_ENTITY, self.velocity.x);
1758                 WriteCoord(MSG_ENTITY, self.velocity.y);
1759                 WriteCoord(MSG_ENTITY, self.velocity.z);
1760         }
1761         if(f & 2)
1762         {
1763                 WriteCoord(MSG_ENTITY, self.angles.x);
1764                 WriteCoord(MSG_ENTITY, self.angles.y);
1765                 WriteCoord(MSG_ENTITY, self.angles.z);
1766         }
1767         if(f & 4)
1768         {
1769                 WriteCoord(MSG_ENTITY, self.avelocity.x);
1770                 WriteCoord(MSG_ENTITY, self.avelocity.y);
1771                 WriteCoord(MSG_ENTITY, self.avelocity.z);
1772         }
1773         WriteShort(MSG_ENTITY, self.scale * 256.0);
1774         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
1775         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
1776         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
1777         WriteByte(MSG_ENTITY, self.alpha * 255.0);
1778
1779         return true;
1780 }
1781
1782 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
1783 {
1784         entity e;
1785         float sz;
1786         e = spawn();
1787         e.classname = "modeleffect";
1788         _setmodel(e, m);
1789         e.frame = f;
1790         setorigin(e, o);
1791         e.velocity = v;
1792         e.angles = ang;
1793         e.avelocity = angv;
1794         e.alpha = a;
1795         e.teleport_time = t1;
1796         e.fade_time = t2;
1797         e.skin = s;
1798         if(s0 >= 0)
1799                 e.scale = s0 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1800         else
1801                 e.scale = -s0;
1802         if(s2 >= 0)
1803                 e.scale2 = s2 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1804         else
1805                 e.scale2 = -s2;
1806         sz = max(e.scale, e.scale2);
1807         setsize(e, e.mins * sz, e.maxs * sz);
1808         Net_LinkEntity(e, false, 0.1, modeleffect_SendEntity);
1809 }
1810
1811 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
1812 {
1813         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
1814 }
1815
1816 float randombit(float bits)
1817 {
1818         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
1819                 return bits;
1820
1821         float n, f, b, r;
1822
1823         r = random();
1824         b = 0;
1825         n = 0;
1826
1827         for(f = 1; f <= bits; f *= 2)
1828         {
1829                 if(bits & f)
1830                 {
1831                         ++n;
1832                         r *= n;
1833                         if(r <= 1)
1834                                 b = f;
1835                         else
1836                                 r = (r - 1) / (n - 1);
1837                 }
1838         }
1839
1840         return b;
1841 }
1842
1843 float randombits(float bits, float k, float error_return)
1844 {
1845         float r;
1846         r = 0;
1847         while(k > 0 && bits != r)
1848         {
1849                 r += randombit(bits - r);
1850                 --k;
1851         }
1852         if(error_return)
1853                 if(k > 0)
1854                         return -1; // all
1855         return r;
1856 }
1857
1858 void randombit_test(float bits, float iter)
1859 {
1860         while(iter > 0)
1861         {
1862                 LOG_INFO(ftos(randombit(bits)), "\n");
1863                 --iter;
1864         }
1865 }
1866
1867 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
1868 {
1869         if(halflifedist > 0)
1870                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
1871         else if(halflifedist < 0)
1872                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
1873         else
1874                 return 1;
1875 }
1876
1877
1878 .string aiment_classname;
1879 .float aiment_deadflag;
1880 void SetMovetypeFollow(entity ent, entity e)
1881 {
1882         // FIXME this may not be warpzone aware
1883         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
1884         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1885         ent.aiment = e; // make the hole follow bmodel
1886         ent.punchangle = e.angles; // the original angles of bmodel
1887         ent.view_ofs = ent.origin - e.origin; // relative origin
1888         ent.v_angle = ent.angles - e.angles; // relative angles
1889         ent.aiment_classname = strzone(e.classname);
1890         ent.aiment_deadflag = e.deadflag;
1891 }
1892 void UnsetMovetypeFollow(entity ent)
1893 {
1894         ent.movetype = MOVETYPE_FLY;
1895         PROJECTILE_MAKETRIGGER(ent);
1896         ent.aiment = world;
1897 }
1898 float LostMovetypeFollow(entity ent)
1899 {
1900 /*
1901         if(ent.movetype != MOVETYPE_FOLLOW)
1902                 if(ent.aiment)
1903                         error("???");
1904 */
1905         if(ent.aiment)
1906         {
1907                 if(ent.aiment.classname != ent.aiment_classname)
1908                         return 1;
1909                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1910                         return 1;
1911         }
1912         return 0;
1913 }
1914
1915 float isPushable(entity e)
1916 {
1917         if(e.pushable)
1918                 return true;
1919         if(IS_VEHICLE(e))
1920                 return false;
1921         if(e.iscreature)
1922                 return true;
1923         switch(e.classname)
1924         {
1925                 case "body":
1926                 case "droppedweapon":
1927                 case "keepawayball":
1928                 case "nexball_basketball":
1929                 case "nexball_football":
1930                         return true;
1931                 case "bullet": // antilagged bullets can't hit this either
1932                         return false;
1933         }
1934         if (e.projectiledeathtype)
1935                 return true;
1936         return false;
1937 }