qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 const float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = W_Name(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else replacement = "batteries"; // ;)
 363                 } else if (escape == "x") {
 364                         replacement = cursor_ent.netname;
 365                         if (replacement == "" || !cursor_ent)
 366                                 replacement = "nothing";
 367                 } else if (escape == "s")
 368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 369                 else if (escape == "S")
 370                         replacement = ftos(vlen(self.velocity));
 371
 372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 373                 p = p + strlen(replacement);
 374         }
 375         return msg;
 376 }
 377
 378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 379         return (value == 0) ? FALSE : TRUE;
 380 }
 381
 382 /*
 383 =============
 384 GetCvars
 385 =============
 386 Called with:
 387   0:  sends the request
 388   >0: receives a cvar from name=argv(f) value=argv(f+1)
 389 */
 390 void GetCvars_handleString(string thisname, float f, .string field, string name)
 391 {
 392         if (f < 0)
 393         {
 394                 if (self.field)
 395                         strunzone(self.field);
 396                 self.field = string_null;
 397         }
 398         else if (f > 0)
 399         {
 400                 if (thisname == name)
 401                 {
 402                         if (self.field)
 403                                 strunzone(self.field);
 404                         self.field = strzone(argv(f + 1));
 405                 }
 406         }
 407         else
 408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 409 }
 410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 411 {
 412         GetCvars_handleString(thisname, f, field, name);
 413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 414                 if (thisname == name)
 415                 {
 416                         string s;
 417                         s = func(strcat1(self.field));
 418                         if (s != self.field)
 419                         {
 420                                 strunzone(self.field);
 421                                 self.field = strzone(s);
 422                         }
 423                 }
 424 }
 425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 426 {
 427         if (f < 0)
 428         {
 429         }
 430         else if (f > 0)
 431         {
 432                 if (thisname == name)
 433                         self.field = stof(argv(f + 1));
 434         }
 435         else
 436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 437 }
 438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 439 {
 440         if (f < 0)
 441         {
 442         }
 443         else if (f > 0)
 444         {
 445                 if (thisname == name)
 446                 {
 447                         if(!self.field)
 448                         {
 449                                 self.field = stof(argv(f + 1));
 450                                 if(!self.field)
 451                                         self.field = -1;
 452                         }
 453                 }
 454         }
 455         else
 456         {
 457                 if(!self.field)
 458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 459         }
 460 }
 461 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 462 {
 463         string o;
 464         o = W_FixWeaponOrder_ForceComplete(wo);
 465         if(self.weaponorder_byimpulse)
 466         {
 467                 strunzone(self.weaponorder_byimpulse);
 468                 self.weaponorder_byimpulse = string_null;
 469         }
 470         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 471         return o;
 472 }
 473 void GetCvars(float f)
 474 {
 475         string s = string_null;
 476
 477         if (f > 0)
 478                 s = strcat1(argv(f));
 479
 480         get_cvars_f = f;
 481         get_cvars_s = s;
 482
 483         MUTATOR_CALLHOOK(GetCvars);
 484
 485         Notification_GetCvars();
 486
 487         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 488         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 489         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 490         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 491         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 492         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 504         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 505         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 506         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 508         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 510
 511         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 512         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 513
 514         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 515         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 516         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 517         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 518         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 519
 520         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 521         if (f > 0)
 522         {
 523                 if (s == "cl_weaponpriority")
 524                         self.switchweapon = w_getbestweapon(self);
 525                 if (s == "cl_allow_uidtracking")
 526                         PlayerStats_AddPlayer(self);
 527         }
 528 }
 529
 530 // decolorizes and team colors the player name when needed
 531 string playername(entity p)
 532 {
 533     string t;
 534     if (teamplay && !intermission_running && IS_PLAYER(p))
 535     {
 536         t = Team_ColorCode(p.team);
 537         return strcat(t, strdecolorize(p.netname));
 538     }
 539     else
 540         return p.netname;
 541 }
 542
 543 vector randompos(vector m1, vector m2)
 544 {
 545     vector v;
 546     m2 = m2 - m1;
 547     v_x = m2_x * random() + m1_x;
 548     v_y = m2_y * random() + m1_y;
 549     v_z = m2_z * random() + m1_z;
 550     return  v;
 551 }
 552
 553 //#NO AUTOCVARS START
 554
 555 float g_pickup_shells;
 556 float g_pickup_shells_max;
 557 float g_pickup_nails;
 558 float g_pickup_nails_max;
 559 float g_pickup_rockets;
 560 float g_pickup_rockets_max;
 561 float g_pickup_cells;
 562 float g_pickup_cells_max;
 563 float g_pickup_fuel;
 564 float g_pickup_fuel_jetpack;
 565 float g_pickup_fuel_max;
 566 float g_pickup_armorsmall;
 567 float g_pickup_armorsmall_max;
 568 float g_pickup_armorsmall_anyway;
 569 float g_pickup_armormedium;
 570 float g_pickup_armormedium_max;
 571 float g_pickup_armormedium_anyway;
 572 float g_pickup_armorbig;
 573 float g_pickup_armorbig_max;
 574 float g_pickup_armorbig_anyway;
 575 float g_pickup_armorlarge;
 576 float g_pickup_armorlarge_max;
 577 float g_pickup_armorlarge_anyway;
 578 float g_pickup_healthsmall;
 579 float g_pickup_healthsmall_max;
 580 float g_pickup_healthsmall_anyway;
 581 float g_pickup_healthmedium;
 582 float g_pickup_healthmedium_max;
 583 float g_pickup_healthmedium_anyway;
 584 float g_pickup_healthlarge;
 585 float g_pickup_healthlarge_max;
 586 float g_pickup_healthlarge_anyway;
 587 float g_pickup_healthmega;
 588 float g_pickup_healthmega_max;
 589 float g_pickup_healthmega_anyway;
 590 float g_pickup_ammo_anyway;
 591 float g_pickup_weapons_anyway;
 592 float g_weaponarena;
 593 WepSet g_weaponarena_weapons;
 594 float g_weaponarena_random;
 595 float g_weaponarena_random_with_laser;
 596 string g_weaponarena_list;
 597 float g_weaponspeedfactor;
 598 float g_weaponratefactor;
 599 float g_weapondamagefactor;
 600 float g_weaponforcefactor;
 601 float g_weaponspreadfactor;
 602
 603 WepSet start_weapons;
 604 WepSet start_weapons_default;
 605 WepSet start_weapons_defaultmask;
 606 float start_items;
 607 float start_ammo_shells;
 608 float start_ammo_nails;
 609 float start_ammo_rockets;
 610 float start_ammo_cells;
 611 float start_ammo_fuel;
 612 float start_health;
 613 float start_armorvalue;
 614 WepSet warmup_start_weapons;
 615 WepSet warmup_start_weapons_default;
 616 WepSet warmup_start_weapons_defaultmask;
 617 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 618 float warmup_start_ammo_shells;
 619 float warmup_start_ammo_nails;
 620 float warmup_start_ammo_rockets;
 621 float warmup_start_ammo_cells;
 622 float warmup_start_ammo_fuel;
 623 float warmup_start_health;
 624 float warmup_start_armorvalue;
 625 float g_weapon_stay;
 626
 627 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO
 628 {
 629         var float i = weaponinfo.weapon;
 630         var float d = 0;
 631
 632         if (!i)
 633                 return 0;
 634
 635         if (g_lms || g_ca || allguns)
 636         {
 637                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 638                         d = TRUE;
 639                 else
 640                         d = FALSE;
 641         }
 642         else if (g_cts)
 643                 d = (i == WEP_SHOCKWAVE); // WEAPONTODO: how to handle shotgun in CTS mode? we're replacing it.. so....
 644         else if (g_nexball)
 645                 d = 0; // weapon is set a few lines later
 646         else
 647                 d = !(!weaponinfo.weaponstart);
 648
 649         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 650                 d |= (i == WEP_HOOK);
 651         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 652                 d = 0;
 653
 654         var float t = weaponinfo.weaponstartoverride;
 655
 656         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 657
 658         // bit order in t:
 659         // 1: want or not
 660         // 2: is default?
 661         // 4: is set by default?
 662         if(t < 0)
 663                 t = 4 | (3 * d);
 664         else
 665                 t |= (2 * d);
 666
 667         return t;
 668 }
 669
 670 void readplayerstartcvars()
 671 {
 672         entity e;
 673         float i, j, t;
 674         string s;
 675
 676         // initialize starting values for players
 677         start_weapons = '0 0 0';
 678         start_weapons_default = '0 0 0';
 679         start_weapons_defaultmask = '0 0 0';
 680         start_items = 0;
 681         start_ammo_shells = 0;
 682         start_ammo_nails = 0;
 683         start_ammo_rockets = 0;
 684         start_ammo_cells = 0;
 685         start_health = cvar("g_balance_health_start");
 686         start_armorvalue = cvar("g_balance_armor_start");
 687
 688         g_weaponarena = 0;
 689         g_weaponarena_weapons = '0 0 0';
 690
 691         s = cvar_string("g_weaponarena");
 692         if (s == "0" || s == "")
 693         {
 694                 if(g_ca)
 695                         s = "most";
 696         }
 697
 698         if (s == "0" || s == "")
 699         {
 700                 // no arena
 701         }
 702         else if (s == "off")
 703         {
 704                 // forcibly turn off weaponarena
 705         }
 706         else if (s == "all")
 707         {
 708                 g_weaponarena = 1;
 709                 g_weaponarena_list = "All Weapons";
 710                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 711                 {
 712                         e = get_weaponinfo(j);
 713                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 714                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 715                 }
 716         }
 717         else if (s == "most")
 718         {
 719                 g_weaponarena = 1;
 720                 g_weaponarena_list = "Most Weapons";
 721                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 722                 {
 723                         e = get_weaponinfo(j);
 724                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 725                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 726                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 727                 }
 728         }
 729         else if (s == "none")
 730         {
 731                 g_weaponarena = 1;
 732                 g_weaponarena_list = "No Weapons";
 733         }
 734         else
 735         {
 736                 g_weaponarena = 1;
 737                 t = tokenize_console(s);
 738                 g_weaponarena_list = "";
 739                 for (i = 0; i < t; ++i)
 740                 {
 741                         s = argv(i);
 742                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 743                         {
 744                                 e = get_weaponinfo(j);
 745                                 if (e.netname == s)
 746                                 {
 747                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 748                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 749                                         break;
 750                                 }
 751                         }
 752                         if (j > WEP_LAST)
 753                         {
 754                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 755                         }
 756                 }
 757                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 758         }
 759
 760         if(g_weaponarena)
 761                 g_weaponarena_random = cvar("g_weaponarena_random");
 762         else
 763                 g_weaponarena_random = 0;
 764         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 765
 766         if (g_weaponarena)
 767         {
 768                 g_weapon_stay = 0; // incompatible
 769                 start_weapons = g_weaponarena_weapons;
 770                 start_items |= IT_UNLIMITED_AMMO;
 771         }
 772         else
 773         {
 774                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 775                 {
 776                         e = get_weaponinfo(i);
 777                         float w = want_weapon(e, FALSE);
 778                         if(w & 1)
 779                                 start_weapons |= WepSet_FromWeapon(i);
 780                         if(w & 2)
 781                                 start_weapons_default |= WepSet_FromWeapon(i);
 782                         if(w & 4)
 783                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 784                 }
 785         }
 786
 787         if(!cvar("g_use_ammunition"))
 788                 start_items |= IT_UNLIMITED_AMMO;
 789
 790         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 791         {
 792                 start_ammo_rockets = 999;
 793                 start_ammo_shells = 999;
 794                 start_ammo_cells = 999;
 795                 start_ammo_nails = 999;
 796                 start_ammo_fuel = 999;
 797         }
 798         else
 799         {
 800                 start_ammo_shells = cvar("g_start_ammo_shells");
 801                 start_ammo_nails = cvar("g_start_ammo_nails");
 802                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 803                 start_ammo_cells = cvar("g_start_ammo_cells");
 804                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 805         }
 806
 807         if (warmup_stage)
 808         {
 809                 warmup_start_ammo_shells = start_ammo_shells;
 810                 warmup_start_ammo_nails = start_ammo_nails;
 811                 warmup_start_ammo_rockets = start_ammo_rockets;
 812                 warmup_start_ammo_cells = start_ammo_cells;
 813                 warmup_start_ammo_fuel = start_ammo_fuel;
 814                 warmup_start_health = start_health;
 815                 warmup_start_armorvalue = start_armorvalue;
 816                 warmup_start_weapons = start_weapons;
 817                 warmup_start_weapons_default = start_weapons_default;
 818                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 819
 820                 if (!g_weaponarena && !g_ca)
 821                 {
 822                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 823                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 824                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 825                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 826                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 827                         warmup_start_health = cvar("g_warmup_start_health");
 828                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 829                         warmup_start_weapons = '0 0 0';
 830                         warmup_start_weapons_default = '0 0 0';
 831                         warmup_start_weapons_defaultmask = '0 0 0';
 832                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 833                         {
 834                                 e = get_weaponinfo(i);
 835                                 float w = want_weapon(e, g_warmup_allguns);
 836                                 if(w & 1)
 837                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 838                                 if(w & 2)
 839                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 840                                 if(w & 4)
 841                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 842                         }
 843                 }
 844         }
 845
 846         if (g_jetpack)
 847                 start_items |= IT_JETPACK;
 848
 849         MUTATOR_CALLHOOK(SetStartItems);
 850
 851         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 852         {
 853                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 854                 start_items |= IT_FUEL_REGEN;
 855                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 856                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 857         }
 858
 859         WepSet precache_weapons = start_weapons;
 860         if (g_warmup_allguns != 1)
 861                 precache_weapons |= warmup_start_weapons;
 862         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 863         {
 864                 e = get_weaponinfo(i);
 865                 if(precache_weapons & WepSet_FromWeapon(i))
 866                         WEP_ACTION(i, WR_INIT);
 867         }
 868
 869         start_ammo_shells = max(0, start_ammo_shells);
 870         start_ammo_nails = max(0, start_ammo_nails);
 871         start_ammo_cells = max(0, start_ammo_cells);
 872         start_ammo_rockets = max(0, start_ammo_rockets);
 873         start_ammo_fuel = max(0, start_ammo_fuel);
 874
 875         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 876         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 877         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 878         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 879         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 880 }
 881
 882 float g_bugrigs;
 883 float g_bugrigs_planar_movement;
 884 float g_bugrigs_planar_movement_car_jumping;
 885 float g_bugrigs_reverse_spinning;
 886 float g_bugrigs_reverse_speeding;
 887 float g_bugrigs_reverse_stopping;
 888 float g_bugrigs_air_steering;
 889 float g_bugrigs_angle_smoothing;
 890 float g_bugrigs_friction_floor;
 891 float g_bugrigs_friction_brake;
 892 float g_bugrigs_friction_air;
 893 float g_bugrigs_accel;
 894 float g_bugrigs_speed_ref;
 895 float g_bugrigs_speed_pow;
 896 float g_bugrigs_steer;
 897
 898 float sv_autotaunt;
 899 float sv_taunt;
 900
 901 string GetGametype(); // g_world.qc
 902 void readlevelcvars(void)
 903 {
 904         // load mutators
 905         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 906                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 907
 908         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 909         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, 1);
 910         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 911         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 912         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 913         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 914         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 915         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 916         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 917         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 918         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 919         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 921         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 922         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 923         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
 924         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
 925         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
 926         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 927         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
 928
 929         #undef CHECK_MUTATOR_ADD
 930
 931         if(cvar("sv_allow_fullbright"))
 932                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 933
 934     g_bugrigs = cvar("g_bugrigs");
 935     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 936     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 937     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 938     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 939     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 940     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 941     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 942     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 943     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 944     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 945     g_bugrigs_accel = cvar("g_bugrigs_accel");
 946     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 947     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 948     g_bugrigs_steer = cvar("g_bugrigs_steer");
 949
 950         g_minstagib = cvar("g_minstagib");
 951
 952         sv_clones = cvar("sv_clones");
 953         sv_foginterval = cvar("sv_foginterval");
 954         g_cloaked = cvar("g_cloaked");
 955     if(g_cts)
 956         g_cloaked = 1; // always enable cloak in CTS
 957         g_footsteps = cvar("g_footsteps");
 958         g_grappling_hook = cvar("g_grappling_hook");
 959         g_jetpack = cvar("g_jetpack");
 960         sv_maxidle = cvar("sv_maxidle");
 961         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 962         sv_autotaunt = cvar("sv_autotaunt");
 963         sv_taunt = cvar("sv_taunt");
 964
 965         warmup_stage = cvar("g_warmup");
 966         g_warmup_limit = cvar("g_warmup_limit");
 967         g_warmup_allguns = cvar("g_warmup_allguns");
 968         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 969
 970         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 971                 warmup_stage = 0; // these modes cannot work together, sorry
 972
 973         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 974         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 975         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 976         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 977         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 978         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 979         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 980         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 981         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 982         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 983         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 984         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 985         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 986         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 987
 988         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 989         g_weaponratefactor = cvar("g_weaponratefactor");
 990         g_weapondamagefactor = cvar("g_weapondamagefactor");
 991         g_weaponforcefactor = cvar("g_weaponforcefactor");
 992         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 993
 994         g_pickup_shells = cvar("g_pickup_shells");
 995         g_pickup_shells_max = cvar("g_pickup_shells_max");
 996         g_pickup_nails = cvar("g_pickup_nails");
 997         g_pickup_nails_max = cvar("g_pickup_nails_max");
 998         g_pickup_rockets = cvar("g_pickup_rockets");
 999         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1000         g_pickup_cells = cvar("g_pickup_cells");
