qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = W_Name(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else replacement = "batteries"; // ;)
 365                 } else if (escape == "x") {
 366                         replacement = cursor_ent.netname;
 367                         if (replacement == "" || !cursor_ent)
 368                                 replacement = "nothing";
 369                 } else if (escape == "s")
 370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 371                 else if (escape == "S")
 372                         replacement = ftos(vlen(self.velocity));
 373
 374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 375                 p = p + strlen(replacement);
 376         }
 377         return msg;
 378 }
 379
 380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 381         return (value == 0) ? FALSE : TRUE;
 382 }
 383
 384 /*
 385 =============
 386 GetCvars
 387 =============
 388 Called with:
 389   0:  sends the request
 390   >0: receives a cvar from name=argv(f) value=argv(f+1)
 391 */
 392 void GetCvars_handleString(string thisname, float f, .string field, string name)
 393 {
 394         if (f < 0)
 395         {
 396                 if (self.field)
 397                         strunzone(self.field);
 398                 self.field = string_null;
 399         }
 400         else if (f > 0)
 401         {
 402                 if (thisname == name)
 403                 {
 404                         if (self.field)
 405                                 strunzone(self.field);
 406                         self.field = strzone(argv(f + 1));
 407                 }
 408         }
 409         else
 410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 411 }
 412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 413 {
 414         GetCvars_handleString(thisname, f, field, name);
 415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 416                 if (thisname == name)
 417                 {
 418                         string s;
 419                         s = func(strcat1(self.field));
 420                         if (s != self.field)
 421                         {
 422                                 strunzone(self.field);
 423                                 self.field = strzone(s);
 424                         }
 425                 }
 426 }
 427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 428 {
 429         if (f < 0)
 430         {
 431         }
 432         else if (f > 0)
 433         {
 434                 if (thisname == name)
 435                         self.field = stof(argv(f + 1));
 436         }
 437         else
 438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 439 }
 440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 441 {
 442         if (f < 0)
 443         {
 444         }
 445         else if (f > 0)
 446         {
 447                 if (thisname == name)
 448                 {
 449                         if(!self.field)
 450                         {
 451                                 self.field = stof(argv(f + 1));
 452                                 if(!self.field)
 453                                         self.field = -1;
 454                         }
 455                 }
 456         }
 457         else
 458         {
 459                 if(!self.field)
 460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 461         }
 462 }
 463 float w_getbestweapon(entity e);
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 vector randompos(vector m1, vector m2)
 547 {
 548     vector v;
 549     m2 = m2 - m1;
 550     v_x = m2_x * random() + m1_x;
 551     v_y = m2_y * random() + m1_y;
 552     v_z = m2_z * random() + m1_z;
 553     return  v;
 554 }
 555
 556 //#NO AUTOCVARS START
 557
 558 float g_pickup_shells;
 559 float g_pickup_shells_max;
 560 float g_pickup_nails;
 561 float g_pickup_nails_max;
 562 float g_pickup_rockets;
 563 float g_pickup_rockets_max;
 564 float g_pickup_cells;
 565 float g_pickup_cells_max;
 566 float g_pickup_fuel;
 567 float g_pickup_fuel_jetpack;
 568 float g_pickup_fuel_max;
 569 float g_pickup_armorsmall;
 570 float g_pickup_armorsmall_max;
 571 float g_pickup_armorsmall_anyway;
 572 float g_pickup_armormedium;
 573 float g_pickup_armormedium_max;
 574 float g_pickup_armormedium_anyway;
 575 float g_pickup_armorbig;
 576 float g_pickup_armorbig_max;
 577 float g_pickup_armorbig_anyway;
 578 float g_pickup_armorlarge;
 579 float g_pickup_armorlarge_max;
 580 float g_pickup_armorlarge_anyway;
 581 float g_pickup_healthsmall;
 582 float g_pickup_healthsmall_max;
 583 float g_pickup_healthsmall_anyway;
 584 float g_pickup_healthmedium;
 585 float g_pickup_healthmedium_max;
 586 float g_pickup_healthmedium_anyway;
 587 float g_pickup_healthlarge;
 588 float g_pickup_healthlarge_max;
 589 float g_pickup_healthlarge_anyway;
 590 float g_pickup_healthmega;
 591 float g_pickup_healthmega_max;
 592 float g_pickup_healthmega_anyway;
 593 float g_pickup_ammo_anyway;
 594 float g_pickup_weapons_anyway;
 595 float g_weaponarena;
 596 WepSet g_weaponarena_weapons;
 597 float g_weaponarena_random;
 598 float g_weaponarena_random_with_laser;
 599 string g_weaponarena_list;
 600 float g_weaponspeedfactor;
 601 float g_weaponratefactor;
 602 float g_weapondamagefactor;
 603 float g_weaponforcefactor;
 604 float g_weaponspreadfactor;
 605
 606 WepSet start_weapons;
 607 WepSet start_weapons_default;
 608 WepSet start_weapons_defaultmask;
 609 float start_items;
 610 float start_ammo_shells;
 611 float start_ammo_nails;
 612 float start_ammo_rockets;
 613 float start_ammo_cells;
 614 float start_ammo_fuel;
 615 float start_health;
 616 float start_armorvalue;
 617 WepSet warmup_start_weapons;
 618 WepSet warmup_start_weapons_default;
 619 WepSet warmup_start_weapons_defaultmask;
 620 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 621 float warmup_start_ammo_shells;
 622 float warmup_start_ammo_nails;
 623 float warmup_start_ammo_rockets;
 624 float warmup_start_ammo_cells;
 625 float warmup_start_ammo_fuel;
 626 float warmup_start_health;
 627 float warmup_start_armorvalue;
 628 float g_weapon_stay;
 629
 630 entity get_weaponinfo(float w);
 631
 632 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 633 {
 634         var float i = weaponinfo.weapon;
 635         var float d = 0;
 636
 637         if (!i)
 638                 return 0;
 639
 640         if (g_lms || g_ca || allguns)
 641         {
 642                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 643                         d = TRUE;
 644                 else
 645                         d = FALSE;
 646         }
 647         else if (g_cts)
 648                 d = (i == WEP_SHOTGUN);
 649         else if (g_nexball)
 650                 d = 0; // weapon is set a few lines later
 651         else
 652                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 653
 654         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 655                 d |= (i == WEP_HOOK);
 656         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 657                 d = 0;
 658
 659         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 660
 661         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 662
 663         // bit order in t:
 664         // 1: want or not
 665         // 2: is default?
 666         // 4: is set by default?
 667         if(t < 0)
 668                 t = 4 | (3 * d);
 669         else
 670                 t |= (2 * d);
 671
 672         return t;
 673 }
 674
 675 void readplayerstartcvars()
 676 {
 677         entity e;
 678         float i, j, t;
 679         string s;
 680
 681         // initialize starting values for players
 682         start_weapons = '0 0 0';
 683         start_weapons_default = '0 0 0';
 684         start_weapons_defaultmask = '0 0 0';
 685         start_items = 0;
 686         start_ammo_shells = 0;
 687         start_ammo_nails = 0;
 688         start_ammo_rockets = 0;
 689         start_ammo_cells = 0;
 690         start_health = cvar("g_balance_health_start");
 691         start_armorvalue = cvar("g_balance_armor_start");
 692
 693         g_weaponarena = 0;
 694         g_weaponarena_weapons = '0 0 0';
 695
 696         s = cvar_string("g_weaponarena");
 697         if (s == "0" || s == "")
 698         {
 699                 if(g_ca)
 700                         s = "most";
 701         }
 702
 703         if (s == "0" || s == "")
 704         {
 705                 // no arena
 706         }
 707         else if (s == "off")
 708         {
 709                 // forcibly turn off weaponarena
 710         }
 711         else if (s == "all")
 712         {
 713                 g_weaponarena = 1;
 714                 g_weaponarena_list = "All Weapons";
 715                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 716                 {
 717                         e = get_weaponinfo(j);
 718                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 719                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 720                 }
 721         }
 722         else if (s == "most")
 723         {
 724                 g_weaponarena = 1;
 725                 g_weaponarena_list = "Most Weapons";
 726                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 727                 {
 728                         e = get_weaponinfo(j);
 729                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 730                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 731                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 732                 }
 733         }
 734         else if (s == "none")
 735         {
 736                 g_weaponarena = 1;
 737                 g_weaponarena_list = "No Weapons";
 738         }
 739         else
 740         {
 741                 g_weaponarena = 1;
 742                 t = tokenize_console(s);
 743                 g_weaponarena_list = "";
 744                 for (i = 0; i < t; ++i)
 745                 {
 746                         s = argv(i);
 747                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 748                         {
 749                                 e = get_weaponinfo(j);
 750                                 if (e.netname == s)
 751                                 {
 752                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 753                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 754                                         break;
 755                                 }
 756                         }
 757                         if (j > WEP_LAST)
 758                         {
 759                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 760                         }
 761                 }
 762                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 763         }
 764
 765         if(g_weaponarena)
 766                 g_weaponarena_random = cvar("g_weaponarena_random");
 767         else
 768                 g_weaponarena_random = 0;
 769         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 770
 771         if (g_weaponarena)
 772         {
 773                 g_weapon_stay = 0; // incompatible
 774                 start_weapons = g_weaponarena_weapons;
 775                 start_items |= IT_UNLIMITED_AMMO;
 776         }
 777         else
 778         {
 779                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 780                 {
 781                         e = get_weaponinfo(i);
 782                         float w = want_weapon("g_start_weapon_", e, FALSE);
 783                         if(w & 1)
 784                                 start_weapons |= WepSet_FromWeapon(i);
 785                         if(w & 2)
 786                                 start_weapons_default |= WepSet_FromWeapon(i);
 787                         if(w & 4)
 788                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 789                 }
 790         }
 791
 792         if(!cvar("g_use_ammunition"))
 793                 start_items |= IT_UNLIMITED_AMMO;
 794
 795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 796         {
 797                 start_ammo_rockets = 999;
 798                 start_ammo_shells = 999;
 799                 start_ammo_cells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_fuel = 999;
 802         }
 803         else
 804         {
 805                 start_ammo_shells = cvar("g_start_ammo_shells");
 806                 start_ammo_nails = cvar("g_start_ammo_nails");
 807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 808                 start_ammo_cells = cvar("g_start_ammo_cells");
 809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 810         }
 811
 812         if (warmup_stage)
 813         {
 814                 warmup_start_ammo_shells = start_ammo_shells;
 815                 warmup_start_ammo_nails = start_ammo_nails;
 816                 warmup_start_ammo_rockets = start_ammo_rockets;
 817                 warmup_start_ammo_cells = start_ammo_cells;
 818                 warmup_start_ammo_fuel = start_ammo_fuel;
 819                 warmup_start_health = start_health;
 820                 warmup_start_armorvalue = start_armorvalue;
 821                 warmup_start_weapons = start_weapons;
 822                 warmup_start_weapons_default = start_weapons_default;
 823                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 824
 825                 if (!g_weaponarena && !g_ca)
 826                 {
 827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 832                         warmup_start_health = cvar("g_warmup_start_health");
 833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 834                         warmup_start_weapons = '0 0 0';
 835                         warmup_start_weapons_default = '0 0 0';
 836                         warmup_start_weapons_defaultmask = '0 0 0';
 837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 838                         {
 839                                 e = get_weaponinfo(i);
 840                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
 841                                 if(w & 1)
 842                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 843                                 if(w & 2)
 844                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 845                                 if(w & 4)
 846                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 847                         }
 848                 }
 849         }
 850
 851         if (g_jetpack)
 852                 start_items |= IT_JETPACK;
 853
 854         MUTATOR_CALLHOOK(SetStartItems);
 855
 856         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 857         {
 858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 859                 start_items |= IT_FUEL_REGEN;
 860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862         }
 863
 864         WepSet precache_weapons = start_weapons;
 865         if (g_warmup_allguns != 1)
 866                 precache_weapons |= warmup_start_weapons;
 867         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 868         {
 869                 e = get_weaponinfo(i);
 870                 if(precache_weapons & WepSet_FromWeapon(i))
 871                         weapon_action(i, WR_PRECACHE);
 872         }
 873
 874         start_ammo_shells = max(0, start_ammo_shells);
 875         start_ammo_nails = max(0, start_ammo_nails);
 876         start_ammo_cells = max(0, start_ammo_cells);
 877         start_ammo_rockets = max(0, start_ammo_rockets);
 878         start_ammo_fuel = max(0, start_ammo_fuel);
 879
 880         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 881         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 882         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 883         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 884         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 885 }
 886
 887 float g_bugrigs;
 888 float g_bugrigs_planar_movement;
 889 float g_bugrigs_planar_movement_car_jumping;
 890 float g_bugrigs_reverse_spinning;
 891 float g_bugrigs_reverse_speeding;
 892 float g_bugrigs_reverse_stopping;
 893 float g_bugrigs_air_steering;
 894 float g_bugrigs_angle_smoothing;
 895 float g_bugrigs_friction_floor;
 896 float g_bugrigs_friction_brake;
 897 float g_bugrigs_friction_air;
 898 float g_bugrigs_accel;
 899 float g_bugrigs_speed_ref;
 900 float g_bugrigs_speed_pow;
 901 float g_bugrigs_steer;
 902
 903 float sv_autotaunt;
 904 float sv_taunt;
 905
 906 string GetGametype(); // g_world.qc
 907 void mutators_add(); // mutators.qc
 908 void readlevelcvars(void)
 909 {
 910         // load mutators
 911         mutators_add();
 912
 913         if(cvar("sv_allow_fullbright"))
 914                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 915
 916     g_bugrigs = cvar("g_bugrigs");
 917     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 918     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 919     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 920     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 921     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 922     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 923     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 924     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 925     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 926     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 927     g_bugrigs_accel = cvar("g_bugrigs_accel");
 928     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 929     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 930     g_bugrigs_steer = cvar("g_bugrigs_steer");
 931
 932         g_minstagib = cvar("g_minstagib");
 933
 934         sv_clones = cvar("sv_clones");
 935         sv_foginterval = cvar("sv_foginterval");
 936         g_cloaked = cvar("g_cloaked");
 937     if(g_cts)
 938         g_cloaked = 1; // always enable cloak in CTS
 939         g_footsteps = cvar("g_footsteps");
 940         g_grappling_hook = cvar("g_grappling_hook");
 941         g_jetpack = cvar("g_jetpack");
 942         sv_maxidle = cvar("sv_maxidle");
 943         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 944         sv_autotaunt = cvar("sv_autotaunt");
 945         sv_taunt = cvar("sv_taunt");
 946
 947         warmup_stage = cvar("g_warmup");
 948         g_warmup_limit = cvar("g_warmup_limit");
 949         g_warmup_allguns = cvar("g_warmup_allguns");
 950         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 951
 952         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 953                 warmup_stage = 0; // these modes cannot work together, sorry
 954
 955         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 956         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 957         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 958         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 959         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 960         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 961         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 962         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 963         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 964         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 965         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 966         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 967         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 968         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 969
 970         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 971         g_weaponratefactor = cvar("g_weaponratefactor");
 972         g_weapondamagefactor = cvar("g_weapondamagefactor");
 973         g_weaponforcefactor = cvar("g_weaponforcefactor");
 974         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 975
 976         g_pickup_shells = cvar("g_pickup_shells");
 977         g_pickup_shells_max = cvar("g_pickup_shells_max");
 978         g_pickup_nails = cvar("g_pickup_nails");
 979         g_pickup_nails_max = cvar("g_pickup_nails_max");
 980         g_pickup_rockets = cvar("g_pickup_rockets");
 981         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 982         g_pickup_cells = cvar("g_pickup_cells");
 983         g_pickup_cells_max = cvar("g_pickup_cells_max");
 984         g_pickup_fuel = cvar("g_pickup_fuel");
 985         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 986         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 987         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 988         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 989         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 990         g_pickup_armormedium = cvar("g_pickup_armormedium");
 991         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
 992         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
 993         g_pickup_armorbig = cvar("g_pickup_armorbig");
 994         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
 995         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
 996         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
 997         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
 998         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
 999         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1000         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1001         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1002         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1003         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1004         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1005         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1006         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1007         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1008         g_pickup_healthmega = cvar("g_pickup_healthmega");
1009         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1010         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1011
1012         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1013         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1014
1015     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1016     if(!g_weapon_stay)
1017         g_weapon_stay = cvar("g_weapon_stay");
1018
1019         if (!warmup_stage)
1020                 game_starttime = time + cvar("g_start_delay");
1021
1022         readplayerstartcvars();
1023 }
1024
1025 //#NO AUTOCVARS END
1026
1027 // Sound functions
1028 string precache_sound (string s) = #19;
1029 float precache_sound_index (string s) = #19;
1030
1031 #define SND_VOLUME      1
1032 #define SND_ATTENUATION 2
1033 #define SND_LARGEENTITY 8
1034 #define SND_LARGESOUND  16
1035
1036 float sound_allowed(float dest, entity e)
1037 {
1038     // sounds from world may always pass
1039     for (;;)
1040     {
1041         if (e.classname == "body")
1042             e = e.enemy;
1043         else if (e.realowner && e.realowner != e)
1044             e = e.realowner;
1045         else if (e.owner && e.owner != e)
1046             e = e.owner;
1047         else
1048             break;
1049     }
1050     // sounds to self may always pass
1051     if (dest == MSG_ONE)
1052         if (e == msg_entity)
1053             return TRUE;
1054     // sounds by players can be removed
1055     if (autocvar_bot_sound_monopoly)
1056         if (IS_REAL_CLIENT(e))
1057             return FALSE;
1058     // anything else may pass
1059     return TRUE;
1060 }
1061
1062 #ifdef COMPAT_XON010_CHANNELS
1063 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1064 void sound(entity e, float chan, string samp, float vol, float atten)
1065 {
1066     if (!sound_allowed(MSG_BROADCAST, e))
1067         return;
1068     builtin_sound(e, chan, samp, vol, atten);
1069 }
1070 #else
1071 #undef sound
1072 void sound(entity e, float chan, string samp, float vol, float atten)
1073 {
1074     if (!sound_allowed(MSG_BROADCAST, e))
1075         return;
1076     sound7(e, chan, samp, vol, atten, 0, 0);
1077 }
1078 #endif
1079
1080 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1081 {
1082     float entno, idx;
1083
1084     if (!sound_allowed(dest, e))
1085         return;
1086
1087     entno = num_for_edict(e);
1088     idx = precache_sound_index(samp);
1089
1090     float sflags;
1091     sflags = 0;
1092
1093     atten = floor(atten * 64);
1094     vol = floor(vol * 255);
1095
1096     if (vol != 255)
1097         sflags |= SND_VOLUME;
1098     if (atten != 64)
1099         sflags |= SND_ATTENUATION;
1100     if (entno >= 8192 || chan < 0 || chan > 7)
1101         sflags |= SND_LARGEENTITY;
1102     if (idx >= 256)
1103         sflags |= SND_LARGESOUND;
1104
1105     WriteByte(dest, SVC_SOUND);
1106     WriteByte(dest, sflags);
1107     if (sflags & SND_VOLUME)
1108         WriteByte(dest, vol);
1109     if (sflags & SND_ATTENUATION)
1110         WriteByte(dest, atten);
1111     if (sflags & SND_LARGEENTITY)
1112     {
1113         WriteShort(dest, entno);
1114         WriteByte(dest, chan);
1115     }
1116     else
1117     {
1118         WriteShort(dest, entno * 8 + chan);
1119     }
1120     if (sflags & SND_LARGESOUND)
1121         WriteShort(dest, idx);
1122     else
1123         WriteByte(dest, idx);
1124
1125     WriteCoord(dest, o_x);
1126     WriteCoord(dest, o_y);
1127     WriteCoord(dest, o_z);
1128 }
1129 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1130 {
1131     vector o;
1132
1133     if (!sound_allowed(dest, e))
1134         return;
1135
1136     o = e.origin + 0.5 * (e.mins + e.maxs);
1137     soundtoat(dest, e, o, chan, samp, vol, atten);
1138 }
1139 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1140 {
1141     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1142 }
1143 void stopsoundto(float dest, entity e, float chan)
1144 {
1145     float entno;
1146
1147     if (!sound_allowed(dest, e))
1148         return;
1149
1150     entno = num_for_edict(e);
1151
1152     if (entno >= 8192 || chan < 0 || chan > 7)
1153     {
1154         float idx, sflags;
1155         idx = precache_sound_index("misc/null.wav");
1156         sflags = SND_LARGEENTITY;
1157         if (idx >= 256)
1158             sflags |= SND_LARGESOUND;
1159         WriteByte(dest, SVC_SOUND);
1160         WriteByte(dest, sflags);
1161         WriteShort(dest, entno);
1162         WriteByte(dest, chan);
1163         if (sflags & SND_LARGESOUND)
1164             WriteShort(dest, idx);
1165         else
1166             WriteByte(dest, idx);
1167         WriteCoord(dest, e.origin_x);
1168         WriteCoord(dest, e.origin_y);
1169         WriteCoord(dest, e.origin_z);
1170     }
1171     else
1172     {
1173         WriteByte(dest, SVC_STOPSOUND);
1174         WriteShort(dest, entno * 8 + chan);
1175     }
1176 }
1177 void stopsound(entity e, float chan)
1178 {
1179     if (!sound_allowed(MSG_BROADCAST, e))
1180         return;
1181
1182     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1183     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1184 }
1185
1186 void play2(entity e, string filename)
1187 {
1188     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1189     msg_entity = e;
1190     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1191 }
1192
1193 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1194 .float spamtime;
1195 float spamsound(entity e, float chan, string samp, float vol, float atten)
1196 {
1197     if (!sound_allowed(MSG_BROADCAST, e))
1198         return FALSE;
1199
1200     if (time > e.spamtime)
1201     {
1202         e.spamtime = time;
1203         sound(e, chan, samp, vol, atten);
1204         return TRUE;
1205     }
1206     return FALSE;
1207 }
1208
1209 void play2team(float t, string filename)
1210 {
1211     entity head;
1212
1213     if (autocvar_bot_sound_monopoly)
1214         return;
1215
1216     FOR_EACH_REALPLAYER(head)
1217     {
1218         if (head.team == t)
1219             play2(head, filename);
1220     }
1221 }
1222
1223 void play2all(string samp)
1224 {
1225     if (autocvar_bot_sound_monopoly)
1226         return;
1227
1228     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1229 }
1230
1231 void PrecachePlayerSounds(string f);
1232 void precache_playermodel(string m)
1233 {
1234         float globhandle, i, n;
1235         string f;
1236
1237         if(substring(m, -9,5) == "_lod1")
1238                 return;
1239         if(substring(m, -9,5) == "_lod2")
1240                 return;
1241         precache_model(m);
1242         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1243         if(fexists(f))
1244                 precache_model(f);
1245         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1246         if(fexists(f))
1247                 precache_model(f);
1248
1249         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1250         if (globhandle < 0)
1251                 return;
1252         n = search_getsize(globhandle);
1253         for (i = 0; i < n; ++i)
1254         {
1255                 //print(search_getfilename(globhandle, i), "\n");
1256                 f = search_getfilename(globhandle, i);
1257                 PrecachePlayerSounds(f);
1258         }
1259         search_end(globhandle);
1260 }
1261 void precache_all_playermodels(string pattern)
1262 {
1263         float globhandle, i, n;
1264         string f;
1265
1266         globhandle = search_begin(pattern, TRUE, FALSE);
1267         if (globhandle < 0)
1268                 return;
1269         n = search_getsize(globhandle);
1270         for (i = 0; i < n; ++i)
1271         {
1272                 //print(search_getfilename(globhandle, i), "\n");
1273                 f = search_getfilename(globhandle, i);
1274                 precache_playermodel(f);
1275         }
1276         search_end(globhandle);
1277 }
1278
1279 void precache()
1280 {
1281     // gamemode related things
1282     precache_model ("models/misc/chatbubble.spr");
1283
1284 #ifdef TTURRETS_ENABLED
1285     if (autocvar_g_turrets)
1286         turrets_precash();
1287 #endif
1288
1289     // Precache all player models if desired
1290     if (autocvar_sv_precacheplayermodels)
1291     {
1292         PrecachePlayerSounds("sound/player/default.sounds");
1293         precache_all_playermodels("models/player/*.zym");
1294         precache_all_playermodels("models/player/*.dpm");
1295         precache_all_playermodels("models/player/*.md3");
1296         precache_all_playermodels("models/player/*.psk");
1297         precache_all_playermodels("models/player/*.iqm");
1298     }
1299
1300     if (autocvar_sv_defaultcharacter)
1301     {
1302         string s;
1303         s = autocvar_sv_defaultplayermodel_red;
1304         if (s != "")
1305             precache_playermodel(s);
1306         s = autocvar_sv_defaultplayermodel_blue;
1307         if (s != "")
1308             precache_playermodel(s);
1309         s = autocvar_sv_defaultplayermodel_yellow;
1310         if (s != "")
1311             precache_playermodel(s);
1312         s = autocvar_sv_defaultplayermodel_pink;
1313         if (s != "")
1314             precache_playermodel(s);
1315         s = autocvar_sv_defaultplayermodel;
1316         if (s != "")
1317             precache_playermodel(s);
1318     }
1319
1320     if (g_footsteps)
1321     {
1322         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1323         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1324     }
1325
1326     // gore and miscellaneous sounds
1327     //precache_sound ("misc/h2ohit.wav");
1328     precache_model ("models/hook.md3");
1329     precache_sound ("misc/armorimpact.wav");
1330     precache_sound ("misc/bodyimpact1.wav");
1331     precache_sound ("misc/bodyimpact2.wav");
1332     precache_sound ("misc/gib.wav");
1333     precache_sound ("misc/gib_splat01.wav");
1334     precache_sound ("misc/gib_splat02.wav");
1335     precache_sound ("misc/gib_splat03.wav");
1336     precache_sound ("misc/gib_splat04.wav");
1337     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1338     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1339     precache_sound ("misc/null.wav");
1340     precache_sound ("misc/spawn.wav");
1341     precache_sound ("misc/talk.wav");
1342     precache_sound ("misc/teleport.wav");
1343     precache_sound ("misc/poweroff.wav");
1344     precache_sound ("player/lava.wav");
1345     precache_sound ("player/slime.wav");
1346
1347     precache_model ("models/sprites/0.spr32");
1348     precache_model ("models/sprites/1.spr32");
1349     precache_model ("models/sprites/2.spr32");
1350     precache_model ("models/sprites/3.spr32");
1351     precache_model ("models/sprites/4.spr32");
1352     precache_model ("models/sprites/5.spr32");
1353     precache_model ("models/sprites/6.spr32");
1354     precache_model ("models/sprites/7.spr32");
1355     precache_model ("models/sprites/8.spr32");
1356     precache_model ("models/sprites/9.spr32");
1357     precache_model ("models/sprites/10.spr32");
1358
1359     // common weapon precaches
1360         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1361     precache_sound ("weapons/weapon_switch.wav");
1362     precache_sound ("weapons/weaponpickup.wav");
1363     precache_sound ("weapons/unavailable.wav");
1364     precache_sound ("weapons/dryfire.wav");
1365     if (g_grappling_hook)
1366     {
1367         precache_sound ("weapons/hook_fire.wav"); // hook
1368         precache_sound ("weapons/hook_impact.wav"); // hook
1369     }
1370
1371     if(autocvar_sv_precacheweapons)
1372     {
1373         //precache weapon models/sounds
1374         float wep;
1375         wep = WEP_FIRST;
1376         while (wep <= WEP_LAST)
1377         {
1378             weapon_action(wep, WR_PRECACHE);
1379             wep = wep + 1;
1380         }
1381     }
1382
1383     precache_model("models/elaser.mdl");
1384     precache_model("models/laser.mdl");
1385     precache_model("models/ebomb.mdl");
1386
1387 #if 0
1388     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1389
1390     if (!self.noise && self.music) // quake 3 uses the music field
1391         self.noise = self.music;
1392
1393     // plays music for the level if there is any
1394     if (self.noise)
1395     {
1396         precache_sound (self.noise);
1397         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1398     }
1399 #endif
1400
1401 #include "precache-for-csqc.inc"
1402 }
1403
1404 // WARNING: this kills the trace globals
1405 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1406 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1407
1408 #define INITPRIO_FIRST              0
1409 #define INITPRIO_GAMETYPE           0
1410 #define INITPRIO_GAMETYPE_FALLBACK  1
1411 #define INITPRIO_FINDTARGET        10
1412 #define INITPRIO_DROPTOFLOOR       20
1413 #define INITPRIO_SETLOCATION       90
1414 #define INITPRIO_LINKDOORS         91
1415 #define INITPRIO_LAST              99
1416
1417 .void(void) initialize_entity;
1418 .float initialize_entity_order;
1419 .entity initialize_entity_next;
1420 entity initialize_entity_first;
1421
1422 void make_safe_for_remove(entity e)
1423 {
1424     if (e.initialize_entity)
1425     {
1426         entity ent, prev = world;
1427         for (ent = initialize_entity_first; ent; )
1428         {
1429             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1430             {
1431                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1432                 // skip it in linked list
1433                 if (prev)
1434                 {
1435                     prev.initialize_entity_next = ent.initialize_entity_next;
1436                     ent = prev.initialize_entity_next;
1437                 }
1438                 else
1439                 {
1440                     initialize_entity_first = ent.initialize_entity_next;
1441                     ent = initialize_entity_first;
1442                 }
1443             }
1444             else
1445             {
1446                 prev = ent;
1447                 ent = ent.initialize_entity_next;
1448             }
1449         }
1450     }
1451 }
1452
1453 void objerror(string s)
1454 {
1455     make_safe_for_remove(self);
1456     builtin_objerror(s);
1457 }
1458
1459 .float remove_except_protected_forbidden;
1460 void remove_except_protected(entity e)
1461 {
1462         if(e.remove_except_protected_forbidden)
1463                 error("not allowed to remove this at this point");
1464         builtin_remove(e);
1465 }
1466
1467 void remove_unsafely(entity e)
1468 {
1469     if(e.classname == "spike")
1470         error("Removing spikes is forbidden (crylink bug), please report");
1471     builtin_remove(e);
1472 }
1473
1474 void remove_safely(entity e)
1475 {
1476     make_safe_for_remove(e);
1477     builtin_remove(e);
1478 }
1479
1480 void InitializeEntity(entity e, void(void) func, float order)
1481 {
1482     entity prev, cur;
1483
1484     if (!e || e.initialize_entity)
1485     {
1486         // make a proxy initializer entity
1487         entity e_old;
1488         e_old = e;
1489         e = spawn();
1490         e.classname = "initialize_entity";
1491         e.enemy = e_old;
1492     }
1493
1494     e.initialize_entity = func;
1495     e.initialize_entity_order = order;
1496
1497     cur = initialize_entity_first;
1498     prev = world;
1499     for (;;)
1500     {
1501         if (!cur || cur.initialize_entity_order > order)
1502         {
1503             // insert between prev and cur
1504             if (prev)
1505                 prev.initialize_entity_next = e;
1506             else
1507                 initialize_entity_first = e;
1508             e.initialize_entity_next = cur;
1509             return;
1510         }
1511         prev = cur;
1512         cur = cur.initialize_entity_next;
1513     }
1514 }
1515 void InitializeEntitiesRun()
1516 {
1517     entity startoflist;
1518     startoflist = initialize_entity_first;
1519     initialize_entity_first = world;
1520     remove = remove_except_protected;
1521     for (self = startoflist; self; self = self.initialize_entity_next)
1522     {
1523         self.remove_except_protected_forbidden = 1;
1524     }
1525     for (self = startoflist; self; )
1526     {
1527         entity e;
1528         var void(void) func;
1529         e = self.initialize_entity_next;
1530         func = self.initialize_entity;
1531         self.initialize_entity_order = 0;
1532         self.initialize_entity = func_null;
1533         self.initialize_entity_next = world;
1534         self.remove_except_protected_forbidden = 0;
1535         if (self.classname == "initialize_entity")
1536         {
1537             entity e_old;
1538             e_old = self.enemy;
1539             builtin_remove(self);
1540             self = e_old;
1541         }
1542         //dprint("Delayed initialization: ", self.classname, "\n");
1543         if(func)
1544             func();
1545         else
1546         {
1547             eprint(self);
1548             backtrace(strcat("Null function in: ", self.classname, "\n"));
1549         }
1550         self = e;
1551     }
1552     remove = remove_unsafely;
1553 }
1554
1555 .float uncustomizeentityforclient_set;
1556 .void(void) uncustomizeentityforclient;
1557 void UncustomizeEntitiesRun()
1558 {
1559     entity oldself;
1560     oldself = self;
1561     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1562         self.uncustomizeentityforclient();
1563     self = oldself;
1564 }
1565 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1566 {
1567     e.customizeentityforclient = customizer;
1568     e.uncustomizeentityforclient = uncustomizer;
1569     e.uncustomizeentityforclient_set = !!uncustomizer;
1570 }
1571
1572 .float nottargeted;
1573 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1574
1575 void() SUB_Remove;
1576 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1577 {
1578     vector mi, ma;
1579
1580     if (e.classname == "")
1581         e.classname = "net_linked";
1582
1583     if (e.model == "" || self.modelindex == 0)
1584     {
1585         mi = e.mins;
1586         ma = e.maxs;
1587         setmodel(e, "null");
1588         setsize(e, mi, ma);
1589     }
1590
1591     e.SendEntity = sendfunc;
1592     e.SendFlags = 0xFFFFFF;
1593
1594     if (!docull)
1595         e.effects |= EF_NODEPTHTEST;
1596
1597     if (dt)
1598     {
1599         e.nextthink = time + dt;
1600         e.think = SUB_Remove;
1601     }
1602 }
1603
1604 void adaptor_think2touch()
1605 {
1606     entity o;
1607     o = other;
1608     other = world;
1609     self.touch();
1610     other = o;
1611 }
1612
1613 void adaptor_think2use()
1614 {
1615     entity o, a;
1616     o = other;
1617     a = activator;
1618     activator = world;
1619     other = world;
1620     self.use();
1621     other = o;
1622     activator = a;
1623 }
1624
1625 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1626 {
1627         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1628                 self.projectiledeathtype |= HITTYPE_SPLASH;
1629         adaptor_think2use();
1630 }
1631
1632 // deferred dropping
1633 void DropToFloor_Handler()
1634 {
1635     builtin_droptofloor();
1636     self.dropped_origin = self.origin;
1637 }
1638
1639 void droptofloor()
1640 {
1641     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1642 }
1643
1644
1645
1646 float trace_hits_box_a0, trace_hits_box_a1;
1647
1648 float trace_hits_box_1d(float end, float thmi, float thma)
1649 {
1650     if (end == 0)
1651     {
1652         // just check if x is in range
1653         if (0 < thmi)
1654             return FALSE;
1655         if (0 > thma)
1656             return FALSE;
1657     }
1658     else
1659     {
1660         // do the trace with respect to x
1661         // 0 -> end has to stay in thmi -> thma
1662         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1663         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1664         if (trace_hits_box_a0 > trace_hits_box_a1)
1665             return FALSE;
1666     }
1667     return TRUE;
1668 }
1669
1670 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1671 {
1672     end -= start;
1673     thmi -= start;
1674     thma -= start;
1675     // now it is a trace from 0 to end
1676
1677     trace_hits_box_a0 = 0;
1678     trace_hits_box_a1 = 1;
1679
1680     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1681         return FALSE;
1682     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1683         return FALSE;
1684     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1685         return FALSE;
1686
1687     return TRUE;
1688 }
1689
1690 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1691 {
1692     return trace_hits_box(start, end, thmi - ma, thma - mi);
1693 }
1694
1695 float SUB_NoImpactCheck()
1696 {
1697         // zero hitcontents = this is not the real impact, but either the
1698         // mirror-impact of something hitting the projectile instead of the
1699         // projectile hitting the something, or a touchareagrid one. Neither of
1700         // these stop the projectile from moving, so...
1701         if(trace_dphitcontents == 0)
1702         {
1703                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1704                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1705                 checkclient();
1706         }
1707     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1708         return 1;
1709     if (other == world && self.size != '0 0 0')
1710     {
1711         vector tic;
1712         tic = self.velocity * sys_frametime;
1713         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1714         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1715         if (trace_fraction >= 1)
1716         {
1717             dprint("Odd... did not hit...?\n");
1718         }
1719         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1720         {
1721             dprint("Detected and prevented the sky-grapple bug.\n");
1722             return 1;
1723         }
1724     }
1725
1726     return 0;
1727 }
1728
1729 #define SUB_OwnerCheck() (other && (other == self.owner))
1730
1731 void RemoveGrapplingHook(entity pl);
1732 void W_Crylink_Dequeue(entity e);
1733 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1734 {
1735         if(SUB_OwnerCheck())
1736                 return TRUE;
1737         if(SUB_NoImpactCheck())
1738         {
1739                 if(self.classname == "grapplinghook")
1740                         RemoveGrapplingHook(self.realowner);
1741                 else if(self.classname == "spike")
1742                 {
1743                         W_Crylink_Dequeue(self);
1744                         remove(self);
1745                 }
1746                 else
1747                         remove(self);
1748                 return TRUE;
1749         }
1750         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1751                 UpdateCSQCProjectile(self);
1752         return FALSE;
1753 }
1754 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1755
1756 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1757 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1758
1759 void URI_Get_Callback(float id, float status, string data)
1760 {
1761         if(url_URI_Get_Callback(id, status, data))
1762         {
1763                 // handled
1764         }
1765         else if (id == URI_GET_DISCARD)
1766         {
1767                 // discard
1768         }
1769         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1770         {
1771                 // sv_cmd curl
1772                 Curl_URI_Get_Callback(id, status, data);
1773         }
1774         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1775         {
1776                 // online ban list
1777                 OnlineBanList_URI_Get_Callback(id, status, data);
1778         }
1779         else
1780         {
1781                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1782         }
1783 }
1784
1785 string uid2name(string myuid) {
1786         string s;
1787         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1788
1789         // FIXME remove this later after 0.6 release
1790         // convert old style broken records to correct style
1791         if(s == "")
1792         {
1793                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1794                 if(s != "")
1795                 {
1796                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1797                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1798                 }
1799         }
1800
1801         if(s == "")
1802                 s = "^1Unregistered Player";
1803         return s;
1804 }
1805
1806 float race_readTime(string map, float pos)
1807 {
1808         string rr;
1809         if(g_cts)
1810                 rr = CTS_RECORD;
1811         else
1812                 rr = RACE_RECORD;
1813
1814         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1815 }
1816
1817 string race_readUID(string map, float pos)
1818 {
1819         string rr;
1820         if(g_cts)
1821                 rr = CTS_RECORD;
1822         else
1823                 rr = RACE_RECORD;
1824
1825         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1826 }
1827
1828 float race_readPos(string map, float t) {
1829         float i;
1830         for (i = 1; i <= RANKINGS_CNT; ++i)
1831                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1832                         return i;
1833
1834         return 0; // pos is zero if unranked
1835 }
1836
1837 void race_writeTime(string map, float t, string myuid)
1838 {
1839         string rr;
1840         if(g_cts)
1841                 rr = CTS_RECORD;
1842         else
1843                 rr = RACE_RECORD;
1844
1845         float newpos;
1846         newpos = race_readPos(map, t);
1847
1848         float i, prevpos = 0;
1849         for(i = 1; i <= RANKINGS_CNT; ++i)
1850         {
1851                 if(race_readUID(map, i) == myuid)
1852                         prevpos = i;
1853         }
1854         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1855                 for (i = prevpos; i > newpos; --i) {
1856                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1857                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1858                 }
1859         } else { // player has no ranked record yet
1860                 for (i = RANKINGS_CNT; i > newpos; --i) {
1861                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1862                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1863                 }
1864         }
1865
1866         // store new time itself
1867         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1868         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1869 }
1870
1871 string race_readName(string map, float pos)
1872 {
1873         string rr;
1874         if(g_cts)
1875                 rr = CTS_RECORD;
1876         else
1877                 rr = RACE_RECORD;
1878
1879         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1880 }
1881
1882 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1883 {
1884     float m, i;
1885     vector start, org, delta, end, enddown, mstart;
1886     entity sp;
1887
1888     m = e.dphitcontentsmask;
1889     e.dphitcontentsmask = goodcontents | badcontents;
1890
1891     org = world.mins;
1892     delta = world.maxs - world.mins;
1893
1894     start = end = org;
1895
1896     for (i = 0; i < attempts; ++i)
1897     {
1898         start_x = org_x + random() * delta_x;
1899         start_y = org_y + random() * delta_y;
1900         start_z = org_z + random() * delta_z;
1901
1902         // rule 1: start inside world bounds, and outside
1903         // solid, and don't start from somewhere where you can
1904         // fall down to evil
1905         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1906         if (trace_fraction >= 1)
1907             continue;
1908         if (trace_startsolid)
1909             continue;
1910         if (trace_dphitcontents & badcontents)
1911             continue;
1912         if (trace_dphitq3surfaceflags & badsurfaceflags)
1913             continue;
1914
1915         // rule 2: if we are too high, lower the point
1916         if (trace_fraction * delta_z > maxaboveground)
1917             start = trace_endpos + '0 0 1' * maxaboveground;
1918         enddown = trace_endpos;
1919
1920         // rule 3: make sure we aren't outside the map. This only works
1921         // for somewhat well formed maps. A good rule of thumb is that
1922         // the map should have a convex outside hull.
1923         // these can be traceLINES as we already verified the starting box
1924         mstart = start + 0.5 * (e.mins + e.maxs);
1925         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1926         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1927             continue;
1928         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1929         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1930             continue;
1931         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1932         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1933             continue;
1934         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1935         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1936             continue;
1937         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1938         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1939             continue;
1940
1941         // rule 4: we must "see" some spawnpoint or item
1942         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1943                 if(checkpvs(mstart, sp))
1944                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1945                                 break;
1946         if(!sp)
1947         {
1948                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1949                         if(checkpvs(mstart, sp))
1950                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1951                                         break;
1952                 if(!sp)
1953                         continue;
1954         }
1955
1956         // find a random vector to "look at"
1957         end_x = org_x + random() * delta_x;
1958         end_y = org_y + random() * delta_y;
1959         end_z = org_z + random() * delta_z;
1960         end = start + normalize(end - start) * vlen(delta);
1961
1962         // rule 4: start TO end must not be too short
1963         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1964         if (trace_startsolid)
1965             continue;
1966         if (trace_fraction < minviewdistance / vlen(delta))
1967             continue;
1968
1969         // rule 5: don't want to look at sky
1970         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1971             continue;
1972
1973         // rule 6: we must not end up in trigger_hurt
1974         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1975             continue;
1976
1977         break;
1978     }
1979
1980     e.dphitcontentsmask = m;
1981
1982     if (i < attempts)
1983     {
1984         setorigin(e, start);
1985         e.angles = vectoangles(end - start);
1986         dprint("Needed ", ftos(i + 1), " attempts\n");
1987         return TRUE;
1988     }
1989     else
1990         return FALSE;
1991 }
1992
1993 void write_recordmarker(entity pl, float tstart, float dt)
1994 {
1995     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1996
1997     // also write a marker into demo files for demotc-race-record-extractor to find
1998     stuffcmd(pl,
1999              strcat(
2000                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2001                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2002 }
2003
2004 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2005 {
2006         switch(algn)
2007         {
2008                 default:
2009                 case 3: // right
2010                         break;
2011
2012                 case 4: // left
2013                         vecs_y = -vecs_y;
2014                         break;
2015
2016                 case 1:
2017                         if(allowcenter) // 2: allow center handedness
2018                         {
2019                                 // center
2020                                 vecs_y = 0;
2021                                 vecs_z -= 2;
2022                         }
2023                         else
2024                         {
2025                                 // right
2026                         }
2027                         break;
2028
2029                 case 2:
2030                         if(allowcenter) // 2: allow center handedness
2031                         {
2032                                 // center
2033                                 vecs_y = 0;
2034                                 vecs_z -= 2;
2035                         }
2036                         else
2037                         {
2038                                 // left
2039                                 vecs_y = -vecs_y;
2040                         }
2041                         break;
2042         }
2043         return vecs;
2044 }
2045
2046 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2047 {
2048         string s;
2049         vector v;
2050
2051         if (autocvar_g_shootfromeye)
2052         {
2053                 if (visual)
2054                 {
2055                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2056                         else { vecs_y = 0; vecs_z -= 2; }
2057                 }
2058                 else
2059                 {
2060                         vecs_y = 0;
2061                         vecs_z = 0;
2062                 }
2063         }
2064         else if (autocvar_g_shootfromcenter)
2065         {
2066                 vecs_y = 0;
2067                 vecs_z -= 2;
2068         }
2069         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2070         {
2071                 v = stov(s);
2072                 if (y_is_right)
2073                         v_y = -v_y;
2074                 if (v_x != 0)
2075                         vecs_x = v_x;
2076                 vecs_y = v_y;
2077                 vecs_z = v_z;
2078         }
2079         else if (autocvar_g_shootfromclient)
2080         {
2081                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2082         }
2083         return vecs;
2084 }
2085
2086 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2087 {
2088         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2089 }
2090
2091
2092 void attach_sameorigin(entity e, entity to, string tag)
2093 {
2094     vector org, t_forward, t_left, t_up, e_forward, e_up;
2095     float tagscale;
2096
2097     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2098     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2099     t_forward = v_forward * tagscale;
2100     t_left = v_right * -tagscale;
2101     t_up = v_up * tagscale;
2102
2103     e.origin_x = org * t_forward;
2104     e.origin_y = org * t_left;
2105     e.origin_z = org * t_up;
2106
2107     // current forward and up directions
2108     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2109                 e.angles = AnglesTransform_FromVAngles(e.angles);
2110         else
2111                 e.angles = AnglesTransform_FromAngles(e.angles);
2112     fixedmakevectors(e.angles);
2113
2114     // untransform forward, up!
2115     e_forward_x = v_forward * t_forward;
2116     e_forward_y = v_forward * t_left;
2117     e_forward_z = v_forward * t_up;
2118     e_up_x = v_up * t_forward;
2119     e_up_y = v_up * t_left;
2120     e_up_z = v_up * t_up;
2121
2122     e.angles = fixedvectoangles2(e_forward, e_up);
2123     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2124                 e.angles = AnglesTransform_ToVAngles(e.angles);
2125         else
2126                 e.angles = AnglesTransform_ToAngles(e.angles);
2127
2128     setattachment(e, to, tag);
2129     setorigin(e, e.origin);
2130 }
2131
2132 void detach_sameorigin(entity e)
2133 {
2134     vector org;
2135     org = gettaginfo(e, 0);
2136     e.angles = fixedvectoangles2(v_forward, v_up);
2137     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2138                 e.angles = AnglesTransform_ToVAngles(e.angles);
2139         else
2140                 e.angles = AnglesTransform_ToAngles(e.angles);
2141     setorigin(e, org);
2142     setattachment(e, world, "");
2143     setorigin(e, e.origin);
2144 }
2145
2146 void follow_sameorigin(entity e, entity to)
2147 {
2148     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2149     e.aiment = to; // make the hole follow bmodel
2150     e.punchangle = to.angles; // the original angles of bmodel
2151     e.view_ofs = e.origin - to.origin; // relative origin
2152     e.v_angle = e.angles - to.angles; // relative angles
2153 }
2154
2155 void unfollow_sameorigin(entity e)
2156 {
2157     e.movetype = MOVETYPE_NONE;
2158 }
2159
2160 entity gettaginfo_relative_ent;
2161 vector gettaginfo_relative(entity e, float tag)
2162 {
2163     if (!gettaginfo_relative_ent)
2164     {
2165         gettaginfo_relative_ent = spawn();
2166         gettaginfo_relative_ent.effects = EF_NODRAW;
2167     }
2168     gettaginfo_relative_ent.model = e.model;
2169     gettaginfo_relative_ent.modelindex = e.modelindex;
2170     gettaginfo_relative_ent.frame = e.frame;
2171     return gettaginfo(gettaginfo_relative_ent, tag);
2172 }
2173
2174 .float scale2;
2175
2176 float modeleffect_SendEntity(entity to, float sf)
2177 {
2178         float f;
2179         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2180
2181         f = 0;
2182         if(self.velocity != '0 0 0')
2183                 f |= 1;
2184         if(self.angles != '0 0 0')
2185                 f |= 2;
2186         if(self.avelocity != '0 0 0')
2187                 f |= 4;
2188
2189         WriteByte(MSG_ENTITY, f);
2190         WriteShort(MSG_ENTITY, self.modelindex);
2191         WriteByte(MSG_ENTITY, self.skin);
2192         WriteByte(MSG_ENTITY, self.frame);
2193         WriteCoord(MSG_ENTITY, self.origin_x);
2194         WriteCoord(MSG_ENTITY, self.origin_y);
2195         WriteCoord(MSG_ENTITY, self.origin_z);
2196         if(f & 1)
2197         {
2198                 WriteCoord(MSG_ENTITY, self.velocity_x);
2199                 WriteCoord(MSG_ENTITY, self.velocity_y);
2200                 WriteCoord(MSG_ENTITY, self.velocity_z);
2201         }
2202         if(f & 2)
2203         {
2204                 WriteCoord(MSG_ENTITY, self.angles_x);
2205                 WriteCoord(MSG_ENTITY, self.angles_y);
2206                 WriteCoord(MSG_ENTITY, self.angles_z);
2207         }
2208         if(f & 4)
2209         {
2210                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2211                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2212                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2213         }
2214         WriteShort(MSG_ENTITY, self.scale * 256.0);
2215         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2216         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2217         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2218         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2219
2220         return TRUE;
2221 }
2222
2223 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2224 {
2225         entity e;
2226         float sz;
2227         e = spawn();
2228         e.classname = "modeleffect";
2229         setmodel(e, m);
2230         e.frame = f;
2231         setorigin(e, o);
2232         e.velocity = v;
2233         e.angles = ang;
2234         e.avelocity = angv;
2235         e.alpha = a;
2236         e.teleport_time = t1;
2237         e.fade_time = t2;
2238         e.skin = s;
2239         if(s0 >= 0)
2240                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2241         else
2242                 e.scale = -s0;
2243         if(s2 >= 0)
2244                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2245         else
2246                 e.scale2 = -s2;
2247         sz = max(e.scale, e.scale2);
2248         setsize(e, e.mins * sz, e.maxs * sz);
2249         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2250 }
2251
2252 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2253 {
2254         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2255 }
2256
2257 float randombit(float bits)
2258 {
2259         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2260                 return bits;
2261
2262         float n, f, b, r;
2263
2264         r = random();
2265         b = 0;
2266         n = 0;
2267
2268         for(f = 1; f <= bits; f *= 2)
2269         {
2270                 if(bits & f)
2271                 {
2272                         ++n;
2273                         r *= n;
2274                         if(r <= 1)
2275                                 b = f;
2276                         else
2277                                 r = (r - 1) / (n - 1);
2278                 }
2279         }
2280
2281         return b;
2282 }
2283
2284 float randombits(float bits, float k, float error_return)
2285 {
2286         float r;
2287         r = 0;
2288         while(k > 0 && bits != r)
2289         {
2290                 r += randombit(bits - r);
2291                 --k;
2292         }
2293         if(error_return)
2294                 if(k > 0)
2295                         return -1; // all
2296         return r;
2297 }
2298
2299 void randombit_test(float bits, float iter)
2300 {
2301         while(iter > 0)
2302         {
2303                 print(ftos(randombit(bits)), "\n");
2304                 --iter;
2305         }
2306 }
2307
2308 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2309 {
2310         if(halflifedist > 0)
2311                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2312         else if(halflifedist < 0)
2313                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2314         else
2315                 return 1;
2316 }
2317
2318
2319
2320
2321 #ifdef RELEASE
2322 #define cvar_string_normal builtin_cvar_string
2323 #define cvar_normal builtin_cvar
2324 #else
2325 string cvar_string_normal(string n)
2326 {
2327         if (!(cvar_type(n) & 1))
2328                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2329         return builtin_cvar_string(n);
2330 }
2331
2332 float cvar_normal(string n)
2333 {
2334         return stof(cvar_string_normal(n));
2335 }
2336 #endif
2337 #define cvar_set_normal builtin_cvar_set
2338
2339 void defer_think()
2340 {
2341     entity oself;
2342
2343     oself           = self;
2344     self            = self.owner;
2345     oself.think     = SUB_Remove;
2346     oself.nextthink = time;
2347
2348     oself.use();
2349 }
2350
2351 /*
2352     Execute func() after time + fdelay.
2353     self when func is executed = self when defer is called
2354 */
2355 void defer(float fdelay, void() func)
2356 {
2357     entity e;
2358
2359     e           = spawn();
2360     e.owner     = self;
2361     e.use       = func;
2362     e.think     = defer_think;
2363     e.nextthink = time + fdelay;
2364 }
2365
2366 .string aiment_classname;
2367 .float aiment_deadflag;
2368 void SetMovetypeFollow(entity ent, entity e)
2369 {
2370         // FIXME this may not be warpzone aware
2371         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2372         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2373         ent.aiment = e; // make the hole follow bmodel
2374         ent.punchangle = e.angles; // the original angles of bmodel
2375         ent.view_ofs = ent.origin - e.origin; // relative origin
2376         ent.v_angle = ent.angles - e.angles; // relative angles
2377         ent.aiment_classname = strzone(e.classname);
2378         ent.aiment_deadflag = e.deadflag;
2379 }
2380 void UnsetMovetypeFollow(entity ent)
2381 {
2382         ent.movetype = MOVETYPE_FLY;
2383         PROJECTILE_MAKETRIGGER(ent);
2384         ent.aiment = world;
2385 }
2386 float LostMovetypeFollow(entity ent)
2387 {
2388 /*
2389         if(ent.movetype != MOVETYPE_FOLLOW)
2390                 if(ent.aiment)
2391                         error("???");
2392 */
2393         if(ent.aiment)
2394         {
2395                 if(ent.aiment.classname != ent.aiment_classname)
2396                         return 1;
2397                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2398                         return 1;
2399         }
2400         return 0;
2401 }
2402
2403 float isPushable(entity e)
2404 {
2405         if(e.iscreature)
2406                 return TRUE;
2407         if(e.pushable)
2408                 return TRUE;
2409         switch(e.classname)
2410         {
2411                 case "body":
2412                 case "droppedweapon":
2413                 case "keepawayball":
2414                 case "nexball_basketball":
2415                 case "nexball_football":
2416                         return TRUE;
2417                 case "bullet": // antilagged bullets can't hit this either
2418                         return FALSE;
2419         }
2420         if (e.projectiledeathtype)
2421                 return TRUE;
2422         return FALSE;
2423 }