qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = W_Name(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else replacement = "batteries"; // ;)
 363                 } else if (escape == "x") {
 364                         replacement = cursor_ent.netname;
 365                         if (replacement == "" || !cursor_ent)
 366                                 replacement = "nothing";
 367                 } else if (escape == "s")
 368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 369                 else if (escape == "S")
 370                         replacement = ftos(vlen(self.velocity));
 371
 372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 373                 p = p + strlen(replacement);
 374         }
 375         return msg;
 376 }
 377
 378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 379         return (value == 0) ? FALSE : TRUE;
 380 }
 381
 382 /*
 383 =============
 384 GetCvars
 385 =============
 386 Called with:
 387   0:  sends the request
 388   >0: receives a cvar from name=argv(f) value=argv(f+1)
 389 */
 390 void GetCvars_handleString(string thisname, float f, .string field, string name)
 391 {
 392         if (f < 0)
 393         {
 394                 if (self.field)
 395                         strunzone(self.field);
 396                 self.field = string_null;
 397         }
 398         else if (f > 0)
 399         {
 400                 if (thisname == name)
 401                 {
 402                         if (self.field)
 403                                 strunzone(self.field);
 404                         self.field = strzone(argv(f + 1));
 405                 }
 406         }
 407         else
 408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 409 }
 410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 411 {
 412         GetCvars_handleString(thisname, f, field, name);
 413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 414                 if (thisname == name)
 415                 {
 416                         string s;
 417                         s = func(strcat1(self.field));
 418                         if (s != self.field)
 419                         {
 420                                 strunzone(self.field);
 421                                 self.field = strzone(s);
 422                         }
 423                 }
 424 }
 425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 426 {
 427         if (f < 0)
 428         {
 429         }
 430         else if (f > 0)
 431         {
 432                 if (thisname == name)
 433                         self.field = stof(argv(f + 1));
 434         }
 435         else
 436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 437 }
 438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 439 {
 440         if (f < 0)
 441         {
 442         }
 443         else if (f > 0)
 444         {
 445                 if (thisname == name)
 446                 {
 447                         if(!self.field)
 448                         {
 449                                 self.field = stof(argv(f + 1));
 450                                 if(!self.field)
 451                                         self.field = -1;
 452                         }
 453                 }
 454         }
 455         else
 456         {
 457                 if(!self.field)
 458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 459         }
 460 }
 461 float w_getbestweapon(entity e);
 462 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 463 {
 464         string o;
 465         o = W_FixWeaponOrder_ForceComplete(wo);
 466         if(self.weaponorder_byimpulse)
 467         {
 468                 strunzone(self.weaponorder_byimpulse);
 469                 self.weaponorder_byimpulse = string_null;
 470         }
 471         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 472         return o;
 473 }
 474 void GetCvars(float f)
 475 {
 476         string s = string_null;
 477
 478         if (f > 0)
 479                 s = strcat1(argv(f));
 480
 481         get_cvars_f = f;
 482         get_cvars_s = s;
 483
 484         MUTATOR_CALLHOOK(GetCvars);
 485
 486         Notification_GetCvars();
 487
 488         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 489         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 490         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 491         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 492         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 505         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 506         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 508         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 510         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 511
 512         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 513         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 514
 515         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 516         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 517         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 518         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 519         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 520
 521         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 522         if (f > 0)
 523         {
 524                 if (s == "cl_weaponpriority")
 525                         self.switchweapon = w_getbestweapon(self);
 526                 if (s == "cl_allow_uidtracking")
 527                         PlayerStats_AddPlayer(self);
 528         }
 529 }
 530
 531 // decolorizes and team colors the player name when needed
 532 string playername(entity p)
 533 {
 534     string t;
 535     if (teamplay && !intermission_running && IS_PLAYER(p))
 536     {
 537         t = Team_ColorCode(p.team);
 538         return strcat(t, strdecolorize(p.netname));
 539     }
 540     else
 541         return p.netname;
 542 }
 543
 544 vector randompos(vector m1, vector m2)
 545 {
 546     vector v;
 547     m2 = m2 - m1;
 548     v_x = m2_x * random() + m1_x;
 549     v_y = m2_y * random() + m1_y;
 550     v_z = m2_z * random() + m1_z;
 551     return  v;
 552 }
 553
 554 //#NO AUTOCVARS START
 555
 556 float g_pickup_shells;
 557 float g_pickup_shells_max;
 558 float g_pickup_nails;
 559 float g_pickup_nails_max;
 560 float g_pickup_rockets;
 561 float g_pickup_rockets_max;
 562 float g_pickup_cells;
 563 float g_pickup_cells_max;
 564 float g_pickup_fuel;
 565 float g_pickup_fuel_jetpack;
 566 float g_pickup_fuel_max;
 567 float g_pickup_armorsmall;
 568 float g_pickup_armorsmall_max;
 569 float g_pickup_armorsmall_anyway;
 570 float g_pickup_armormedium;
 571 float g_pickup_armormedium_max;
 572 float g_pickup_armormedium_anyway;
 573 float g_pickup_armorbig;
 574 float g_pickup_armorbig_max;
 575 float g_pickup_armorbig_anyway;
 576 float g_pickup_armorlarge;
 577 float g_pickup_armorlarge_max;
 578 float g_pickup_armorlarge_anyway;
 579 float g_pickup_healthsmall;
 580 float g_pickup_healthsmall_max;
 581 float g_pickup_healthsmall_anyway;
 582 float g_pickup_healthmedium;
 583 float g_pickup_healthmedium_max;
 584 float g_pickup_healthmedium_anyway;
 585 float g_pickup_healthlarge;
 586 float g_pickup_healthlarge_max;
 587 float g_pickup_healthlarge_anyway;
 588 float g_pickup_healthmega;
 589 float g_pickup_healthmega_max;
 590 float g_pickup_healthmega_anyway;
 591 float g_pickup_ammo_anyway;
 592 float g_pickup_weapons_anyway;
 593 float g_weaponarena;
 594 WEPSET_DECLARE_A(g_weaponarena_weapons);
 595 float g_weaponarena_random;
 596 float g_weaponarena_random_with_laser;
 597 string g_weaponarena_list;
 598 float g_weaponspeedfactor;
 599 float g_weaponratefactor;
 600 float g_weapondamagefactor;
 601 float g_weaponforcefactor;
 602 float g_weaponspreadfactor;
 603
 604 WEPSET_DECLARE_A(start_weapons);
 605 WEPSET_DECLARE_A(start_weapons_default);
 606 WEPSET_DECLARE_A(start_weapons_defaultmask);
 607 float start_items;
 608 float start_ammo_shells;
 609 float start_ammo_nails;
 610 float start_ammo_rockets;
 611 float start_ammo_cells;
 612 float start_ammo_fuel;
 613 float start_health;
 614 float start_armorvalue;
 615 WEPSET_DECLARE_A(warmup_start_weapons);
 616 WEPSET_DECLARE_A(warmup_start_weapons_default);
 617 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 618 float warmup_start_ammo_shells;
 619 float warmup_start_ammo_nails;
 620 float warmup_start_ammo_rockets;
 621 float warmup_start_ammo_cells;
 622 float warmup_start_ammo_fuel;
 623 float warmup_start_health;
 624 float warmup_start_armorvalue;
 625 float g_weapon_stay;
 626
 627 entity get_weaponinfo(float w);
 628
 629 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 630 {
 631         var float i = weaponinfo.weapon;
 632         var float d = 0;
 633
 634         if (!i)
 635                 return 0;
 636
 637         if (g_lms || g_ca || allguns)
 638         {
 639                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 640                         d = TRUE;
 641                 else
 642                         d = FALSE;
 643         }
 644         else if (g_cts)
 645                 d = (i == WEP_SHOTGUN);
 646         else if (g_nexball)
 647                 d = 0; // weapon is set a few lines later
 648         else
 649                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 650
 651         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 652                 d |= (i == WEP_HOOK);
 653         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 654                 d = 0;
 655
 656         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 657
 658         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 659
 660         // bit order in t:
 661         // 1: want or not
 662         // 2: is default?
 663         // 4: is set by default?
 664         if(t < 0)
 665                 t = 4 | (3 * d);
 666         else
 667                 t |= (2 * d);
 668
 669         return t;
 670 }
 671
 672 void readplayerstartcvars()
 673 {
 674         entity e;
 675         float i, j, t;
 676         string s;
 677
 678         // initialize starting values for players
 679         WEPSET_CLEAR_A(start_weapons);
 680         WEPSET_CLEAR_A(start_weapons_default);
 681         WEPSET_CLEAR_A(start_weapons_defaultmask);
 682         start_items = 0;
 683         start_ammo_shells = 0;
 684         start_ammo_nails = 0;
 685         start_ammo_rockets = 0;
 686         start_ammo_cells = 0;
 687         start_health = cvar("g_balance_health_start");
 688         start_armorvalue = cvar("g_balance_armor_start");
 689
 690         g_weaponarena = 0;
 691         WEPSET_CLEAR_A(g_weaponarena_weapons);
 692
 693         s = cvar_string("g_weaponarena");
 694         if (s == "0" || s == "")
 695         {
 696                 if(g_ca)
 697                         s = "most";
 698         }
 699
 700         if (s == "0" || s == "")
 701         {
 702                 // no arena
 703         }
 704         else if (s == "off")
 705         {
 706                 // forcibly turn off weaponarena
 707         }
 708         else if (s == "all")
 709         {
 710                 g_weaponarena = 1;
 711                 g_weaponarena_list = "All Weapons";
 712                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 713                 {
 714                         e = get_weaponinfo(j);
 715                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 716                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 717                 }
 718         }
 719         else if (s == "most")
 720         {
 721                 g_weaponarena = 1;
 722                 g_weaponarena_list = "Most Weapons";
 723                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 724                 {
 725                         e = get_weaponinfo(j);
 726                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 727                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 728                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 729                 }
 730         }
 731         else if (s == "none")
 732         {
 733                 g_weaponarena = 1;
 734                 g_weaponarena_list = "No Weapons";
 735         }
 736         else
 737         {
 738                 g_weaponarena = 1;
 739                 t = tokenize_console(s);
 740                 g_weaponarena_list = "";
 741                 for (i = 0; i < t; ++i)
 742                 {
 743                         s = argv(i);
 744                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 745                         {
 746                                 e = get_weaponinfo(j);
 747                                 if (e.netname == s)
 748                                 {
 749                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 750                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 751                                         break;
 752                                 }
 753                         }
 754                         if (j > WEP_LAST)
 755                         {
 756                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 757                         }
 758                 }
 759                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 760         }
 761
 762         if(g_weaponarena)
 763                 g_weaponarena_random = cvar("g_weaponarena_random");
 764         else
 765                 g_weaponarena_random = 0;
 766         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 767
 768         if (g_weaponarena)
 769         {
 770                 g_pinata = 0; // incompatible
 771                 g_weapon_stay = 0; // incompatible
 772                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 773                 start_items |= IT_UNLIMITED_AMMO;
 774         }
 775         else
 776         {
 777                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 778                 {
 779                         e = get_weaponinfo(i);
 780                         float w = want_weapon("g_start_weapon_", e, FALSE);
 781                         if(w & 1)
 782                                 WEPSET_OR_AW(start_weapons, i);
 783                         if(w & 2)
 784                                 WEPSET_OR_AW(start_weapons_default, i);
 785                         if(w & 4)
 786                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 787                 }
 788         }
 789
 790         if(!cvar("g_use_ammunition"))
 791                 start_items |= IT_UNLIMITED_AMMO;
 792
 793         if(cvar("g_nexball"))
 794                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 795
 796         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 797         {
 798                 start_ammo_rockets = 999;
 799                 start_ammo_shells = 999;
 800                 start_ammo_cells = 999;
 801                 start_ammo_nails = 999;
 802                 start_ammo_fuel = 999;
 803         }
 804         else
 805         {
 806                 start_ammo_shells = cvar("g_start_ammo_shells");
 807                 start_ammo_nails = cvar("g_start_ammo_nails");
 808                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 809                 start_ammo_cells = cvar("g_start_ammo_cells");
 810                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 811         }
 812
 813         if (inWarmupStage)
 814         {
 815                 warmup_start_ammo_shells = start_ammo_shells;
 816                 warmup_start_ammo_nails = start_ammo_nails;
 817                 warmup_start_ammo_rockets = start_ammo_rockets;
 818                 warmup_start_ammo_cells = start_ammo_cells;
 819                 warmup_start_ammo_fuel = start_ammo_fuel;
 820                 warmup_start_health = start_health;
 821                 warmup_start_armorvalue = start_armorvalue;
 822                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 823                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 824                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 825
 826                 if (!g_weaponarena && !g_ca)
 827                 {
 828                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 829                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 830                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 831                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 832                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 833                         warmup_start_health = cvar("g_warmup_start_health");
 834                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 835                         WEPSET_CLEAR_A(warmup_start_weapons);
 836                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 837                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 838                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 839                         {
 840                                 e = get_weaponinfo(i);
 841                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 842                                 if(w & 1)
 843                                         WEPSET_OR_AW(warmup_start_weapons, i);
 844                                 if(w & 2)
 845                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 846                                 if(w & 4)
 847                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 848                         }
 849                 }
 850         }
 851
 852         if (g_jetpack)
 853                 start_items |= IT_JETPACK;
 854
 855         MUTATOR_CALLHOOK(SetStartItems);
 856
 857         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 858         {
 859                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 860                 start_items |= IT_FUEL_REGEN;
 861                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 863         }
 864
 865         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 866         {
 867                 e = get_weaponinfo(i);
 868                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 869                         weapon_action(i, WR_PRECACHE);
 870         }
 871
 872         start_ammo_shells = max(0, start_ammo_shells);
 873         start_ammo_nails = max(0, start_ammo_nails);
 874         start_ammo_cells = max(0, start_ammo_cells);
 875         start_ammo_rockets = max(0, start_ammo_rockets);
 876         start_ammo_fuel = max(0, start_ammo_fuel);
 877
 878         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 879         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 880         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 881         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 882         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 883 }
 884
 885 float g_bugrigs;
 886 float g_bugrigs_planar_movement;
 887 float g_bugrigs_planar_movement_car_jumping;
 888 float g_bugrigs_reverse_spinning;
 889 float g_bugrigs_reverse_speeding;
 890 float g_bugrigs_reverse_stopping;
 891 float g_bugrigs_air_steering;
 892 float g_bugrigs_angle_smoothing;
 893 float g_bugrigs_friction_floor;
 894 float g_bugrigs_friction_brake;
 895 float g_bugrigs_friction_air;
 896 float g_bugrigs_accel;
 897 float g_bugrigs_speed_ref;
 898 float g_bugrigs_speed_pow;
 899 float g_bugrigs_steer;
 900
 901 float sv_autotaunt;
 902 float sv_taunt;
 903
 904 string GetGametype(); // g_world.qc
 905 void readlevelcvars(void)
 906 {
 907         // load mutators
 908         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 909                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 910
 911         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 912         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, 1);
 913         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 914         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 915         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 916         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 917         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 918         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 921         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 922         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 923
 924         #undef CHECK_MUTATOR_ADD
 925
 926         if(cvar("sv_allow_fullbright"))
 927                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 928
 929     g_bugrigs = cvar("g_bugrigs");
 930     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 931     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 932     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 933     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 934     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 935     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 936     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 937     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 938     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 939     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 940     g_bugrigs_accel = cvar("g_bugrigs_accel");
 941     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 942     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 943     g_bugrigs_steer = cvar("g_bugrigs_steer");
 944
 945         g_minstagib = cvar("g_minstagib");
 946
 947         sv_clones = cvar("sv_clones");
 948         sv_foginterval = cvar("sv_foginterval");
 949         g_cloaked = cvar("g_cloaked");
 950     if(g_cts)
 951         g_cloaked = 1; // always enable cloak in CTS
 952         g_jump_grunt = cvar("g_jump_grunt");
 953         g_footsteps = cvar("g_footsteps");
 954         g_grappling_hook = cvar("g_grappling_hook");
 955         g_jetpack = cvar("g_jetpack");
 956         g_midair = cvar("g_midair");
 957         g_norecoil = cvar("g_norecoil");
 958         g_bloodloss = cvar("g_bloodloss");
 959         sv_maxidle = cvar("sv_maxidle");
 960         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 961         sv_autotaunt = cvar("sv_autotaunt");
 962         sv_taunt = cvar("sv_taunt");
 963
 964         inWarmupStage = cvar("g_warmup");
 965         g_warmup_limit = cvar("g_warmup_limit");
 966         g_warmup_allguns = cvar("g_warmup_allguns");
 967         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 968
 969         if ((g_race && g_race_qualifying == 2) || g_arena || g_minstagib || g_assault || cvar("g_campaign"))
 970                 inWarmupStage = 0; // these modes cannot work together, sorry
 971
 972         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 973         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 974         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 975         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 976         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 977         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 978         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 979         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 980         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 981         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 982         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 983         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 984         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 985         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 986
 987         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 988         g_weaponratefactor = cvar("g_weaponratefactor");
 989         g_weapondamagefactor = cvar("g_weapondamagefactor");
 990         g_weaponforcefactor = cvar("g_weaponforcefactor");
 991         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 992
 993         g_pickup_shells = cvar("g_pickup_shells");
 994         g_pickup_shells_max = cvar("g_pickup_shells_max");
 995         g_pickup_nails = cvar("g_pickup_nails");
 996         g_pickup_nails_max = cvar("g_pickup_nails_max");
 997         g_pickup_rockets = cvar("g_pickup_rockets");
 998         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 999         g_pickup_cells = cvar("g_pickup_cells");
