qcsrc/server/mutators/gamemode_freezetag.qc

   1 float freezetag_CheckTeams();
   2 float freezetag_CheckWinner();
   3 void freezetag_Initialize()
   4 {
   5         precache_model("models/ice/ice.md3");
   6         ScoreRules_freezetag();
   7
   8         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, 5, autocvar_g_freezetag_warmup);
   9
  10         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  11         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  12         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  13         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  14
  15         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  16         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  17 }
  18
  19 void freezetag_count_alive_players()
  20 {
  21         entity e;
  22         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  23         FOR_EACH_PLAYER(e) {
  24                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  25                 {
  26                         ++total_players;
  27                         if (!e.freezetag_frozen) ++redalive;
  28                 }
  29                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  30                 {
  31                         ++total_players;
  32                         if (!e.freezetag_frozen) ++bluealive;
  33                 }
  34                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  35                 {
  36                         ++total_players;
  37                         if (!e.freezetag_frozen) ++yellowalive;
  38                 }
  39                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  40                 {
  41                         ++total_players;
  42                         if (!e.freezetag_frozen) ++pinkalive;
  43                 }
  44         }
  45         FOR_EACH_REALCLIENT(e) {
  46                 e.redalive_stat = redalive;
  47                 e.bluealive_stat = bluealive;
  48                 e.yellowalive_stat = yellowalive;
  49                 e.pinkalive_stat = pinkalive;
  50         }
  51 }
  52
  53 float freezetag_TeamsCanPlay()
  54 {
  55         if((redalive >= 1 && bluealive >= 1)
  56                 || (redalive >= 1 && yellowalive >= 1)
  57                 || (redalive >= 1 && pinkalive >= 1)
  58                 || (bluealive >= 1 && yellowalive >= 1)
  59                 || (bluealive >= 1 && pinkalive >= 1)
  60                 || (yellowalive >= 1 && pinkalive >= 1))
  61                 return 1; // we still have active players on two or more teams, nobody won yet
  62         return 0;
  63 }
  64
  65 float prev_total_players;
  66 float freezetag_CheckTeams()
  67 {
  68         entity e;
  69         if(freezetag_TeamsCanPlay())
  70         {
  71                 if(prev_total_players != -1)
  72                 {
  73                         FOR_EACH_REALCLIENT(e)
  74                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  75                 }
  76                 prev_total_players = -1;
  77                 return 1;
  78         }
  79         if(prev_total_players != total_players)
  80         {
  81                 string teams_missing;
  82                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  83                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  84                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  85
  86                 FOR_EACH_REALCLIENT(e)
  87                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  88                 prev_total_players = total_players;
  89         }
  90         return 0;
  91 }
  92 float freezetag_CheckWinner()
  93 {
  94         if(freezetag_TeamsCanPlay())
  95                 return 0;
  96
  97         entity e, winner;
  98         string teamname;
  99         winner = world;
 100
 101         FOR_EACH_PLAYER(e)
 102         {
 103                 if(e.freezetag_frozen == 0 && e.health >= 1) // here's one player from the winning team... good
 104                 {
 105                         winner = e;
 106                         break; // break, we found the winner
 107                 }
 108         }
 109
 110         if(winner != world) // just in case a winner wasn't found
 111         {
 112                 teamname = ColoredTeamName(winner.team);
 113                 FOR_EACH_REALCLIENT(e)
 114                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 115                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 116                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
 117         }
 118
 119         return 1;
 120 }
 121
 122 // this is needed to allow the player to turn his view around (fixangle can't
 123 // be used to freeze his view, as that also changes the angles), while not
 124 // turning that ice object with the player
 125 void freezetag_Ice_Think()
 126 {
 127         setorigin(self, self.owner.origin - '0 0 16');
 128         self.nextthink = time;
 129 }
 130
 131 void freezetag_Add_Score(entity attacker)
 132 {
 133         if(attacker == self)
 134         {
 135                 // you froze your own dumb self
 136                 // counted as "suicide" already
 137                 PlayerScore_Add(self, SP_SCORE, -1);
 138         }
 139         else if(attacker.classname == "player")
 140         {
 141                 // got frozen by an enemy
 142                 // counted as "kill" and "death" already
 143                 PlayerScore_Add(self, SP_SCORE, -1);
 144                 PlayerScore_Add(attacker, SP_SCORE, +1);
 145         }
 146         // else nothing - got frozen by the game type rules themselves
 147 }
 148
 149 void freezetag_Freeze(entity attacker)
 150 {
 151         if(self.freezetag_frozen)
 152                 return;
 153         self.freezetag_frozen = 1;
 154         self.freezetag_revive_progress = 0;
 155         self.health = 1;
 156         // if(inWarmupStage)
 157                 // self.freezetag_frozen_timeout = time + 5;
 158
 159         freezetag_count_alive_players();
 160
 161         entity ice;
 162         ice = spawn();
 163         ice.owner = self;
 164         ice.classname = "freezetag_ice";
 165         ice.think = freezetag_Ice_Think;
 166         ice.nextthink = time;
 167         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 168         setmodel(ice, "models/ice/ice.md3");
 169
 170         entity oldself;
 171         oldself = self;
 172         self = ice;
 173         freezetag_Ice_Think();
 174         self = oldself;
 175
 176         RemoveGrapplingHook(self);
 177
 178         // add waypoint
 179         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 180
 181         freezetag_Add_Score(attacker);
 182 }
 183
 184 void freezetag_Unfreeze(entity attacker)
 185 {
 186         self.freezetag_frozen = 0;
 187         self.freezetag_frozen_timeout = 0;
 188         self.freezetag_revive_progress = 0;
 189
 190         // remove the ice block
 191         entity ice;
 192         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 193         {
 194                 remove(ice);
 195                 break;
 196         }
 197
 198         // remove waypoint
 199         if(self.waypointsprite_attached)
 200                 WaypointSprite_Kill(self.waypointsprite_attached);
 201 }
 202
 203
 204 // ================
 205 // Bot player logic
 206 // ================
 207
 208 void() havocbot_role_ft_freeing;
 209 void() havocbot_role_ft_offense;
 210
 211 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 212 {
 213         entity head;
 214         float distance;
 215
 216         FOR_EACH_PLAYER(head)
 217         {
 218                 if ((head != self) && (head.team == self.team))
 219                 {
 220                         if (head.freezetag_frozen)
 221                         {
 222                                 distance = vlen(head.origin - org);
 223                                 if (distance > sradius)
 224                                         continue;
 225                                 navigation_routerating(head, ratingscale, 2000);
 226                         }
 227                         else
 228                         {
 229                                 // If teamate is not frozen still seek them out as fight better
 230                                 // in a group.
 231                                 navigation_routerating(head, ratingscale/3, 2000);
 232                         }
 233                 }
 234         }
 235 }
 236
 237 void havocbot_role_ft_offense()
 238 {
 239         entity head;
 240         float unfrozen;
 241
 242         if(self.deadflag != DEAD_NO)
 243                 return;
 244
 245         if (!self.havocbot_role_timeout)
 246                 self.havocbot_role_timeout = time + random() * 10 + 20;
 247
 248         // Count how many players on team are unfrozen.
 249         unfrozen = 0;
 250         FOR_EACH_PLAYER(head)
 251         {
 252                 if ((head.team == self.team) && (!head.freezetag_frozen))
 253                         unfrozen++;
 254         }
 255
 256         // If only one left on team or if role has timed out then start trying to free players.
 257         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 258         {
 259                 dprint("changing role to freeing\n");
 260                 self.havocbot_role = havocbot_role_ft_freeing;
 261                 self.havocbot_role_timeout = 0;
 262                 return;
 263         }
 264
 265         if (time > self.bot_strategytime)
 266         {
 267                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 268
 269                 navigation_goalrating_start();
 270                 havocbot_goalrating_items(10000, self.origin, 10000);
 271                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 272                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 273                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 274                 navigation_goalrating_end();
 275         }
 276 }
 277
 278 void havocbot_role_ft_freeing()
 279 {
 280         if(self.deadflag != DEAD_NO)
 281                 return;
 282
 283         if (!self.havocbot_role_timeout)
 284                 self.havocbot_role_timeout = time + random() * 10 + 20;
 285
 286         if (time > self.havocbot_role_timeout)
 287         {
 288                 dprint("changing role to offense\n");
 289                 self.havocbot_role = havocbot_role_ft_offense;
 290                 self.havocbot_role_timeout = 0;
 291                 return;
 292         }
 293
 294         if (time > self.bot_strategytime)
 295         {
 296                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 297
 298                 navigation_goalrating_start();
 299                 havocbot_goalrating_items(8000, self.origin, 10000);
 300                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 301                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 302                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 303                 navigation_goalrating_end();
 304         }
 305 }
 306
 307
 308 // ==============
 309 // Hook Functions
 310 // ==============
 311
 312 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 313 {
 314         self.health = 0; // neccessary to update correctly alive stats
 315         freezetag_Unfreeze(world);
 316         freezetag_count_alive_players();
 317         return 1;
 318 }
 319
 320 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 321 {
 322         if(round_handler_IsActive())
 323         if(round_handler_CountdownRunning())
 324         {
 325                 if(self.freezetag_frozen)
 326                         freezetag_Unfreeze(world);
 327                 freezetag_count_alive_players();
 328                 return 1; // let the player die so that he can respawn whenever he wants
 329         }
 330
 331         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 332         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 333         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 334                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 335         {
 336                 // let the player die, he will be automatically frozen when he respawns
 337                 if(!self.freezetag_frozen)
 338                 {
 339                         freezetag_Add_Score(frag_attacker);
 340                         freezetag_count_alive_players();
 341                 }
 342                 else
 343                         freezetag_Unfreeze(world); // remove ice
 344                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 345                 return 1;
 346         }
 347
 348         if(self.freezetag_frozen)
 349                 return 1;
 350
 351         freezetag_Freeze(frag_attacker);
 352
 353         if(frag_attacker == frag_target || frag_attacker == world)
 354         {
 355                 if(frag_target.classname == STR_PLAYER)
 356                         centerprint(frag_target, "^1You froze yourself.\n");
 357                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 358         }
 359         else
 360         {
 361                 if(frag_target.classname == STR_PLAYER)
 362                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 363                 if(frag_attacker.classname == STR_PLAYER)
 364                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 365                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 366         }
 367
 368         frag_target.health = 1; // "respawn" the player :P
 369
 370         return 1;
 371 }
 372
 373 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 374 {
 375         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 376                 return 1; // do nothing, round is starting right now
 377
 378         if(self.freezetag_frozen_timeout == -2) // player was dead
 379         {
 380                 freezetag_Freeze(world);
 381                 return 1;
 382         }
 383
 384         freezetag_count_alive_players();
 385
 386         if(round_handler_IsActive())
 387         if(round_handler_IsRoundStarted())
 388         {
 389                 centerprint(self, "^1Round already started, you spawn as frozen.");
 390                 freezetag_Freeze(world);
 391         }
 392
 393         return 1;
 394 }
 395
 396 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 397 {
 398         FOR_EACH_PLAYER(self)
 399         {
 400                 if (self.freezetag_frozen)
 401                         freezetag_Unfreeze(world);
 402                 self.freezetag_frozen_timeout = -1;
 403                 PutClientInServer();
 404                 self.freezetag_frozen_timeout = 0;
 405         }
 406         freezetag_count_alive_players();
 407         return 1;
 408 }
 409
 410 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 411 {
 412         frag_score = 0; // no frags counted in Freeze Tag
 413         return 1;
 414 }
 415
 416 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 417 {
 418         float n;
 419         vector revive_extra_size;
 420
 421         if(gameover)
 422                 return 1;
 423
 424         if(self.freezetag_frozen)
 425         {
 426                 // keep health = 1
 427                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 428
 429                 if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 430                 {
 431                         self.health = autocvar_g_balance_health_start;
 432                         freezetag_Unfreeze(world);
 433                         freezetag_count_alive_players();
 434                         return 1;
 435                 }
 436         }
 437
 438         if(round_handler_IsActive())
 439         if(!round_handler_IsRoundStarted())
 440                 return 1;
 441
 442         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 443
 444         entity o;
 445         o = world;
 446         n = 0;
 447         FOR_EACH_PLAYER(other) if(self != other)
 448         {
 449                 if(other.freezetag_frozen == 0)
 450                 {
 451                         if(other.team == self.team)
 452                         {
 453                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 454                                 {
 455                                         if(!o)
 456                                                 o = other;
 457                                         ++n;
 458                                 }
 459                         }
 460                 }
 461         }
 462
 463         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 464         {
 465                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 466                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 467
 468                 if(self.freezetag_revive_progress >= 1)
 469                 {
 470                         freezetag_Unfreeze(self);
 471                         freezetag_count_alive_players();
 472
 473                         // EVERY team mate nearby gets a point (even if multiple!)
 474                         FOR_EACH_PLAYER(other) if(self != other)
 475                         {
 476                                 if(other.freezetag_frozen == 0)
 477                                 {
 478                                         if(other.team == self.team)
 479                                         {
 480                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 481                                                 {
 482                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 483                                                         PlayerScore_Add(other, SP_SCORE, +1);
 484                                                 }
 485                                         }
 486                                 }
 487                         }
 488
 489                         if(n > 1)
 490                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 491                         else
 492                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 493                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 494                         if(n > 1)
 495                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 496                         else
 497                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 498                 }
 499
 500                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 501                 FOR_EACH_PLAYER(other) if(self != other)
 502                 {
 503                         if(other.freezetag_frozen == 0)
 504                         {
 505                                 if(other.team == self.team)
 506                                 {
 507                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 508                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 509                                 }
 510                         }
 511                 }
 512         }
 513         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 514         {
 515                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 516                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 517         }
 518         else if(!n)
 519         {
 520                 self.freezetag_revive_progress = 0; // thawing nobody
 521         }
 522
 523         return 1;
 524 }
 525
 526 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 527 {
 528         if(self.freezetag_frozen)
 529         {
 530                 self.movement = '0 0 0';
 531                 self.disableclientprediction = 1;
 532         }
 533         return 1;
 534 }
 535
 536 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 537 {
 538         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 539         {
 540                 frag_damage = 0;
 541                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 542         }
 543         return 1;
 544 }
 545
 546 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 547 {
 548         if (self.freezetag_frozen)
 549                 return 1;
 550         return 0;
 551 }
 552
 553 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 554 {
 555         if not(self.deadflag)
 556         {
 557                 if (random() < 0.5)
 558                         self.havocbot_role = havocbot_role_ft_freeing;
 559                 else
 560                         self.havocbot_role = havocbot_role_ft_offense;
 561         }
 562
 563         return TRUE;
 564 }
 565
 566 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 567 {
 568         self.freezetag_frozen = other.freezetag_frozen;
 569         self.freezetag_revive_progress = other.freezetag_revive_progress;
 570         return 0;
 571 }
 572
 573 MUTATOR_DEFINITION(gamemode_freezetag)
 574 {
 575         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 576         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 577         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 578         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 579         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 580         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 581         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 582         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 583         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 584         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 585         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 586         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 587
 588         MUTATOR_ONADD
 589         {
 590                 if(time > 1) // game loads at time 1
 591                         error("This is a game type and it cannot be added at runtime.");
 592                 freezetag_Initialize();
 593         }
 594
 595         MUTATOR_ONROLLBACK_OR_REMOVE
 596         {
 597                 // we actually cannot roll back freezetag_Initialize here
 598                 // BUT: we don't need to! If this gets called, adding always
 599                 // succeeds.
 600         }
 601
 602         MUTATOR_ONREMOVE
 603         {
 604                 print("This is a game type and it cannot be removed at runtime.");
 605                 return -1;
 606         }
 607
 608         return 0;
 609 }