qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 float spawnpoint_nag;
 159 void relocate_spawnpoint()
 160 {
 161     // nudge off the floor
 162     setorigin(self, self.origin + '0 0 1');
 163
 164     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 165     if (trace_startsolid)
 166     {
 167         vector o;
 168         o = self.origin;
 169         self.mins = PL_MIN;
 170         self.maxs = PL_MAX;
 171         if (!move_out_of_solid(self))
 172             objerror("could not get out of solid at all!");
 173         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 174         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 175         print(" ", ftos(self.origin_y - o_y));
 176         print(" ", ftos(self.origin_z - o_z), "'\n");
 177         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 178         {
 179             if (!spawnpoint_nag)
 180                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 181             spawnpoint_nag = 1;
 182         }
 183         else
 184         {
 185             setorigin(self, o);
 186             self.mins = self.maxs = '0 0 0';
 187             objerror("player spawn point in solid, mapper sucks!\n");
 188             return;
 189         }
 190     }
 191
 192     self.use = spawnpoint_use;
 193     self.team_saved = self.team;
 194     if (!self.cnt)
 195         self.cnt = 1;
 196
 197     if (have_team_spawns != 0)
 198         if (self.team)
 199             have_team_spawns = 1;
 200     have_team_spawns_forteam[self.team] = 1;
 201
 202     if (autocvar_r_showbboxes)
 203     {
 204         // show where spawnpoints point at too
 205         makevectors(self.angles);
 206         entity e;
 207         e = spawn();
 208         e.classname = "info_player_foo";
 209         setorigin(e, self.origin + v_forward * 24);
 210         setsize(e, '-8 -8 -8', '8 8 8');
 211         e.solid = SOLID_TRIGGER;
 212     }
 213 }
 214
 215 #define strstr strstrofs
 216 /*
 217 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 218 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 219 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 220 // BE CONSTANT OR strzoneD!
 221 float strstr(string haystack, string needle, float offset)
 222 {
 223         float len, endpos;
 224         string found;
 225         len = strlen(needle);
 226         endpos = strlen(haystack) - len;
 227         while(offset <= endpos)
 228         {
 229                 found = substring(haystack, offset, len);
 230                 if(found == needle)
 231                         return offset;
 232                 offset = offset + 1;
 233         }
 234         return -1;
 235 }
 236 */
 237
 238 float NUM_NEAREST_ENTITIES = 4;
 239 entity nearest_entity[NUM_NEAREST_ENTITIES];
 240 float nearest_length[NUM_NEAREST_ENTITIES];
 241 entity findnearest(vector point, .string field, string value, vector axismod)
 242 {
 243     entity localhead;
 244     float i;
 245     float j;
 246     float len;
 247     vector dist;
 248
 249     float num_nearest;
 250     num_nearest = 0;
 251
 252     localhead = find(world, field, value);
 253     while (localhead)
 254     {
 255         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 256             dist = localhead.oldorigin;
 257         else
 258             dist = localhead.origin;
 259         dist = dist - point;
 260         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 261         len = vlen(dist);
 262
 263         for (i = 0; i < num_nearest; ++i)
 264         {
 265             if (len < nearest_length[i])
 266                 break;
 267         }
 268
 269         // now i tells us where to insert at
 270         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 271         if (i < NUM_NEAREST_ENTITIES)
 272         {
 273             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 274             {
 275                 nearest_length[j + 1] = nearest_length[j];
 276                 nearest_entity[j + 1] = nearest_entity[j];
 277             }
 278             nearest_length[i] = len;
 279             nearest_entity[i] = localhead;
 280             if (num_nearest < NUM_NEAREST_ENTITIES)
 281                 num_nearest = num_nearest + 1;
 282         }
 283
 284         localhead = find(localhead, field, value);
 285     }
 286
 287     // now use the first one from our list that we can see
 288     for (i = 0; i < num_nearest; ++i)
 289     {
 290         traceline(point, nearest_entity[i].origin, TRUE, world);
 291         if (trace_fraction == 1)
 292         {
 293             if (i != 0)
 294             {
 295                 dprint("Nearest point (");
 296                 dprint(nearest_entity[0].netname);
 297                 dprint(") is not visible, using a visible one.\n");
 298             }
 299             return nearest_entity[i];
 300         }
 301     }
 302
 303     if (num_nearest == 0)
 304         return world;
 305
 306     dprint("Not seeing any location point, using nearest as fallback.\n");
 307     /* DEBUGGING CODE:
 308     dprint("Candidates were: ");
 309     for(j = 0; j < num_nearest; ++j)
 310     {
 311         if(j != 0)
 312                 dprint(", ");
 313         dprint(nearest_entity[j].netname);
 314     }
 315     dprint("\n");
 316     */
 317
 318     return nearest_entity[0];
 319 }
 320
 321 void spawnfunc_target_location()
 322 {
 323     self.classname = "target_location";
 324     // location name in netname
 325     // eventually support: count, teamgame selectors, line of sight?
 326 }
 327
 328 void spawnfunc_info_location()
 329 {
 330     self.classname = "target_location";
 331     self.message = self.netname;
 332 }
 333
 334 string NearestLocation(vector p)
 335 {
 336     entity loc;
 337     string ret;
 338     ret = "somewhere";
 339     loc = findnearest(p, classname, "target_location", '1 1 1');
 340     if (loc)
 341     {
 342         ret = loc.message;
 343     }
 344     else
 345     {
 346         loc = findnearest(p, target, "###item###", '1 1 4');
 347         if (loc)
 348             ret = loc.netname;
 349     }
 350     return ret;
 351 }
 352
 353 string formatmessage(string msg)
 354 {
 355         float p, p1, p2;
 356         float n;
 357         vector cursor;
 358         entity cursor_ent;
 359         string escape;
 360         string replacement;
 361         p = 0;
 362         n = 7;
 363
 364         WarpZone_crosshair_trace(self);
 365         cursor = trace_endpos;
 366         cursor_ent = trace_ent;
 367
 368         while (1) {
 369                 if (n < 1)
 370                         break; // too many replacements
 371
 372                 n = n - 1;
 373                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 374                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 375
 376                 if (p1 < 0)
 377                         p1 = p2;
 378
 379                 if (p2 < 0)
 380                         p2 = p1;
 381
 382                 p = min(p1, p2);
 383
 384                 if (p < 0)
 385                         break;
 386
 387                 replacement = substring(msg, p, 2);
 388                 escape = substring(msg, p + 1, 1);
 389
 390                 if (escape == "%")
 391                         replacement = "%";
 392                 else if (escape == "\\")
 393                         replacement = "\\";
 394                 else if (escape == "n")
 395                         replacement = "\n";
 396                 else if (escape == "a")
 397                         replacement = ftos(floor(self.armorvalue));
 398                 else if (escape == "h")
 399                         replacement = ftos(floor(self.health));
 400                 else if (escape == "l")
 401                         replacement = NearestLocation(self.origin);
 402                 else if (escape == "y")
 403                         replacement = NearestLocation(cursor);
 404                 else if (escape == "d")
 405                         replacement = NearestLocation(self.death_origin);
 406                 else if (escape == "w") {
 407                         float wep;
 408                         wep = self.weapon;
 409                         if (!wep)
 410                                 wep = self.switchweapon;
 411                         if (!wep)
 412                                 wep = self.cnt;
 413                         replacement = W_Name(wep);
 414                 } else if (escape == "W") {
 415                         if (self.items & IT_SHELLS) replacement = "shells";
 416                         else if (self.items & IT_NAILS) replacement = "bullets";
 417                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 418                         else if (self.items & IT_CELLS) replacement = "cells";
 419                         else replacement = "batteries"; // ;)
 420                 } else if (escape == "x") {
 421                         replacement = cursor_ent.netname;
 422                         if (replacement == "" || !cursor_ent)
 423                                 replacement = "nothing";
 424                 } else if (escape == "s")
 425                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 426                 else if (escape == "S")
 427                         replacement = ftos(vlen(self.velocity));
 428
 429                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 430                 p = p + strlen(replacement);
 431         }
 432         return msg;
 433 }
 434
 435 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 436         return (value == 0) ? FALSE : TRUE;
 437 }
 438
 439 /*
 440 =============
 441 GetCvars
 442 =============
 443 Called with:
 444   0:  sends the request
 445   >0: receives a cvar from name=argv(f) value=argv(f+1)
 446 */
 447 void GetCvars_handleString(string thisname, float f, .string field, string name)
 448 {
 449         if (f < 0)
 450         {
 451                 if (self.field)
 452                         strunzone(self.field);
 453                 self.field = string_null;
 454         }
 455         else if (f > 0)
 456         {
 457                 if (thisname == name)
 458                 {
 459                         if (self.field)
 460                                 strunzone(self.field);
 461                         self.field = strzone(argv(f + 1));
 462                 }
 463         }
 464         else
 465                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 466 }
 467 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 468 {
 469         GetCvars_handleString(thisname, f, field, name);
 470         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 471                 if (thisname == name)
 472                 {
 473                         string s;
 474                         s = func(strcat1(self.field));
 475                         if (s != self.field)
 476                         {
 477                                 strunzone(self.field);
 478                                 self.field = strzone(s);
 479                         }
 480                 }
 481 }
 482 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 483 {
 484         if (f < 0)
 485         {
 486         }
 487         else if (f > 0)
 488         {
 489                 if (thisname == name)
 490                         self.field = stof(argv(f + 1));
 491         }
 492         else
 493                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 494 }
 495 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 496 {
 497         if (f < 0)
 498         {
 499         }
 500         else if (f > 0)
 501         {
 502                 if (thisname == name)
 503                 {
 504                         if(!self.field)
 505                         {
 506                                 self.field = stof(argv(f + 1));
 507                                 if(!self.field)
 508                                         self.field = -1;
 509                         }
 510                 }
 511         }
 512         else
 513         {
 514                 if(!self.field)
 515                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 516         }
 517 }
 518 float w_getbestweapon(entity e);
 519 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 520 {
 521         string o;
 522         o = W_FixWeaponOrder_ForceComplete(wo);
 523         if(self.weaponorder_byimpulse)
 524         {
 525                 strunzone(self.weaponorder_byimpulse);
 526                 self.weaponorder_byimpulse = string_null;
 527         }
 528         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 529         return o;
 530 }
 531 void GetCvars(float f)
 532 {
 533         string s = string_null;
 534
 535         if (f > 0)
 536                 s = strcat1(argv(f));
 537
 538         get_cvars_f = f;
 539         get_cvars_s = s;
 540
 541         MUTATOR_CALLHOOK(GetCvars);
 542
 543         Notification_GetCvars();
 544
 545         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 546         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 547         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 548         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 549         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 562         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 563         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 564         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 565         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 566         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 567         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 568
 569         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 570         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 571
 572         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 573         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 574         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 575         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 576         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 577
 578         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 579         if (f > 0)
 580         {
 581                 if (s == "cl_weaponpriority")
 582                         self.switchweapon = w_getbestweapon(self);
 583                 if (s == "cl_allow_uidtracking")
 584                         PlayerStats_AddPlayer(self);
 585         }
 586 }
 587
 588 // decolorizes and team colors the player name when needed
 589 string playername(entity p)
 590 {
 591     string t;
 592     if (teamplay && !intermission_running && p.classname == "player")
 593     {
 594         t = Team_ColorCode(p.team);
 595         return strcat(t, strdecolorize(p.netname));
 596     }
 597     else
 598         return p.netname;
 599 }
 600
 601 vector randompos(vector m1, vector m2)
 602 {
 603     vector v;
 604     m2 = m2 - m1;
 605     v_x = m2_x * random() + m1_x;
 606     v_y = m2_y * random() + m1_y;
 607     v_z = m2_z * random() + m1_z;
 608     return  v;
 609 }
 610
 611 //#NO AUTOCVARS START
 612
 613 float g_pickup_shells;
 614 float g_pickup_shells_max;
 615 float g_pickup_nails;
 616 float g_pickup_nails_max;
 617 float g_pickup_rockets;
 618 float g_pickup_rockets_max;
 619 float g_pickup_cells;
 620 float g_pickup_cells_max;
 621 float g_pickup_fuel;
 622 float g_pickup_fuel_jetpack;
 623 float g_pickup_fuel_max;
 624 float g_pickup_armorsmall;
 625 float g_pickup_armorsmall_max;
 626 float g_pickup_armorsmall_anyway;
 627 float g_pickup_armormedium;
 628 float g_pickup_armormedium_max;
 629 float g_pickup_armormedium_anyway;
 630 float g_pickup_armorbig;
 631 float g_pickup_armorbig_max;
 632 float g_pickup_armorbig_anyway;
 633 float g_pickup_armorlarge;
 634 float g_pickup_armorlarge_max;
 635 float g_pickup_armorlarge_anyway;
 636 float g_pickup_healthsmall;
 637 float g_pickup_healthsmall_max;
 638 float g_pickup_healthsmall_anyway;
 639 float g_pickup_healthmedium;
 640 float g_pickup_healthmedium_max;
 641 float g_pickup_healthmedium_anyway;
 642 float g_pickup_healthlarge;
 643 float g_pickup_healthlarge_max;
 644 float g_pickup_healthlarge_anyway;
 645 float g_pickup_healthmega;
 646 float g_pickup_healthmega_max;
 647 float g_pickup_healthmega_anyway;
 648 float g_pickup_ammo_anyway;
 649 float g_pickup_weapons_anyway;
 650 float g_weaponarena;
 651 WEPSET_DECLARE_A(g_weaponarena_weapons);
 652 float g_weaponarena_random;
 653 float g_weaponarena_random_with_laser;
 654 string g_weaponarena_list;
 655 float g_weaponspeedfactor;
 656 float g_weaponratefactor;
 657 float g_weapondamagefactor;
 658 float g_weaponforcefactor;
 659 float g_weaponspreadfactor;
 660
 661 WEPSET_DECLARE_A(start_weapons);
 662 WEPSET_DECLARE_A(start_weapons_default);
 663 WEPSET_DECLARE_A(start_weapons_defaultmask);
 664 float start_items;
 665 float start_ammo_shells;
 666 float start_ammo_nails;
 667 float start_ammo_rockets;
 668 float start_ammo_cells;
 669 float start_ammo_fuel;
 670 float start_health;
 671 float start_armorvalue;
 672 WEPSET_DECLARE_A(warmup_start_weapons);
 673 WEPSET_DECLARE_A(warmup_start_weapons_default);
 674 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 675 float warmup_start_ammo_shells;
 676 float warmup_start_ammo_nails;
 677 float warmup_start_ammo_rockets;
 678 float warmup_start_ammo_cells;
 679 float warmup_start_ammo_fuel;
 680 float warmup_start_health;
 681 float warmup_start_armorvalue;
 682 float g_weapon_stay;
 683
 684 entity get_weaponinfo(float w);
 685
 686 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 687 {
 688         var float i = weaponinfo.weapon;
 689         var float d = 0;
 690
 691         if (!i)
 692                 return 0;
 693
 694         if (g_lms || g_ca || allguns)
 695         {
 696                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 697                         d = TRUE;
 698                 else
 699                         d = FALSE;
 700         }
 701         else if (g_cts)
 702                 d = (i == WEP_SHOTGUN);
 703         else if (g_nexball)
 704                 d = 0; // weapon is set a few lines later
 705         else
 706                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 707
 708         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 709                 d |= (i == WEP_HOOK);
 710         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 711                 d = 0;
 712
 713         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 714
 715         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 716
 717         // bit order in t:
 718         // 1: want or not
 719         // 2: is default?
 720         // 4: is set by default?
 721         if(t < 0)
 722                 t = 4 | (3 * d);
 723         else
 724                 t |= (2 * d);
 725
 726         return t;
 727 }
 728
 729 void readplayerstartcvars()
 730 {
 731         entity e;
 732         float i, j, t;
 733         string s;
 734
 735         // initialize starting values for players
 736         WEPSET_CLEAR_A(start_weapons);
 737         WEPSET_CLEAR_A(start_weapons_default);
 738         WEPSET_CLEAR_A(start_weapons_defaultmask);
 739         start_items = 0;
 740         start_ammo_shells = 0;
 741         start_ammo_nails = 0;
 742         start_ammo_rockets = 0;
 743         start_ammo_cells = 0;
 744         start_health = cvar("g_balance_health_start");
 745         start_armorvalue = cvar("g_balance_armor_start");
 746
 747         g_weaponarena = 0;
 748         WEPSET_CLEAR_A(g_weaponarena_weapons);
 749
 750         s = cvar_string("g_weaponarena");
 751         if (s == "0" || s == "")
 752         {
 753                 if(g_ca)
 754                         s = "most";
 755         }
 756
 757         if (s == "0" || s == "")
 758         {
 759                 // no arena
 760         }
 761         else if (s == "off")
 762         {
 763                 // forcibly turn off weaponarena
 764         }
 765         else if (s == "all")
 766         {
 767                 g_weaponarena = 1;
 768                 g_weaponarena_list = "All Weapons";
 769                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 770                 {
 771                         e = get_weaponinfo(j);
 772                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 773                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 774                 }
 775         }
 776         else if (s == "most")
 777         {
 778                 g_weaponarena = 1;
 779                 g_weaponarena_list = "Most Weapons";
 780                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 781                 {
 782                         e = get_weaponinfo(j);
 783                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 784                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 785                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 786                 }
 787         }
 788         else if (s == "none")
 789         {
 790                 g_weaponarena = 1;
 791                 g_weaponarena_list = "No Weapons";
 792         }
 793         else
 794         {
 795                 g_weaponarena = 1;
 796                 t = tokenize_console(s);
 797                 g_weaponarena_list = "";
 798                 for (i = 0; i < t; ++i)
 799                 {
 800                         s = argv(i);
 801                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 802                         {
 803                                 e = get_weaponinfo(j);
 804                                 if (e.netname == s)
 805                                 {
 806                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 807                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 808                                         break;
 809                                 }
 810                         }
 811                         if (j > WEP_LAST)
 812                         {
 813                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 814                         }
 815                 }
 816                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 817         }
 818
 819         if(g_weaponarena)
 820                 g_weaponarena_random = cvar("g_weaponarena_random");
 821         else
 822                 g_weaponarena_random = 0;
 823         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 824
 825         if (g_weaponarena)
 826         {
 827                 g_pinata = 0; // incompatible
 828                 g_weapon_stay = 0; // incompatible
 829                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 830                 start_items |= IT_UNLIMITED_AMMO;
 831         }
 832         else
 833         {
 834                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 835                 {
 836                         e = get_weaponinfo(i);
 837                         float w = want_weapon("g_start_weapon_", e, FALSE);
 838                         if(w & 1)
 839                                 WEPSET_OR_AW(start_weapons, i);
 840                         if(w & 2)
 841                                 WEPSET_OR_AW(start_weapons_default, i);
 842                         if(w & 4)
 843                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 844                 }
 845         }
 846
 847         if(!cvar("g_use_ammunition"))
 848                 start_items |= IT_UNLIMITED_AMMO;
 849
 850         if(cvar("g_nexball"))
 851                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 852
 853         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 854         {
 855                 start_ammo_rockets = 999;
 856                 start_ammo_shells = 999;
 857                 start_ammo_cells = 999;
 858                 start_ammo_nails = 999;
 859                 start_ammo_fuel = 999;
 860         }
 861         else
 862         {
 863                 start_ammo_shells = cvar("g_start_ammo_shells");
 864                 start_ammo_nails = cvar("g_start_ammo_nails");
 865                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 866                 start_ammo_cells = cvar("g_start_ammo_cells");
 867                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 868         }
 869
 870         if (inWarmupStage)
 871         {
 872                 warmup_start_ammo_shells = start_ammo_shells;
 873                 warmup_start_ammo_nails = start_ammo_nails;
 874                 warmup_start_ammo_rockets = start_ammo_rockets;
 875                 warmup_start_ammo_cells = start_ammo_cells;
 876                 warmup_start_ammo_fuel = start_ammo_fuel;
 877                 warmup_start_health = start_health;
 878                 warmup_start_armorvalue = start_armorvalue;
 879                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 880                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 881                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 882
 883                 if (!g_weaponarena && !g_ca)
 884                 {
 885                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 886                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 887                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 888                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 889                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 890                         warmup_start_health = cvar("g_warmup_start_health");
 891                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 892                         WEPSET_CLEAR_A(warmup_start_weapons);
 893                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 894                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 895                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 896                         {
 897                                 e = get_weaponinfo(i);
 898                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 899                                 if(w & 1)
 900                                         WEPSET_OR_AW(warmup_start_weapons, i);
 901                                 if(w & 2)
 902                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 903                                 if(w & 4)
 904                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 905                         }
 906                 }
 907         }
 908
 909         if (g_jetpack)
 910                 start_items |= IT_JETPACK;
 911
 912         MUTATOR_CALLHOOK(SetStartItems);
 913
 914         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 915         {
 916                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 917                 start_items |= IT_FUEL_REGEN;
 918                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 919                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 920         }
 921
 922         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 923         {
 924                 e = get_weaponinfo(i);
 925                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 926                         weapon_action(i, WR_PRECACHE);
 927         }
 928
 929         start_ammo_shells = max(0, start_ammo_shells);
 930         start_ammo_nails = max(0, start_ammo_nails);
 931         start_ammo_cells = max(0, start_ammo_cells);
 932         start_ammo_rockets = max(0, start_ammo_rockets);
 933         start_ammo_fuel = max(0, start_ammo_fuel);
 934
 935         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 936         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 937         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 938         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 939         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 940 }
 941
 942 float g_bugrigs;
 943 float g_bugrigs_planar_movement;
 944 float g_bugrigs_planar_movement_car_jumping;
 945 float g_bugrigs_reverse_spinning;
 946 float g_bugrigs_reverse_speeding;
 947 float g_bugrigs_reverse_stopping;
 948 float g_bugrigs_air_steering;
 949 float g_bugrigs_angle_smoothing;
 950 float g_bugrigs_friction_floor;
 951 float g_bugrigs_friction_brake;
 952 float g_bugrigs_friction_air;
 953 float g_bugrigs_accel;
 954 float g_bugrigs_speed_ref;
 955 float g_bugrigs_speed_pow;
 956 float g_bugrigs_steer;
 957
 958 float sv_autotaunt;
 959 float sv_taunt;
 960
 961 string GetGametype(); // g_world.qc
 962 void readlevelcvars(void)
 963 {
 964         // load ALL the mutators
 965         if(cvar("g_dodging"))
 966                 MUTATOR_ADD(mutator_dodging);
 967         if(cvar("g_spawn_near_teammate"))
 968                 MUTATOR_ADD(mutator_spawn_near_teammate);
 969         if(cvar("g_physical_items"))
 970                 MUTATOR_ADD(mutator_physical_items);
 971         if(cvar("g_touchexplode"))
 972                 MUTATOR_ADD(mutator_touchexplode);
 973         if(cvar("g_minstagib"))
 974                 MUTATOR_ADD(mutator_minstagib);
 975         if(cvar("g_invincible_projectiles"))
 976                 MUTATOR_ADD(mutator_invincibleprojectiles);
 977         if(cvar("g_new_toys"))
 978                 MUTATOR_ADD(mutator_new_toys);
 979         if(!cvar("g_minstagib")) // TODO: nix support?
 980         if(cvar("g_nix"))
 981                 MUTATOR_ADD(mutator_nix);
 982         if(cvar("g_rocket_flying"))
 983                 MUTATOR_ADD(mutator_rocketflying);
 984         if(cvar("g_vampire"))
 985                 MUTATOR_ADD(mutator_vampire);
 986         if(cvar("g_superspectate"))
 987                 MUTATOR_ADD(mutator_superspec);
 988
 989         // is this a mutator? is this a mode?
 990         if(cvar("g_sandbox"))
 991                 MUTATOR_ADD(sandbox);
 992
 993         if(cvar("sv_allow_fullbright"))
 994                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 995
 996     g_bugrigs = cvar("g_bugrigs");
 997     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 998     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 999     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1000     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1001     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1002     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1003     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1004     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1005     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1006     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1007     g_bugrigs_accel = cvar("g_bugrigs_accel");
1008     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1009     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1010     g_bugrigs_steer = cvar("g_bugrigs_steer");
1011
1012         g_minstagib = cvar("g_minstagib");
1013
1014         sv_clones = cvar("sv_clones");
1015         sv_foginterval = cvar("sv_foginterval");
1016         g_cloaked = cvar("g_cloaked");
1017     if(g_cts)
1018         g_cloaked = 1; // always enable cloak in CTS
1019         g_jump_grunt = cvar("g_jump_grunt");
1020         g_footsteps = cvar("g_footsteps");
1021         g_grappling_hook = cvar("g_grappling_hook");
1022         g_jetpack = cvar("g_jetpack");
1023         g_midair = cvar("g_midair");
1024         g_norecoil = cvar("g_norecoil");
1025         g_bloodloss = cvar("g_bloodloss");
1026         sv_maxidle = cvar("sv_maxidle");
1027         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1028         sv_autotaunt = cvar("sv_autotaunt");
1029         sv_taunt = cvar("sv_taunt");
1030
1031         inWarmupStage = cvar("g_warmup");
1032         g_warmup_limit = cvar("g_warmup_limit");
1033         g_warmup_allguns = cvar("g_warmup_allguns");
1034         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1035
1036         if ((g_race && g_race_qualifying == 2) || g_arena || g_minstagib || g_assault || cvar("g_campaign"))
1037                 inWarmupStage = 0; // these modes cannot work together, sorry
1038
1039         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1040         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1041         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1042         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1043         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1044         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1045         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1046         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1047         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1048         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1049         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1050         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1051         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1052         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1053
1054         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1055         g_weaponratefactor = cvar("g_weaponratefactor");
1056         g_weapondamagefactor = cvar("g_weapondamagefactor");
1057         g_weaponforcefactor = cvar("g_weaponforcefactor");
1058         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1059
1060         g_pickup_shells = cvar("g_pickup_shells");
1061         g_pickup_shells_max = cvar("g_pickup_shells_max");
1062         g_pickup_nails = cvar("g_pickup_nails");
1063         g_pickup_nails_max = cvar("g_pickup_nails_max");
1064         g_pickup_rockets = cvar("g_pickup_rockets");
1065         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1066         g_pickup_cells = cvar("g_pickup_cells");
1067         g_pickup_cells_max = cvar("g_pickup_cells_max");
1068         g_pickup_fuel = cvar("g_pickup_fuel");
1069         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1070         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1071         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1072         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1073         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1074         g_pickup_armormedium = cvar("g_pickup_armormedium");
1075         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1076         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1077         g_pickup_armorbig = cvar("g_pickup_armorbig");
1078         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1079         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1080         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1081         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1082         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1083         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1084         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1085         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1086         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1087         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1088         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1089         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1090         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1091         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1092         g_pickup_healthmega = cvar("g_pickup_healthmega");
1093         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1094         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1095
1096         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1097         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1098
1099         g_pinata = cvar("g_pinata");
1100
1101     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1102     if(!g_weapon_stay)
1103         g_weapon_stay = cvar("g_weapon_stay");
1104
1105         if not(inWarmupStage)
1106                 game_starttime = time + cvar("g_start_delay");
1107
1108         readplayerstartcvars();
1109 }
1110
1111 //#NO AUTOCVARS END
1112
1113 // Sound functions
1114 string precache_sound (string s) = #19;
1115 float precache_sound_index (string s) = #19;
1116
1117 #define SND_VOLUME      1
1118 #define SND_ATTENUATION 2
1119 #define SND_LARGEENTITY 8
1120 #define SND_LARGESOUND  16
1121
1122 float sound_allowed(float dest, entity e)
1123 {
1124     // sounds from world may always pass
1125     for (;;)
1126     {
1127         if (e.classname == "body")
1128             e = e.enemy;
1129         else if (e.realowner && e.realowner != e)
1130             e = e.realowner;
1131         else if (e.owner && e.owner != e)
1132             e = e.owner;
1133         else
1134             break;
1135     }
1136     // sounds to self may always pass
1137     if (dest == MSG_ONE)
1138         if (e == msg_entity)
1139             return TRUE;
1140     // sounds by players can be removed
1141     if (autocvar_bot_sound_monopoly)
1142         if (clienttype(e) == CLIENTTYPE_REAL)
1143             return FALSE;
1144     // anything else may pass
1145     return TRUE;
1146 }
1147
1148 #ifdef COMPAT_XON010_CHANNELS
1149 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1150 void sound(entity e, float chan, string samp, float vol, float atten)
1151 {
1152     if (!sound_allowed(MSG_BROADCAST, e))
1153         return;
1154     builtin_sound(e, chan, samp, vol, atten);
1155 }
1156 #else
1157 #undef sound
1158 void sound(entity e, float chan, string samp, float vol, float atten)
1159 {
1160     if (!sound_allowed(MSG_BROADCAST, e))
1161         return;
1162     sound7(e, chan, samp, vol, atten, 0, 0);
1163 }
1164 #endif
1165
1166 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1167 {
1168     float entno, idx;
1169
1170     if (!sound_allowed(dest, e))
1171         return;
1172
1173     entno = num_for_edict(e);
1174     idx = precache_sound_index(samp);
1175
1176     float sflags;
1177     sflags = 0;
1178
1179     atten = floor(atten * 64);
1180     vol = floor(vol * 255);
1181
1182     if (vol != 255)
1183         sflags |= SND_VOLUME;
1184     if (atten != 64)
1185         sflags |= SND_ATTENUATION;
1186     if (entno >= 8192 || chan < 0 || chan > 7)
1187         sflags |= SND_LARGEENTITY;
1188     if (idx >= 256)
1189         sflags |= SND_LARGESOUND;
1190
1191     WriteByte(dest, SVC_SOUND);
1192     WriteByte(dest, sflags);
1193     if (sflags & SND_VOLUME)
1194         WriteByte(dest, vol);
1195     if (sflags & SND_ATTENUATION)
1196         WriteByte(dest, atten);
1197     if (sflags & SND_LARGEENTITY)
1198     {
1199         WriteShort(dest, entno);
1200         WriteByte(dest, chan);
1201     }
1202     else
1203     {
1204         WriteShort(dest, entno * 8 + chan);
1205     }
1206     if (sflags & SND_LARGESOUND)
1207         WriteShort(dest, idx);
1208     else
1209         WriteByte(dest, idx);
1210
1211     WriteCoord(dest, o_x);
1212     WriteCoord(dest, o_y);
1213     WriteCoord(dest, o_z);
1214 }
1215 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1216 {
1217     vector o;
1218
1219     if (!sound_allowed(dest, e))
1220         return;
1221
1222     o = e.origin + 0.5 * (e.mins + e.maxs);
1223     soundtoat(dest, e, o, chan, samp, vol, atten);
1224 }
1225 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1226 {
1227     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1228 }
1229 void stopsoundto(float dest, entity e, float chan)
1230 {
1231     float entno;
1232
1233     if (!sound_allowed(dest, e))
1234         return;
1235
1236     entno = num_for_edict(e);
1237
1238     if (entno >= 8192 || chan < 0 || chan > 7)
1239     {
1240         float idx, sflags;
1241         idx = precache_sound_index("misc/null.wav");
1242         sflags = SND_LARGEENTITY;
1243         if (idx >= 256)
1244             sflags |= SND_LARGESOUND;
1245         WriteByte(dest, SVC_SOUND);
1246         WriteByte(dest, sflags);
1247         WriteShort(dest, entno);
1248         WriteByte(dest, chan);
1249         if (sflags & SND_LARGESOUND)
1250             WriteShort(dest, idx);
1251         else
1252             WriteByte(dest, idx);
1253         WriteCoord(dest, e.origin_x);
1254         WriteCoord(dest, e.origin_y);
1255         WriteCoord(dest, e.origin_z);
1256     }
1257     else
1258     {
1259         WriteByte(dest, SVC_STOPSOUND);
1260         WriteShort(dest, entno * 8 + chan);
1261     }
1262 }
1263 void stopsound(entity e, float chan)
1264 {
1265     if (!sound_allowed(MSG_BROADCAST, e))
1266         return;
1267
1268     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1269     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1270 }
1271
1272 void play2(entity e, string filename)
1273 {
1274     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1275     msg_entity = e;
1276     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1277 }
1278
1279 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1280 .float spamtime;
1281 float spamsound(entity e, float chan, string samp, float vol, float atten)
1282 {
1283     if (!sound_allowed(MSG_BROADCAST, e))
1284         return FALSE;
1285
1286     if (time > e.spamtime)
1287     {
1288         e.spamtime = time;
1289         sound(e, chan, samp, vol, atten);
1290         return TRUE;
1291     }
1292     return FALSE;
1293 }
1294
1295 void play2team(float t, string filename)
1296 {
1297     entity head;
1298
1299     if (autocvar_bot_sound_monopoly)
1300         return;
1301
1302     FOR_EACH_REALPLAYER(head)
1303     {
1304         if (head.team == t)
1305             play2(head, filename);
1306     }
1307 }
1308
1309 void play2all(string samp)
1310 {
1311     if (autocvar_bot_sound_monopoly)
1312         return;
1313
1314     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1315 }
1316
1317 void PrecachePlayerSounds(string f);
1318 void precache_playermodel(string m)
1319 {
1320         float globhandle, i, n;
1321         string f;
1322
1323         if(substring(m, -9,5) == "_lod1")
1324                 return;
1325         if(substring(m, -9,5) == "_lod2")
1326                 return;
1327         precache_model(m);
1328         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1329         if(fexists(f))
1330                 precache_model(f);
1331         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1332         if(fexists(f))
1333                 precache_model(f);
1334
1335         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1336         if (globhandle < 0)
1337                 return;
1338         n = search_getsize(globhandle);
1339         for (i = 0; i < n; ++i)
1340         {
1341                 //print(search_getfilename(globhandle, i), "\n");
1342                 f = search_getfilename(globhandle, i);
1343                 PrecachePlayerSounds(f);
1344         }
1345         search_end(globhandle);
1346 }
1347 void precache_all_playermodels(string pattern)
1348 {
1349         float globhandle, i, n;
1350         string f;
1351
1352         globhandle = search_begin(pattern, TRUE, FALSE);
1353         if (globhandle < 0)
1354                 return;
1355         n = search_getsize(globhandle);
1356         for (i = 0; i < n; ++i)
1357         {
1358                 //print(search_getfilename(globhandle, i), "\n");
1359                 f = search_getfilename(globhandle, i);
1360                 precache_playermodel(f);
1361         }
1362         search_end(globhandle);
1363 }
1364
1365 void precache()
1366 {
1367     // gamemode related things
1368     precache_model ("models/misc/chatbubble.spr");
1369
1370 #ifdef TTURRETS_ENABLED
1371     if (autocvar_g_turrets)
1372         turrets_precash();
1373 #endif
1374
1375     // Precache all player models if desired
1376     if (autocvar_sv_precacheplayermodels)
1377     {
1378         PrecachePlayerSounds("sound/player/default.sounds");
1379         precache_all_playermodels("models/player/*.zym");
1380         precache_all_playermodels("models/player/*.dpm");
1381         precache_all_playermodels("models/player/*.md3");
1382         precache_all_playermodels("models/player/*.psk");
1383         precache_all_playermodels("models/player/*.iqm");
1384     }
1385
1386     if (autocvar_sv_defaultcharacter)
1387     {
1388         string s;
1389         s = autocvar_sv_defaultplayermodel_red;
1390         if (s != "")
1391             precache_playermodel(s);
1392         s = autocvar_sv_defaultplayermodel_blue;
1393         if (s != "")
1394             precache_playermodel(s);
1395         s = autocvar_sv_defaultplayermodel_yellow;
1396         if (s != "")
1397             precache_playermodel(s);
1398         s = autocvar_sv_defaultplayermodel_pink;
1399         if (s != "")
1400             precache_playermodel(s);
1401         s = autocvar_sv_defaultplayermodel;
1402         if (s != "")
1403             precache_playermodel(s);
1404     }
1405
1406     if (g_footsteps)
1407     {
1408         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1409         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1410     }
1411
1412     // gore and miscellaneous sounds
1413     //precache_sound ("misc/h2ohit.wav");
1414     precache_model ("models/hook.md3");
1415     precache_sound ("misc/armorimpact.wav");
1416     precache_sound ("misc/bodyimpact1.wav");
1417     precache_sound ("misc/bodyimpact2.wav");
1418     precache_sound ("misc/gib.wav");
1419     precache_sound ("misc/gib_splat01.wav");
1420     precache_sound ("misc/gib_splat02.wav");
1421     precache_sound ("misc/gib_splat03.wav");
1422     precache_sound ("misc/gib_splat04.wav");
1423     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1424     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1425     precache_sound ("misc/null.wav");
1426     precache_sound ("misc/spawn.wav");
1427     precache_sound ("misc/talk.wav");
1428     precache_sound ("misc/teleport.wav");
1429     precache_sound ("misc/poweroff.wav");
1430     precache_sound ("player/lava.wav");
1431     precache_sound ("player/slime.wav");
1432
1433     precache_model ("models/sprites/0.spr32");
1434     precache_model ("models/sprites/1.spr32");
1435     precache_model ("models/sprites/2.spr32");
1436     precache_model ("models/sprites/3.spr32");
1437     precache_model ("models/sprites/4.spr32");
1438     precache_model ("models/sprites/5.spr32");
1439     precache_model ("models/sprites/6.spr32");
1440     precache_model ("models/sprites/7.spr32");
1441     precache_model ("models/sprites/8.spr32");
1442     precache_model ("models/sprites/9.spr32");
1443     precache_model ("models/sprites/10.spr32");
1444
1445     // common weapon precaches
1446         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1447     precache_sound ("weapons/weapon_switch.wav");
1448     precache_sound ("weapons/weaponpickup.wav");
1449     precache_sound ("weapons/unavailable.wav");
1450     precache_sound ("weapons/dryfire.wav");
1451     if (g_grappling_hook)
1452     {
1453         precache_sound ("weapons/hook_fire.wav"); // hook
1454         precache_sound ("weapons/hook_impact.wav"); // hook
1455     }
1456
1457     if(autocvar_sv_precacheweapons)
1458     {
1459         //precache weapon models/sounds
1460         float wep;
1461         wep = WEP_FIRST;
1462         while (wep <= WEP_LAST)
1463         {
1464             weapon_action(wep, WR_PRECACHE);
1465             wep = wep + 1;
1466         }
1467     }
1468
1469     precache_model("models/elaser.mdl");
1470     precache_model("models/laser.mdl");
1471     precache_model("models/ebomb.mdl");
1472
1473 #if 0
1474     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1475
1476     if (!self.noise && self.music) // quake 3 uses the music field
1477         self.noise = self.music;
1478
1479     // plays music for the level if there is any
1480     if (self.noise)
1481     {
1482         precache_sound (self.noise);
1483         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1484     }
1485 #endif
1486 }
1487
1488 // WARNING: this kills the trace globals
1489 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1490 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1491
1492 #define INITPRIO_FIRST              0
1493 #define INITPRIO_GAMETYPE           0
1494 #define INITPRIO_GAMETYPE_FALLBACK  1
1495 #define INITPRIO_FINDTARGET        10
1496 #define INITPRIO_DROPTOFLOOR       20
1497 #define INITPRIO_SETLOCATION       90
1498 #define INITPRIO_LINKDOORS         91
1499 #define INITPRIO_LAST              99
1500
1501 .void(void) initialize_entity;
1502 .float initialize_entity_order;
1503 .entity initialize_entity_next;
1504 entity initialize_entity_first;
1505
1506 void make_safe_for_remove(entity e)
1507 {
1508     if (e.initialize_entity)
1509     {
1510         entity ent, prev = world;
1511         for (ent = initialize_entity_first; ent; )
1512         {
1513             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1514             {
1515                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1516                 // skip it in linked list
1517                 if (prev)
1518                 {
1519                     prev.initialize_entity_next = ent.initialize_entity_next;
1520                     ent = prev.initialize_entity_next;
1521                 }
1522                 else
1523                 {
1524                     initialize_entity_first = ent.initialize_entity_next;
1525                     ent = initialize_entity_first;
1526                 }
1527             }
1528             else
1529             {
1530                 prev = ent;
1531                 ent = ent.initialize_entity_next;
1532             }
1533         }
1534     }
1535 }
1536
1537 void objerror(string s)
1538 {
1539     make_safe_for_remove(self);
1540     builtin_objerror(s);
1541 }
1542
1543 .float remove_except_protected_forbidden;
1544 void remove_except_protected(entity e)
1545 {
1546         if(e.remove_except_protected_forbidden)
1547                 error("not allowed to remove this at this point");
1548         builtin_remove(e);
1549 }
1550
1551 void remove_unsafely(entity e)
1552 {
1553     if(e.classname == "spike")
1554         error("Removing spikes is forbidden (crylink bug), please report");
1555     builtin_remove(e);
1556 }
1557
1558 void remove_safely(entity e)
1559 {
1560     make_safe_for_remove(e);
1561     builtin_remove(e);
1562 }
1563
1564 void InitializeEntity(entity e, void(void) func, float order)
1565 {
1566     entity prev, cur;
1567
1568     if (!e || e.initialize_entity)
1569     {
1570         // make a proxy initializer entity
1571         entity e_old;
1572         e_old = e;
1573         e = spawn();
1574         e.classname = "initialize_entity";
1575         e.enemy = e_old;
1576     }
1577
1578     e.initialize_entity = func;
1579     e.initialize_entity_order = order;
1580
1581     cur = initialize_entity_first;
1582     prev = world;
1583     for (;;)
1584     {
1585         if (!cur || cur.initialize_entity_order > order)
1586         {
1587             // insert between prev and cur
1588             if (prev)
1589                 prev.initialize_entity_next = e;
1590             else
1591                 initialize_entity_first = e;
1592             e.initialize_entity_next = cur;
1593             return;
1594         }
1595         prev = cur;
1596         cur = cur.initialize_entity_next;
1597     }
1598 }
1599 void InitializeEntitiesRun()
1600 {
1601     entity startoflist;
1602     startoflist = initialize_entity_first;
1603     initialize_entity_first = world;
1604     remove = remove_except_protected;
1605     for (self = startoflist; self; self = self.initialize_entity_next)
1606     {
1607         self.remove_except_protected_forbidden = 1;
1608     }
1609     for (self = startoflist; self; )
1610     {
1611         entity e;
1612         var void(void) func;
1613         e = self.initialize_entity_next;
1614         func = self.initialize_entity;
1615         self.initialize_entity_order = 0;
1616         self.initialize_entity = func_null;
1617         self.initialize_entity_next = world;
1618         self.remove_except_protected_forbidden = 0;
1619         if (self.classname == "initialize_entity")
1620         {
1621             entity e_old;
1622             e_old = self.enemy;
1623             builtin_remove(self);
1624             self = e_old;
1625         }
1626         //dprint("Delayed initialization: ", self.classname, "\n");
1627         if(func)
1628             func();
1629         else
1630         {
1631             eprint(self);
1632             backtrace(strcat("Null function in: ", self.classname, "\n"));
1633         }
1634         self = e;
1635     }
1636     remove = remove_unsafely;
1637 }
1638
1639 .float uncustomizeentityforclient_set;
1640 .void(void) uncustomizeentityforclient;
1641 void UncustomizeEntitiesRun()
1642 {
1643     entity oldself;
1644     oldself = self;
1645     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1646         self.uncustomizeentityforclient();
1647     self = oldself;
1648 }
1649 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1650 {
1651     e.customizeentityforclient = customizer;
1652     e.uncustomizeentityforclient = uncustomizer;
1653     e.uncustomizeentityforclient_set = !!uncustomizer;
1654 }
1655
1656 .float nottargeted;
1657 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1658
1659 void() SUB_Remove;
1660 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1661 {
1662     vector mi, ma;
1663
1664     if (e.classname == "")
1665         e.classname = "net_linked";
1666
1667     if (e.model == "" || self.modelindex == 0)
1668     {
1669         mi = e.mins;
1670         ma = e.maxs;
1671         setmodel(e, "null");
1672         setsize(e, mi, ma);
1673     }
1674
1675     e.SendEntity = sendfunc;
1676     e.SendFlags = 0xFFFFFF;
1677
1678     if (!docull)
1679         e.effects |= EF_NODEPTHTEST;
1680
1681     if (dt)
1682     {
1683         e.nextthink = time + dt;
1684         e.think = SUB_Remove;
1685     }
1686 }
1687
1688 void adaptor_think2touch()
1689 {
1690     entity o;
1691     o = other;
1692     other = world;
1693     self.touch();
1694     other = o;
1695 }
1696
1697 void adaptor_think2use()
1698 {
1699     entity o, a;
1700     o = other;
1701     a = activator;
1702     activator = world;
1703     other = world;
1704     self.use();
1705     other = o;
1706     activator = a;
1707 }
1708
1709 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1710 {
1711         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1712                 self.projectiledeathtype |= HITTYPE_SPLASH;
1713         adaptor_think2use();
1714 }
1715
1716 // deferred dropping
1717 void DropToFloor_Handler()
1718 {
1719     builtin_droptofloor();
1720     self.dropped_origin = self.origin;
1721 }
1722
1723 void droptofloor()
1724 {
1725     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1726 }
1727
1728
1729
1730 float trace_hits_box_a0, trace_hits_box_a1;
1731
1732 float trace_hits_box_1d(float end, float thmi, float thma)
1733 {
1734     if (end == 0)
1735     {
1736         // just check if x is in range
1737         if (0 < thmi)
1738             return FALSE;
1739         if (0 > thma)
1740             return FALSE;
1741     }
1742     else
1743     {
1744         // do the trace with respect to x
1745         // 0 -> end has to stay in thmi -> thma
1746         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1747         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1748         if (trace_hits_box_a0 > trace_hits_box_a1)
1749             return FALSE;
1750     }
1751     return TRUE;
1752 }
1753
1754 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1755 {
1756     end -= start;
1757     thmi -= start;
1758     thma -= start;
1759     // now it is a trace from 0 to end
1760
1761     trace_hits_box_a0 = 0;
1762     trace_hits_box_a1 = 1;
1763
1764     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1765         return FALSE;
1766     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1767         return FALSE;
1768     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1769         return FALSE;
1770
1771     return TRUE;
1772 }
1773
1774 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1775 {
1776     return trace_hits_box(start, end, thmi - ma, thma - mi);
1777 }
1778
1779 float SUB_NoImpactCheck()
1780 {
1781         // zero hitcontents = this is not the real impact, but either the
1782         // mirror-impact of something hitting the projectile instead of the
1783         // projectile hitting the something, or a touchareagrid one. Neither of
1784         // these stop the projectile from moving, so...
1785         if(trace_dphitcontents == 0)
1786         {
1787                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1788                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1789                 checkclient();
1790         }
1791     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1792         return 1;
1793     if (other == world && self.size != '0 0 0')
1794     {
1795         vector tic;
1796         tic = self.velocity * sys_frametime;
1797         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1798         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1799         if (trace_fraction >= 1)
1800         {
1801             dprint("Odd... did not hit...?\n");
1802         }
1803         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1804         {
1805             dprint("Detected and prevented the sky-grapple bug.\n");
1806             return 1;
1807         }
1808     }
1809
1810     return 0;
1811 }
1812
1813 #define SUB_OwnerCheck() (other && (other == self.owner))
1814
1815 void RemoveGrapplingHook(entity pl);
1816 void W_Crylink_Dequeue(entity e);
1817 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1818 {
1819         if(SUB_OwnerCheck())
1820                 return TRUE;
1821         if(SUB_NoImpactCheck())
1822         {
1823                 if(self.classname == "grapplinghook")
1824                         RemoveGrapplingHook(self.realowner);
1825                 else if(self.classname == "spike")
1826                 {
1827                         W_Crylink_Dequeue(self);
1828                         remove(self);
1829                 }
1830                 else
1831                         remove(self);
1832                 return TRUE;
1833         }
1834         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1835                 UpdateCSQCProjectile(self);
1836         return FALSE;
1837 }
1838 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1839
1840 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1841 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1842
1843 void URI_Get_Callback(float id, float status, string data)
1844 {
1845         if(url_URI_Get_Callback(id, status, data))
1846         {
1847                 // handled
1848         }
1849         else if (id == URI_GET_DISCARD)
1850         {
1851                 // discard
1852         }
1853         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1854         {
1855                 // sv_cmd curl
1856                 Curl_URI_Get_Callback(id, status, data);
1857         }
1858         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1859         {
1860                 // online ban list
1861                 OnlineBanList_URI_Get_Callback(id, status, data);
1862         }
1863         else
1864         {
1865                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1866         }
1867 }
1868
1869 string uid2name(string myuid) {
1870         string s;
1871         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1872
1873         // FIXME remove this later after 0.6 release
1874         // convert old style broken records to correct style
1875         if(s == "")
1876         {
1877                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1878                 if(s != "")
1879                 {
1880                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1881                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1882                 }
1883         }
1884
1885         if(s == "")
1886                 s = "^1Unregistered Player";
1887         return s;
1888 }
1889
1890 float race_readTime(string map, float pos)
1891 {
1892         string rr;
1893         if(g_cts)
1894                 rr = CTS_RECORD;
1895         else
1896                 rr = RACE_RECORD;
1897
1898         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1899 }
1900
1901 string race_readUID(string map, float pos)
1902 {
1903         string rr;
1904         if(g_cts)
1905                 rr = CTS_RECORD;
1906         else
1907                 rr = RACE_RECORD;
1908
1909         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1910 }
1911
1912 float race_readPos(string map, float t) {
1913         float i;
1914         for (i = 1; i <= RANKINGS_CNT; ++i)
1915                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1916                         return i;
1917
1918         return 0; // pos is zero if unranked
1919 }
1920
1921 void race_writeTime(string map, float t, string myuid)
1922 {
1923         string rr;
1924         if(g_cts)
1925                 rr = CTS_RECORD;
1926         else
1927                 rr = RACE_RECORD;
1928
1929         float newpos;
1930         newpos = race_readPos(map, t);
1931
1932         float i, prevpos = 0;
1933         for(i = 1; i <= RANKINGS_CNT; ++i)
1934         {
1935                 if(race_readUID(map, i) == myuid)
1936                         prevpos = i;
1937         }
1938         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1939                 for (i = prevpos; i > newpos; --i) {
1940                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1941                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1942                 }
1943         } else { // player has no ranked record yet
1944                 for (i = RANKINGS_CNT; i > newpos; --i) {
1945                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1946                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1947                 }
1948         }
1949
1950         // store new time itself
1951         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1952         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1953 }
1954
1955 string race_readName(string map, float pos)
1956 {
1957         string rr;
1958         if(g_cts)
1959                 rr = CTS_RECORD;
1960         else
1961                 rr = RACE_RECORD;
1962
1963         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1964 }
1965
1966 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1967 {
1968     float m, i;
1969     vector start, org, delta, end, enddown, mstart;
1970     entity sp;
1971
1972     m = e.dphitcontentsmask;
1973     e.dphitcontentsmask = goodcontents | badcontents;
1974
1975     org = world.mins;
1976     delta = world.maxs - world.mins;
1977
1978     start = end = org;
1979
1980     for (i = 0; i < attempts; ++i)
1981     {
1982         start_x = org_x + random() * delta_x;
1983         start_y = org_y + random() * delta_y;
1984         start_z = org_z + random() * delta_z;
1985
1986         // rule 1: start inside world bounds, and outside
1987         // solid, and don't start from somewhere where you can
1988         // fall down to evil
1989         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1990         if (trace_fraction >= 1)
1991             continue;
1992         if (trace_startsolid)
1993             continue;
1994         if (trace_dphitcontents & badcontents)
1995             continue;
1996         if (trace_dphitq3surfaceflags & badsurfaceflags)
1997             continue;
1998
1999         // rule 2: if we are too high, lower the point
2000         if (trace_fraction * delta_z > maxaboveground)
2001             start = trace_endpos + '0 0 1' * maxaboveground;
2002         enddown = trace_endpos;
2003
2004         // rule 3: make sure we aren't outside the map. This only works
2005         // for somewhat well formed maps. A good rule of thumb is that
2006         // the map should have a convex outside hull.
2007         // these can be traceLINES as we already verified the starting box
2008         mstart = start + 0.5 * (e.mins + e.maxs);
2009         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2010         if (trace_fraction >= 1)
2011             continue;
2012         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2013         if (trace_fraction >= 1)
2014             continue;
2015         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2016         if (trace_fraction >= 1)
2017             continue;
2018         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2019         if (trace_fraction >= 1)
2020             continue;
2021         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2022         if (trace_fraction >= 1)
2023             continue;
2024
2025         // rule 4: we must "see" some spawnpoint
2026         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2027                 if(checkpvs(mstart, sp))
2028                         break;
2029         if(!sp)
2030         {
2031                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2032                         if(checkpvs(mstart, sp))
2033                                 break;
2034                 if(!sp)
2035                         continue;
2036         }
2037
2038         // find a random vector to "look at"
2039         end_x = org_x + random() * delta_x;
2040         end_y = org_y + random() * delta_y;
2041         end_z = org_z + random() * delta_z;
2042         end = start + normalize(end - start) * vlen(delta);
2043
2044         // rule 4: start TO end must not be too short
2045         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2046         if (trace_startsolid)
2047             continue;
2048         if (trace_fraction < minviewdistance / vlen(delta))
2049             continue;
2050
2051         // rule 5: don't want to look at sky
2052         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2053             continue;
2054
2055         // rule 6: we must not end up in trigger_hurt
2056         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2057             continue;
2058
2059         break;
2060     }
2061
2062     e.dphitcontentsmask = m;
2063
2064     if (i < attempts)
2065     {
2066         setorigin(e, start);
2067         e.angles = vectoangles(end - start);
2068         dprint("Needed ", ftos(i + 1), " attempts\n");
2069         return TRUE;
2070     }
2071     else
2072         return FALSE;
2073 }
2074
2075 float zcurveparticles_effectno;
2076 vector zcurveparticles_start;
2077 float zcurveparticles_spd;
2078
2079 void endzcurveparticles()
2080 {
2081         if(zcurveparticles_effectno)
2082         {
2083                 // terminator
2084                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2085         }
2086         zcurveparticles_effectno = 0;
2087 }
2088
2089 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2090 {
2091         spd = bound(0, floor(spd / 16), 32767);
2092         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2093         {
2094                 endzcurveparticles();
2095                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2096                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2097                 WriteShort(MSG_BROADCAST, effectno);
2098                 WriteCoord(MSG_BROADCAST, start_x);
2099                 WriteCoord(MSG_BROADCAST, start_y);
2100                 WriteCoord(MSG_BROADCAST, start_z);
2101                 zcurveparticles_effectno = effectno;
2102                 zcurveparticles_start = start;
2103         }
2104         else
2105                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2106         WriteCoord(MSG_BROADCAST, end_x);
2107         WriteCoord(MSG_BROADCAST, end_y);
2108         WriteCoord(MSG_BROADCAST, end_z);
2109         WriteCoord(MSG_BROADCAST, end_dz);
2110         zcurveparticles_spd = spd;
2111 }
2112
2113 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2114 {
2115         float end_dz;
2116         vector vecxy, velxy;
2117
2118         vecxy = end - start;
2119         vecxy_z = 0;
2120         velxy = vel;
2121         velxy_z = 0;
2122
2123         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2124         {
2125                 endzcurveparticles();
2126                 trailparticles(world, effectno, start, end);
2127                 return;
2128         }
2129
2130         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2131         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2132 }
2133
2134 void write_recordmarker(entity pl, float tstart, float dt)
2135 {
2136     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2137
2138     // also write a marker into demo files for demotc-race-record-extractor to find
2139     stuffcmd(pl,
2140              strcat(
2141                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2142                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2143 }
2144
2145 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2146 {
2147         switch(algn)
2148         {
2149                 default:
2150                 case 3: // right
2151                         break;
2152
2153                 case 4: // left
2154                         vecs_y = -vecs_y;
2155                         break;
2156
2157                 case 1:
2158                         if(allowcenter) // 2: allow center handedness
2159                         {
2160                                 // center
2161                                 vecs_y = 0;
2162                                 vecs_z -= 2;
2163                         }
2164                         else
2165                         {
2166                                 // right
2167                         }
2168                         break;
2169
2170                 case 2:
2171                         if(allowcenter) // 2: allow center handedness
2172                         {
2173                                 // center
2174                                 vecs_y = 0;
2175                                 vecs_z -= 2;
2176                         }
2177                         else
2178                         {
2179                                 // left
2180                                 vecs_y = -vecs_y;
2181                         }
2182                         break;
2183         }
2184         return vecs;
2185 }
2186
2187 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2188 {
2189         string s;
2190         vector v;
2191
2192         if (autocvar_g_shootfromeye)
2193         {
2194                 if (visual)
2195                 {
2196                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2197                         else { vecs_y = 0; vecs_z -= 2; }
2198                 }
2199                 else
2200                 {
2201                         vecs_y = 0;
2202                         vecs_z = 0;
2203                 }
2204         }
2205         else if (autocvar_g_shootfromcenter)
2206         {
2207                 vecs_y = 0;
2208                 vecs_z -= 2;
2209         }
2210         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2211         {
2212                 v = stov(s);
2213                 if (y_is_right)
2214                         v_y = -v_y;
2215                 if (v_x != 0)
2216                         vecs_x = v_x;
2217                 vecs_y = v_y;
2218                 vecs_z = v_z;
2219         }
2220         else if (autocvar_g_shootfromclient)
2221         {
2222                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2223         }
2224         return vecs;
2225 }
2226
2227 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2228 {
2229         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2230 }
2231
2232
2233 void attach_sameorigin(entity e, entity to, string tag)
2234 {
2235     vector org, t_forward, t_left, t_up, e_forward, e_up;
2236     float tagscale;
2237
2238     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2239     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2240     t_forward = v_forward * tagscale;
2241     t_left = v_right * -tagscale;
2242     t_up = v_up * tagscale;
2243
2244     e.origin_x = org * t_forward;
2245     e.origin_y = org * t_left;
2246     e.origin_z = org * t_up;
2247
2248     // current forward and up directions
2249     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2250                 e.angles = AnglesTransform_FromVAngles(e.angles);
2251         else
2252                 e.angles = AnglesTransform_FromAngles(e.angles);
2253     fixedmakevectors(e.angles);
2254
2255     // untransform forward, up!
2256     e_forward_x = v_forward * t_forward;
2257     e_forward_y = v_forward * t_left;
2258     e_forward_z = v_forward * t_up;
2259     e_up_x = v_up * t_forward;
2260     e_up_y = v_up * t_left;
2261     e_up_z = v_up * t_up;
2262
2263     e.angles = fixedvectoangles2(e_forward, e_up);
2264     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2265                 e.angles = AnglesTransform_ToVAngles(e.angles);
2266         else
2267                 e.angles = AnglesTransform_ToAngles(e.angles);
2268
2269     setattachment(e, to, tag);
2270     setorigin(e, e.origin);
2271 }
2272
2273 void detach_sameorigin(entity e)
2274 {
2275     vector org;
2276     org = gettaginfo(e, 0);
2277     e.angles = fixedvectoangles2(v_forward, v_up);
2278     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2279                 e.angles = AnglesTransform_ToVAngles(e.angles);
2280         else
2281                 e.angles = AnglesTransform_ToAngles(e.angles);
2282     setorigin(e, org);
2283     setattachment(e, world, "");
2284     setorigin(e, e.origin);
2285 }
2286
2287 void follow_sameorigin(entity e, entity to)
2288 {
2289     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2290     e.aiment = to; // make the hole follow bmodel
2291     e.punchangle = to.angles; // the original angles of bmodel
2292     e.view_ofs = e.origin - to.origin; // relative origin
2293     e.v_angle = e.angles - to.angles; // relative angles
2294 }
2295
2296 void unfollow_sameorigin(entity e)
2297 {
2298     e.movetype = MOVETYPE_NONE;
2299 }
2300
2301 entity gettaginfo_relative_ent;
2302 vector gettaginfo_relative(entity e, float tag)
2303 {
2304     if (!gettaginfo_relative_ent)
2305     {
2306         gettaginfo_relative_ent = spawn();
2307         gettaginfo_relative_ent.effects = EF_NODRAW;
2308     }
2309     gettaginfo_relative_ent.model = e.model;
2310     gettaginfo_relative_ent.modelindex = e.modelindex;
2311     gettaginfo_relative_ent.frame = e.frame;
2312     return gettaginfo(gettaginfo_relative_ent, tag);
2313 }
2314
2315 .float scale2;
2316
2317 float modeleffect_SendEntity(entity to, float sf)
2318 {
2319         float f;
2320         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2321
2322         f = 0;
2323         if(self.velocity != '0 0 0')
2324                 f |= 1;
2325         if(self.angles != '0 0 0')
2326                 f |= 2;
2327         if(self.avelocity != '0 0 0')
2328                 f |= 4;
2329
2330         WriteByte(MSG_ENTITY, f);
2331         WriteShort(MSG_ENTITY, self.modelindex);
2332         WriteByte(MSG_ENTITY, self.skin);
2333         WriteByte(MSG_ENTITY, self.frame);
2334         WriteCoord(MSG_ENTITY, self.origin_x);
2335         WriteCoord(MSG_ENTITY, self.origin_y);
2336         WriteCoord(MSG_ENTITY, self.origin_z);
2337         if(f & 1)
2338         {
2339                 WriteCoord(MSG_ENTITY, self.velocity_x);
2340                 WriteCoord(MSG_ENTITY, self.velocity_y);
2341                 WriteCoord(MSG_ENTITY, self.velocity_z);
2342         }
2343         if(f & 2)
2344         {
2345                 WriteCoord(MSG_ENTITY, self.angles_x);
2346                 WriteCoord(MSG_ENTITY, self.angles_y);
2347                 WriteCoord(MSG_ENTITY, self.angles_z);
2348         }
2349         if(f & 4)
2350         {
2351                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2352                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2353                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2354         }
2355         WriteShort(MSG_ENTITY, self.scale * 256.0);
2356         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2357         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2358         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2359         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2360
2361         return TRUE;
2362 }
2363
2364 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2365 {
2366         entity e;
2367         float sz;
2368         e = spawn();
2369         e.classname = "modeleffect";
2370         setmodel(e, m);
2371         e.frame = f;
2372         setorigin(e, o);
2373         e.velocity = v;
2374         e.angles = ang;
2375         e.avelocity = angv;
2376         e.alpha = a;
2377         e.teleport_time = t1;
2378         e.fade_time = t2;
2379         e.skin = s;
2380         if(s0 >= 0)
2381                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2382         else
2383                 e.scale = -s0;
2384         if(s2 >= 0)
2385                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2386         else
2387                 e.scale2 = -s2;
2388         sz = max(e.scale, e.scale2);
2389         setsize(e, e.mins * sz, e.maxs * sz);
2390         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2391 }
2392
2393 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2394 {
2395         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2396 }
2397
2398 float randombit(float bits)
2399 {
2400         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2401                 return bits;
2402
2403         float n, f, b, r;
2404
2405         r = random();
2406         b = 0;
2407         n = 0;
2408
2409         for(f = 1; f <= bits; f *= 2)
2410         {
2411                 if(bits & f)
2412                 {
2413                         ++n;
2414                         r *= n;
2415                         if(r <= 1)
2416                                 b = f;
2417                         else
2418                                 r = (r - 1) / (n - 1);
2419                 }
2420         }
2421
2422         return b;
2423 }
2424
2425 float randombits(float bits, float k, float error_return)
2426 {
2427         float r;
2428         r = 0;
2429         while(k > 0 && bits != r)
2430         {
2431                 r += randombit(bits - r);
2432                 --k;
2433         }
2434         if(error_return)
2435                 if(k > 0)
2436                         return -1; // all
2437         return r;
2438 }
2439
2440 void randombit_test(float bits, float iter)
2441 {
2442         while(iter > 0)
2443         {
2444                 print(ftos(randombit(bits)), "\n");
2445                 --iter;
2446         }
2447 }
2448
2449 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2450 {
2451         if(halflifedist > 0)
2452                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2453         else if(halflifedist < 0)
2454                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2455         else
2456                 return 1;
2457 }
2458
2459
2460
2461
2462 #ifdef RELEASE
2463 #define cvar_string_normal builtin_cvar_string
2464 #define cvar_normal builtin_cvar
2465 #else
2466 string cvar_string_normal(string n)
2467 {
2468         if not(cvar_type(n) & 1)
2469                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2470         return builtin_cvar_string(n);
2471 }
2472
2473 float cvar_normal(string n)
2474 {
2475         return stof(cvar_string_normal(n));
2476 }
2477 #endif
2478 #define cvar_set_normal builtin_cvar_set
2479
2480 void defer_think()
2481 {
2482     entity oself;
2483
2484     oself           = self;
2485     self            = self.owner;
2486     oself.think     = SUB_Remove;
2487     oself.nextthink = time;
2488
2489     oself.use();
2490 }
2491
2492 /*
2493     Execute func() after time + fdelay.
2494     self when func is executed = self when defer is called
2495 */
2496 void defer(float fdelay, void() func)
2497 {
2498     entity e;
2499
2500     e           = spawn();
2501     e.owner     = self;
2502     e.use       = func;
2503     e.think     = defer_think;
2504     e.nextthink = time + fdelay;
2505 }
2506
2507 .string aiment_classname;
2508 .float aiment_deadflag;
2509 void SetMovetypeFollow(entity ent, entity e)
2510 {
2511         // FIXME this may not be warpzone aware
2512         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2513         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2514         ent.aiment = e; // make the hole follow bmodel
2515         ent.punchangle = e.angles; // the original angles of bmodel
2516         ent.view_ofs = ent.origin - e.origin; // relative origin
2517         ent.v_angle = ent.angles - e.angles; // relative angles
2518         ent.aiment_classname = strzone(e.classname);
2519         ent.aiment_deadflag = e.deadflag;
2520 }
2521 void UnsetMovetypeFollow(entity ent)
2522 {
2523         ent.movetype = MOVETYPE_FLY;
2524         PROJECTILE_MAKETRIGGER(ent);
2525         ent.aiment = world;
2526 }
2527 float LostMovetypeFollow(entity ent)
2528 {
2529 /*
2530         if(ent.movetype != MOVETYPE_FOLLOW)
2531                 if(ent.aiment)
2532                         error("???");
2533 */
2534         if(ent.aiment)
2535         {
2536                 if(ent.aiment.classname != ent.aiment_classname)
2537                         return 1;
2538                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2539                         return 1;
2540         }
2541         return 0;
2542 }
2543
2544 float isPushable(entity e)
2545 {
2546         if(e.iscreature)
2547                 return TRUE;
2548         if(e.pushable)
2549                 return TRUE;
2550         switch(e.classname)
2551         {
2552                 case "body":
2553                 case "droppedweapon":
2554                 case "keepawayball":
2555                 case "nexball_basketball":
2556                 case "nexball_football":
2557                         return TRUE;
2558                 case "bullet": // antilagged bullets can't hit this either
2559                         return FALSE;
2560         }
2561         if (e.projectiledeathtype)
2562                 return TRUE;
2563         return FALSE;
2564 }