1000         g_pickup_cells_max = cvar("g_pickup_cells_max");
1001         g_pickup_fuel = cvar("g_pickup_fuel");
1002         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1003         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1004         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1005         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1006         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1007         g_pickup_armormedium = cvar("g_pickup_armormedium");
1008         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1009         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1010         g_pickup_armorbig = cvar("g_pickup_armorbig");
1011         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1012         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1013         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1014         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1015         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1016         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1017         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1018         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1019         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1020         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1021         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1022         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1023         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1024         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1025         g_pickup_healthmega = cvar("g_pickup_healthmega");
1026         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1027         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1028
1029         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1030         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1031
1032         g_pinata = cvar("g_pinata");
1033
1034     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1035     if(!g_weapon_stay)
1036         g_weapon_stay = cvar("g_weapon_stay");
1037
1038         if not(inWarmupStage)
1039                 game_starttime = time + cvar("g_start_delay");
1040
1041         readplayerstartcvars();
1042 }
1043
1044 //#NO AUTOCVARS END
1045
1046 // Sound functions
1047 string precache_sound (string s) = #19;
1048 float precache_sound_index (string s) = #19;
1049
1050 #define SND_VOLUME      1
1051 #define SND_ATTENUATION 2
1052 #define SND_LARGEENTITY 8
1053 #define SND_LARGESOUND  16
1054
1055 float sound_allowed(float dest, entity e)
1056 {
1057     // sounds from world may always pass
1058     for (;;)
1059     {
1060         if (e.classname == "body")
1061             e = e.enemy;
1062         else if (e.realowner && e.realowner != e)
1063             e = e.realowner;
1064         else if (e.owner && e.owner != e)
1065             e = e.owner;
1066         else
1067             break;
1068     }
1069     // sounds to self may always pass
1070     if (dest == MSG_ONE)
1071         if (e == msg_entity)
1072             return TRUE;
1073     // sounds by players can be removed
1074     if (autocvar_bot_sound_monopoly)
1075         if (IS_REAL_CLIENT(e))
1076             return FALSE;
1077     // anything else may pass
1078     return TRUE;
1079 }
1080
1081 #ifdef COMPAT_XON010_CHANNELS
1082 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1083 void sound(entity e, float chan, string samp, float vol, float atten)
1084 {
1085     if (!sound_allowed(MSG_BROADCAST, e))
1086         return;
1087     builtin_sound(e, chan, samp, vol, atten);
1088 }
1089 #else
1090 #undef sound
1091 void sound(entity e, float chan, string samp, float vol, float atten)
1092 {
1093     if (!sound_allowed(MSG_BROADCAST, e))
1094         return;
1095     sound7(e, chan, samp, vol, atten, 0, 0);
1096 }
1097 #endif
1098
1099 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1100 {
1101     float entno, idx;
1102
1103     if (!sound_allowed(dest, e))
1104         return;
1105
1106     entno = num_for_edict(e);
1107     idx = precache_sound_index(samp);
1108
1109     float sflags;
1110     sflags = 0;
1111
1112     atten = floor(atten * 64);
1113     vol = floor(vol * 255);
1114
1115     if (vol != 255)
1116         sflags |= SND_VOLUME;
1117     if (atten != 64)
1118         sflags |= SND_ATTENUATION;
1119     if (entno >= 8192 || chan < 0 || chan > 7)
1120         sflags |= SND_LARGEENTITY;
1121     if (idx >= 256)
1122         sflags |= SND_LARGESOUND;
1123
1124     WriteByte(dest, SVC_SOUND);
1125     WriteByte(dest, sflags);
1126     if (sflags & SND_VOLUME)
1127         WriteByte(dest, vol);
1128     if (sflags & SND_ATTENUATION)
1129         WriteByte(dest, atten);
1130     if (sflags & SND_LARGEENTITY)
1131     {
1132         WriteShort(dest, entno);
1133         WriteByte(dest, chan);
1134     }
1135     else
1136     {
1137         WriteShort(dest, entno * 8 + chan);
1138     }
1139     if (sflags & SND_LARGESOUND)
1140         WriteShort(dest, idx);
1141     else
1142         WriteByte(dest, idx);
1143
1144     WriteCoord(dest, o_x);
1145     WriteCoord(dest, o_y);
1146     WriteCoord(dest, o_z);
1147 }
1148 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1149 {
1150     vector o;
1151
1152     if (!sound_allowed(dest, e))
1153         return;
1154
1155     o = e.origin + 0.5 * (e.mins + e.maxs);
1156     soundtoat(dest, e, o, chan, samp, vol, atten);
1157 }
1158 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1159 {
1160     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1161 }
1162 void stopsoundto(float dest, entity e, float chan)
1163 {
1164     float entno;
1165
1166     if (!sound_allowed(dest, e))
1167         return;
1168
1169     entno = num_for_edict(e);
1170
1171     if (entno >= 8192 || chan < 0 || chan > 7)
1172     {
1173         float idx, sflags;
1174         idx = precache_sound_index("misc/null.wav");
1175         sflags = SND_LARGEENTITY;
1176         if (idx >= 256)
1177             sflags |= SND_LARGESOUND;
1178         WriteByte(dest, SVC_SOUND);
1179         WriteByte(dest, sflags);
1180         WriteShort(dest, entno);
1181         WriteByte(dest, chan);
1182         if (sflags & SND_LARGESOUND)
1183             WriteShort(dest, idx);
1184         else
1185             WriteByte(dest, idx);
1186         WriteCoord(dest, e.origin_x);
1187         WriteCoord(dest, e.origin_y);
1188         WriteCoord(dest, e.origin_z);
1189     }
1190     else
1191     {
1192         WriteByte(dest, SVC_STOPSOUND);
1193         WriteShort(dest, entno * 8 + chan);
1194     }
1195 }
1196 void stopsound(entity e, float chan)
1197 {
1198     if (!sound_allowed(MSG_BROADCAST, e))
1199         return;
1200
1201     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1202     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1203 }
1204
1205 void play2(entity e, string filename)
1206 {
1207     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1208     msg_entity = e;
1209     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1210 }
1211
1212 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1213 .float spamtime;
1214 float spamsound(entity e, float chan, string samp, float vol, float atten)
1215 {
1216     if (!sound_allowed(MSG_BROADCAST, e))
1217         return FALSE;
1218
1219     if (time > e.spamtime)
1220     {
1221         e.spamtime = time;
1222         sound(e, chan, samp, vol, atten);
1223         return TRUE;
1224     }
1225     return FALSE;
1226 }
1227
1228 void play2team(float t, string filename)
1229 {
1230     entity head;
1231
1232     if (autocvar_bot_sound_monopoly)
1233         return;
1234
1235     FOR_EACH_REALPLAYER(head)
1236     {
1237         if (head.team == t)
1238             play2(head, filename);
1239     }
1240 }
1241
1242 void play2all(string samp)
1243 {
1244     if (autocvar_bot_sound_monopoly)
1245         return;
1246
1247     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1248 }
1249
1250 void PrecachePlayerSounds(string f);
1251 void precache_playermodel(string m)
1252 {
1253         float globhandle, i, n;
1254         string f;
1255
1256         if(substring(m, -9,5) == "_lod1")
1257                 return;
1258         if(substring(m, -9,5) == "_lod2")
1259                 return;
1260         precache_model(m);
1261         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1262         if(fexists(f))
1263                 precache_model(f);
1264         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1265         if(fexists(f))
1266                 precache_model(f);
1267
1268         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1269         if (globhandle < 0)
1270                 return;
1271         n = search_getsize(globhandle);
1272         for (i = 0; i < n; ++i)
1273         {
1274                 //print(search_getfilename(globhandle, i), "\n");
1275                 f = search_getfilename(globhandle, i);
1276                 PrecachePlayerSounds(f);
1277         }
1278         search_end(globhandle);
1279 }
1280 void precache_all_playermodels(string pattern)
1281 {
1282         float globhandle, i, n;
1283         string f;
1284
1285         globhandle = search_begin(pattern, TRUE, FALSE);
1286         if (globhandle < 0)
1287                 return;
1288         n = search_getsize(globhandle);
1289         for (i = 0; i < n; ++i)
1290         {
1291                 //print(search_getfilename(globhandle, i), "\n");
1292                 f = search_getfilename(globhandle, i);
1293                 precache_playermodel(f);
1294         }
1295         search_end(globhandle);
1296 }
1297
1298 void precache()
1299 {
1300     // gamemode related things
1301     precache_model ("models/misc/chatbubble.spr");
1302
1303 #ifdef TTURRETS_ENABLED
1304     if (autocvar_g_turrets)
1305         turrets_precash();
1306 #endif
1307
1308     // Precache all player models if desired
1309     if (autocvar_sv_precacheplayermodels)
1310     {
1311         PrecachePlayerSounds("sound/player/default.sounds");
1312         precache_all_playermodels("models/player/*.zym");
1313         precache_all_playermodels("models/player/*.dpm");
1314         precache_all_playermodels("models/player/*.md3");
1315         precache_all_playermodels("models/player/*.psk");
1316         precache_all_playermodels("models/player/*.iqm");
1317     }
1318
1319     if (autocvar_sv_defaultcharacter)
1320     {
1321         string s;
1322         s = autocvar_sv_defaultplayermodel_red;
1323         if (s != "")
1324             precache_playermodel(s);
1325         s = autocvar_sv_defaultplayermodel_blue;
1326         if (s != "")
1327             precache_playermodel(s);
1328         s = autocvar_sv_defaultplayermodel_yellow;
1329         if (s != "")
1330             precache_playermodel(s);
1331         s = autocvar_sv_defaultplayermodel_pink;
1332         if (s != "")
1333             precache_playermodel(s);
1334         s = autocvar_sv_defaultplayermodel;
1335         if (s != "")
1336             precache_playermodel(s);
1337     }
1338
1339     if (g_footsteps)
1340     {
1341         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1342         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1343     }
1344
1345     // gore and miscellaneous sounds
1346     //precache_sound ("misc/h2ohit.wav");
1347     precache_model ("models/hook.md3");
1348     precache_sound ("misc/armorimpact.wav");
1349     precache_sound ("misc/bodyimpact1.wav");
1350     precache_sound ("misc/bodyimpact2.wav");
1351     precache_sound ("misc/gib.wav");
1352     precache_sound ("misc/gib_splat01.wav");
1353     precache_sound ("misc/gib_splat02.wav");
1354     precache_sound ("misc/gib_splat03.wav");
1355     precache_sound ("misc/gib_splat04.wav");
1356     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1357     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1358     precache_sound ("misc/null.wav");
1359     precache_sound ("misc/spawn.wav");
1360     precache_sound ("misc/talk.wav");
1361     precache_sound ("misc/teleport.wav");
1362     precache_sound ("misc/poweroff.wav");
1363     precache_sound ("player/lava.wav");
1364     precache_sound ("player/slime.wav");
1365
1366     precache_model ("models/sprites/0.spr32");
1367     precache_model ("models/sprites/1.spr32");
1368     precache_model ("models/sprites/2.spr32");
1369     precache_model ("models/sprites/3.spr32");
1370     precache_model ("models/sprites/4.spr32");
1371     precache_model ("models/sprites/5.spr32");
1372     precache_model ("models/sprites/6.spr32");
1373     precache_model ("models/sprites/7.spr32");
1374     precache_model ("models/sprites/8.spr32");
1375     precache_model ("models/sprites/9.spr32");
1376     precache_model ("models/sprites/10.spr32");
1377
1378     // common weapon precaches
1379         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1380     precache_sound ("weapons/weapon_switch.wav");
1381     precache_sound ("weapons/weaponpickup.wav");
1382     precache_sound ("weapons/unavailable.wav");
1383     precache_sound ("weapons/dryfire.wav");
1384     if (g_grappling_hook)
1385     {
1386         precache_sound ("weapons/hook_fire.wav"); // hook
1387         precache_sound ("weapons/hook_impact.wav"); // hook
1388     }
1389
1390     if(autocvar_sv_precacheweapons)
1391     {
1392         //precache weapon models/sounds
1393         float wep;
1394         wep = WEP_FIRST;
1395         while (wep <= WEP_LAST)
1396         {
1397             weapon_action(wep, WR_PRECACHE);
1398             wep = wep + 1;
1399         }
1400     }
1401
1402     precache_model("models/elaser.mdl");
1403     precache_model("models/laser.mdl");
1404     precache_model("models/ebomb.mdl");
1405
1406 #if 0
1407     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1408
1409     if (!self.noise && self.music) // quake 3 uses the music field
1410         self.noise = self.music;
1411
1412     // plays music for the level if there is any
1413     if (self.noise)
1414     {
1415         precache_sound (self.noise);
1416         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1417     }
1418 #endif
1419
1420 #include "precache-for-csqc.inc"
1421 }
1422
1423 // WARNING: this kills the trace globals
1424 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1425 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1426
1427 #define INITPRIO_FIRST              0
1428 #define INITPRIO_GAMETYPE           0
1429 #define INITPRIO_GAMETYPE_FALLBACK  1
1430 #define INITPRIO_FINDTARGET        10
1431 #define INITPRIO_DROPTOFLOOR       20
1432 #define INITPRIO_SETLOCATION       90
1433 #define INITPRIO_LINKDOORS         91
1434 #define INITPRIO_LAST              99
1435
1436 .void(void) initialize_entity;
1437 .float initialize_entity_order;
1438 .entity initialize_entity_next;
1439 entity initialize_entity_first;
1440
1441 void make_safe_for_remove(entity e)
1442 {
1443     if (e.initialize_entity)
1444     {
1445         entity ent, prev = world;
1446         for (ent = initialize_entity_first; ent; )
1447         {
1448             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1449             {
1450                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1451                 // skip it in linked list
1452                 if (prev)
1453                 {
1454                     prev.initialize_entity_next = ent.initialize_entity_next;
1455                     ent = prev.initialize_entity_next;
1456                 }
1457                 else
1458                 {
1459                     initialize_entity_first = ent.initialize_entity_next;
1460                     ent = initialize_entity_first;
1461                 }
1462             }
1463             else
1464             {
1465                 prev = ent;
1466                 ent = ent.initialize_entity_next;
1467             }
1468         }
1469     }
1470 }
1471
1472 void objerror(string s)
1473 {
1474     make_safe_for_remove(self);
1475     builtin_objerror(s);
1476 }
1477
1478 .float remove_except_protected_forbidden;
1479 void remove_except_protected(entity e)
1480 {
1481         if(e.remove_except_protected_forbidden)
1482                 error("not allowed to remove this at this point");
1483         builtin_remove(e);
1484 }
1485
1486 void remove_unsafely(entity e)
1487 {
1488     if(e.classname == "spike")
1489         error("Removing spikes is forbidden (crylink bug), please report");
1490     builtin_remove(e);
1491 }
1492
1493 void remove_safely(entity e)
1494 {
1495     make_safe_for_remove(e);
1496     builtin_remove(e);
1497 }
1498
1499 void InitializeEntity(entity e, void(void) func, float order)
1500 {
1501     entity prev, cur;
1502
1503     if (!e || e.initialize_entity)
1504     {
1505         // make a proxy initializer entity
1506         entity e_old;
1507         e_old = e;
1508         e = spawn();
1509         e.classname = "initialize_entity";
1510         e.enemy = e_old;
1511     }
1512
1513     e.initialize_entity = func;
1514     e.initialize_entity_order = order;
1515
1516     cur = initialize_entity_first;
1517     prev = world;
1518     for (;;)
1519     {
1520         if (!cur || cur.initialize_entity_order > order)
1521         {
1522             // insert between prev and cur
1523             if (prev)
1524                 prev.initialize_entity_next = e;
1525             else
1526                 initialize_entity_first = e;
1527             e.initialize_entity_next = cur;
1528             return;
1529         }
1530         prev = cur;
1531         cur = cur.initialize_entity_next;
1532     }
1533 }
1534 void InitializeEntitiesRun()
1535 {
1536     entity startoflist;
1537     startoflist = initialize_entity_first;
1538     initialize_entity_first = world;
1539     remove = remove_except_protected;
1540     for (self = startoflist; self; self = self.initialize_entity_next)
1541     {
1542         self.remove_except_protected_forbidden = 1;
1543     }
1544     for (self = startoflist; self; )
1545     {
1546         entity e;
1547         var void(void) func;
1548         e = self.initialize_entity_next;
1549         func = self.initialize_entity;
1550         self.initialize_entity_order = 0;
1551         self.initialize_entity = func_null;
1552         self.initialize_entity_next = world;
1553         self.remove_except_protected_forbidden = 0;
1554         if (self.classname == "initialize_entity")
1555         {
1556             entity e_old;
1557             e_old = self.enemy;
1558             builtin_remove(self);
1559             self = e_old;
1560         }
1561         //dprint("Delayed initialization: ", self.classname, "\n");
1562         if(func)
1563             func();
1564         else
1565         {
1566             eprint(self);
1567             backtrace(strcat("Null function in: ", self.classname, "\n"));
1568         }
1569         self = e;
1570     }
1571     remove = remove_unsafely;
1572 }
1573
1574 .float uncustomizeentityforclient_set;
1575 .void(void) uncustomizeentityforclient;
1576 void UncustomizeEntitiesRun()
1577 {
1578     entity oldself;
1579     oldself = self;
1580     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1581         self.uncustomizeentityforclient();
1582     self = oldself;
1583 }
1584 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1585 {
1586     e.customizeentityforclient = customizer;
1587     e.uncustomizeentityforclient = uncustomizer;
1588     e.uncustomizeentityforclient_set = !!uncustomizer;
1589 }
1590
1591 .float nottargeted;
1592 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1593
1594 void() SUB_Remove;
1595 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1596 {
1597     vector mi, ma;
1598
1599     if (e.classname == "")
1600         e.classname = "net_linked";
1601
1602     if (e.model == "" || self.modelindex == 0)
1603     {
1604         mi = e.mins;
1605         ma = e.maxs;
1606         setmodel(e, "null");
1607         setsize(e, mi, ma);
1608     }
1609
1610     e.SendEntity = sendfunc;
1611     e.SendFlags = 0xFFFFFF;
1612
1613     if (!docull)
1614         e.effects |= EF_NODEPTHTEST;
1615
1616     if (dt)
1617     {
1618         e.nextthink = time + dt;
1619         e.think = SUB_Remove;
1620     }
1621 }
1622
1623 void adaptor_think2touch()
1624 {
1625     entity o;
1626     o = other;
1627     other = world;
1628     self.touch();
1629     other = o;
1630 }
1631
1632 void adaptor_think2use()
1633 {
1634     entity o, a;
1635     o = other;
1636     a = activator;
1637     activator = world;
1638     other = world;
1639     self.use();
1640     other = o;
1641     activator = a;
1642 }
1643
1644 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1645 {
1646         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1647                 self.projectiledeathtype |= HITTYPE_SPLASH;
1648         adaptor_think2use();
1649 }
1650
1651 // deferred dropping
1652 void DropToFloor_Handler()
1653 {
1654     builtin_droptofloor();
1655     self.dropped_origin = self.origin;
1656 }
1657
1658 void droptofloor()
1659 {
1660     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1661 }
1662
1663
1664
1665 float trace_hits_box_a0, trace_hits_box_a1;
1666
1667 float trace_hits_box_1d(float end, float thmi, float thma)
1668 {
1669     if (end == 0)
1670     {
1671         // just check if x is in range
1672         if (0 < thmi)
1673             return FALSE;
1674         if (0 > thma)
1675             return FALSE;
1676     }
1677     else
1678     {
1679         // do the trace with respect to x
1680         // 0 -> end has to stay in thmi -> thma
1681         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1682         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1683         if (trace_hits_box_a0 > trace_hits_box_a1)
1684             return FALSE;
1685     }
1686     return TRUE;
1687 }
1688
1689 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1690 {
1691     end -= start;
1692     thmi -= start;
1693     thma -= start;
1694     // now it is a trace from 0 to end
1695
1696     trace_hits_box_a0 = 0;
1697     trace_hits_box_a1 = 1;
1698
1699     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1700         return FALSE;
1701     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1702         return FALSE;
1703     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1704         return FALSE;
1705
1706     return TRUE;
1707 }
1708
1709 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1710 {
1711     return trace_hits_box(start, end, thmi - ma, thma - mi);
1712 }
1713
1714 float SUB_NoImpactCheck()
1715 {
1716         // zero hitcontents = this is not the real impact, but either the
1717         // mirror-impact of something hitting the projectile instead of the
1718         // projectile hitting the something, or a touchareagrid one. Neither of
1719         // these stop the projectile from moving, so...
1720         if(trace_dphitcontents == 0)
1721         {
1722                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1723                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1724                 checkclient();
1725         }
1726     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1727         return 1;
1728     if (other == world && self.size != '0 0 0')
1729     {
1730         vector tic;
1731         tic = self.velocity * sys_frametime;
1732         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1733         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1734         if (trace_fraction >= 1)
1735         {
1736             dprint("Odd... did not hit...?\n");
1737         }
1738         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1739         {
1740             dprint("Detected and prevented the sky-grapple bug.\n");
1741             return 1;
1742         }
1743     }
1744
1745     return 0;
1746 }
1747
1748 #define SUB_OwnerCheck() (other && (other == self.owner))
1749
1750 void RemoveGrapplingHook(entity pl);
1751 void W_Crylink_Dequeue(entity e);
1752 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1753 {
1754         if(SUB_OwnerCheck())
1755                 return TRUE;
1756         if(SUB_NoImpactCheck())
1757         {
1758                 if(self.classname == "grapplinghook")
1759                         RemoveGrapplingHook(self.realowner);
1760                 else if(self.classname == "spike")
1761                 {
1762                         W_Crylink_Dequeue(self);
1763                         remove(self);
1764                 }
1765                 else
1766                         remove(self);
1767                 return TRUE;
1768         }
1769         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1770                 UpdateCSQCProjectile(self);
1771         return FALSE;
1772 }
1773 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1774
1775 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1776 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1777
1778 void URI_Get_Callback(float id, float status, string data)
1779 {
1780         if(url_URI_Get_Callback(id, status, data))
1781         {
1782                 // handled
1783         }
1784         else if (id == URI_GET_DISCARD)
1785         {
1786                 // discard
1787         }
1788         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1789         {
1790                 // sv_cmd curl
1791                 Curl_URI_Get_Callback(id, status, data);
1792         }
1793         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1794         {
1795                 // online ban list
1796                 OnlineBanList_URI_Get_Callback(id, status, data);
1797         }
1798         else
1799         {
1800                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1801         }
1802 }
1803
1804 string uid2name(string myuid) {
1805         string s;
1806         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1807
1808         // FIXME remove this later after 0.6 release
1809         // convert old style broken records to correct style
1810         if(s == "")
1811         {
1812                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1813                 if(s != "")
1814                 {
1815                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1816                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1817                 }
1818         }
1819
1820         if(s == "")
1821                 s = "^1Unregistered Player";
1822         return s;
1823 }
1824
1825 float race_readTime(string map, float pos)
1826 {
1827         string rr;
1828         if(g_cts)
1829                 rr = CTS_RECORD;
1830         else
1831                 rr = RACE_RECORD;
1832
1833         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1834 }
1835
1836 string race_readUID(string map, float pos)
1837 {
1838         string rr;
1839         if(g_cts)
1840                 rr = CTS_RECORD;
1841         else
1842                 rr = RACE_RECORD;
1843
1844         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1845 }
1846
1847 float race_readPos(string map, float t) {
1848         float i;
1849         for (i = 1; i <= RANKINGS_CNT; ++i)
1850                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1851                         return i;
1852
1853         return 0; // pos is zero if unranked
1854 }
1855
1856 void race_writeTime(string map, float t, string myuid)
1857 {
1858         string rr;
1859         if(g_cts)
1860                 rr = CTS_RECORD;
1861         else
1862                 rr = RACE_RECORD;
1863
1864         float newpos;
1865         newpos = race_readPos(map, t);
1866
1867         float i, prevpos = 0;
1868         for(i = 1; i <= RANKINGS_CNT; ++i)
1869         {
1870                 if(race_readUID(map, i) == myuid)
1871                         prevpos = i;
1872         }
1873         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1874                 for (i = prevpos; i > newpos; --i) {
1875                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1876                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1877                 }
1878         } else { // player has no ranked record yet
1879                 for (i = RANKINGS_CNT; i > newpos; --i) {
1880                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1881                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1882                 }
1883         }
1884
1885         // store new time itself
1886         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1887         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1888 }
1889
1890 string race_readName(string map, float pos)
1891 {
1892         string rr;
1893         if(g_cts)
1894                 rr = CTS_RECORD;
1895         else
1896                 rr = RACE_RECORD;
1897
1898         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1899 }
1900
1901 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1902 {
1903     float m, i;
1904     vector start, org, delta, end, enddown, mstart;
1905     entity sp;
1906
1907     m = e.dphitcontentsmask;
1908     e.dphitcontentsmask = goodcontents | badcontents;
1909
1910     org = world.mins;
1911     delta = world.maxs - world.mins;
1912
1913     start = end = org;
1914
1915     for (i = 0; i < attempts; ++i)
1916     {
1917         start_x = org_x + random() * delta_x;
1918         start_y = org_y + random() * delta_y;
1919         start_z = org_z + random() * delta_z;
1920
1921         // rule 1: start inside world bounds, and outside
1922         // solid, and don't start from somewhere where you can
1923         // fall down to evil
1924         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1925         if (trace_fraction >= 1)
1926             continue;
1927         if (trace_startsolid)
1928             continue;
1929         if (trace_dphitcontents & badcontents)
1930             continue;
1931         if (trace_dphitq3surfaceflags & badsurfaceflags)
1932             continue;
1933
1934         // rule 2: if we are too high, lower the point
1935         if (trace_fraction * delta_z > maxaboveground)
1936             start = trace_endpos + '0 0 1' * maxaboveground;
1937         enddown = trace_endpos;
1938
1939         // rule 3: make sure we aren't outside the map. This only works
1940         // for somewhat well formed maps. A good rule of thumb is that
1941         // the map should have a convex outside hull.
1942         // these can be traceLINES as we already verified the starting box
1943         mstart = start + 0.5 * (e.mins + e.maxs);
1944         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1945         if (trace_fraction >= 1)
1946             continue;
1947         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1948         if (trace_fraction >= 1)
1949             continue;
1950         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1951         if (trace_fraction >= 1)
1952             continue;
1953         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1954         if (trace_fraction >= 1)
1955             continue;
1956         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1957         if (trace_fraction >= 1)
1958             continue;
1959
1960         // rule 4: we must "see" some spawnpoint
1961         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1962                 if(checkpvs(mstart, sp))
1963                         break;
1964         if(!sp)
1965         {
1966                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1967                         if(checkpvs(mstart, sp))
1968                                 break;
1969                 if(!sp)
1970                         continue;
1971         }
1972
1973         // find a random vector to "look at"
1974         end_x = org_x + random() * delta_x;
1975         end_y = org_y + random() * delta_y;
1976         end_z = org_z + random() * delta_z;
1977         end = start + normalize(end - start) * vlen(delta);
1978
1979         // rule 4: start TO end must not be too short
1980         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1981         if (trace_startsolid)
1982             continue;
1983         if (trace_fraction < minviewdistance / vlen(delta))
1984             continue;
1985
1986         // rule 5: don't want to look at sky
1987         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1988             continue;
1989
1990         // rule 6: we must not end up in trigger_hurt
1991         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1992             continue;
1993
1994         break;
1995     }
1996
1997     e.dphitcontentsmask = m;
1998
1999     if (i < attempts)
2000     {
2001         setorigin(e, start);
2002         e.angles = vectoangles(end - start);
2003         dprint("Needed ", ftos(i + 1), " attempts\n");
2004         return TRUE;
2005     }
2006     else
2007         return FALSE;
2008 }
2009
2010 float zcurveparticles_effectno;
2011 vector zcurveparticles_start;
2012 float zcurveparticles_spd;
2013
2014 void endzcurveparticles()
2015 {
2016         if(zcurveparticles_effectno)
2017         {
2018                 // terminator
2019                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2020         }
2021         zcurveparticles_effectno = 0;
2022 }
2023
2024 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2025 {
2026         spd = bound(0, floor(spd / 16), 32767);
2027         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2028         {
2029                 endzcurveparticles();
2030                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2031                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2032                 WriteShort(MSG_BROADCAST, effectno);
2033                 WriteCoord(MSG_BROADCAST, start_x);
2034                 WriteCoord(MSG_BROADCAST, start_y);
2035                 WriteCoord(MSG_BROADCAST, start_z);
2036                 zcurveparticles_effectno = effectno;
2037                 zcurveparticles_start = start;
2038         }
2039         else
2040                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2041         WriteCoord(MSG_BROADCAST, end_x);
2042         WriteCoord(MSG_BROADCAST, end_y);
2043         WriteCoord(MSG_BROADCAST, end_z);
2044         WriteCoord(MSG_BROADCAST, end_dz);
2045         zcurveparticles_spd = spd;
2046 }
2047
2048 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2049 {
2050         float end_dz;
2051         vector vecxy, velxy;
2052
2053         vecxy = end - start;
2054         vecxy_z = 0;
2055         velxy = vel;
2056         velxy_z = 0;
2057
2058         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2059         {
2060                 endzcurveparticles();
2061                 trailparticles(world, effectno, start, end);
2062                 return;
2063         }
2064
2065         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2066         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2067 }
2068
2069 void write_recordmarker(entity pl, float tstart, float dt)
2070 {
2071     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2072
2073     // also write a marker into demo files for demotc-race-record-extractor to find
2074     stuffcmd(pl,
2075              strcat(
2076                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2077                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2078 }
2079
2080 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2081 {
2082         switch(algn)
2083         {
2084                 default:
2085                 case 3: // right
2086                         break;
2087
2088                 case 4: // left
2089                         vecs_y = -vecs_y;
2090                         break;
2091
2092                 case 1:
2093                         if(allowcenter) // 2: allow center handedness
2094                         {
2095                                 // center
2096                                 vecs_y = 0;
2097                                 vecs_z -= 2;
2098                         }
2099                         else
2100                         {
2101                                 // right
2102                         }
2103                         break;
2104
2105                 case 2:
2106                         if(allowcenter) // 2: allow center handedness
2107                         {
2108                                 // center
2109                                 vecs_y = 0;
2110                                 vecs_z -= 2;
2111                         }
2112                         else
2113                         {
2114                                 // left
2115                                 vecs_y = -vecs_y;
2116                         }
2117                         break;
2118         }
2119         return vecs;
2120 }
2121
2122 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2123 {
2124         string s;
2125         vector v;
2126
2127         if (autocvar_g_shootfromeye)
2128         {
2129                 if (visual)
2130                 {
2131                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2132                         else { vecs_y = 0; vecs_z -= 2; }
2133                 }
2134                 else
2135                 {
2136                         vecs_y = 0;
2137                         vecs_z = 0;
2138                 }
2139         }
2140         else if (autocvar_g_shootfromcenter)
2141         {
2142                 vecs_y = 0;
2143                 vecs_z -= 2;
2144         }
2145         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2146         {
2147                 v = stov(s);
2148                 if (y_is_right)
2149                         v_y = -v_y;
2150                 if (v_x != 0)
2151                         vecs_x = v_x;
2152                 vecs_y = v_y;
2153                 vecs_z = v_z;
2154         }
2155         else if (autocvar_g_shootfromclient)
2156         {
2157                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2158         }
2159         return vecs;
2160 }
2161
2162 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2163 {
2164         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2165 }
2166
2167
2168 void attach_sameorigin(entity e, entity to, string tag)
2169 {
2170     vector org, t_forward, t_left, t_up, e_forward, e_up;
2171     float tagscale;
2172
2173     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2174     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2175     t_forward = v_forward * tagscale;
2176     t_left = v_right * -tagscale;
2177     t_up = v_up * tagscale;
2178
2179     e.origin_x = org * t_forward;
2180     e.origin_y = org * t_left;
2181     e.origin_z = org * t_up;
2182
2183     // current forward and up directions
2184     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2185                 e.angles = AnglesTransform_FromVAngles(e.angles);
2186         else
2187                 e.angles = AnglesTransform_FromAngles(e.angles);
2188     fixedmakevectors(e.angles);
2189
2190     // untransform forward, up!
2191     e_forward_x = v_forward * t_forward;
2192     e_forward_y = v_forward * t_left;
2193     e_forward_z = v_forward * t_up;
2194     e_up_x = v_up * t_forward;
2195     e_up_y = v_up * t_left;
2196     e_up_z = v_up * t_up;
2197
2198     e.angles = fixedvectoangles2(e_forward, e_up);
2199     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2200                 e.angles = AnglesTransform_ToVAngles(e.angles);
2201         else
2202                 e.angles = AnglesTransform_ToAngles(e.angles);
2203
2204     setattachment(e, to, tag);
2205     setorigin(e, e.origin);
2206 }
2207
2208 void detach_sameorigin(entity e)
2209 {
2210     vector org;
2211     org = gettaginfo(e, 0);
2212     e.angles = fixedvectoangles2(v_forward, v_up);
2213     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2214                 e.angles = AnglesTransform_ToVAngles(e.angles);
2215         else
2216                 e.angles = AnglesTransform_ToAngles(e.angles);
2217     setorigin(e, org);
2218     setattachment(e, world, "");
2219     setorigin(e, e.origin);
2220 }
2221
2222 void follow_sameorigin(entity e, entity to)
2223 {
2224     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2225     e.aiment = to; // make the hole follow bmodel
2226     e.punchangle = to.angles; // the original angles of bmodel
2227     e.view_ofs = e.origin - to.origin; // relative origin
2228     e.v_angle = e.angles - to.angles; // relative angles
2229 }
2230
2231 void unfollow_sameorigin(entity e)
2232 {
2233     e.movetype = MOVETYPE_NONE;
2234 }
2235
2236 entity gettaginfo_relative_ent;
2237 vector gettaginfo_relative(entity e, float tag)
2238 {
2239     if (!gettaginfo_relative_ent)
2240     {
2241         gettaginfo_relative_ent = spawn();
2242         gettaginfo_relative_ent.effects = EF_NODRAW;
2243     }
2244     gettaginfo_relative_ent.model = e.model;
2245     gettaginfo_relative_ent.modelindex = e.modelindex;
2246     gettaginfo_relative_ent.frame = e.frame;
2247     return gettaginfo(gettaginfo_relative_ent, tag);
2248 }
2249
2250 .float scale2;
2251
2252 float modeleffect_SendEntity(entity to, float sf)
2253 {
2254         float f;
2255         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2256
2257         f = 0;
2258         if(self.velocity != '0 0 0')
2259                 f |= 1;
2260         if(self.angles != '0 0 0')
2261                 f |= 2;
2262         if(self.avelocity != '0 0 0')
2263                 f |= 4;
2264
2265         WriteByte(MSG_ENTITY, f);
2266         WriteShort(MSG_ENTITY, self.modelindex);
2267         WriteByte(MSG_ENTITY, self.skin);
2268         WriteByte(MSG_ENTITY, self.frame);
2269         WriteCoord(MSG_ENTITY, self.origin_x);
2270         WriteCoord(MSG_ENTITY, self.origin_y);
2271         WriteCoord(MSG_ENTITY, self.origin_z);
2272         if(f & 1)
2273         {
2274                 WriteCoord(MSG_ENTITY, self.velocity_x);
2275                 WriteCoord(MSG_ENTITY, self.velocity_y);
2276                 WriteCoord(MSG_ENTITY, self.velocity_z);
2277         }
2278         if(f & 2)
2279         {
2280                 WriteCoord(MSG_ENTITY, self.angles_x);
2281                 WriteCoord(MSG_ENTITY, self.angles_y);
2282                 WriteCoord(MSG_ENTITY, self.angles_z);
2283         }
2284         if(f & 4)
2285         {
2286                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2287                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2288                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2289         }
2290         WriteShort(MSG_ENTITY, self.scale * 256.0);
2291         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2292         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2293         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2294         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2295
2296         return TRUE;
2297 }
2298
2299 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2300 {
2301         entity e;
2302         float sz;
2303         e = spawn();
2304         e.classname = "modeleffect";
2305         setmodel(e, m);
2306         e.frame = f;
2307         setorigin(e, o);
2308         e.velocity = v;
2309         e.angles = ang;
2310         e.avelocity = angv;
2311         e.alpha = a;
2312         e.teleport_time = t1;
2313         e.fade_time = t2;
2314         e.skin = s;
2315         if(s0 >= 0)
2316                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2317         else
2318                 e.scale = -s0;
2319         if(s2 >= 0)
2320                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2321         else
2322                 e.scale2 = -s2;
2323         sz = max(e.scale, e.scale2);
2324         setsize(e, e.mins * sz, e.maxs * sz);
2325         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2326 }
2327
2328 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2329 {
2330         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2331 }
2332
2333 float randombit(float bits)
2334 {
2335         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2336                 return bits;
2337
2338         float n, f, b, r;
2339
2340         r = random();
2341         b = 0;
2342         n = 0;
2343
2344         for(f = 1; f <= bits; f *= 2)
2345         {
2346                 if(bits & f)
2347                 {
2348                         ++n;
2349                         r *= n;
2350                         if(r <= 1)
2351                                 b = f;
2352                         else
2353                                 r = (r - 1) / (n - 1);
2354                 }
2355         }
2356
2357         return b;
2358 }
2359
2360 float randombits(float bits, float k, float error_return)
2361 {
2362         float r;
2363         r = 0;
2364         while(k > 0 && bits != r)
2365         {
2366                 r += randombit(bits - r);
2367                 --k;
2368         }
2369         if(error_return)
2370                 if(k > 0)
2371                         return -1; // all
2372         return r;
2373 }
2374
2375 void randombit_test(float bits, float iter)
2376 {
2377         while(iter > 0)
2378         {
2379                 print(ftos(randombit(bits)), "\n");
2380                 --iter;
2381         }
2382 }
2383
2384 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2385 {
2386         if(halflifedist > 0)
2387                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2388         else if(halflifedist < 0)
2389                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2390         else
2391                 return 1;
2392 }
2393
2394
2395
2396
2397 #ifdef RELEASE
2398 #define cvar_string_normal builtin_cvar_string
2399 #define cvar_normal builtin_cvar
2400 #else
2401 string cvar_string_normal(string n)
2402 {
2403         if not(cvar_type(n) & 1)
2404                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2405         return builtin_cvar_string(n);
2406 }
2407
2408 float cvar_normal(string n)
2409 {
2410         return stof(cvar_string_normal(n));
2411 }
2412 #endif
2413 #define cvar_set_normal builtin_cvar_set
2414
2415 void defer_think()
2416 {
2417     entity oself;
2418
2419     oself           = self;
2420     self            = self.owner;
2421     oself.think     = SUB_Remove;
2422     oself.nextthink = time;
2423
2424     oself.use();
2425 }
2426
2427 /*
2428     Execute func() after time + fdelay.
2429     self when func is executed = self when defer is called
2430 */
2431 void defer(float fdelay, void() func)
2432 {
2433     entity e;
2434
2435     e           = spawn();
2436     e.owner     = self;
2437     e.use       = func;
2438     e.think     = defer_think;
2439     e.nextthink = time + fdelay;
2440 }
2441
2442 .string aiment_classname;
2443 .float aiment_deadflag;
2444 void SetMovetypeFollow(entity ent, entity e)
2445 {
2446         // FIXME this may not be warpzone aware
2447         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2448         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2449         ent.aiment = e; // make the hole follow bmodel
2450         ent.punchangle = e.angles; // the original angles of bmodel
2451         ent.view_ofs = ent.origin - e.origin; // relative origin
2452         ent.v_angle = ent.angles - e.angles; // relative angles
2453         ent.aiment_classname = strzone(e.classname);
2454         ent.aiment_deadflag = e.deadflag;
2455 }
2456 void UnsetMovetypeFollow(entity ent)
2457 {
2458         ent.movetype = MOVETYPE_FLY;
2459         PROJECTILE_MAKETRIGGER(ent);
2460         ent.aiment = world;
2461 }
2462 float LostMovetypeFollow(entity ent)
2463 {
2464 /*
2465         if(ent.movetype != MOVETYPE_FOLLOW)
2466                 if(ent.aiment)
2467                         error("???");
2468 */
2469         if(ent.aiment)
2470         {
2471                 if(ent.aiment.classname != ent.aiment_classname)
2472                         return 1;
2473                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2474                         return 1;
2475         }
2476         return 0;
2477 }
2478
2479 float isPushable(entity e)
2480 {
2481         if(e.iscreature)
2482                 return TRUE;
2483         if(e.pushable)
2484                 return TRUE;
2485         switch(e.classname)
2486         {
2487                 case "body":
2488                 case "droppedweapon":
2489                 case "keepawayball":
2490                 case "nexball_basketball":
2491                 case "nexball_football":
2492                         return TRUE;
2493                 case "bullet": // antilagged bullets can't hit this either
2494                         return FALSE;
2495         }
2496         if (e.projectiledeathtype)
2497                 return TRUE;
2498         return FALSE;
2499 }