qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (autocvar_r_showbboxes)
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471
 472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 473                 p = p + strlen(replacement);
 474         }
 475         return msg;
 476 }
 477
 478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 479         return (value == 0) ? FALSE : TRUE;
 480 }
 481
 482 /*
 483 =============
 484 GetCvars
 485 =============
 486 Called with:
 487   0:  sends the request
 488   >0: receives a cvar from name=argv(f) value=argv(f+1)
 489 */
 490 void GetCvars_handleString(string thisname, float f, .string field, string name)
 491 {
 492         if (f < 0)
 493         {
 494                 if (self.field)
 495                         strunzone(self.field);
 496                 self.field = string_null;
 497         }
 498         else if (f > 0)
 499         {
 500                 if (thisname == name)
 501                 {
 502                         if (self.field)
 503                                 strunzone(self.field);
 504                         self.field = strzone(argv(f + 1));
 505                 }
 506         }
 507         else
 508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 509 }
 510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 511 {
 512         GetCvars_handleString(thisname, f, field, name);
 513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 514                 if (thisname == name)
 515                 {
 516                         string s;
 517                         s = func(strcat1(self.field));
 518                         if (s != self.field)
 519                         {
 520                                 strunzone(self.field);
 521                                 self.field = strzone(s);
 522                         }
 523                 }
 524 }
 525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 526 {
 527         if (f < 0)
 528         {
 529         }
 530         else if (f > 0)
 531         {
 532                 if (thisname == name)
 533                         self.field = stof(argv(f + 1));
 534         }
 535         else
 536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 537 }
 538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 539 {
 540         if (f < 0)
 541         {
 542         }
 543         else if (f > 0)
 544         {
 545                 if (thisname == name)
 546                 {
 547                         if(!self.field)
 548                         {
 549                                 self.field = stof(argv(f + 1));
 550                                 if(!self.field)
 551                                         self.field = -1;
 552                         }
 553                 }
 554         }
 555         else
 556         {
 557                 if(!self.field)
 558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559         }
 560 }
 561 float w_getbestweapon(entity e);
 562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 563 {
 564         string o;
 565         o = W_FixWeaponOrder_ForceComplete(wo);
 566         if(self.weaponorder_byimpulse)
 567         {
 568                 strunzone(self.weaponorder_byimpulse);
 569                 self.weaponorder_byimpulse = string_null;
 570         }
 571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 572         return o;
 573 }
 574 void GetCvars(float f)
 575 {
 576         string s;
 577
 578         if (f > 0)
 579                 s = strcat1(argv(f));
 580
 581         get_cvars_f = f;
 582         get_cvars_s = s;
 583         MUTATOR_CALLHOOK(GetCvars);
 584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 609
 610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 612
 613 #ifdef ALLOW_FORCEMODELS
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 616 #endif
 617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 619
 620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 621         if (f > 0)
 622         {
 623                 if (s == "cl_weaponpriority")
 624                         self.switchweapon = w_getbestweapon(self);
 625         }
 626 }
 627
 628 float fexists(string f)
 629 {
 630     float fh;
 631     fh = fopen(f, FILE_READ);
 632     if (fh < 0)
 633         return FALSE;
 634     fclose(fh);
 635     return TRUE;
 636 }
 637
 638 void backtrace(string msg)
 639 {
 640     float dev, war;
 641     dev = autocvar_developer;
 642     war = autocvar_prvm_backtraceforwarnings;
 643     cvar_set("developer", "1");
 644     cvar_set("prvm_backtraceforwarnings", "1");
 645     print("\n");
 646     print("--- CUT HERE ---\nWARNING: ");
 647     print(msg);
 648     print("\n");
 649     remove(world); // isn't there any better way to cause a backtrace?
 650     print("\n--- CUT UNTIL HERE ---\n");
 651     cvar_set("developer", ftos(dev));
 652     cvar_set("prvm_backtraceforwarnings", ftos(war));
 653 }
 654
 655 string Team_ColorCode(float teamid)
 656 {
 657     if (teamid == COLOR_TEAM1)
 658         return "^1";
 659     else if (teamid == COLOR_TEAM2)
 660         return "^4";
 661     else if (teamid == COLOR_TEAM3)
 662         return "^3";
 663     else if (teamid == COLOR_TEAM4)
 664         return "^6";
 665     else
 666         return "^7";
 667 }
 668
 669 string Team_ColorName(float t)
 670 {
 671     // fixme: Search for team entities and get their .netname's!
 672     if (t == COLOR_TEAM1)
 673         return "Red";
 674     if (t == COLOR_TEAM2)
 675         return "Blue";
 676     if (t == COLOR_TEAM3)
 677         return "Yellow";
 678     if (t == COLOR_TEAM4)
 679         return "Pink";
 680     return "Neutral";
 681 }
 682
 683 string Team_ColorNameLowerCase(float t)
 684 {
 685     // fixme: Search for team entities and get their .netname's!
 686     if (t == COLOR_TEAM1)
 687         return "red";
 688     if (t == COLOR_TEAM2)
 689         return "blue";
 690     if (t == COLOR_TEAM3)
 691         return "yellow";
 692     if (t == COLOR_TEAM4)
 693         return "pink";
 694     return "neutral";
 695 }
 696
 697 float ColourToNumber(string team_colour)
 698 {
 699         if (team_colour == "red")
 700                 return COLOR_TEAM1;
 701
 702         if (team_colour == "blue")
 703                 return COLOR_TEAM2;
 704
 705         if (team_colour == "yellow")
 706                 return COLOR_TEAM3;
 707
 708         if (team_colour == "pink")
 709                 return COLOR_TEAM4;
 710
 711         if (team_colour == "auto")
 712                 return 0;
 713
 714         return -1;
 715 }
 716
 717 float NumberToTeamNumber(float number)
 718 {
 719         if (number == 1)
 720                 return COLOR_TEAM1;
 721
 722         if (number == 2)
 723                 return COLOR_TEAM2;
 724
 725         if (number == 3)
 726                 return COLOR_TEAM3;
 727
 728         if (number == 4)
 729                 return COLOR_TEAM4;
 730
 731         return -1;
 732 }
 733
 734 #define CENTERPRIO_POINT 1
 735 #define CENTERPRIO_SPAM 2
 736 #define CENTERPRIO_VOTE 4
 737 #define CENTERPRIO_NORMAL 5
 738 #define CENTERPRIO_SHIELDING 7
 739 #define CENTERPRIO_MAPVOTE 9
 740 #define CENTERPRIO_IDLEKICK 50
 741 #define CENTERPRIO_ADMIN 99
 742 .float centerprint_priority;
 743 .float centerprint_expires;
 744 void centerprint_atprio(entity e, float prio, string s)
 745 {
 746     if (intermission_running)
 747         if (prio < CENTERPRIO_MAPVOTE)
 748             return;
 749     if (time > e.centerprint_expires)
 750         e.centerprint_priority = 0;
 751     if (prio >= e.centerprint_priority)
 752     {
 753         e.centerprint_priority = prio;
 754         if (timeoutStatus == 2)
 755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 756         else
 757             e.centerprint_expires = time + e.cvar_scr_centertime;
 758         centerprint_builtin(e, s);
 759     }
 760 }
 761 void centerprint_expire(entity e, float prio)
 762 {
 763     if (prio == e.centerprint_priority)
 764     {
 765         e.centerprint_priority = 0;
 766         centerprint_builtin(e, "");
 767     }
 768 }
 769 void centerprint(entity e, string s)
 770 {
 771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 772 }
 773
 774 // decolorizes and team colors the player name when needed
 775 string playername(entity p)
 776 {
 777     string t;
 778     if (teams_matter && !intermission_running && p.classname == "player")
 779     {
 780         t = Team_ColorCode(p.team);
 781         return strcat(t, strdecolorize(p.netname));
 782     }
 783     else
 784         return p.netname;
 785 }
 786
 787 vector randompos(vector m1, vector m2)
 788 {
 789     local vector v;
 790     m2 = m2 - m1;
 791     v_x = m2_x * random() + m1_x;
 792     v_y = m2_y * random() + m1_y;
 793     v_z = m2_z * random() + m1_z;
 794     return  v;
 795 };
 796
 797 //#NO AUTOCVARS START
 798
 799 float g_pickup_shells;
 800 float g_pickup_shells_max;
 801 float g_pickup_nails;
 802 float g_pickup_nails_max;
 803 float g_pickup_rockets;
 804 float g_pickup_rockets_max;
 805 float g_pickup_cells;
 806 float g_pickup_cells_max;
 807 float g_pickup_fuel;
 808 float g_pickup_fuel_jetpack;
 809 float g_pickup_fuel_max;
 810 float g_pickup_armorsmall;
 811 float g_pickup_armorsmall_max;
 812 float g_pickup_armorsmall_anyway;
 813 float g_pickup_armormedium;
 814 float g_pickup_armormedium_max;
 815 float g_pickup_armormedium_anyway;
 816 float g_pickup_armorbig;
 817 float g_pickup_armorbig_max;
 818 float g_pickup_armorbig_anyway;
 819 float g_pickup_armorlarge;
 820 float g_pickup_armorlarge_max;
 821 float g_pickup_armorlarge_anyway;
 822 float g_pickup_healthsmall;
 823 float g_pickup_healthsmall_max;
 824 float g_pickup_healthsmall_anyway;
 825 float g_pickup_healthmedium;
 826 float g_pickup_healthmedium_max;
 827 float g_pickup_healthmedium_anyway;
 828 float g_pickup_healthlarge;
 829 float g_pickup_healthlarge_max;
 830 float g_pickup_healthlarge_anyway;
 831 float g_pickup_healthmega;
 832 float g_pickup_healthmega_max;
 833 float g_pickup_healthmega_anyway;
 834 float g_pickup_ammo_anyway;
 835 float g_pickup_weapons_anyway;
 836 float g_weaponarena;
 837 float g_weaponarena_random;
 838 float g_weaponarena_random_with_laser;
 839 string g_weaponarena_list;
 840 float g_weaponspeedfactor;
 841 float g_weaponratefactor;
 842 float g_weapondamagefactor;
 843 float g_weaponforcefactor;
 844 float g_weaponspreadfactor;
 845
 846 float start_weapons;
 847 float start_items;
 848 float start_ammo_shells;
 849 float start_ammo_nails;
 850 float start_ammo_rockets;
 851 float start_ammo_cells;
 852 float start_ammo_fuel;
 853 float start_health;
 854 float start_armorvalue;
 855 float warmup_start_weapons;
 856 float warmup_start_ammo_shells;
 857 float warmup_start_ammo_nails;
 858 float warmup_start_ammo_rockets;
 859 float warmup_start_ammo_cells;
 860 float warmup_start_ammo_fuel;
 861 float warmup_start_health;
 862 float warmup_start_armorvalue;
 863 float g_weapon_stay;
 864 float g_ghost_items;
 865
 866 entity get_weaponinfo(float w);
 867
 868 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 869 {
 870         var float i = weaponinfo.weapon;
 871
 872         if (!i)
 873                 return 0;
 874
 875         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 876
 877         if (t < 0) // "default" weapon selection
 878         {
 879                 if (g_lms || g_ca || allguns)
 880                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 881                 else if(t < -1)
 882                         t = 0;
 883                 else if (g_cts)
 884                         t = (i == WEP_SHOTGUN);
 885                 else if (g_nexball)
 886                         t = 0; // weapon is set a few lines later
 887                 else
 888                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 889                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 890                         t |= (i == WEP_HOOK);
 891         }
 892
 893         // we cannot disable porto in Nexball, we must force it
 894         if(g_nexball && i == WEP_PORTO)
 895                 t = 1;
 896
 897         return t;
 898 }
 899
 900 void readplayerstartcvars()
 901 {
 902         entity e;
 903         float i, j, t;
 904         string s;
 905
 906         // initialize starting values for players
 907         start_weapons = 0;
 908         start_items = 0;
 909         start_ammo_shells = 0;
 910         start_ammo_nails = 0;
 911         start_ammo_rockets = 0;
 912         start_ammo_cells = 0;
 913         start_health = cvar("g_balance_health_start");
 914         start_armorvalue = cvar("g_balance_armor_start");
 915
 916         g_weaponarena = 0;
 917         s = cvar_string("g_weaponarena");
 918         if (s == "0")
 919         {
 920         }
 921         else if (s == "all")
 922         {
 923                 g_weaponarena_list = "All Weapons";
 924                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 925                 {
 926                         e = get_weaponinfo(j);
 927                         g_weaponarena |= e.weapons;
 928                         weapon_action(e.weapon, WR_PRECACHE);
 929                 }
 930         }
 931         else if (s == "most")
 932         {
 933                 g_weaponarena_list = "Most Weapons";
 934                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 935                 {
 936                         e = get_weaponinfo(j);
 937                         if (e.spawnflags & WEP_FLAG_NORMAL)
 938                         {
 939                                 g_weaponarena |= e.weapons;
 940                                 weapon_action(e.weapon, WR_PRECACHE);
 941                         }
 942                 }
 943         }
 944         else if (s == "none")
 945         {
 946                 g_weaponarena_list = "No Weapons";
 947                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 948         }
 949         else
 950         {
 951                 t = tokenize_console(s);
 952                 g_weaponarena_list = "";
 953                 for (i = 0; i < t; ++i)
 954                 {
 955                         s = argv(i);
 956                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 957                         {
 958                                 e = get_weaponinfo(j);
 959                                 if (e.netname == s)
 960                                 {
 961                                         g_weaponarena |= e.weapons;
 962                                         weapon_action(e.weapon, WR_PRECACHE);
 963                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 964                                         break;
 965                                 }
 966                         }
 967                         if (j > WEP_LAST)
 968                         {
 969                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 970                         }
 971                 }
 972                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 973         }
 974
 975         if(g_weaponarena)
 976                 g_weaponarena_random = cvar("g_weaponarena_random");
 977         else
 978                 g_weaponarena_random = 0;
 979         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 980
 981         if (g_weaponarena)
 982         {
 983                 start_weapons = g_weaponarena;
 984                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 985                 {
 986                         e = get_weaponinfo(j);
 987                         if(start_weapons & e.weapons)
 988                         {
 989                                 if(e.items & IT_ROCKETS)
 990                                         start_ammo_rockets = 999;
 991                                 if(e.items & IT_SHELLS)
 992                                         start_ammo_shells = 999;
 993                                 if(e.items & IT_CELLS)
 994                                         start_ammo_cells = 999;
 995                                 if(e.items & IT_NAILS)
 996                                         start_ammo_nails = 999;
 997                                 if(e.items & IT_FUEL)
 998                                         start_ammo_fuel = 999;
 999                         }
1000                 }
1001                 start_items |= IT_UNLIMITED_AMMO;
1002         }
1003         else if (g_minstagib)
1004         {
1005                 start_health = 100;
1006                 start_armorvalue = 0;
1007                 start_weapons = WEPBIT_MINSTANEX;
1008                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1009                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1010                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1011                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1012
1013                 if (g_minstagib_invis_alpha <= 0)
1014                         g_minstagib_invis_alpha = -1;
1015         }
1016         else
1017         {
1018                 if (g_lms || g_ca)
1019                 {
1020                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1021                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1022                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1023                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1024                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1025                         start_health = cvar("g_lms_start_health");
1026                         start_armorvalue = cvar("g_lms_start_armor");
1027                 }
1028                 else
1029                 {
1030                         start_ammo_shells = cvar("g_start_ammo_shells");
1031                         start_ammo_nails = cvar("g_start_ammo_nails");
1032                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1033                         start_ammo_cells = cvar("g_start_ammo_cells");
1034                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1035                 }
1036
1037                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1038                 {
1039                         e = get_weaponinfo(i);
1040                         if(want_weapon("g_start_weapon_", e, FALSE))
1041                                 start_weapons |= e.weapons;
1042                 }
1043         }
1044
1045         if (inWarmupStage)
1046         {
1047                 warmup_start_ammo_shells = start_ammo_shells;
1048                 warmup_start_ammo_nails = start_ammo_nails;
1049                 warmup_start_ammo_rockets = start_ammo_rockets;
1050                 warmup_start_ammo_cells = start_ammo_cells;
1051                 warmup_start_ammo_fuel = start_ammo_fuel;
1052                 warmup_start_health = start_health;
1053                 warmup_start_armorvalue = start_armorvalue;
1054                 warmup_start_weapons = start_weapons;
1055
1056                 if (!g_weaponarena && !g_minstagib && !g_ca)
1057                 {
1058                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1059                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1060                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1061                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1062                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1063                         warmup_start_health = cvar("g_warmup_start_health");
1064                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1065                         warmup_start_weapons = 0;
1066                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1067                         {
1068                                 e = get_weaponinfo(i);
1069                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1070                                         warmup_start_weapons |= e.weapons;
1071                         }
1072                 }
1073         }
1074
1075         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1076         {
1077                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1078                 start_items |= IT_FUEL_REGEN;
1079                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1080                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1081         }
1082
1083         if(!cvar("g_use_ammunition"))
1084         {
1085                 start_ammo_shells = cvar("g_pickup_shells_max");
1086                 start_ammo_nails = cvar("g_pickup_nails_max");
1087                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1088                 start_ammo_cells = cvar("g_pickup_cells_max");
1089                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1090                 start_items |= IT_UNLIMITED_AMMO;
1091                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1092                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1093                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1094                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1095                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1096                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1097         }
1098
1099         if (g_jetpack)
1100                 start_items |= IT_JETPACK;
1101
1102         if (g_weapon_stay == 2)
1103         {
1104                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1105                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1106                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1107                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1108                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1109                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1110                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1111                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1112                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1113                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1114         }
1115
1116         MUTATOR_CALLHOOK(SetStartItems);
1117
1118         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1119         {
1120                 e = get_weaponinfo(i);
1121                 if(e.weapons & (start_weapons | warmup_start_weapons))
1122                         weapon_action(e.weapon, WR_PRECACHE);
1123         }
1124
1125         start_ammo_shells = max(0, start_ammo_shells);
1126         start_ammo_nails = max(0, start_ammo_nails);
1127         start_ammo_cells = max(0, start_ammo_cells);
1128         start_ammo_rockets = max(0, start_ammo_rockets);
1129         start_ammo_fuel = max(0, start_ammo_fuel);
1130
1131         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1132         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1133         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1134         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1135         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1136 }
1137
1138 float g_bugrigs;
1139 float g_bugrigs_planar_movement;
1140 float g_bugrigs_planar_movement_car_jumping;
1141 float g_bugrigs_reverse_spinning;
1142 float g_bugrigs_reverse_speeding;
1143 float g_bugrigs_reverse_stopping;
1144 float g_bugrigs_air_steering;
1145 float g_bugrigs_angle_smoothing;
1146 float g_bugrigs_friction_floor;
1147 float g_bugrigs_friction_brake;
1148 float g_bugrigs_friction_air;
1149 float g_bugrigs_accel;
1150 float g_bugrigs_speed_ref;
1151 float g_bugrigs_speed_pow;
1152 float g_bugrigs_steer;
1153
1154 float g_touchexplode;
1155 float g_touchexplode_radius;
1156 float g_touchexplode_damage;
1157 float g_touchexplode_edgedamage;
1158 float g_touchexplode_force;
1159
1160 float sv_autotaunt;
1161 float sv_taunt;
1162
1163 float sv_pitch_min;
1164 float sv_pitch_max;
1165 float sv_pitch_fixyaw;
1166
1167 string GetGametype(); // g_world.qc
1168 void readlevelcvars(void)
1169 {
1170         // first load all the mutators
1171         if(cvar("g_nix"))
1172                 MUTATOR_ADD(mutator_nix);
1173         if(cvar("g_dodging"))
1174                 MUTATOR_ADD(mutator_dodging);
1175         if(cvar("g_rocket_flying"))
1176                 MUTATOR_ADD(mutator_rocketflying);
1177         if(cvar("g_vampire"))
1178                 MUTATOR_ADD(mutator_vampire);
1179
1180         if(cvar("sv_allow_fullbright"))
1181                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1182
1183     g_bugrigs = cvar("g_bugrigs");
1184     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1185     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1186     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1187     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1188     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1189     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1190     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1191     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1192     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1193     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1194     g_bugrigs_accel = cvar("g_bugrigs_accel");
1195     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1196     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1197     g_bugrigs_steer = cvar("g_bugrigs_steer");
1198
1199     g_touchexplode = cvar("g_touchexplode");
1200     g_touchexplode_radius = cvar("g_touchexplode_radius");
1201     g_touchexplode_damage = cvar("g_touchexplode_damage");
1202     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1203     g_touchexplode_force = cvar("g_touchexplode_force");
1204
1205 #ifdef ALLOW_FORCEMODELS
1206         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1207 #endif
1208         sv_loddistance1 = cvar("sv_loddistance1");
1209         sv_loddistance2 = cvar("sv_loddistance2");
1210
1211         if(sv_loddistance2 <= sv_loddistance1)
1212                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1213
1214         sv_clones = cvar("sv_clones");
1215         sv_gentle = cvar("sv_gentle");
1216         sv_foginterval = cvar("sv_foginterval");
1217         g_cloaked = cvar("g_cloaked");
1218     if(g_cts)
1219         g_cloaked = 1; // always enable cloak in CTS
1220         g_jump_grunt = cvar("g_jump_grunt");
1221         g_footsteps = cvar("g_footsteps");
1222         g_grappling_hook = cvar("g_grappling_hook");
1223         g_jetpack = cvar("g_jetpack");
1224         g_midair = cvar("g_midair");
1225         g_minstagib = cvar("g_minstagib");
1226         g_norecoil = cvar("g_norecoil");
1227         g_bloodloss = cvar("g_bloodloss");
1228         sv_maxidle = cvar("sv_maxidle");
1229         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1230         sv_pogostick = cvar("sv_pogostick");
1231         g_ctf_reverse = cvar("g_ctf_reverse");
1232         sv_autotaunt = cvar("sv_autotaunt");
1233         sv_taunt = cvar("sv_taunt");
1234
1235         inWarmupStage = cvar("g_warmup");
1236         g_warmup_limit = cvar("g_warmup_limit");
1237         g_warmup_allguns = cvar("g_warmup_allguns");
1238         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1239
1240         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1241                 inWarmupStage = 0; // these modes cannot work together, sorry
1242
1243         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1244         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1245         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1246         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1247         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1248         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1249         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1250         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1251         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1252         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1253         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1254         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1255
1256         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1257         g_weaponratefactor = cvar("g_weaponratefactor");
1258         g_weapondamagefactor = cvar("g_weapondamagefactor");
1259         g_weaponforcefactor = cvar("g_weaponforcefactor");
1260         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1261
1262         g_pickup_shells = cvar("g_pickup_shells");
1263         g_pickup_shells_max = cvar("g_pickup_shells_max");
1264         g_pickup_nails = cvar("g_pickup_nails");
1265         g_pickup_nails_max = cvar("g_pickup_nails_max");
1266         g_pickup_rockets = cvar("g_pickup_rockets");
1267         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1268         g_pickup_cells = cvar("g_pickup_cells");
1269         g_pickup_cells_max = cvar("g_pickup_cells_max");
1270         g_pickup_fuel = cvar("g_pickup_fuel");
1271         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1272         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1273         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1274         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1275         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1276         g_pickup_armormedium = cvar("g_pickup_armormedium");
1277         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1278         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1279         g_pickup_armorbig = cvar("g_pickup_armorbig");
1280         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1281         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1282         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1283         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1284         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1285         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1286         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1287         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1288         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1289         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1290         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1291         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1292         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1293         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1294         g_pickup_healthmega = cvar("g_pickup_healthmega");
1295         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1296         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1297
1298         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1299         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1300
1301         g_pinata = cvar("g_pinata");
1302
1303     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1304     if(!g_weapon_stay)
1305         g_weapon_stay = cvar("g_weapon_stay");
1306
1307         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1308                 g_weapon_stay = 1;
1309
1310         g_ghost_items = cvar("g_ghost_items");
1311
1312         if(g_ghost_items >= 1)
1313                 g_ghost_items = 0.25; // default alpha value
1314
1315         if not(inWarmupStage && !g_ca)
1316                 game_starttime = cvar("g_start_delay");
1317
1318         sv_pitch_min = cvar("sv_pitch_min");
1319         sv_pitch_max = cvar("sv_pitch_max");
1320         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1321
1322         readplayerstartcvars();
1323 }
1324
1325 //#NO AUTOCVARS END
1326
1327 // Sound functions
1328 string precache_sound (string s) = #19;
1329 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1330 float precache_sound_index (string s) = #19;
1331
1332 #define SND_VOLUME      1
1333 #define SND_ATTENUATION 2
1334 #define SND_LARGEENTITY 8
1335 #define SND_LARGESOUND  16
1336
1337 float sound_allowed(float dest, entity e)
1338 {
1339     // sounds from world may always pass
1340     for (;;)
1341     {
1342         if (e.classname == "body")
1343             e = e.enemy;
1344         if (e.owner && e.owner != e)
1345             e = e.owner;
1346         else
1347             break;
1348     }
1349     // sounds to self may always pass
1350     if (dest == MSG_ONE)
1351         if (e == msg_entity)
1352             return TRUE;
1353     // sounds by players can be removed
1354     if (autocvar_bot_sound_monopoly)
1355         if (clienttype(e) == CLIENTTYPE_REAL)
1356             return FALSE;
1357     // anything else may pass
1358     return TRUE;
1359 }
1360
1361 void sound(entity e, float chan, string samp, float vol, float atten)
1362 {
1363     if (!sound_allowed(MSG_BROADCAST, e))
1364         return;
1365     sound_builtin(e, chan, samp, vol, atten);
1366 }
1367 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1368 {
1369     float entno, idx;
1370
1371     if (!sound_allowed(dest, e))
1372         return;
1373
1374     entno = num_for_edict(e);
1375     idx = precache_sound_index(samp);
1376
1377     float sflags;
1378     sflags = 0;
1379
1380     atten = floor(atten * 64);
1381     vol = floor(vol * 255);
1382
1383     if (vol != 255)
1384         sflags |= SND_VOLUME;
1385     if (atten != 64)
1386         sflags |= SND_ATTENUATION;
1387     if (entno >= 8192)
1388         sflags |= SND_LARGEENTITY;
1389     if (idx >= 256)
1390         sflags |= SND_LARGESOUND;
1391
1392     WriteByte(dest, SVC_SOUND);
1393     WriteByte(dest, sflags);
1394     if (sflags & SND_VOLUME)
1395         WriteByte(dest, vol);
1396     if (sflags & SND_ATTENUATION)
1397         WriteByte(dest, atten);
1398     if (sflags & SND_LARGEENTITY)
1399     {
1400         WriteShort(dest, entno);
1401         WriteByte(dest, chan);
1402     }
1403     else
1404     {
1405         WriteShort(dest, entno * 8 + chan);
1406     }
1407     if (sflags & SND_LARGESOUND)
1408         WriteShort(dest, idx);
1409     else
1410         WriteByte(dest, idx);
1411
1412     WriteCoord(dest, o_x);
1413     WriteCoord(dest, o_y);
1414     WriteCoord(dest, o_z);
1415 }
1416 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1417 {
1418     vector o;
1419
1420     if (!sound_allowed(dest, e))
1421         return;
1422
1423     o = e.origin + 0.5 * (e.mins + e.maxs);
1424     soundtoat(dest, e, o, chan, samp, vol, atten);
1425 }
1426 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1427 {
1428     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1429 }
1430 void stopsoundto(float dest, entity e, float chan)
1431 {
1432     float entno;
1433
1434     if (!sound_allowed(dest, e))
1435         return;
1436
1437     entno = num_for_edict(e);
1438
1439     if (entno >= 8192)
1440     {
1441         float idx, sflags;
1442         idx = precache_sound_index("misc/null.wav");
1443         sflags = SND_LARGEENTITY;
1444         if (idx >= 256)
1445             sflags |= SND_LARGESOUND;
1446         WriteByte(dest, SVC_SOUND);
1447         WriteByte(dest, sflags);
1448         WriteShort(dest, entno);
1449         WriteByte(dest, chan);
1450         if (sflags & SND_LARGESOUND)
1451             WriteShort(dest, idx);
1452         else
1453             WriteByte(dest, idx);
1454         WriteCoord(dest, e.origin_x);
1455         WriteCoord(dest, e.origin_y);
1456         WriteCoord(dest, e.origin_z);
1457     }
1458     else
1459     {
1460         WriteByte(dest, SVC_STOPSOUND);
1461         WriteShort(dest, entno * 8 + chan);
1462     }
1463 }
1464 void stopsound(entity e, float chan)
1465 {
1466     if (!sound_allowed(MSG_BROADCAST, e))
1467         return;
1468
1469     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1470     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1471 }
1472
1473 void play2(entity e, string filename)
1474 {
1475     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1476     msg_entity = e;
1477     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1478 }
1479
1480 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1481 .float spamtime;
1482 float spamsound(entity e, float chan, string samp, float vol, float atten)
1483 {
1484     if (!sound_allowed(MSG_BROADCAST, e))
1485         return FALSE;
1486
1487     if (time > e.spamtime)
1488     {
1489         e.spamtime = time;
1490         sound(e, chan, samp, vol, atten);
1491         return TRUE;
1492     }
1493     return FALSE;
1494 }
1495
1496 void play2team(float t, string filename)
1497 {
1498     local entity head;
1499
1500     if (autocvar_bot_sound_monopoly)
1501         return;
1502
1503     FOR_EACH_REALPLAYER(head)
1504     {
1505         if (head.team == t)
1506             play2(head, filename);
1507     }
1508 }
1509
1510 void play2all(string samp)
1511 {
1512     if (autocvar_bot_sound_monopoly)
1513         return;
1514
1515     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1516 }
1517
1518 void PrecachePlayerSounds(string f);
1519 void precache_playermodel(string m)
1520 {
1521         float globhandle, i, n;
1522         string f;
1523
1524         if(substring(m, -9,5) == "_lod1")
1525                 return;
1526         if(substring(m, -9,5) == "_lod2")
1527                 return;
1528         precache_model(m);
1529         if(sv_loddistance1)
1530         {
1531                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1532                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1533         }
1534
1535         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1536         if (globhandle < 0)
1537                 return;
1538         n = search_getsize(globhandle);
1539         for (i = 0; i < n; ++i)
1540         {
1541                 //print(search_getfilename(globhandle, i), "\n");
1542                 f = search_getfilename(globhandle, i);
1543                 PrecachePlayerSounds(f);
1544         }
1545         search_end(globhandle);
1546 }
1547 void precache_all_playermodels(string pattern)
1548 {
1549         float globhandle, i, n;
1550         string f;
1551
1552         globhandle = search_begin(pattern, TRUE, FALSE);
1553         if (globhandle < 0)
1554                 return;
1555         n = search_getsize(globhandle);
1556         for (i = 0; i < n; ++i)
1557         {
1558                 //print(search_getfilename(globhandle, i), "\n");
1559                 f = search_getfilename(globhandle, i);
1560                 precache_playermodel(f);
1561         }
1562         search_end(globhandle);
1563 }
1564
1565 void precache()
1566 {
1567     // gamemode related things
1568     precache_model ("models/misc/chatbubble.spr");
1569     precache_model ("models/misc/teambubble.spr");
1570     if (g_runematch)
1571     {
1572         precache_model ("models/runematch/curse.mdl");
1573         precache_model ("models/runematch/rune.mdl");
1574     }
1575
1576 #ifdef TTURRETS_ENABLED
1577     if (autocvar_g_turrets)
1578         turrets_precash();
1579 #endif
1580
1581     // Precache all player models if desired
1582     if (autocvar_sv_precacheplayermodels)
1583     {
1584         PrecachePlayerSounds("sound/player/default.sounds");
1585         precache_all_playermodels("models/player/*.zym");
1586         precache_all_playermodels("models/player/*.dpm");
1587         precache_all_playermodels("models/player/*.md3");
1588         precache_all_playermodels("models/player/*.psk");
1589         precache_all_playermodels("models/player/*.iqm");
1590     }
1591
1592     if (autocvar_sv_defaultcharacter)
1593     {
1594         string s;
1595         s = autocvar_sv_defaultplayermodel_red;
1596         if (s != "")
1597             precache_playermodel(s);
1598         s = autocvar_sv_defaultplayermodel_blue;
1599         if (s != "")
1600             precache_playermodel(s);
1601         s = autocvar_sv_defaultplayermodel_yellow;
1602         if (s != "")
1603             precache_playermodel(s);
1604         s = autocvar_sv_defaultplayermodel_pink;
1605         if (s != "")
1606             precache_playermodel(s);
1607         s = autocvar_sv_defaultplayermodel;
1608         if (s != "")
1609             precache_playermodel(s);
1610     }
1611
1612     if (g_footsteps)
1613     {
1614         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1615         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1616     }
1617
1618     // gore and miscellaneous sounds
1619     //precache_sound ("misc/h2ohit.wav");
1620     precache_model ("models/hook.md3");
1621     precache_sound ("misc/armorimpact.wav");
1622     precache_sound ("misc/bodyimpact1.wav");
1623     precache_sound ("misc/bodyimpact2.wav");
1624     precache_sound ("misc/gib.wav");
1625     precache_sound ("misc/gib_splat01.wav");
1626     precache_sound ("misc/gib_splat02.wav");
1627     precache_sound ("misc/gib_splat03.wav");
1628     precache_sound ("misc/gib_splat04.wav");
1629     precache_sound ("misc/hit.wav");
1630         precache_sound ("misc/typehit.wav");
1631     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1632     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1633     precache_sound ("misc/null.wav");
1634     precache_sound ("misc/spawn.wav");
1635     precache_sound ("misc/talk.wav");
1636     precache_sound ("misc/teleport.wav");
1637     precache_sound ("misc/poweroff.wav");
1638     precache_sound ("player/lava.wav");
1639     precache_sound ("player/slime.wav");
1640
1641     if (g_jetpack)
1642         precache_sound ("misc/jetpack_fly.wav");
1643
1644     precache_model ("models/sprites/0.spr32");
1645     precache_model ("models/sprites/1.spr32");
1646     precache_model ("models/sprites/2.spr32");
1647     precache_model ("models/sprites/3.spr32");
1648     precache_model ("models/sprites/4.spr32");
1649     precache_model ("models/sprites/5.spr32");
1650     precache_model ("models/sprites/6.spr32");
1651     precache_model ("models/sprites/7.spr32");
1652     precache_model ("models/sprites/8.spr32");
1653     precache_model ("models/sprites/9.spr32");
1654     precache_model ("models/sprites/10.spr32");
1655
1656     // common weapon precaches
1657     precache_sound ("weapons/weapon_switch.wav");
1658     precache_sound ("weapons/weaponpickup.wav");
1659     precache_sound ("weapons/unavailable.wav");
1660     precache_sound ("weapons/dryfire.wav");
1661     if (g_grappling_hook)
1662     {
1663         precache_sound ("weapons/hook_fire.wav"); // hook
1664         precache_sound ("weapons/hook_impact.wav"); // hook
1665     }
1666
1667     if(autocvar_sv_precacheweapons)
1668     {
1669         //precache weapon models/sounds
1670         local float wep;
1671         wep = WEP_FIRST;
1672         while (wep <= WEP_LAST)
1673         {
1674             weapon_action(wep, WR_PRECACHE);
1675             wep = wep + 1;
1676         }
1677     }
1678
1679     precache_model("models/elaser.mdl");
1680     precache_model("models/laser.mdl");
1681     precache_model("models/ebomb.mdl");
1682
1683 #if 0
1684     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1685
1686     if (!self.noise && self.music) // quake 3 uses the music field
1687         self.noise = self.music;
1688
1689     // plays music for the level if there is any
1690     if (self.noise)
1691     {
1692         precache_sound (self.noise);
1693         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1694     }
1695 #endif
1696 }
1697
1698 // sorry, but using \ in macros breaks line numbers
1699 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1700 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1701 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1702
1703 // WARNING: this kills the trace globals
1704 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1705 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1706
1707 #define INITPRIO_FIRST              0
1708 #define INITPRIO_GAMETYPE           0
1709 #define INITPRIO_GAMETYPE_FALLBACK  1
1710 #define INITPRIO_FINDTARGET        10
1711 #define INITPRIO_DROPTOFLOOR       20
1712 #define INITPRIO_SETLOCATION       90
1713 #define INITPRIO_LINKDOORS         91
1714 #define INITPRIO_LAST              99
1715
1716 .void(void) initialize_entity;
1717 .float initialize_entity_order;
1718 .entity initialize_entity_next;
1719 entity initialize_entity_first;
1720
1721 void make_safe_for_remove(entity e)
1722 {
1723     if (e.initialize_entity)
1724     {
1725         entity ent, prev;
1726         for (ent = initialize_entity_first; ent; )
1727         {
1728             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1729             {
1730                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1731                 // skip it in linked list
1732                 if (prev)
1733                 {
1734                     prev.initialize_entity_next = ent.initialize_entity_next;
1735                     ent = prev.initialize_entity_next;
1736                 }
1737                 else
1738                 {
1739                     initialize_entity_first = ent.initialize_entity_next;
1740                     ent = initialize_entity_first;
1741                 }
1742             }
1743             else
1744             {
1745                 prev = ent;
1746                 ent = ent.initialize_entity_next;
1747             }
1748         }
1749     }
1750 }
1751
1752 void objerror(string s)
1753 {
1754     make_safe_for_remove(self);
1755     objerror_builtin(s);
1756 }
1757
1758 .float remove_except_protected_forbidden;
1759 void remove_except_protected(entity e)
1760 {
1761         if(e.remove_except_protected_forbidden)
1762                 error("not allowed to remove this at this point");
1763         remove_builtin(e);
1764 }
1765
1766 void remove_unsafely(entity e)
1767 {
1768     remove_builtin(e);
1769 }
1770
1771 void remove_safely(entity e)
1772 {
1773     make_safe_for_remove(e);
1774     remove_builtin(e);
1775 }
1776
1777 void InitializeEntity(entity e, void(void) func, float order)
1778 {
1779     entity prev, cur;
1780
1781     if (!e || e.initialize_entity)
1782     {
1783         // make a proxy initializer entity
1784         entity e_old;
1785         e_old = e;
1786         e = spawn();
1787         e.classname = "initialize_entity";
1788         e.enemy = e_old;
1789     }
1790
1791     e.initialize_entity = func;
1792     e.initialize_entity_order = order;
1793
1794     cur = initialize_entity_first;
1795     for (;;)
1796     {
1797         if (!cur || cur.initialize_entity_order > order)
1798         {
1799             // insert between prev and cur
1800             if (prev)
1801                 prev.initialize_entity_next = e;
1802             else
1803                 initialize_entity_first = e;
1804             e.initialize_entity_next = cur;
1805             return;
1806         }
1807         prev = cur;
1808         cur = cur.initialize_entity_next;
1809     }
1810 }
1811 void InitializeEntitiesRun()
1812 {
1813     entity startoflist;
1814     startoflist = initialize_entity_first;
1815     initialize_entity_first = world;
1816     remove = remove_except_protected;
1817     for (self = startoflist; self; self = self.initialize_entity_next)
1818     {
1819         self.remove_except_protected_forbidden = 1;
1820     }
1821     for (self = startoflist; self; )
1822     {
1823         entity e;
1824         var void(void) func;
1825         e = self.initialize_entity_next;
1826         func = self.initialize_entity;
1827         self.initialize_entity_order = 0;
1828         self.initialize_entity = func_null;
1829         self.initialize_entity_next = world;
1830         self.remove_except_protected_forbidden = 0;
1831         if (self.classname == "initialize_entity")
1832         {
1833             entity e_old;
1834             e_old = self.enemy;
1835             remove_builtin(self);
1836             self = e_old;
1837         }
1838         //dprint("Delayed initialization: ", self.classname, "\n");
1839         if(func != func_null)
1840             func();
1841         else
1842         {
1843             eprint(self);
1844             backtrace(strcat("Null function in: ", self.classname, "\n"));
1845         }
1846         self = e;
1847     }
1848     remove = remove_unsafely;
1849 }
1850
1851 .float uncustomizeentityforclient_set;
1852 .void(void) uncustomizeentityforclient;
1853 void(void) SUB_Nullpointer = #0;
1854 void UncustomizeEntitiesRun()
1855 {
1856     entity oldself;
1857     oldself = self;
1858     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1859         self.uncustomizeentityforclient();
1860     self = oldself;
1861 }
1862 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1863 {
1864     e.customizeentityforclient = customizer;
1865     e.uncustomizeentityforclient = uncustomizer;
1866     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1867 }
1868
1869 .float nottargeted;
1870 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1871
1872 void() SUB_Remove;
1873 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1874 {
1875     vector mi, ma;
1876
1877     if (e.classname == "")
1878         e.classname = "net_linked";
1879
1880     if (e.model == "" || self.modelindex == 0)
1881     {
1882         mi = e.mins;
1883         ma = e.maxs;
1884         setmodel(e, "null");
1885         setsize(e, mi, ma);
1886     }
1887
1888     e.SendEntity = sendfunc;
1889     e.SendFlags = 0xFFFFFF;
1890
1891     if (!docull)
1892         e.effects |= EF_NODEPTHTEST;
1893
1894     if (dt)
1895     {
1896         e.nextthink = time + dt;
1897         e.think = SUB_Remove;
1898     }
1899 }
1900
1901 void adaptor_think2touch()
1902 {
1903     entity o;
1904     o = other;
1905     other = world;
1906     self.touch();
1907     other = o;
1908 }
1909
1910 void adaptor_think2use()
1911 {
1912     entity o, a;
1913     o = other;
1914     a = activator;
1915     activator = world;
1916     other = world;
1917     self.use();
1918     other = o;
1919     activator = a;
1920 }
1921
1922 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1923 {
1924         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1925                 self.projectiledeathtype |= HITTYPE_SPLASH;
1926         adaptor_think2use();
1927 }
1928
1929 // deferred dropping
1930 void DropToFloor_Handler()
1931 {
1932     droptofloor_builtin();
1933     self.dropped_origin = self.origin;
1934 }
1935
1936 void droptofloor()
1937 {
1938     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1939 }
1940
1941
1942
1943 float trace_hits_box_a0, trace_hits_box_a1;
1944
1945 float trace_hits_box_1d(float end, float thmi, float thma)
1946 {
1947     if (end == 0)
1948     {
1949         // just check if x is in range
1950         if (0 < thmi)
1951             return FALSE;
1952         if (0 > thma)
1953             return FALSE;
1954     }
1955     else
1956     {
1957         // do the trace with respect to x
1958         // 0 -> end has to stay in thmi -> thma
1959         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1960         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1961         if (trace_hits_box_a0 > trace_hits_box_a1)
1962             return FALSE;
1963     }
1964     return TRUE;
1965 }
1966
1967 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1968 {
1969     end -= start;
1970     thmi -= start;
1971     thma -= start;
1972     // now it is a trace from 0 to end
1973
1974     trace_hits_box_a0 = 0;
1975     trace_hits_box_a1 = 1;
1976
1977     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1978         return FALSE;
1979     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1980         return FALSE;
1981     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1982         return FALSE;
1983
1984     return TRUE;
1985 }
1986
1987 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1988 {
1989     return trace_hits_box(start, end, thmi - ma, thma - mi);
1990 }
1991
1992 float SUB_NoImpactCheck()
1993 {
1994         // zero hitcontents = this is not the real impact, but either the
1995         // mirror-impact of something hitting the projectile instead of the
1996         // projectile hitting the something, or a touchareagrid one. Neither of
1997         // these stop the projectile from moving, so...
1998         if(trace_dphitcontents == 0)
1999         {
2000                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
2001                 checkclient();
2002         }
2003     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2004         return 1;
2005     if (other == world && self.size != '0 0 0')
2006     {
2007         vector tic;
2008         tic = self.velocity * sys_frametime;
2009         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2010         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2011         if (trace_fraction >= 1)
2012         {
2013             dprint("Odd... did not hit...?\n");
2014         }
2015         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2016         {
2017             dprint("Detected and prevented the sky-grapple bug.\n");
2018             return 1;
2019         }
2020     }
2021
2022     return 0;
2023 }
2024
2025 #define SUB_OwnerCheck() (other && (other == self.owner))
2026
2027 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2028 {
2029         if(SUB_OwnerCheck())
2030                 return TRUE;
2031         if(SUB_NoImpactCheck())
2032         {
2033                 remove(self);
2034                 return TRUE;
2035         }
2036         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2037                 UpdateCSQCProjectileNextFrame(self);
2038         return FALSE;
2039 }
2040 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2041
2042 float MAX_IPBAN_URIS           = 16;
2043
2044 float URI_GET_DISCARD          = 0;
2045 float URI_GET_IPBAN            = 1;
2046 float URI_GET_IPBAN_END        = 16;
2047 float URI_GET_PLAYERSTATS_SENT = 17;
2048
2049 void URI_Get_Callback(float id, float status, string data)
2050 {
2051     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2052     dprint(data);
2053     dprint("\nEnd of data.\n");
2054
2055     if (id == URI_GET_DISCARD)
2056     {
2057         // discard
2058     }
2059     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2060     {
2061         // online ban list
2062         OnlineBanList_URI_Get_Callback(id, status, data);
2063     }
2064     else if (id == URI_GET_PLAYERSTATS_SENT)
2065     {
2066         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2067     }
2068     else
2069     {
2070         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2071     }
2072 }
2073
2074 void print_to(entity e, string s)
2075 {
2076     if (e)
2077         sprint(e, strcat(s, "\n"));
2078     else
2079         print(s, "\n");
2080 }
2081
2082 string uid2name(string myuid) {
2083         string s;
2084         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2085
2086         if(s == "")
2087                 s = "^1Unregistered Player";
2088         return s;
2089 }
2090
2091 float race_readTime(string map, float pos)
2092 {
2093         string rr;
2094         if(g_cts)
2095                 rr = CTS_RECORD;
2096         else
2097                 rr = RACE_RECORD;
2098
2099         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2100 }
2101
2102 string race_readUID(string map, float pos)
2103 {
2104         string rr;
2105         if(g_cts)
2106                 rr = CTS_RECORD;
2107         else
2108                 rr = RACE_RECORD;
2109
2110         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2111 }
2112
2113 float race_readPos(string map, float t) {
2114         float i;
2115         for (i = 1; i <= RANKINGS_CNT; ++i)
2116                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2117                         return i;
2118
2119         return 0; // pos is zero if unranked
2120 }
2121
2122 void race_writeTime(string map, float t, string myuid)
2123 {
2124         string rr;
2125         if(g_cts)
2126                 rr = CTS_RECORD;
2127         else
2128                 rr = RACE_RECORD;
2129
2130         float newpos;
2131         newpos = race_readPos(map, t);
2132
2133         float i, prevpos;
2134         for(i = 1; i <= RANKINGS_CNT; ++i)
2135         {
2136                 if(race_readUID(map, i) == myuid)
2137                         prevpos = i;
2138         }
2139         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2140                 for (i = prevpos; i > newpos; --i) {
2141                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2142                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2143                 }
2144         } else { // player has no ranked record yet
2145                 for (i = RANKINGS_CNT; i > newpos; --i) {
2146                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2147                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2148                 }
2149         }
2150
2151         // store new time itself
2152         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2153         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2154 }
2155
2156 string race_readName(string map, float pos)
2157 {
2158         string rr;
2159         if(g_cts)
2160                 rr = CTS_RECORD;
2161         else
2162                 rr = RACE_RECORD;
2163
2164         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2165 }
2166
2167 string race_placeName(float pos) {
2168         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2169         {
2170                 if(mod(pos, 10) == 1)
2171                         return strcat(ftos(pos), "st");
2172                 else if(mod(pos, 10) == 2)
2173                         return strcat(ftos(pos), "nd");
2174                 else if(mod(pos, 10) == 3)
2175                         return strcat(ftos(pos), "rd");
2176                 else
2177                         return strcat(ftos(pos), "th");
2178         }
2179         else
2180                 return strcat(ftos(pos), "th");
2181 }
2182 string getrecords(float page) // 50 records per page
2183 {
2184     float rec;
2185     string h;
2186     float r;
2187     float i;
2188     string s;
2189
2190     rec = 0;
2191
2192     s = "";
2193
2194     if (g_ctf)
2195     {
2196         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2197         {
2198             if (MapInfo_Get_ByID(i))
2199             {
2200                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2201                 if (r == 0)
2202                     continue;
2203                 // TODO: uid2name
2204                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2205                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2206                 ++rec;
2207             }
2208         }
2209     }
2210
2211     if (g_race)
2212     {
2213         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2214         {
2215             if (MapInfo_Get_ByID(i))
2216             {
2217                 r = race_readTime(MapInfo_Map_bspname, 1);
2218                 if (r == 0)
2219                     continue;
2220                 h = race_readName(MapInfo_Map_bspname, 1);
2221                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2222                 ++rec;
2223             }
2224         }
2225     }
2226
2227     if (g_cts)
2228     {
2229         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2230         {
2231             if (MapInfo_Get_ByID(i))
2232             {
2233                 r = race_readTime(MapInfo_Map_bspname, 1);
2234                 if (r == 0)
2235                     continue;
2236                 h = race_readName(MapInfo_Map_bspname, 1);
2237                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2238                 ++rec;
2239             }
2240         }
2241     }
2242
2243     MapInfo_ClearTemps();
2244
2245     if (s == "" && page == 0)
2246         return "No records are available on this server.\n";
2247     else
2248         return s;
2249 }
2250
2251 string getrankings()
2252 {
2253     string n;
2254     float t;
2255     float i;
2256     string s;
2257     string p;
2258     string map;
2259
2260     s = "";
2261
2262     map = GetMapname();
2263
2264     for (i = 1; i <= RANKINGS_CNT; ++i)
2265     {
2266         t = race_readTime(map, i);
2267         if (t == 0)
2268             continue;
2269         n = race_readName(map, i);
2270         p = race_placeName(i);
2271         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2272     }
2273
2274     MapInfo_ClearTemps();
2275
2276     if (s == "")
2277         return strcat("No records are available for the map: ", map, "\n");
2278     else
2279         return strcat("Records for ", map, ":\n", s);
2280 }
2281
2282 #define LADDER_FIRSTPOINT 100
2283 #define LADDER_CNT 10
2284         // position X still gives LADDER_FIRSTPOINT/X points
2285 #define LADDER_SIZE 30
2286         // ladder shows the top X players
2287 string top_uids[LADDER_SIZE];
2288 float top_scores[LADDER_SIZE];
2289 string getladder()
2290 {
2291     float i, j, k, uidcnt;
2292     string s, temp_s;
2293
2294     s = "";
2295     temp_s = "";
2296
2297     string rr;
2298     if(g_cts)
2299         rr = CTS_RECORD;
2300     else
2301         rr = RACE_RECORD;
2302
2303     string myuid;
2304
2305     for (k = 0; k < MapInfo_count; ++k)
2306     {
2307         if (MapInfo_Get_ByID(k))
2308         {
2309                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2310                         if(i == 0) // speed award
2311                         {
2312                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2313                                         continue;
2314
2315                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2316                         }
2317                         else // normal record, if it exists (else break)
2318                         {
2319                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2320                                         continue;
2321
2322                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2323                         }
2324
2325                         // string s contains:
2326                         // arg 0 = # of speed recs
2327                         // arg 1 = # of 1st place recs
2328                         // arg 2 = # of 2nd place recs
2329                         // ... etc
2330                         // LADDER_CNT+1 = total points
2331
2332                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2333                         if (temp_s == "")
2334                         {
2335                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2336                             ++uidcnt;
2337                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2338                             {
2339                                 if(j != LADDER_CNT + 1)
2340                                     temp_s = strcat(temp_s, "0 ");
2341                                 else
2342                                     temp_s = strcat(temp_s, "0");
2343                             }
2344                         }
2345
2346                         tokenize_console(temp_s);
2347                         s = "";
2348
2349                         if(i == 0) // speed award
2350                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2351                             {
2352                                 if(j == 0) // speed award
2353                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2354                                 else
2355                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2356                             }
2357                         else // record
2358                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2359                             {
2360                                 if(j == 0)
2361                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2362                                 else if(j == i) // wanted rec!
2363                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2364                                 else
2365                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2366                             }
2367
2368                         // total points are (by default) calculated like this:
2369                         // speedrec = floor(100 / 10) = 10 points
2370                         // 1st place = floor(100 / 1) = 100 points
2371                         // 2nd place = floor(100 / 2) = 50 points
2372                         // 3rd place = floor(100 / 3) = 33 points
2373                         // 4th place = floor(100 / 4) = 25 points
2374                         // 5th place = floor(100 / 5) = 20 points
2375                         // ... etc
2376
2377                         if(i == 0)
2378                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2379                         else
2380                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2381
2382                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2383                 }
2384         }
2385     }
2386
2387     float thiscnt;
2388     string thisuid;
2389     for (i = 0; i <= uidcnt; ++i) // for each known uid
2390     {
2391         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2392         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2393         tokenize_console(temp_s);
2394         thiscnt = stof(argv(LADDER_CNT+1));
2395
2396         if(thiscnt > top_scores[LADDER_SIZE-1])
2397         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2398         {
2399             if(thiscnt > top_scores[j])
2400             {
2401                 for (k = LADDER_SIZE-1; k >= j; --k)
2402                 {
2403                     top_uids[k] = top_uids[k-1];
2404                     top_scores[k] = top_scores[k-1];
2405                 }
2406                 top_uids[j] = thisuid;
2407                 top_scores[j] = thiscnt;
2408                 break;
2409             }
2410         }
2411     }
2412
2413     s = "^3-----------------------\n\n";
2414
2415     s = strcat(s, "Pos ^3|");
2416     s = strcat(s, " ^7Total  ^3|");
2417     for (i = 1; i <= LADDER_CNT; ++i)
2418     {
2419         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2420     }
2421     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2422
2423     s = strcat(s, "\n^3----+--------");
2424     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2425     {
2426         s = strcat(s, "+-----");
2427     }
2428 #if LADDER_CNT > 9
2429     for (i = 1; i <= LADDER_CNT - 9; ++i)
2430     {
2431         s = strcat(s, "+------");
2432     }
2433 #endif
2434
2435     s = strcat(s, "+--------------+--------------------\n");
2436
2437     for (i = 0; i < LADDER_SIZE; ++i)
2438     {
2439         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2440         tokenize_console(temp_s);
2441         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2442             continue;
2443         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2444         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2445         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2446         {
2447             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2448         }
2449 #if LADDER_CNT > 9
2450         for (j = 10; j <= LADDER_CNT; ++j)
2451         {
2452             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2453         }
2454 #endif
2455
2456         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2457         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2458     }
2459
2460     MapInfo_ClearTemps();
2461
2462     if (s == "")
2463         return "No ladder on this server!\n";
2464     else
2465         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2466 }
2467
2468
2469 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2470 {
2471     float m, i;
2472     vector start, org, delta, end, enddown, mstart;
2473
2474     m = e.dphitcontentsmask;
2475     e.dphitcontentsmask = goodcontents | badcontents;
2476
2477     org = world.mins;
2478     delta = world.maxs - world.mins;
2479
2480     for (i = 0; i < attempts; ++i)
2481     {
2482         start_x = org_x + random() * delta_x;
2483         start_y = org_y + random() * delta_y;
2484         start_z = org_z + random() * delta_z;
2485
2486         // rule 1: start inside world bounds, and outside
2487         // solid, and don't start from somewhere where you can
2488         // fall down to evil
2489         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2490         if (trace_fraction >= 1)
2491             continue;
2492         if (trace_startsolid)
2493             continue;
2494         if (trace_dphitcontents & badcontents)
2495             continue;
2496         if (trace_dphitq3surfaceflags & badsurfaceflags)
2497             continue;
2498
2499         // rule 2: if we are too high, lower the point
2500         if (trace_fraction * delta_z > maxaboveground)
2501             start = trace_endpos + '0 0 1' * maxaboveground;
2502         enddown = trace_endpos;
2503
2504         // rule 3: make sure we aren't outside the map. This only works
2505         // for somewhat well formed maps. A good rule of thumb is that
2506         // the map should have a convex outside hull.
2507         // these can be traceLINES as we already verified the starting box
2508         mstart = start + 0.5 * (e.mins + e.maxs);
2509         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2510         if (trace_fraction >= 1)
2511             continue;
2512         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2513         if (trace_fraction >= 1)
2514             continue;
2515         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2516         if (trace_fraction >= 1)
2517             continue;
2518         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2519         if (trace_fraction >= 1)
2520             continue;
2521         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2522         if (trace_fraction >= 1)
2523             continue;
2524
2525         // find a random vector to "look at"
2526         end_x = org_x + random() * delta_x;
2527         end_y = org_y + random() * delta_y;
2528         end_z = org_z + random() * delta_z;
2529         end = start + normalize(end - start) * vlen(delta);
2530
2531         // rule 4: start TO end must not be too short
2532         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2533         if (trace_startsolid)
2534             continue;
2535         if (trace_fraction < minviewdistance / vlen(delta))
2536             continue;
2537
2538         // rule 5: don't want to look at sky
2539         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2540             continue;
2541
2542         // rule 6: we must not end up in trigger_hurt
2543         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2544         {
2545             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2546             continue;
2547         }
2548
2549         break;
2550     }
2551
2552     e.dphitcontentsmask = m;
2553
2554     if (i < attempts)
2555     {
2556         setorigin(e, start);
2557         e.angles = vectoangles(end - start);
2558         dprint("Needed ", ftos(i + 1), " attempts\n");
2559         return TRUE;
2560     }
2561     else
2562         return FALSE;
2563 }
2564
2565 float zcurveparticles_effectno;
2566 vector zcurveparticles_start;
2567 float zcurveparticles_spd;
2568
2569 void endzcurveparticles()
2570 {
2571         if(zcurveparticles_effectno)
2572         {
2573                 // terminator
2574                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2575         }
2576         zcurveparticles_effectno = 0;
2577 }
2578
2579 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2580 {
2581         spd = bound(0, floor(spd / 16), 32767);
2582         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2583         {
2584                 endzcurveparticles();
2585                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2586                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2587                 WriteShort(MSG_BROADCAST, effectno);
2588                 WriteCoord(MSG_BROADCAST, start_x);
2589                 WriteCoord(MSG_BROADCAST, start_y);
2590                 WriteCoord(MSG_BROADCAST, start_z);
2591                 zcurveparticles_effectno = effectno;
2592                 zcurveparticles_start = start;
2593         }
2594         else
2595                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2596         WriteCoord(MSG_BROADCAST, end_x);
2597         WriteCoord(MSG_BROADCAST, end_y);
2598         WriteCoord(MSG_BROADCAST, end_z);
2599         WriteCoord(MSG_BROADCAST, end_dz);
2600         zcurveparticles_spd = spd;
2601 }
2602
2603 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2604 {
2605         float end_dz;
2606         vector vecxy, velxy;
2607
2608         vecxy = end - start;
2609         vecxy_z = 0;
2610         velxy = vel;
2611         velxy_z = 0;
2612
2613         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2614         {
2615                 endzcurveparticles();
2616                 trailparticles(world, effectno, start, end);
2617                 return;
2618         }
2619
2620         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2621         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2622 }
2623
2624 void write_recordmarker(entity pl, float tstart, float dt)
2625 {
2626     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2627
2628     // also write a marker into demo files for demotc-race-record-extractor to find
2629     stuffcmd(pl,
2630              strcat(
2631                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2632                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2633 }
2634
2635 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2636 {
2637         switch(algn)
2638         {
2639                 case 1: // right
2640                         break;
2641
2642                 case 2: // left
2643                         vecs_y = -vecs_y;
2644                         break;
2645
2646                 default:
2647                 case 3:
2648                         if(allowcenter) // 2: allow center handedness
2649                         {
2650                                 // center
2651                                 vecs_y = 0;
2652                                 vecs_z -= 2;
2653                         }
2654                         else
2655                         {
2656                                 // right
2657                         }
2658                         break;
2659
2660                 case 4:
2661                         if(allowcenter) // 2: allow center handedness
2662                         {
2663                                 // center
2664                                 vecs_y = 0;
2665                                 vecs_z -= 2;
2666                         }
2667                         else
2668                         {
2669                                 // left
2670                                 vecs_y = -vecs_y;
2671                         }
2672                         break;
2673         }
2674         return vecs;
2675 }
2676
2677 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2678 {
2679         string s;
2680         vector v;
2681
2682         if (autocvar_g_shootfromeye)
2683         {
2684                 if (visual)
2685                 {
2686                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2687                 }
2688                 else
2689                 {
2690                         vecs_y = 0;
2691                         vecs_z = 0;
2692                 }
2693         }
2694         else if (autocvar_g_shootfromcenter)
2695         {
2696                 if (visual)
2697                 {
2698                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2699                 }
2700                 else
2701                 {
2702                         vecs_y = 0;
2703                         vecs_z -= 2;
2704                 }
2705         }
2706         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2707         {
2708                 v = stov(s);
2709                 if (y_is_right)
2710                         v_y = -v_y;
2711                 if (v_x != 0)
2712                         vecs_x = v_x;
2713                 vecs_y = v_y;
2714                 vecs_z = v_z;
2715         }
2716         else if (autocvar_g_shootfromclient)
2717         {
2718                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2719         }
2720         return vecs;
2721 }
2722
2723 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2724 {
2725         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2726 }
2727
2728
2729 void attach_sameorigin(entity e, entity to, string tag)
2730 {
2731     vector org, t_forward, t_left, t_up, e_forward, e_up;
2732     vector org0, ang0;
2733     float tagscale;
2734
2735     ang0 = e.angles;
2736     org0 = e.origin;
2737
2738     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2739     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2740     t_forward = v_forward * tagscale;
2741     t_left = v_right * -tagscale;
2742     t_up = v_up * tagscale;
2743
2744     e.origin_x = org * t_forward;
2745     e.origin_y = org * t_left;
2746     e.origin_z = org * t_up;
2747
2748     // current forward and up directions
2749     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2750                 e.angles = AnglesTransform_FromVAngles(e.angles);
2751         else
2752                 e.angles = AnglesTransform_FromAngles(e.angles);
2753     fixedmakevectors(e.angles);
2754
2755     // untransform forward, up!
2756     e_forward_x = v_forward * t_forward;
2757     e_forward_y = v_forward * t_left;
2758     e_forward_z = v_forward * t_up;
2759     e_up_x = v_up * t_forward;
2760     e_up_y = v_up * t_left;
2761     e_up_z = v_up * t_up;
2762
2763     e.angles = fixedvectoangles2(e_forward, e_up);
2764     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2765                 e.angles = AnglesTransform_ToVAngles(e.angles);
2766         else
2767                 e.angles = AnglesTransform_ToAngles(e.angles);
2768
2769     setattachment(e, to, tag);
2770     setorigin(e, e.origin);
2771 }
2772
2773 void detach_sameorigin(entity e)
2774 {
2775     vector org;
2776     org = gettaginfo(e, 0);
2777     e.angles = fixedvectoangles2(v_forward, v_up);
2778     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2779                 e.angles = AnglesTransform_ToVAngles(e.angles);
2780         else
2781                 e.angles = AnglesTransform_ToAngles(e.angles);
2782     setorigin(e, org);
2783     setattachment(e, world, "");
2784     setorigin(e, e.origin);
2785 }
2786
2787 void follow_sameorigin(entity e, entity to)
2788 {
2789     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2790     e.aiment = to; // make the hole follow bmodel
2791     e.punchangle = to.angles; // the original angles of bmodel
2792     e.view_ofs = e.origin - to.origin; // relative origin
2793     e.v_angle = e.angles - to.angles; // relative angles
2794 }
2795
2796 void unfollow_sameorigin(entity e)
2797 {
2798     e.movetype = MOVETYPE_NONE;
2799 }
2800
2801 entity gettaginfo_relative_ent;
2802 vector gettaginfo_relative(entity e, float tag)
2803 {
2804     if (!gettaginfo_relative_ent)
2805     {
2806         gettaginfo_relative_ent = spawn();
2807         gettaginfo_relative_ent.effects = EF_NODRAW;
2808     }
2809     gettaginfo_relative_ent.model = e.model;
2810     gettaginfo_relative_ent.modelindex = e.modelindex;
2811     gettaginfo_relative_ent.frame = e.frame;
2812     return gettaginfo(gettaginfo_relative_ent, tag);
2813 }
2814
2815 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2816 {
2817     float p;
2818     p = pow(2, chan);
2819     if (pl.soundentity.cnt & p)
2820         return;
2821     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2822     pl.soundentity.cnt |= p;
2823 }
2824
2825 void SoundEntity_StopSound(entity pl, float chan)
2826 {
2827     float p;
2828     p = pow(2, chan);
2829     if (pl.soundentity.cnt & p)
2830     {
2831         stopsoundto(MSG_ALL, pl.soundentity, chan);
2832         pl.soundentity.cnt &~= p;
2833     }
2834 }
2835
2836 void SoundEntity_Attach(entity pl)
2837 {
2838     pl.soundentity = spawn();
2839     pl.soundentity.classname = "soundentity";
2840     pl.soundentity.owner = pl;
2841     setattachment(pl.soundentity, pl, "");
2842     setmodel(pl.soundentity, "null");
2843 }
2844
2845 void SoundEntity_Detach(entity pl)
2846 {
2847     float i;
2848     for (i = 0; i <= 7; ++i)
2849         SoundEntity_StopSound(pl, i);
2850 }
2851
2852
2853 float ParseCommandPlayerSlotTarget_firsttoken;
2854 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2855 {
2856     string s;
2857     entity e, head;
2858     float n;
2859
2860     s = string_null;
2861
2862     ParseCommandPlayerSlotTarget_firsttoken = -1;
2863
2864     if (tokens > idx)
2865     {
2866         if (substring(argv(idx), 0, 1) == "#")
2867         {
2868             s = substring(argv(idx), 1, -1);
2869             ++idx;
2870             if (s == "")
2871                 if (tokens > idx)
2872                 {
2873                     s = argv(idx);
2874                     ++idx;
2875                 }
2876                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2877             if (s == ftos(stof(s)))
2878             {
2879                 e = edict_num(stof(s));
2880                 if (e.flags & FL_CLIENT)
2881                     return e;
2882             }
2883         }
2884         else
2885         {
2886             // it must be a nick name
2887             s = argv(idx);
2888             ++idx;
2889                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2890
2891             n = 0;
2892             FOR_EACH_CLIENT(head)
2893             if (head.netname == s)
2894             {
2895                 e = head;
2896                 ++n;
2897             }
2898             if (n == 1)
2899                 return e;
2900
2901             s = strdecolorize(s);
2902             n = 0;
2903             FOR_EACH_CLIENT(head)
2904             if (strdecolorize(head.netname) == s)
2905             {
2906                 e = head;
2907                 ++n;
2908             }
2909             if (n == 1)
2910                 return e;
2911         }
2912     }
2913
2914     return world;
2915 }
2916
2917 .float scale2;
2918
2919 float modeleffect_SendEntity(entity to, float sf)
2920 {
2921         float f;
2922         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2923
2924         f = 0;
2925         if(self.velocity != '0 0 0')
2926                 f |= 1;
2927         if(self.angles != '0 0 0')
2928                 f |= 2;
2929         if(self.avelocity != '0 0 0')
2930                 f |= 4;
2931
2932         WriteByte(MSG_ENTITY, f);
2933         WriteShort(MSG_ENTITY, self.modelindex);
2934         WriteByte(MSG_ENTITY, self.skin);
2935         WriteByte(MSG_ENTITY, self.frame);
2936         WriteCoord(MSG_ENTITY, self.origin_x);
2937         WriteCoord(MSG_ENTITY, self.origin_y);
2938         WriteCoord(MSG_ENTITY, self.origin_z);
2939         if(f & 1)
2940         {
2941                 WriteCoord(MSG_ENTITY, self.velocity_x);
2942                 WriteCoord(MSG_ENTITY, self.velocity_y);
2943                 WriteCoord(MSG_ENTITY, self.velocity_z);
2944         }
2945         if(f & 2)
2946         {
2947                 WriteCoord(MSG_ENTITY, self.angles_x);
2948                 WriteCoord(MSG_ENTITY, self.angles_y);
2949                 WriteCoord(MSG_ENTITY, self.angles_z);
2950         }
2951         if(f & 4)
2952         {
2953                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2954                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2955                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2956         }
2957         WriteShort(MSG_ENTITY, self.scale * 256.0);
2958         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2959         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2960         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2961         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2962
2963         return TRUE;
2964 }
2965
2966 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2967 {
2968         entity e;
2969         float sz;
2970         e = spawn();
2971         e.classname = "modeleffect";
2972         setmodel(e, m);
2973         e.frame = f;
2974         setorigin(e, o);
2975         e.velocity = v;
2976         e.angles = ang;
2977         e.avelocity = angv;
2978         e.alpha = a;
2979         e.teleport_time = t1;
2980         e.fade_time = t2;
2981         e.skin = s;
2982         if(s0 >= 0)
2983                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2984         else
2985                 e.scale = -s0;
2986         if(s2 >= 0)
2987                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2988         else
2989                 e.scale2 = -s2;
2990         sz = max(e.scale, e.scale2);
2991         setsize(e, e.mins * sz, e.maxs * sz);
2992         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2993 }
2994
2995 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2996 {
2997         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2998 }
2999
3000 float randombit(float bits)
3001 {
3002         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3003                 return bits;
3004
3005         float n, f, b, r;
3006
3007         r = random();
3008         b = 0;
3009         n = 0;
3010
3011         for(f = 1; f <= bits; f *= 2)
3012         {
3013                 if(bits & f)
3014                 {
3015                         ++n;
3016                         r *= n;
3017                         if(r <= 1)
3018                                 b = f;
3019                         else
3020                                 r = (r - 1) / (n - 1);
3021                 }
3022         }
3023
3024         return b;
3025 }
3026
3027 float randombits(float bits, float k, float error_return)
3028 {
3029         float r;
3030         r = 0;
3031         while(k > 0 && bits != r)
3032         {
3033                 r += randombit(bits - r);
3034                 --k;
3035         }
3036         if(error_return)
3037                 if(k > 0)
3038                         return -1; // all
3039         return r;
3040 }
3041
3042 void randombit_test(float bits, float iter)
3043 {
3044         while(iter > 0)
3045         {
3046                 print(ftos(randombit(bits)), "\n");
3047                 --iter;
3048         }
3049 }
3050
3051 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3052 {
3053         if(halflifedist > 0)
3054                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3055         else if(halflifedist < 0)
3056                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3057         else
3058                 return 1;
3059 }
3060
3061
3062
3063
3064 #ifdef RELEASE
3065 #define cvar_string_normal cvar_string_builtin
3066 #define cvar_normal cvar_builtin
3067 #else
3068 string cvar_string_normal(string n)
3069 {
3070         if not(cvar_type(n) & 1)
3071                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3072         return cvar_string_builtin(n);
3073 }
3074
3075 float cvar_normal(string n)
3076 {
3077         return stof(cvar_string_normal(n));
3078 }
3079 #endif
3080 #define cvar_set_normal cvar_set_builtin
3081
3082 void defer_think()
3083 {
3084     entity oself;
3085
3086     oself           = self;
3087     self            = self.owner;
3088     oself.think     = SUB_Remove;
3089     oself.nextthink = time;
3090
3091     oself.use();
3092 }
3093
3094 /*
3095     Execute func() after time + fdelay.
3096     self when func is executed = self when defer is called
3097 */
3098 void defer(float fdelay, void() func)
3099 {
3100     entity e;
3101
3102     e           = spawn();
3103     e.owner     = self;
3104     e.use       = func;
3105     e.think     = defer_think;
3106     e.nextthink = time + fdelay;
3107 }