qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = W_Name(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else replacement = "batteries"; // ;)
 365                 } else if (escape == "x") {
 366                         replacement = cursor_ent.netname;
 367                         if (replacement == "" || !cursor_ent)
 368                                 replacement = "nothing";
 369                 } else if (escape == "s")
 370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 371                 else if (escape == "S")
 372                         replacement = ftos(vlen(self.velocity));
 373
 374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 375                 p = p + strlen(replacement);
 376         }
 377         return msg;
 378 }
 379
 380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 381         return (value == 0) ? FALSE : TRUE;
 382 }
 383
 384 /*
 385 =============
 386 GetCvars
 387 =============
 388 Called with:
 389   0:  sends the request
 390   >0: receives a cvar from name=argv(f) value=argv(f+1)
 391 */
 392 void GetCvars_handleString(string thisname, float f, .string field, string name)
 393 {
 394         if (f < 0)
 395         {
 396                 if (self.field)
 397                         strunzone(self.field);
 398                 self.field = string_null;
 399         }
 400         else if (f > 0)
 401         {
 402                 if (thisname == name)
 403                 {
 404                         if (self.field)
 405                                 strunzone(self.field);
 406                         self.field = strzone(argv(f + 1));
 407                 }
 408         }
 409         else
 410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 411 }
 412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 413 {
 414         GetCvars_handleString(thisname, f, field, name);
 415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 416                 if (thisname == name)
 417                 {
 418                         string s;
 419                         s = func(strcat1(self.field));
 420                         if (s != self.field)
 421                         {
 422                                 strunzone(self.field);
 423                                 self.field = strzone(s);
 424                         }
 425                 }
 426 }
 427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 428 {
 429         if (f < 0)
 430         {
 431         }
 432         else if (f > 0)
 433         {
 434                 if (thisname == name)
 435                         self.field = stof(argv(f + 1));
 436         }
 437         else
 438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 439 }
 440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 441 {
 442         if (f < 0)
 443         {
 444         }
 445         else if (f > 0)
 446         {
 447                 if (thisname == name)
 448                 {
 449                         if(!self.field)
 450                         {
 451                                 self.field = stof(argv(f + 1));
 452                                 if(!self.field)
 453                                         self.field = -1;
 454                         }
 455                 }
 456         }
 457         else
 458         {
 459                 if(!self.field)
 460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 461         }
 462 }
 463 float w_getbestweapon(entity e);
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 vector randompos(vector m1, vector m2)
 547 {
 548     vector v;
 549     m2 = m2 - m1;
 550     v_x = m2_x * random() + m1_x;
 551     v_y = m2_y * random() + m1_y;
 552     v_z = m2_z * random() + m1_z;
 553     return  v;
 554 }
 555
 556 //#NO AUTOCVARS START
 557
 558 float g_pickup_shells;
 559 float g_pickup_shells_max;
 560 float g_pickup_nails;
 561 float g_pickup_nails_max;
 562 float g_pickup_rockets;
 563 float g_pickup_rockets_max;
 564 float g_pickup_cells;
 565 float g_pickup_cells_max;
 566 float g_pickup_fuel;
 567 float g_pickup_fuel_jetpack;
 568 float g_pickup_fuel_max;
 569 float g_pickup_armorsmall;
 570 float g_pickup_armorsmall_max;
 571 float g_pickup_armorsmall_anyway;
 572 float g_pickup_armormedium;
 573 float g_pickup_armormedium_max;
 574 float g_pickup_armormedium_anyway;
 575 float g_pickup_armorbig;
 576 float g_pickup_armorbig_max;
 577 float g_pickup_armorbig_anyway;
 578 float g_pickup_armorlarge;
 579 float g_pickup_armorlarge_max;
 580 float g_pickup_armorlarge_anyway;
 581 float g_pickup_healthsmall;
 582 float g_pickup_healthsmall_max;
 583 float g_pickup_healthsmall_anyway;
 584 float g_pickup_healthmedium;
 585 float g_pickup_healthmedium_max;
 586 float g_pickup_healthmedium_anyway;
 587 float g_pickup_healthlarge;
 588 float g_pickup_healthlarge_max;
 589 float g_pickup_healthlarge_anyway;
 590 float g_pickup_healthmega;
 591 float g_pickup_healthmega_max;
 592 float g_pickup_healthmega_anyway;
 593 float g_pickup_ammo_anyway;
 594 float g_pickup_weapons_anyway;
 595 float g_weaponarena;
 596 WepSet g_weaponarena_weapons;
 597 float g_weaponarena_random;
 598 float g_weaponarena_random_with_laser;
 599 string g_weaponarena_list;
 600 float g_weaponspeedfactor;
 601 float g_weaponratefactor;
 602 float g_weapondamagefactor;
 603 float g_weaponforcefactor;
 604 float g_weaponspreadfactor;
 605
 606 WepSet start_weapons;
 607 WepSet start_weapons_default;
 608 WepSet start_weapons_defaultmask;
 609 float start_items;
 610 float start_ammo_shells;
 611 float start_ammo_nails;
 612 float start_ammo_rockets;
 613 float start_ammo_cells;
 614 float start_ammo_fuel;
 615 float start_health;
 616 float start_armorvalue;
 617 WepSet warmup_start_weapons;
 618 WepSet warmup_start_weapons_default;
 619 WepSet warmup_start_weapons_defaultmask;
 620 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 621 float warmup_start_ammo_shells;
 622 float warmup_start_ammo_nails;
 623 float warmup_start_ammo_rockets;
 624 float warmup_start_ammo_cells;
 625 float warmup_start_ammo_fuel;
 626 float warmup_start_health;
 627 float warmup_start_armorvalue;
 628 float g_weapon_stay;
 629
 630 entity get_weaponinfo(float w);
 631
 632 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 633 {
 634         var float i = weaponinfo.weapon;
 635         var float d = 0;
 636
 637         if (!i)
 638                 return 0;
 639
 640         if (g_lms || g_ca || allguns)
 641         {
 642                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 643                         d = TRUE;
 644                 else
 645                         d = FALSE;
 646         }
 647         else if (g_cts)
 648                 d = (i == WEP_SHOTGUN);
 649         else if (g_nexball)
 650                 d = 0; // weapon is set a few lines later
 651         else
 652                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 653
 654         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 655                 d |= (i == WEP_HOOK);
 656         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 657                 d = 0;
 658
 659         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 660
 661         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 662
 663         // bit order in t:
 664         // 1: want or not
 665         // 2: is default?
 666         // 4: is set by default?
 667         if(t < 0)
 668                 t = 4 | (3 * d);
 669         else
 670                 t |= (2 * d);
 671
 672         return t;
 673 }
 674
 675 void readplayerstartcvars()
 676 {
 677         entity e;
 678         float i, j, t;
 679         string s;
 680
 681         // initialize starting values for players
 682         start_weapons = '0 0 0';
 683         start_weapons_default = '0 0 0';
 684         start_weapons_defaultmask = '0 0 0';
 685         start_items = 0;
 686         start_ammo_shells = 0;
 687         start_ammo_nails = 0;
 688         start_ammo_rockets = 0;
 689         start_ammo_cells = 0;
 690         start_health = cvar("g_balance_health_start");
 691         start_armorvalue = cvar("g_balance_armor_start");
 692
 693         g_weaponarena = 0;
 694         g_weaponarena_weapons = '0 0 0';
 695
 696         s = cvar_string("g_weaponarena");
 697         if (s == "0" || s == "")
 698         {
 699                 if(g_ca)
 700                         s = "most";
 701         }
 702
 703         if (s == "0" || s == "")
 704         {
 705                 // no arena
 706         }
 707         else if (s == "off")
 708         {
 709                 // forcibly turn off weaponarena
 710         }
 711         else if (s == "all")
 712         {
 713                 g_weaponarena = 1;
 714                 g_weaponarena_list = "All Weapons";
 715                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 716                 {
 717                         e = get_weaponinfo(j);
 718                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 719                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 720                 }
 721         }
 722         else if (s == "most")
 723         {
 724                 g_weaponarena = 1;
 725                 g_weaponarena_list = "Most Weapons";
 726                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 727                 {
 728                         e = get_weaponinfo(j);
 729                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 730                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 731                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 732                 }
 733         }
 734         else if (s == "none")
 735         {
 736                 g_weaponarena = 1;
 737                 g_weaponarena_list = "No Weapons";
 738         }
 739         else
 740         {
 741                 g_weaponarena = 1;
 742                 t = tokenize_console(s);
 743                 g_weaponarena_list = "";
 744                 for (i = 0; i < t; ++i)
 745                 {
 746                         s = argv(i);
 747                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 748                         {
 749                                 e = get_weaponinfo(j);
 750                                 if (e.netname == s)
 751                                 {
 752                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 753                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 754                                         break;
 755                                 }
 756                         }
 757                         if (j > WEP_LAST)
 758                         {
 759                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 760                         }
 761                 }
 762                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 763         }
 764
 765         if(g_weaponarena)
 766                 g_weaponarena_random = cvar("g_weaponarena_random");
 767         else
 768                 g_weaponarena_random = 0;
 769         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 770
 771         if (g_weaponarena)
 772         {
 773                 g_weapon_stay = 0; // incompatible
 774                 start_weapons = g_weaponarena_weapons;
 775                 start_items |= IT_UNLIMITED_AMMO;
 776         }
 777         else
 778         {
 779                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 780                 {
 781                         e = get_weaponinfo(i);
 782                         float w = want_weapon("g_start_weapon_", e, FALSE);
 783                         if(w & 1)
 784                                 start_weapons |= WepSet_FromWeapon(i);
 785                         if(w & 2)
 786                                 start_weapons_default |= WepSet_FromWeapon(i);
 787                         if(w & 4)
 788                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 789                 }
 790         }
 791
 792         if(!cvar("g_use_ammunition"))
 793                 start_items |= IT_UNLIMITED_AMMO;
 794
 795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 796         {
 797                 start_ammo_rockets = 999;
 798                 start_ammo_shells = 999;
 799                 start_ammo_cells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_fuel = 999;
 802         }
 803         else
 804         {
 805                 start_ammo_shells = cvar("g_start_ammo_shells");
 806                 start_ammo_nails = cvar("g_start_ammo_nails");
 807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 808                 start_ammo_cells = cvar("g_start_ammo_cells");
 809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 810         }
 811
 812         if (warmup_stage)
 813         {
 814                 warmup_start_ammo_shells = start_ammo_shells;
 815                 warmup_start_ammo_nails = start_ammo_nails;
 816                 warmup_start_ammo_rockets = start_ammo_rockets;
 817                 warmup_start_ammo_cells = start_ammo_cells;
 818                 warmup_start_ammo_fuel = start_ammo_fuel;
 819                 warmup_start_health = start_health;
 820                 warmup_start_armorvalue = start_armorvalue;
 821                 warmup_start_weapons = start_weapons;
 822                 warmup_start_weapons_default = start_weapons_default;
 823                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 824
 825                 if (!g_weaponarena && !g_ca)
 826                 {
 827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 832                         warmup_start_health = cvar("g_warmup_start_health");
 833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 834                         warmup_start_weapons = '0 0 0';
 835                         warmup_start_weapons_default = '0 0 0';
 836                         warmup_start_weapons_defaultmask = '0 0 0';
 837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 838                         {
 839                                 e = get_weaponinfo(i);
 840                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
 841                                 if(w & 1)
 842                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 843                                 if(w & 2)
 844                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 845                                 if(w & 4)
 846                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 847                         }
 848                 }
 849         }
 850
 851         if (g_jetpack)
 852                 start_items |= IT_JETPACK;
 853
 854         MUTATOR_CALLHOOK(SetStartItems);
 855
 856         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 857         {
 858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 859                 start_items |= IT_FUEL_REGEN;
 860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862         }
 863
 864         WepSet precache_weapons = start_weapons;
 865         if (g_warmup_allguns != 1)
 866                 precache_weapons |= warmup_start_weapons;
 867         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 868         {
 869                 e = get_weaponinfo(i);
 870                 if(precache_weapons & WepSet_FromWeapon(i))
 871                         weapon_action(i, WR_PRECACHE);
 872         }
 873
 874         start_ammo_shells = max(0, start_ammo_shells);
 875         start_ammo_nails = max(0, start_ammo_nails);
 876         start_ammo_cells = max(0, start_ammo_cells);
 877         start_ammo_rockets = max(0, start_ammo_rockets);
 878         start_ammo_fuel = max(0, start_ammo_fuel);
 879
 880         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 881         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 882         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 883         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 884         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 885 }
 886
 887 float g_bugrigs;
 888 float g_bugrigs_planar_movement;
 889 float g_bugrigs_planar_movement_car_jumping;
 890 float g_bugrigs_reverse_spinning;
 891 float g_bugrigs_reverse_speeding;
 892 float g_bugrigs_reverse_stopping;
 893 float g_bugrigs_air_steering;
 894 float g_bugrigs_angle_smoothing;
 895 float g_bugrigs_friction_floor;
 896 float g_bugrigs_friction_brake;
 897 float g_bugrigs_friction_air;
 898 float g_bugrigs_accel;
 899 float g_bugrigs_speed_ref;
 900 float g_bugrigs_speed_pow;
 901 float g_bugrigs_steer;
 902
 903 float sv_autotaunt;
 904 float sv_taunt;
 905
 906 string GetGametype(); // g_world.qc
 907 void mutators_add(); // mutators.qc
 908 void readlevelcvars(void)
 909 {
 910         // load mutators
 911         mutators_add();
 912
 913         if(cvar("sv_allow_fullbright"))
 914                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 915
 916     g_bugrigs = cvar("g_bugrigs");
 917     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 918     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 919     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 920     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 921     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 922     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 923     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 924     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 925     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 926     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 927     g_bugrigs_accel = cvar("g_bugrigs_accel");
 928     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 929     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 930     g_bugrigs_steer = cvar("g_bugrigs_steer");
 931
 932         g_minstagib = cvar("g_minstagib");
 933
 934         sv_clones = cvar("sv_clones");
 935         sv_foginterval = cvar("sv_foginterval");
 936         g_cloaked = cvar("g_cloaked");
 937     if(g_cts)
 938         g_cloaked = 1; // always enable cloak in CTS
 939         g_footsteps = cvar("g_footsteps");
 940         g_grappling_hook = cvar("g_grappling_hook");
 941         g_jetpack = cvar("g_jetpack");
 942         sv_maxidle = cvar("sv_maxidle");
 943         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 944         sv_autotaunt = cvar("sv_autotaunt");
 945         sv_taunt = cvar("sv_taunt");
 946
 947         warmup_stage = cvar("g_warmup");
 948         g_warmup_limit = cvar("g_warmup_limit");
 949         g_warmup_allguns = cvar("g_warmup_allguns");
 950         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 951
 952         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 953                 warmup_stage = 0; // these modes cannot work together, sorry
 954
 955         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 956         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 957         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 958         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 959         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 960         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 961         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 962         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 963         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 964         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 965         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 966         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 967         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 968         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 969
 970         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 971         g_weaponratefactor = cvar("g_weaponratefactor");
 972         g_weapondamagefactor = cvar("g_weapondamagefactor");
 973         g_weaponforcefactor = cvar("g_weaponforcefactor");
 974         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 975
 976         g_pickup_shells = cvar("g_pickup_shells");
 977         g_pickup_shells_max = cvar("g_pickup_shells_max");
 978         g_pickup_nails = cvar("g_pickup_nails");
 979         g_pickup_nails_max = cvar("g_pickup_nails_max");
 980         g_pickup_rockets = cvar("g_pickup_rockets");
 981         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 982         g_pickup_cells = cvar("g_pickup_cells");
 983         g_pickup_cells_max = cvar("g_pickup_cells_max");
 984         g_pickup_fuel = cvar("g_pickup_fuel");
 985         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 986         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 987         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 988         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 989         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 990         g_pickup_armormedium = cvar("g_pickup_armormedium");
 991         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
 992         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
 993         g_pickup_armorbig = cvar("g_pickup_armorbig");
 994         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
 995         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
 996         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
 997         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
 998         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
 999         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1000         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1001         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1002         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1003         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1004         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1005         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1006         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1007         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1008         g_pickup_healthmega = cvar("g_pickup_healthmega");
1009         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1010         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1011
1012         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1013         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1014
1015     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1016     if(!g_weapon_stay)
1017         g_weapon_stay = cvar("g_weapon_stay");
1018
1019         if (!warmup_stage)
1020                 game_starttime = time + cvar("g_start_delay");
1021
1022         readplayerstartcvars();
1023 }
1024
1025 //#NO AUTOCVARS END
1026
1027 // Sound functions
1028 string precache_sound (string s) = #19;
1029 float precache_sound_index (string s) = #19;
1030
1031 #define SND_VOLUME      1
1032 #define SND_ATTENUATION 2
1033 #define SND_LARGEENTITY 8
1034 #define SND_LARGESOUND  16
1035
1036 float sound_allowed(float dest, entity e)
1037 {
1038     // sounds from world may always pass
1039     for (;;)
1040     {
1041         if (e.classname == "body")
1042             e = e.enemy;
1043         else if (e.realowner && e.realowner != e)
1044             e = e.realowner;
1045         else if (e.owner && e.owner != e)
1046             e = e.owner;
1047         else
1048             break;
1049     }
1050     // sounds to self may always pass
1051     if (dest == MSG_ONE)
1052         if (e == msg_entity)
1053             return TRUE;
1054     // sounds by players can be removed
1055     if (autocvar_bot_sound_monopoly)
1056         if (IS_REAL_CLIENT(e))
1057             return FALSE;
1058     // anything else may pass
1059     return TRUE;
1060 }
1061
1062 #undef sound
1063 void sound(entity e, float chan, string samp, float vol, float atten)
1064 {
1065     if (!sound_allowed(MSG_BROADCAST, e))
1066         return;
1067     sound7(e, chan, samp, vol, atten, 0, 0);
1068 }
1069
1070 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1071 {
1072     float entno, idx;
1073
1074     if (!sound_allowed(dest, e))
1075         return;
1076
1077     entno = num_for_edict(e);
1078     idx = precache_sound_index(samp);
1079
1080     float sflags;
1081     sflags = 0;
1082
1083     atten = floor(atten * 64);
1084     vol = floor(vol * 255);
1085
1086     if (vol != 255)
1087         sflags |= SND_VOLUME;
1088     if (atten != 64)
1089         sflags |= SND_ATTENUATION;
1090     if (entno >= 8192 || chan < 0 || chan > 7)
1091         sflags |= SND_LARGEENTITY;
1092     if (idx >= 256)
1093         sflags |= SND_LARGESOUND;
1094
1095     WriteByte(dest, SVC_SOUND);
1096     WriteByte(dest, sflags);
1097     if (sflags & SND_VOLUME)
1098         WriteByte(dest, vol);
1099     if (sflags & SND_ATTENUATION)
1100         WriteByte(dest, atten);
1101     if (sflags & SND_LARGEENTITY)
1102     {
1103         WriteShort(dest, entno);
1104         WriteByte(dest, chan);
1105     }
1106     else
1107     {
1108         WriteShort(dest, entno * 8 + chan);
1109     }
1110     if (sflags & SND_LARGESOUND)
1111         WriteShort(dest, idx);
1112     else
1113         WriteByte(dest, idx);
1114
1115     WriteCoord(dest, o_x);
1116     WriteCoord(dest, o_y);
1117     WriteCoord(dest, o_z);
1118 }
1119 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1120 {
1121     vector o;
1122
1123     if (!sound_allowed(dest, e))
1124         return;
1125
1126     o = e.origin + 0.5 * (e.mins + e.maxs);
1127     soundtoat(dest, e, o, chan, samp, vol, atten);
1128 }
1129 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1130 {
1131     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1132 }
1133 void stopsoundto(float dest, entity e, float chan)
1134 {
1135     float entno;
1136
1137     if (!sound_allowed(dest, e))
1138         return;
1139
1140     entno = num_for_edict(e);
1141
1142     if (entno >= 8192 || chan < 0 || chan > 7)
1143     {
1144         float idx, sflags;
1145         idx = precache_sound_index("misc/null.wav");
1146         sflags = SND_LARGEENTITY;
1147         if (idx >= 256)
1148             sflags |= SND_LARGESOUND;
1149         WriteByte(dest, SVC_SOUND);
1150         WriteByte(dest, sflags);
1151         WriteShort(dest, entno);
1152         WriteByte(dest, chan);
1153         if (sflags & SND_LARGESOUND)
1154             WriteShort(dest, idx);
1155         else
1156             WriteByte(dest, idx);
1157         WriteCoord(dest, e.origin_x);
1158         WriteCoord(dest, e.origin_y);
1159         WriteCoord(dest, e.origin_z);
1160     }
1161     else
1162     {
1163         WriteByte(dest, SVC_STOPSOUND);
1164         WriteShort(dest, entno * 8 + chan);
1165     }
1166 }
1167 void stopsound(entity e, float chan)
1168 {
1169     if (!sound_allowed(MSG_BROADCAST, e))
1170         return;
1171
1172     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1173     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1174 }
1175
1176 void play2(entity e, string filename)
1177 {
1178     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1179     msg_entity = e;
1180     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1181 }
1182
1183 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1184 .float spamtime;
1185 float spamsound(entity e, float chan, string samp, float vol, float atten)
1186 {
1187     if (!sound_allowed(MSG_BROADCAST, e))
1188         return FALSE;
1189
1190     if (time > e.spamtime)
1191     {
1192         e.spamtime = time;
1193         sound(e, chan, samp, vol, atten);
1194         return TRUE;
1195     }
1196     return FALSE;
1197 }
1198
1199 void play2team(float t, string filename)
1200 {
1201     entity head;
1202
1203     if (autocvar_bot_sound_monopoly)
1204         return;
1205
1206     FOR_EACH_REALPLAYER(head)
1207     {
1208         if (head.team == t)
1209             play2(head, filename);
1210     }
1211 }
1212
1213 void play2all(string samp)
1214 {
1215     if (autocvar_bot_sound_monopoly)
1216         return;
1217
1218     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1219 }
1220
1221 void PrecachePlayerSounds(string f);
1222 void precache_playermodel(string m)
1223 {
1224         float globhandle, i, n;
1225         string f;
1226
1227         if(substring(m, -9,5) == "_lod1")
1228                 return;
1229         if(substring(m, -9,5) == "_lod2")
1230                 return;
1231         precache_model(m);
1232         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1233         if(fexists(f))
1234                 precache_model(f);
1235         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1236         if(fexists(f))
1237                 precache_model(f);
1238
1239         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1240         if (globhandle < 0)
1241                 return;
1242         n = search_getsize(globhandle);
1243         for (i = 0; i < n; ++i)
1244         {
1245                 //print(search_getfilename(globhandle, i), "\n");
1246                 f = search_getfilename(globhandle, i);
1247                 PrecachePlayerSounds(f);
1248         }
1249         search_end(globhandle);
1250 }
1251 void precache_all_playermodels(string pattern)
1252 {
1253         float globhandle, i, n;
1254         string f;
1255
1256         globhandle = search_begin(pattern, TRUE, FALSE);
1257         if (globhandle < 0)
1258                 return;
1259         n = search_getsize(globhandle);
1260         for (i = 0; i < n; ++i)
1261         {
1262                 //print(search_getfilename(globhandle, i), "\n");
1263                 f = search_getfilename(globhandle, i);
1264                 precache_playermodel(f);
1265         }
1266         search_end(globhandle);
1267 }
1268
1269 void precache()
1270 {
1271     // gamemode related things
1272     precache_model ("models/misc/chatbubble.spr");
1273
1274 #ifdef TTURRETS_ENABLED
1275     if (autocvar_g_turrets)
1276         turrets_precash();
1277 #endif
1278
1279     // Precache all player models if desired
1280     if (autocvar_sv_precacheplayermodels)
1281     {
1282         PrecachePlayerSounds("sound/player/default.sounds");
1283         precache_all_playermodels("models/player/*.zym");
1284         precache_all_playermodels("models/player/*.dpm");
1285         precache_all_playermodels("models/player/*.md3");
1286         precache_all_playermodels("models/player/*.psk");
1287         precache_all_playermodels("models/player/*.iqm");
1288     }
1289
1290     if (autocvar_sv_defaultcharacter)
1291     {
1292         string s;
1293         s = autocvar_sv_defaultplayermodel_red;
1294         if (s != "")
1295             precache_playermodel(s);
1296         s = autocvar_sv_defaultplayermodel_blue;
1297         if (s != "")
1298             precache_playermodel(s);
1299         s = autocvar_sv_defaultplayermodel_yellow;
1300         if (s != "")
1301             precache_playermodel(s);
1302         s = autocvar_sv_defaultplayermodel_pink;
1303         if (s != "")
1304             precache_playermodel(s);
1305         s = autocvar_sv_defaultplayermodel;
1306         if (s != "")
1307             precache_playermodel(s);
1308     }
1309
1310     if (g_footsteps)
1311     {
1312         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1313         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1314     }
1315
1316     // gore and miscellaneous sounds
1317     //precache_sound ("misc/h2ohit.wav");
1318     precache_model ("models/hook.md3");
1319     precache_sound ("misc/armorimpact.wav");
1320     precache_sound ("misc/bodyimpact1.wav");
1321     precache_sound ("misc/bodyimpact2.wav");
1322     precache_sound ("misc/gib.wav");
1323     precache_sound ("misc/gib_splat01.wav");
1324     precache_sound ("misc/gib_splat02.wav");
1325     precache_sound ("misc/gib_splat03.wav");
1326     precache_sound ("misc/gib_splat04.wav");
1327     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1328     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1329     precache_sound ("misc/null.wav");
1330     precache_sound ("misc/spawn.wav");
1331     precache_sound ("misc/talk.wav");
1332     precache_sound ("misc/teleport.wav");
1333     precache_sound ("misc/poweroff.wav");
1334     precache_sound ("player/lava.wav");
1335     precache_sound ("player/slime.wav");
1336
1337     precache_model ("models/sprites/0.spr32");
1338     precache_model ("models/sprites/1.spr32");
1339     precache_model ("models/sprites/2.spr32");
1340     precache_model ("models/sprites/3.spr32");
1341     precache_model ("models/sprites/4.spr32");
1342     precache_model ("models/sprites/5.spr32");
1343     precache_model ("models/sprites/6.spr32");
1344     precache_model ("models/sprites/7.spr32");
1345     precache_model ("models/sprites/8.spr32");
1346     precache_model ("models/sprites/9.spr32");
1347     precache_model ("models/sprites/10.spr32");
1348
1349     // common weapon precaches
1350         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1351     precache_sound ("weapons/weapon_switch.wav");
1352     precache_sound ("weapons/weaponpickup.wav");
1353     precache_sound ("weapons/unavailable.wav");
1354     precache_sound ("weapons/dryfire.wav");
1355     if (g_grappling_hook)
1356     {
1357         precache_sound ("weapons/hook_fire.wav"); // hook
1358         precache_sound ("weapons/hook_impact.wav"); // hook
1359     }
1360
1361     if(autocvar_sv_precacheweapons)
1362     {
1363         //precache weapon models/sounds
1364         float wep;
1365         wep = WEP_FIRST;
1366         while (wep <= WEP_LAST)
1367         {
1368             weapon_action(wep, WR_PRECACHE);
1369             wep = wep + 1;
1370         }
1371     }
1372
1373     precache_model("models/elaser.mdl");
1374     precache_model("models/laser.mdl");
1375     precache_model("models/ebomb.mdl");
1376
1377 #if 0
1378     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1379
1380     if (!self.noise && self.music) // quake 3 uses the music field
1381         self.noise = self.music;
1382
1383     // plays music for the level if there is any
1384     if (self.noise)
1385     {
1386         precache_sound (self.noise);
1387         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1388     }
1389 #endif
1390
1391 #include "precache-for-csqc.inc"
1392 }
1393
1394 // WARNING: this kills the trace globals
1395 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1396 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1397
1398 #define INITPRIO_FIRST              0
1399 #define INITPRIO_GAMETYPE           0
1400 #define INITPRIO_GAMETYPE_FALLBACK  1
1401 #define INITPRIO_FINDTARGET        10
1402 #define INITPRIO_DROPTOFLOOR       20
1403 #define INITPRIO_SETLOCATION       90
1404 #define INITPRIO_LINKDOORS         91
1405 #define INITPRIO_LAST              99
1406
1407 .void(void) initialize_entity;
1408 .float initialize_entity_order;
1409 .entity initialize_entity_next;
1410 entity initialize_entity_first;
1411
1412 void make_safe_for_remove(entity e)
1413 {
1414     if (e.initialize_entity)
1415     {
1416         entity ent, prev = world;
1417         for (ent = initialize_entity_first; ent; )
1418         {
1419             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1420             {
1421                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1422                 // skip it in linked list
1423                 if (prev)
1424                 {
1425                     prev.initialize_entity_next = ent.initialize_entity_next;
1426                     ent = prev.initialize_entity_next;
1427                 }
1428                 else
1429                 {
1430                     initialize_entity_first = ent.initialize_entity_next;
1431                     ent = initialize_entity_first;
1432                 }
1433             }
1434             else
1435             {
1436                 prev = ent;
1437                 ent = ent.initialize_entity_next;
1438             }
1439         }
1440     }
1441 }
1442
1443 void objerror(string s)
1444 {
1445     make_safe_for_remove(self);
1446     builtin_objerror(s);
1447 }
1448
1449 .float remove_except_protected_forbidden;
1450 void remove_except_protected(entity e)
1451 {
1452         if(e.remove_except_protected_forbidden)
1453                 error("not allowed to remove this at this point");
1454         builtin_remove(e);
1455 }
1456
1457 void remove_unsafely(entity e)
1458 {
1459     if(e.classname == "spike")
1460         error("Removing spikes is forbidden (crylink bug), please report");
1461     builtin_remove(e);
1462 }
1463
1464 void remove_safely(entity e)
1465 {
1466     make_safe_for_remove(e);
1467     builtin_remove(e);
1468 }
1469
1470 void InitializeEntity(entity e, void(void) func, float order)
1471 {
1472     entity prev, cur;
1473
1474     if (!e || e.initialize_entity)
1475     {
1476         // make a proxy initializer entity
1477         entity e_old;
1478         e_old = e;
1479         e = spawn();
1480         e.classname = "initialize_entity";
1481         e.enemy = e_old;
1482     }
1483
1484     e.initialize_entity = func;
1485     e.initialize_entity_order = order;
1486
1487     cur = initialize_entity_first;
1488     prev = world;
1489     for (;;)
1490     {
1491         if (!cur || cur.initialize_entity_order > order)
1492         {
1493             // insert between prev and cur
1494             if (prev)
1495                 prev.initialize_entity_next = e;
1496             else
1497                 initialize_entity_first = e;
1498             e.initialize_entity_next = cur;
1499             return;
1500         }
1501         prev = cur;
1502         cur = cur.initialize_entity_next;
1503     }
1504 }
1505 void InitializeEntitiesRun()
1506 {
1507     entity startoflist;
1508     startoflist = initialize_entity_first;
1509     initialize_entity_first = world;
1510     remove = remove_except_protected;
1511     for (self = startoflist; self; self = self.initialize_entity_next)
1512     {
1513         self.remove_except_protected_forbidden = 1;
1514     }
1515     for (self = startoflist; self; )
1516     {
1517         entity e;
1518         var void(void) func;
1519         e = self.initialize_entity_next;
1520         func = self.initialize_entity;
1521         self.initialize_entity_order = 0;
1522         self.initialize_entity = func_null;
1523         self.initialize_entity_next = world;
1524         self.remove_except_protected_forbidden = 0;
1525         if (self.classname == "initialize_entity")
1526         {
1527             entity e_old;
1528             e_old = self.enemy;
1529             builtin_remove(self);
1530             self = e_old;
1531         }
1532         //dprint("Delayed initialization: ", self.classname, "\n");
1533         if(func)
1534             func();
1535         else
1536         {
1537             eprint(self);
1538             backtrace(strcat("Null function in: ", self.classname, "\n"));
1539         }
1540         self = e;
1541     }
1542     remove = remove_unsafely;
1543 }
1544
1545 .float uncustomizeentityforclient_set;
1546 .void(void) uncustomizeentityforclient;
1547 void UncustomizeEntitiesRun()
1548 {
1549     entity oldself;
1550     oldself = self;
1551     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1552         self.uncustomizeentityforclient();
1553     self = oldself;
1554 }
1555 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1556 {
1557     e.customizeentityforclient = customizer;
1558     e.uncustomizeentityforclient = uncustomizer;
1559     e.uncustomizeentityforclient_set = !!uncustomizer;
1560 }
1561
1562 .float nottargeted;
1563 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1564
1565 void() SUB_Remove;
1566 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1567 {
1568     vector mi, ma;
1569
1570     if (e.classname == "")
1571         e.classname = "net_linked";
1572
1573     if (e.model == "" || self.modelindex == 0)
1574     {
1575         mi = e.mins;
1576         ma = e.maxs;
1577         setmodel(e, "null");
1578         setsize(e, mi, ma);
1579     }
1580
1581     e.SendEntity = sendfunc;
1582     e.SendFlags = 0xFFFFFF;
1583
1584     if (!docull)
1585         e.effects |= EF_NODEPTHTEST;
1586
1587     if (dt)
1588     {
1589         e.nextthink = time + dt;
1590         e.think = SUB_Remove;
1591     }
1592 }
1593
1594 void adaptor_think2touch()
1595 {
1596     entity o;
1597     o = other;
1598     other = world;
1599     self.touch();
1600     other = o;
1601 }
1602
1603 void adaptor_think2use()
1604 {
1605     entity o, a;
1606     o = other;
1607     a = activator;
1608     activator = world;
1609     other = world;
1610     self.use();
1611     other = o;
1612     activator = a;
1613 }
1614
1615 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1616 {
1617         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1618                 self.projectiledeathtype |= HITTYPE_SPLASH;
1619         adaptor_think2use();
1620 }
1621
1622 // deferred dropping
1623 void DropToFloor_Handler()
1624 {
1625     builtin_droptofloor();
1626     self.dropped_origin = self.origin;
1627 }
1628
1629 void droptofloor()
1630 {
1631     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1632 }
1633
1634
1635
1636 float trace_hits_box_a0, trace_hits_box_a1;
1637
1638 float trace_hits_box_1d(float end, float thmi, float thma)
1639 {
1640     if (end == 0)
1641     {
1642         // just check if x is in range
1643         if (0 < thmi)
1644             return FALSE;
1645         if (0 > thma)
1646             return FALSE;
1647     }
1648     else
1649     {
1650         // do the trace with respect to x
1651         // 0 -> end has to stay in thmi -> thma
1652         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1653         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1654         if (trace_hits_box_a0 > trace_hits_box_a1)
1655             return FALSE;
1656     }
1657     return TRUE;
1658 }
1659
1660 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1661 {
1662     end -= start;
1663     thmi -= start;
1664     thma -= start;
1665     // now it is a trace from 0 to end
1666
1667     trace_hits_box_a0 = 0;
1668     trace_hits_box_a1 = 1;
1669
1670     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1671         return FALSE;
1672     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1673         return FALSE;
1674     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1675         return FALSE;
1676
1677     return TRUE;
1678 }
1679
1680 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1681 {
1682     return trace_hits_box(start, end, thmi - ma, thma - mi);
1683 }
1684
1685 float SUB_NoImpactCheck()
1686 {
1687         // zero hitcontents = this is not the real impact, but either the
1688         // mirror-impact of something hitting the projectile instead of the
1689         // projectile hitting the something, or a touchareagrid one. Neither of
1690         // these stop the projectile from moving, so...
1691         if(trace_dphitcontents == 0)
1692         {
1693                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1694                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1695                 checkclient();
1696         }
1697     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1698         return 1;
1699     if (other == world && self.size != '0 0 0')
1700     {
1701         vector tic;
1702         tic = self.velocity * sys_frametime;
1703         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1704         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1705         if (trace_fraction >= 1)
1706         {
1707             dprint("Odd... did not hit...?\n");
1708         }
1709         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1710         {
1711             dprint("Detected and prevented the sky-grapple bug.\n");
1712             return 1;
1713         }
1714     }
1715
1716     return 0;
1717 }
1718
1719 #define SUB_OwnerCheck() (other && (other == self.owner))
1720
1721 void RemoveGrapplingHook(entity pl);
1722 void W_Crylink_Dequeue(entity e);
1723 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1724 {
1725         if(SUB_OwnerCheck())
1726                 return TRUE;
1727         if(SUB_NoImpactCheck())
1728         {
1729                 if(self.classname == "grapplinghook")
1730                         RemoveGrapplingHook(self.realowner);
1731                 else if(self.classname == "spike")
1732                 {
1733                         W_Crylink_Dequeue(self);
1734                         remove(self);
1735                 }
1736                 else
1737                         remove(self);
1738                 return TRUE;
1739         }
1740         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1741                 UpdateCSQCProjectile(self);
1742         return FALSE;
1743 }
1744 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1745
1746 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1747 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1748
1749 void URI_Get_Callback(float id, float status, string data)
1750 {
1751         if(url_URI_Get_Callback(id, status, data))
1752         {
1753                 // handled
1754         }
1755         else if (id == URI_GET_DISCARD)
1756         {
1757                 // discard
1758         }
1759         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1760         {
1761                 // sv_cmd curl
1762                 Curl_URI_Get_Callback(id, status, data);
1763         }
1764         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1765         {
1766                 // online ban list
1767                 OnlineBanList_URI_Get_Callback(id, status, data);
1768         }
1769         else
1770         {
1771                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1772         }
1773 }
1774
1775 string uid2name(string myuid) {
1776         string s;
1777         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1778
1779         // FIXME remove this later after 0.6 release
1780         // convert old style broken records to correct style
1781         if(s == "")
1782         {
1783                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1784                 if(s != "")
1785                 {
1786                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1787                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1788                 }
1789         }
1790
1791         if(s == "")
1792                 s = "^1Unregistered Player";
1793         return s;
1794 }
1795
1796 float race_readTime(string map, float pos)
1797 {
1798         string rr;
1799         if(g_cts)
1800                 rr = CTS_RECORD;
1801         else
1802                 rr = RACE_RECORD;
1803
1804         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1805 }
1806
1807 string race_readUID(string map, float pos)
1808 {
1809         string rr;
1810         if(g_cts)
1811                 rr = CTS_RECORD;
1812         else
1813                 rr = RACE_RECORD;
1814
1815         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1816 }
1817
1818 float race_readPos(string map, float t) {
1819         float i;
1820         for (i = 1; i <= RANKINGS_CNT; ++i)
1821                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1822                         return i;
1823
1824         return 0; // pos is zero if unranked
1825 }
1826
1827 void race_writeTime(string map, float t, string myuid)
1828 {
1829         string rr;
1830         if(g_cts)
1831                 rr = CTS_RECORD;
1832         else
1833                 rr = RACE_RECORD;
1834
1835         float newpos;
1836         newpos = race_readPos(map, t);
1837
1838         float i, prevpos = 0;
1839         for(i = 1; i <= RANKINGS_CNT; ++i)
1840         {
1841                 if(race_readUID(map, i) == myuid)
1842                         prevpos = i;
1843         }
1844         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1845                 for (i = prevpos; i > newpos; --i) {
1846                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1847                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1848                 }
1849         } else { // player has no ranked record yet
1850                 for (i = RANKINGS_CNT; i > newpos; --i) {
1851                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1852                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1853                 }
1854         }
1855
1856         // store new time itself
1857         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1858         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1859 }
1860
1861 string race_readName(string map, float pos)
1862 {
1863         string rr;
1864         if(g_cts)
1865                 rr = CTS_RECORD;
1866         else
1867                 rr = RACE_RECORD;
1868
1869         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1870 }
1871
1872 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1873 {
1874     float m, i;
1875     vector start, org, delta, end, enddown, mstart;
1876     entity sp;
1877
1878     m = e.dphitcontentsmask;
1879     e.dphitcontentsmask = goodcontents | badcontents;
1880
1881     org = world.mins;
1882     delta = world.maxs - world.mins;
1883
1884     start = end = org;
1885
1886     for (i = 0; i < attempts; ++i)
1887     {
1888         start_x = org_x + random() * delta_x;
1889         start_y = org_y + random() * delta_y;
1890         start_z = org_z + random() * delta_z;
1891
1892         // rule 1: start inside world bounds, and outside
1893         // solid, and don't start from somewhere where you can
1894         // fall down to evil
1895         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1896         if (trace_fraction >= 1)
1897             continue;
1898         if (trace_startsolid)
1899             continue;
1900         if (trace_dphitcontents & badcontents)
1901             continue;
1902         if (trace_dphitq3surfaceflags & badsurfaceflags)
1903             continue;
1904
1905         // rule 2: if we are too high, lower the point
1906         if (trace_fraction * delta_z > maxaboveground)
1907             start = trace_endpos + '0 0 1' * maxaboveground;
1908         enddown = trace_endpos;
1909
1910         // rule 3: make sure we aren't outside the map. This only works
1911         // for somewhat well formed maps. A good rule of thumb is that
1912         // the map should have a convex outside hull.
1913         // these can be traceLINES as we already verified the starting box
1914         mstart = start + 0.5 * (e.mins + e.maxs);
1915         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1916         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1917             continue;
1918         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1919         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1920             continue;
1921         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1922         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1923             continue;
1924         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1925         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1926             continue;
1927         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1928         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1929             continue;
1930
1931         // rule 4: we must "see" some spawnpoint or item
1932         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1933                 if(checkpvs(mstart, sp))
1934                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1935                                 break;
1936         if(!sp)
1937         {
1938                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1939                         if(checkpvs(mstart, sp))
1940                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1941                                         break;
1942                 if(!sp)
1943                         continue;
1944         }
1945
1946         // find a random vector to "look at"
1947         end_x = org_x + random() * delta_x;
1948         end_y = org_y + random() * delta_y;
1949         end_z = org_z + random() * delta_z;
1950         end = start + normalize(end - start) * vlen(delta);
1951
1952         // rule 4: start TO end must not be too short
1953         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1954         if (trace_startsolid)
1955             continue;
1956         if (trace_fraction < minviewdistance / vlen(delta))
1957             continue;
1958
1959         // rule 5: don't want to look at sky
1960         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1961             continue;
1962
1963         // rule 6: we must not end up in trigger_hurt
1964         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1965             continue;
1966
1967         break;
1968     }
1969
1970     e.dphitcontentsmask = m;
1971
1972     if (i < attempts)
1973     {
1974         setorigin(e, start);
1975         e.angles = vectoangles(end - start);
1976         dprint("Needed ", ftos(i + 1), " attempts\n");
1977         return TRUE;
1978     }
1979     else
1980         return FALSE;
1981 }
1982
1983 void write_recordmarker(entity pl, float tstart, float dt)
1984 {
1985     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1986
1987     // also write a marker into demo files for demotc-race-record-extractor to find
1988     stuffcmd(pl,
1989              strcat(
1990                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1991                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1992 }
1993
1994 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1995 {
1996         switch(algn)
1997         {
1998                 default:
1999                 case 3: // right
2000                         break;
2001
2002                 case 4: // left
2003                         vecs_y = -vecs_y;
2004                         break;
2005
2006                 case 1:
2007                         if(allowcenter) // 2: allow center handedness
2008                         {
2009                                 // center
2010                                 vecs_y = 0;
2011                                 vecs_z -= 2;
2012                         }
2013                         else
2014                         {
2015                                 // right
2016                         }
2017                         break;
2018
2019                 case 2:
2020                         if(allowcenter) // 2: allow center handedness
2021                         {
2022                                 // center
2023                                 vecs_y = 0;
2024                                 vecs_z -= 2;
2025                         }
2026                         else
2027                         {
2028                                 // left
2029                                 vecs_y = -vecs_y;
2030                         }
2031                         break;
2032         }
2033         return vecs;
2034 }
2035
2036 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2037 {
2038         string s;
2039         vector v;
2040
2041         if (autocvar_g_shootfromeye)
2042         {
2043                 if (visual)
2044                 {
2045                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2046                         else { vecs_y = 0; vecs_z -= 2; }
2047                 }
2048                 else
2049                 {
2050                         vecs_y = 0;
2051                         vecs_z = 0;
2052                 }
2053         }
2054         else if (autocvar_g_shootfromcenter)
2055         {
2056                 vecs_y = 0;
2057                 vecs_z -= 2;
2058         }
2059         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2060         {
2061                 v = stov(s);
2062                 if (y_is_right)
2063                         v_y = -v_y;
2064                 if (v_x != 0)
2065                         vecs_x = v_x;
2066                 vecs_y = v_y;
2067                 vecs_z = v_z;
2068         }
2069         else if (autocvar_g_shootfromclient)
2070         {
2071                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2072         }
2073         return vecs;
2074 }
2075
2076 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2077 {
2078         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2079 }
2080
2081
2082 void attach_sameorigin(entity e, entity to, string tag)
2083 {
2084     vector org, t_forward, t_left, t_up, e_forward, e_up;
2085     float tagscale;
2086
2087     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2088     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2089     t_forward = v_forward * tagscale;
2090     t_left = v_right * -tagscale;
2091     t_up = v_up * tagscale;
2092
2093     e.origin_x = org * t_forward;
2094     e.origin_y = org * t_left;
2095     e.origin_z = org * t_up;
2096
2097     // current forward and up directions
2098     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2099                 e.angles = AnglesTransform_FromVAngles(e.angles);
2100         else
2101                 e.angles = AnglesTransform_FromAngles(e.angles);
2102     fixedmakevectors(e.angles);
2103
2104     // untransform forward, up!
2105     e_forward_x = v_forward * t_forward;
2106     e_forward_y = v_forward * t_left;
2107     e_forward_z = v_forward * t_up;
2108     e_up_x = v_up * t_forward;
2109     e_up_y = v_up * t_left;
2110     e_up_z = v_up * t_up;
2111
2112     e.angles = fixedvectoangles2(e_forward, e_up);
2113     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2114                 e.angles = AnglesTransform_ToVAngles(e.angles);
2115         else
2116                 e.angles = AnglesTransform_ToAngles(e.angles);
2117
2118     setattachment(e, to, tag);
2119     setorigin(e, e.origin);
2120 }
2121
2122 void detach_sameorigin(entity e)
2123 {
2124     vector org;
2125     org = gettaginfo(e, 0);
2126     e.angles = fixedvectoangles2(v_forward, v_up);
2127     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2128                 e.angles = AnglesTransform_ToVAngles(e.angles);
2129         else
2130                 e.angles = AnglesTransform_ToAngles(e.angles);
2131     setorigin(e, org);
2132     setattachment(e, world, "");
2133     setorigin(e, e.origin);
2134 }
2135
2136 void follow_sameorigin(entity e, entity to)
2137 {
2138     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2139     e.aiment = to; // make the hole follow bmodel
2140     e.punchangle = to.angles; // the original angles of bmodel
2141     e.view_ofs = e.origin - to.origin; // relative origin
2142     e.v_angle = e.angles - to.angles; // relative angles
2143 }
2144
2145 void unfollow_sameorigin(entity e)
2146 {
2147     e.movetype = MOVETYPE_NONE;
2148 }
2149
2150 entity gettaginfo_relative_ent;
2151 vector gettaginfo_relative(entity e, float tag)
2152 {
2153     if (!gettaginfo_relative_ent)
2154     {
2155         gettaginfo_relative_ent = spawn();
2156         gettaginfo_relative_ent.effects = EF_NODRAW;
2157     }
2158     gettaginfo_relative_ent.model = e.model;
2159     gettaginfo_relative_ent.modelindex = e.modelindex;
2160     gettaginfo_relative_ent.frame = e.frame;
2161     return gettaginfo(gettaginfo_relative_ent, tag);
2162 }
2163
2164 .float scale2;
2165
2166 float modeleffect_SendEntity(entity to, float sf)
2167 {
2168         float f;
2169         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2170
2171         f = 0;
2172         if(self.velocity != '0 0 0')
2173                 f |= 1;
2174         if(self.angles != '0 0 0')
2175                 f |= 2;
2176         if(self.avelocity != '0 0 0')
2177                 f |= 4;
2178
2179         WriteByte(MSG_ENTITY, f);
2180         WriteShort(MSG_ENTITY, self.modelindex);
2181         WriteByte(MSG_ENTITY, self.skin);
2182         WriteByte(MSG_ENTITY, self.frame);
2183         WriteCoord(MSG_ENTITY, self.origin_x);
2184         WriteCoord(MSG_ENTITY, self.origin_y);
2185         WriteCoord(MSG_ENTITY, self.origin_z);
2186         if(f & 1)
2187         {
2188                 WriteCoord(MSG_ENTITY, self.velocity_x);
2189                 WriteCoord(MSG_ENTITY, self.velocity_y);
2190                 WriteCoord(MSG_ENTITY, self.velocity_z);
2191         }
2192         if(f & 2)
2193         {
2194                 WriteCoord(MSG_ENTITY, self.angles_x);
2195                 WriteCoord(MSG_ENTITY, self.angles_y);
2196                 WriteCoord(MSG_ENTITY, self.angles_z);
2197         }
2198         if(f & 4)
2199         {
2200                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2201                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2202                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2203         }
2204         WriteShort(MSG_ENTITY, self.scale * 256.0);
2205         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2206         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2207         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2208         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2209
2210         return TRUE;
2211 }
2212
2213 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2214 {
2215         entity e;
2216         float sz;
2217         e = spawn();
2218         e.classname = "modeleffect";
2219         setmodel(e, m);
2220         e.frame = f;
2221         setorigin(e, o);
2222         e.velocity = v;
2223         e.angles = ang;
2224         e.avelocity = angv;
2225         e.alpha = a;
2226         e.teleport_time = t1;
2227         e.fade_time = t2;
2228         e.skin = s;
2229         if(s0 >= 0)
2230                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2231         else
2232                 e.scale = -s0;
2233         if(s2 >= 0)
2234                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2235         else
2236                 e.scale2 = -s2;
2237         sz = max(e.scale, e.scale2);
2238         setsize(e, e.mins * sz, e.maxs * sz);
2239         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2240 }
2241
2242 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2243 {
2244         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2245 }
2246
2247 float randombit(float bits)
2248 {
2249         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2250                 return bits;
2251
2252         float n, f, b, r;
2253
2254         r = random();
2255         b = 0;
2256         n = 0;
2257
2258         for(f = 1; f <= bits; f *= 2)
2259         {
2260                 if(bits & f)
2261                 {
2262                         ++n;
2263                         r *= n;
2264                         if(r <= 1)
2265                                 b = f;
2266                         else
2267                                 r = (r - 1) / (n - 1);
2268                 }
2269         }
2270
2271         return b;
2272 }
2273
2274 float randombits(float bits, float k, float error_return)
2275 {
2276         float r;
2277         r = 0;
2278         while(k > 0 && bits != r)
2279         {
2280                 r += randombit(bits - r);
2281                 --k;
2282         }
2283         if(error_return)
2284                 if(k > 0)
2285                         return -1; // all
2286         return r;
2287 }
2288
2289 void randombit_test(float bits, float iter)
2290 {
2291         while(iter > 0)
2292         {
2293                 print(ftos(randombit(bits)), "\n");
2294                 --iter;
2295         }
2296 }
2297
2298 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2299 {
2300         if(halflifedist > 0)
2301                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2302         else if(halflifedist < 0)
2303                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2304         else
2305                 return 1;
2306 }
2307
2308
2309
2310
2311 #ifdef RELEASE
2312 #define cvar_string_normal builtin_cvar_string
2313 #define cvar_normal builtin_cvar
2314 #else
2315 string cvar_string_normal(string n)
2316 {
2317         if (!(cvar_type(n) & 1))
2318                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2319         return builtin_cvar_string(n);
2320 }
2321
2322 float cvar_normal(string n)
2323 {
2324         return stof(cvar_string_normal(n));
2325 }
2326 #endif
2327 #define cvar_set_normal builtin_cvar_set
2328
2329 void defer_think()
2330 {
2331     entity oself;
2332
2333     oself           = self;
2334     self            = self.owner;
2335     oself.think     = SUB_Remove;
2336     oself.nextthink = time;
2337
2338     oself.use();
2339 }
2340
2341 /*
2342     Execute func() after time + fdelay.
2343     self when func is executed = self when defer is called
2344 */
2345 void defer(float fdelay, void() func)
2346 {
2347     entity e;
2348
2349     e           = spawn();
2350     e.owner     = self;
2351     e.use       = func;
2352     e.think     = defer_think;
2353     e.nextthink = time + fdelay;
2354 }
2355
2356 .string aiment_classname;
2357 .float aiment_deadflag;
2358 void SetMovetypeFollow(entity ent, entity e)
2359 {
2360         // FIXME this may not be warpzone aware
2361         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2362         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2363         ent.aiment = e; // make the hole follow bmodel
2364         ent.punchangle = e.angles; // the original angles of bmodel
2365         ent.view_ofs = ent.origin - e.origin; // relative origin
2366         ent.v_angle = ent.angles - e.angles; // relative angles
2367         ent.aiment_classname = strzone(e.classname);
2368         ent.aiment_deadflag = e.deadflag;
2369 }
2370 void UnsetMovetypeFollow(entity ent)
2371 {
2372         ent.movetype = MOVETYPE_FLY;
2373         PROJECTILE_MAKETRIGGER(ent);
2374         ent.aiment = world;
2375 }
2376 float LostMovetypeFollow(entity ent)
2377 {
2378 /*
2379         if(ent.movetype != MOVETYPE_FOLLOW)
2380                 if(ent.aiment)
2381                         error("???");
2382 */
2383         if(ent.aiment)
2384         {
2385                 if(ent.aiment.classname != ent.aiment_classname)
2386                         return 1;
2387                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2388                         return 1;
2389         }
2390         return 0;
2391 }
2392
2393 float isPushable(entity e)
2394 {
2395         if(e.iscreature)
2396                 return TRUE;
2397         if(e.pushable)
2398                 return TRUE;
2399         switch(e.classname)
2400         {
2401                 case "body":
2402                 case "droppedweapon":
2403                 case "keepawayball":
2404                 case "nexball_basketball":
2405                 case "nexball_football":
2406                         return TRUE;
2407                 case "bullet": // antilagged bullets can't hit this either
2408                         return FALSE;
2409         }
2410         if (e.projectiledeathtype)
2411                 return TRUE;
2412         return FALSE;
2413 }