qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 float spawnpoint_nag;
 159 void relocate_spawnpoint()
 160 {
 161     // nudge off the floor
 162     setorigin(self, self.origin + '0 0 1');
 163
 164     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 165     if (trace_startsolid)
 166     {
 167         vector o;
 168         o = self.origin;
 169         self.mins = PL_MIN;
 170         self.maxs = PL_MAX;
 171         if (!move_out_of_solid(self))
 172             objerror("could not get out of solid at all!");
 173         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 174         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 175         print(" ", ftos(self.origin_y - o_y));
 176         print(" ", ftos(self.origin_z - o_z), "'\n");
 177         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 178         {
 179             if (!spawnpoint_nag)
 180                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 181             spawnpoint_nag = 1;
 182         }
 183         else
 184         {
 185             setorigin(self, o);
 186             self.mins = self.maxs = '0 0 0';
 187             objerror("player spawn point in solid, mapper sucks!\n");
 188             return;
 189         }
 190     }
 191
 192     self.use = spawnpoint_use;
 193     self.team_saved = self.team;
 194     if (!self.cnt)
 195         self.cnt = 1;
 196
 197     if (have_team_spawns != 0)
 198         if (self.team)
 199             have_team_spawns = 1;
 200     have_team_spawns_forteam[self.team] = 1;
 201
 202     if (autocvar_r_showbboxes)
 203     {
 204         // show where spawnpoints point at too
 205         makevectors(self.angles);
 206         entity e;
 207         e = spawn();
 208         e.classname = "info_player_foo";
 209         setorigin(e, self.origin + v_forward * 24);
 210         setsize(e, '-8 -8 -8', '8 8 8');
 211         e.solid = SOLID_TRIGGER;
 212     }
 213 }
 214
 215 #define strstr strstrofs
 216 /*
 217 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 218 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 219 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 220 // BE CONSTANT OR strzoneD!
 221 float strstr(string haystack, string needle, float offset)
 222 {
 223         float len, endpos;
 224         string found;
 225         len = strlen(needle);
 226         endpos = strlen(haystack) - len;
 227         while(offset <= endpos)
 228         {
 229                 found = substring(haystack, offset, len);
 230                 if(found == needle)
 231                         return offset;
 232                 offset = offset + 1;
 233         }
 234         return -1;
 235 }
 236 */
 237
 238 float NUM_NEAREST_ENTITIES = 4;
 239 entity nearest_entity[NUM_NEAREST_ENTITIES];
 240 float nearest_length[NUM_NEAREST_ENTITIES];
 241 entity findnearest(vector point, .string field, string value, vector axismod)
 242 {
 243     entity localhead;
 244     float i;
 245     float j;
 246     float len;
 247     vector dist;
 248
 249     float num_nearest;
 250     num_nearest = 0;
 251
 252     localhead = find(world, field, value);
 253     while (localhead)
 254     {
 255         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 256             dist = localhead.oldorigin;
 257         else
 258             dist = localhead.origin;
 259         dist = dist - point;
 260         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 261         len = vlen(dist);
 262
 263         for (i = 0; i < num_nearest; ++i)
 264         {
 265             if (len < nearest_length[i])
 266                 break;
 267         }
 268
 269         // now i tells us where to insert at
 270         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 271         if (i < NUM_NEAREST_ENTITIES)
 272         {
 273             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 274             {
 275                 nearest_length[j + 1] = nearest_length[j];
 276                 nearest_entity[j + 1] = nearest_entity[j];
 277             }
 278             nearest_length[i] = len;
 279             nearest_entity[i] = localhead;
 280             if (num_nearest < NUM_NEAREST_ENTITIES)
 281                 num_nearest = num_nearest + 1;
 282         }
 283
 284         localhead = find(localhead, field, value);
 285     }
 286
 287     // now use the first one from our list that we can see
 288     for (i = 0; i < num_nearest; ++i)
 289     {
 290         traceline(point, nearest_entity[i].origin, TRUE, world);
 291         if (trace_fraction == 1)
 292         {
 293             if (i != 0)
 294             {
 295                 dprint("Nearest point (");
 296                 dprint(nearest_entity[0].netname);
 297                 dprint(") is not visible, using a visible one.\n");
 298             }
 299             return nearest_entity[i];
 300         }
 301     }
 302
 303     if (num_nearest == 0)
 304         return world;
 305
 306     dprint("Not seeing any location point, using nearest as fallback.\n");
 307     /* DEBUGGING CODE:
 308     dprint("Candidates were: ");
 309     for(j = 0; j < num_nearest; ++j)
 310     {
 311         if(j != 0)
 312                 dprint(", ");
 313         dprint(nearest_entity[j].netname);
 314     }
 315     dprint("\n");
 316     */
 317
 318     return nearest_entity[0];
 319 }
 320
 321 void spawnfunc_target_location()
 322 {
 323     self.classname = "target_location";
 324     // location name in netname
 325     // eventually support: count, teamgame selectors, line of sight?
 326 }
 327
 328 void spawnfunc_info_location()
 329 {
 330     self.classname = "target_location";
 331     self.message = self.netname;
 332 }
 333
 334 string NearestLocation(vector p)
 335 {
 336     entity loc;
 337     string ret;
 338     ret = "somewhere";
 339     loc = findnearest(p, classname, "target_location", '1 1 1');
 340     if (loc)
 341     {
 342         ret = loc.message;
 343     }
 344     else
 345     {
 346         loc = findnearest(p, target, "###item###", '1 1 4');
 347         if (loc)
 348             ret = loc.netname;
 349     }
 350     return ret;
 351 }
 352
 353 string formatmessage(string msg)
 354 {
 355         float p, p1, p2;
 356         float n;
 357         vector cursor;
 358         entity cursor_ent;
 359         string escape;
 360         string replacement;
 361         p = 0;
 362         n = 7;
 363
 364         WarpZone_crosshair_trace(self);
 365         cursor = trace_endpos;
 366         cursor_ent = trace_ent;
 367
 368         while (1) {
 369                 if (n < 1)
 370                         break; // too many replacements
 371
 372                 n = n - 1;
 373                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 374                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 375
 376                 if (p1 < 0)
 377                         p1 = p2;
 378
 379                 if (p2 < 0)
 380                         p2 = p1;
 381
 382                 p = min(p1, p2);
 383
 384                 if (p < 0)
 385                         break;
 386
 387                 replacement = substring(msg, p, 2);
 388                 escape = substring(msg, p + 1, 1);
 389
 390                 if (escape == "%")
 391                         replacement = "%";
 392                 else if (escape == "\\")
 393                         replacement = "\\";
 394                 else if (escape == "n")
 395                         replacement = "\n";
 396                 else if (escape == "a")
 397                         replacement = ftos(floor(self.armorvalue));
 398                 else if (escape == "h")
 399                         replacement = ftos(floor(self.health));
 400                 else if (escape == "l")
 401                         replacement = NearestLocation(self.origin);
 402                 else if (escape == "y")
 403                         replacement = NearestLocation(cursor);
 404                 else if (escape == "d")
 405                         replacement = NearestLocation(self.death_origin);
 406                 else if (escape == "w") {
 407                         float wep;
 408                         wep = self.weapon;
 409                         if (!wep)
 410                                 wep = self.switchweapon;
 411                         if (!wep)
 412                                 wep = self.cnt;
 413                         replacement = W_Name(wep);
 414                 } else if (escape == "W") {
 415                         if (self.items & IT_SHELLS) replacement = "shells";
 416                         else if (self.items & IT_NAILS) replacement = "bullets";
 417                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 418                         else if (self.items & IT_CELLS) replacement = "cells";
 419                         else replacement = "batteries"; // ;)
 420                 } else if (escape == "x") {
 421                         replacement = cursor_ent.netname;
 422                         if (replacement == "" || !cursor_ent)
 423                                 replacement = "nothing";
 424                 } else if (escape == "s")
 425                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 426                 else if (escape == "S")
 427                         replacement = ftos(vlen(self.velocity));
 428
 429                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 430                 p = p + strlen(replacement);
 431         }
 432         return msg;
 433 }
 434
 435 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 436         return (value == 0) ? FALSE : TRUE;
 437 }
 438
 439 /*
 440 =============
 441 GetCvars
 442 =============
 443 Called with:
 444   0:  sends the request
 445   >0: receives a cvar from name=argv(f) value=argv(f+1)
 446 */
 447 void GetCvars_handleString(string thisname, float f, .string field, string name)
 448 {
 449         if (f < 0)
 450         {
 451                 if (self.field)
 452                         strunzone(self.field);
 453                 self.field = string_null;
 454         }
 455         else if (f > 0)
 456         {
 457                 if (thisname == name)
 458                 {
 459                         if (self.field)
 460                                 strunzone(self.field);
 461                         self.field = strzone(argv(f + 1));
 462                 }
 463         }
 464         else
 465                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 466 }
 467 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 468 {
 469         GetCvars_handleString(thisname, f, field, name);
 470         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 471                 if (thisname == name)
 472                 {
 473                         string s;
 474                         s = func(strcat1(self.field));
 475                         if (s != self.field)
 476                         {
 477                                 strunzone(self.field);
 478                                 self.field = strzone(s);
 479                         }
 480                 }
 481 }
 482 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 483 {
 484         if (f < 0)
 485         {
 486         }
 487         else if (f > 0)
 488         {
 489                 if (thisname == name)
 490                         self.field = stof(argv(f + 1));
 491         }
 492         else
 493                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 494 }
 495 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 496 {
 497         if (f < 0)
 498         {
 499         }
 500         else if (f > 0)
 501         {
 502                 if (thisname == name)
 503                 {
 504                         if(!self.field)
 505                         {
 506                                 self.field = stof(argv(f + 1));
 507                                 if(!self.field)
 508                                         self.field = -1;
 509                         }
 510                 }
 511         }
 512         else
 513         {
 514                 if(!self.field)
 515                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 516         }
 517 }
 518 float w_getbestweapon(entity e);
 519 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 520 {
 521         string o;
 522         o = W_FixWeaponOrder_ForceComplete(wo);
 523         if(self.weaponorder_byimpulse)
 524         {
 525                 strunzone(self.weaponorder_byimpulse);
 526                 self.weaponorder_byimpulse = string_null;
 527         }
 528         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 529         return o;
 530 }
 531 void GetCvars(float f)
 532 {
 533         string s = string_null;
 534
 535         if (f > 0)
 536                 s = strcat1(argv(f));
 537
 538         get_cvars_f = f;
 539         get_cvars_s = s;
 540
 541         MUTATOR_CALLHOOK(GetCvars);
 542
 543         Notification_GetCvars();
 544
 545         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 546         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 547         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 548         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 549         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 562         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 563         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 564         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 565         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 566         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 567         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 568
 569         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 570         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 571
 572         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 573         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 574         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 575         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 576         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 577
 578         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 579         if (f > 0)
 580         {
 581                 if (s == "cl_weaponpriority")
 582                         self.switchweapon = w_getbestweapon(self);
 583                 if (s == "cl_allow_uidtracking")
 584                         PlayerStats_AddPlayer(self);
 585         }
 586 }
 587
 588 // decolorizes and team colors the player name when needed
 589 string playername(entity p)
 590 {
 591     string t;
 592     if (teamplay && !intermission_running && p.classname == "player")
 593     {
 594         t = Team_ColorCode(p.team);
 595         return strcat(t, strdecolorize(p.netname));
 596     }
 597     else
 598         return p.netname;
 599 }
 600
 601 vector randompos(vector m1, vector m2)
 602 {
 603     vector v;
 604     m2 = m2 - m1;
 605     v_x = m2_x * random() + m1_x;
 606     v_y = m2_y * random() + m1_y;
 607     v_z = m2_z * random() + m1_z;
 608     return  v;
 609 }
 610
 611 //#NO AUTOCVARS START
 612
 613 float g_pickup_shells;
 614 float g_pickup_shells_max;
 615 float g_pickup_nails;
 616 float g_pickup_nails_max;
 617 float g_pickup_rockets;
 618 float g_pickup_rockets_max;
 619 float g_pickup_cells;
 620 float g_pickup_cells_max;
 621 float g_pickup_fuel;
 622 float g_pickup_fuel_jetpack;
 623 float g_pickup_fuel_max;
 624 float g_pickup_armorsmall;
 625 float g_pickup_armorsmall_max;
 626 float g_pickup_armorsmall_anyway;
 627 float g_pickup_armormedium;
 628 float g_pickup_armormedium_max;
 629 float g_pickup_armormedium_anyway;
 630 float g_pickup_armorbig;
 631 float g_pickup_armorbig_max;
 632 float g_pickup_armorbig_anyway;
 633 float g_pickup_armorlarge;
 634 float g_pickup_armorlarge_max;
 635 float g_pickup_armorlarge_anyway;
 636 float g_pickup_healthsmall;
 637 float g_pickup_healthsmall_max;
 638 float g_pickup_healthsmall_anyway;
 639 float g_pickup_healthmedium;
 640 float g_pickup_healthmedium_max;
 641 float g_pickup_healthmedium_anyway;
 642 float g_pickup_healthlarge;
 643 float g_pickup_healthlarge_max;
 644 float g_pickup_healthlarge_anyway;
 645 float g_pickup_healthmega;
 646 float g_pickup_healthmega_max;
 647 float g_pickup_healthmega_anyway;
 648 float g_pickup_ammo_anyway;
 649 float g_pickup_weapons_anyway;
 650 float g_weaponarena;
 651 WEPSET_DECLARE_A(g_weaponarena_weapons);
 652 float g_weaponarena_random;
 653 float g_weaponarena_random_with_laser;
 654 string g_weaponarena_list;
 655 float g_weaponspeedfactor;
 656 float g_weaponratefactor;
 657 float g_weapondamagefactor;
 658 float g_weaponforcefactor;
 659 float g_weaponspreadfactor;
 660
 661 WEPSET_DECLARE_A(start_weapons);
 662 WEPSET_DECLARE_A(start_weapons_default);
 663 WEPSET_DECLARE_A(start_weapons_defaultmask);
 664 float start_items;
 665 float start_ammo_shells;
 666 float start_ammo_nails;
 667 float start_ammo_rockets;
 668 float start_ammo_cells;
 669 float start_ammo_fuel;
 670 float start_health;
 671 float start_armorvalue;
 672 WEPSET_DECLARE_A(warmup_start_weapons);
 673 WEPSET_DECLARE_A(warmup_start_weapons_default);
 674 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 675 float warmup_start_ammo_shells;
 676 float warmup_start_ammo_nails;
 677 float warmup_start_ammo_rockets;
 678 float warmup_start_ammo_cells;
 679 float warmup_start_ammo_fuel;
 680 float warmup_start_health;
 681 float warmup_start_armorvalue;
 682 float g_weapon_stay;
 683
 684 entity get_weaponinfo(float w);
 685
 686 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 687 {
 688         var float i = weaponinfo.weapon;
 689         var float d = 0;
 690
 691         if (!i)
 692                 return 0;
 693
 694         if (g_lms || g_ca || allguns)
 695         {
 696                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 697                         d = TRUE;
 698                 else
 699                         d = FALSE;
 700         }
 701         else if (g_cts)
 702                 d = (i == WEP_SHOTGUN);
 703         else if (g_nexball)
 704                 d = 0; // weapon is set a few lines later
 705         else
 706                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 707
 708         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 709                 d |= (i == WEP_HOOK);
 710         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 711                 d = 0;
 712
 713         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 714
 715         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 716
 717         // bit order in t:
 718         // 1: want or not
 719         // 2: is default?
 720         // 4: is set by default?
 721         if(t < 0)
 722                 t = 4 | (3 * d);
 723         else
 724                 t |= (2 * d);
 725
 726         return t;
 727 }
 728
 729 void readplayerstartcvars()
 730 {
 731         entity e;
 732         float i, j, t;
 733         string s;
 734
 735         // initialize starting values for players
 736         WEPSET_CLEAR_A(start_weapons);
 737         WEPSET_CLEAR_A(start_weapons_default);
 738         WEPSET_CLEAR_A(start_weapons_defaultmask);
 739         start_items = 0;
 740         start_ammo_shells = 0;
 741         start_ammo_nails = 0;
 742         start_ammo_rockets = 0;
 743         start_ammo_cells = 0;
 744         start_health = cvar("g_balance_health_start");
 745         start_armorvalue = cvar("g_balance_armor_start");
 746
 747         g_weaponarena = 0;
 748         WEPSET_CLEAR_A(g_weaponarena_weapons);
 749
 750         s = cvar_string("g_weaponarena");
 751         if (s == "0" || s == "")
 752         {
 753                 if(g_ca)
 754                         s = "most";
 755         }
 756
 757         if (s == "0" || s == "")
 758         {
 759                 // no arena
 760         }
 761         else if (s == "off")
 762         {
 763                 // forcibly turn off weaponarena
 764         }
 765         else if (s == "all")
 766         {
 767                 g_weaponarena = 1;
 768                 g_weaponarena_list = "All Weapons";
 769                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 770                 {
 771                         e = get_weaponinfo(j);
 772                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 773                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 774                 }
 775         }
 776         else if (s == "most")
 777         {
 778                 g_weaponarena = 1;
 779                 g_weaponarena_list = "Most Weapons";
 780                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 781                 {
 782                         e = get_weaponinfo(j);
 783                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 784                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 785                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 786                 }
 787         }
 788         else if (s == "none")
 789         {
 790                 g_weaponarena = 1;
 791                 g_weaponarena_list = "No Weapons";
 792         }
 793         else
 794         {
 795                 g_weaponarena = 1;
 796                 t = tokenize_console(s);
 797                 g_weaponarena_list = "";
 798                 for (i = 0; i < t; ++i)
 799                 {
 800                         s = argv(i);
 801                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 802                         {
 803                                 e = get_weaponinfo(j);
 804                                 if (e.netname == s)
 805                                 {
 806                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 807                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 808                                         break;
 809                                 }
 810                         }
 811                         if (j > WEP_LAST)
 812                         {
 813                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 814                         }
 815                 }
 816                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 817         }
 818
 819         if(g_weaponarena)
 820                 g_weaponarena_random = cvar("g_weaponarena_random");
 821         else
 822                 g_weaponarena_random = 0;
 823         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 824
 825         if (g_weaponarena)
 826         {
 827                 g_minstagib = 0; // incompatible
 828                 g_pinata = 0; // incompatible
 829                 g_weapon_stay = 0; // incompatible
 830                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 831                 start_items |= IT_UNLIMITED_AMMO;
 832         }
 833         else if (g_minstagib)
 834         {
 835                 g_pinata = 0; // incompatible
 836                 g_weapon_stay = 0; // incompatible
 837                 g_bloodloss = 0; // incompatible
 838                 start_health = 100;
 839                 start_armorvalue = 0;
 840                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 841                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 842                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 843
 844                 if (g_minstagib_invis_alpha <= 0)
 845                         g_minstagib_invis_alpha = -1;
 846         }
 847         else
 848         {
 849                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 850                 {
 851                         e = get_weaponinfo(i);
 852                         float w = want_weapon("g_start_weapon_", e, FALSE);
 853                         if(w & 1)
 854                                 WEPSET_OR_AW(start_weapons, i);
 855                         if(w & 2)
 856                                 WEPSET_OR_AW(start_weapons_default, i);
 857                         if(w & 4)
 858                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 859                 }
 860         }
 861
 862         if(!cvar("g_use_ammunition"))
 863                 start_items |= IT_UNLIMITED_AMMO;
 864
 865         if(cvar("g_nexball"))
 866                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 867
 868         if(g_minstagib)
 869         {
 870                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 871                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 872         }
 873         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 874         {
 875                 start_ammo_rockets = 999;
 876                 start_ammo_shells = 999;
 877                 start_ammo_cells = 999;
 878                 start_ammo_nails = 999;
 879                 start_ammo_fuel = 999;
 880         }
 881         else
 882         {
 883                 start_ammo_shells = cvar("g_start_ammo_shells");
 884                 start_ammo_nails = cvar("g_start_ammo_nails");
 885                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 886                 start_ammo_cells = cvar("g_start_ammo_cells");
 887                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 888         }
 889
 890         if (inWarmupStage)
 891         {
 892                 warmup_start_ammo_shells = start_ammo_shells;
 893                 warmup_start_ammo_nails = start_ammo_nails;
 894                 warmup_start_ammo_rockets = start_ammo_rockets;
 895                 warmup_start_ammo_cells = start_ammo_cells;
 896                 warmup_start_ammo_fuel = start_ammo_fuel;
 897                 warmup_start_health = start_health;
 898                 warmup_start_armorvalue = start_armorvalue;
 899                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 900                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 901                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 902
 903                 if (!g_weaponarena && !g_minstagib && !g_ca)
 904                 {
 905                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 906                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 907                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 908                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 909                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 910                         warmup_start_health = cvar("g_warmup_start_health");
 911                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 912                         WEPSET_CLEAR_A(warmup_start_weapons);
 913                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 914                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 915                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 916                         {
 917                                 e = get_weaponinfo(i);
 918                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 919                                 if(w & 1)
 920                                         WEPSET_OR_AW(warmup_start_weapons, i);
 921                                 if(w & 2)
 922                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 923                                 if(w & 4)
 924                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 925                         }
 926                 }
 927         }
 928
 929         if (g_jetpack)
 930                 start_items |= IT_JETPACK;
 931
 932         MUTATOR_CALLHOOK(SetStartItems);
 933
 934         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 935         {
 936                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 937                 start_items |= IT_FUEL_REGEN;
 938                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 939                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 940         }
 941
 942         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 943         {
 944                 e = get_weaponinfo(i);
 945                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 946                         weapon_action(i, WR_PRECACHE);
 947         }
 948
 949         start_ammo_shells = max(0, start_ammo_shells);
 950         start_ammo_nails = max(0, start_ammo_nails);
 951         start_ammo_cells = max(0, start_ammo_cells);
 952         start_ammo_rockets = max(0, start_ammo_rockets);
 953         start_ammo_fuel = max(0, start_ammo_fuel);
 954
 955         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 956         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 957         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 958         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 959         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 960 }
 961
 962 float g_bugrigs;
 963 float g_bugrigs_planar_movement;
 964 float g_bugrigs_planar_movement_car_jumping;
 965 float g_bugrigs_reverse_spinning;
 966 float g_bugrigs_reverse_speeding;
 967 float g_bugrigs_reverse_stopping;
 968 float g_bugrigs_air_steering;
 969 float g_bugrigs_angle_smoothing;
 970 float g_bugrigs_friction_floor;
 971 float g_bugrigs_friction_brake;
 972 float g_bugrigs_friction_air;
 973 float g_bugrigs_accel;
 974 float g_bugrigs_speed_ref;
 975 float g_bugrigs_speed_pow;
 976 float g_bugrigs_steer;
 977
 978 float sv_autotaunt;
 979 float sv_taunt;
 980
 981 string GetGametype(); // g_world.qc
 982 void readlevelcvars(void)
 983 {
 984         g_minstagib = cvar("g_minstagib");
 985
 986         // load ALL the mutators
 987         if(cvar("g_dodging"))
 988                 MUTATOR_ADD(mutator_dodging);
 989         if(cvar("g_spawn_near_teammate"))
 990                 MUTATOR_ADD(mutator_spawn_near_teammate);
 991         if(cvar("g_physical_items"))
 992                 MUTATOR_ADD(mutator_physical_items);
 993         if(cvar("g_touchexplode"))
 994                 MUTATOR_ADD(mutator_touchexplode);
 995         if(!g_minstagib)
 996         {
 997                 if(cvar("g_invincible_projectiles"))
 998                         MUTATOR_ADD(mutator_invincibleprojectiles);
 999                 if(cvar("g_new_toys"))
1000                         MUTATOR_ADD(mutator_new_toys);
1001                 if(cvar("g_nix"))
1002                         MUTATOR_ADD(mutator_nix);
1003                 if(cvar("g_rocket_flying"))
1004                         MUTATOR_ADD(mutator_rocketflying);
1005                 if(cvar("g_vampire"))
1006                         MUTATOR_ADD(mutator_vampire);
1007                 if(cvar("g_superspectate"))
1008                         MUTATOR_ADD(mutator_superspec);
1009         }
1010
1011         // is this a mutator? is this a mode?
1012         if(cvar("g_sandbox"))
1013                 MUTATOR_ADD(sandbox);
1014
1015         if(cvar("sv_allow_fullbright"))
1016                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1017
1018     g_bugrigs = cvar("g_bugrigs");
1019     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1020     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1021     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1022     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1023     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1024     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1025     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1026     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1027     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1028     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1029     g_bugrigs_accel = cvar("g_bugrigs_accel");
1030     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1031     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1032     g_bugrigs_steer = cvar("g_bugrigs_steer");
1033
1034         sv_clones = cvar("sv_clones");
1035         sv_foginterval = cvar("sv_foginterval");
1036         g_cloaked = cvar("g_cloaked");
1037     if(g_cts)
1038         g_cloaked = 1; // always enable cloak in CTS
1039         g_jump_grunt = cvar("g_jump_grunt");
1040         g_footsteps = cvar("g_footsteps");
1041         g_grappling_hook = cvar("g_grappling_hook");
1042         g_jetpack = cvar("g_jetpack");
1043         g_midair = cvar("g_midair");
1044         g_norecoil = cvar("g_norecoil");
1045         g_bloodloss = cvar("g_bloodloss");
1046         sv_maxidle = cvar("sv_maxidle");
1047         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1048         sv_autotaunt = cvar("sv_autotaunt");
1049         sv_taunt = cvar("sv_taunt");
1050
1051         inWarmupStage = cvar("g_warmup");
1052         g_warmup_limit = cvar("g_warmup_limit");
1053         g_warmup_allguns = cvar("g_warmup_allguns");
1054         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1055
1056         if ((g_race && g_race_qualifying == 2) || g_arena || g_assault || cvar("g_campaign"))
1057                 inWarmupStage = 0; // these modes cannot work together, sorry
1058
1059         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1060         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1061         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1062         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1063         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1064         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1065         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1066         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1067         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1068         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1069         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1070         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1071         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1072         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1073
1074         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1075         g_weaponratefactor = cvar("g_weaponratefactor");
1076         g_weapondamagefactor = cvar("g_weapondamagefactor");
1077         g_weaponforcefactor = cvar("g_weaponforcefactor");
1078         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1079
1080         g_pickup_shells = cvar("g_pickup_shells");
1081         g_pickup_shells_max = cvar("g_pickup_shells_max");
1082         g_pickup_nails = cvar("g_pickup_nails");
1083         g_pickup_nails_max = cvar("g_pickup_nails_max");
1084         g_pickup_rockets = cvar("g_pickup_rockets");
1085         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1086         g_pickup_cells = cvar("g_pickup_cells");
1087         g_pickup_cells_max = cvar("g_pickup_cells_max");
1088         g_pickup_fuel = cvar("g_pickup_fuel");
1089         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1090         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1091         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1092         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1093         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1094         g_pickup_armormedium = cvar("g_pickup_armormedium");
1095         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1096         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1097         g_pickup_armorbig = cvar("g_pickup_armorbig");
1098         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1099         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1100         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1101         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1102         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1103         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1104         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1105         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1106         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1107         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1108         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1109         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1110         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1111         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1112         g_pickup_healthmega = cvar("g_pickup_healthmega");
1113         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1114         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1115
1116         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1117         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1118
1119         g_pinata = cvar("g_pinata");
1120
1121     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1122     if(!g_weapon_stay)
1123         g_weapon_stay = cvar("g_weapon_stay");
1124
1125         if not(inWarmupStage)
1126                 game_starttime = time + cvar("g_start_delay");
1127
1128         readplayerstartcvars();
1129 }
1130
1131 //#NO AUTOCVARS END
1132
1133 // Sound functions
1134 string precache_sound (string s) = #19;
1135 float precache_sound_index (string s) = #19;
1136
1137 #define SND_VOLUME      1
1138 #define SND_ATTENUATION 2
1139 #define SND_LARGEENTITY 8
1140 #define SND_LARGESOUND  16
1141
1142 float sound_allowed(float dest, entity e)
1143 {
1144     // sounds from world may always pass
1145     for (;;)
1146     {
1147         if (e.classname == "body")
1148             e = e.enemy;
1149         else if (e.realowner && e.realowner != e)
1150             e = e.realowner;
1151         else if (e.owner && e.owner != e)
1152             e = e.owner;
1153         else
1154             break;
1155     }
1156     // sounds to self may always pass
1157     if (dest == MSG_ONE)
1158         if (e == msg_entity)
1159             return TRUE;
1160     // sounds by players can be removed
1161     if (autocvar_bot_sound_monopoly)
1162         if (clienttype(e) == CLIENTTYPE_REAL)
1163             return FALSE;
1164     // anything else may pass
1165     return TRUE;
1166 }
1167
1168 #ifdef COMPAT_XON010_CHANNELS
1169 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1170 void sound(entity e, float chan, string samp, float vol, float atten)
1171 {
1172     if (!sound_allowed(MSG_BROADCAST, e))
1173         return;
1174     builtin_sound(e, chan, samp, vol, atten);
1175 }
1176 #else
1177 #undef sound
1178 void sound(entity e, float chan, string samp, float vol, float atten)
1179 {
1180     if (!sound_allowed(MSG_BROADCAST, e))
1181         return;
1182     sound7(e, chan, samp, vol, atten, 0, 0);
1183 }
1184 #endif
1185
1186 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1187 {
1188     float entno, idx;
1189
1190     if (!sound_allowed(dest, e))
1191         return;
1192
1193     entno = num_for_edict(e);
1194     idx = precache_sound_index(samp);
1195
1196     float sflags;
1197     sflags = 0;
1198
1199     atten = floor(atten * 64);
1200     vol = floor(vol * 255);
1201
1202     if (vol != 255)
1203         sflags |= SND_VOLUME;
1204     if (atten != 64)
1205         sflags |= SND_ATTENUATION;
1206     if (entno >= 8192 || chan < 0 || chan > 7)
1207         sflags |= SND_LARGEENTITY;
1208     if (idx >= 256)
1209         sflags |= SND_LARGESOUND;
1210
1211     WriteByte(dest, SVC_SOUND);
1212     WriteByte(dest, sflags);
1213     if (sflags & SND_VOLUME)
1214         WriteByte(dest, vol);
1215     if (sflags & SND_ATTENUATION)
1216         WriteByte(dest, atten);
1217     if (sflags & SND_LARGEENTITY)
1218     {
1219         WriteShort(dest, entno);
1220         WriteByte(dest, chan);
1221     }
1222     else
1223     {
1224         WriteShort(dest, entno * 8 + chan);
1225     }
1226     if (sflags & SND_LARGESOUND)
1227         WriteShort(dest, idx);
1228     else
1229         WriteByte(dest, idx);
1230
1231     WriteCoord(dest, o_x);
1232     WriteCoord(dest, o_y);
1233     WriteCoord(dest, o_z);
1234 }
1235 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1236 {
1237     vector o;
1238
1239     if (!sound_allowed(dest, e))
1240         return;
1241
1242     o = e.origin + 0.5 * (e.mins + e.maxs);
1243     soundtoat(dest, e, o, chan, samp, vol, atten);
1244 }
1245 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1246 {
1247     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1248 }
1249 void stopsoundto(float dest, entity e, float chan)
1250 {
1251     float entno;
1252
1253     if (!sound_allowed(dest, e))
1254         return;
1255
1256     entno = num_for_edict(e);
1257
1258     if (entno >= 8192 || chan < 0 || chan > 7)
1259     {
1260         float idx, sflags;
1261         idx = precache_sound_index("misc/null.wav");
1262         sflags = SND_LARGEENTITY;
1263         if (idx >= 256)
1264             sflags |= SND_LARGESOUND;
1265         WriteByte(dest, SVC_SOUND);
1266         WriteByte(dest, sflags);
1267         WriteShort(dest, entno);
1268         WriteByte(dest, chan);
1269         if (sflags & SND_LARGESOUND)
1270             WriteShort(dest, idx);
1271         else
1272             WriteByte(dest, idx);
1273         WriteCoord(dest, e.origin_x);
1274         WriteCoord(dest, e.origin_y);
1275         WriteCoord(dest, e.origin_z);
1276     }
1277     else
1278     {
1279         WriteByte(dest, SVC_STOPSOUND);
1280         WriteShort(dest, entno * 8 + chan);
1281     }
1282 }
1283 void stopsound(entity e, float chan)
1284 {
1285     if (!sound_allowed(MSG_BROADCAST, e))
1286         return;
1287
1288     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1289     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1290 }
1291
1292 void play2(entity e, string filename)
1293 {
1294     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1295     msg_entity = e;
1296     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1297 }
1298
1299 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1300 .float spamtime;
1301 float spamsound(entity e, float chan, string samp, float vol, float atten)
1302 {
1303     if (!sound_allowed(MSG_BROADCAST, e))
1304         return FALSE;
1305
1306     if (time > e.spamtime)
1307     {
1308         e.spamtime = time;
1309         sound(e, chan, samp, vol, atten);
1310         return TRUE;
1311     }
1312     return FALSE;
1313 }
1314
1315 void play2team(float t, string filename)
1316 {
1317     entity head;
1318
1319     if (autocvar_bot_sound_monopoly)
1320         return;
1321
1322     FOR_EACH_REALPLAYER(head)
1323     {
1324         if (head.team == t)
1325             play2(head, filename);
1326     }
1327 }
1328
1329 void play2all(string samp)
1330 {
1331     if (autocvar_bot_sound_monopoly)
1332         return;
1333
1334     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1335 }
1336
1337 void PrecachePlayerSounds(string f);
1338 void precache_playermodel(string m)
1339 {
1340         float globhandle, i, n;
1341         string f;
1342
1343         if(substring(m, -9,5) == "_lod1")
1344                 return;
1345         if(substring(m, -9,5) == "_lod2")
1346                 return;
1347         precache_model(m);
1348         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1349         if(fexists(f))
1350                 precache_model(f);
1351         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1352         if(fexists(f))
1353                 precache_model(f);
1354
1355         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1356         if (globhandle < 0)
1357                 return;
1358         n = search_getsize(globhandle);
1359         for (i = 0; i < n; ++i)
1360         {
1361                 //print(search_getfilename(globhandle, i), "\n");
1362                 f = search_getfilename(globhandle, i);
1363                 PrecachePlayerSounds(f);
1364         }
1365         search_end(globhandle);
1366 }
1367 void precache_all_playermodels(string pattern)
1368 {
1369         float globhandle, i, n;
1370         string f;
1371
1372         globhandle = search_begin(pattern, TRUE, FALSE);
1373         if (globhandle < 0)
1374                 return;
1375         n = search_getsize(globhandle);
1376         for (i = 0; i < n; ++i)
1377         {
1378                 //print(search_getfilename(globhandle, i), "\n");
1379                 f = search_getfilename(globhandle, i);
1380                 precache_playermodel(f);
1381         }
1382         search_end(globhandle);
1383 }
1384
1385 void precache()
1386 {
1387     // gamemode related things
1388     precache_model ("models/misc/chatbubble.spr");
1389
1390 #ifdef TTURRETS_ENABLED
1391     if (autocvar_g_turrets)
1392         turrets_precash();
1393 #endif
1394
1395     // Precache all player models if desired
1396     if (autocvar_sv_precacheplayermodels)
1397     {
1398         PrecachePlayerSounds("sound/player/default.sounds");
1399         precache_all_playermodels("models/player/*.zym");
1400         precache_all_playermodels("models/player/*.dpm");
1401         precache_all_playermodels("models/player/*.md3");
1402         precache_all_playermodels("models/player/*.psk");
1403         precache_all_playermodels("models/player/*.iqm");
1404     }
1405
1406     if (autocvar_sv_defaultcharacter)
1407     {
1408         string s;
1409         s = autocvar_sv_defaultplayermodel_red;
1410         if (s != "")
1411             precache_playermodel(s);
1412         s = autocvar_sv_defaultplayermodel_blue;
1413         if (s != "")
1414             precache_playermodel(s);
1415         s = autocvar_sv_defaultplayermodel_yellow;
1416         if (s != "")
1417             precache_playermodel(s);
1418         s = autocvar_sv_defaultplayermodel_pink;
1419         if (s != "")
1420             precache_playermodel(s);
1421         s = autocvar_sv_defaultplayermodel;
1422         if (s != "")
1423             precache_playermodel(s);
1424     }
1425
1426     if (g_footsteps)
1427     {
1428         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1429         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1430     }
1431
1432     // gore and miscellaneous sounds
1433     //precache_sound ("misc/h2ohit.wav");
1434     precache_model ("models/hook.md3");
1435     precache_sound ("misc/armorimpact.wav");
1436     precache_sound ("misc/bodyimpact1.wav");
1437     precache_sound ("misc/bodyimpact2.wav");
1438     precache_sound ("misc/gib.wav");
1439     precache_sound ("misc/gib_splat01.wav");
1440     precache_sound ("misc/gib_splat02.wav");
1441     precache_sound ("misc/gib_splat03.wav");
1442     precache_sound ("misc/gib_splat04.wav");
1443     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1444     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1445     precache_sound ("misc/null.wav");
1446     precache_sound ("misc/spawn.wav");
1447     precache_sound ("misc/talk.wav");
1448     precache_sound ("misc/teleport.wav");
1449     precache_sound ("misc/poweroff.wav");
1450     precache_sound ("player/lava.wav");
1451     precache_sound ("player/slime.wav");
1452
1453     precache_model ("models/sprites/0.spr32");
1454     precache_model ("models/sprites/1.spr32");
1455     precache_model ("models/sprites/2.spr32");
1456     precache_model ("models/sprites/3.spr32");
1457     precache_model ("models/sprites/4.spr32");
1458     precache_model ("models/sprites/5.spr32");
1459     precache_model ("models/sprites/6.spr32");
1460     precache_model ("models/sprites/7.spr32");
1461     precache_model ("models/sprites/8.spr32");
1462     precache_model ("models/sprites/9.spr32");
1463     precache_model ("models/sprites/10.spr32");
1464
1465     // common weapon precaches
1466         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1467     precache_sound ("weapons/weapon_switch.wav");
1468     precache_sound ("weapons/weaponpickup.wav");
1469     precache_sound ("weapons/unavailable.wav");
1470     precache_sound ("weapons/dryfire.wav");
1471     if (g_grappling_hook)
1472     {
1473         precache_sound ("weapons/hook_fire.wav"); // hook
1474         precache_sound ("weapons/hook_impact.wav"); // hook
1475     }
1476
1477     if(autocvar_sv_precacheweapons)
1478     {
1479         //precache weapon models/sounds
1480         float wep;
1481         wep = WEP_FIRST;
1482         while (wep <= WEP_LAST)
1483         {
1484             weapon_action(wep, WR_PRECACHE);
1485             wep = wep + 1;
1486         }
1487     }
1488
1489     precache_model("models/elaser.mdl");
1490     precache_model("models/laser.mdl");
1491     precache_model("models/ebomb.mdl");
1492
1493 #if 0
1494     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1495
1496     if (!self.noise && self.music) // quake 3 uses the music field
1497         self.noise = self.music;
1498
1499     // plays music for the level if there is any
1500     if (self.noise)
1501     {
1502         precache_sound (self.noise);
1503         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1504     }
1505 #endif
1506 }
1507
1508 // WARNING: this kills the trace globals
1509 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1510 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1511
1512 #define INITPRIO_FIRST              0
1513 #define INITPRIO_GAMETYPE           0
1514 #define INITPRIO_GAMETYPE_FALLBACK  1
1515 #define INITPRIO_FINDTARGET        10
1516 #define INITPRIO_DROPTOFLOOR       20
1517 #define INITPRIO_SETLOCATION       90
1518 #define INITPRIO_LINKDOORS         91
1519 #define INITPRIO_LAST              99
1520
1521 .void(void) initialize_entity;
1522 .float initialize_entity_order;
1523 .entity initialize_entity_next;
1524 entity initialize_entity_first;
1525
1526 void make_safe_for_remove(entity e)
1527 {
1528     if (e.initialize_entity)
1529     {
1530         entity ent, prev = world;
1531         for (ent = initialize_entity_first; ent; )
1532         {
1533             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1534             {
1535                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1536                 // skip it in linked list
1537                 if (prev)
1538                 {
1539                     prev.initialize_entity_next = ent.initialize_entity_next;
1540                     ent = prev.initialize_entity_next;
1541                 }
1542                 else
1543                 {
1544                     initialize_entity_first = ent.initialize_entity_next;
1545                     ent = initialize_entity_first;
1546                 }
1547             }
1548             else
1549             {
1550                 prev = ent;
1551                 ent = ent.initialize_entity_next;
1552             }
1553         }
1554     }
1555 }
1556
1557 void objerror(string s)
1558 {
1559     make_safe_for_remove(self);
1560     builtin_objerror(s);
1561 }
1562
1563 .float remove_except_protected_forbidden;
1564 void remove_except_protected(entity e)
1565 {
1566         if(e.remove_except_protected_forbidden)
1567                 error("not allowed to remove this at this point");
1568         builtin_remove(e);
1569 }
1570
1571 void remove_unsafely(entity e)
1572 {
1573     if(e.classname == "spike")
1574         error("Removing spikes is forbidden (crylink bug), please report");
1575     builtin_remove(e);
1576 }
1577
1578 void remove_safely(entity e)
1579 {
1580     make_safe_for_remove(e);
1581     builtin_remove(e);
1582 }
1583
1584 void InitializeEntity(entity e, void(void) func, float order)
1585 {
1586     entity prev, cur;
1587
1588     if (!e || e.initialize_entity)
1589     {
1590         // make a proxy initializer entity
1591         entity e_old;
1592         e_old = e;
1593         e = spawn();
1594         e.classname = "initialize_entity";
1595         e.enemy = e_old;
1596     }
1597
1598     e.initialize_entity = func;
1599     e.initialize_entity_order = order;
1600
1601     cur = initialize_entity_first;
1602     prev = world;
1603     for (;;)
1604     {
1605         if (!cur || cur.initialize_entity_order > order)
1606         {
1607             // insert between prev and cur
1608             if (prev)
1609                 prev.initialize_entity_next = e;
1610             else
1611                 initialize_entity_first = e;
1612             e.initialize_entity_next = cur;
1613             return;
1614         }
1615         prev = cur;
1616         cur = cur.initialize_entity_next;
1617     }
1618 }
1619 void InitializeEntitiesRun()
1620 {
1621     entity startoflist;
1622     startoflist = initialize_entity_first;
1623     initialize_entity_first = world;
1624     remove = remove_except_protected;
1625     for (self = startoflist; self; self = self.initialize_entity_next)
1626     {
1627         self.remove_except_protected_forbidden = 1;
1628     }
1629     for (self = startoflist; self; )
1630     {
1631         entity e;
1632         var void(void) func;
1633         e = self.initialize_entity_next;
1634         func = self.initialize_entity;
1635         self.initialize_entity_order = 0;
1636         self.initialize_entity = func_null;
1637         self.initialize_entity_next = world;
1638         self.remove_except_protected_forbidden = 0;
1639         if (self.classname == "initialize_entity")
1640         {
1641             entity e_old;
1642             e_old = self.enemy;
1643             builtin_remove(self);
1644             self = e_old;
1645         }
1646         //dprint("Delayed initialization: ", self.classname, "\n");
1647         if(func)
1648             func();
1649         else
1650         {
1651             eprint(self);
1652             backtrace(strcat("Null function in: ", self.classname, "\n"));
1653         }
1654         self = e;
1655     }
1656     remove = remove_unsafely;
1657 }
1658
1659 .float uncustomizeentityforclient_set;
1660 .void(void) uncustomizeentityforclient;
1661 void UncustomizeEntitiesRun()
1662 {
1663     entity oldself;
1664     oldself = self;
1665     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1666         self.uncustomizeentityforclient();
1667     self = oldself;
1668 }
1669 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1670 {
1671     e.customizeentityforclient = customizer;
1672     e.uncustomizeentityforclient = uncustomizer;
1673     e.uncustomizeentityforclient_set = !!uncustomizer;
1674 }
1675
1676 .float nottargeted;
1677 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1678
1679 void() SUB_Remove;
1680 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1681 {
1682     vector mi, ma;
1683
1684     if (e.classname == "")
1685         e.classname = "net_linked";
1686
1687     if (e.model == "" || self.modelindex == 0)
1688     {
1689         mi = e.mins;
1690         ma = e.maxs;
1691         setmodel(e, "null");
1692         setsize(e, mi, ma);
1693     }
1694
1695     e.SendEntity = sendfunc;
1696     e.SendFlags = 0xFFFFFF;
1697
1698     if (!docull)
1699         e.effects |= EF_NODEPTHTEST;
1700
1701     if (dt)
1702     {
1703         e.nextthink = time + dt;
1704         e.think = SUB_Remove;
1705     }
1706 }
1707
1708 void adaptor_think2touch()
1709 {
1710     entity o;
1711     o = other;
1712     other = world;
1713     self.touch();
1714     other = o;
1715 }
1716
1717 void adaptor_think2use()
1718 {
1719     entity o, a;
1720     o = other;
1721     a = activator;
1722     activator = world;
1723     other = world;
1724     self.use();
1725     other = o;
1726     activator = a;
1727 }
1728
1729 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1730 {
1731         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1732                 self.projectiledeathtype |= HITTYPE_SPLASH;
1733         adaptor_think2use();
1734 }
1735
1736 // deferred dropping
1737 void DropToFloor_Handler()
1738 {
1739     builtin_droptofloor();
1740     self.dropped_origin = self.origin;
1741 }
1742
1743 void droptofloor()
1744 {
1745     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1746 }
1747
1748
1749
1750 float trace_hits_box_a0, trace_hits_box_a1;
1751
1752 float trace_hits_box_1d(float end, float thmi, float thma)
1753 {
1754     if (end == 0)
1755     {
1756         // just check if x is in range
1757         if (0 < thmi)
1758             return FALSE;
1759         if (0 > thma)
1760             return FALSE;
1761     }
1762     else
1763     {
1764         // do the trace with respect to x
1765         // 0 -> end has to stay in thmi -> thma
1766         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1767         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1768         if (trace_hits_box_a0 > trace_hits_box_a1)
1769             return FALSE;
1770     }
1771     return TRUE;
1772 }
1773
1774 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1775 {
1776     end -= start;
1777     thmi -= start;
1778     thma -= start;
1779     // now it is a trace from 0 to end
1780
1781     trace_hits_box_a0 = 0;
1782     trace_hits_box_a1 = 1;
1783
1784     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1785         return FALSE;
1786     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1787         return FALSE;
1788     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1789         return FALSE;
1790
1791     return TRUE;
1792 }
1793
1794 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1795 {
1796     return trace_hits_box(start, end, thmi - ma, thma - mi);
1797 }
1798
1799 float SUB_NoImpactCheck()
1800 {
1801         // zero hitcontents = this is not the real impact, but either the
1802         // mirror-impact of something hitting the projectile instead of the
1803         // projectile hitting the something, or a touchareagrid one. Neither of
1804         // these stop the projectile from moving, so...
1805         if(trace_dphitcontents == 0)
1806         {
1807                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1808                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1809                 checkclient();
1810         }
1811     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1812         return 1;
1813     if (other == world && self.size != '0 0 0')
1814     {
1815         vector tic;
1816         tic = self.velocity * sys_frametime;
1817         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1818         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1819         if (trace_fraction >= 1)
1820         {
1821             dprint("Odd... did not hit...?\n");
1822         }
1823         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1824         {
1825             dprint("Detected and prevented the sky-grapple bug.\n");
1826             return 1;
1827         }
1828     }
1829
1830     return 0;
1831 }
1832
1833 #define SUB_OwnerCheck() (other && (other == self.owner))
1834
1835 void RemoveGrapplingHook(entity pl);
1836 void W_Crylink_Dequeue(entity e);
1837 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1838 {
1839         if(SUB_OwnerCheck())
1840                 return TRUE;
1841         if(SUB_NoImpactCheck())
1842         {
1843                 if(self.classname == "grapplinghook")
1844                         RemoveGrapplingHook(self.realowner);
1845                 else if(self.classname == "spike")
1846                 {
1847                         W_Crylink_Dequeue(self);
1848                         remove(self);
1849                 }
1850                 else
1851                         remove(self);
1852                 return TRUE;
1853         }
1854         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1855                 UpdateCSQCProjectile(self);
1856         return FALSE;
1857 }
1858 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1859
1860 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1861 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1862
1863 void URI_Get_Callback(float id, float status, string data)
1864 {
1865         if(url_URI_Get_Callback(id, status, data))
1866         {
1867                 // handled
1868         }
1869         else if (id == URI_GET_DISCARD)
1870         {
1871                 // discard
1872         }
1873         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1874         {
1875                 // sv_cmd curl
1876                 Curl_URI_Get_Callback(id, status, data);
1877         }
1878         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1879         {
1880                 // online ban list
1881                 OnlineBanList_URI_Get_Callback(id, status, data);
1882         }
1883         else
1884         {
1885                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1886         }
1887 }
1888
1889 string uid2name(string myuid) {
1890         string s;
1891         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1892
1893         // FIXME remove this later after 0.6 release
1894         // convert old style broken records to correct style
1895         if(s == "")
1896         {
1897                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1898                 if(s != "")
1899                 {
1900                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1901                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1902                 }
1903         }
1904
1905         if(s == "")
1906                 s = "^1Unregistered Player";
1907         return s;
1908 }
1909
1910 float race_readTime(string map, float pos)
1911 {
1912         string rr;
1913         if(g_cts)
1914                 rr = CTS_RECORD;
1915         else
1916                 rr = RACE_RECORD;
1917
1918         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1919 }
1920
1921 string race_readUID(string map, float pos)
1922 {
1923         string rr;
1924         if(g_cts)
1925                 rr = CTS_RECORD;
1926         else
1927                 rr = RACE_RECORD;
1928
1929         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1930 }
1931
1932 float race_readPos(string map, float t) {
1933         float i;
1934         for (i = 1; i <= RANKINGS_CNT; ++i)
1935                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1936                         return i;
1937
1938         return 0; // pos is zero if unranked
1939 }
1940
1941 void race_writeTime(string map, float t, string myuid)
1942 {
1943         string rr;
1944         if(g_cts)
1945                 rr = CTS_RECORD;
1946         else
1947                 rr = RACE_RECORD;
1948
1949         float newpos;
1950         newpos = race_readPos(map, t);
1951
1952         float i, prevpos = 0;
1953         for(i = 1; i <= RANKINGS_CNT; ++i)
1954         {
1955                 if(race_readUID(map, i) == myuid)
1956                         prevpos = i;
1957         }
1958         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1959                 for (i = prevpos; i > newpos; --i) {
1960                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1961                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1962                 }
1963         } else { // player has no ranked record yet
1964                 for (i = RANKINGS_CNT; i > newpos; --i) {
1965                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1966                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1967                 }
1968         }
1969
1970         // store new time itself
1971         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1972         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1973 }
1974
1975 string race_readName(string map, float pos)
1976 {
1977         string rr;
1978         if(g_cts)
1979                 rr = CTS_RECORD;
1980         else
1981                 rr = RACE_RECORD;
1982
1983         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1984 }
1985
1986 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1987 {
1988     float m, i;
1989     vector start, org, delta, end, enddown, mstart;
1990     entity sp;
1991
1992     m = e.dphitcontentsmask;
1993     e.dphitcontentsmask = goodcontents | badcontents;
1994
1995     org = world.mins;
1996     delta = world.maxs - world.mins;
1997
1998     start = end = org;
1999
2000     for (i = 0; i < attempts; ++i)
2001     {
2002         start_x = org_x + random() * delta_x;
2003         start_y = org_y + random() * delta_y;
2004         start_z = org_z + random() * delta_z;
2005
2006         // rule 1: start inside world bounds, and outside
2007         // solid, and don't start from somewhere where you can
2008         // fall down to evil
2009         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2010         if (trace_fraction >= 1)
2011             continue;
2012         if (trace_startsolid)
2013             continue;
2014         if (trace_dphitcontents & badcontents)
2015             continue;
2016         if (trace_dphitq3surfaceflags & badsurfaceflags)
2017             continue;
2018
2019         // rule 2: if we are too high, lower the point
2020         if (trace_fraction * delta_z > maxaboveground)
2021             start = trace_endpos + '0 0 1' * maxaboveground;
2022         enddown = trace_endpos;
2023
2024         // rule 3: make sure we aren't outside the map. This only works
2025         // for somewhat well formed maps. A good rule of thumb is that
2026         // the map should have a convex outside hull.
2027         // these can be traceLINES as we already verified the starting box
2028         mstart = start + 0.5 * (e.mins + e.maxs);
2029         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2030         if (trace_fraction >= 1)
2031             continue;
2032         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2033         if (trace_fraction >= 1)
2034             continue;
2035         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2036         if (trace_fraction >= 1)
2037             continue;
2038         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2039         if (trace_fraction >= 1)
2040             continue;
2041         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2042         if (trace_fraction >= 1)
2043             continue;
2044
2045         // rule 4: we must "see" some spawnpoint
2046         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2047                 if(checkpvs(mstart, sp))
2048                         break;
2049         if(!sp)
2050         {
2051                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2052                         if(checkpvs(mstart, sp))
2053                                 break;
2054                 if(!sp)
2055                         continue;
2056         }
2057
2058         // find a random vector to "look at"
2059         end_x = org_x + random() * delta_x;
2060         end_y = org_y + random() * delta_y;
2061         end_z = org_z + random() * delta_z;
2062         end = start + normalize(end - start) * vlen(delta);
2063
2064         // rule 4: start TO end must not be too short
2065         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2066         if (trace_startsolid)
2067             continue;
2068         if (trace_fraction < minviewdistance / vlen(delta))
2069             continue;
2070
2071         // rule 5: don't want to look at sky
2072         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2073             continue;
2074
2075         // rule 6: we must not end up in trigger_hurt
2076         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2077             continue;
2078
2079         break;
2080     }
2081
2082     e.dphitcontentsmask = m;
2083
2084     if (i < attempts)
2085     {
2086         setorigin(e, start);
2087         e.angles = vectoangles(end - start);
2088         dprint("Needed ", ftos(i + 1), " attempts\n");
2089         return TRUE;
2090     }
2091     else
2092         return FALSE;
2093 }
2094
2095 float zcurveparticles_effectno;
2096 vector zcurveparticles_start;
2097 float zcurveparticles_spd;
2098
2099 void endzcurveparticles()
2100 {
2101         if(zcurveparticles_effectno)
2102         {
2103                 // terminator
2104                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2105         }
2106         zcurveparticles_effectno = 0;
2107 }
2108
2109 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2110 {
2111         spd = bound(0, floor(spd / 16), 32767);
2112         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2113         {
2114                 endzcurveparticles();
2115                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2116                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2117                 WriteShort(MSG_BROADCAST, effectno);
2118                 WriteCoord(MSG_BROADCAST, start_x);
2119                 WriteCoord(MSG_BROADCAST, start_y);
2120                 WriteCoord(MSG_BROADCAST, start_z);
2121                 zcurveparticles_effectno = effectno;
2122                 zcurveparticles_start = start;
2123         }
2124         else
2125                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2126         WriteCoord(MSG_BROADCAST, end_x);
2127         WriteCoord(MSG_BROADCAST, end_y);
2128         WriteCoord(MSG_BROADCAST, end_z);
2129         WriteCoord(MSG_BROADCAST, end_dz);
2130         zcurveparticles_spd = spd;
2131 }
2132
2133 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2134 {
2135         float end_dz;
2136         vector vecxy, velxy;
2137
2138         vecxy = end - start;
2139         vecxy_z = 0;
2140         velxy = vel;
2141         velxy_z = 0;
2142
2143         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2144         {
2145                 endzcurveparticles();
2146                 trailparticles(world, effectno, start, end);
2147                 return;
2148         }
2149
2150         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2151         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2152 }
2153
2154 void write_recordmarker(entity pl, float tstart, float dt)
2155 {
2156     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2157
2158     // also write a marker into demo files for demotc-race-record-extractor to find
2159     stuffcmd(pl,
2160              strcat(
2161                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2162                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2163 }
2164
2165 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2166 {
2167         switch(algn)
2168         {
2169                 default:
2170                 case 3: // right
2171                         break;
2172
2173                 case 4: // left
2174                         vecs_y = -vecs_y;
2175                         break;
2176
2177                 case 1:
2178                         if(allowcenter) // 2: allow center handedness
2179                         {
2180                                 // center
2181                                 vecs_y = 0;
2182                                 vecs_z -= 2;
2183                         }
2184                         else
2185                         {
2186                                 // right
2187                         }
2188                         break;
2189
2190                 case 2:
2191                         if(allowcenter) // 2: allow center handedness
2192                         {
2193                                 // center
2194                                 vecs_y = 0;
2195                                 vecs_z -= 2;
2196                         }
2197                         else
2198                         {
2199                                 // left
2200                                 vecs_y = -vecs_y;
2201                         }
2202                         break;
2203         }
2204         return vecs;
2205 }
2206
2207 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2208 {
2209         string s;
2210         vector v;
2211
2212         if (autocvar_g_shootfromeye)
2213         {
2214                 if (visual)
2215                 {
2216                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2217                         else { vecs_y = 0; vecs_z -= 2; }
2218                 }
2219                 else
2220                 {
2221                         vecs_y = 0;
2222                         vecs_z = 0;
2223                 }
2224         }
2225         else if (autocvar_g_shootfromcenter)
2226         {
2227                 vecs_y = 0;
2228                 vecs_z -= 2;
2229         }
2230         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2231         {
2232                 v = stov(s);
2233                 if (y_is_right)
2234                         v_y = -v_y;
2235                 if (v_x != 0)
2236                         vecs_x = v_x;
2237                 vecs_y = v_y;
2238                 vecs_z = v_z;
2239         }
2240         else if (autocvar_g_shootfromclient)
2241         {
2242                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2243         }
2244         return vecs;
2245 }
2246
2247 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2248 {
2249         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2250 }
2251
2252
2253 void attach_sameorigin(entity e, entity to, string tag)
2254 {
2255     vector org, t_forward, t_left, t_up, e_forward, e_up;
2256     float tagscale;
2257
2258     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2259     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2260     t_forward = v_forward * tagscale;
2261     t_left = v_right * -tagscale;
2262     t_up = v_up * tagscale;
2263
2264     e.origin_x = org * t_forward;
2265     e.origin_y = org * t_left;
2266     e.origin_z = org * t_up;
2267
2268     // current forward and up directions
2269     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2270                 e.angles = AnglesTransform_FromVAngles(e.angles);
2271         else
2272                 e.angles = AnglesTransform_FromAngles(e.angles);
2273     fixedmakevectors(e.angles);
2274
2275     // untransform forward, up!
2276     e_forward_x = v_forward * t_forward;
2277     e_forward_y = v_forward * t_left;
2278     e_forward_z = v_forward * t_up;
2279     e_up_x = v_up * t_forward;
2280     e_up_y = v_up * t_left;
2281     e_up_z = v_up * t_up;
2282
2283     e.angles = fixedvectoangles2(e_forward, e_up);
2284     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2285                 e.angles = AnglesTransform_ToVAngles(e.angles);
2286         else
2287                 e.angles = AnglesTransform_ToAngles(e.angles);
2288
2289     setattachment(e, to, tag);
2290     setorigin(e, e.origin);
2291 }
2292
2293 void detach_sameorigin(entity e)
2294 {
2295     vector org;
2296     org = gettaginfo(e, 0);
2297     e.angles = fixedvectoangles2(v_forward, v_up);
2298     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2299                 e.angles = AnglesTransform_ToVAngles(e.angles);
2300         else
2301                 e.angles = AnglesTransform_ToAngles(e.angles);
2302     setorigin(e, org);
2303     setattachment(e, world, "");
2304     setorigin(e, e.origin);
2305 }
2306
2307 void follow_sameorigin(entity e, entity to)
2308 {
2309     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2310     e.aiment = to; // make the hole follow bmodel
2311     e.punchangle = to.angles; // the original angles of bmodel
2312     e.view_ofs = e.origin - to.origin; // relative origin
2313     e.v_angle = e.angles - to.angles; // relative angles
2314 }
2315
2316 void unfollow_sameorigin(entity e)
2317 {
2318     e.movetype = MOVETYPE_NONE;
2319 }
2320
2321 entity gettaginfo_relative_ent;
2322 vector gettaginfo_relative(entity e, float tag)
2323 {
2324     if (!gettaginfo_relative_ent)
2325     {
2326         gettaginfo_relative_ent = spawn();
2327         gettaginfo_relative_ent.effects = EF_NODRAW;
2328     }
2329     gettaginfo_relative_ent.model = e.model;
2330     gettaginfo_relative_ent.modelindex = e.modelindex;
2331     gettaginfo_relative_ent.frame = e.frame;
2332     return gettaginfo(gettaginfo_relative_ent, tag);
2333 }
2334
2335 .float scale2;
2336
2337 float modeleffect_SendEntity(entity to, float sf)
2338 {
2339         float f;
2340         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2341
2342         f = 0;
2343         if(self.velocity != '0 0 0')
2344                 f |= 1;
2345         if(self.angles != '0 0 0')
2346                 f |= 2;
2347         if(self.avelocity != '0 0 0')
2348                 f |= 4;
2349
2350         WriteByte(MSG_ENTITY, f);
2351         WriteShort(MSG_ENTITY, self.modelindex);
2352         WriteByte(MSG_ENTITY, self.skin);
2353         WriteByte(MSG_ENTITY, self.frame);
2354         WriteCoord(MSG_ENTITY, self.origin_x);
2355         WriteCoord(MSG_ENTITY, self.origin_y);
2356         WriteCoord(MSG_ENTITY, self.origin_z);
2357         if(f & 1)
2358         {
2359                 WriteCoord(MSG_ENTITY, self.velocity_x);
2360                 WriteCoord(MSG_ENTITY, self.velocity_y);
2361                 WriteCoord(MSG_ENTITY, self.velocity_z);
2362         }
2363         if(f & 2)
2364         {
2365                 WriteCoord(MSG_ENTITY, self.angles_x);
2366                 WriteCoord(MSG_ENTITY, self.angles_y);
2367                 WriteCoord(MSG_ENTITY, self.angles_z);
2368         }
2369         if(f & 4)
2370         {
2371                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2372                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2373                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2374         }
2375         WriteShort(MSG_ENTITY, self.scale * 256.0);
2376         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2377         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2378         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2379         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2380
2381         return TRUE;
2382 }
2383
2384 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2385 {
2386         entity e;
2387         float sz;
2388         e = spawn();
2389         e.classname = "modeleffect";
2390         setmodel(e, m);
2391         e.frame = f;
2392         setorigin(e, o);
2393         e.velocity = v;
2394         e.angles = ang;
2395         e.avelocity = angv;
2396         e.alpha = a;
2397         e.teleport_time = t1;
2398         e.fade_time = t2;
2399         e.skin = s;
2400         if(s0 >= 0)
2401                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2402         else
2403                 e.scale = -s0;
2404         if(s2 >= 0)
2405                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2406         else
2407                 e.scale2 = -s2;
2408         sz = max(e.scale, e.scale2);
2409         setsize(e, e.mins * sz, e.maxs * sz);
2410         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2411 }
2412
2413 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2414 {
2415         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2416 }
2417
2418 float randombit(float bits)
2419 {
2420         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2421                 return bits;
2422
2423         float n, f, b, r;
2424
2425         r = random();
2426         b = 0;
2427         n = 0;
2428
2429         for(f = 1; f <= bits; f *= 2)
2430         {
2431                 if(bits & f)
2432                 {
2433                         ++n;
2434                         r *= n;
2435                         if(r <= 1)
2436                                 b = f;
2437                         else
2438                                 r = (r - 1) / (n - 1);
2439                 }
2440         }
2441
2442         return b;
2443 }
2444
2445 float randombits(float bits, float k, float error_return)
2446 {
2447         float r;
2448         r = 0;
2449         while(k > 0 && bits != r)
2450         {
2451                 r += randombit(bits - r);
2452                 --k;
2453         }
2454         if(error_return)
2455                 if(k > 0)
2456                         return -1; // all
2457         return r;
2458 }
2459
2460 void randombit_test(float bits, float iter)
2461 {
2462         while(iter > 0)
2463         {
2464                 print(ftos(randombit(bits)), "\n");
2465                 --iter;
2466         }
2467 }
2468
2469 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2470 {
2471         if(halflifedist > 0)
2472                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2473         else if(halflifedist < 0)
2474                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2475         else
2476                 return 1;
2477 }
2478
2479
2480
2481
2482 #ifdef RELEASE
2483 #define cvar_string_normal builtin_cvar_string
2484 #define cvar_normal builtin_cvar
2485 #else
2486 string cvar_string_normal(string n)
2487 {
2488         if not(cvar_type(n) & 1)
2489                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2490         return builtin_cvar_string(n);
2491 }
2492
2493 float cvar_normal(string n)
2494 {
2495         return stof(cvar_string_normal(n));
2496 }
2497 #endif
2498 #define cvar_set_normal builtin_cvar_set
2499
2500 void defer_think()
2501 {
2502     entity oself;
2503
2504     oself           = self;
2505     self            = self.owner;
2506     oself.think     = SUB_Remove;
2507     oself.nextthink = time;
2508
2509     oself.use();
2510 }
2511
2512 /*
2513     Execute func() after time + fdelay.
2514     self when func is executed = self when defer is called
2515 */
2516 void defer(float fdelay, void() func)
2517 {
2518     entity e;
2519
2520     e           = spawn();
2521     e.owner     = self;
2522     e.use       = func;
2523     e.think     = defer_think;
2524     e.nextthink = time + fdelay;
2525 }
2526
2527 .string aiment_classname;
2528 .float aiment_deadflag;
2529 void SetMovetypeFollow(entity ent, entity e)
2530 {
2531         // FIXME this may not be warpzone aware
2532         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2533         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2534         ent.aiment = e; // make the hole follow bmodel
2535         ent.punchangle = e.angles; // the original angles of bmodel
2536         ent.view_ofs = ent.origin - e.origin; // relative origin
2537         ent.v_angle = ent.angles - e.angles; // relative angles
2538         ent.aiment_classname = strzone(e.classname);
2539         ent.aiment_deadflag = e.deadflag;
2540 }
2541 void UnsetMovetypeFollow(entity ent)
2542 {
2543         ent.movetype = MOVETYPE_FLY;
2544         PROJECTILE_MAKETRIGGER(ent);
2545         ent.aiment = world;
2546 }
2547 float LostMovetypeFollow(entity ent)
2548 {
2549 /*
2550         if(ent.movetype != MOVETYPE_FOLLOW)
2551                 if(ent.aiment)
2552                         error("???");
2553 */
2554         if(ent.aiment)
2555         {
2556                 if(ent.aiment.classname != ent.aiment_classname)
2557                         return 1;
2558                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2559                         return 1;
2560         }
2561         return 0;
2562 }
2563
2564 float isPushable(entity e)
2565 {
2566         if(e.iscreature)
2567                 return TRUE;
2568         if(e.pushable)
2569                 return TRUE;
2570         switch(e.classname)
2571         {
2572                 case "body":
2573                 case "droppedweapon":
2574                 case "keepawayball":
2575                 case "nexball_basketball":
2576                 case "nexball_football":
2577                         return TRUE;
2578                 case "bullet": // antilagged bullets can't hit this either
2579                         return FALSE;
2580         }
2581         if (e.projectiledeathtype)
2582                 return TRUE;
2583         return FALSE;
2584 }