qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239     have_team_spawns_forteam[self.team] = 1;
 240
 241     if (autocvar_r_showbboxes)
 242     {
 243         // show where spawnpoints point at too
 244         makevectors(self.angles);
 245         entity e;
 246         e = spawn();
 247         e.classname = "info_player_foo";
 248         setorigin(e, self.origin + v_forward * 24);
 249         setsize(e, '-8 -8 -8', '8 8 8');
 250         e.solid = SOLID_TRIGGER;
 251     }
 252 }
 253
 254 #define strstr strstrofs
 255 /*
 256 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 257 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 258 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 259 // BE CONSTANT OR strzoneD!
 260 float strstr(string haystack, string needle, float offset)
 261 {
 262         float len, endpos;
 263         string found;
 264         len = strlen(needle);
 265         endpos = strlen(haystack) - len;
 266         while(offset <= endpos)
 267         {
 268                 found = substring(haystack, offset, len);
 269                 if(found == needle)
 270                         return offset;
 271                 offset = offset + 1;
 272         }
 273         return -1;
 274 }
 275 */
 276
 277 float NUM_NEAREST_ENTITIES = 4;
 278 entity nearest_entity[NUM_NEAREST_ENTITIES];
 279 float nearest_length[NUM_NEAREST_ENTITIES];
 280 entity findnearest(vector point, .string field, string value, vector axismod)
 281 {
 282     entity localhead;
 283     float i;
 284     float j;
 285     float len;
 286     vector dist;
 287
 288     float num_nearest;
 289     num_nearest = 0;
 290
 291     localhead = find(world, field, value);
 292     while (localhead)
 293     {
 294         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 295             dist = localhead.oldorigin;
 296         else
 297             dist = localhead.origin;
 298         dist = dist - point;
 299         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 300         len = vlen(dist);
 301
 302         for (i = 0; i < num_nearest; ++i)
 303         {
 304             if (len < nearest_length[i])
 305                 break;
 306         }
 307
 308         // now i tells us where to insert at
 309         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 310         if (i < NUM_NEAREST_ENTITIES)
 311         {
 312             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 313             {
 314                 nearest_length[j + 1] = nearest_length[j];
 315                 nearest_entity[j + 1] = nearest_entity[j];
 316             }
 317             nearest_length[i] = len;
 318             nearest_entity[i] = localhead;
 319             if (num_nearest < NUM_NEAREST_ENTITIES)
 320                 num_nearest = num_nearest + 1;
 321         }
 322
 323         localhead = find(localhead, field, value);
 324     }
 325
 326     // now use the first one from our list that we can see
 327     for (i = 0; i < num_nearest; ++i)
 328     {
 329         traceline(point, nearest_entity[i].origin, TRUE, world);
 330         if (trace_fraction == 1)
 331         {
 332             if (i != 0)
 333             {
 334                 dprint("Nearest point (");
 335                 dprint(nearest_entity[0].netname);
 336                 dprint(") is not visible, using a visible one.\n");
 337             }
 338             return nearest_entity[i];
 339         }
 340     }
 341
 342     if (num_nearest == 0)
 343         return world;
 344
 345     dprint("Not seeing any location point, using nearest as fallback.\n");
 346     /* DEBUGGING CODE:
 347     dprint("Candidates were: ");
 348     for(j = 0; j < num_nearest; ++j)
 349     {
 350         if(j != 0)
 351                 dprint(", ");
 352         dprint(nearest_entity[j].netname);
 353     }
 354     dprint("\n");
 355     */
 356
 357     return nearest_entity[0];
 358 }
 359
 360 void spawnfunc_target_location()
 361 {
 362     self.classname = "target_location";
 363     // location name in netname
 364     // eventually support: count, teamgame selectors, line of sight?
 365 };
 366
 367 void spawnfunc_info_location()
 368 {
 369     self.classname = "target_location";
 370     self.message = self.netname;
 371 };
 372
 373 string NearestLocation(vector p)
 374 {
 375     entity loc;
 376     string ret;
 377     ret = "somewhere";
 378     loc = findnearest(p, classname, "target_location", '1 1 1');
 379     if (loc)
 380     {
 381         ret = loc.message;
 382     }
 383     else
 384     {
 385         loc = findnearest(p, target, "###item###", '1 1 4');
 386         if (loc)
 387             ret = loc.netname;
 388     }
 389     return ret;
 390 }
 391
 392 string formatmessage(string msg)
 393 {
 394         float p, p1, p2;
 395         float n;
 396         vector cursor;
 397         entity cursor_ent;
 398         string escape;
 399         string replacement;
 400         p = 0;
 401         n = 7;
 402
 403         WarpZone_crosshair_trace(self);
 404         cursor = trace_endpos;
 405         cursor_ent = trace_ent;
 406
 407         while (1) {
 408                 if (n < 1)
 409                         break; // too many replacements
 410
 411                 n = n - 1;
 412                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 413                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 414
 415                 if (p1 < 0)
 416                         p1 = p2;
 417
 418                 if (p2 < 0)
 419                         p2 = p1;
 420
 421                 p = min(p1, p2);
 422
 423                 if (p < 0)
 424                         break;
 425
 426                 replacement = substring(msg, p, 2);
 427                 escape = substring(msg, p + 1, 1);
 428
 429                 if (escape == "%")
 430                         replacement = "%";
 431                 else if (escape == "\\")
 432                         replacement = "\\";
 433                 else if (escape == "n")
 434                         replacement = "\n";
 435                 else if (escape == "a")
 436                         replacement = ftos(floor(self.armorvalue));
 437                 else if (escape == "h")
 438                         replacement = ftos(floor(self.health));
 439                 else if (escape == "l")
 440                         replacement = NearestLocation(self.origin);
 441                 else if (escape == "y")
 442                         replacement = NearestLocation(cursor);
 443                 else if (escape == "d")
 444                         replacement = NearestLocation(self.death_origin);
 445                 else if (escape == "w") {
 446                         float wep;
 447                         wep = self.weapon;
 448                         if (!wep)
 449                                 wep = self.switchweapon;
 450                         if (!wep)
 451                                 wep = self.cnt;
 452                         replacement = W_Name(wep);
 453                 } else if (escape == "W") {
 454                         if (self.items & IT_SHELLS) replacement = "shells";
 455                         else if (self.items & IT_NAILS) replacement = "bullets";
 456                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 457                         else if (self.items & IT_CELLS) replacement = "cells";
 458                         else replacement = "batteries"; // ;)
 459                 } else if (escape == "x") {
 460                         replacement = cursor_ent.netname;
 461                         if (!replacement || !cursor_ent)
 462                                 replacement = "nothing";
 463                 } else if (escape == "s")
 464                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 465                 else if (escape == "S")
 466                         replacement = ftos(vlen(self.velocity));
 467
 468                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 469                 p = p + strlen(replacement);
 470         }
 471         return msg;
 472 }
 473
 474 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 475         return (value == 0) ? FALSE : TRUE;
 476 }
 477
 478 /*
 479 =============
 480 GetCvars
 481 =============
 482 Called with:
 483   0:  sends the request
 484   >0: receives a cvar from name=argv(f) value=argv(f+1)
 485 */
 486 void GetCvars_handleString(string thisname, float f, .string field, string name)
 487 {
 488         if (f < 0)
 489         {
 490                 if (self.field)
 491                         strunzone(self.field);
 492                 self.field = string_null;
 493         }
 494         else if (f > 0)
 495         {
 496                 if (thisname == name)
 497                 {
 498                         if (self.field)
 499                                 strunzone(self.field);
 500                         self.field = strzone(argv(f + 1));
 501                 }
 502         }
 503         else
 504                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 505 }
 506 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 507 {
 508         GetCvars_handleString(thisname, f, field, name);
 509         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 510                 if (thisname == name)
 511                 {
 512                         string s;
 513                         s = func(strcat1(self.field));
 514                         if (s != self.field)
 515                         {
 516                                 strunzone(self.field);
 517                                 self.field = strzone(s);
 518                         }
 519                 }
 520 }
 521 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 522 {
 523         if (f < 0)
 524         {
 525         }
 526         else if (f > 0)
 527         {
 528                 if (thisname == name)
 529                         self.field = stof(argv(f + 1));
 530         }
 531         else
 532                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 533 }
 534 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 535 {
 536         if (f < 0)
 537         {
 538         }
 539         else if (f > 0)
 540         {
 541                 if (thisname == name)
 542                 {
 543                         if(!self.field)
 544                         {
 545                                 self.field = stof(argv(f + 1));
 546                                 if(!self.field)
 547                                         self.field = -1;
 548                         }
 549                 }
 550         }
 551         else
 552         {
 553                 if(!self.field)
 554                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 555         }
 556 }
 557 float w_getbestweapon(entity e);
 558 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 559 {
 560         string o;
 561         o = W_FixWeaponOrder_ForceComplete(wo);
 562         if(self.weaponorder_byimpulse)
 563         {
 564                 strunzone(self.weaponorder_byimpulse);
 565                 self.weaponorder_byimpulse = string_null;
 566         }
 567         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 568         return o;
 569 }
 570 void GetCvars(float f)
 571 {
 572         string s;
 573
 574         if (f > 0)
 575                 s = strcat1(argv(f));
 576
 577         get_cvars_f = f;
 578         get_cvars_s = s;
 579         MUTATOR_CALLHOOK(GetCvars);
 580         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 581         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 582         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 583         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 584         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 585         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 586         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 587         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 588         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 589         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 598         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 599         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 600         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 601         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 602         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 603         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 604
 605         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 606         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 607
 608 #ifdef ALLOW_FORCEMODELS
 609         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 610         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 611 #endif
 612         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 613         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 614         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 615
 616         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 617         if (f > 0)
 618         {
 619                 if (s == "cl_weaponpriority")
 620                         self.switchweapon = w_getbestweapon(self);
 621                 if (s == "cl_allow_uidtracking")
 622                         PlayerStats_AddPlayer(self);
 623         }
 624 }
 625
 626 void backtrace(string msg)
 627 {
 628     float dev, war;
 629     dev = autocvar_developer;
 630     war = autocvar_prvm_backtraceforwarnings;
 631     cvar_set("developer", "1");
 632     cvar_set("prvm_backtraceforwarnings", "1");
 633     print("\n");
 634     print("--- CUT HERE ---\nWARNING: ");
 635     print(msg);
 636     print("\n");
 637     remove(world); // isn't there any better way to cause a backtrace?
 638     print("\n--- CUT UNTIL HERE ---\n");
 639     cvar_set("developer", ftos(dev));
 640     cvar_set("prvm_backtraceforwarnings", ftos(war));
 641 }
 642
 643 string Team_ColorCode(float teamid)
 644 {
 645     if (teamid == COLOR_TEAM1)
 646         return "^1";
 647     else if (teamid == COLOR_TEAM2)
 648         return "^4";
 649     else if (teamid == COLOR_TEAM3)
 650         return "^3";
 651     else if (teamid == COLOR_TEAM4)
 652         return "^6";
 653     else
 654         return "^7";
 655 }
 656
 657 string Team_ColorName(float t)
 658 {
 659     // fixme: Search for team entities and get their .netname's!
 660     if (t == COLOR_TEAM1)
 661         return "Red";
 662     if (t == COLOR_TEAM2)
 663         return "Blue";
 664     if (t == COLOR_TEAM3)
 665         return "Yellow";
 666     if (t == COLOR_TEAM4)
 667         return "Pink";
 668     return "Neutral";
 669 }
 670
 671 string Team_ColorNameLowerCase(float t)
 672 {
 673     // fixme: Search for team entities and get their .netname's!
 674     if (t == COLOR_TEAM1)
 675         return "red";
 676     if (t == COLOR_TEAM2)
 677         return "blue";
 678     if (t == COLOR_TEAM3)
 679         return "yellow";
 680     if (t == COLOR_TEAM4)
 681         return "pink";
 682     return "neutral";
 683 }
 684
 685 float ColourToNumber(string team_colour)
 686 {
 687         if (team_colour == "red")
 688                 return COLOR_TEAM1;
 689
 690         if (team_colour == "blue")
 691                 return COLOR_TEAM2;
 692
 693         if (team_colour == "yellow")
 694                 return COLOR_TEAM3;
 695
 696         if (team_colour == "pink")
 697                 return COLOR_TEAM4;
 698
 699         if (team_colour == "auto")
 700                 return 0;
 701
 702         return -1;
 703 }
 704
 705 float NumberToTeamNumber(float number)
 706 {
 707         if (number == 1)
 708                 return COLOR_TEAM1;
 709
 710         if (number == 2)
 711                 return COLOR_TEAM2;
 712
 713         if (number == 3)
 714                 return COLOR_TEAM3;
 715
 716         if (number == 4)
 717                 return COLOR_TEAM4;
 718
 719         return -1;
 720 }
 721
 722 #define CENTERPRIO_POINT 1
 723 #define CENTERPRIO_SPAM 2
 724 #define CENTERPRIO_VOTE 4
 725 #define CENTERPRIO_NORMAL 5
 726 #define CENTERPRIO_SHIELDING 7
 727 #define CENTERPRIO_MAPVOTE 9
 728 #define CENTERPRIO_IDLEKICK 50
 729 #define CENTERPRIO_ADMIN 99
 730 .float centerprint_priority;
 731 .float centerprint_expires;
 732 void centerprint_atprio(entity e, float prio, string s)
 733 {
 734     if (intermission_running)
 735         if (prio < CENTERPRIO_MAPVOTE)
 736             return;
 737     if (time > e.centerprint_expires)
 738         e.centerprint_priority = 0;
 739     if (prio >= e.centerprint_priority)
 740     {
 741         e.centerprint_priority = prio;
 742         if (timeoutStatus == 2)
 743             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 744         else
 745             e.centerprint_expires = time + e.cvar_scr_centertime;
 746         centerprint_builtin(e, s);
 747     }
 748 }
 749 void centerprint_expire(entity e, float prio)
 750 {
 751     if (prio == e.centerprint_priority)
 752     {
 753         e.centerprint_priority = 0;
 754         centerprint_builtin(e, "");
 755     }
 756 }
 757 void centerprint(entity e, string s)
 758 {
 759     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 760 }
 761
 762 // decolorizes and team colors the player name when needed
 763 string playername(entity p)
 764 {
 765     string t;
 766     if (teamplay && !intermission_running && p.classname == "player")
 767     {
 768         t = Team_ColorCode(p.team);
 769         return strcat(t, strdecolorize(p.netname));
 770     }
 771     else
 772         return p.netname;
 773 }
 774
 775 vector randompos(vector m1, vector m2)
 776 {
 777     local vector v;
 778     m2 = m2 - m1;
 779     v_x = m2_x * random() + m1_x;
 780     v_y = m2_y * random() + m1_y;
 781     v_z = m2_z * random() + m1_z;
 782     return  v;
 783 };
 784
 785 //#NO AUTOCVARS START
 786
 787 float g_pickup_shells;
 788 float g_pickup_shells_max;
 789 float g_pickup_nails;
 790 float g_pickup_nails_max;
 791 float g_pickup_rockets;
 792 float g_pickup_rockets_max;
 793 float g_pickup_cells;
 794 float g_pickup_cells_max;
 795 float g_pickup_fuel;
 796 float g_pickup_fuel_jetpack;
 797 float g_pickup_fuel_max;
 798 float g_pickup_armorsmall;
 799 float g_pickup_armorsmall_max;
 800 float g_pickup_armorsmall_anyway;
 801 float g_pickup_armormedium;
 802 float g_pickup_armormedium_max;
 803 float g_pickup_armormedium_anyway;
 804 float g_pickup_armorbig;
 805 float g_pickup_armorbig_max;
 806 float g_pickup_armorbig_anyway;
 807 float g_pickup_armorlarge;
 808 float g_pickup_armorlarge_max;
 809 float g_pickup_armorlarge_anyway;
 810 float g_pickup_healthsmall;
 811 float g_pickup_healthsmall_max;
 812 float g_pickup_healthsmall_anyway;
 813 float g_pickup_healthmedium;
 814 float g_pickup_healthmedium_max;
 815 float g_pickup_healthmedium_anyway;
 816 float g_pickup_healthlarge;
 817 float g_pickup_healthlarge_max;
 818 float g_pickup_healthlarge_anyway;
 819 float g_pickup_healthmega;
 820 float g_pickup_healthmega_max;
 821 float g_pickup_healthmega_anyway;
 822 float g_pickup_ammo_anyway;
 823 float g_pickup_weapons_anyway;
 824 float g_weaponarena;
 825 float g_weaponarena_random;
 826 float g_weaponarena_random_with_laser;
 827 string g_weaponarena_list;
 828 float g_weaponspeedfactor;
 829 float g_weaponratefactor;
 830 float g_weapondamagefactor;
 831 float g_weaponforcefactor;
 832 float g_weaponspreadfactor;
 833
 834 float start_weapons;
 835 float start_items;
 836 float start_ammo_shells;
 837 float start_ammo_nails;
 838 float start_ammo_rockets;
 839 float start_ammo_cells;
 840 float start_ammo_fuel;
 841 float start_health;
 842 float start_armorvalue;
 843 float warmup_start_weapons;
 844 float warmup_start_ammo_shells;
 845 float warmup_start_ammo_nails;
 846 float warmup_start_ammo_rockets;
 847 float warmup_start_ammo_cells;
 848 float warmup_start_ammo_fuel;
 849 float warmup_start_health;
 850 float warmup_start_armorvalue;
 851 float g_weapon_stay;
 852 float g_ghost_items;
 853
 854 entity get_weaponinfo(float w);
 855
 856 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 857 {
 858         var float i = weaponinfo.weapon;
 859
 860         if (!i)
 861                 return 0;
 862
 863         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 864
 865         if (t < 0) // "default" weapon selection
 866         {
 867                 if (g_lms || g_ca || allguns)
 868                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 869                 else if(t < -1)
 870                         t = 0;
 871                 else if (g_cts)
 872                         t = (i == WEP_SHOTGUN);
 873                 else if (g_nexball)
 874                         t = 0; // weapon is set a few lines later
 875                 else
 876                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 877                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 878                         t |= (i == WEP_HOOK);
 879         }
 880
 881         // we cannot disable porto in Nexball, we must force it
 882         if(g_nexball && i == WEP_PORTO)
 883                 t = 1;
 884
 885         return t;
 886 }
 887
 888 void readplayerstartcvars()
 889 {
 890         entity e;
 891         float i, j, t;
 892         string s;
 893
 894         // initialize starting values for players
 895         start_weapons = 0;
 896         start_items = 0;
 897         start_ammo_shells = 0;
 898         start_ammo_nails = 0;
 899         start_ammo_rockets = 0;
 900         start_ammo_cells = 0;
 901         start_health = cvar("g_balance_health_start");
 902         start_armorvalue = cvar("g_balance_armor_start");
 903
 904         g_weaponarena = 0;
 905         s = cvar_string("g_weaponarena");
 906         if (s == "0" || s == "")
 907         {
 908                 if(g_lms || g_ca)
 909                         s = "most";
 910         }
 911
 912         if (s == "0" || s == "")
 913         {
 914                 // no arena
 915         }
 916         else if (s == "off")
 917         {
 918                 // forcibly turn off weaponarena
 919         }
 920         else if (s == "all")
 921         {
 922                 g_weaponarena_list = "All Weapons";
 923                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 924                 {
 925                         e = get_weaponinfo(j);
 926                         g_weaponarena |= e.weapons;
 927                         weapon_action(e.weapon, WR_PRECACHE);
 928                 }
 929         }
 930         else if (s == "most")
 931         {
 932                 g_weaponarena_list = "Most Weapons";
 933                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 934                 {
 935                         e = get_weaponinfo(j);
 936                         if (e.spawnflags & WEP_FLAG_NORMAL)
 937                         {
 938                                 g_weaponarena |= e.weapons;
 939                                 weapon_action(e.weapon, WR_PRECACHE);
 940                         }
 941                 }
 942         }
 943         else if (s == "none")
 944         {
 945                 g_weaponarena_list = "No Weapons";
 946                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 947         }
 948         else
 949         {
 950                 t = tokenize_console(s);
 951                 g_weaponarena_list = "";
 952                 for (i = 0; i < t; ++i)
 953                 {
 954                         s = argv(i);
 955                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 956                         {
 957                                 e = get_weaponinfo(j);
 958                                 if (e.netname == s)
 959                                 {
 960                                         g_weaponarena |= e.weapons;
 961                                         weapon_action(e.weapon, WR_PRECACHE);
 962                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 963                                         break;
 964                                 }
 965                         }
 966                         if (j > WEP_LAST)
 967                         {
 968                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 969                         }
 970                 }
 971                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 972         }
 973
 974         if(g_weaponarena)
 975                 g_weaponarena_random = cvar("g_weaponarena_random");
 976         else
 977                 g_weaponarena_random = 0;
 978         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 979
 980         if (g_weaponarena)
 981         {
 982                 start_weapons = g_weaponarena;
 983                 if(!(g_lms || g_ca))
 984                         start_items |= IT_UNLIMITED_AMMO;
 985         }
 986         else if (g_minstagib)
 987         {
 988                 start_health = 100;
 989                 start_armorvalue = 0;
 990                 start_weapons = WEPBIT_MINSTANEX;
 991                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 992                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 993
 994                 if (g_minstagib_invis_alpha <= 0)
 995                         g_minstagib_invis_alpha = -1;
 996         }
 997         else
 998         {
 999                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1000                 {
1001                         e = get_weaponinfo(i);
1002                         if(want_weapon("g_start_weapon_", e, FALSE))
1003                                 start_weapons |= e.weapons;
1004                 }
1005         }
1006
1007         if(!cvar("g_use_ammunition"))
1008                 start_items |= IT_UNLIMITED_AMMO;
1009
1010         if(g_minstagib)
1011         {
1012                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1013                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1014         }
1015         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
1016         {
1017                 start_ammo_rockets = 999;
1018                 start_ammo_shells = 999;
1019                 start_ammo_cells = 999;
1020                 start_ammo_nails = 999;
1021                 start_ammo_fuel = 999;
1022         }
1023         else
1024         {
1025                 if(g_lms || g_ca)
1026                 {
1027                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1028                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1029                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1030                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1031                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1032                 }
1033                 else
1034                 {
1035                         start_ammo_shells = cvar("g_start_ammo_shells");
1036                         start_ammo_nails = cvar("g_start_ammo_nails");
1037                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1038                         start_ammo_cells = cvar("g_start_ammo_cells");
1039                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1040                 }
1041         }
1042
1043         if (g_lms || g_ca)
1044         {
1045                 start_health = cvar("g_lms_start_health");
1046                 start_armorvalue = cvar("g_lms_start_armor");
1047         }
1048
1049         if (inWarmupStage)
1050         {
1051                 warmup_start_ammo_shells = start_ammo_shells;
1052                 warmup_start_ammo_nails = start_ammo_nails;
1053                 warmup_start_ammo_rockets = start_ammo_rockets;
1054                 warmup_start_ammo_cells = start_ammo_cells;
1055                 warmup_start_ammo_fuel = start_ammo_fuel;
1056                 warmup_start_health = start_health;
1057                 warmup_start_armorvalue = start_armorvalue;
1058                 warmup_start_weapons = start_weapons;
1059
1060                 if (!g_weaponarena && !g_minstagib && !g_ca)
1061                 {
1062                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1063                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1064                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1065                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1066                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1067                         warmup_start_health = cvar("g_warmup_start_health");
1068                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1069                         warmup_start_weapons = 0;
1070                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1071                         {
1072                                 e = get_weaponinfo(i);
1073                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1074                                         warmup_start_weapons |= e.weapons;
1075                         }
1076                 }
1077         }
1078
1079         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1080         {
1081                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1082                 start_items |= IT_FUEL_REGEN;
1083                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1084                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1085         }
1086
1087         if (g_jetpack)
1088                 start_items |= IT_JETPACK;
1089
1090         if (g_weapon_stay == 2)
1091         {
1092                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1093                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1094                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1095                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1096                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1097                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1098                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1099                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1100                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1101                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1102         }
1103
1104         MUTATOR_CALLHOOK(SetStartItems);
1105
1106         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1107         {
1108                 e = get_weaponinfo(i);
1109                 if(e.weapons & (start_weapons | warmup_start_weapons))
1110                         weapon_action(e.weapon, WR_PRECACHE);
1111         }
1112
1113         start_ammo_shells = max(0, start_ammo_shells);
1114         start_ammo_nails = max(0, start_ammo_nails);
1115         start_ammo_cells = max(0, start_ammo_cells);
1116         start_ammo_rockets = max(0, start_ammo_rockets);
1117         start_ammo_fuel = max(0, start_ammo_fuel);
1118
1119         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1120         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1121         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1122         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1123         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1124 }
1125
1126 float g_bugrigs;
1127 float g_bugrigs_planar_movement;
1128 float g_bugrigs_planar_movement_car_jumping;
1129 float g_bugrigs_reverse_spinning;
1130 float g_bugrigs_reverse_speeding;
1131 float g_bugrigs_reverse_stopping;
1132 float g_bugrigs_air_steering;
1133 float g_bugrigs_angle_smoothing;
1134 float g_bugrigs_friction_floor;
1135 float g_bugrigs_friction_brake;
1136 float g_bugrigs_friction_air;
1137 float g_bugrigs_accel;
1138 float g_bugrigs_speed_ref;
1139 float g_bugrigs_speed_pow;
1140 float g_bugrigs_steer;
1141
1142 float g_touchexplode;
1143 float g_touchexplode_radius;
1144 float g_touchexplode_damage;
1145 float g_touchexplode_edgedamage;
1146 float g_touchexplode_force;
1147
1148 float sv_autotaunt;
1149 float sv_taunt;
1150
1151 float sv_pitch_min;
1152 float sv_pitch_max;
1153 float sv_pitch_fixyaw;
1154
1155 string GetGametype(); // g_world.qc
1156 void readlevelcvars(void)
1157 {
1158         // first load all the mutators
1159         if(cvar("g_nix"))
1160                 MUTATOR_ADD(mutator_nix);
1161         if(cvar("g_dodging"))
1162                 MUTATOR_ADD(mutator_dodging);
1163         if(cvar("g_rocket_flying"))
1164                 MUTATOR_ADD(mutator_rocketflying);
1165         if(cvar("g_vampire"))
1166                 MUTATOR_ADD(mutator_vampire);
1167
1168         if(cvar("sv_allow_fullbright"))
1169                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1170
1171     g_bugrigs = cvar("g_bugrigs");
1172     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1173     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1174     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1175     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1176     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1177     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1178     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1179     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1180     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1181     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1182     g_bugrigs_accel = cvar("g_bugrigs_accel");
1183     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1184     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1185     g_bugrigs_steer = cvar("g_bugrigs_steer");
1186
1187     g_touchexplode = cvar("g_touchexplode");
1188     g_touchexplode_radius = cvar("g_touchexplode_radius");
1189     g_touchexplode_damage = cvar("g_touchexplode_damage");
1190     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1191     g_touchexplode_force = cvar("g_touchexplode_force");
1192
1193 #ifdef ALLOW_FORCEMODELS
1194         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1195 #endif
1196         sv_loddistance1 = cvar("sv_loddistance1");
1197         sv_loddistance2 = cvar("sv_loddistance2");
1198
1199         if(sv_loddistance2 <= sv_loddistance1)
1200                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1201
1202         sv_clones = cvar("sv_clones");
1203         sv_gentle = cvar("sv_gentle");
1204         sv_foginterval = cvar("sv_foginterval");
1205         g_cloaked = cvar("g_cloaked");
1206     if(g_cts)
1207         g_cloaked = 1; // always enable cloak in CTS
1208         g_jump_grunt = cvar("g_jump_grunt");
1209         g_footsteps = cvar("g_footsteps");
1210         g_grappling_hook = cvar("g_grappling_hook");
1211         g_jetpack = cvar("g_jetpack");
1212         g_midair = cvar("g_midair");
1213         g_minstagib = cvar("g_minstagib");
1214         g_norecoil = cvar("g_norecoil");
1215         g_bloodloss = cvar("g_bloodloss");
1216         sv_maxidle = cvar("sv_maxidle");
1217         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1218         sv_pogostick = cvar("sv_pogostick");
1219         g_ctf_reverse = cvar("g_ctf_reverse");
1220         sv_autotaunt = cvar("sv_autotaunt");
1221         sv_taunt = cvar("sv_taunt");
1222
1223         inWarmupStage = cvar("g_warmup");
1224         g_warmup_limit = cvar("g_warmup_limit");
1225         g_warmup_allguns = cvar("g_warmup_allguns");
1226         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1227
1228         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1229                 inWarmupStage = 0; // these modes cannot work together, sorry
1230
1231         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1232         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1233         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1234         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1235         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1236         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1237         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1238         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1239         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1240         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1241         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1242         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1243
1244         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1245         g_weaponratefactor = cvar("g_weaponratefactor");
1246         g_weapondamagefactor = cvar("g_weapondamagefactor");
1247         g_weaponforcefactor = cvar("g_weaponforcefactor");
1248         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1249
1250         g_pickup_shells = cvar("g_pickup_shells");
1251         g_pickup_shells_max = cvar("g_pickup_shells_max");
1252         g_pickup_nails = cvar("g_pickup_nails");
1253         g_pickup_nails_max = cvar("g_pickup_nails_max");
1254         g_pickup_rockets = cvar("g_pickup_rockets");
1255         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1256         g_pickup_cells = cvar("g_pickup_cells");
1257         g_pickup_cells_max = cvar("g_pickup_cells_max");
1258         g_pickup_fuel = cvar("g_pickup_fuel");
1259         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1260         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1261         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1262         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1263         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1264         g_pickup_armormedium = cvar("g_pickup_armormedium");
1265         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1266         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1267         g_pickup_armorbig = cvar("g_pickup_armorbig");
1268         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1269         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1270         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1271         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1272         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1273         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1274         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1275         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1276         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1277         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1278         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1279         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1280         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1281         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1282         g_pickup_healthmega = cvar("g_pickup_healthmega");
1283         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1284         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1285
1286         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1287         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1288
1289         g_pinata = cvar("g_pinata");
1290
1291     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1292     if(!g_weapon_stay)
1293         g_weapon_stay = cvar("g_weapon_stay");
1294
1295         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1296                 g_weapon_stay = 1;
1297
1298         g_ghost_items = cvar("g_ghost_items");
1299
1300         if(g_ghost_items >= 1)
1301                 g_ghost_items = 0.25; // default alpha value
1302
1303         if not(inWarmupStage && !g_ca)
1304                 game_starttime = cvar("g_start_delay");
1305
1306         sv_pitch_min = cvar("sv_pitch_min");
1307         sv_pitch_max = cvar("sv_pitch_max");
1308         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1309
1310         readplayerstartcvars();
1311 }
1312
1313 //#NO AUTOCVARS END
1314
1315 // Sound functions
1316 string precache_sound (string s) = #19;
1317 float precache_sound_index (string s) = #19;
1318
1319 #define SND_VOLUME      1
1320 #define SND_ATTENUATION 2
1321 #define SND_LARGEENTITY 8
1322 #define SND_LARGESOUND  16
1323
1324 float sound_allowed(float dest, entity e)
1325 {
1326     // sounds from world may always pass
1327     for (;;)
1328     {
1329         if (e.classname == "body")
1330             e = e.enemy;
1331         if (e.owner && e.owner != e)
1332             e = e.owner;
1333         else
1334             break;
1335     }
1336     // sounds to self may always pass
1337     if (dest == MSG_ONE)
1338         if (e == msg_entity)
1339             return TRUE;
1340     // sounds by players can be removed
1341     if (autocvar_bot_sound_monopoly)
1342         if (clienttype(e) == CLIENTTYPE_REAL)
1343             return FALSE;
1344     // anything else may pass
1345     return TRUE;
1346 }
1347
1348 #ifdef COMPAT_XON010_CHANNELS
1349 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1350 void sound(entity e, float chan, string samp, float vol, float atten)
1351 {
1352     if (!sound_allowed(MSG_BROADCAST, e))
1353         return;
1354     sound_builtin(e, chan, samp, vol, atten);
1355 }
1356 #else
1357 #undef sound
1358 void sound(entity e, float chan, string samp, float vol, float atten)
1359 {
1360     if (!sound_allowed(MSG_BROADCAST, e))
1361         return;
1362     sound7(e, chan, samp, vol, atten, 0, 0);
1363 }
1364 #endif
1365
1366 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1367 {
1368     float entno, idx;
1369
1370     if (!sound_allowed(dest, e))
1371         return;
1372
1373     entno = num_for_edict(e);
1374     idx = precache_sound_index(samp);
1375
1376     float sflags;
1377     sflags = 0;
1378
1379     atten = floor(atten * 64);
1380     vol = floor(vol * 255);
1381
1382     if (vol != 255)
1383         sflags |= SND_VOLUME;
1384     if (atten != 64)
1385         sflags |= SND_ATTENUATION;
1386     if (entno >= 8192 || chan < 0 || chan > 7)
1387         sflags |= SND_LARGEENTITY;
1388     if (idx >= 256)
1389         sflags |= SND_LARGESOUND;
1390
1391     WriteByte(dest, SVC_SOUND);
1392     WriteByte(dest, sflags);
1393     if (sflags & SND_VOLUME)
1394         WriteByte(dest, vol);
1395     if (sflags & SND_ATTENUATION)
1396         WriteByte(dest, atten);
1397     if (sflags & SND_LARGEENTITY)
1398     {
1399         WriteShort(dest, entno);
1400         WriteByte(dest, chan);
1401     }
1402     else
1403     {
1404         WriteShort(dest, entno * 8 + chan);
1405     }
1406     if (sflags & SND_LARGESOUND)
1407         WriteShort(dest, idx);
1408     else
1409         WriteByte(dest, idx);
1410
1411     WriteCoord(dest, o_x);
1412     WriteCoord(dest, o_y);
1413     WriteCoord(dest, o_z);
1414 }
1415 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1416 {
1417     vector o;
1418
1419     if (!sound_allowed(dest, e))
1420         return;
1421
1422     o = e.origin + 0.5 * (e.mins + e.maxs);
1423     soundtoat(dest, e, o, chan, samp, vol, atten);
1424 }
1425 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1426 {
1427     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1428 }
1429 void stopsoundto(float dest, entity e, float chan)
1430 {
1431     float entno;
1432
1433     if (!sound_allowed(dest, e))
1434         return;
1435
1436     entno = num_for_edict(e);
1437
1438     if (entno >= 8192 || chan < 0 || chan > 7)
1439     {
1440         float idx, sflags;
1441         idx = precache_sound_index("misc/null.wav");
1442         sflags = SND_LARGEENTITY;
1443         if (idx >= 256)
1444             sflags |= SND_LARGESOUND;
1445         WriteByte(dest, SVC_SOUND);
1446         WriteByte(dest, sflags);
1447         WriteShort(dest, entno);
1448         WriteByte(dest, chan);
1449         if (sflags & SND_LARGESOUND)
1450             WriteShort(dest, idx);
1451         else
1452             WriteByte(dest, idx);
1453         WriteCoord(dest, e.origin_x);
1454         WriteCoord(dest, e.origin_y);
1455         WriteCoord(dest, e.origin_z);
1456     }
1457     else
1458     {
1459         WriteByte(dest, SVC_STOPSOUND);
1460         WriteShort(dest, entno * 8 + chan);
1461     }
1462 }
1463 void stopsound(entity e, float chan)
1464 {
1465     if (!sound_allowed(MSG_BROADCAST, e))
1466         return;
1467
1468     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1469     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1470 }
1471
1472 void play2(entity e, string filename)
1473 {
1474     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1475     msg_entity = e;
1476     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1477 }
1478
1479 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1480 .float spamtime;
1481 float spamsound(entity e, float chan, string samp, float vol, float atten)
1482 {
1483     if (!sound_allowed(MSG_BROADCAST, e))
1484         return FALSE;
1485
1486     if (time > e.spamtime)
1487     {
1488         e.spamtime = time;
1489         sound(e, chan, samp, vol, atten);
1490         return TRUE;
1491     }
1492     return FALSE;
1493 }
1494
1495 void play2team(float t, string filename)
1496 {
1497     local entity head;
1498
1499     if (autocvar_bot_sound_monopoly)
1500         return;
1501
1502     FOR_EACH_REALPLAYER(head)
1503     {
1504         if (head.team == t)
1505             play2(head, filename);
1506     }
1507 }
1508
1509 void play2all(string samp)
1510 {
1511     if (autocvar_bot_sound_monopoly)
1512         return;
1513
1514     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1515 }
1516
1517 void PrecachePlayerSounds(string f);
1518 void precache_playermodel(string m)
1519 {
1520         float globhandle, i, n;
1521         string f;
1522
1523         if(substring(m, -9,5) == "_lod1")
1524                 return;
1525         if(substring(m, -9,5) == "_lod2")
1526                 return;
1527         precache_model(m);
1528         if(sv_loddistance1)
1529         {
1530                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1531                 if(fexists(f))
1532                         precache_model(f);
1533                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1534                 if(fexists(f))
1535                         precache_model(f);
1536         }
1537
1538         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1539         if (globhandle < 0)
1540                 return;
1541         n = search_getsize(globhandle);
1542         for (i = 0; i < n; ++i)
1543         {
1544                 //print(search_getfilename(globhandle, i), "\n");
1545                 f = search_getfilename(globhandle, i);
1546                 PrecachePlayerSounds(f);
1547         }
1548         search_end(globhandle);
1549 }
1550 void precache_all_playermodels(string pattern)
1551 {
1552         float globhandle, i, n;
1553         string f;
1554
1555         globhandle = search_begin(pattern, TRUE, FALSE);
1556         if (globhandle < 0)
1557                 return;
1558         n = search_getsize(globhandle);
1559         for (i = 0; i < n; ++i)
1560         {
1561                 //print(search_getfilename(globhandle, i), "\n");
1562                 f = search_getfilename(globhandle, i);
1563                 precache_playermodel(f);
1564         }
1565         search_end(globhandle);
1566 }
1567
1568 void precache()
1569 {
1570     // gamemode related things
1571     precache_model ("models/misc/chatbubble.spr");
1572     if (g_runematch)
1573     {
1574         precache_model ("models/runematch/curse.mdl");
1575         precache_model ("models/runematch/rune.mdl");
1576     }
1577
1578 #ifdef TTURRETS_ENABLED
1579     if (autocvar_g_turrets)
1580         turrets_precash();
1581 #endif
1582
1583     // Precache all player models if desired
1584     if (autocvar_sv_precacheplayermodels)
1585     {
1586         PrecachePlayerSounds("sound/player/default.sounds");
1587         precache_all_playermodels("models/player/*.zym");
1588         precache_all_playermodels("models/player/*.dpm");
1589         precache_all_playermodels("models/player/*.md3");
1590         precache_all_playermodels("models/player/*.psk");
1591         precache_all_playermodels("models/player/*.iqm");
1592     }
1593
1594     if (autocvar_sv_defaultcharacter)
1595     {
1596         string s;
1597         s = autocvar_sv_defaultplayermodel_red;
1598         if (s != "")
1599             precache_playermodel(s);
1600         s = autocvar_sv_defaultplayermodel_blue;
1601         if (s != "")
1602             precache_playermodel(s);
1603         s = autocvar_sv_defaultplayermodel_yellow;
1604         if (s != "")
1605             precache_playermodel(s);
1606         s = autocvar_sv_defaultplayermodel_pink;
1607         if (s != "")
1608             precache_playermodel(s);
1609         s = autocvar_sv_defaultplayermodel;
1610         if (s != "")
1611             precache_playermodel(s);
1612     }
1613
1614     if (g_footsteps)
1615     {
1616         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1617         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1618     }
1619
1620     // gore and miscellaneous sounds
1621     //precache_sound ("misc/h2ohit.wav");
1622     precache_model ("models/hook.md3");
1623     precache_sound ("misc/armorimpact.wav");
1624     precache_sound ("misc/bodyimpact1.wav");
1625     precache_sound ("misc/bodyimpact2.wav");
1626     precache_sound ("misc/gib.wav");
1627     precache_sound ("misc/gib_splat01.wav");
1628     precache_sound ("misc/gib_splat02.wav");
1629     precache_sound ("misc/gib_splat03.wav");
1630     precache_sound ("misc/gib_splat04.wav");
1631     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1632     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1633     precache_sound ("misc/null.wav");
1634     precache_sound ("misc/spawn.wav");
1635     precache_sound ("misc/talk.wav");
1636     precache_sound ("misc/teleport.wav");
1637     precache_sound ("misc/poweroff.wav");
1638     precache_sound ("player/lava.wav");
1639     precache_sound ("player/slime.wav");
1640
1641     if (g_jetpack)
1642         precache_sound ("misc/jetpack_fly.wav");
1643
1644     precache_model ("models/sprites/0.spr32");
1645     precache_model ("models/sprites/1.spr32");
1646     precache_model ("models/sprites/2.spr32");
1647     precache_model ("models/sprites/3.spr32");
1648     precache_model ("models/sprites/4.spr32");
1649     precache_model ("models/sprites/5.spr32");
1650     precache_model ("models/sprites/6.spr32");
1651     precache_model ("models/sprites/7.spr32");
1652     precache_model ("models/sprites/8.spr32");
1653     precache_model ("models/sprites/9.spr32");
1654     precache_model ("models/sprites/10.spr32");
1655
1656     // common weapon precaches
1657         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1658     precache_sound ("weapons/weapon_switch.wav");
1659     precache_sound ("weapons/weaponpickup.wav");
1660     precache_sound ("weapons/unavailable.wav");
1661     precache_sound ("weapons/dryfire.wav");
1662     if (g_grappling_hook)
1663     {
1664         precache_sound ("weapons/hook_fire.wav"); // hook
1665         precache_sound ("weapons/hook_impact.wav"); // hook
1666     }
1667
1668     if(autocvar_sv_precacheweapons)
1669     {
1670         //precache weapon models/sounds
1671         local float wep;
1672         wep = WEP_FIRST;
1673         while (wep <= WEP_LAST)
1674         {
1675             weapon_action(wep, WR_PRECACHE);
1676             wep = wep + 1;
1677         }
1678     }
1679
1680     precache_model("models/elaser.mdl");
1681     precache_model("models/laser.mdl");
1682     precache_model("models/ebomb.mdl");
1683
1684 #if 0
1685     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1686
1687     if (!self.noise && self.music) // quake 3 uses the music field
1688         self.noise = self.music;
1689
1690     // plays music for the level if there is any
1691     if (self.noise)
1692     {
1693         precache_sound (self.noise);
1694         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1695     }
1696 #endif
1697 }
1698
1699 // sorry, but using \ in macros breaks line numbers
1700 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1701 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1702 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1703
1704 // WARNING: this kills the trace globals
1705 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1706 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1707
1708 #define INITPRIO_FIRST              0
1709 #define INITPRIO_GAMETYPE           0
1710 #define INITPRIO_GAMETYPE_FALLBACK  1
1711 #define INITPRIO_FINDTARGET        10
1712 #define INITPRIO_DROPTOFLOOR       20
1713 #define INITPRIO_SETLOCATION       90
1714 #define INITPRIO_LINKDOORS         91
1715 #define INITPRIO_LAST              99
1716
1717 .void(void) initialize_entity;
1718 .float initialize_entity_order;
1719 .entity initialize_entity_next;
1720 entity initialize_entity_first;
1721
1722 void make_safe_for_remove(entity e)
1723 {
1724     if (e.initialize_entity)
1725     {
1726         entity ent, prev;
1727         for (ent = initialize_entity_first; ent; )
1728         {
1729             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1730             {
1731                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1732                 // skip it in linked list
1733                 if (prev)
1734                 {
1735                     prev.initialize_entity_next = ent.initialize_entity_next;
1736                     ent = prev.initialize_entity_next;
1737                 }
1738                 else
1739                 {
1740                     initialize_entity_first = ent.initialize_entity_next;
1741                     ent = initialize_entity_first;
1742                 }
1743             }
1744             else
1745             {
1746                 prev = ent;
1747                 ent = ent.initialize_entity_next;
1748             }
1749         }
1750     }
1751 }
1752
1753 void objerror(string s)
1754 {
1755     make_safe_for_remove(self);
1756     objerror_builtin(s);
1757 }
1758
1759 .float remove_except_protected_forbidden;
1760 void remove_except_protected(entity e)
1761 {
1762         if(e.remove_except_protected_forbidden)
1763                 error("not allowed to remove this at this point");
1764         remove_builtin(e);
1765 }
1766
1767 void remove_unsafely(entity e)
1768 {
1769     remove_builtin(e);
1770 }
1771
1772 void remove_safely(entity e)
1773 {
1774     make_safe_for_remove(e);
1775     remove_builtin(e);
1776 }
1777
1778 void InitializeEntity(entity e, void(void) func, float order)
1779 {
1780     entity prev, cur;
1781
1782     if (!e || e.initialize_entity)
1783     {
1784         // make a proxy initializer entity
1785         entity e_old;
1786         e_old = e;
1787         e = spawn();
1788         e.classname = "initialize_entity";
1789         e.enemy = e_old;
1790     }
1791
1792     e.initialize_entity = func;
1793     e.initialize_entity_order = order;
1794
1795     cur = initialize_entity_first;
1796     for (;;)
1797     {
1798         if (!cur || cur.initialize_entity_order > order)
1799         {
1800             // insert between prev and cur
1801             if (prev)
1802                 prev.initialize_entity_next = e;
1803             else
1804                 initialize_entity_first = e;
1805             e.initialize_entity_next = cur;
1806             return;
1807         }
1808         prev = cur;
1809         cur = cur.initialize_entity_next;
1810     }
1811 }
1812 void InitializeEntitiesRun()
1813 {
1814     entity startoflist;
1815     startoflist = initialize_entity_first;
1816     initialize_entity_first = world;
1817     remove = remove_except_protected;
1818     for (self = startoflist; self; self = self.initialize_entity_next)
1819     {
1820         self.remove_except_protected_forbidden = 1;
1821     }
1822     for (self = startoflist; self; )
1823     {
1824         entity e;
1825         var void(void) func;
1826         e = self.initialize_entity_next;
1827         func = self.initialize_entity;
1828         self.initialize_entity_order = 0;
1829         self.initialize_entity = func_null;
1830         self.initialize_entity_next = world;
1831         self.remove_except_protected_forbidden = 0;
1832         if (self.classname == "initialize_entity")
1833         {
1834             entity e_old;
1835             e_old = self.enemy;
1836             remove_builtin(self);
1837             self = e_old;
1838         }
1839         //dprint("Delayed initialization: ", self.classname, "\n");
1840         if(func != func_null)
1841             func();
1842         else
1843         {
1844             eprint(self);
1845             backtrace(strcat("Null function in: ", self.classname, "\n"));
1846         }
1847         self = e;
1848     }
1849     remove = remove_unsafely;
1850 }
1851
1852 .float uncustomizeentityforclient_set;
1853 .void(void) uncustomizeentityforclient;
1854 void(void) SUB_Nullpointer = #0;
1855 void UncustomizeEntitiesRun()
1856 {
1857     entity oldself;
1858     oldself = self;
1859     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1860         self.uncustomizeentityforclient();
1861     self = oldself;
1862 }
1863 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1864 {
1865     e.customizeentityforclient = customizer;
1866     e.uncustomizeentityforclient = uncustomizer;
1867     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1868 }
1869
1870 .float nottargeted;
1871 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1872
1873 void() SUB_Remove;
1874 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1875 {
1876     vector mi, ma;
1877
1878     if (e.classname == "")
1879         e.classname = "net_linked";
1880
1881     if (e.model == "" || self.modelindex == 0)
1882     {
1883         mi = e.mins;
1884         ma = e.maxs;
1885         setmodel(e, "null");
1886         setsize(e, mi, ma);
1887     }
1888
1889     e.SendEntity = sendfunc;
1890     e.SendFlags = 0xFFFFFF;
1891
1892     if (!docull)
1893         e.effects |= EF_NODEPTHTEST;
1894
1895     if (dt)
1896     {
1897         e.nextthink = time + dt;
1898         e.think = SUB_Remove;
1899     }
1900 }
1901
1902 void adaptor_think2touch()
1903 {
1904     entity o;
1905     o = other;
1906     other = world;
1907     self.touch();
1908     other = o;
1909 }
1910
1911 void adaptor_think2use()
1912 {
1913     entity o, a;
1914     o = other;
1915     a = activator;
1916     activator = world;
1917     other = world;
1918     self.use();
1919     other = o;
1920     activator = a;
1921 }
1922
1923 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1924 {
1925         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1926                 self.projectiledeathtype |= HITTYPE_SPLASH;
1927         adaptor_think2use();
1928 }
1929
1930 // deferred dropping
1931 void DropToFloor_Handler()
1932 {
1933     droptofloor_builtin();
1934     self.dropped_origin = self.origin;
1935 }
1936
1937 void droptofloor()
1938 {
1939     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1940 }
1941
1942
1943
1944 float trace_hits_box_a0, trace_hits_box_a1;
1945
1946 float trace_hits_box_1d(float end, float thmi, float thma)
1947 {
1948     if (end == 0)
1949     {
1950         // just check if x is in range
1951         if (0 < thmi)
1952             return FALSE;
1953         if (0 > thma)
1954             return FALSE;
1955     }
1956     else
1957     {
1958         // do the trace with respect to x
1959         // 0 -> end has to stay in thmi -> thma
1960         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1961         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1962         if (trace_hits_box_a0 > trace_hits_box_a1)
1963             return FALSE;
1964     }
1965     return TRUE;
1966 }
1967
1968 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1969 {
1970     end -= start;
1971     thmi -= start;
1972     thma -= start;
1973     // now it is a trace from 0 to end
1974
1975     trace_hits_box_a0 = 0;
1976     trace_hits_box_a1 = 1;
1977
1978     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1979         return FALSE;
1980     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1981         return FALSE;
1982     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1983         return FALSE;
1984
1985     return TRUE;
1986 }
1987
1988 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1989 {
1990     return trace_hits_box(start, end, thmi - ma, thma - mi);
1991 }
1992
1993 float SUB_NoImpactCheck()
1994 {
1995         // zero hitcontents = this is not the real impact, but either the
1996         // mirror-impact of something hitting the projectile instead of the
1997         // projectile hitting the something, or a touchareagrid one. Neither of
1998         // these stop the projectile from moving, so...
1999         if(trace_dphitcontents == 0)
2000         {
2001                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
2002                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
2003                 checkclient();
2004         }
2005     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2006         return 1;
2007     if (other == world && self.size != '0 0 0')
2008     {
2009         vector tic;
2010         tic = self.velocity * sys_frametime;
2011         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2012         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2013         if (trace_fraction >= 1)
2014         {
2015             dprint("Odd... did not hit...?\n");
2016         }
2017         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2018         {
2019             dprint("Detected and prevented the sky-grapple bug.\n");
2020             return 1;
2021         }
2022     }
2023
2024     return 0;
2025 }
2026
2027 #define SUB_OwnerCheck() (other && (other == self.owner))
2028
2029 void RemoveGrapplingHook(entity pl);
2030 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2031 {
2032         if(SUB_OwnerCheck())
2033                 return TRUE;
2034         if(SUB_NoImpactCheck())
2035         {
2036                 if(self.classname == "grapplinghook")
2037                         RemoveGrapplingHook(self.realowner);
2038                 else
2039                         remove(self);
2040                 return TRUE;
2041         }
2042         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2043                 UpdateCSQCProjectileNextFrame(self);
2044         return FALSE;
2045 }
2046 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2047
2048 float MAX_IPBAN_URIS           = 16;
2049
2050 float URI_GET_DISCARD          = 0;
2051 float URI_GET_IPBAN            = 1;
2052 float URI_GET_IPBAN_END        = 16;
2053 float URI_GET_PLAYERSTATS_SENT = 17;
2054
2055 void URI_Get_Callback(float id, float status, string data)
2056 {
2057     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2058     dprint(data);
2059     dprint("\nEnd of data.\n");
2060
2061     if (id == URI_GET_DISCARD)
2062     {
2063         // discard
2064     }
2065     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2066     {
2067         // online ban list
2068         OnlineBanList_URI_Get_Callback(id, status, data);
2069     }
2070     else if (id == URI_GET_PLAYERSTATS_SENT)
2071     {
2072         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2073     }
2074     else
2075     {
2076         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2077     }
2078 }
2079
2080 void print_to(entity e, string s)
2081 {
2082     if (e)
2083         sprint(e, strcat(s, "\n"));
2084     else
2085         print(s, "\n");
2086 }
2087
2088 string uid2name(string myuid) {
2089         string s;
2090         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2091
2092         if(s == "")
2093                 s = "^1Unregistered Player";
2094         return s;
2095 }
2096
2097 float race_readTime(string map, float pos)
2098 {
2099         string rr;
2100         if(g_cts)
2101                 rr = CTS_RECORD;
2102         else
2103                 rr = RACE_RECORD;
2104
2105         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2106 }
2107
2108 string race_readUID(string map, float pos)
2109 {
2110         string rr;
2111         if(g_cts)
2112                 rr = CTS_RECORD;
2113         else
2114                 rr = RACE_RECORD;
2115
2116         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2117 }
2118
2119 float race_readPos(string map, float t) {
2120         float i;
2121         for (i = 1; i <= RANKINGS_CNT; ++i)
2122                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2123                         return i;
2124
2125         return 0; // pos is zero if unranked
2126 }
2127
2128 void race_writeTime(string map, float t, string myuid)
2129 {
2130         string rr;
2131         if(g_cts)
2132                 rr = CTS_RECORD;
2133         else
2134                 rr = RACE_RECORD;
2135
2136         float newpos;
2137         newpos = race_readPos(map, t);
2138
2139         float i, prevpos;
2140         for(i = 1; i <= RANKINGS_CNT; ++i)
2141         {
2142                 if(race_readUID(map, i) == myuid)
2143                         prevpos = i;
2144         }
2145         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2146                 for (i = prevpos; i > newpos; --i) {
2147                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2148                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2149                 }
2150         } else { // player has no ranked record yet
2151                 for (i = RANKINGS_CNT; i > newpos; --i) {
2152                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2153                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2154                 }
2155         }
2156
2157         // store new time itself
2158         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2159         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2160 }
2161
2162 string race_readName(string map, float pos)
2163 {
2164         string rr;
2165         if(g_cts)
2166                 rr = CTS_RECORD;
2167         else
2168                 rr = RACE_RECORD;
2169
2170         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2171 }
2172
2173 string race_placeName(float pos) {
2174         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2175         {
2176                 if(mod(pos, 10) == 1)
2177                         return strcat(ftos(pos), "st");
2178                 else if(mod(pos, 10) == 2)
2179                         return strcat(ftos(pos), "nd");
2180                 else if(mod(pos, 10) == 3)
2181                         return strcat(ftos(pos), "rd");
2182                 else
2183                         return strcat(ftos(pos), "th");
2184         }
2185         else
2186                 return strcat(ftos(pos), "th");
2187 }
2188 string getrecords(float page) // 50 records per page
2189 {
2190     float rec;
2191     string h;
2192     float r;
2193     float i;
2194     string s;
2195
2196     rec = 0;
2197
2198     s = "";
2199
2200     if (g_ctf)
2201     {
2202         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2203         {
2204             if (MapInfo_Get_ByID(i))
2205             {
2206                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2207                 if (r == 0)
2208                     continue;
2209                 // TODO: uid2name
2210                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2211                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2212                 ++rec;
2213             }
2214         }
2215     }
2216
2217     if (g_race)
2218     {
2219         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2220         {
2221             if (MapInfo_Get_ByID(i))
2222             {
2223                 r = race_readTime(MapInfo_Map_bspname, 1);
2224                 if (r == 0)
2225                     continue;
2226                 h = race_readName(MapInfo_Map_bspname, 1);
2227                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2228                 ++rec;
2229             }
2230         }
2231     }
2232
2233     if (g_cts)
2234     {
2235         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2236         {
2237             if (MapInfo_Get_ByID(i))
2238             {
2239                 r = race_readTime(MapInfo_Map_bspname, 1);
2240                 if (r == 0)
2241                     continue;
2242                 h = race_readName(MapInfo_Map_bspname, 1);
2243                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2244                 ++rec;
2245             }
2246         }
2247     }
2248
2249     MapInfo_ClearTemps();
2250
2251     if (s == "" && page == 0)
2252         return "No records are available on this server.\n";
2253     else
2254         return s;
2255 }
2256
2257 string getrankings()
2258 {
2259     string n;
2260     float t;
2261     float i;
2262     string s;
2263     string p;
2264     string map;
2265
2266     s = "";
2267
2268     map = GetMapname();
2269
2270     for (i = 1; i <= RANKINGS_CNT; ++i)
2271     {
2272         t = race_readTime(map, i);
2273         if (t == 0)
2274             continue;
2275         n = race_readName(map, i);
2276         p = race_placeName(i);
2277         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2278     }
2279
2280     MapInfo_ClearTemps();
2281
2282     if (s == "")
2283         return strcat("No records are available for the map: ", map, "\n");
2284     else
2285         return strcat("Records for ", map, ":\n", s);
2286 }
2287
2288 #define LADDER_FIRSTPOINT 100
2289 #define LADDER_CNT 10
2290         // position X still gives LADDER_FIRSTPOINT/X points
2291 #define LADDER_SIZE 30
2292         // ladder shows the top X players
2293 string top_uids[LADDER_SIZE];
2294 float top_scores[LADDER_SIZE];
2295 string getladder()
2296 {
2297     float i, j, k, uidcnt;
2298     string s, temp_s;
2299
2300     s = "";
2301     temp_s = "";
2302
2303     string rr;
2304     if(g_cts)
2305         rr = CTS_RECORD;
2306     else
2307         rr = RACE_RECORD;
2308
2309     string myuid;
2310
2311     for (k = 0; k < MapInfo_count; ++k)
2312     {
2313         if (MapInfo_Get_ByID(k))
2314         {
2315                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2316                         if(i == 0) // speed award
2317                         {
2318                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2319                                         continue;
2320
2321                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2322                         }
2323                         else // normal record, if it exists (else break)
2324                         {
2325                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2326                                         continue;
2327
2328                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2329                         }
2330
2331                         // string s contains:
2332                         // arg 0 = # of speed recs
2333                         // arg 1 = # of 1st place recs
2334                         // arg 2 = # of 2nd place recs
2335                         // ... etc
2336                         // LADDER_CNT+1 = total points
2337
2338                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2339                         if (temp_s == "")
2340                         {
2341                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2342                             ++uidcnt;
2343                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2344                             {
2345                                 if(j != LADDER_CNT + 1)
2346                                     temp_s = strcat(temp_s, "0 ");
2347                                 else
2348                                     temp_s = strcat(temp_s, "0");
2349                             }
2350                         }
2351
2352                         tokenize_console(temp_s);
2353                         s = "";
2354
2355                         if(i == 0) // speed award
2356                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2357                             {
2358                                 if(j == 0) // speed award
2359                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2360                                 else
2361                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2362                             }
2363                         else // record
2364                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2365                             {
2366                                 if(j == 0)
2367                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2368                                 else if(j == i) // wanted rec!
2369                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2370                                 else
2371                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2372                             }
2373
2374                         // total points are (by default) calculated like this:
2375                         // speedrec = floor(100 / 10) = 10 points
2376                         // 1st place = floor(100 / 1) = 100 points
2377                         // 2nd place = floor(100 / 2) = 50 points
2378                         // 3rd place = floor(100 / 3) = 33 points
2379                         // 4th place = floor(100 / 4) = 25 points
2380                         // 5th place = floor(100 / 5) = 20 points
2381                         // ... etc
2382
2383                         if(i == 0)
2384                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2385                         else
2386                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2387
2388                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2389                 }
2390         }
2391     }
2392
2393     float thiscnt;
2394     string thisuid;
2395     for (i = 0; i <= uidcnt; ++i) // for each known uid
2396     {
2397         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2398         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2399         tokenize_console(temp_s);
2400         thiscnt = stof(argv(LADDER_CNT+1));
2401
2402         if(thiscnt > top_scores[LADDER_SIZE-1])
2403         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2404         {
2405             if(thiscnt > top_scores[j])
2406             {
2407                 for (k = LADDER_SIZE-1; k >= j; --k)
2408                 {
2409                     top_uids[k] = top_uids[k-1];
2410                     top_scores[k] = top_scores[k-1];
2411                 }
2412                 top_uids[j] = thisuid;
2413                 top_scores[j] = thiscnt;
2414                 break;
2415             }
2416         }
2417     }
2418
2419     s = "^3-----------------------\n\n";
2420
2421     s = strcat(s, "Pos ^3|");
2422     s = strcat(s, " ^7Total  ^3|");
2423     for (i = 1; i <= LADDER_CNT; ++i)
2424     {
2425         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2426     }
2427     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2428
2429     s = strcat(s, "\n^3----+--------");
2430     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2431     {
2432         s = strcat(s, "+-----");
2433     }
2434 #if LADDER_CNT > 9
2435     for (i = 1; i <= LADDER_CNT - 9; ++i)
2436     {
2437         s = strcat(s, "+------");
2438     }
2439 #endif
2440
2441     s = strcat(s, "+--------------+--------------------\n");
2442
2443     for (i = 0; i < LADDER_SIZE; ++i)
2444     {
2445         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2446         tokenize_console(temp_s);
2447         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2448             continue;
2449         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2450         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2451         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2452         {
2453             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2454         }
2455 #if LADDER_CNT > 9
2456         for (j = 10; j <= LADDER_CNT; ++j)
2457         {
2458             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2459         }
2460 #endif
2461
2462         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2463         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2464     }
2465
2466     MapInfo_ClearTemps();
2467
2468     if (s == "")
2469         return "No ladder on this server!\n";
2470     else
2471         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2472 }
2473
2474
2475 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2476 {
2477     float m, i;
2478     vector start, org, delta, end, enddown, mstart;
2479
2480     m = e.dphitcontentsmask;
2481     e.dphitcontentsmask = goodcontents | badcontents;
2482
2483     org = world.mins;
2484     delta = world.maxs - world.mins;
2485
2486     for (i = 0; i < attempts; ++i)
2487     {
2488         start_x = org_x + random() * delta_x;
2489         start_y = org_y + random() * delta_y;
2490         start_z = org_z + random() * delta_z;
2491
2492         // rule 1: start inside world bounds, and outside
2493         // solid, and don't start from somewhere where you can
2494         // fall down to evil
2495         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2496         if (trace_fraction >= 1)
2497             continue;
2498         if (trace_startsolid)
2499             continue;
2500         if (trace_dphitcontents & badcontents)
2501             continue;
2502         if (trace_dphitq3surfaceflags & badsurfaceflags)
2503             continue;
2504
2505         // rule 2: if we are too high, lower the point
2506         if (trace_fraction * delta_z > maxaboveground)
2507             start = trace_endpos + '0 0 1' * maxaboveground;
2508         enddown = trace_endpos;
2509
2510         // rule 3: make sure we aren't outside the map. This only works
2511         // for somewhat well formed maps. A good rule of thumb is that
2512         // the map should have a convex outside hull.
2513         // these can be traceLINES as we already verified the starting box
2514         mstart = start + 0.5 * (e.mins + e.maxs);
2515         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2516         if (trace_fraction >= 1)
2517             continue;
2518         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2519         if (trace_fraction >= 1)
2520             continue;
2521         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2522         if (trace_fraction >= 1)
2523             continue;
2524         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2525         if (trace_fraction >= 1)
2526             continue;
2527         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2528         if (trace_fraction >= 1)
2529             continue;
2530
2531         // find a random vector to "look at"
2532         end_x = org_x + random() * delta_x;
2533         end_y = org_y + random() * delta_y;
2534         end_z = org_z + random() * delta_z;
2535         end = start + normalize(end - start) * vlen(delta);
2536
2537         // rule 4: start TO end must not be too short
2538         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2539         if (trace_startsolid)
2540             continue;
2541         if (trace_fraction < minviewdistance / vlen(delta))
2542             continue;
2543
2544         // rule 5: don't want to look at sky
2545         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2546             continue;
2547
2548         // rule 6: we must not end up in trigger_hurt
2549         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2550             continue;
2551
2552         break;
2553     }
2554
2555     e.dphitcontentsmask = m;
2556
2557     if (i < attempts)
2558     {
2559         setorigin(e, start);
2560         e.angles = vectoangles(end - start);
2561         dprint("Needed ", ftos(i + 1), " attempts\n");
2562         return TRUE;
2563     }
2564     else
2565         return FALSE;
2566 }
2567
2568 float zcurveparticles_effectno;
2569 vector zcurveparticles_start;
2570 float zcurveparticles_spd;
2571
2572 void endzcurveparticles()
2573 {
2574         if(zcurveparticles_effectno)
2575         {
2576                 // terminator
2577                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2578         }
2579         zcurveparticles_effectno = 0;
2580 }
2581
2582 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2583 {
2584         spd = bound(0, floor(spd / 16), 32767);
2585         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2586         {
2587                 endzcurveparticles();
2588                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2589                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2590                 WriteShort(MSG_BROADCAST, effectno);
2591                 WriteCoord(MSG_BROADCAST, start_x);
2592                 WriteCoord(MSG_BROADCAST, start_y);
2593                 WriteCoord(MSG_BROADCAST, start_z);
2594                 zcurveparticles_effectno = effectno;
2595                 zcurveparticles_start = start;
2596         }
2597         else
2598                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2599         WriteCoord(MSG_BROADCAST, end_x);
2600         WriteCoord(MSG_BROADCAST, end_y);
2601         WriteCoord(MSG_BROADCAST, end_z);
2602         WriteCoord(MSG_BROADCAST, end_dz);
2603         zcurveparticles_spd = spd;
2604 }
2605
2606 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2607 {
2608         float end_dz;
2609         vector vecxy, velxy;
2610
2611         vecxy = end - start;
2612         vecxy_z = 0;
2613         velxy = vel;
2614         velxy_z = 0;
2615
2616         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2617         {
2618                 endzcurveparticles();
2619                 trailparticles(world, effectno, start, end);
2620                 return;
2621         }
2622
2623         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2624         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2625 }
2626
2627 void write_recordmarker(entity pl, float tstart, float dt)
2628 {
2629     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2630
2631     // also write a marker into demo files for demotc-race-record-extractor to find
2632     stuffcmd(pl,
2633              strcat(
2634                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2635                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2636 }
2637
2638 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2639 {
2640         switch(algn)
2641         {
2642                 default:
2643                 case 3: // right
2644                         break;
2645
2646                 case 4: // left
2647                         vecs_y = -vecs_y;
2648                         break;
2649
2650                 case 1:
2651                         if(allowcenter) // 2: allow center handedness
2652                         {
2653                                 // center
2654                                 vecs_y = 0;
2655                                 vecs_z -= 2;
2656                         }
2657                         else
2658                         {
2659                                 // right
2660                         }
2661                         break;
2662
2663                 case 2:
2664                         if(allowcenter) // 2: allow center handedness
2665                         {
2666                                 // center
2667                                 vecs_y = 0;
2668                                 vecs_z -= 2;
2669                         }
2670                         else
2671                         {
2672                                 // left
2673                                 vecs_y = -vecs_y;
2674                         }
2675                         break;
2676         }
2677         return vecs;
2678 }
2679
2680 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2681 {
2682         string s;
2683         vector v;
2684
2685         if (autocvar_g_shootfromeye)
2686         {
2687                 if (visual)
2688                 {
2689                         vecs_y = 0;
2690                         vecs_z -= 2;
2691                 }
2692                 else
2693                 {
2694                         vecs_y = 0;
2695                         vecs_z = 0;
2696                 }
2697         }
2698         else if (autocvar_g_shootfromcenter)
2699         {
2700                 vecs_y = 0;
2701                 vecs_z -= 2;
2702         }
2703         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2704         {
2705                 v = stov(s);
2706                 if (y_is_right)
2707                         v_y = -v_y;
2708                 if (v_x != 0)
2709                         vecs_x = v_x;
2710                 vecs_y = v_y;
2711                 vecs_z = v_z;
2712         }
2713         else if (autocvar_g_shootfromclient)
2714         {
2715                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2716         }
2717         return vecs;
2718 }
2719
2720 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2721 {
2722         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2723 }
2724
2725
2726 void attach_sameorigin(entity e, entity to, string tag)
2727 {
2728     vector org, t_forward, t_left, t_up, e_forward, e_up;
2729     vector org0, ang0;
2730     float tagscale;
2731
2732     ang0 = e.angles;
2733     org0 = e.origin;
2734
2735     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2736     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2737     t_forward = v_forward * tagscale;
2738     t_left = v_right * -tagscale;
2739     t_up = v_up * tagscale;
2740
2741     e.origin_x = org * t_forward;
2742     e.origin_y = org * t_left;
2743     e.origin_z = org * t_up;
2744
2745     // current forward and up directions
2746     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2747                 e.angles = AnglesTransform_FromVAngles(e.angles);
2748         else
2749                 e.angles = AnglesTransform_FromAngles(e.angles);
2750     fixedmakevectors(e.angles);
2751
2752     // untransform forward, up!
2753     e_forward_x = v_forward * t_forward;
2754     e_forward_y = v_forward * t_left;
2755     e_forward_z = v_forward * t_up;
2756     e_up_x = v_up * t_forward;
2757     e_up_y = v_up * t_left;
2758     e_up_z = v_up * t_up;
2759
2760     e.angles = fixedvectoangles2(e_forward, e_up);
2761     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2762                 e.angles = AnglesTransform_ToVAngles(e.angles);
2763         else
2764                 e.angles = AnglesTransform_ToAngles(e.angles);
2765
2766     setattachment(e, to, tag);
2767     setorigin(e, e.origin);
2768 }
2769
2770 void detach_sameorigin(entity e)
2771 {
2772     vector org;
2773     org = gettaginfo(e, 0);
2774     e.angles = fixedvectoangles2(v_forward, v_up);
2775     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2776                 e.angles = AnglesTransform_ToVAngles(e.angles);
2777         else
2778                 e.angles = AnglesTransform_ToAngles(e.angles);
2779     setorigin(e, org);
2780     setattachment(e, world, "");
2781     setorigin(e, e.origin);
2782 }
2783
2784 void follow_sameorigin(entity e, entity to)
2785 {
2786     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2787     e.aiment = to; // make the hole follow bmodel
2788     e.punchangle = to.angles; // the original angles of bmodel
2789     e.view_ofs = e.origin - to.origin; // relative origin
2790     e.v_angle = e.angles - to.angles; // relative angles
2791 }
2792
2793 void unfollow_sameorigin(entity e)
2794 {
2795     e.movetype = MOVETYPE_NONE;
2796 }
2797
2798 entity gettaginfo_relative_ent;
2799 vector gettaginfo_relative(entity e, float tag)
2800 {
2801     if (!gettaginfo_relative_ent)
2802     {
2803         gettaginfo_relative_ent = spawn();
2804         gettaginfo_relative_ent.effects = EF_NODRAW;
2805     }
2806     gettaginfo_relative_ent.model = e.model;
2807     gettaginfo_relative_ent.modelindex = e.modelindex;
2808     gettaginfo_relative_ent.frame = e.frame;
2809     return gettaginfo(gettaginfo_relative_ent, tag);
2810 }
2811
2812 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2813 {
2814     float p;
2815     p = pow(2, chan);
2816     if (pl.soundentity.cnt & p)
2817         return;
2818     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2819     pl.soundentity.cnt |= p;
2820 }
2821
2822 void SoundEntity_StopSound(entity pl, float chan)
2823 {
2824     float p;
2825     p = pow(2, chan);
2826     if (pl.soundentity.cnt & p)
2827     {
2828         stopsoundto(MSG_ALL, pl.soundentity, chan);
2829         pl.soundentity.cnt &~= p;
2830     }
2831 }
2832
2833 void SoundEntity_Attach(entity pl)
2834 {
2835     pl.soundentity = spawn();
2836     pl.soundentity.classname = "soundentity";
2837     pl.soundentity.owner = pl;
2838     setattachment(pl.soundentity, pl, "");
2839     setmodel(pl.soundentity, "null");
2840 }
2841
2842 void SoundEntity_Detach(entity pl)
2843 {
2844     float i;
2845     for (i = 0; i <= 7; ++i)
2846         SoundEntity_StopSound(pl, i);
2847 }
2848
2849
2850 float ParseCommandPlayerSlotTarget_firsttoken;
2851 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2852 {
2853         string s;
2854         entity e, head;
2855         float n;
2856
2857         s = string_null;
2858
2859         ParseCommandPlayerSlotTarget_firsttoken = -1;
2860
2861         if (tokens > idx)
2862         {
2863                 if (substring(argv(idx), 0, 1) == "#")
2864                 {
2865                         s = substring(argv(idx), 1, -1);
2866                         ++idx;
2867                         if (s == "") if (tokens > idx)
2868                         {
2869                                 s = argv(idx);
2870                                 ++idx;
2871                         }
2872                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2873                         n = stof(s);
2874                         if (s == ftos(n) && n > 0 && n <= maxclients)
2875                         {
2876                                 e = edict_num(n);
2877                                 if (e.flags & FL_CLIENT)
2878                                         return e;
2879                         }
2880                 }
2881                 else
2882                 {
2883                         // it must be a nick name
2884                         s = argv(idx);
2885                         ++idx;
2886                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2887
2888                         n = 0;
2889                         FOR_EACH_CLIENT(head)
2890                                 if (head.netname == s)
2891                                 {
2892                                         e = head;
2893                                         ++n;
2894                                 }
2895                         if (n == 1)
2896                                 return e;
2897
2898                         s = strdecolorize(s);
2899                         n = 0;
2900                         FOR_EACH_CLIENT(head)
2901                                 if (strdecolorize(head.netname) == s)
2902                                 {
2903                                         e = head;
2904                                         ++n;
2905                                 }
2906                         if (n == 1)
2907                                 return e;
2908                 }
2909         }
2910
2911         return world;
2912 }
2913
2914 .float scale2;
2915
2916 float modeleffect_SendEntity(entity to, float sf)
2917 {
2918         float f;
2919         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2920
2921         f = 0;
2922         if(self.velocity != '0 0 0')
2923                 f |= 1;
2924         if(self.angles != '0 0 0')
2925                 f |= 2;
2926         if(self.avelocity != '0 0 0')
2927                 f |= 4;
2928
2929         WriteByte(MSG_ENTITY, f);
2930         WriteShort(MSG_ENTITY, self.modelindex);
2931         WriteByte(MSG_ENTITY, self.skin);
2932         WriteByte(MSG_ENTITY, self.frame);
2933         WriteCoord(MSG_ENTITY, self.origin_x);
2934         WriteCoord(MSG_ENTITY, self.origin_y);
2935         WriteCoord(MSG_ENTITY, self.origin_z);
2936         if(f & 1)
2937         {
2938                 WriteCoord(MSG_ENTITY, self.velocity_x);
2939                 WriteCoord(MSG_ENTITY, self.velocity_y);
2940                 WriteCoord(MSG_ENTITY, self.velocity_z);
2941         }
2942         if(f & 2)
2943         {
2944                 WriteCoord(MSG_ENTITY, self.angles_x);
2945                 WriteCoord(MSG_ENTITY, self.angles_y);
2946                 WriteCoord(MSG_ENTITY, self.angles_z);
2947         }
2948         if(f & 4)
2949         {
2950                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2951                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2952                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2953         }
2954         WriteShort(MSG_ENTITY, self.scale * 256.0);
2955         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2956         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2957         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2958         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2959
2960         return TRUE;
2961 }
2962
2963 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2964 {
2965         entity e;
2966         float sz;
2967         e = spawn();
2968         e.classname = "modeleffect";
2969         setmodel(e, m);
2970         e.frame = f;
2971         setorigin(e, o);
2972         e.velocity = v;
2973         e.angles = ang;
2974         e.avelocity = angv;
2975         e.alpha = a;
2976         e.teleport_time = t1;
2977         e.fade_time = t2;
2978         e.skin = s;
2979         if(s0 >= 0)
2980                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2981         else
2982                 e.scale = -s0;
2983         if(s2 >= 0)
2984                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2985         else
2986                 e.scale2 = -s2;
2987         sz = max(e.scale, e.scale2);
2988         setsize(e, e.mins * sz, e.maxs * sz);
2989         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2990 }
2991
2992 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2993 {
2994         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2995 }
2996
2997 float randombit(float bits)
2998 {
2999         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3000                 return bits;
3001
3002         float n, f, b, r;
3003
3004         r = random();
3005         b = 0;
3006         n = 0;
3007
3008         for(f = 1; f <= bits; f *= 2)
3009         {
3010                 if(bits & f)
3011                 {
3012                         ++n;
3013                         r *= n;
3014                         if(r <= 1)
3015                                 b = f;
3016                         else
3017                                 r = (r - 1) / (n - 1);
3018                 }
3019         }
3020
3021         return b;
3022 }
3023
3024 float randombits(float bits, float k, float error_return)
3025 {
3026         float r;
3027         r = 0;
3028         while(k > 0 && bits != r)
3029         {
3030                 r += randombit(bits - r);
3031                 --k;
3032         }
3033         if(error_return)
3034                 if(k > 0)
3035                         return -1; // all
3036         return r;
3037 }
3038
3039 void randombit_test(float bits, float iter)
3040 {
3041         while(iter > 0)
3042         {
3043                 print(ftos(randombit(bits)), "\n");
3044                 --iter;
3045         }
3046 }
3047
3048 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3049 {
3050         if(halflifedist > 0)
3051                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3052         else if(halflifedist < 0)
3053                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3054         else
3055                 return 1;
3056 }
3057
3058
3059
3060
3061 #ifdef RELEASE
3062 #define cvar_string_normal cvar_string_builtin
3063 #define cvar_normal cvar_builtin
3064 #else
3065 string cvar_string_normal(string n)
3066 {
3067         if not(cvar_type(n) & 1)
3068                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3069         return cvar_string_builtin(n);
3070 }
3071
3072 float cvar_normal(string n)
3073 {
3074         return stof(cvar_string_normal(n));
3075 }
3076 #endif
3077 #define cvar_set_normal cvar_set_builtin
3078
3079 void defer_think()
3080 {
3081     entity oself;
3082
3083     oself           = self;
3084     self            = self.owner;
3085     oself.think     = SUB_Remove;
3086     oself.nextthink = time;
3087
3088     oself.use();
3089 }
3090
3091 /*
3092     Execute func() after time + fdelay.
3093     self when func is executed = self when defer is called
3094 */
3095 void defer(float fdelay, void() func)
3096 {
3097     entity e;
3098
3099     e           = spawn();
3100     e.owner     = self;
3101     e.use       = func;
3102     e.think     = defer_think;
3103     e.nextthink = time + fdelay;
3104 }
3105
3106 .string aiment_classname;
3107 .float aiment_deadflag;
3108 void SetMovetypeFollow(entity ent, entity e)
3109 {
3110         // FIXME this may not be warpzone aware
3111         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3112         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3113         ent.aiment = e; // make the hole follow bmodel
3114         ent.punchangle = e.angles; // the original angles of bmodel
3115         ent.view_ofs = ent.origin - e.origin; // relative origin
3116         ent.v_angle = ent.angles - e.angles; // relative angles
3117         ent.aiment_classname = strzone(e.classname);
3118         ent.aiment_deadflag = e.deadflag;
3119 }
3120 void UnsetMovetypeFollow(entity ent)
3121 {
3122         ent.movetype = MOVETYPE_FLY;
3123         PROJECTILE_MAKETRIGGER(ent);
3124         ent.aiment = world;
3125 }
3126 float LostMovetypeFollow(entity ent)
3127 {
3128 /*
3129         if(ent.movetype != MOVETYPE_FOLLOW)
3130                 if(ent.aiment)
3131                         error("???");
3132 */
3133         if(ent.aiment)
3134         {
3135                 if(ent.aiment.classname != ent.aiment_classname)
3136                         return 1;
3137                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3138                         return 1;
3139         }
3140         return 0;
3141 }
3142
3143 float isPushable(entity e)
3144 {
3145         if(e.iscreature)
3146                 return TRUE;
3147         switch(e.classname)
3148         {
3149                 case "body":
3150                 case "droppedweapon":
3151                 case "keepawayball":
3152                 case "nexball_basketball":
3153                 case "nexball_football":
3154                         return TRUE;
3155                 case "bullet": // antilagged bullets can't hit this either
3156                         return FALSE;
3157         }
3158         if (e.projectiledeathtype)
3159                 return TRUE;
3160         return FALSE;
3161 }