qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (autocvar_r_showbboxes)
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471
 472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 473                 p = p + strlen(replacement);
 474         }
 475         return msg;
 476 }
 477
 478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 479         return (value == 0) ? FALSE : TRUE;
 480 }
 481
 482 /*
 483 =============
 484 GetCvars
 485 =============
 486 Called with:
 487   0:  sends the request
 488   >0: receives a cvar from name=argv(f) value=argv(f+1)
 489 */
 490 void GetCvars_handleString(string thisname, float f, .string field, string name)
 491 {
 492         if (f < 0)
 493         {
 494                 if (self.field)
 495                         strunzone(self.field);
 496                 self.field = string_null;
 497         }
 498         else if (f > 0)
 499         {
 500                 if (thisname == name)
 501                 {
 502                         if (self.field)
 503                                 strunzone(self.field);
 504                         self.field = strzone(argv(f + 1));
 505                 }
 506         }
 507         else
 508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 509 }
 510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 511 {
 512         GetCvars_handleString(thisname, f, field, name);
 513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 514                 if (thisname == name)
 515                 {
 516                         string s;
 517                         s = func(strcat1(self.field));
 518                         if (s != self.field)
 519                         {
 520                                 strunzone(self.field);
 521                                 self.field = strzone(s);
 522                         }
 523                 }
 524 }
 525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 526 {
 527         if (f < 0)
 528         {
 529         }
 530         else if (f > 0)
 531         {
 532                 if (thisname == name)
 533                         self.field = stof(argv(f + 1));
 534         }
 535         else
 536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 537 }
 538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 539 {
 540         if (f < 0)
 541         {
 542         }
 543         else if (f > 0)
 544         {
 545                 if (thisname == name)
 546                 {
 547                         if(!self.field)
 548                         {
 549                                 self.field = stof(argv(f + 1));
 550                                 if(!self.field)
 551                                         self.field = -1;
 552                         }
 553                 }
 554         }
 555         else
 556         {
 557                 if(!self.field)
 558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559         }
 560 }
 561 float w_getbestweapon(entity e);
 562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 563 {
 564         string o;
 565         o = W_FixWeaponOrder_ForceComplete(wo);
 566         if(self.weaponorder_byimpulse)
 567         {
 568                 strunzone(self.weaponorder_byimpulse);
 569                 self.weaponorder_byimpulse = string_null;
 570         }
 571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 572         return o;
 573 }
 574 void GetCvars(float f)
 575 {
 576         string s;
 577
 578         if (f > 0)
 579                 s = strcat1(argv(f));
 580
 581         get_cvars_f = f;
 582         get_cvars_s = s;
 583         MUTATOR_CALLHOOK(GetCvars);
 584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 609
 610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 612
 613 #ifdef ALLOW_FORCEMODELS
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 616 #endif
 617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 619
 620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 621         if (f > 0)
 622         {
 623                 if (s == "cl_weaponpriority")
 624                         self.switchweapon = w_getbestweapon(self);
 625         }
 626 }
 627
 628 float fexists(string f)
 629 {
 630     float fh;
 631     fh = fopen(f, FILE_READ);
 632     if (fh < 0)
 633         return FALSE;
 634     fclose(fh);
 635     return TRUE;
 636 }
 637
 638 void backtrace(string msg)
 639 {
 640     float dev, war;
 641     dev = autocvar_developer;
 642     war = autocvar_prvm_backtraceforwarnings;
 643     cvar_set("developer", "1");
 644     cvar_set("prvm_backtraceforwarnings", "1");
 645     print("\n");
 646     print("--- CUT HERE ---\nWARNING: ");
 647     print(msg);
 648     print("\n");
 649     remove(world); // isn't there any better way to cause a backtrace?
 650     print("\n--- CUT UNTIL HERE ---\n");
 651     cvar_set("developer", ftos(dev));
 652     cvar_set("prvm_backtraceforwarnings", ftos(war));
 653 }
 654
 655 string Team_ColorCode(float teamid)
 656 {
 657     if (teamid == COLOR_TEAM1)
 658         return "^1";
 659     else if (teamid == COLOR_TEAM2)
 660         return "^4";
 661     else if (teamid == COLOR_TEAM3)
 662         return "^3";
 663     else if (teamid == COLOR_TEAM4)
 664         return "^6";
 665     else
 666         return "^7";
 667 }
 668
 669 string Team_ColorName(float t)
 670 {
 671     // fixme: Search for team entities and get their .netname's!
 672     if (t == COLOR_TEAM1)
 673         return "Red";
 674     if (t == COLOR_TEAM2)
 675         return "Blue";
 676     if (t == COLOR_TEAM3)
 677         return "Yellow";
 678     if (t == COLOR_TEAM4)
 679         return "Pink";
 680     return "Neutral";
 681 }
 682
 683 string Team_ColorNameLowerCase(float t)
 684 {
 685     // fixme: Search for team entities and get their .netname's!
 686     if (t == COLOR_TEAM1)
 687         return "red";
 688     if (t == COLOR_TEAM2)
 689         return "blue";
 690     if (t == COLOR_TEAM3)
 691         return "yellow";
 692     if (t == COLOR_TEAM4)
 693         return "pink";
 694     return "neutral";
 695 }
 696
 697 float ColourToNumber(string team_colour)
 698 {
 699         if (team_colour == "red")
 700                 return COLOR_TEAM1;
 701
 702         if (team_colour == "blue")
 703                 return COLOR_TEAM2;
 704
 705         if (team_colour == "yellow")
 706                 return COLOR_TEAM3;
 707
 708         if (team_colour == "pink")
 709                 return COLOR_TEAM4;
 710
 711         if (team_colour == "auto")
 712                 return 0;
 713
 714         return -1;
 715 }
 716
 717 float NumberToTeamNumber(float number)
 718 {
 719         if (number == 1)
 720                 return COLOR_TEAM1;
 721
 722         if (number == 2)
 723                 return COLOR_TEAM2;
 724
 725         if (number == 3)
 726                 return COLOR_TEAM3;
 727
 728         if (number == 4)
 729                 return COLOR_TEAM4;
 730
 731         return -1;
 732 }
 733
 734 #define CENTERPRIO_POINT 1
 735 #define CENTERPRIO_SPAM 2
 736 #define CENTERPRIO_VOTE 4
 737 #define CENTERPRIO_NORMAL 5
 738 #define CENTERPRIO_SHIELDING 7
 739 #define CENTERPRIO_MAPVOTE 9
 740 #define CENTERPRIO_IDLEKICK 50
 741 #define CENTERPRIO_ADMIN 99
 742 .float centerprint_priority;
 743 .float centerprint_expires;
 744 void centerprint_atprio(entity e, float prio, string s)
 745 {
 746     if (intermission_running)
 747         if (prio < CENTERPRIO_MAPVOTE)
 748             return;
 749     if (time > e.centerprint_expires)
 750         e.centerprint_priority = 0;
 751     if (prio >= e.centerprint_priority)
 752     {
 753         e.centerprint_priority = prio;
 754         if (timeoutStatus == 2)
 755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 756         else
 757             e.centerprint_expires = time + e.cvar_scr_centertime;
 758         centerprint_builtin(e, s);
 759     }
 760 }
 761 void centerprint_expire(entity e, float prio)
 762 {
 763     if (prio == e.centerprint_priority)
 764     {
 765         e.centerprint_priority = 0;
 766         centerprint_builtin(e, "");
 767     }
 768 }
 769 void centerprint(entity e, string s)
 770 {
 771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 772 }
 773
 774 // decolorizes and team colors the player name when needed
 775 string playername(entity p)
 776 {
 777     string t;
 778     if (teams_matter && !intermission_running && p.classname == "player")
 779     {
 780         t = Team_ColorCode(p.team);
 781         return strcat(t, strdecolorize(p.netname));
 782     }
 783     else
 784         return p.netname;
 785 }
 786
 787 vector randompos(vector m1, vector m2)
 788 {
 789     local vector v;
 790     m2 = m2 - m1;
 791     v_x = m2_x * random() + m1_x;
 792     v_y = m2_y * random() + m1_y;
 793     v_z = m2_z * random() + m1_z;
 794     return  v;
 795 };
 796
 797 //#NO AUTOCVARS START
 798
 799 float g_pickup_shells;
 800 float g_pickup_shells_max;
 801 float g_pickup_nails;
 802 float g_pickup_nails_max;
 803 float g_pickup_rockets;
 804 float g_pickup_rockets_max;
 805 float g_pickup_cells;
 806 float g_pickup_cells_max;
 807 float g_pickup_fuel;
 808 float g_pickup_fuel_jetpack;
 809 float g_pickup_fuel_max;
 810 float g_pickup_armorsmall;
 811 float g_pickup_armorsmall_max;
 812 float g_pickup_armorsmall_anyway;
 813 float g_pickup_armormedium;
 814 float g_pickup_armormedium_max;
 815 float g_pickup_armormedium_anyway;
 816 float g_pickup_armorbig;
 817 float g_pickup_armorbig_max;
 818 float g_pickup_armorbig_anyway;
 819 float g_pickup_armorlarge;
 820 float g_pickup_armorlarge_max;
 821 float g_pickup_armorlarge_anyway;
 822 float g_pickup_healthsmall;
 823 float g_pickup_healthsmall_max;
 824 float g_pickup_healthsmall_anyway;
 825 float g_pickup_healthmedium;
 826 float g_pickup_healthmedium_max;
 827 float g_pickup_healthmedium_anyway;
 828 float g_pickup_healthlarge;
 829 float g_pickup_healthlarge_max;
 830 float g_pickup_healthlarge_anyway;
 831 float g_pickup_healthmega;
 832 float g_pickup_healthmega_max;
 833 float g_pickup_healthmega_anyway;
 834 float g_pickup_ammo_anyway;
 835 float g_pickup_weapons_anyway;
 836 float g_weaponarena;
 837 float g_weaponarena_random;
 838 float g_weaponarena_random_with_laser;
 839 string g_weaponarena_list;
 840 float g_weaponspeedfactor;
 841 float g_weaponratefactor;
 842 float g_weapondamagefactor;
 843 float g_weaponforcefactor;
 844 float g_weaponspreadfactor;
 845
 846 float start_weapons;
 847 float start_items;
 848 float start_ammo_shells;
 849 float start_ammo_nails;
 850 float start_ammo_rockets;
 851 float start_ammo_cells;
 852 float start_ammo_fuel;
 853 float start_health;
 854 float start_armorvalue;
 855 float warmup_start_weapons;
 856 float warmup_start_ammo_shells;
 857 float warmup_start_ammo_nails;
 858 float warmup_start_ammo_rockets;
 859 float warmup_start_ammo_cells;
 860 float warmup_start_ammo_fuel;
 861 float warmup_start_health;
 862 float warmup_start_armorvalue;
 863 float g_weapon_stay;
 864 float g_ghost_items;
 865
 866 entity get_weaponinfo(float w);
 867
 868 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 869 {
 870         var float i = weaponinfo.weapon;
 871
 872         if (!i)
 873                 return 0;
 874
 875         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 876
 877         if (t < 0) // "default" weapon selection
 878         {
 879                 if (g_lms || g_ca || allguns)
 880                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 881                 else if(t < -1)
 882                         t = 0;
 883                 else if (g_race)
 884                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 885                 else if (g_cts)
 886                         t = (i == WEP_SHOTGUN);
 887                 else if (g_nexball)
 888                         t = 0; // weapon is set a few lines later
 889                 else
 890                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 891                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 892                         t |= (i == WEP_HOOK);
 893         }
 894
 895         // we cannot disable porto in Nexball, we must force it
 896         if(g_nexball && i == WEP_PORTO)
 897                 t = 1;
 898
 899         return t;
 900 }
 901
 902 void readplayerstartcvars()
 903 {
 904         entity e;
 905         float i, j, t;
 906         string s;
 907
 908         // initialize starting values for players
 909         start_weapons = 0;
 910         start_items = 0;
 911         start_ammo_shells = 0;
 912         start_ammo_nails = 0;
 913         start_ammo_rockets = 0;
 914         start_ammo_cells = 0;
 915         start_health = cvar("g_balance_health_start");
 916         start_armorvalue = cvar("g_balance_armor_start");
 917
 918         g_weaponarena = 0;
 919         s = cvar_string("g_weaponarena");
 920         if (s == "0")
 921         {
 922         }
 923         else if (s == "all")
 924         {
 925                 g_weaponarena_list = "All Weapons";
 926                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 927                 {
 928                         e = get_weaponinfo(j);
 929                         g_weaponarena |= e.weapons;
 930                         weapon_action(e.weapon, WR_PRECACHE);
 931                 }
 932         }
 933         else if (s == "most")
 934         {
 935                 g_weaponarena_list = "Most Weapons";
 936                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 937                 {
 938                         e = get_weaponinfo(j);
 939                         if (e.spawnflags & WEP_FLAG_NORMAL)
 940                         {
 941                                 g_weaponarena |= e.weapons;
 942                                 weapon_action(e.weapon, WR_PRECACHE);
 943                         }
 944                 }
 945         }
 946         else if (s == "none")
 947         {
 948                 g_weaponarena_list = "No Weapons";
 949                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 950         }
 951         else
 952         {
 953                 t = tokenize_console(s);
 954                 g_weaponarena_list = "";
 955                 for (i = 0; i < t; ++i)
 956                 {
 957                         s = argv(i);
 958                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 959                         {
 960                                 e = get_weaponinfo(j);
 961                                 if (e.netname == s)
 962                                 {
 963                                         g_weaponarena |= e.weapons;
 964                                         weapon_action(e.weapon, WR_PRECACHE);
 965                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 966                                         break;
 967                                 }
 968                         }
 969                         if (j > WEP_LAST)
 970                         {
 971                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 972                         }
 973                 }
 974                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 975         }
 976
 977         if(g_weaponarena)
 978                 g_weaponarena_random = cvar("g_weaponarena_random");
 979         else
 980                 g_weaponarena_random = 0;
 981         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 982
 983         if (g_weaponarena)
 984         {
 985                 start_weapons = g_weaponarena;
 986                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
 987                         start_ammo_rockets = 999;
 988                 if (g_weaponarena & WEPBIT_SHOTGUN)
 989                         start_ammo_shells = 999;
 990                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
 991                         start_ammo_cells = 999;
 992                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
 993                         start_ammo_nails = 999;
 994                 if (g_weaponarena & WEPBIT_HOOK)
 995                         start_ammo_fuel = 999;
 996                 start_items |= IT_UNLIMITED_AMMO;
 997         }
 998         else if (g_minstagib)
 999         {
1000                 start_health = 100;
1001                 start_armorvalue = 0;
1002                 start_weapons = WEPBIT_MINSTANEX;
1003                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1004                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1005                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1006                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1007
1008                 if (g_minstagib_invis_alpha <= 0)
1009                         g_minstagib_invis_alpha = -1;
1010         }
1011         else
1012         {
1013                 if (g_lms || g_ca)
1014                 {
1015                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1016                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1017                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1018                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1019                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1020                         start_health = cvar("g_lms_start_health");
1021                         start_armorvalue = cvar("g_lms_start_armor");
1022                 }
1023                 else
1024                 {
1025                         start_ammo_shells = cvar("g_start_ammo_shells");
1026                         start_ammo_nails = cvar("g_start_ammo_nails");
1027                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1028                         start_ammo_cells = cvar("g_start_ammo_cells");
1029                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1030                 }
1031
1032                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1033                 {
1034                         e = get_weaponinfo(i);
1035                         if(want_weapon("g_start_weapon_", e, FALSE))
1036                                 start_weapons |= e.weapons;
1037                 }
1038         }
1039
1040         if (inWarmupStage)
1041         {
1042                 warmup_start_ammo_shells = start_ammo_shells;
1043                 warmup_start_ammo_nails = start_ammo_nails;
1044                 warmup_start_ammo_rockets = start_ammo_rockets;
1045                 warmup_start_ammo_cells = start_ammo_cells;
1046                 warmup_start_ammo_fuel = start_ammo_fuel;
1047                 warmup_start_health = start_health;
1048                 warmup_start_armorvalue = start_armorvalue;
1049                 warmup_start_weapons = start_weapons;
1050
1051                 if (!g_weaponarena && !g_minstagib && !g_ca)
1052                 {
1053                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1054                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1055                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1056                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1057                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1058                         warmup_start_health = cvar("g_warmup_start_health");
1059                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1060                         warmup_start_weapons = 0;
1061                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1062                         {
1063                                 e = get_weaponinfo(i);
1064                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1065                                         warmup_start_weapons |= e.weapons;
1066                         }
1067                 }
1068         }
1069
1070         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1071         {
1072                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1073                 start_items |= IT_FUEL_REGEN;
1074                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1075                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1076         }
1077
1078         if(!cvar("g_use_ammunition"))
1079         {
1080                 start_ammo_shells = cvar("g_pickup_shells_max");
1081                 start_ammo_nails = cvar("g_pickup_nails_max");
1082                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1083                 start_ammo_cells = cvar("g_pickup_cells_max");
1084                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1085                 start_items |= IT_UNLIMITED_AMMO;
1086                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1087                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1088                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1089                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1090                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1091                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1092         }
1093
1094         if (g_jetpack)
1095                 start_items |= IT_JETPACK;
1096
1097         if (g_weapon_stay == 2)
1098         {
1099                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1100                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1101                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1102                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1103                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1104                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1105                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1106                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1107                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1108                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1109         }
1110
1111         MUTATOR_CALLHOOK(SetStartItems);
1112
1113         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1114         {
1115                 e = get_weaponinfo(i);
1116                 if(e.weapons & (start_weapons | warmup_start_weapons))
1117                         weapon_action(e.weapon, WR_PRECACHE);
1118         }
1119
1120         start_ammo_shells = max(0, start_ammo_shells);
1121         start_ammo_nails = max(0, start_ammo_nails);
1122         start_ammo_cells = max(0, start_ammo_cells);
1123         start_ammo_rockets = max(0, start_ammo_rockets);
1124         start_ammo_fuel = max(0, start_ammo_fuel);
1125
1126         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1127         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1128         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1129         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1130         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1131 }
1132
1133 float g_bugrigs;
1134 float g_bugrigs_planar_movement;
1135 float g_bugrigs_planar_movement_car_jumping;
1136 float g_bugrigs_reverse_spinning;
1137 float g_bugrigs_reverse_speeding;
1138 float g_bugrigs_reverse_stopping;
1139 float g_bugrigs_air_steering;
1140 float g_bugrigs_angle_smoothing;
1141 float g_bugrigs_friction_floor;
1142 float g_bugrigs_friction_brake;
1143 float g_bugrigs_friction_air;
1144 float g_bugrigs_accel;
1145 float g_bugrigs_speed_ref;
1146 float g_bugrigs_speed_pow;
1147 float g_bugrigs_steer;
1148
1149 float g_touchexplode;
1150 float g_touchexplode_radius;
1151 float g_touchexplode_damage;
1152 float g_touchexplode_edgedamage;
1153 float g_touchexplode_force;
1154
1155 float sv_autotaunt;
1156 float sv_taunt;
1157
1158 float sv_pitch_min;
1159 float sv_pitch_max;
1160 float sv_pitch_fixyaw;
1161
1162 void readlevelcvars(void)
1163 {
1164         // first load all the mutators
1165         if(cvar("g_nix"))
1166                 MUTATOR_ADD(mutator_nix);
1167         if(cvar("g_dodging"))
1168                 MUTATOR_ADD(mutator_dodging);
1169         if(cvar("g_rocket_flying"))
1170                 MUTATOR_ADD(mutator_rocketflying);
1171         if(cvar("g_vampire"))
1172                 MUTATOR_ADD(mutator_vampire);
1173
1174         if(cvar("sv_allow_fullbright"))
1175                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1176
1177     g_bugrigs = cvar("g_bugrigs");
1178     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1179     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1180     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1181     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1182     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1183     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1184     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1185     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1186     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1187     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1188     g_bugrigs_accel = cvar("g_bugrigs_accel");
1189     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1190     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1191     g_bugrigs_steer = cvar("g_bugrigs_steer");
1192
1193     g_touchexplode = cvar("g_touchexplode");
1194     g_touchexplode_radius = cvar("g_touchexplode_radius");
1195     g_touchexplode_damage = cvar("g_touchexplode_damage");
1196     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1197     g_touchexplode_force = cvar("g_touchexplode_force");
1198
1199 #ifdef ALLOW_FORCEMODELS
1200         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1201 #endif
1202         sv_loddistance1 = cvar("sv_loddistance1");
1203         sv_loddistance2 = cvar("sv_loddistance2");
1204
1205         if(sv_loddistance2 <= sv_loddistance1)
1206                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1207
1208         sv_clones = cvar("sv_clones");
1209         sv_gentle = cvar("sv_gentle");
1210         sv_foginterval = cvar("sv_foginterval");
1211         g_cloaked = cvar("g_cloaked");
1212         g_jump_grunt = cvar("g_jump_grunt");
1213         g_footsteps = cvar("g_footsteps");
1214         g_grappling_hook = cvar("g_grappling_hook");
1215         g_jetpack = cvar("g_jetpack");
1216         g_midair = cvar("g_midair");
1217         g_minstagib = cvar("g_minstagib");
1218         g_norecoil = cvar("g_norecoil");
1219         g_bloodloss = cvar("g_bloodloss");
1220         sv_maxidle = cvar("sv_maxidle");
1221         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1222         sv_pogostick = cvar("sv_pogostick");
1223         g_ctf_reverse = cvar("g_ctf_reverse");
1224         sv_autotaunt = cvar("sv_autotaunt");
1225         sv_taunt = cvar("sv_taunt");
1226
1227         inWarmupStage = cvar("g_warmup");
1228         g_warmup_limit = cvar("g_warmup_limit");
1229         g_warmup_allguns = cvar("g_warmup_allguns");
1230         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1231
1232         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1233                 inWarmupStage = 0; // these modes cannot work together, sorry
1234
1235         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1236         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1237         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1238         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1239         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1240         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1241         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1242         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1243         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1244         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1245         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1246         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1247
1248         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1249         g_weaponratefactor = cvar("g_weaponratefactor");
1250         g_weapondamagefactor = cvar("g_weapondamagefactor");
1251         g_weaponforcefactor = cvar("g_weaponforcefactor");
1252         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1253
1254         g_pickup_shells = cvar("g_pickup_shells");
1255         g_pickup_shells_max = cvar("g_pickup_shells_max");
1256         g_pickup_nails = cvar("g_pickup_nails");
1257         g_pickup_nails_max = cvar("g_pickup_nails_max");
1258         g_pickup_rockets = cvar("g_pickup_rockets");
1259         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1260         g_pickup_cells = cvar("g_pickup_cells");
1261         g_pickup_cells_max = cvar("g_pickup_cells_max");
1262         g_pickup_fuel = cvar("g_pickup_fuel");
1263         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1264         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1265         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1266         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1267         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1268         g_pickup_armormedium = cvar("g_pickup_armormedium");
1269         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1270         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1271         g_pickup_armorbig = cvar("g_pickup_armorbig");
1272         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1273         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1274         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1275         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1276         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1277         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1278         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1279         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1280         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1281         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1282         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1283         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1284         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1285         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1286         g_pickup_healthmega = cvar("g_pickup_healthmega");
1287         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1288         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1289
1290         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1291         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1292
1293         g_pinata = cvar("g_pinata");
1294
1295         g_weapon_stay = cvar("g_weapon_stay");
1296
1297         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1298                 g_weapon_stay = 1;
1299
1300         if (!g_weapon_stay && g_cts)
1301                 g_weapon_stay = 1;
1302
1303         g_ghost_items = cvar("g_ghost_items");
1304
1305         if(g_ghost_items >= 1)
1306                 g_ghost_items = 0.25; // default alpha value
1307
1308         if not(inWarmupStage && !g_ca)
1309                 game_starttime = cvar("g_start_delay");
1310
1311         sv_pitch_min = cvar("sv_pitch_min");
1312         sv_pitch_max = cvar("sv_pitch_max");
1313         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1314
1315         readplayerstartcvars();
1316 }
1317
1318 //#NO AUTOCVARS END
1319
1320 // Sound functions
1321 string precache_sound (string s) = #19;
1322 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1323 float precache_sound_index (string s) = #19;
1324
1325 #define SND_VOLUME      1
1326 #define SND_ATTENUATION 2
1327 #define SND_LARGEENTITY 8
1328 #define SND_LARGESOUND  16
1329
1330 float sound_allowed(float dest, entity e)
1331 {
1332     // sounds from world may always pass
1333     for (;;)
1334     {
1335         if (e.classname == "body")
1336             e = e.enemy;
1337         if (e.owner && e.owner != e)
1338             e = e.owner;
1339         else
1340             break;
1341     }
1342     // sounds to self may always pass
1343     if (dest == MSG_ONE)
1344         if (e == msg_entity)
1345             return TRUE;
1346     // sounds by players can be removed
1347     if (autocvar_bot_sound_monopoly)
1348         if (clienttype(e) == CLIENTTYPE_REAL)
1349             return FALSE;
1350     // anything else may pass
1351     return TRUE;
1352 }
1353
1354 void sound(entity e, float chan, string samp, float vol, float atten)
1355 {
1356     if (!sound_allowed(MSG_BROADCAST, e))
1357         return;
1358     sound_builtin(e, chan, samp, vol, atten);
1359 }
1360 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1361 {
1362     float entno, idx;
1363
1364     if (!sound_allowed(dest, e))
1365         return;
1366
1367     entno = num_for_edict(e);
1368     idx = precache_sound_index(samp);
1369
1370     float sflags;
1371     sflags = 0;
1372
1373     atten = floor(atten * 64);
1374     vol = floor(vol * 255);
1375
1376     if (vol != 255)
1377         sflags |= SND_VOLUME;
1378     if (atten != 64)
1379         sflags |= SND_ATTENUATION;
1380     if (entno >= 8192)
1381         sflags |= SND_LARGEENTITY;
1382     if (idx >= 256)
1383         sflags |= SND_LARGESOUND;
1384
1385     WriteByte(dest, SVC_SOUND);
1386     WriteByte(dest, sflags);
1387     if (sflags & SND_VOLUME)
1388         WriteByte(dest, vol);
1389     if (sflags & SND_ATTENUATION)
1390         WriteByte(dest, atten);
1391     if (sflags & SND_LARGEENTITY)
1392     {
1393         WriteShort(dest, entno);
1394         WriteByte(dest, chan);
1395     }
1396     else
1397     {
1398         WriteShort(dest, entno * 8 + chan);
1399     }
1400     if (sflags & SND_LARGESOUND)
1401         WriteShort(dest, idx);
1402     else
1403         WriteByte(dest, idx);
1404
1405     WriteCoord(dest, o_x);
1406     WriteCoord(dest, o_y);
1407     WriteCoord(dest, o_z);
1408 }
1409 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1410 {
1411     vector o;
1412
1413     if (!sound_allowed(dest, e))
1414         return;
1415
1416     o = e.origin + 0.5 * (e.mins + e.maxs);
1417     soundtoat(dest, e, o, chan, samp, vol, atten);
1418 }
1419 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1420 {
1421     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1422 }
1423 void stopsoundto(float dest, entity e, float chan)
1424 {
1425     float entno;
1426
1427     if (!sound_allowed(dest, e))
1428         return;
1429
1430     entno = num_for_edict(e);
1431
1432     if (entno >= 8192)
1433     {
1434         float idx, sflags;
1435         idx = precache_sound_index("misc/null.wav");
1436         sflags = SND_LARGEENTITY;
1437         if (idx >= 256)
1438             sflags |= SND_LARGESOUND;
1439         WriteByte(dest, SVC_SOUND);
1440         WriteByte(dest, sflags);
1441         WriteShort(dest, entno);
1442         WriteByte(dest, chan);
1443         if (sflags & SND_LARGESOUND)
1444             WriteShort(dest, idx);
1445         else
1446             WriteByte(dest, idx);
1447         WriteCoord(dest, e.origin_x);
1448         WriteCoord(dest, e.origin_y);
1449         WriteCoord(dest, e.origin_z);
1450     }
1451     else
1452     {
1453         WriteByte(dest, SVC_STOPSOUND);
1454         WriteShort(dest, entno * 8 + chan);
1455     }
1456 }
1457 void stopsound(entity e, float chan)
1458 {
1459     if (!sound_allowed(MSG_BROADCAST, e))
1460         return;
1461
1462     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1463     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1464 }
1465
1466 void play2(entity e, string filename)
1467 {
1468     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1469     msg_entity = e;
1470     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1471 }
1472
1473 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1474 .float spamtime;
1475 float spamsound(entity e, float chan, string samp, float vol, float atten)
1476 {
1477     if (!sound_allowed(MSG_BROADCAST, e))
1478         return FALSE;
1479
1480     if (time > e.spamtime)
1481     {
1482         e.spamtime = time;
1483         sound(e, chan, samp, vol, atten);
1484         return TRUE;
1485     }
1486     return FALSE;
1487 }
1488
1489 void play2team(float t, string filename)
1490 {
1491     local entity head;
1492
1493     if (autocvar_bot_sound_monopoly)
1494         return;
1495
1496     FOR_EACH_REALPLAYER(head)
1497     {
1498         if (head.team == t)
1499             play2(head, filename);
1500     }
1501 }
1502
1503 void play2all(string samp)
1504 {
1505     if (autocvar_bot_sound_monopoly)
1506         return;
1507
1508     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1509 }
1510
1511 void PrecachePlayerSounds(string f);
1512 void precache_playermodel(string m)
1513 {
1514         float globhandle, i, n;
1515         string f;
1516
1517         if(substring(m, -9,5) == "_lod1")
1518                 return;
1519         if(substring(m, -9,5) == "_lod2")
1520                 return;
1521         precache_model(m);
1522         if(sv_loddistance1)
1523         {
1524                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1525                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1526         }
1527
1528         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1529         if (globhandle < 0)
1530                 return;
1531         n = search_getsize(globhandle);
1532         for (i = 0; i < n; ++i)
1533         {
1534                 //print(search_getfilename(globhandle, i), "\n");
1535                 f = search_getfilename(globhandle, i);
1536                 PrecachePlayerSounds(f);
1537         }
1538         search_end(globhandle);
1539 }
1540 void precache_all_playermodels(string pattern)
1541 {
1542         float globhandle, i, n;
1543         string f;
1544
1545         globhandle = search_begin(pattern, TRUE, FALSE);
1546         if (globhandle < 0)
1547                 return;
1548         n = search_getsize(globhandle);
1549         for (i = 0; i < n; ++i)
1550         {
1551                 //print(search_getfilename(globhandle, i), "\n");
1552                 f = search_getfilename(globhandle, i);
1553                 precache_playermodel(f);
1554         }
1555         search_end(globhandle);
1556 }
1557
1558 void precache()
1559 {
1560     // gamemode related things
1561     precache_model ("models/misc/chatbubble.spr");
1562     precache_model ("models/misc/teambubble.spr");
1563     if (g_runematch)
1564     {
1565         precache_model ("models/runematch/curse.mdl");
1566         precache_model ("models/runematch/rune.mdl");
1567     }
1568
1569 #ifdef TTURRETS_ENABLED
1570     if (autocvar_g_turrets)
1571         turrets_precash();
1572 #endif
1573
1574     // Precache all player models if desired
1575     if (autocvar_sv_precacheplayermodels)
1576     {
1577         PrecachePlayerSounds("sound/player/default.sounds");
1578         precache_all_playermodels("models/player/*.zym");
1579         precache_all_playermodels("models/player/*.dpm");
1580         precache_all_playermodels("models/player/*.md3");
1581         precache_all_playermodels("models/player/*.psk");
1582         precache_all_playermodels("models/player/*.iqm");
1583     }
1584
1585     if (autocvar_sv_defaultcharacter)
1586     {
1587         string s;
1588         s = autocvar_sv_defaultplayermodel_red;
1589         if (s != "")
1590             precache_playermodel(s);
1591         s = autocvar_sv_defaultplayermodel_blue;
1592         if (s != "")
1593             precache_playermodel(s);
1594         s = autocvar_sv_defaultplayermodel_yellow;
1595         if (s != "")
1596             precache_playermodel(s);
1597         s = autocvar_sv_defaultplayermodel_pink;
1598         if (s != "")
1599             precache_playermodel(s);
1600         s = autocvar_sv_defaultplayermodel;
1601         if (s != "")
1602             precache_playermodel(s);
1603     }
1604
1605     if (g_footsteps)
1606     {
1607         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1608         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1609     }
1610
1611     // gore and miscellaneous sounds
1612     //precache_sound ("misc/h2ohit.wav");
1613     precache_model ("models/hook.md3");
1614     precache_sound ("misc/armorimpact.wav");
1615     precache_sound ("misc/bodyimpact1.wav");
1616     precache_sound ("misc/bodyimpact2.wav");
1617     precache_sound ("misc/gib.wav");
1618     precache_sound ("misc/gib_splat01.wav");
1619     precache_sound ("misc/gib_splat02.wav");
1620     precache_sound ("misc/gib_splat03.wav");
1621     precache_sound ("misc/gib_splat04.wav");
1622     precache_sound ("misc/hit.wav");
1623         precache_sound ("misc/typehit.wav");
1624     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1625     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1626     precache_sound ("misc/null.wav");
1627     precache_sound ("misc/spawn.wav");
1628     precache_sound ("misc/talk.wav");
1629     precache_sound ("misc/teleport.wav");
1630     precache_sound ("misc/poweroff.wav");
1631     precache_sound ("player/lava.wav");
1632     precache_sound ("player/slime.wav");
1633
1634     if (g_jetpack)
1635         precache_sound ("misc/jetpack_fly.wav");
1636
1637     precache_model ("models/sprites/0.spr32");
1638     precache_model ("models/sprites/1.spr32");
1639     precache_model ("models/sprites/2.spr32");
1640     precache_model ("models/sprites/3.spr32");
1641     precache_model ("models/sprites/4.spr32");
1642     precache_model ("models/sprites/5.spr32");
1643     precache_model ("models/sprites/6.spr32");
1644     precache_model ("models/sprites/7.spr32");
1645     precache_model ("models/sprites/8.spr32");
1646     precache_model ("models/sprites/9.spr32");
1647     precache_model ("models/sprites/10.spr32");
1648
1649     // common weapon precaches
1650     precache_sound ("weapons/weapon_switch.wav");
1651     precache_sound ("weapons/weaponpickup.wav");
1652     precache_sound ("weapons/unavailable.wav");
1653     precache_sound ("weapons/dryfire.wav");
1654     if (g_grappling_hook)
1655     {
1656         precache_sound ("weapons/hook_fire.wav"); // hook
1657         precache_sound ("weapons/hook_impact.wav"); // hook
1658     }
1659
1660     if(autocvar_sv_precacheweapons)
1661     {
1662         //precache weapon models/sounds
1663         local float wep;
1664         wep = WEP_FIRST;
1665         while (wep <= WEP_LAST)
1666         {
1667             weapon_action(wep, WR_PRECACHE);
1668             wep = wep + 1;
1669         }
1670     }
1671
1672     precache_model("models/elaser.mdl");
1673     precache_model("models/laser.mdl");
1674     precache_model("models/ebomb.mdl");
1675
1676 #if 0
1677     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1678
1679     if (!self.noise && self.music) // quake 3 uses the music field
1680         self.noise = self.music;
1681
1682     // plays music for the level if there is any
1683     if (self.noise)
1684     {
1685         precache_sound (self.noise);
1686         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1687     }
1688 #endif
1689 }
1690
1691 // sorry, but using \ in macros breaks line numbers
1692 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1693 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1694 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1695
1696 // WARNING: this kills the trace globals
1697 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1698 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1699
1700 #define INITPRIO_FIRST              0
1701 #define INITPRIO_GAMETYPE           0
1702 #define INITPRIO_GAMETYPE_FALLBACK  1
1703 #define INITPRIO_FINDTARGET        10
1704 #define INITPRIO_DROPTOFLOOR       20
1705 #define INITPRIO_SETLOCATION       90
1706 #define INITPRIO_LINKDOORS         91
1707 #define INITPRIO_LAST              99
1708
1709 .void(void) initialize_entity;
1710 .float initialize_entity_order;
1711 .entity initialize_entity_next;
1712 entity initialize_entity_first;
1713
1714 void make_safe_for_remove(entity e)
1715 {
1716     if (e.initialize_entity)
1717     {
1718         entity ent, prev;
1719         for (ent = initialize_entity_first; ent; )
1720         {
1721             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1722             {
1723                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1724                 // skip it in linked list
1725                 if (prev)
1726                 {
1727                     prev.initialize_entity_next = ent.initialize_entity_next;
1728                     ent = prev.initialize_entity_next;
1729                 }
1730                 else
1731                 {
1732                     initialize_entity_first = ent.initialize_entity_next;
1733                     ent = initialize_entity_first;
1734                 }
1735             }
1736             else
1737             {
1738                 prev = ent;
1739                 ent = ent.initialize_entity_next;
1740             }
1741         }
1742     }
1743 }
1744
1745 void objerror(string s)
1746 {
1747     make_safe_for_remove(self);
1748     objerror_builtin(s);
1749 }
1750
1751 void remove_unsafely(entity e)
1752 {
1753     remove_builtin(e);
1754 }
1755
1756 void remove_safely(entity e)
1757 {
1758     make_safe_for_remove(e);
1759     remove_builtin(e);
1760 }
1761
1762 void InitializeEntity(entity e, void(void) func, float order)
1763 {
1764     entity prev, cur;
1765
1766     if (!e || e.initialize_entity)
1767     {
1768         // make a proxy initializer entity
1769         entity e_old;
1770         e_old = e;
1771         e = spawn();
1772         e.classname = "initialize_entity";
1773         e.enemy = e_old;
1774     }
1775
1776     e.initialize_entity = func;
1777     e.initialize_entity_order = order;
1778
1779     cur = initialize_entity_first;
1780     for (;;)
1781     {
1782         if (!cur || cur.initialize_entity_order > order)
1783         {
1784             // insert between prev and cur
1785             if (prev)
1786                 prev.initialize_entity_next = e;
1787             else
1788                 initialize_entity_first = e;
1789             e.initialize_entity_next = cur;
1790             return;
1791         }
1792         prev = cur;
1793         cur = cur.initialize_entity_next;
1794     }
1795 }
1796 void InitializeEntitiesRun()
1797 {
1798     entity startoflist;
1799     startoflist = initialize_entity_first;
1800     initialize_entity_first = world;
1801     for (self = startoflist; self; )
1802     {
1803         entity e;
1804         var void(void) func;
1805         e = self.initialize_entity_next;
1806         func = self.initialize_entity;
1807         self.initialize_entity_order = 0;
1808         self.initialize_entity = func_null;
1809         self.initialize_entity_next = world;
1810         if (self.classname == "initialize_entity")
1811         {
1812             entity e_old;
1813             e_old = self.enemy;
1814             remove_builtin(self);
1815             self = e_old;
1816         }
1817         //dprint("Delayed initialization: ", self.classname, "\n");
1818         if(func != func_null)
1819             func();
1820         else
1821         {
1822             eprint(self);
1823             backtrace(strcat("Null function in: ", self.classname, "\n"));
1824         }
1825         self = e;
1826     }
1827 }
1828
1829 .float uncustomizeentityforclient_set;
1830 .void(void) uncustomizeentityforclient;
1831 void(void) SUB_Nullpointer = #0;
1832 void UncustomizeEntitiesRun()
1833 {
1834     entity oldself;
1835     oldself = self;
1836     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1837         self.uncustomizeentityforclient();
1838     self = oldself;
1839 }
1840 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1841 {
1842     e.customizeentityforclient = customizer;
1843     e.uncustomizeentityforclient = uncustomizer;
1844     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1845 }
1846
1847 .float nottargeted;
1848 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1849
1850 void() SUB_Remove;
1851 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1852 {
1853     vector mi, ma;
1854
1855     if (e.classname == "")
1856         e.classname = "net_linked";
1857
1858     if (e.model == "" || self.modelindex == 0)
1859     {
1860         mi = e.mins;
1861         ma = e.maxs;
1862         setmodel(e, "null");
1863         setsize(e, mi, ma);
1864     }
1865
1866     e.SendEntity = sendfunc;
1867     e.SendFlags = 0xFFFFFF;
1868
1869     if (!docull)
1870         e.effects |= EF_NODEPTHTEST;
1871
1872     if (dt)
1873     {
1874         e.nextthink = time + dt;
1875         e.think = SUB_Remove;
1876     }
1877 }
1878
1879 void adaptor_think2touch()
1880 {
1881     entity o;
1882     o = other;
1883     other = world;
1884     self.touch();
1885     other = o;
1886 }
1887
1888 void adaptor_think2use()
1889 {
1890     entity o, a;
1891     o = other;
1892     a = activator;
1893     activator = world;
1894     other = world;
1895     self.use();
1896     other = o;
1897     activator = a;
1898 }
1899
1900 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1901 {
1902         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1903                 self.projectiledeathtype |= HITTYPE_SPLASH;
1904         adaptor_think2use();
1905 }
1906
1907 // deferred dropping
1908 void DropToFloor_Handler()
1909 {
1910     droptofloor_builtin();
1911     self.dropped_origin = self.origin;
1912 }
1913
1914 void droptofloor()
1915 {
1916     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1917 }
1918
1919
1920
1921 float trace_hits_box_a0, trace_hits_box_a1;
1922
1923 float trace_hits_box_1d(float end, float thmi, float thma)
1924 {
1925     if (end == 0)
1926     {
1927         // just check if x is in range
1928         if (0 < thmi)
1929             return FALSE;
1930         if (0 > thma)
1931             return FALSE;
1932     }
1933     else
1934     {
1935         // do the trace with respect to x
1936         // 0 -> end has to stay in thmi -> thma
1937         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1938         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1939         if (trace_hits_box_a0 > trace_hits_box_a1)
1940             return FALSE;
1941     }
1942     return TRUE;
1943 }
1944
1945 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1946 {
1947     end -= start;
1948     thmi -= start;
1949     thma -= start;
1950     // now it is a trace from 0 to end
1951
1952     trace_hits_box_a0 = 0;
1953     trace_hits_box_a1 = 1;
1954
1955     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1956         return FALSE;
1957     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1958         return FALSE;
1959     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1960         return FALSE;
1961
1962     return TRUE;
1963 }
1964
1965 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1966 {
1967     return trace_hits_box(start, end, thmi - ma, thma - mi);
1968 }
1969
1970 float SUB_NoImpactCheck()
1971 {
1972         // zero hitcontents = this is not the real impact, but either the
1973         // mirror-impact of something hitting the projectile instead of the
1974         // projectile hitting the something, or a touchareagrid one. Neither of
1975         // these stop the projectile from moving, so...
1976         if(trace_dphitcontents == 0)
1977         {
1978                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1979                 checkclient();
1980         }
1981     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1982         return 1;
1983     if (other == world && self.size != '0 0 0')
1984     {
1985         vector tic;
1986         tic = self.velocity * sys_frametime;
1987         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1988         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1989         if (trace_fraction >= 1)
1990         {
1991             dprint("Odd... did not hit...?\n");
1992         }
1993         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1994         {
1995             dprint("Detected and prevented the sky-grapple bug.\n");
1996             return 1;
1997         }
1998     }
1999
2000     return 0;
2001 }
2002
2003 #define SUB_OwnerCheck() (other && (other == self.owner))
2004
2005 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2006 {
2007         if(SUB_OwnerCheck())
2008                 return TRUE;
2009         if(SUB_NoImpactCheck())
2010         {
2011                 remove(self);
2012                 return TRUE;
2013         }
2014         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2015                 UpdateCSQCProjectileNextFrame(self);
2016         return FALSE;
2017 }
2018 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2019
2020 float MAX_IPBAN_URIS           = 16;
2021
2022 float URI_GET_DISCARD          = 0;
2023 float URI_GET_IPBAN            = 1;
2024 float URI_GET_IPBAN_END        = 16;
2025 float URI_GET_PLAYERSTATS_SENT = 17;
2026
2027 void URI_Get_Callback(float id, float status, string data)
2028 {
2029     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2030     dprint(data);
2031     dprint("\nEnd of data.\n");
2032
2033     if (id == URI_GET_DISCARD)
2034     {
2035         // discard
2036     }
2037     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2038     {
2039         // online ban list
2040         OnlineBanList_URI_Get_Callback(id, status, data);
2041     }
2042     else if (id == URI_GET_PLAYERSTATS_SENT)
2043     {
2044         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2045     }
2046     else
2047     {
2048         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2049     }
2050 }
2051
2052 void print_to(entity e, string s)
2053 {
2054     if (e)
2055         sprint(e, strcat(s, "\n"));
2056     else
2057         print(s, "\n");
2058 }
2059
2060 string uid2name(string myuid) {
2061         string s;
2062         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2063
2064         if(s == "")
2065                 s = "^1Unregistered Player";
2066         return s;
2067 }
2068
2069 float race_readTime(string map, float pos)
2070 {
2071         string rr;
2072         if(g_cts)
2073                 rr = CTS_RECORD;
2074         else
2075                 rr = RACE_RECORD;
2076
2077         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2078 }
2079
2080 string race_readUID(string map, float pos)
2081 {
2082         string rr;
2083         if(g_cts)
2084                 rr = CTS_RECORD;
2085         else
2086                 rr = RACE_RECORD;
2087
2088         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2089 }
2090
2091 float race_readPos(string map, float t) {
2092         float i;
2093         for (i = 1; i <= RANKINGS_CNT; ++i)
2094                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2095                         return i;
2096
2097         return 0; // pos is zero if unranked
2098 }
2099
2100 void race_writeTime(string map, float t, string myuid)
2101 {
2102         string rr;
2103         if(g_cts)
2104                 rr = CTS_RECORD;
2105         else
2106                 rr = RACE_RECORD;
2107
2108         float newpos;
2109         newpos = race_readPos(map, t);
2110
2111         float i, prevpos;
2112         for(i = 1; i <= RANKINGS_CNT; ++i)
2113         {
2114                 if(race_readUID(map, i) == myuid)
2115                         prevpos = i;
2116         }
2117         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2118                 for (i = prevpos; i > newpos; --i) {
2119                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2120                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2121                 }
2122         } else { // player has no ranked record yet
2123                 for (i = RANKINGS_CNT; i > newpos; --i) {
2124                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2125                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2126                 }
2127         }
2128
2129         // store new time itself
2130         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2131         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2132 }
2133
2134 string race_readName(string map, float pos)
2135 {
2136         string rr;
2137         if(g_cts)
2138                 rr = CTS_RECORD;
2139         else
2140                 rr = RACE_RECORD;
2141
2142         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2143 }
2144
2145 string race_placeName(float pos) {
2146         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2147         {
2148                 if(mod(pos, 10) == 1)
2149                         return strcat(ftos(pos), "st");
2150                 else if(mod(pos, 10) == 2)
2151                         return strcat(ftos(pos), "nd");
2152                 else if(mod(pos, 10) == 3)
2153                         return strcat(ftos(pos), "rd");
2154                 else
2155                         return strcat(ftos(pos), "th");
2156         }
2157         else
2158                 return strcat(ftos(pos), "th");
2159 }
2160 string getrecords(float page) // 50 records per page
2161 {
2162     float rec;
2163     string h;
2164     float r;
2165     float i;
2166     string s;
2167
2168     rec = 0;
2169
2170     s = "";
2171
2172     if (g_ctf)
2173     {
2174         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2175         {
2176             if (MapInfo_Get_ByID(i))
2177             {
2178                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2179                 if (r == 0)
2180                     continue;
2181                 // TODO: uid2name
2182                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2183                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2184                 ++rec;
2185             }
2186         }
2187     }
2188
2189     if (g_race)
2190     {
2191         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2192         {
2193             if (MapInfo_Get_ByID(i))
2194             {
2195                 r = race_readTime(MapInfo_Map_bspname, 1);
2196                 if (r == 0)
2197                     continue;
2198                 h = race_readName(MapInfo_Map_bspname, 1);
2199                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2200                 ++rec;
2201             }
2202         }
2203     }
2204
2205     if (g_cts)
2206     {
2207         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2208         {
2209             if (MapInfo_Get_ByID(i))
2210             {
2211                 r = race_readTime(MapInfo_Map_bspname, 1);
2212                 if (r == 0)
2213                     continue;
2214                 h = race_readName(MapInfo_Map_bspname, 1);
2215                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2216                 ++rec;
2217             }
2218         }
2219     }
2220
2221     MapInfo_ClearTemps();
2222
2223     if (s == "" && page == 0)
2224         return "No records are available on this server.\n";
2225     else
2226         return s;
2227 }
2228
2229 string getrankings()
2230 {
2231     string n;
2232     float t;
2233     float i;
2234     string s;
2235     string p;
2236     string map;
2237
2238     s = "";
2239
2240     map = GetMapname();
2241
2242     for (i = 1; i <= RANKINGS_CNT; ++i)
2243     {
2244         t = race_readTime(map, i);
2245         if (t == 0)
2246             continue;
2247         n = race_readName(map, i);
2248         p = race_placeName(i);
2249         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2250     }
2251
2252     MapInfo_ClearTemps();
2253
2254     if (s == "")
2255         return strcat("No records are available for the map: ", map, "\n");
2256     else
2257         return strcat("Records for ", map, ":\n", s);
2258 }
2259
2260 #define LADDER_FIRSTPOINT 100
2261 #define LADDER_CNT 10
2262         // position X still gives LADDER_FIRSTPOINT/X points
2263 #define LADDER_SIZE 30
2264         // ladder shows the top X players
2265 string top_uids[LADDER_SIZE];
2266 float top_scores[LADDER_SIZE];
2267 string getladder()
2268 {
2269     float i, j, k, uidcnt;
2270     string s, temp_s;
2271
2272     s = "";
2273     temp_s = "";
2274
2275     string rr;
2276     if(g_cts)
2277         rr = CTS_RECORD;
2278     else
2279         rr = RACE_RECORD;
2280
2281     string myuid;
2282
2283     for (k = 0; k < MapInfo_count; ++k)
2284     {
2285         if (MapInfo_Get_ByID(k))
2286         {
2287                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2288                         if(i == 0) // speed award
2289                         {
2290                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2291                                         continue;
2292
2293                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2294                         }
2295                         else // normal record, if it exists (else break)
2296                         {
2297                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2298                                         continue;
2299
2300                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2301                         }
2302
2303                         // string s contains:
2304                         // arg 0 = # of speed recs
2305                         // arg 1 = # of 1st place recs
2306                         // arg 2 = # of 2nd place recs
2307                         // ... etc
2308                         // LADDER_CNT+1 = total points
2309
2310                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2311                         if (temp_s == "")
2312                         {
2313                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2314                             ++uidcnt;
2315                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2316                             {
2317                                 if(j != LADDER_CNT + 1)
2318                                     temp_s = strcat(temp_s, "0 ");
2319                                 else
2320                                     temp_s = strcat(temp_s, "0");
2321                             }
2322                         }
2323
2324                         tokenize_console(temp_s);
2325                         s = "";
2326
2327                         if(i == 0) // speed award
2328                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2329                             {
2330                                 if(j == 0) // speed award
2331                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2332                                 else
2333                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2334                             }
2335                         else // record
2336                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2337                             {
2338                                 if(j == 0)
2339                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2340                                 else if(j == i) // wanted rec!
2341                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2342                                 else
2343                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2344                             }
2345
2346                         // total points are (by default) calculated like this:
2347                         // speedrec = floor(100 / 10) = 10 points
2348                         // 1st place = floor(100 / 1) = 100 points
2349                         // 2nd place = floor(100 / 2) = 50 points
2350                         // 3rd place = floor(100 / 3) = 33 points
2351                         // 4th place = floor(100 / 4) = 25 points
2352                         // 5th place = floor(100 / 5) = 20 points
2353                         // ... etc
2354
2355                         if(i == 0)
2356                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2357                         else
2358                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2359
2360                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2361                 }
2362         }
2363     }
2364
2365     float thiscnt;
2366     string thisuid;
2367     for (i = 0; i <= uidcnt; ++i) // for each known uid
2368     {
2369         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2370         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2371         tokenize_console(temp_s);
2372         thiscnt = stof(argv(LADDER_CNT+1));
2373
2374         if(thiscnt > top_scores[LADDER_SIZE-1])
2375         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2376         {
2377             if(thiscnt > top_scores[j])
2378             {
2379                 for (k = LADDER_SIZE-1; k >= j; --k)
2380                 {
2381                     top_uids[k] = top_uids[k-1];
2382                     top_scores[k] = top_scores[k-1];
2383                 }
2384                 top_uids[j] = thisuid;
2385                 top_scores[j] = thiscnt;
2386                 break;
2387             }
2388         }
2389     }
2390
2391     s = "^3-----------------------\n\n";
2392
2393     s = strcat(s, "Pos ^3|");
2394     s = strcat(s, " ^7Total  ^3|");
2395     for (i = 1; i <= LADDER_CNT; ++i)
2396     {
2397         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2398     }
2399     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2400
2401     s = strcat(s, "\n^3----+--------");
2402     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2403     {
2404         s = strcat(s, "+-----");
2405     }
2406 #if LADDER_CNT > 9
2407     for (i = 1; i <= LADDER_CNT - 9; ++i)
2408     {
2409         s = strcat(s, "+------");
2410     }
2411 #endif
2412
2413     s = strcat(s, "+--------------+--------------------\n");
2414
2415     for (i = 0; i < LADDER_SIZE; ++i)
2416     {
2417         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2418         tokenize_console(temp_s);
2419         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2420             continue;
2421         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2422         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2423         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2424         {
2425             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2426         }
2427 #if LADDER_CNT > 9
2428         for (j = 10; j <= LADDER_CNT; ++j)
2429         {
2430             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2431         }
2432 #endif
2433
2434         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2435         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2436     }
2437
2438     MapInfo_ClearTemps();
2439
2440     if (s == "")
2441         return "No ladder on this server!\n";
2442     else
2443         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2444 }
2445
2446
2447 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2448 {
2449     float m, i;
2450     vector start, org, delta, end, enddown, mstart;
2451
2452     m = e.dphitcontentsmask;
2453     e.dphitcontentsmask = goodcontents | badcontents;
2454
2455     org = world.mins;
2456     delta = world.maxs - world.mins;
2457
2458     for (i = 0; i < attempts; ++i)
2459     {
2460         start_x = org_x + random() * delta_x;
2461         start_y = org_y + random() * delta_y;
2462         start_z = org_z + random() * delta_z;
2463
2464         // rule 1: start inside world bounds, and outside
2465         // solid, and don't start from somewhere where you can
2466         // fall down to evil
2467         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2468         if (trace_fraction >= 1)
2469             continue;
2470         if (trace_startsolid)
2471             continue;
2472         if (trace_dphitcontents & badcontents)
2473             continue;
2474         if (trace_dphitq3surfaceflags & badsurfaceflags)
2475             continue;
2476
2477         // rule 2: if we are too high, lower the point
2478         if (trace_fraction * delta_z > maxaboveground)
2479             start = trace_endpos + '0 0 1' * maxaboveground;
2480         enddown = trace_endpos;
2481
2482         // rule 3: make sure we aren't outside the map. This only works
2483         // for somewhat well formed maps. A good rule of thumb is that
2484         // the map should have a convex outside hull.
2485         // these can be traceLINES as we already verified the starting box
2486         mstart = start + 0.5 * (e.mins + e.maxs);
2487         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2488         if (trace_fraction >= 1)
2489             continue;
2490         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2491         if (trace_fraction >= 1)
2492             continue;
2493         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2494         if (trace_fraction >= 1)
2495             continue;
2496         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2497         if (trace_fraction >= 1)
2498             continue;
2499         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2500         if (trace_fraction >= 1)
2501             continue;
2502
2503         // find a random vector to "look at"
2504         end_x = org_x + random() * delta_x;
2505         end_y = org_y + random() * delta_y;
2506         end_z = org_z + random() * delta_z;
2507         end = start + normalize(end - start) * vlen(delta);
2508
2509         // rule 4: start TO end must not be too short
2510         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2511         if (trace_startsolid)
2512             continue;
2513         if (trace_fraction < minviewdistance / vlen(delta))
2514             continue;
2515
2516         // rule 5: don't want to look at sky
2517         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2518             continue;
2519
2520         // rule 6: we must not end up in trigger_hurt
2521         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2522         {
2523             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2524             continue;
2525         }
2526
2527         break;
2528     }
2529
2530     e.dphitcontentsmask = m;
2531
2532     if (i < attempts)
2533     {
2534         setorigin(e, start);
2535         e.angles = vectoangles(end - start);
2536         dprint("Needed ", ftos(i + 1), " attempts\n");
2537         return TRUE;
2538     }
2539     else
2540         return FALSE;
2541 }
2542
2543 float zcurveparticles_effectno;
2544 vector zcurveparticles_start;
2545 float zcurveparticles_spd;
2546
2547 void endzcurveparticles()
2548 {
2549         if(zcurveparticles_effectno)
2550         {
2551                 // terminator
2552                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2553         }
2554         zcurveparticles_effectno = 0;
2555 }
2556
2557 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2558 {
2559         spd = bound(0, floor(spd / 16), 32767);
2560         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2561         {
2562                 endzcurveparticles();
2563                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2564                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2565                 WriteShort(MSG_BROADCAST, effectno);
2566                 WriteCoord(MSG_BROADCAST, start_x);
2567                 WriteCoord(MSG_BROADCAST, start_y);
2568                 WriteCoord(MSG_BROADCAST, start_z);
2569                 zcurveparticles_effectno = effectno;
2570                 zcurveparticles_start = start;
2571         }
2572         else
2573                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2574         WriteCoord(MSG_BROADCAST, end_x);
2575         WriteCoord(MSG_BROADCAST, end_y);
2576         WriteCoord(MSG_BROADCAST, end_z);
2577         WriteCoord(MSG_BROADCAST, end_dz);
2578         zcurveparticles_spd = spd;
2579 }
2580
2581 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2582 {
2583         float end_dz;
2584         vector vecxy, velxy;
2585
2586         vecxy = end - start;
2587         vecxy_z = 0;
2588         velxy = vel;
2589         velxy_z = 0;
2590
2591         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2592         {
2593                 endzcurveparticles();
2594                 trailparticles(world, effectno, start, end);
2595                 return;
2596         }
2597
2598         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2599         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2600 }
2601
2602 string GetGametype(); // g_world.qc
2603 void write_recordmarker(entity pl, float tstart, float dt)
2604 {
2605     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2606
2607     // also write a marker into demo files for demotc-race-record-extractor to find
2608     stuffcmd(pl,
2609              strcat(
2610                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2611                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2612 }
2613
2614 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2615 {
2616         switch(algn)
2617         {
2618                 case 1: // right
2619                         break;
2620
2621                 case 2: // left
2622                         vecs_y = -vecs_y;
2623                         break;
2624
2625                 default:
2626                 case 3:
2627                         if(allowcenter) // 2: allow center handedness
2628                         {
2629                                 // center
2630                                 vecs_y = 0;
2631                                 vecs_z -= 2;
2632                         }
2633                         else
2634                         {
2635                                 // right
2636                         }
2637                         break;
2638
2639                 case 4:
2640                         if(allowcenter) // 2: allow center handedness
2641                         {
2642                                 // center
2643                                 vecs_y = 0;
2644                                 vecs_z -= 2;
2645                         }
2646                         else
2647                         {
2648                                 // left
2649                                 vecs_y = -vecs_y;
2650                         }
2651                         break;
2652         }
2653         return vecs;
2654 }
2655
2656 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2657 {
2658         string s;
2659         vector v;
2660
2661         if (autocvar_g_shootfromeye)
2662         {
2663                 if (visual)
2664                 {
2665                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2666                 }
2667                 else
2668                 {
2669                         vecs_y = 0;
2670                         vecs_z = 0;
2671                 }
2672         }
2673         else if (autocvar_g_shootfromcenter)
2674         {
2675                 if (visual)
2676                 {
2677                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2678                 }
2679                 else
2680                 {
2681                         vecs_y = 0;
2682                         vecs_z -= 2;
2683                 }
2684         }
2685         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2686         {
2687                 v = stov(s);
2688                 if (y_is_right)
2689                         v_y = -v_y;
2690                 if (v_x != 0)
2691                         vecs_x = v_x;
2692                 vecs_y = v_y;
2693                 vecs_z = v_z;
2694         }
2695         else if (autocvar_g_shootfromclient)
2696         {
2697                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2698         }
2699         return vecs;
2700 }
2701
2702 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2703 {
2704         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2705 }
2706
2707
2708 void attach_sameorigin(entity e, entity to, string tag)
2709 {
2710     vector org, t_forward, t_left, t_up, e_forward, e_up;
2711     vector org0, ang0;
2712     float tagscale;
2713
2714     ang0 = e.angles;
2715     org0 = e.origin;
2716
2717     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2718     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2719     t_forward = v_forward * tagscale;
2720     t_left = v_right * -tagscale;
2721     t_up = v_up * tagscale;
2722
2723     e.origin_x = org * t_forward;
2724     e.origin_y = org * t_left;
2725     e.origin_z = org * t_up;
2726
2727     // current forward and up directions
2728     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2729                 e.angles = AnglesTransform_FromVAngles(e.angles);
2730         else
2731                 e.angles = AnglesTransform_FromAngles(e.angles);
2732     fixedmakevectors(e.angles);
2733
2734     // untransform forward, up!
2735     e_forward_x = v_forward * t_forward;
2736     e_forward_y = v_forward * t_left;
2737     e_forward_z = v_forward * t_up;
2738     e_up_x = v_up * t_forward;
2739     e_up_y = v_up * t_left;
2740     e_up_z = v_up * t_up;
2741
2742     e.angles = fixedvectoangles2(e_forward, e_up);
2743     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2744                 e.angles = AnglesTransform_ToVAngles(e.angles);
2745         else
2746                 e.angles = AnglesTransform_ToAngles(e.angles);
2747
2748     setattachment(e, to, tag);
2749     setorigin(e, e.origin);
2750 }
2751
2752 void detach_sameorigin(entity e)
2753 {
2754     vector org;
2755     org = gettaginfo(e, 0);
2756     e.angles = fixedvectoangles2(v_forward, v_up);
2757     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2758                 e.angles = AnglesTransform_ToVAngles(e.angles);
2759         else
2760                 e.angles = AnglesTransform_ToAngles(e.angles);
2761     setorigin(e, org);
2762     setattachment(e, world, "");
2763     setorigin(e, e.origin);
2764 }
2765
2766 void follow_sameorigin(entity e, entity to)
2767 {
2768     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2769     e.aiment = to; // make the hole follow bmodel
2770     e.punchangle = to.angles; // the original angles of bmodel
2771     e.view_ofs = e.origin - to.origin; // relative origin
2772     e.v_angle = e.angles - to.angles; // relative angles
2773 }
2774
2775 void unfollow_sameorigin(entity e)
2776 {
2777     e.movetype = MOVETYPE_NONE;
2778 }
2779
2780 entity gettaginfo_relative_ent;
2781 vector gettaginfo_relative(entity e, float tag)
2782 {
2783     if (!gettaginfo_relative_ent)
2784     {
2785         gettaginfo_relative_ent = spawn();
2786         gettaginfo_relative_ent.effects = EF_NODRAW;
2787     }
2788     gettaginfo_relative_ent.model = e.model;
2789     gettaginfo_relative_ent.modelindex = e.modelindex;
2790     gettaginfo_relative_ent.frame = e.frame;
2791     return gettaginfo(gettaginfo_relative_ent, tag);
2792 }
2793
2794 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2795 {
2796     float p;
2797     p = pow(2, chan);
2798     if (pl.soundentity.cnt & p)
2799         return;
2800     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2801     pl.soundentity.cnt |= p;
2802 }
2803
2804 void SoundEntity_StopSound(entity pl, float chan)
2805 {
2806     float p;
2807     p = pow(2, chan);
2808     if (pl.soundentity.cnt & p)
2809     {
2810         stopsoundto(MSG_ALL, pl.soundentity, chan);
2811         pl.soundentity.cnt &~= p;
2812     }
2813 }
2814
2815 void SoundEntity_Attach(entity pl)
2816 {
2817     pl.soundentity = spawn();
2818     pl.soundentity.classname = "soundentity";
2819     pl.soundentity.owner = pl;
2820     setattachment(pl.soundentity, pl, "");
2821     setmodel(pl.soundentity, "null");
2822 }
2823
2824 void SoundEntity_Detach(entity pl)
2825 {
2826     float i;
2827     for (i = 0; i <= 7; ++i)
2828         SoundEntity_StopSound(pl, i);
2829 }
2830
2831
2832 float ParseCommandPlayerSlotTarget_firsttoken;
2833 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2834 {
2835     string s;
2836     entity e, head;
2837     float n;
2838
2839     s = string_null;
2840
2841     ParseCommandPlayerSlotTarget_firsttoken = -1;
2842
2843     if (tokens > idx)
2844     {
2845         if (substring(argv(idx), 0, 1) == "#")
2846         {
2847             s = substring(argv(idx), 1, -1);
2848             ++idx;
2849             if (s == "")
2850                 if (tokens > idx)
2851                 {
2852                     s = argv(idx);
2853                     ++idx;
2854                 }
2855                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2856             if (s == ftos(stof(s)))
2857             {
2858                 e = edict_num(stof(s));
2859                 if (e.flags & FL_CLIENT)
2860                     return e;
2861             }
2862         }
2863         else
2864         {
2865             // it must be a nick name
2866             s = argv(idx);
2867             ++idx;
2868                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2869
2870             n = 0;
2871             FOR_EACH_CLIENT(head)
2872             if (head.netname == s)
2873             {
2874                 e = head;
2875                 ++n;
2876             }
2877             if (n == 1)
2878                 return e;
2879
2880             s = strdecolorize(s);
2881             n = 0;
2882             FOR_EACH_CLIENT(head)
2883             if (strdecolorize(head.netname) == s)
2884             {
2885                 e = head;
2886                 ++n;
2887             }
2888             if (n == 1)
2889                 return e;
2890         }
2891     }
2892
2893     return world;
2894 }
2895
2896 .float scale2;
2897
2898 float modeleffect_SendEntity(entity to, float sf)
2899 {
2900         float f;
2901         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2902
2903         f = 0;
2904         if(self.velocity != '0 0 0')
2905                 f |= 1;
2906         if(self.angles != '0 0 0')
2907                 f |= 2;
2908         if(self.avelocity != '0 0 0')
2909                 f |= 4;
2910
2911         WriteByte(MSG_ENTITY, f);
2912         WriteShort(MSG_ENTITY, self.modelindex);
2913         WriteByte(MSG_ENTITY, self.skin);
2914         WriteByte(MSG_ENTITY, self.frame);
2915         WriteCoord(MSG_ENTITY, self.origin_x);
2916         WriteCoord(MSG_ENTITY, self.origin_y);
2917         WriteCoord(MSG_ENTITY, self.origin_z);
2918         if(f & 1)
2919         {
2920                 WriteCoord(MSG_ENTITY, self.velocity_x);
2921                 WriteCoord(MSG_ENTITY, self.velocity_y);
2922                 WriteCoord(MSG_ENTITY, self.velocity_z);
2923         }
2924         if(f & 2)
2925         {
2926                 WriteCoord(MSG_ENTITY, self.angles_x);
2927                 WriteCoord(MSG_ENTITY, self.angles_y);
2928                 WriteCoord(MSG_ENTITY, self.angles_z);
2929         }
2930         if(f & 4)
2931         {
2932                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2933                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2934                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2935         }
2936         WriteShort(MSG_ENTITY, self.scale * 256.0);
2937         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2938         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2939         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2940         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2941
2942         return TRUE;
2943 }
2944
2945 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2946 {
2947         entity e;
2948         float sz;
2949         e = spawn();
2950         e.classname = "modeleffect";
2951         setmodel(e, m);
2952         e.frame = f;
2953         setorigin(e, o);
2954         e.velocity = v;
2955         e.angles = ang;
2956         e.avelocity = angv;
2957         e.alpha = a;
2958         e.teleport_time = t1;
2959         e.fade_time = t2;
2960         e.skin = s;
2961         if(s0 >= 0)
2962                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2963         else
2964                 e.scale = -s0;
2965         if(s2 >= 0)
2966                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2967         else
2968                 e.scale2 = -s2;
2969         sz = max(e.scale, e.scale2);
2970         setsize(e, e.mins * sz, e.maxs * sz);
2971         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2972 }
2973
2974 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2975 {
2976         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2977 }
2978
2979 float randombit(float bits)
2980 {
2981         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2982                 return bits;
2983
2984         float n, f, b, r;
2985
2986         r = random();
2987         b = 0;
2988         n = 0;
2989
2990         for(f = 1; f <= bits; f *= 2)
2991         {
2992                 if(bits & f)
2993                 {
2994                         ++n;
2995                         r *= n;
2996                         if(r <= 1)
2997                                 b = f;
2998                         else
2999                                 r = (r - 1) / (n - 1);
3000                 }
3001         }
3002
3003         return b;
3004 }
3005
3006 float randombits(float bits, float k, float error_return)
3007 {
3008         float r;
3009         r = 0;
3010         while(k > 0 && bits != r)
3011         {
3012                 r += randombit(bits - r);
3013                 --k;
3014         }
3015         if(error_return)
3016                 if(k > 0)
3017                         return -1; // all
3018         return r;
3019 }
3020
3021 void randombit_test(float bits, float iter)
3022 {
3023         while(iter > 0)
3024         {
3025                 print(ftos(randombit(bits)), "\n");
3026                 --iter;
3027         }
3028 }
3029
3030 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3031 {
3032         if(halflifedist > 0)
3033                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3034         else if(halflifedist < 0)
3035                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3036         else
3037                 return 1;
3038 }
3039
3040
3041
3042
3043 #ifdef RELEASE
3044 #define cvar_string_normal cvar_string_builtin
3045 #define cvar_normal cvar_builtin
3046 #else
3047 string cvar_string_normal(string n)
3048 {
3049         if not(cvar_type(n) & 1)
3050                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3051         return cvar_string_builtin(n);
3052 }
3053
3054 float cvar_normal(string n)
3055 {
3056         return stof(cvar_string_normal(n));
3057 }
3058 #endif
3059 #define cvar_set_normal cvar_set_builtin
3060
3061 void defer_think()
3062 {
3063     entity oself;
3064
3065     oself           = self;
3066     self            = self.owner;
3067     oself.think     = SUB_Remove;
3068     oself.nextthink = time;
3069
3070     oself.use();
3071 }
3072
3073 /*
3074     Execute func() after time + fdelay.
3075     self when func is executed = self when defer is called
3076 */
3077 void defer(float fdelay, void() func)
3078 {
3079     entity e;
3080
3081     e           = spawn();
3082     e.owner     = self;
3083     e.use       = func;
3084     e.think     = defer_think;
3085     e.nextthink = time + fdelay;
3086 }