qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include <server/mutators/_mod.qh>
   9 #include "../common/t_items.qh"
  10 #include "mapvoting.qh"
  11 #include "resources.qh"
  12 #include "items.qh"
  13 #include "player.qh"
  14 #include "weapons/accuracy.qh"
  15 #include "weapons/csqcprojectile.qh"
  16 #include "weapons/selection.qh"
  17 #include "../common/command/_mod.qh"
  18 #include "../common/constants.qh"
  19 #include <common/net_linked.qh>
  20 #include <common/weapons/weapon/crylink.qh>
  21 #include "../common/deathtypes/all.qh"
  22 #include "../common/mapinfo.qh"
  23 #include "../common/notifications/all.qh"
  24 #include "../common/playerstats.qh"
  25 #include "../common/teams.qh"
  26 #include "../common/mapobjects/subs.qh"
  27 #include "../common/util.qh"
  28 #include "../common/turrets/sv_turrets.qh"
  29 #include <common/weapons/_all.qh>
  30 #include "../common/vehicles/sv_vehicles.qh"
  31 #include "../common/vehicles/vehicle.qh"
  32 #include "../common/items/_mod.qh"
  33 #include "../common/state.qh"
  34 #include "../common/effects/qc/globalsound.qh"
  35 #include "../common/wepent.qh"
  36 #include <common/weapons/weapon.qh>
  37 #include "../lib/csqcmodel/sv_model.qh"
  38 #include "../lib/warpzone/anglestransform.qh"
  39 #include "../lib/warpzone/server.qh"
  40
  41 void crosshair_trace(entity pl)
  42 {
  43         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  44 }
  45
  46 void crosshair_trace_plusvisibletriggers(entity pl)
  47 {
  48         crosshair_trace_plusvisibletriggers__is_wz(pl, false);
  49 }
  50
  51 void WarpZone_crosshair_trace_plusvisibletriggers(entity pl)
  52 {
  53         crosshair_trace_plusvisibletriggers__is_wz(pl, true);
  54 }
  55
  56 void crosshair_trace_plusvisibletriggers__is_wz(entity pl, bool is_wz)
  57 {
  58         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  59         {
  60                 if(it.model != "")
  61                 {
  62                         it.solid = SOLID_BSP;
  63                         IL_PUSH(g_ctrace_changed, it);
  64                 }
  65         });
  66
  67         if (is_wz)
  68                 WarpZone_crosshair_trace(pl);
  69         else
  70                 crosshair_trace(pl);
  71
  72         IL_EACH(g_ctrace_changed, true, { it.solid = SOLID_TRIGGER; });
  73
  74         IL_CLEAR(g_ctrace_changed);
  75 }
  76
  77 void WarpZone_crosshair_trace(entity pl)
  78 {
  79         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  80 }
  81
  82 void dedicated_print(string input)
  83 {
  84         if (server_is_dedicated) print(input);
  85 }
  86
  87 string GameLog_ProcessIP(string s)
  88 {
  89         return strreplace(":", autocvar_sv_eventlog_ipv6_delimiter, s);
  90 }
  91
  92 void GameLogEcho(string s)
  93 {
  94     string fn;
  95     int matches;
  96
  97     if (autocvar_sv_eventlog_files)
  98     {
  99         if (!logfile_open)
 100         {
 101             logfile_open = true;
 102             matches = autocvar_sv_eventlog_files_counter + 1;
 103             cvar_set("sv_eventlog_files_counter", itos(matches));
 104             fn = ftos(matches);
 105             if (strlen(fn) < 8)
 106                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 107             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 108             logfile = fopen(fn, FILE_APPEND);
 109             fputs(logfile, ":logversion:3\n");
 110         }
 111         if (logfile >= 0)
 112         {
 113             if (autocvar_sv_eventlog_files_timestamps)
 114                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 115             else
 116                 fputs(logfile, strcat(s, "\n"));
 117         }
 118     }
 119     if (autocvar_sv_eventlog_console)
 120     {
 121         dedicated_print(strcat(s, "\n"));
 122     }
 123 }
 124
 125 void GameLogInit()
 126 {
 127     logfile_open = 0;
 128     // will be opened later
 129 }
 130
 131 void GameLogClose()
 132 {
 133     if (logfile_open && logfile >= 0)
 134     {
 135         fclose(logfile);
 136         logfile = -1;
 137     }
 138 }
 139
 140 entity findnearest(vector point, bool checkitems, vector axismod)
 141 {
 142     vector dist;
 143     int num_nearest = 0;
 144
 145     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 146     {
 147         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 148             dist = it.oldorigin;
 149         else
 150             dist = it.origin;
 151         dist = dist - point;
 152         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 153         float len = vlen2(dist);
 154
 155         int l;
 156         for (l = 0; l < num_nearest; ++l)
 157         {
 158             if (len < nearest_length[l])
 159                 break;
 160         }
 161
 162         // now i tells us where to insert at
 163         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 164         if (l < NUM_NEAREST_ENTITIES)
 165         {
 166             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 167             {
 168                 nearest_length[j + 1] = nearest_length[j];
 169                 nearest_entity[j + 1] = nearest_entity[j];
 170             }
 171             nearest_length[l] = len;
 172             nearest_entity[l] = it;
 173             if (num_nearest < NUM_NEAREST_ENTITIES)
 174                 num_nearest = num_nearest + 1;
 175         }
 176     });
 177
 178     // now use the first one from our list that we can see
 179     for (int j = 0; j < num_nearest; ++j)
 180     {
 181         traceline(point, nearest_entity[j].origin, true, NULL);
 182         if (trace_fraction == 1)
 183         {
 184             if (j != 0)
 185                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 186             return nearest_entity[j];
 187         }
 188     }
 189
 190     if (num_nearest == 0)
 191         return NULL;
 192
 193     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 194     /* DEBUGGING CODE:
 195     dprint("Candidates were: ");
 196     for(j = 0; j < num_nearest; ++j)
 197     {
 198         if(j != 0)
 199                 dprint(", ");
 200         dprint(nearest_entity[j].netname);
 201     }
 202     dprint("\n");
 203     */
 204
 205     return nearest_entity[0];
 206 }
 207
 208 string NearestLocation(vector p)
 209 {
 210     string ret = "somewhere";
 211     entity loc = findnearest(p, false, '1 1 1');
 212     if (loc)
 213         ret = loc.message;
 214     else
 215     {
 216         loc = findnearest(p, true, '1 1 4');
 217         if (loc)
 218             ret = loc.netname;
 219     }
 220     return ret;
 221 }
 222
 223 string PlayerHealth(entity this)
 224 {
 225         float myhealth = floor(GetResource(this, RES_HEALTH));
 226         if(myhealth == -666)
 227                 return "spectating";
 228         else if(myhealth == -2342 || (myhealth == 2342 && mapvote_initialized))
 229                 return "observing";
 230         else if(myhealth <= 0 || IS_DEAD(this))
 231                 return "dead";
 232         return ftos(myhealth);
 233 }
 234
 235 string WeaponNameFromWeaponentity(entity this, .entity weaponentity)
 236 {
 237         entity wepent = this.(weaponentity);
 238         if(!wepent)
 239                 return "none";
 240         else if(wepent.m_weapon != WEP_Null)
 241                 return wepent.m_weapon.m_name;
 242         else if(wepent.m_switchweapon != WEP_Null)
 243                 return wepent.m_switchweapon.m_name;
 244         return "none"; //Weapons_from(wepent.cnt).m_name;
 245 }
 246
 247 string formatmessage(entity this, string msg)
 248 {
 249         float p, p1, p2;
 250         float n;
 251         vector cursor = '0 0 0';
 252         entity cursor_ent = NULL;
 253         string escape;
 254         string replacement;
 255         p = 0;
 256         n = 7;
 257         bool traced = false;
 258
 259         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 260         msg = M_ARGV(1, string);
 261
 262         while (1) {
 263                 if (n < 1)
 264                         break; // too many replacements
 265
 266                 n = n - 1;
 267                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 268                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 269
 270                 if (p1 < 0)
 271                         p1 = p2;
 272
 273                 if (p2 < 0)
 274                         p2 = p1;
 275
 276                 p = min(p1, p2);
 277
 278                 if (p < 0)
 279                         break;
 280
 281                 if(!traced)
 282                 {
 283                         WarpZone_crosshair_trace_plusvisibletriggers(this);
 284                         cursor = trace_endpos;
 285                         cursor_ent = trace_ent;
 286                         traced = true;
 287                 }
 288
 289                 replacement = substring(msg, p, 2);
 290                 escape = substring(msg, p + 1, 1);
 291
 292                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 293
 294                 switch(escape)
 295                 {
 296                         case "%": replacement = "%"; break;
 297                         case "\\":replacement = "\\"; break;
 298                         case "n": replacement = "\n"; break;
 299                         case "a": replacement = ftos(floor(GetResource(this, RES_ARMOR))); break;
 300                         case "h": replacement = PlayerHealth(this); break;
 301                         case "l": replacement = NearestLocation(this.origin); break;
 302                         case "y": replacement = NearestLocation(cursor); break;
 303                         case "d": replacement = NearestLocation(this.death_origin); break;
 304                         case "w": replacement = WeaponNameFromWeaponentity(this, weaponentity); break;
 305                         case "W": replacement = GetAmmoName(this.(weaponentity).m_weapon.ammo_type); break;
 306                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 307                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 308                         case "S": replacement = ftos(vlen(this.velocity)); break;
 309                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 310                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 311                         default:
 312                         {
 313                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 314                                 replacement = M_ARGV(2, string);
 315                                 break;
 316                         }
 317                 }
 318
 319                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 320                 p = p + strlen(replacement);
 321         }
 322         return msg;
 323 }
 324
 325 /*
 326 =============
 327 GetCvars
 328 =============
 329 Called with:
 330   0:  sends the request
 331   >0: receives a cvar from name=argv(f) value=argv(f+1)
 332 */
 333 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 334 {
 335         if (f < 0)
 336         {
 337                 strfree(store.(field));
 338         }
 339         else if (f > 0)
 340         {
 341                 if (thisname == name)
 342                 {
 343                         strcpy(store.(field), argv(f + 1));
 344                 }
 345         }
 346         else
 347                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 348 }
 349 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 350 {
 351         GetCvars_handleString(this, store, thisname, f, field, name);
 352         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 353                 if (thisname == name)
 354                 {
 355                         string s = func(this, strcat1(store.(field)));
 356                         if (s != store.(field))
 357                         {
 358                                 strcpy(store.(field), s);
 359                         }
 360                 }
 361 }
 362 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 363 {
 364         if (f < 0)
 365         {
 366         }
 367         else if (f > 0)
 368         {
 369                 if (thisname == name)
 370                         store.(field) = stof(argv(f + 1));
 371         }
 372         else
 373                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 374 }
 375 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 376 {
 377         if (f < 0)
 378         {
 379         }
 380         else if (f > 0)
 381         {
 382                 if (thisname == name)
 383                 {
 384                         if (!store.(field))
 385                         {
 386                                 store.(field) = stof(argv(f + 1));
 387                                 if (!store.(field))
 388                                         store.(field) = -1;
 389                         }
 390                 }
 391         }
 392         else
 393         {
 394                 if (!store.(field))
 395                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 396         }
 397 }
 398 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 399 {
 400         string o = W_FixWeaponOrder_ForceComplete(wo);
 401         strcpy(CS(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 402         return o;
 403 }
 404
 405 REPLICATE(autoswitch, bool, "cl_autoswitch");
 406
 407 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 408
 409 REPLICATE(cvar_cl_allow_uidranking, bool, "cl_allow_uidranking");
 410
 411 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 412
 413 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 414
 415 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 416
 417 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 418
 419 REPLICATE(cvar_cl_gunalign, int, "cl_gunalign");
 420
 421 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 422
 423 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 424
 425 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 426
 427 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 428
 429 REPLICATE(cvar_cl_physics, string, "cl_physics");
 430
 431 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 432
 433 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 434
 435 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 436
 437 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 438
 439 REPLICATE(cvar_cl_cts_noautoswitch, bool, "cl_cts_noautoswitch");
 440
 441 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 442
 443 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 444
 445 /**
 446  * @param f -1: cleanup, 0: request, 1: receive
 447  */
 448 void GetCvars(entity this, entity store, int f)
 449 {
 450         string s = string_null;
 451
 452         if (f == 0)
 453                 LOG_INFO("Warning: requesting cvar values is deprecated. Client should send them automatically using REPLICATE.\n");
 454
 455         if (f > 0)
 456                 s = strcat1(argv(f));
 457
 458         get_cvars_f = f;
 459         get_cvars_s = s;
 460         MUTATOR_CALLHOOK(GetCvars);
 461
 462         Notification_GetCvars(this);
 463
 464         ReplicateVars(this, store, s, f);
 465
 466         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 467         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 468         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 469         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 470         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 471         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 472         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 473         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 474         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 475         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 476         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 477
 478         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 479
 480         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 481         if (f > 0)
 482         {
 483                 if (s == "cl_weaponpriority")
 484                 {
 485                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 486                         {
 487                                 .entity weaponentity = weaponentities[slot];
 488                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 489                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 490                         }
 491                 }
 492                 if (s == "cl_allow_uidtracking")
 493                         PlayerStats_GameReport_AddPlayer(this);
 494                 //if (s == "cl_gunalign")
 495                         //W_ResetGunAlign(this, store.cvar_cl_gunalign);
 496         }
 497 }
 498
 499 // decolorizes and team colors the player name when needed
 500 string playername(entity p, bool team_colorize)
 501 {
 502     string t;
 503     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 504     {
 505         t = Team_ColorCode(p.team);
 506         return strcat(t, strdecolorize(p.netname));
 507     }
 508     else
 509         return p.netname;
 510 }
 511
 512 float want_weapon(entity weaponinfo, float allguns)
 513 {
 514         int d = 0;
 515         bool allow_mutatorblocked = false;
 516
 517         if(!weaponinfo.m_id)
 518                 return 0;
 519
 520         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 521         d = M_ARGV(1, float);
 522         allguns = M_ARGV(2, bool);
 523         allow_mutatorblocked = M_ARGV(3, bool);
 524
 525         if(allguns)
 526                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
 527         else if(!mutator_returnvalue)
 528                 d = !(!weaponinfo.weaponstart);
 529
 530         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 531                 d = 0;
 532
 533         float t = weaponinfo.weaponstartoverride;
 534
 535         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
 536
 537         // bit order in t:
 538         // 1: want or not
 539         // 2: is default?
 540         // 4: is set by default?
 541         if(t < 0)
 542                 t = 4 | (3 * d);
 543         else
 544                 t |= (2 * d);
 545
 546         return t;
 547 }
 548
 549 /// Weapons the player normally starts with outside weapon arena.
 550 WepSet weapons_start()
 551 {
 552         WepSet ret = '0 0 0';
 553         FOREACH(Weapons, it != WEP_Null, {
 554                 int w = want_weapon(it, false);
 555                 if (w & 1)
 556                         ret |= it.m_wepset;
 557         });
 558         return ret;
 559 }
 560
 561 WepSet weapons_all()
 562 {
 563         WepSet ret = '0 0 0';
 564         FOREACH(Weapons, it != WEP_Null, {
 565                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
 566                         ret |= it.m_wepset;
 567         });
 568         return ret;
 569 }
 570
 571 WepSet weapons_devall()
 572 {
 573         WepSet ret = '0 0 0';
 574         FOREACH(Weapons, it != WEP_Null,
 575         {
 576                 ret |= it.m_wepset;
 577         });
 578         return ret;
 579 }
 580
 581 WepSet weapons_most()
 582 {
 583         WepSet ret = '0 0 0';
 584         FOREACH(Weapons, it != WEP_Null, {
 585                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
 586                         ret |= it.m_wepset;
 587         });
 588         return ret;
 589 }
 590
 591 void weaponarena_available_all_update(entity this)
 592 {
 593         if (weaponsInMapAll)
 594         {
 595                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
 596         }
 597         else
 598         {
 599                 // if no weapons are available on the map, just fall back to all weapons arena
 600                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
 601         }
 602 }
 603
 604 void weaponarena_available_devall_update(entity this)
 605 {
 606         if (weaponsInMapAll)
 607         {
 608                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
 609         }
 610         else
 611         {
 612                 // if no weapons are available on the map, just fall back to devall weapons arena
 613                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
 614         }
 615 }
 616
 617 void weaponarena_available_most_update(entity this)
 618 {
 619         if (weaponsInMapAll)
 620         {
 621                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
 622         }
 623         else
 624         {
 625                 // if no weapons are available on the map, just fall back to most weapons arena
 626                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
 627         }
 628 }
 629
 630 void readplayerstartcvars()
 631 {
 632         // initialize starting values for players
 633         start_weapons = '0 0 0';
 634         start_weapons_default = '0 0 0';
 635         start_weapons_defaultmask = '0 0 0';
 636         start_items = 0;
 637         start_ammo_shells = 0;
 638         start_ammo_nails = 0;
 639         start_ammo_rockets = 0;
 640         start_ammo_cells = 0;
 641         start_ammo_plasma = 0;
 642         if (random_start_ammo == NULL)
 643         {
 644                 random_start_ammo = spawn();
 645         }
 646         start_health = cvar("g_balance_health_start");
 647         start_armorvalue = cvar("g_balance_armor_start");
 648
 649         g_weaponarena = 0;
 650         g_weaponarena_weapons = '0 0 0';
 651
 652         string s = cvar_string("g_weaponarena");
 653
 654         MUTATOR_CALLHOOK(SetWeaponArena, s);
 655         s = M_ARGV(0, string);
 656
 657         if (s == "0" || s == "")
 658         {
 659                 // no arena
 660         }
 661         else if (s == "off")
 662         {
 663                 // forcibly turn off weaponarena
 664         }
 665         else if (s == "all" || s == "1")
 666         {
 667                 g_weaponarena = 1;
 668                 g_weaponarena_list = "All Weapons";
 669                 g_weaponarena_weapons = weapons_all();
 670         }
 671         else if (s == "devall")
 672         {
 673                 g_weaponarena = 1;
 674                 g_weaponarena_list = "Dev All Weapons";
 675                 g_weaponarena_weapons = weapons_devall();
 676         }
 677         else if (s == "most")
 678         {
 679                 g_weaponarena = 1;
 680                 g_weaponarena_list = "Most Weapons";
 681                 g_weaponarena_weapons = weapons_most();
 682         }
 683         else if (s == "all_available")
 684         {
 685                 g_weaponarena = 1;
 686                 g_weaponarena_list = "All Available Weapons";
 687
 688                 // this needs to run after weaponsInMapAll is initialized
 689                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
 690         }
 691         else if (s == "devall_available")
 692         {
 693                 g_weaponarena = 1;
 694                 g_weaponarena_list = "Dev All Available Weapons";
 695
 696                 // this needs to run after weaponsInMapAll is initialized
 697                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
 698         }
 699         else if (s == "most_available")
 700         {
 701                 g_weaponarena = 1;
 702                 g_weaponarena_list = "Most Available Weapons";
 703
 704                 // this needs to run after weaponsInMapAll is initialized
 705                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
 706         }
 707         else if (s == "none")
 708         {
 709                 g_weaponarena = 1;
 710                 g_weaponarena_list = "No Weapons";
 711         }
 712         else
 713         {
 714                 g_weaponarena = 1;
 715                 float t = tokenize_console(s);
 716                 g_weaponarena_list = "";
 717                 for (int j = 0; j < t; ++j)
 718                 {
 719                         s = argv(j);
 720                         Weapon wep = Weapons_fromstr(s);
 721                         if(wep != WEP_Null)
 722                         {
 723                                 g_weaponarena_weapons |= (wep.m_wepset);
 724                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
 725                         }
 726                 }
 727                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 728         }
 729
 730         if (g_weaponarena)
 731         {
 732                 g_weapon_stay = 0; // incompatible
 733                 start_weapons = g_weaponarena_weapons;
 734                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
 735         }
 736         else
 737         {
 738                 FOREACH(Weapons, it != WEP_Null, {
 739                         int w = want_weapon(it, false);
 740                         WepSet s = it.m_wepset;
 741                         if(w & 1)
 742                                 start_weapons |= s;
 743                         if(w & 2)
 744                                 start_weapons_default |= s;
 745                         if(w & 4)
 746                                 start_weapons_defaultmask |= s;
 747                 });
 748         }
 749
 750         if(cvar("g_balance_superweapons_time") < 0)
 751                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 752
 753         if(!cvar("g_use_ammunition"))
 754                 start_items |= IT_UNLIMITED_AMMO;
 755
 756         if(start_items & IT_UNLIMITED_AMMO)
 757         {
 758                 start_ammo_shells = 999;
 759                 start_ammo_nails = 999;
 760                 start_ammo_rockets = 999;
 761                 start_ammo_cells = 999;
 762                 start_ammo_plasma = 999;
 763                 start_ammo_fuel = 999;
 764         }
 765         else
 766         {
 767                 start_ammo_shells = cvar("g_start_ammo_shells");
 768                 start_ammo_nails = cvar("g_start_ammo_nails");
 769                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 770                 start_ammo_cells = cvar("g_start_ammo_cells");
 771                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 772                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 773                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 774                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
 775                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
 776                 SetResource(random_start_ammo, RES_ROCKETS,cvar("g_random_start_rockets"));
 777                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
 778                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
 779         }
 780
 781         warmup_start_ammo_shells = start_ammo_shells;
 782         warmup_start_ammo_nails = start_ammo_nails;
 783         warmup_start_ammo_rockets = start_ammo_rockets;
 784         warmup_start_ammo_cells = start_ammo_cells;
 785         warmup_start_ammo_plasma = start_ammo_plasma;
 786         warmup_start_ammo_fuel = start_ammo_fuel;
 787         warmup_start_health = start_health;
 788         warmup_start_armorvalue = start_armorvalue;
 789         warmup_start_weapons = start_weapons;
 790         warmup_start_weapons_default = start_weapons_default;
 791         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 792
 793         if (!g_weaponarena)
 794         {
 795                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 796                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 797                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 798                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 799                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 800                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 801                 warmup_start_health = cvar("g_warmup_start_health");
 802                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
 803                 warmup_start_weapons = '0 0 0';
 804                 warmup_start_weapons_default = '0 0 0';
 805                 warmup_start_weapons_defaultmask = '0 0 0';
 806                 FOREACH(Weapons, it != WEP_Null, {
 807                         int w = want_weapon(it, g_warmup_allguns);
 808                         WepSet s = it.m_wepset;
 809                         if(w & 1)
 810                                 warmup_start_weapons |= s;
 811                         if(w & 2)
 812                                 warmup_start_weapons_default |= s;
 813                         if(w & 4)
 814                                 warmup_start_weapons_defaultmask |= s;
 815                 });
 816         }
 817
 818         if (g_jetpack)
 819                 start_items |= ITEM_Jetpack.m_itemid;
 820
 821         MUTATOR_CALLHOOK(SetStartItems);
 822
 823         if (start_items & ITEM_Jetpack.m_itemid)
 824         {
 825                 start_items |= ITEM_JetpackRegen.m_itemid;
 826                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 827                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 828         }
 829
 830         start_ammo_shells = max(0, start_ammo_shells);
 831         start_ammo_nails = max(0, start_ammo_nails);
 832         start_ammo_rockets = max(0, start_ammo_rockets);
 833         start_ammo_cells = max(0, start_ammo_cells);
 834         start_ammo_plasma = max(0, start_ammo_plasma);
 835         start_ammo_fuel = max(0, start_ammo_fuel);
 836         SetResource(random_start_ammo, RES_SHELLS,
 837                 max(0, GetResource(random_start_ammo, RES_SHELLS)));
 838         SetResource(random_start_ammo, RES_BULLETS,
 839                 max(0, GetResource(random_start_ammo, RES_BULLETS)));
 840         SetResource(random_start_ammo, RES_ROCKETS,
 841                 max(0, GetResource(random_start_ammo, RES_ROCKETS)));
 842         SetResource(random_start_ammo, RES_CELLS,
 843                 max(0, GetResource(random_start_ammo, RES_CELLS)));
 844         SetResource(random_start_ammo, RES_PLASMA,
 845                 max(0, GetResource(random_start_ammo, RES_PLASMA)));
 846
 847         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 848         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 849         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 850         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 851         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 852         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 853 }
 854
 855 void precache_playermodel(string m)
 856 {
 857         float globhandle, i, n;
 858         string f;
 859
 860         if(substring(m, -9, 5) == "_lod1")
 861                 return;
 862         if(substring(m, -9, 5) == "_lod2")
 863                 return;
 864         precache_model(m);
 865         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 866         if(fexists(f))
 867                 precache_model(f);
 868         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 869         if(fexists(f))
 870                 precache_model(f);
 871
 872         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 873         if (globhandle < 0)
 874                 return;
 875         n = search_getsize(globhandle);
 876         for (i = 0; i < n; ++i)
 877         {
 878                 //print(search_getfilename(globhandle, i), "\n");
 879                 f = search_getfilename(globhandle, i);
 880                 PrecachePlayerSounds(f);
 881         }
 882         search_end(globhandle);
 883 }
 884 void precache_all_playermodels(string pattern)
 885 {
 886         int globhandle = search_begin(pattern, true, false);
 887         if (globhandle < 0) return;
 888         int n = search_getsize(globhandle);
 889         for (int i = 0; i < n; ++i)
 890         {
 891                 string s = search_getfilename(globhandle, i);
 892                 precache_playermodel(s);
 893         }
 894         search_end(globhandle);
 895 }
 896
 897 void precache_playermodels(string s)
 898 {
 899         FOREACH_WORD(s, true, { precache_playermodel(it); });
 900 }
 901
 902 void precache()
 903 {
 904     // gamemode related things
 905
 906     // Precache all player models if desired
 907     if (autocvar_sv_precacheplayermodels)
 908     {
 909         PrecachePlayerSounds("sound/player/default.sounds");
 910         precache_all_playermodels("models/player/*.zym");
 911         precache_all_playermodels("models/player/*.dpm");
 912         precache_all_playermodels("models/player/*.md3");
 913         precache_all_playermodels("models/player/*.psk");
 914         precache_all_playermodels("models/player/*.iqm");
 915     }
 916
 917     if (autocvar_sv_defaultcharacter)
 918     {
 919                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 920                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 921                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 922                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 923                 precache_playermodels(autocvar_sv_defaultplayermodel);
 924     }
 925
 926 #if 0
 927     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 928
 929     if (!this.noise && this.music) // quake 3 uses the music field
 930         this.noise = this.music;
 931
 932     // plays music for the level if there is any
 933     if (this.noise)
 934     {
 935         precache_sound (this.noise);
 936         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 937     }
 938 #endif
 939 }
 940
 941
 942 void make_safe_for_remove(entity e)
 943 {
 944     if (e.initialize_entity)
 945     {
 946         entity ent, prev = NULL;
 947         for (ent = initialize_entity_first; ent; )
 948         {
 949             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 950             {
 951                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 952                 // skip it in linked list
 953                 if (prev)
 954                 {
 955                     prev.initialize_entity_next = ent.initialize_entity_next;
 956                     ent = prev.initialize_entity_next;
 957                 }
 958                 else
 959                 {
 960                     initialize_entity_first = ent.initialize_entity_next;
 961                     ent = initialize_entity_first;
 962                 }
 963             }
 964             else
 965             {
 966                 prev = ent;
 967                 ent = ent.initialize_entity_next;
 968             }
 969         }
 970     }
 971 }
 972
 973 .float remove_except_protected_forbidden;
 974 void remove_except_protected(entity e)
 975 {
 976         if(e.remove_except_protected_forbidden)
 977                 error("not allowed to remove this at this point");
 978         builtin_remove(e);
 979 }
 980
 981 void remove_unsafely(entity e)
 982 {
 983     if(e.classname == "spike")
 984         error("Removing spikes is forbidden (crylink bug), please report");
 985     builtin_remove(e);
 986 }
 987
 988 void remove_safely(entity e)
 989 {
 990     make_safe_for_remove(e);
 991     builtin_remove(e);
 992 }
 993
 994 void InitializeEntity(entity e, void(entity this) func, int order)
 995 {
 996     entity prev, cur;
 997
 998     if (!e || e.initialize_entity)
 999     {
1000         // make a proxy initializer entity
1001         entity e_old = e;
1002         e = new(initialize_entity);
1003         e.enemy = e_old;
1004     }
1005
1006     e.initialize_entity = func;
1007     e.initialize_entity_order = order;
1008
1009     cur = initialize_entity_first;
1010     prev = NULL;
1011     for (;;)
1012     {
1013         if (!cur || cur.initialize_entity_order > order)
1014         {
1015             // insert between prev and cur
1016             if (prev)
1017                 prev.initialize_entity_next = e;
1018             else
1019                 initialize_entity_first = e;
1020             e.initialize_entity_next = cur;
1021             return;
1022         }
1023         prev = cur;
1024         cur = cur.initialize_entity_next;
1025     }
1026 }
1027 void InitializeEntitiesRun()
1028 {
1029     entity startoflist = initialize_entity_first;
1030     initialize_entity_first = NULL;
1031     delete_fn = remove_except_protected;
1032     for (entity e = startoflist; e; e = e.initialize_entity_next)
1033     {
1034                 e.remove_except_protected_forbidden = 1;
1035     }
1036     for (entity e = startoflist; e; )
1037     {
1038                 e.remove_except_protected_forbidden = 0;
1039         e.initialize_entity_order = 0;
1040         entity next = e.initialize_entity_next;
1041         e.initialize_entity_next = NULL;
1042         var void(entity this) func = e.initialize_entity;
1043         e.initialize_entity = func_null;
1044         if (e.classname == "initialize_entity")
1045         {
1046             entity wrappee = e.enemy;
1047             builtin_remove(e);
1048             e = wrappee;
1049         }
1050         //dprint("Delayed initialization: ", e.classname, "\n");
1051         if (func)
1052         {
1053                 func(e);
1054         }
1055         else
1056         {
1057             eprint(e);
1058             backtrace(strcat("Null function in: ", e.classname, "\n"));
1059         }
1060         e = next;
1061     }
1062     delete_fn = remove_unsafely;
1063 }
1064
1065 .float(entity) isEliminated;
1066 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
1067 {
1068         Stream out = MSG_ENTITY;
1069         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
1070         serialize(byte, out, sendflags);
1071         if (sendflags & 1) {
1072                 for (int i = 1; i <= maxclients; i += 8) {
1073                         int f = 0;
1074                         entity e = edict_num(i);
1075                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
1076                                 if (eliminatedPlayers.isEliminated(e)) {
1077                                         f |= BIT(b);
1078                                 }
1079                         }
1080                         serialize(byte, out, f);
1081                 }
1082         }
1083         return true;
1084 }
1085
1086 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1087 {
1088         if(eliminatedPlayers)
1089         {
1090                 backtrace("Can't spawn eliminatedPlayers again!");
1091                 return;
1092         }
1093         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1094         eliminatedPlayers.isEliminated = isEliminated_func;
1095 }
1096
1097
1098
1099
1100 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
1101 {
1102         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1103                 this.projectiledeathtype |= HITTYPE_SPLASH;
1104         adaptor_think2use(this);
1105 }
1106
1107 // deferred dropping
1108 void DropToFloor_Handler(entity this)
1109 {
1110     WITHSELF(this, builtin_droptofloor());
1111     this.dropped_origin = this.origin;
1112 }
1113
1114 void droptofloor(entity this)
1115 {
1116     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1117 }
1118
1119
1120
1121 float trace_hits_box_a0, trace_hits_box_a1;
1122
1123 float trace_hits_box_1d(float end, float thmi, float thma)
1124 {
1125     if (end == 0)
1126     {
1127         // just check if x is in range
1128         if (0 < thmi)
1129             return false;
1130         if (0 > thma)
1131             return false;
1132     }
1133     else
1134     {
1135         // do the trace with respect to x
1136         // 0 -> end has to stay in thmi -> thma
1137         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1138         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1139         if (trace_hits_box_a0 > trace_hits_box_a1)
1140             return false;
1141     }
1142     return true;
1143 }
1144
1145 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1146 {
1147     end -= start;
1148     thmi -= start;
1149     thma -= start;
1150     // now it is a trace from 0 to end
1151
1152     trace_hits_box_a0 = 0;
1153     trace_hits_box_a1 = 1;
1154
1155     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1156         return false;
1157     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1158         return false;
1159     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1160         return false;
1161
1162     return true;
1163 }
1164
1165 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1166 {
1167     return trace_hits_box(start, end, thmi - ma, thma - mi);
1168 }
1169
1170 bool SUB_NoImpactCheck(entity this, entity toucher)
1171 {
1172         // zero hitcontents = this is not the real impact, but either the
1173         // mirror-impact of something hitting the projectile instead of the
1174         // projectile hitting the something, or a touchareagrid one. Neither of
1175         // these stop the projectile from moving, so...
1176         if(trace_dphitcontents == 0)
1177         {
1178                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1179                 checkclient(this); // TODO: .health is checked in the engine with this, possibly replace with a QC function?
1180         }
1181     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1182         return true;
1183     if (toucher == NULL && this.size != '0 0 0')
1184     {
1185         vector tic;
1186         tic = this.velocity * sys_frametime;
1187         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1188         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1189         if (trace_fraction >= 1)
1190         {
1191             LOG_TRACE("Odd... did not hit...?");
1192         }
1193         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1194         {
1195             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1196             return true;
1197         }
1198     }
1199
1200     return false;
1201 }
1202
1203 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1204 {
1205         // owner check
1206         if(toucher && toucher == this.owner)
1207                 return true;
1208         if(SUB_NoImpactCheck(this, toucher))
1209         {
1210                 if(this.classname == "nade")
1211                         return false; // no checks here
1212                 else if(this.classname == "grapplinghook")
1213                         RemoveHook(this);
1214                 else
1215                         delete(this);
1216                 return true;
1217         }
1218         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1219                 UpdateCSQCProjectile(this);
1220         return false;
1221 }
1222
1223 /** engine callback */
1224 void URI_Get_Callback(float id, float status, string data)
1225 {
1226         if(url_URI_Get_Callback(id, status, data))
1227         {
1228                 // handled
1229         }
1230         else if (id == URI_GET_DISCARD)
1231         {
1232                 // discard
1233         }
1234         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1235         {
1236                 // sv_cmd curl
1237                 Curl_URI_Get_Callback(id, status, data);
1238         }
1239         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1240         {
1241                 // online ban list
1242                 OnlineBanList_URI_Get_Callback(id, status, data);
1243         }
1244         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1245         {
1246                 // handled by a mutator
1247         }
1248         else
1249         {
1250                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1251         }
1252 }
1253
1254 string uid2name(string myuid)
1255 {
1256         string s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1257
1258         // FIXME remove this later after 0.6 release
1259         // convert old style broken records to correct style
1260         if(s == "")
1261         {
1262                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1263                 if(s != "")
1264                 {
1265                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1266                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1267                 }
1268         }
1269
1270         if(s == "")
1271                 s = "^1Unregistered Player";
1272         return s;
1273 }
1274
1275 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance)
1276 {
1277     float m = e.dphitcontentsmask;
1278     e.dphitcontentsmask = goodcontents | badcontents;
1279
1280     vector org = boundmin;
1281     vector delta = boundmax - boundmin;
1282
1283     vector start, end;
1284     start = end = org;
1285     int j; // used after the loop
1286     for(j = 0; j < attempts; ++j)
1287     {
1288         start.x = org.x + random() * delta.x;
1289         start.y = org.y + random() * delta.y;
1290         start.z = org.z + random() * delta.z;
1291
1292         // rule 1: start inside world bounds, and outside
1293         // solid, and don't start from somewhere where you can
1294         // fall down to evil
1295         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1296         if (trace_fraction >= 1)
1297             continue;
1298         if (trace_startsolid)
1299             continue;
1300         if (trace_dphitcontents & badcontents)
1301             continue;
1302         if (trace_dphitq3surfaceflags & badsurfaceflags)
1303             continue;
1304
1305         // rule 2: if we are too high, lower the point
1306         if (trace_fraction * delta.z > maxaboveground)
1307             start = trace_endpos + '0 0 1' * maxaboveground;
1308         vector enddown = trace_endpos;
1309
1310         // rule 3: make sure we aren't outside the map. This only works
1311         // for somewhat well formed maps. A good rule of thumb is that
1312         // the map should have a convex outside hull.
1313         // these can be traceLINES as we already verified the starting box
1314         vector mstart = start + 0.5 * (e.mins + e.maxs);
1315         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1316         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1317             continue;
1318         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1319         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1320             continue;
1321         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1322         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1323             continue;
1324         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1325         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1326             continue;
1327         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1328         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1329             continue;
1330
1331                 // rule 4: we must "see" some spawnpoint or item
1332             entity sp = NULL;
1333             IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1334             {
1335                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1336                 {
1337                         sp = it;
1338                         break;
1339                 }
1340             });
1341                 if(!sp)
1342                 {
1343                         int items_checked = 0;
1344                         IL_EACH(g_items, checkpvs(mstart, it),
1345                         {
1346                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1347                                 {
1348                                         sp = it;
1349                                         break;
1350                                 }
1351
1352                                 ++items_checked;
1353                                 if(items_checked >= attempts)
1354                                         break; // sanity
1355                         });
1356
1357                         if(!sp)
1358                                 continue;
1359                 }
1360
1361         // find a random vector to "look at"
1362         end.x = org.x + random() * delta.x;
1363         end.y = org.y + random() * delta.y;
1364         end.z = org.z + random() * delta.z;
1365         end = start + normalize(end - start) * vlen(delta);
1366
1367         // rule 4: start TO end must not be too short
1368         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1369         if(trace_startsolid)
1370             continue;
1371         if(trace_fraction < minviewdistance / vlen(delta))
1372             continue;
1373
1374         // rule 5: don't want to look at sky
1375         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1376             continue;
1377
1378         // rule 6: we must not end up in trigger_hurt
1379         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1380             continue;
1381
1382         break;
1383     }
1384
1385     e.dphitcontentsmask = m;
1386
1387     if(j < attempts)
1388     {
1389         setorigin(e, start);
1390         e.angles = vectoangles(end - start);
1391         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1392         return true;
1393     }
1394     return false;
1395 }
1396
1397 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1398 {
1399         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1400 }
1401
1402 void write_recordmarker(entity pl, float tstart, float dt)
1403 {
1404     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1405
1406     // also write a marker into demo files for demotc-race-record-extractor to find
1407     stuffcmd(pl,
1408              strcat(
1409                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1410                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1411 }
1412
1413 void attach_sameorigin(entity e, entity to, string tag)
1414 {
1415     vector org, t_forward, t_left, t_up, e_forward, e_up;
1416     float tagscale;
1417
1418     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1419     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1420     t_forward = v_forward * tagscale;
1421     t_left = v_right * -tagscale;
1422     t_up = v_up * tagscale;
1423
1424     e.origin_x = org * t_forward;
1425     e.origin_y = org * t_left;
1426     e.origin_z = org * t_up;
1427
1428     // current forward and up directions
1429     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1430                 e.angles = AnglesTransform_FromVAngles(e.angles);
1431         else
1432                 e.angles = AnglesTransform_FromAngles(e.angles);
1433     fixedmakevectors(e.angles);
1434
1435     // untransform forward, up!
1436     e_forward.x = v_forward * t_forward;
1437     e_forward.y = v_forward * t_left;
1438     e_forward.z = v_forward * t_up;
1439     e_up.x = v_up * t_forward;
1440     e_up.y = v_up * t_left;
1441     e_up.z = v_up * t_up;
1442
1443     e.angles = fixedvectoangles2(e_forward, e_up);
1444     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1445                 e.angles = AnglesTransform_ToVAngles(e.angles);
1446         else
1447                 e.angles = AnglesTransform_ToAngles(e.angles);
1448
1449     setattachment(e, to, tag);
1450     setorigin(e, e.origin);
1451 }
1452
1453 void detach_sameorigin(entity e)
1454 {
1455     vector org;
1456     org = gettaginfo(e, 0);
1457     e.angles = fixedvectoangles2(v_forward, v_up);
1458     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1459                 e.angles = AnglesTransform_ToVAngles(e.angles);
1460         else
1461                 e.angles = AnglesTransform_ToAngles(e.angles);
1462     setorigin(e, org);
1463     setattachment(e, NULL, "");
1464     setorigin(e, e.origin);
1465 }
1466
1467 void follow_sameorigin(entity e, entity to)
1468 {
1469     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1470     e.aiment = to; // make the hole follow bmodel
1471     e.punchangle = to.angles; // the original angles of bmodel
1472     e.view_ofs = e.origin - to.origin; // relative origin
1473     e.v_angle = e.angles - to.angles; // relative angles
1474 }
1475
1476 #if 0
1477 // TODO: unused, likely for a reason, possibly needs extensions (allow setting the new movetype as a parameter?)
1478 void unfollow_sameorigin(entity e)
1479 {
1480     set_movetype(e, MOVETYPE_NONE);
1481 }
1482 #endif
1483
1484 .string aiment_classname;
1485 .float aiment_deadflag;
1486 void SetMovetypeFollow(entity ent, entity e)
1487 {
1488         // FIXME this may not be warpzone aware
1489         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1490         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1491         ent.aiment = e; // make the hole follow bmodel
1492         ent.punchangle = e.angles; // the original angles of bmodel
1493         ent.view_ofs = ent.origin - e.origin; // relative origin
1494         ent.v_angle = ent.angles - e.angles; // relative angles
1495         ent.aiment_classname = strzone(e.classname);
1496         ent.aiment_deadflag = e.deadflag;
1497 }
1498 void UnsetMovetypeFollow(entity ent)
1499 {
1500         set_movetype(ent, MOVETYPE_FLY);
1501         PROJECTILE_MAKETRIGGER(ent);
1502         ent.aiment = NULL;
1503 }
1504 float LostMovetypeFollow(entity ent)
1505 {
1506 /*
1507         if(ent.move_movetype != MOVETYPE_FOLLOW)
1508                 if(ent.aiment)
1509                         error("???");
1510 */
1511         if(ent.aiment)
1512         {
1513                 if(ent.aiment.classname != ent.aiment_classname)
1514                         return 1;
1515                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1516                         return 1;
1517         }
1518         return 0;
1519 }
1520
1521 .bool pushable;
1522 bool isPushable(entity e)
1523 {
1524         if(e.pushable)
1525                 return true;
1526         if(IS_VEHICLE(e))
1527                 return false;
1528         if(e.iscreature)
1529                 return true;
1530         if (Item_IsLoot(e))
1531         {
1532                 return true;
1533         }
1534         switch(e.classname)
1535         {
1536                 case "body":
1537                         return true;
1538                 case "bullet": // antilagged bullets can't hit this either
1539                         return false;
1540         }
1541         if (e.projectiledeathtype)
1542                 return true;
1543         return false;
1544 }