qcsrc/server/mutators/gamemode_invasion.qc

   1 void invasion_spawnpoint()
   2 {
   3         if(!g_invasion) { remove(self); return; }
   4
   5         self.classname = "invasion_spawnpoint";
   6 }
   7
   8 float invasion_PickMonster(float supermonster_count)
   9 {
  10         if(autocvar_g_invasion_zombies_only)
  11                 return MON_ZOMBIE;
  12
  13         float i;
  14         entity mon;
  15
  16         RandomSelection_Init();
  17
  18         for(i = MON_FIRST; i <= MON_LAST; ++i)
  19         {
  20                 mon = get_monsterinfo(i);
  21                 if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM) || ((mon.spawnflags & MON_FLAG_SUPERMONSTER) && supermonster_count >= 1))
  22                         continue; // flying/swimming monsters not yet supported
  23
  24                 RandomSelection_Add(world, i, "", 1, 1);
  25         }
  26
  27         return RandomSelection_chosen_float;
  28 }
  29
  30 entity invasion_PickSpawn()
  31 {
  32         entity e;
  33
  34         RandomSelection_Init();
  35
  36         for(e = world;(e = find(e, classname, "invasion_spawnpoint")); )
  37                 RandomSelection_Add(e, 0, string_null, 1, 1);
  38
  39         return RandomSelection_chosen_ent;
  40 }
  41
  42 void invasion_SpawnChosenMonster(float mon)
  43 {
  44         entity spawn_point, monster;
  45
  46         spawn_point = invasion_PickSpawn();
  47
  48         if(spawn_point == world)
  49         {
  50                 dprint("Warning: couldn't find any invasion_spawnpoint spawnpoints, no monsters will spawn!\n");
  51                 return;
  52         }
  53
  54         monster = spawnmonster("", mon, spawn_point, spawn_point, spawn_point.origin, FALSE, FALSE, 2);
  55
  56         monster.target2 = spawn_point.target2;
  57
  58         if(inv_roundcnt >= inv_maxrounds)
  59                 monster.spawnflags |= MONSTERFLAG_MINIBOSS; // last round spawns minibosses
  60 }
  61
  62 void invasion_SpawnMonsters(float supermonster_count)
  63 {
  64         float chosen_monster = invasion_PickMonster(supermonster_count);
  65
  66         invasion_SpawnChosenMonster(chosen_monster);
  67 }
  68
  69 float Invasion_CheckWinner()
  70 {
  71         entity head;
  72         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  73         {
  74                 FOR_EACH_MONSTER(head)
  75                         monster_remove(head);
  76
  77                 if(inv_roundcnt >= inv_maxrounds)
  78                 {
  79                         NextLevel();
  80                         return 1;
  81                 }
  82
  83                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  84                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  85                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
  86                 return 1;
  87         }
  88
  89         float total_alive_monsters = 0, supermonster_count = 0;
  90
  91         FOR_EACH_MONSTER(head) if(head.health > 0)
  92         {
  93                 if((get_monsterinfo(head.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
  94                         ++supermonster_count;
  95                 ++total_alive_monsters;
  96         }
  97
  98         if((total_alive_monsters + inv_numkilled) < inv_maxspawned && inv_maxcurrent < 10) // 10 at a time should be plenty
  99         {
 100                 if(time >= inv_lastcheck)
 101                 {
 102                         invasion_SpawnMonsters(supermonster_count);
 103                         inv_lastcheck = time + autocvar_g_invasion_spawn_delay;
 104                 }
 105
 106                 return 0;
 107         }
 108
 109         if(inv_numspawned < 1 || inv_numkilled < inv_maxspawned)
 110                 return 0; // nothing has spawned yet, or there are still alive monsters
 111
 112         if(inv_roundcnt >= inv_maxrounds)
 113         {
 114                 NextLevel();
 115                 return 1;
 116         }
 117
 118         entity winner = world;
 119         float winning_score = 0;
 120
 121         FOR_EACH_PLAYER(head)
 122         {
 123                 float cs = PlayerScore_Add(head, SP_KILLS, 0);
 124                 if(cs > winning_score)
 125                 {
 126                         winning_score = cs;
 127                         winner = head;
 128                 }
 129         }
 130
 131         FOR_EACH_MONSTER(head)
 132                 monster_remove(head);
 133
 134         if(winner)
 135         {
 136                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
 137                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
 138         }
 139
 140         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 141
 142         return 1;
 143 }
 144
 145 float Invasion_CheckPlayers()
 146 {
 147         return TRUE;
 148 }
 149
 150 void Invasion_RoundStart()
 151 {
 152         entity e;
 153         float numplayers = 0;
 154         FOR_EACH_PLAYER(e)
 155         {
 156                 e.player_blocked = 0;
 157                 ++numplayers;
 158         }
 159
 160         inv_roundcnt += 1;
 161
 162         inv_monsterskill = inv_roundcnt + max(1, numplayers * 0.3);
 163
 164         inv_maxcurrent = 0;
 165         inv_numspawned = 0;
 166         inv_numkilled = 0;
 167
 168         inv_maxspawned = rint(max(autocvar_g_invasion_monster_count, autocvar_g_invasion_monster_count * (inv_roundcnt * 0.5)));
 169 }
 170
 171 MUTATOR_HOOKFUNCTION(invasion_MonsterDies)
 172 {
 173         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 174         {
 175                 inv_numkilled += 1;
 176                 inv_maxcurrent -= 1;
 177
 178                 if(IS_PLAYER(frag_attacker))
 179                         PlayerScore_Add(frag_attacker, SP_KILLS, +1);
 180         }
 181
 182         return FALSE;
 183 }
 184
 185 MUTATOR_HOOKFUNCTION(invasion_MonsterSpawn)
 186 {
 187         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
 188         {
 189                 monster_remove(self);
 190                 return FALSE;
 191         }
 192
 193         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 194         {
 195                 inv_numspawned += 1;
 196                 inv_maxcurrent += 1;
 197         }
 198
 199         self.monster_skill = inv_monsterskill;
 200
 201         if((get_monsterinfo(self.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
 202                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_INVASION_SUPERMONSTER, M_NAME(self.monsterid));
 203
 204         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 205
 206         return FALSE;
 207 }
 208
 209 MUTATOR_HOOKFUNCTION(invasion_PlayerThink)
 210 {
 211         monsters_total = inv_maxspawned; // TODO: make sure numspawned never exceeds maxspawned
 212         monsters_killed = inv_numkilled;
 213
 214         return FALSE;
 215 }
 216
 217 MUTATOR_HOOKFUNCTION(invasion_PlayerRegen)
 218 {
 219         // no regeneration in invasion
 220         return TRUE;
 221 }
 222
 223 MUTATOR_HOOKFUNCTION(invasion_PlayerSpawn)
 224 {
 225         self.bot_attack = FALSE;
 226         return FALSE;
 227 }
 228
 229 MUTATOR_HOOKFUNCTION(invasion_PlayerDamage)
 230 {
 231         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
 232         {
 233                 frag_damage = 0;
 234                 frag_force = '0 0 0';
 235         }
 236
 237         return FALSE;
 238 }
 239
 240 MUTATOR_HOOKFUNCTION(invasion_PlayerCommand)
 241 {
 242         if(MUTATOR_RETURNVALUE) // command was already handled?
 243                 return FALSE;
 244
 245         if(cmd_name == "debuginvasion")
 246         {
 247                 sprint(self, strcat("inv_maxspawned = ", ftos(inv_maxspawned), "\n"));
 248                 sprint(self, strcat("inv_numspawned = ", ftos(inv_numspawned), "\n"));
 249                 sprint(self, strcat("inv_numkilled = ", ftos(inv_numkilled), "\n"));
 250                 sprint(self, strcat("inv_roundcnt = ", ftos(inv_roundcnt), "\n"));
 251                 sprint(self, strcat("monsters_total = ", ftos(monsters_total), "\n"));
 252                 sprint(self, strcat("monsters_killed = ", ftos(monsters_killed), "\n"));
 253                 sprint(self, strcat("inv_monsterskill = ", ftos(inv_monsterskill), "\n"));
 254
 255                 return TRUE;
 256         }
 257
 258         return FALSE;
 259 }
 260
 261 MUTATOR_HOOKFUNCTION(invasion_SetStartItems)
 262 {
 263         start_health = 200;
 264         start_armorvalue = 200;
 265
 266         return FALSE;
 267 }
 268
 269 MUTATOR_HOOKFUNCTION(invasion_AccuracyTargetValid)
 270 {
 271         if(frag_target.flags & FL_MONSTER)
 272                 return MUT_ACCADD_INVALID;
 273         return MUT_ACCADD_INDIFFERENT;
 274 }
 275
 276 MUTATOR_HOOKFUNCTION(invasion_AllowMobSpawning)
 277 {
 278         // monster spawning disabled during an invasion
 279         return TRUE;
 280 }
 281
 282 void invasion_ScoreRules()
 283 {
 284         ScoreRules_basics(0, 0, 0, FALSE);
 285         ScoreInfo_SetLabel_PlayerScore(SP_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
 286         ScoreRules_basics_end();
 287 }
 288
 289 void invasion_Initialize()
 290 {
 291         independent_players = 1; // to disable extra useless scores
 292
 293         invasion_ScoreRules();
 294
 295         independent_players = 0;
 296
 297         round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
 298         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 299
 300         allowed_to_spawn = TRUE;
 301
 302         inv_roundcnt = 0;
 303 }
 304
 305 MUTATOR_DEFINITION(gamemode_invasion)
 306 {
 307         MUTATOR_HOOK(MonsterDies, invasion_MonsterDies, CBC_ORDER_ANY);
 308         MUTATOR_HOOK(MonsterSpawn, invasion_MonsterSpawn, CBC_ORDER_ANY);
 309         MUTATOR_HOOK(PlayerPreThink, invasion_PlayerThink, CBC_ORDER_ANY);
 310         MUTATOR_HOOK(PlayerRegen, invasion_PlayerRegen, CBC_ORDER_ANY);
 311         MUTATOR_HOOK(PlayerSpawn, invasion_PlayerSpawn, CBC_ORDER_ANY);
 312         MUTATOR_HOOK(PlayerDamage_Calculate, invasion_PlayerDamage, CBC_ORDER_ANY);
 313         MUTATOR_HOOK(SV_ParseClientCommand, invasion_PlayerCommand, CBC_ORDER_ANY);
 314         MUTATOR_HOOK(SetStartItems, invasion_SetStartItems, CBC_ORDER_ANY);
 315         MUTATOR_HOOK(AccuracyTargetValid, invasion_AccuracyTargetValid, CBC_ORDER_ANY);
 316         MUTATOR_HOOK(AllowMobSpawning, invasion_AllowMobSpawning, CBC_ORDER_ANY);
 317
 318         MUTATOR_ONADD
 319         {
 320                 if(time > 1) // game loads at time 1
 321                         error("This is a game type and it cannot be added at runtime.");
 322                 invasion_Initialize();
 323
 324                 cvar_settemp("g_monsters", "1");
 325         }
 326
 327         MUTATOR_ONROLLBACK_OR_REMOVE
 328         {
 329                 // we actually cannot roll back invasion_Initialize here
 330                 // BUT: we don't need to! If this gets called, adding always
 331                 // succeeds.
 332         }
 333
 334         MUTATOR_ONREMOVE
 335         {
 336                 print("This is a game type and it cannot be removed at runtime.");
 337                 return -1;
 338         }
 339
 340         return 0;
 341 }