qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         next_round = time + cvar("g_start_delay");
   5 }
   6
   7 void freezetag_CheckWinner()
   8 {
   9         if(time <= game_starttime)
  10                 return;
  11
  12         if(next_round || (time > warmup - cvar("g_freezetag_warmup") && time < warmup))
  13                 return; // already waiting for next round to start
  14
  15         if(redalive + bluealive + yellowalive + pinkalive <= 0 && time > game_starttime)
  16         {
  17                 next_round = time + 5;
  18         }
  19
  20         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  21                 || (redalive >= 1 && yellowalive >= 1)
  22                 || (redalive >= 1 && pinkalive >= 1)
  23                 || (bluealive >= 1 && yellowalive >= 1)
  24                 || (bluealive >= 1 && pinkalive >= 1)
  25                 || (yellowalive >= 1 && pinkalive >= 1))
  26                 return; // we still have active players on two or more teams
  27
  28         entity e, winner;
  29         string teamname;
  30
  31         FOR_EACH_PLAYER(e)
  32         {
  33                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  34                 {
  35                         winner = e;
  36                         break; // break, we found the winner
  37                 }
  38         }
  39
  40         if(winner != world) // just in case a winner isn't found
  41         {
  42                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  43                 if(winner.team == COLOR_TEAM1)
  44                         teamname = "^1Red Team";
  45                 else if(winner.team == COLOR_TEAM2)
  46                         teamname = "^4Blue Team";
  47                 else if(winner.team == COLOR_TEAM3)
  48                         teamname = "^3Yellow Team";
  49                 else
  50                         teamname = "^6Pink Team";
  51                 FOR_EACH_PLAYER(e) {
  52                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  53                 }
  54                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  55         }
  56
  57         next_round = time + 5;
  58 }
  59
  60 void freezetag_Ice_Think()
  61 {
  62         setorigin(self, self.owner.origin - '0 0 16');
  63         self.nextthink = time;
  64 }
  65
  66 void freezetag_Freeze()
  67 {
  68         self.freezetag_frozen = 1;
  69
  70         entity ice;
  71         ice = spawn();
  72         ice.owner = self;
  73         ice.classname = "freezetag_ice";
  74         ice.think = freezetag_Ice_Think;
  75         ice.nextthink = time;
  76         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  77         setmodel(ice, "models/ice/ice.md3");
  78
  79         self.movement = '0 0 0';
  80
  81         // add waypoint
  82         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  83         if(self.waypointsprite_attached)
  84         {
  85                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  86         }
  87 }
  88
  89 void freezetag_Unfreeze()
  90 {
  91         self.freezetag_frozen = 0;
  92
  93         // remove the ice block
  94         entity ice;
  95         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
  96         {
  97                 remove(ice);
  98                 break;
  99         }
 100
 101         // remove waypoint
 102         if(self.waypointsprite_attached)
 103                 WaypointSprite_Kill(self.waypointsprite_attached);
 104 }
 105
 106 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 107 {
 108         if(self.freezetag_frozen == 0)
 109         {
 110                 if(self.team == COLOR_TEAM1)
 111                         --redalive;
 112                 else if(self.team == COLOR_TEAM2)
 113                         --bluealive;
 114                 else if(self.team == COLOR_TEAM3)
 115                         --yellowalive;
 116                 else if(self.team == COLOR_TEAM4)
 117                         --pinkalive;
 118         }
 119
 120         freezetag_CheckWinner();
 121         freezetag_Unfreeze();
 122
 123         return 1;
 124 }
 125
 126 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 127 {
 128         freezetag_Freeze();
 129         count_alive_players();
 130
 131         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 132         if(frag_attacker == frag_target || frag_attacker == world)
 133         {
 134                 centerprint(frag_target, "^1You froze yourself.\n");
 135                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 136         }
 137         else
 138         {
 139                 centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 140                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 141         }
 142
 143         frag_target.health = cvar("g_balance_health_start"); // "respawn" the player :P
 144
 145         freezetag_CheckWinner();
 146
 147         return 1;
 148 }
 149
 150 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 151 {
 152         if(time > warmup) // spawn too late, freeze player
 153         {
 154                 print("time: ", ftos(time), " warmup: ", ftos(warmup), "\n");
 155                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 156                 freezetag_Freeze();
 157         }
 158         else // we are still in the delay period before the round starts
 159         {
 160                 freezetag_Unfreeze();
 161         }
 162
 163         return 1;
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 167 {
 168         frag_score = 0; // no frags counted in Freeze Tag
 169         return 1;
 170 }
 171
 172 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 173 {
 174         vector revive_extra_size;
 175         revive_extra_size = '1 1 1' * cvar("g_freezetag_revive_extra_size");
 176
 177         float teammate_nearby;
 178         FOR_EACH_PLAYER(other) if(self != other)
 179         {
 180                 if(other.freezetag_frozen == 0)
 181                 {
 182                         if(other.team == self.team)
 183                         {
 184                                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 185                                 if(teammate_nearby)
 186                                         break;
 187                         }
 188                 }
 189         }
 190
 191         if(teammate_nearby && self.freezetag_frozen == 1)
 192         {
 193                 if(self.freezetag_beginrevive_time == -9999)
 194                 {
 195                         self.freezetag_beginrevive_time = time;
 196                         self.freezetag_revive_progress = 0;
 197                         other.freezetag_revive_progress = 0;
 198                 }
 199                 else
 200                 {
 201                         self.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / cvar("g_freezetag_revive_time");
 202                         other.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / cvar("g_freezetag_revive_time");
 203                         if(time - self.freezetag_beginrevive_time >= cvar("g_freezetag_revive_time"))
 204                         {
 205                                 freezetag_Unfreeze();
 206
 207                                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 208                                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 209                                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 210
 211                                 self.freezetag_beginrevive_time = -9999;
 212                                 self.freezetag_revive_progress = 0;
 213                                 other.freezetag_revive_progress = 0;
 214                         }
 215                 }
 216         }
 217         else if(!teammate_nearby) // only if no teammate is nearby will we reset
 218         {
 219                 self.freezetag_beginrevive_time = -9999;
 220                 self.freezetag_revive_progress = 0;
 221         }
 222
 223         return 1;
 224 }
 225
 226 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 227 {
 228         if(self.freezetag_frozen)
 229                 self.movement = '0 0 0';
 230         return 1;
 231 }
 232
 233 MUTATOR_DEFINITION(gamemode_freezetag)
 234 {
 235         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 236         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 237         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 238         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 239         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 240         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 241         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 242
 243         MUTATOR_ONADD
 244         {
 245                 if(time > 1) // game loads at time 1
 246                         error("This is a game type and it cannot be added at runtime.");
 247                 g_freezetag = 1;
 248                 freezetag_Initialize();
 249         }
 250
 251         MUTATOR_ONREMOVE
 252         {
 253                 g_freezetag = 0;
 254                 error("This is a game type and it cannot be removed at runtime.");
 255         }
 256
 257         return 0;
 258 }