qcsrc/server/mutators/gamemode_freezetag.qc

   1 float freezetag_teams;
   2 float freezetag_CheckTeams();
   3 float freezetag_CheckWinner();
   4 void freezetag_Initialize()
   5 {
   6         precache_model("models/ice/ice.md3");
   7         ScoreRules_freezetag();
   8
   9         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, 5, autocvar_g_freezetag_warmup);
  10
  11         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  12         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  13         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  14         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  15
  16         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  17         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  18 }
  19
  20 void freezetag_count_alive_players()
  21 {
  22         entity e;
  23         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  24         FOR_EACH_PLAYER(e) {
  25                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  26                 {
  27                         ++total_players;
  28                         if (!e.freezetag_frozen) ++redalive;
  29                 }
  30                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  31                 {
  32                         ++total_players;
  33                         if (!e.freezetag_frozen) ++bluealive;
  34                 }
  35                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  36                 {
  37                         ++total_players;
  38                         if (!e.freezetag_frozen) ++yellowalive;
  39                 }
  40                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  41                 {
  42                         ++total_players;
  43                         if (!e.freezetag_frozen) ++pinkalive;
  44                 }
  45         }
  46         FOR_EACH_REALCLIENT(e) {
  47                 e.redalive_stat = redalive;
  48                 e.bluealive_stat = bluealive;
  49                 e.yellowalive_stat = yellowalive;
  50                 e.pinkalive_stat = pinkalive;
  51         }
  52 }
  53 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  54 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  55
  56 float prev_total_players;
  57 float freezetag_CheckTeams()
  58 {
  59         entity e;
  60         if(FREEZETAG_ALIVE_TEAMS_OK())
  61         {
  62                 if(prev_total_players != -1)
  63                 {
  64                         FOR_EACH_REALCLIENT(e)
  65                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  66                 }
  67                 prev_total_players = -1;
  68                 return 1;
  69         }
  70         if(prev_total_players != total_players)
  71         {
  72                 string teams_missing;
  73                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  74                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  75                 if(freezetag_teams >= 3)
  76                 if(!yellowalive)        teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM3), ", ");
  77                 if(freezetag_teams == 4)
  78                 if(!pinkalive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM4), ", ");
  79                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  80
  81                 FOR_EACH_REALCLIENT(e)
  82                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  83                 prev_total_players = total_players;
  84         }
  85         return 0;
  86 }
  87
  88 float freezetag_getWinnerTeam()
  89 {
  90         float winner_team;
  91         if(redalive >= 1)
  92                 winner_team = COLOR_TEAM1;
  93         if(bluealive >= 1)
  94         {
  95                 if(winner_team) return 0;
  96                 winner_team = COLOR_TEAM2;
  97         }
  98         if(yellowalive >= 1)
  99         {
 100                 if(winner_team) return 0;
 101                 winner_team = COLOR_TEAM3;
 102         }
 103         if(pinkalive >= 1)
 104         {
 105                 if(winner_team) return 0;
 106                 winner_team = COLOR_TEAM4;
 107         }
 108         if(winner_team)
 109                 return winner_team;
 110         return -1; // no player left
 111 }
 112
 113 float freezetag_CheckWinner()
 114 {
 115         if(FREEZETAG_ALIVE_TEAMS() > 1)
 116                 return 0;
 117
 118         entity e;
 119         float winner_team;
 120         string teamname;
 121         winner_team = freezetag_getWinnerTeam();
 122         if(winner_team > 0)
 123         {
 124                 teamname = ColoredTeamName(winner_team);
 125                 FOR_EACH_REALCLIENT(e)
 126                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 127                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 128                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 129         }
 130         else if(winner_team == -1)
 131         {
 132                 FOR_EACH_REALCLIENT(e)
 133                         centerprint(e, "^5Round tied! All teams were frozen.");
 134                 bprint("^5Round tied! All teams were frozen.\n");
 135         }
 136
 137         return 1;
 138 }
 139
 140 // this is needed to allow the player to turn his view around (fixangle can't
 141 // be used to freeze his view, as that also changes the angles), while not
 142 // turning that ice object with the player
 143 void freezetag_Ice_Think()
 144 {
 145         setorigin(self, self.owner.origin - '0 0 16');
 146         self.nextthink = time;
 147 }
 148
 149 void freezetag_Add_Score(entity attacker)
 150 {
 151         if(attacker == self)
 152         {
 153                 // you froze your own dumb self
 154                 // counted as "suicide" already
 155                 PlayerScore_Add(self, SP_SCORE, -1);
 156         }
 157         else if(attacker.classname == "player")
 158         {
 159                 // got frozen by an enemy
 160                 // counted as "kill" and "death" already
 161                 PlayerScore_Add(self, SP_SCORE, -1);
 162                 PlayerScore_Add(attacker, SP_SCORE, +1);
 163         }
 164         // else nothing - got frozen by the game type rules themselves
 165 }
 166
 167 void freezetag_Freeze(entity attacker)
 168 {
 169         if(self.freezetag_frozen)
 170                 return;
 171         self.freezetag_frozen = 1;
 172         self.freezetag_revive_progress = 0;
 173         self.health = 1;
 174         // if(inWarmupStage)
 175                 // self.freezetag_frozen_timeout = time + 5;
 176
 177         freezetag_count_alive_players();
 178
 179         entity ice;
 180         ice = spawn();
 181         ice.owner = self;
 182         ice.classname = "freezetag_ice";
 183         ice.think = freezetag_Ice_Think;
 184         ice.nextthink = time;
 185         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 186         setmodel(ice, "models/ice/ice.md3");
 187
 188         entity oldself;
 189         oldself = self;
 190         self = ice;
 191         freezetag_Ice_Think();
 192         self = oldself;
 193
 194         RemoveGrapplingHook(self);
 195
 196         // add waypoint
 197         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 198
 199         freezetag_Add_Score(attacker);
 200 }
 201
 202 void freezetag_Unfreeze(entity attacker)
 203 {
 204         self.freezetag_frozen = 0;
 205         self.freezetag_frozen_timeout = 0;
 206         self.freezetag_revive_progress = 0;
 207
 208         // remove the ice block
 209         entity ice;
 210         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 211         {
 212                 remove(ice);
 213                 break;
 214         }
 215
 216         // remove waypoint
 217         if(self.waypointsprite_attached)
 218                 WaypointSprite_Kill(self.waypointsprite_attached);
 219 }
 220
 221
 222 // ================
 223 // Bot player logic
 224 // ================
 225
 226 void() havocbot_role_ft_freeing;
 227 void() havocbot_role_ft_offense;
 228
 229 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 230 {
 231         entity head;
 232         float distance;
 233
 234         FOR_EACH_PLAYER(head)
 235         {
 236                 if ((head != self) && (head.team == self.team))
 237                 {
 238                         if (head.freezetag_frozen)
 239                         {
 240                                 distance = vlen(head.origin - org);
 241                                 if (distance > sradius)
 242                                         continue;
 243                                 navigation_routerating(head, ratingscale, 2000);
 244                         }
 245                         else
 246                         {
 247                                 // If teamate is not frozen still seek them out as fight better
 248                                 // in a group.
 249                                 navigation_routerating(head, ratingscale/3, 2000);
 250                         }
 251                 }
 252         }
 253 }
 254
 255 void havocbot_role_ft_offense()
 256 {
 257         entity head;
 258         float unfrozen;
 259
 260         if(self.deadflag != DEAD_NO)
 261                 return;
 262
 263         if (!self.havocbot_role_timeout)
 264                 self.havocbot_role_timeout = time + random() * 10 + 20;
 265
 266         // Count how many players on team are unfrozen.
 267         unfrozen = 0;
 268         FOR_EACH_PLAYER(head)
 269         {
 270                 if ((head.team == self.team) && (!head.freezetag_frozen))
 271                         unfrozen++;
 272         }
 273
 274         // If only one left on team or if role has timed out then start trying to free players.
 275         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 276         {
 277                 dprint("changing role to freeing\n");
 278                 self.havocbot_role = havocbot_role_ft_freeing;
 279                 self.havocbot_role_timeout = 0;
 280                 return;
 281         }
 282
 283         if (time > self.bot_strategytime)
 284         {
 285                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 286
 287                 navigation_goalrating_start();
 288                 havocbot_goalrating_items(10000, self.origin, 10000);
 289                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 290                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 291                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 292                 navigation_goalrating_end();
 293         }
 294 }
 295
 296 void havocbot_role_ft_freeing()
 297 {
 298         if(self.deadflag != DEAD_NO)
 299                 return;
 300
 301         if (!self.havocbot_role_timeout)
 302                 self.havocbot_role_timeout = time + random() * 10 + 20;
 303
 304         if (time > self.havocbot_role_timeout)
 305         {
 306                 dprint("changing role to offense\n");
 307                 self.havocbot_role = havocbot_role_ft_offense;
 308                 self.havocbot_role_timeout = 0;
 309                 return;
 310         }
 311
 312         if (time > self.bot_strategytime)
 313         {
 314                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 315
 316                 navigation_goalrating_start();
 317                 havocbot_goalrating_items(8000, self.origin, 10000);
 318                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 319                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 320                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 321                 navigation_goalrating_end();
 322         }
 323 }
 324
 325
 326 // ==============
 327 // Hook Functions
 328 // ==============
 329
 330 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 331 {
 332         self.health = 0; // neccessary to update correctly alive stats
 333         freezetag_Unfreeze(world);
 334         freezetag_count_alive_players();
 335         return 1;
 336 }
 337
 338 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 339 {
 340         if(round_handler_IsActive())
 341         if(round_handler_CountdownRunning())
 342         {
 343                 if(self.freezetag_frozen)
 344                         freezetag_Unfreeze(world);
 345                 freezetag_count_alive_players();
 346                 return 1; // let the player die so that he can respawn whenever he wants
 347         }
 348
 349         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 350         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 351         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 352                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 353         {
 354                 // let the player die, he will be automatically frozen when he respawns
 355                 if(!self.freezetag_frozen)
 356                 {
 357                         freezetag_Add_Score(frag_attacker);
 358                         freezetag_count_alive_players();
 359                 }
 360                 else
 361                         freezetag_Unfreeze(world); // remove ice
 362                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 363                 return 1;
 364         }
 365
 366         if(self.freezetag_frozen)
 367                 return 1;
 368
 369         freezetag_Freeze(frag_attacker);
 370
 371         if(frag_attacker == frag_target || frag_attacker == world)
 372         {
 373                 if(frag_target.classname == STR_PLAYER)
 374                         centerprint(frag_target, "^1You froze yourself.\n");
 375                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 376         }
 377         else
 378         {
 379                 if(frag_target.classname == STR_PLAYER)
 380                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 381                 if(frag_attacker.classname == STR_PLAYER)
 382                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 383                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 384         }
 385
 386         frag_target.health = 1; // "respawn" the player :P
 387
 388         return 1;
 389 }
 390
 391 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 392 {
 393         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 394                 return 1; // do nothing, round is starting right now
 395
 396         if(self.freezetag_frozen_timeout == -2) // player was dead
 397         {
 398                 freezetag_Freeze(world);
 399                 return 1;
 400         }
 401
 402         freezetag_count_alive_players();
 403
 404         if(round_handler_IsActive())
 405         if(round_handler_IsRoundStarted())
 406         {
 407                 centerprint(self, "^1Round already started, you spawn as frozen.");
 408                 freezetag_Freeze(world);
 409         }
 410
 411         return 1;
 412 }
 413
 414 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 415 {
 416         FOR_EACH_PLAYER(self)
 417         {
 418                 if (self.freezetag_frozen)
 419                         freezetag_Unfreeze(world);
 420                 self.freezetag_frozen_timeout = -1;
 421                 PutClientInServer();
 422                 self.freezetag_frozen_timeout = 0;
 423         }
 424         freezetag_count_alive_players();
 425         return 1;
 426 }
 427
 428 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 429 {
 430         frag_score = 0; // no frags counted in Freeze Tag
 431         return 1;
 432 }
 433
 434 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 435 {
 436         float n;
 437         vector revive_extra_size;
 438
 439         if(gameover)
 440                 return 1;
 441
 442         if(self.freezetag_frozen)
 443         {
 444                 // keep health = 1
 445                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 446
 447                 if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 448                 {
 449                         self.health = autocvar_g_balance_health_start;
 450                         freezetag_Unfreeze(world);
 451                         freezetag_count_alive_players();
 452                         return 1;
 453                 }
 454         }
 455
 456         if(round_handler_IsActive())
 457         if(!round_handler_IsRoundStarted())
 458                 return 1;
 459
 460         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 461
 462         entity o;
 463         o = world;
 464         n = 0;
 465         FOR_EACH_PLAYER(other) if(self != other)
 466         {
 467                 if(other.freezetag_frozen == 0)
 468                 {
 469                         if(other.team == self.team)
 470                         {
 471                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 472                                 {
 473                                         if(!o)
 474                                                 o = other;
 475                                         ++n;
 476                                 }
 477                         }
 478                 }
 479         }
 480
 481         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 482         {
 483                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 484                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 485
 486                 if(self.freezetag_revive_progress >= 1)
 487                 {
 488                         freezetag_Unfreeze(self);
 489                         freezetag_count_alive_players();
 490
 491                         // EVERY team mate nearby gets a point (even if multiple!)
 492                         FOR_EACH_PLAYER(other) if(self != other)
 493                         {
 494                                 if(other.freezetag_frozen == 0)
 495                                 {
 496                                         if(other.team == self.team)
 497                                         {
 498                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 499                                                 {
 500                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 501                                                         PlayerScore_Add(other, SP_SCORE, +1);
 502                                                 }
 503                                         }
 504                                 }
 505                         }
 506
 507                         if(n > 1)
 508                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 509                         else
 510                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 511                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 512                         if(n > 1)
 513                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 514                         else
 515                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 516                 }
 517
 518                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 519                 FOR_EACH_PLAYER(other) if(self != other)
 520                 {
 521                         if(other.freezetag_frozen == 0)
 522                         {
 523                                 if(other.team == self.team)
 524                                 {
 525                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 526                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 527                                 }
 528                         }
 529                 }
 530         }
 531         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 532         {
 533                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 534                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 535         }
 536         else if(!n)
 537         {
 538                 self.freezetag_revive_progress = 0; // thawing nobody
 539         }
 540
 541         return 1;
 542 }
 543
 544 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 545 {
 546         if(self.freezetag_frozen)
 547         {
 548                 self.movement = '0 0 0';
 549                 self.disableclientprediction = 1;
 550         }
 551         return 1;
 552 }
 553
 554 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 555 {
 556         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 557         {
 558                 frag_damage = 0;
 559                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 560         }
 561         return 1;
 562 }
 563
 564 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 565 {
 566         if (self.freezetag_frozen)
 567                 return 1;
 568         return 0;
 569 }
 570
 571 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 572 {
 573         if not(self.deadflag)
 574         {
 575                 if (random() < 0.5)
 576                         self.havocbot_role = havocbot_role_ft_freeing;
 577                 else
 578                         self.havocbot_role = havocbot_role_ft_offense;
 579         }
 580
 581         return TRUE;
 582 }
 583
 584 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 585 {
 586         self.freezetag_frozen = other.freezetag_frozen;
 587         self.freezetag_revive_progress = other.freezetag_revive_progress;
 588         return 0;
 589 }
 590
 591 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 592 {
 593         freezetag_teams = autocvar_g_freezetag_teams_override;
 594         if(freezetag_teams < 2)
 595                 freezetag_teams = autocvar_g_freezetag_teams;
 596         freezetag_teams = bound(2, freezetag_teams, 4);
 597         ret_float = freezetag_teams;
 598         return 0;
 599 }
 600
 601 MUTATOR_DEFINITION(gamemode_freezetag)
 602 {
 603         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 604         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 605         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 606         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 607         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 608         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 609         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 610         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 611         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 612         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 613         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 614         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 615         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 616
 617         MUTATOR_ONADD
 618         {
 619                 if(time > 1) // game loads at time 1
 620                         error("This is a game type and it cannot be added at runtime.");
 621                 freezetag_Initialize();
 622         }
 623
 624         MUTATOR_ONREMOVE
 625         {
 626                 error("This is a game type and it cannot be removed at runtime.");
 627         }
 628
 629         return 0;
 630 }