1001         g_pickup_cells_max = cvar("g_pickup_cells_max");
1002         g_pickup_fuel = cvar("g_pickup_fuel");
1003         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1004         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1005         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1006         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1007         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1008         g_pickup_armormedium = cvar("g_pickup_armormedium");
1009         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1010         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1011         g_pickup_armorbig = cvar("g_pickup_armorbig");
1012         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1013         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1014         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1015         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1016         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1017         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1018         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1019         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1020         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1021         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1022         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1023         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1024         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1025         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1026         g_pickup_healthmega = cvar("g_pickup_healthmega");
1027         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1028         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1029
1030         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1031         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1032
1033     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1034     if(!g_weapon_stay)
1035         g_weapon_stay = cvar("g_weapon_stay");
1036
1037         if (!warmup_stage)
1038                 game_starttime = time + cvar("g_start_delay");
1039
1040         readplayerstartcvars();
1041 }
1042
1043 //#NO AUTOCVARS END
1044
1045 // Sound functions
1046 string precache_sound (string s) = #19;
1047 float precache_sound_index (string s) = #19;
1048
1049 #define SND_VOLUME      1
1050 #define SND_ATTENUATION 2
1051 #define SND_LARGEENTITY 8
1052 #define SND_LARGESOUND  16
1053
1054 float sound_allowed(float dest, entity e)
1055 {
1056     // sounds from world may always pass
1057     for (;;)
1058     {
1059         if (e.classname == "body")
1060             e = e.enemy;
1061         else if (e.realowner && e.realowner != e)
1062             e = e.realowner;
1063         else if (e.owner && e.owner != e)
1064             e = e.owner;
1065         else
1066             break;
1067     }
1068     // sounds to self may always pass
1069     if (dest == MSG_ONE)
1070         if (e == msg_entity)
1071             return TRUE;
1072     // sounds by players can be removed
1073     if (autocvar_bot_sound_monopoly)
1074         if (IS_REAL_CLIENT(e))
1075             return FALSE;
1076     // anything else may pass
1077     return TRUE;
1078 }
1079
1080 #ifdef COMPAT_XON010_CHANNELS
1081 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1082 void sound(entity e, float chan, string samp, float vol, float atten)
1083 {
1084     if (!sound_allowed(MSG_BROADCAST, e))
1085         return;
1086     builtin_sound(e, chan, samp, vol, atten);
1087 }
1088 #else
1089 #undef sound
1090 void sound(entity e, float chan, string samp, float vol, float atten)
1091 {
1092     if (!sound_allowed(MSG_BROADCAST, e))
1093         return;
1094     sound7(e, chan, samp, vol, atten, 0, 0);
1095 }
1096 #endif
1097
1098 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1099 {
1100     float entno, idx;
1101
1102     if (!sound_allowed(dest, e))
1103         return;
1104
1105     entno = num_for_edict(e);
1106     idx = precache_sound_index(samp);
1107
1108     float sflags;
1109     sflags = 0;
1110
1111     atten = floor(atten * 64);
1112     vol = floor(vol * 255);
1113
1114     if (vol != 255)
1115         sflags |= SND_VOLUME;
1116     if (atten != 64)
1117         sflags |= SND_ATTENUATION;
1118     if (entno >= 8192 || chan < 0 || chan > 7)
1119         sflags |= SND_LARGEENTITY;
1120     if (idx >= 256)
1121         sflags |= SND_LARGESOUND;
1122
1123     WriteByte(dest, SVC_SOUND);
1124     WriteByte(dest, sflags);
1125     if (sflags & SND_VOLUME)
1126         WriteByte(dest, vol);
1127     if (sflags & SND_ATTENUATION)
1128         WriteByte(dest, atten);
1129     if (sflags & SND_LARGEENTITY)
1130     {
1131         WriteShort(dest, entno);
1132         WriteByte(dest, chan);
1133     }
1134     else
1135     {
1136         WriteShort(dest, entno * 8 + chan);
1137     }
1138     if (sflags & SND_LARGESOUND)
1139         WriteShort(dest, idx);
1140     else
1141         WriteByte(dest, idx);
1142
1143     WriteCoord(dest, o_x);
1144     WriteCoord(dest, o_y);
1145     WriteCoord(dest, o_z);
1146 }
1147 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1148 {
1149     vector o;
1150
1151     if (!sound_allowed(dest, e))
1152         return;
1153
1154     o = e.origin + 0.5 * (e.mins + e.maxs);
1155     soundtoat(dest, e, o, chan, samp, vol, atten);
1156 }
1157 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1158 {
1159     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1160 }
1161 void stopsoundto(float dest, entity e, float chan)
1162 {
1163     float entno;
1164
1165     if (!sound_allowed(dest, e))
1166         return;
1167
1168     entno = num_for_edict(e);
1169
1170     if (entno >= 8192 || chan < 0 || chan > 7)
1171     {
1172         float idx, sflags;
1173         idx = precache_sound_index("misc/null.wav");
1174         sflags = SND_LARGEENTITY;
1175         if (idx >= 256)
1176             sflags |= SND_LARGESOUND;
1177         WriteByte(dest, SVC_SOUND);
1178         WriteByte(dest, sflags);
1179         WriteShort(dest, entno);
1180         WriteByte(dest, chan);
1181         if (sflags & SND_LARGESOUND)
1182             WriteShort(dest, idx);
1183         else
1184             WriteByte(dest, idx);
1185         WriteCoord(dest, e.origin_x);
1186         WriteCoord(dest, e.origin_y);
1187         WriteCoord(dest, e.origin_z);
1188     }
1189     else
1190     {
1191         WriteByte(dest, SVC_STOPSOUND);
1192         WriteShort(dest, entno * 8 + chan);
1193     }
1194 }
1195 void stopsound(entity e, float chan)
1196 {
1197     if (!sound_allowed(MSG_BROADCAST, e))
1198         return;
1199
1200     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1201     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1202 }
1203
1204 void play2(entity e, string filename)
1205 {
1206     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1207     msg_entity = e;
1208     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1209 }
1210
1211 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1212 .float spamtime;
1213 float spamsound(entity e, float chan, string samp, float vol, float atten)
1214 {
1215     if (!sound_allowed(MSG_BROADCAST, e))
1216         return FALSE;
1217
1218     if (time > e.spamtime)
1219     {
1220         e.spamtime = time;
1221         sound(e, chan, samp, vol, atten);
1222         return TRUE;
1223     }
1224     return FALSE;
1225 }
1226
1227 void play2team(float t, string filename)
1228 {
1229     entity head;
1230
1231     if (autocvar_bot_sound_monopoly)
1232         return;
1233
1234     FOR_EACH_REALPLAYER(head)
1235     {
1236         if (head.team == t)
1237             play2(head, filename);
1238     }
1239 }
1240
1241 void play2all(string samp)
1242 {
1243     if (autocvar_bot_sound_monopoly)
1244         return;
1245
1246     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1247 }
1248
1249 void PrecachePlayerSounds(string f);
1250 void precache_playermodel(string m)
1251 {
1252         float globhandle, i, n;
1253         string f;
1254
1255         if(substring(m, -9,5) == "_lod1")
1256                 return;
1257         if(substring(m, -9,5) == "_lod2")
1258                 return;
1259         precache_model(m);
1260         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1261         if(fexists(f))
1262                 precache_model(f);
1263         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1264         if(fexists(f))
1265                 precache_model(f);
1266
1267         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1268         if (globhandle < 0)
1269                 return;
1270         n = search_getsize(globhandle);
1271         for (i = 0; i < n; ++i)
1272         {
1273                 //print(search_getfilename(globhandle, i), "\n");
1274                 f = search_getfilename(globhandle, i);
1275                 PrecachePlayerSounds(f);
1276         }
1277         search_end(globhandle);
1278 }
1279 void precache_all_playermodels(string pattern)
1280 {
1281         float globhandle, i, n;
1282         string f;
1283
1284         globhandle = search_begin(pattern, TRUE, FALSE);
1285         if (globhandle < 0)
1286                 return;
1287         n = search_getsize(globhandle);
1288         for (i = 0; i < n; ++i)
1289         {
1290                 //print(search_getfilename(globhandle, i), "\n");
1291                 f = search_getfilename(globhandle, i);
1292                 precache_playermodel(f);
1293         }
1294         search_end(globhandle);
1295 }
1296
1297 void precache()
1298 {
1299     // gamemode related things
1300     precache_model ("models/misc/chatbubble.spr");
1301
1302 #ifdef TTURRETS_ENABLED
1303     if (autocvar_g_turrets)
1304         turrets_precash();
1305 #endif
1306
1307     // Precache all player models if desired
1308     if (autocvar_sv_precacheplayermodels)
1309     {
1310         PrecachePlayerSounds("sound/player/default.sounds");
1311         precache_all_playermodels("models/player/*.zym");
1312         precache_all_playermodels("models/player/*.dpm");
1313         precache_all_playermodels("models/player/*.md3");
1314         precache_all_playermodels("models/player/*.psk");
1315         precache_all_playermodels("models/player/*.iqm");
1316     }
1317
1318     if (autocvar_sv_defaultcharacter)
1319     {
1320         string s;
1321         s = autocvar_sv_defaultplayermodel_red;
1322         if (s != "")
1323             precache_playermodel(s);
1324         s = autocvar_sv_defaultplayermodel_blue;
1325         if (s != "")
1326             precache_playermodel(s);
1327         s = autocvar_sv_defaultplayermodel_yellow;
1328         if (s != "")
1329             precache_playermodel(s);
1330         s = autocvar_sv_defaultplayermodel_pink;
1331         if (s != "")
1332             precache_playermodel(s);
1333         s = autocvar_sv_defaultplayermodel;
1334         if (s != "")
1335             precache_playermodel(s);
1336     }
1337
1338     if (g_footsteps)
1339     {
1340         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1341         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1342     }
1343
1344     // gore and miscellaneous sounds
1345     //precache_sound ("misc/h2ohit.wav");
1346     precache_model ("models/hook.md3");
1347     precache_sound ("misc/armorimpact.wav");
1348     precache_sound ("misc/bodyimpact1.wav");
1349     precache_sound ("misc/bodyimpact2.wav");
1350     precache_sound ("misc/gib.wav");
1351     precache_sound ("misc/gib_splat01.wav");
1352     precache_sound ("misc/gib_splat02.wav");
1353     precache_sound ("misc/gib_splat03.wav");
1354     precache_sound ("misc/gib_splat04.wav");
1355     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1356     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1357     precache_sound ("misc/null.wav");
1358     precache_sound ("misc/spawn.wav");
1359     precache_sound ("misc/talk.wav");
1360     precache_sound ("misc/teleport.wav");
1361     precache_sound ("misc/poweroff.wav");
1362     precache_sound ("player/lava.wav");
1363     precache_sound ("player/slime.wav");
1364
1365     precache_model ("models/sprites/0.spr32");
1366     precache_model ("models/sprites/1.spr32");
1367     precache_model ("models/sprites/2.spr32");
1368     precache_model ("models/sprites/3.spr32");
1369     precache_model ("models/sprites/4.spr32");
1370     precache_model ("models/sprites/5.spr32");
1371     precache_model ("models/sprites/6.spr32");
1372     precache_model ("models/sprites/7.spr32");
1373     precache_model ("models/sprites/8.spr32");
1374     precache_model ("models/sprites/9.spr32");
1375     precache_model ("models/sprites/10.spr32");
1376
1377     // common weapon precaches
1378         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1379     precache_sound ("weapons/weapon_switch.wav");
1380     precache_sound ("weapons/weaponpickup.wav");
1381     precache_sound ("weapons/unavailable.wav");
1382     precache_sound ("weapons/dryfire.wav");
1383     if (g_grappling_hook)
1384     {
1385         precache_sound ("weapons/hook_fire.wav"); // hook
1386         precache_sound ("weapons/hook_impact.wav"); // hook
1387     }
1388
1389     precache_model("models/elaser.mdl");
1390     precache_model("models/laser.mdl");
1391     precache_model("models/ebomb.mdl");
1392
1393 #if 0
1394     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1395
1396     if (!self.noise && self.music) // quake 3 uses the music field
1397         self.noise = self.music;
1398
1399     // plays music for the level if there is any
1400     if (self.noise)
1401     {
1402         precache_sound (self.noise);
1403         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1404     }
1405 #endif
1406
1407 #include "precache-for-csqc.inc"
1408 }
1409
1410 // WARNING: this kills the trace globals
1411 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1412 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1413
1414 #define INITPRIO_FIRST              0
1415 #define INITPRIO_GAMETYPE           0
1416 #define INITPRIO_GAMETYPE_FALLBACK  1
1417 #define INITPRIO_FINDTARGET        10
1418 #define INITPRIO_DROPTOFLOOR       20
1419 #define INITPRIO_SETLOCATION       90
1420 #define INITPRIO_LINKDOORS         91
1421 #define INITPRIO_LAST              99
1422
1423 .void(void) initialize_entity;
1424 .float initialize_entity_order;
1425 .entity initialize_entity_next;
1426 entity initialize_entity_first;
1427
1428 void make_safe_for_remove(entity e)
1429 {
1430     if (e.initialize_entity)
1431     {
1432         entity ent, prev = world;
1433         for (ent = initialize_entity_first; ent; )
1434         {
1435             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1436             {
1437                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1438                 // skip it in linked list
1439                 if (prev)
1440                 {
1441                     prev.initialize_entity_next = ent.initialize_entity_next;
1442                     ent = prev.initialize_entity_next;
1443                 }
1444                 else
1445                 {
1446                     initialize_entity_first = ent.initialize_entity_next;
1447                     ent = initialize_entity_first;
1448                 }
1449             }
1450             else
1451             {
1452                 prev = ent;
1453                 ent = ent.initialize_entity_next;
1454             }
1455         }
1456     }
1457 }
1458
1459 void objerror(string s)
1460 {
1461     make_safe_for_remove(self);
1462     builtin_objerror(s);
1463 }
1464
1465 .float remove_except_protected_forbidden;
1466 void remove_except_protected(entity e)
1467 {
1468         if(e.remove_except_protected_forbidden)
1469                 error("not allowed to remove this at this point");
1470         builtin_remove(e);
1471 }
1472
1473 void remove_unsafely(entity e)
1474 {
1475     if(e.classname == "spike")
1476         error("Removing spikes is forbidden (crylink bug), please report");
1477     builtin_remove(e);
1478 }
1479
1480 void remove_safely(entity e)
1481 {
1482     make_safe_for_remove(e);
1483     builtin_remove(e);
1484 }
1485
1486 void InitializeEntity(entity e, void(void) func, float order)
1487 {
1488     entity prev, cur;
1489
1490     if (!e || e.initialize_entity)
1491     {
1492         // make a proxy initializer entity
1493         entity e_old;
1494         e_old = e;
1495         e = spawn();
1496         e.classname = "initialize_entity";
1497         e.enemy = e_old;
1498     }
1499
1500     e.initialize_entity = func;
1501     e.initialize_entity_order = order;
1502
1503     cur = initialize_entity_first;
1504     prev = world;
1505     for (;;)
1506     {
1507         if (!cur || cur.initialize_entity_order > order)
1508         {
1509             // insert between prev and cur
1510             if (prev)
1511                 prev.initialize_entity_next = e;
1512             else
1513                 initialize_entity_first = e;
1514             e.initialize_entity_next = cur;
1515             return;
1516         }
1517         prev = cur;
1518         cur = cur.initialize_entity_next;
1519     }
1520 }
1521 void InitializeEntitiesRun()
1522 {
1523     entity startoflist;
1524     startoflist = initialize_entity_first;
1525     initialize_entity_first = world;
1526     remove = remove_except_protected;
1527     for (self = startoflist; self; self = self.initialize_entity_next)
1528     {
1529         self.remove_except_protected_forbidden = 1;
1530     }
1531     for (self = startoflist; self; )
1532     {
1533         entity e;
1534         var void(void) func;
1535         e = self.initialize_entity_next;
1536         func = self.initialize_entity;
1537         self.initialize_entity_order = 0;
1538         self.initialize_entity = func_null;
1539         self.initialize_entity_next = world;
1540         self.remove_except_protected_forbidden = 0;
1541         if (self.classname == "initialize_entity")
1542         {
1543             entity e_old;
1544             e_old = self.enemy;
1545             builtin_remove(self);
1546             self = e_old;
1547         }
1548         //dprint("Delayed initialization: ", self.classname, "\n");
1549         if(func)
1550             func();
1551         else
1552         {
1553             eprint(self);
1554             backtrace(strcat("Null function in: ", self.classname, "\n"));
1555         }
1556         self = e;
1557     }
1558     remove = remove_unsafely;
1559 }
1560
1561 .float uncustomizeentityforclient_set;
1562 .void(void) uncustomizeentityforclient;
1563 void UncustomizeEntitiesRun()
1564 {
1565     entity oldself;
1566     oldself = self;
1567     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1568         self.uncustomizeentityforclient();
1569     self = oldself;
1570 }
1571 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1572 {
1573     e.customizeentityforclient = customizer;
1574     e.uncustomizeentityforclient = uncustomizer;
1575     e.uncustomizeentityforclient_set = !!uncustomizer;
1576 }
1577
1578 .float nottargeted;
1579 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1580
1581 void() SUB_Remove;
1582 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1583 {
1584     vector mi, ma;
1585
1586     if (e.classname == "")
1587         e.classname = "net_linked";
1588
1589     if (e.model == "" || self.modelindex == 0)
1590     {
1591         mi = e.mins;
1592         ma = e.maxs;
1593         setmodel(e, "null");
1594         setsize(e, mi, ma);
1595     }
1596
1597     e.SendEntity = sendfunc;
1598     e.SendFlags = 0xFFFFFF;
1599
1600     if (!docull)
1601         e.effects |= EF_NODEPTHTEST;
1602
1603     if (dt)
1604     {
1605         e.nextthink = time + dt;
1606         e.think = SUB_Remove;
1607     }
1608 }
1609
1610 void adaptor_think2touch()
1611 {
1612     entity o;
1613     o = other;
1614     other = world;
1615     self.touch();
1616     other = o;
1617 }
1618
1619 void adaptor_think2use()
1620 {
1621     entity o, a;
1622     o = other;
1623     a = activator;
1624     activator = world;
1625     other = world;
1626     self.use();
1627     other = o;
1628     activator = a;
1629 }
1630
1631 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1632 {
1633         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1634                 self.projectiledeathtype |= HITTYPE_SPLASH;
1635         adaptor_think2use();
1636 }
1637
1638 // deferred dropping
1639 void DropToFloor_Handler()
1640 {
1641     builtin_droptofloor();
1642     self.dropped_origin = self.origin;
1643 }
1644
1645 void droptofloor()
1646 {
1647     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1648 }
1649
1650
1651
1652 float trace_hits_box_a0, trace_hits_box_a1;
1653
1654 float trace_hits_box_1d(float end, float thmi, float thma)
1655 {
1656     if (end == 0)
1657     {
1658         // just check if x is in range
1659         if (0 < thmi)
1660             return FALSE;
1661         if (0 > thma)
1662             return FALSE;
1663     }
1664     else
1665     {
1666         // do the trace with respect to x
1667         // 0 -> end has to stay in thmi -> thma
1668         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1669         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1670         if (trace_hits_box_a0 > trace_hits_box_a1)
1671             return FALSE;
1672     }
1673     return TRUE;
1674 }
1675
1676 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1677 {
1678     end -= start;
1679     thmi -= start;
1680     thma -= start;
1681     // now it is a trace from 0 to end
1682
1683     trace_hits_box_a0 = 0;
1684     trace_hits_box_a1 = 1;
1685
1686     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1687         return FALSE;
1688     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1689         return FALSE;
1690     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1691         return FALSE;
1692
1693     return TRUE;
1694 }
1695
1696 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1697 {
1698     return trace_hits_box(start, end, thmi - ma, thma - mi);
1699 }
1700
1701 float SUB_NoImpactCheck()
1702 {
1703         // zero hitcontents = this is not the real impact, but either the
1704         // mirror-impact of something hitting the projectile instead of the
1705         // projectile hitting the something, or a touchareagrid one. Neither of
1706         // these stop the projectile from moving, so...
1707         if(trace_dphitcontents == 0)
1708         {
1709                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1710                 dprint(sprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin)));
1711                 checkclient();
1712         }
1713     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1714         return 1;
1715     if (other == world && self.size != '0 0 0')
1716     {
1717         vector tic;
1718         tic = self.velocity * sys_frametime;
1719         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1720         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1721         if (trace_fraction >= 1)
1722         {
1723             dprint("Odd... did not hit...?\n");
1724         }
1725         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1726         {
1727             dprint("Detected and prevented the sky-grapple bug.\n");
1728             return 1;
1729         }
1730     }
1731
1732     return 0;
1733 }
1734
1735 #define SUB_OwnerCheck() (other && (other == self.owner))
1736
1737 void RemoveGrapplingHook(entity pl);
1738 void W_Crylink_Dequeue(entity e);
1739 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1740 {
1741         if(SUB_OwnerCheck())
1742                 return TRUE;
1743         if(SUB_NoImpactCheck())
1744         {
1745                 if(self.classname == "grapplinghook")
1746                         RemoveGrapplingHook(self.realowner);
1747                 else if(self.classname == "spike")
1748                 {
1749                         W_Crylink_Dequeue(self);
1750                         remove(self);
1751                 }
1752                 else
1753                         remove(self);
1754                 return TRUE;
1755         }
1756         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1757                 UpdateCSQCProjectile(self);
1758         return FALSE;
1759 }
1760 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1761
1762 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1763 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1764
1765 void URI_Get_Callback(float id, float status, string data)
1766 {
1767         if(url_URI_Get_Callback(id, status, data))
1768         {
1769                 // handled
1770         }
1771         else if (id == URI_GET_DISCARD)
1772         {
1773                 // discard
1774         }
1775         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1776         {
1777                 // sv_cmd curl
1778                 Curl_URI_Get_Callback(id, status, data);
1779         }
1780         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1781         {
1782                 // online ban list
1783                 OnlineBanList_URI_Get_Callback(id, status, data);
1784         }
1785         else
1786         {
1787                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1788         }
1789 }
1790
1791 string uid2name(string myuid) {
1792         string s;
1793         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1794
1795         // FIXME remove this later after 0.6 release
1796         // convert old style broken records to correct style
1797         if(s == "")
1798         {
1799                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1800                 if(s != "")
1801                 {
1802                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1803                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1804                 }
1805         }
1806
1807         if(s == "")
1808                 s = "^1Unregistered Player";
1809         return s;
1810 }
1811
1812 float race_readTime(string map, float pos)
1813 {
1814         string rr;
1815         if(g_cts)
1816                 rr = CTS_RECORD;
1817         else
1818                 rr = RACE_RECORD;
1819
1820         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1821 }
1822
1823 string race_readUID(string map, float pos)
1824 {
1825         string rr;
1826         if(g_cts)
1827                 rr = CTS_RECORD;
1828         else
1829                 rr = RACE_RECORD;
1830
1831         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1832 }
1833
1834 float race_readPos(string map, float t) {
1835         float i;
1836         for (i = 1; i <= RANKINGS_CNT; ++i)
1837                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1838                         return i;
1839
1840         return 0; // pos is zero if unranked
1841 }
1842
1843 void race_writeTime(string map, float t, string myuid)
1844 {
1845         string rr;
1846         if(g_cts)
1847                 rr = CTS_RECORD;
1848         else
1849                 rr = RACE_RECORD;
1850
1851         float newpos;
1852         newpos = race_readPos(map, t);
1853
1854         float i, prevpos = 0;
1855         for(i = 1; i <= RANKINGS_CNT; ++i)
1856         {
1857                 if(race_readUID(map, i) == myuid)
1858                         prevpos = i;
1859         }
1860         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1861                 for (i = prevpos; i > newpos; --i) {
1862                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1863                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1864                 }
1865         } else { // player has no ranked record yet
1866                 for (i = RANKINGS_CNT; i > newpos; --i) {
1867                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1868                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1869                 }
1870         }
1871
1872         // store new time itself
1873         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1874         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1875 }
1876
1877 string race_readName(string map, float pos)
1878 {
1879         string rr;
1880         if(g_cts)
1881                 rr = CTS_RECORD;
1882         else
1883                 rr = RACE_RECORD;
1884
1885         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1886 }
1887
1888 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1889 {
1890     float m, i;
1891     vector start, org, delta, end, enddown, mstart;
1892     entity sp;
1893
1894     m = e.dphitcontentsmask;
1895     e.dphitcontentsmask = goodcontents | badcontents;
1896
1897     org = world.mins;
1898     delta = world.maxs - world.mins;
1899
1900     start = end = org;
1901
1902     for (i = 0; i < attempts; ++i)
1903     {
1904         start_x = org_x + random() * delta_x;
1905         start_y = org_y + random() * delta_y;
1906         start_z = org_z + random() * delta_z;
1907
1908         // rule 1: start inside world bounds, and outside
1909         // solid, and don't start from somewhere where you can
1910         // fall down to evil
1911         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1912         if (trace_fraction >= 1)
1913             continue;
1914         if (trace_startsolid)
1915             continue;
1916         if (trace_dphitcontents & badcontents)
1917             continue;
1918         if (trace_dphitq3surfaceflags & badsurfaceflags)
1919             continue;
1920
1921         // rule 2: if we are too high, lower the point
1922         if (trace_fraction * delta_z > maxaboveground)
1923             start = trace_endpos + '0 0 1' * maxaboveground;
1924         enddown = trace_endpos;
1925
1926         // rule 3: make sure we aren't outside the map. This only works
1927         // for somewhat well formed maps. A good rule of thumb is that
1928         // the map should have a convex outside hull.
1929         // these can be traceLINES as we already verified the starting box
1930         mstart = start + 0.5 * (e.mins + e.maxs);
1931         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1932         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1933             continue;
1934         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1935         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1936             continue;
1937         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1938         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1939             continue;
1940         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1941         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1942             continue;
1943         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1944         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1945             continue;
1946
1947         // rule 4: we must "see" some spawnpoint or item
1948         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1949                 if(checkpvs(mstart, sp))
1950                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1951                                 break;
1952         if(!sp)
1953         {
1954                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1955                         if(checkpvs(mstart, sp))
1956                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1957                                         break;
1958                 if(!sp)
1959                         continue;
1960         }
1961
1962         // find a random vector to "look at"
1963         end_x = org_x + random() * delta_x;
1964         end_y = org_y + random() * delta_y;
1965         end_z = org_z + random() * delta_z;
1966         end = start + normalize(end - start) * vlen(delta);
1967
1968         // rule 4: start TO end must not be too short
1969         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1970         if (trace_startsolid)
1971             continue;
1972         if (trace_fraction < minviewdistance / vlen(delta))
1973             continue;
1974
1975         // rule 5: don't want to look at sky
1976         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1977             continue;
1978
1979         // rule 6: we must not end up in trigger_hurt
1980         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1981             continue;
1982
1983         break;
1984     }
1985
1986     e.dphitcontentsmask = m;
1987
1988     if (i < attempts)
1989     {
1990         setorigin(e, start);
1991         e.angles = vectoangles(end - start);
1992         dprint("Needed ", ftos(i + 1), " attempts\n");
1993         return TRUE;
1994     }
1995     else
1996         return FALSE;
1997 }
1998
1999 float zcurveparticles_effectno;
2000 vector zcurveparticles_start;
2001 float zcurveparticles_spd;
2002
2003 void endzcurveparticles()
2004 {
2005         if(zcurveparticles_effectno)
2006         {
2007                 // terminator
2008                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2009         }
2010         zcurveparticles_effectno = 0;
2011 }
2012
2013 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2014 {
2015         spd = bound(0, floor(spd / 16), 32767);
2016         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2017         {
2018                 endzcurveparticles();
2019                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2020                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2021                 WriteShort(MSG_BROADCAST, effectno);
2022                 WriteCoord(MSG_BROADCAST, start_x);
2023                 WriteCoord(MSG_BROADCAST, start_y);
2024                 WriteCoord(MSG_BROADCAST, start_z);
2025                 zcurveparticles_effectno = effectno;
2026                 zcurveparticles_start = start;
2027         }
2028         else
2029                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2030         WriteCoord(MSG_BROADCAST, end_x);
2031         WriteCoord(MSG_BROADCAST, end_y);
2032         WriteCoord(MSG_BROADCAST, end_z);
2033         WriteCoord(MSG_BROADCAST, end_dz);
2034         zcurveparticles_spd = spd;
2035 }
2036
2037 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2038 {
2039         float end_dz;
2040         vector vecxy, velxy;
2041
2042         vecxy = end - start;
2043         vecxy_z = 0;
2044         velxy = vel;
2045         velxy_z = 0;
2046
2047         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2048         {
2049                 endzcurveparticles();
2050                 trailparticles(world, effectno, start, end);
2051                 return;
2052         }
2053
2054         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2055         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2056 }
2057
2058 void write_recordmarker(entity pl, float tstart, float dt)
2059 {
2060     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2061
2062     // also write a marker into demo files for demotc-race-record-extractor to find
2063     stuffcmd(pl,
2064              strcat(
2065                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2066                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2067 }
2068
2069 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2070 {
2071         switch(algn)
2072         {
2073                 default:
2074                 case 3: // right
2075                         break;
2076
2077                 case 4: // left
2078                         vecs_y = -vecs_y;
2079                         break;
2080
2081                 case 1:
2082                         if(allowcenter) // 2: allow center handedness
2083                         {
2084                                 // center
2085                                 vecs_y = 0;
2086                                 vecs_z -= 2;
2087                         }
2088                         else
2089                         {
2090                                 // right
2091                         }
2092                         break;
2093
2094                 case 2:
2095                         if(allowcenter) // 2: allow center handedness
2096                         {
2097                                 // center
2098                                 vecs_y = 0;
2099                                 vecs_z -= 2;
2100                         }
2101                         else
2102                         {
2103                                 // left
2104                                 vecs_y = -vecs_y;
2105                         }
2106                         break;
2107         }
2108         return vecs;
2109 }
2110
2111 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2112 {
2113         string s;
2114         vector v;
2115
2116         if (autocvar_g_shootfromeye)
2117         {
2118                 if (visual)
2119                 {
2120                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2121                         else { vecs_y = 0; vecs_z -= 2; }
2122                 }
2123                 else
2124                 {
2125                         vecs_y = 0;
2126                         vecs_z = 0;
2127                 }
2128         }
2129         else if (autocvar_g_shootfromcenter)
2130         {
2131                 vecs_y = 0;
2132                 vecs_z -= 2;
2133         }
2134         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2135         {
2136                 v = stov(s);
2137                 if (y_is_right)
2138                         v_y = -v_y;
2139                 if (v_x != 0)
2140                         vecs_x = v_x;
2141                 vecs_y = v_y;
2142                 vecs_z = v_z;
2143         }
2144         else if (autocvar_g_shootfromclient)
2145         {
2146                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2147         }
2148         return vecs;
2149 }
2150
2151 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2152 {
2153         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2154 }
2155
2156
2157 void attach_sameorigin(entity e, entity to, string tag)
2158 {
2159     vector org, t_forward, t_left, t_up, e_forward, e_up;
2160     float tagscale;
2161
2162     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2163     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2164     t_forward = v_forward * tagscale;
2165     t_left = v_right * -tagscale;
2166     t_up = v_up * tagscale;
2167
2168     e.origin_x = org * t_forward;
2169     e.origin_y = org * t_left;
2170     e.origin_z = org * t_up;
2171
2172     // current forward and up directions
2173     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2174                 e.angles = AnglesTransform_FromVAngles(e.angles);
2175         else
2176                 e.angles = AnglesTransform_FromAngles(e.angles);
2177     fixedmakevectors(e.angles);
2178
2179     // untransform forward, up!
2180     e_forward_x = v_forward * t_forward;
2181     e_forward_y = v_forward * t_left;
2182     e_forward_z = v_forward * t_up;
2183     e_up_x = v_up * t_forward;
2184     e_up_y = v_up * t_left;
2185     e_up_z = v_up * t_up;
2186
2187     e.angles = fixedvectoangles2(e_forward, e_up);
2188     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2189                 e.angles = AnglesTransform_ToVAngles(e.angles);
2190         else
2191                 e.angles = AnglesTransform_ToAngles(e.angles);
2192
2193     setattachment(e, to, tag);
2194     setorigin(e, e.origin);
2195 }
2196
2197 void detach_sameorigin(entity e)
2198 {
2199     vector org;
2200     org = gettaginfo(e, 0);
2201     e.angles = fixedvectoangles2(v_forward, v_up);
2202     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2203                 e.angles = AnglesTransform_ToVAngles(e.angles);
2204         else
2205                 e.angles = AnglesTransform_ToAngles(e.angles);
2206     setorigin(e, org);
2207     setattachment(e, world, "");
2208     setorigin(e, e.origin);
2209 }
2210
2211 void follow_sameorigin(entity e, entity to)
2212 {
2213     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2214     e.aiment = to; // make the hole follow bmodel
2215     e.punchangle = to.angles; // the original angles of bmodel
2216     e.view_ofs = e.origin - to.origin; // relative origin
2217     e.v_angle = e.angles - to.angles; // relative angles
2218 }
2219
2220 void unfollow_sameorigin(entity e)
2221 {
2222     e.movetype = MOVETYPE_NONE;
2223 }
2224
2225 entity gettaginfo_relative_ent;
2226 vector gettaginfo_relative(entity e, float tag)
2227 {
2228     if (!gettaginfo_relative_ent)
2229     {
2230         gettaginfo_relative_ent = spawn();
2231         gettaginfo_relative_ent.effects = EF_NODRAW;
2232     }
2233     gettaginfo_relative_ent.model = e.model;
2234     gettaginfo_relative_ent.modelindex = e.modelindex;
2235     gettaginfo_relative_ent.frame = e.frame;
2236     return gettaginfo(gettaginfo_relative_ent, tag);
2237 }
2238
2239 .float scale2;
2240
2241 float modeleffect_SendEntity(entity to, float sf)
2242 {
2243         float f;
2244         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2245
2246         f = 0;
2247         if(self.velocity != '0 0 0')
2248                 f |= 1;
2249         if(self.angles != '0 0 0')
2250                 f |= 2;
2251         if(self.avelocity != '0 0 0')
2252                 f |= 4;
2253
2254         WriteByte(MSG_ENTITY, f);
2255         WriteShort(MSG_ENTITY, self.modelindex);
2256         WriteByte(MSG_ENTITY, self.skin);
2257         WriteByte(MSG_ENTITY, self.frame);
2258         WriteCoord(MSG_ENTITY, self.origin_x);
2259         WriteCoord(MSG_ENTITY, self.origin_y);
2260         WriteCoord(MSG_ENTITY, self.origin_z);
2261         if(f & 1)
2262         {
2263                 WriteCoord(MSG_ENTITY, self.velocity_x);
2264                 WriteCoord(MSG_ENTITY, self.velocity_y);
2265                 WriteCoord(MSG_ENTITY, self.velocity_z);
2266         }
2267         if(f & 2)
2268         {
2269                 WriteCoord(MSG_ENTITY, self.angles_x);
2270                 WriteCoord(MSG_ENTITY, self.angles_y);
2271                 WriteCoord(MSG_ENTITY, self.angles_z);
2272         }
2273         if(f & 4)
2274         {
2275                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2276                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2277                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2278         }
2279         WriteShort(MSG_ENTITY, self.scale * 256.0);
2280         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2281         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2282         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2283         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2284
2285         return TRUE;
2286 }
2287
2288 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2289 {
2290         entity e;
2291         float sz;
2292         e = spawn();
2293         e.classname = "modeleffect";
2294         setmodel(e, m);
2295         e.frame = f;
2296         setorigin(e, o);
2297         e.velocity = v;
2298         e.angles = ang;
2299         e.avelocity = angv;
2300         e.alpha = a;
2301         e.teleport_time = t1;
2302         e.fade_time = t2;
2303         e.skin = s;
2304         if(s0 >= 0)
2305                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2306         else
2307                 e.scale = -s0;
2308         if(s2 >= 0)
2309                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2310         else
2311                 e.scale2 = -s2;
2312         sz = max(e.scale, e.scale2);
2313         setsize(e, e.mins * sz, e.maxs * sz);
2314         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2315 }
2316
2317 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2318 {
2319         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2320 }
2321
2322 float randombit(float bits)
2323 {
2324         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2325                 return bits;
2326
2327         float n, f, b, r;
2328
2329         r = random();
2330         b = 0;
2331         n = 0;
2332
2333         for(f = 1; f <= bits; f *= 2)
2334         {
2335                 if(bits & f)
2336                 {
2337                         ++n;
2338                         r *= n;
2339                         if(r <= 1)
2340                                 b = f;
2341                         else
2342                                 r = (r - 1) / (n - 1);
2343                 }
2344         }
2345
2346         return b;
2347 }
2348
2349 float randombits(float bits, float k, float error_return)
2350 {
2351         float r;
2352         r = 0;
2353         while(k > 0 && bits != r)
2354         {
2355                 r += randombit(bits - r);
2356                 --k;
2357         }
2358         if(error_return)
2359                 if(k > 0)
2360                         return -1; // all
2361         return r;
2362 }
2363
2364 void randombit_test(float bits, float iter)
2365 {
2366         while(iter > 0)
2367         {
2368                 print(ftos(randombit(bits)), "\n");
2369                 --iter;
2370         }
2371 }
2372
2373 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2374 {
2375         if(halflifedist > 0)
2376                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2377         else if(halflifedist < 0)
2378                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2379         else
2380                 return 1;
2381 }
2382
2383
2384
2385
2386 #ifdef RELEASE
2387 #define cvar_string_normal builtin_cvar_string
2388 #define cvar_normal builtin_cvar
2389 #else
2390 string cvar_string_normal(string n)
2391 {
2392         if (!(cvar_type(n) & 1))
2393                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2394         return builtin_cvar_string(n);
2395 }
2396
2397 float cvar_normal(string n)
2398 {
2399         return stof(cvar_string_normal(n));
2400 }
2401 #endif
2402 #define cvar_set_normal builtin_cvar_set
2403
2404 void defer_think()
2405 {
2406     entity oself;
2407
2408     oself           = self;
2409     self            = self.owner;
2410     oself.think     = SUB_Remove;
2411     oself.nextthink = time;
2412
2413     oself.use();
2414 }
2415
2416 /*
2417     Execute func() after time + fdelay.
2418     self when func is executed = self when defer is called
2419 */
2420 void defer(float fdelay, void() func)
2421 {
2422     entity e;
2423
2424     e           = spawn();
2425     e.owner     = self;
2426     e.use       = func;
2427     e.think     = defer_think;
2428     e.nextthink = time + fdelay;
2429 }
2430
2431 .string aiment_classname;
2432 .float aiment_deadflag;
2433 void SetMovetypeFollow(entity ent, entity e)
2434 {
2435         // FIXME this may not be warpzone aware
2436         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2437         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2438         ent.aiment = e; // make the hole follow bmodel
2439         ent.punchangle = e.angles; // the original angles of bmodel
2440         ent.view_ofs = ent.origin - e.origin; // relative origin
2441         ent.v_angle = ent.angles - e.angles; // relative angles
2442         ent.aiment_classname = strzone(e.classname);
2443         ent.aiment_deadflag = e.deadflag;
2444 }
2445 void UnsetMovetypeFollow(entity ent)
2446 {
2447         ent.movetype = MOVETYPE_FLY;
2448         PROJECTILE_MAKETRIGGER(ent);
2449         ent.aiment = world;
2450 }
2451 float LostMovetypeFollow(entity ent)
2452 {
2453 /*
2454         if(ent.movetype != MOVETYPE_FOLLOW)
2455                 if(ent.aiment)
2456                         error("???");
2457 */
2458         if(ent.aiment)
2459         {
2460                 if(ent.aiment.classname != ent.aiment_classname)
2461                         return 1;
2462                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2463                         return 1;
2464         }
2465         return 0;
2466 }
2467
2468 float isPushable(entity e)
2469 {
2470         if(e.iscreature)
2471                 return TRUE;
2472         if(e.pushable)
2473                 return TRUE;
2474         switch(e.classname)
2475         {
2476                 case "body":
2477                 case "droppedweapon":
2478                 case "keepawayball":
2479                 case "nexball_basketball":
2480                 case "nexball_football":
2481                         return TRUE;
2482                 case "bullet": // antilagged bullets can't hit this either
2483                         return FALSE;
2484         }
2485         if (e.projectiledeathtype)
2486                 return TRUE;
2487         return FALSE;
2488 }